lisp/image-mode.el

   1 ;;; image-mode.el --- support for visiting image files  -*- lexical-binding: t -*-
   2 ;;
   3 ;; Copyright (C) 2005-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Richard Stallman <rms@gnu.org>
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Defines a major mode for visiting image files
  27 ;; that allows conversion between viewing the text of the file
  28 ;; and viewing the file as an image.  Viewing the image
  29 ;; works by putting a `display' text-property on the
  30 ;; image data, with the image-data still present underneath; if the
  31 ;; resulting buffer file is saved to another name it will correctly save
  32 ;; the image data to the new file.
  33
  34 ;; Todo:
  35
  36 ;; Consolidate with doc-view to make them work on directories of images or on
  37 ;; image files containing various "pages".
  38
  39 ;;; Code:
  40
  41 (require 'image)
  42 (eval-when-compile (require 'cl-lib))
  43
  44 ;;; Image mode window-info management.
  45
  46 (defvar-local image-mode-winprops-alist t)
  47
  48 (defvar image-mode-new-window-functions nil
  49   "Special hook run when image data is requested in a new window.
  50 It is called with one argument, the initial WINPROPS.")
  51
  52 (defun image-mode-winprops (&optional window cleanup)
  53   "Return winprops of WINDOW.
  54 A winprops object has the shape (WINDOW . ALIST).
  55 WINDOW defaults to `selected-window' if it displays the current buffer, and
  56 otherwise it defaults to t, used for times when the buffer is not displayed."
  57   (cond ((null window)
  58          (setq window
  59                (if (eq (current-buffer) (window-buffer)) (selected-window) t)))
  60         ((eq window t))
  61         ((not (windowp window))
  62          (error "Not a window: %s" window)))
  63   (when cleanup
  64     (setq image-mode-winprops-alist
  65           (delq nil (mapcar (lambda (winprop)
  66                               (let ((w (car-safe winprop)))
  67                                 (if (or (not (windowp w)) (window-live-p w))
  68                                     winprop)))
  69                             image-mode-winprops-alist))))
  70   (let ((winprops (assq window image-mode-winprops-alist)))
  71     ;; For new windows, set defaults from the latest.
  72     (unless winprops
  73       (setq winprops (cons window
  74                            (copy-alist (cdar image-mode-winprops-alist))))
  75       (run-hook-with-args 'image-mode-new-window-functions winprops))
  76     ;; Move window to front.
  77     (setq image-mode-winprops-alist
  78           (cons winprops (delq winprops image-mode-winprops-alist)))
  79     winprops))
  80
  81 (defun image-mode-window-get (prop &optional winprops)
  82   (declare (gv-setter (lambda (val)
  83                         `(image-mode-window-put ,prop ,val ,winprops))))
  84   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  85   (cdr (assq prop (cdr winprops))))
  86
  87 (defun image-mode-window-put (prop val &optional winprops)
  88   (unless (consp winprops) (setq winprops (image-mode-winprops winprops)))
  89   (setcdr winprops (cons (cons prop val)
  90                          (delq (assq prop (cdr winprops)) (cdr winprops)))))
  91
  92 (defun image-set-window-vscroll (vscroll)
  93   (setf (image-mode-window-get 'vscroll) vscroll)
  94   (set-window-vscroll (selected-window) vscroll))
  95
  96 (defun image-set-window-hscroll (ncol)
  97   (setf (image-mode-window-get 'hscroll) ncol)
  98   (set-window-hscroll (selected-window) ncol))
  99
 100 (defun image-mode-reapply-winprops ()
 101   ;; When set-window-buffer, set hscroll and vscroll to what they were
 102   ;; last time the image was displayed in this window.
 103   (when (and (image-get-display-property)
 104              (listp image-mode-winprops-alist))
 105     (let* ((winprops (image-mode-winprops nil t))
 106            (hscroll (image-mode-window-get 'hscroll winprops))
 107            (vscroll (image-mode-window-get 'vscroll winprops)))
 108       (if hscroll (set-window-hscroll (selected-window) hscroll))
 109       (if vscroll (set-window-vscroll (selected-window) vscroll)))))
 110
 111 (defun image-mode-setup-winprops ()
 112   ;; Record current scroll settings.
 113   (unless (listp image-mode-winprops-alist)
 114     (setq image-mode-winprops-alist nil))
 115   (add-hook 'window-configuration-change-hook
 116             'image-mode-reapply-winprops nil t))
 117
 118 ;;; Image scrolling functions
 119
 120 (defun image-get-display-property ()
 121   (get-char-property (point-min) 'display
 122                      ;; There might be different images for different displays.
 123                      (if (eq (window-buffer) (current-buffer))
 124                          (selected-window))))
 125
 126 (declare-function image-size "image.c" (spec &optional pixels frame))
 127
 128 (defun image-display-size (spec &optional pixels frame)
 129   "Wrapper around `image-size', handling slice display properties.
 130 Like `image-size', the return value is (WIDTH . HEIGHT).
 131 WIDTH and HEIGHT are in canonical character units if PIXELS is
 132 nil, and in pixel units if PIXELS is non-nil.
 133
 134 If SPEC is an image display property, this function is equivalent
 135 to `image-size'.  If SPEC is a list of properties containing
 136 `image' and `slice' properties, return the display size taking
 137 the slice property into account.  If the list contains `image'
 138 but not `slice', return the `image-size' of the specified image."
 139   (if (eq (car spec) 'image)
 140       (image-size spec pixels frame)
 141     (let ((image (assoc 'image spec))
 142           (slice (assoc 'slice spec)))
 143       (cond ((and image slice)
 144              (if pixels
 145                  (cons (nth 3 slice) (nth 4 slice))
 146                (cons (/ (float (nth 3 slice)) (frame-char-width frame))
 147                      (/ (float (nth 4 slice)) (frame-char-height frame)))))
 148             (image
 149              (image-size image pixels frame))
 150             (t
 151              (error "Invalid image specification: %s" spec))))))
 152
 153 (defun image-forward-hscroll (&optional n)
 154   "Scroll image in current window to the left by N character widths.
 155 Stop if the right edge of the image is reached."
 156   (interactive "p")
 157   (cond ((= n 0) nil)
 158         ((< n 0)
 159          (image-set-window-hscroll (max 0 (+ (window-hscroll) n))))
 160         (t
 161          (let* ((image (image-get-display-property))
 162                 (edges (window-inside-edges))
 163                 (win-width (- (nth 2 edges) (nth 0 edges)))
 164                 (img-width (ceiling (car (image-display-size image)))))
 165            (image-set-window-hscroll (min (max 0 (- img-width win-width))
 166                                           (+ n (window-hscroll))))))))
 167
 168 (defun image-backward-hscroll (&optional n)
 169   "Scroll image in current window to the right by N character widths.
 170 Stop if the left edge of the image is reached."
 171   (interactive "p")
 172   (image-forward-hscroll (- n)))
 173
 174 (defun image-next-line (n)
 175   "Scroll image in current window upward by N lines.
 176 Stop if the bottom edge of the image is reached."
 177   (interactive "p")
 178   (cond ((= n 0) nil)
 179         ((< n 0)
 180          (image-set-window-vscroll (max 0 (+ (window-vscroll) n))))
 181         (t
 182          (let* ((image (image-get-display-property))
 183                 (edges (window-inside-edges))
 184                 (win-height (- (nth 3 edges) (nth 1 edges)))
 185                 (img-height (ceiling (cdr (image-display-size image)))))
 186            (image-set-window-vscroll (min (max 0 (- img-height win-height))
 187                                           (+ n (window-vscroll))))))))
 188
 189 (defun image-previous-line (&optional n)
 190   "Scroll image in current window downward by N lines.
 191 Stop if the top edge of the image is reached."
 192   (interactive "p")
 193   (image-next-line (- n)))
 194
 195 (defun image-scroll-up (&optional n)
 196   "Scroll image in current window upward by N lines.
 197 Stop if the bottom edge of the image is reached.
 198 If ARG is omitted or nil, scroll upward by a near full screen.
 199 A near full screen is `next-screen-context-lines' less than a full screen.
 200 Negative ARG means scroll downward.
 201 If ARG is the atom `-', scroll downward by nearly full screen.
 202 When calling from a program, supply as argument a number, nil, or `-'."
 203   (interactive "P")
 204   (cond ((null n)
 205          (let* ((edges (window-inside-edges))
 206                 (win-height (- (nth 3 edges) (nth 1 edges))))
 207            (image-next-line
 208             (max 0 (- win-height next-screen-context-lines)))))
 209         ((eq n '-)
 210          (let* ((edges (window-inside-edges))
 211                 (win-height (- (nth 3 edges) (nth 1 edges))))
 212            (image-next-line
 213             (min 0 (- next-screen-context-lines win-height)))))
 214         (t (image-next-line (prefix-numeric-value n)))))
 215
 216 (defun image-scroll-down (&optional n)
 217   "Scroll image in current window downward by N lines.
 218 Stop if the top edge of the image is reached.
 219 If ARG is omitted or nil, scroll downward by a near full screen.
 220 A near full screen is `next-screen-context-lines' less than a full screen.
 221 Negative ARG means scroll upward.
 222 If ARG is the atom `-', scroll upward by nearly full screen.
 223 When calling from a program, supply as argument a number, nil, or `-'."
 224   (interactive "P")
 225   (cond ((null n)
 226          (let* ((edges (window-inside-edges))
 227                 (win-height (- (nth 3 edges) (nth 1 edges))))
 228            (image-next-line
 229             (min 0 (- next-screen-context-lines win-height)))))
 230         ((eq n '-)
 231          (let* ((edges (window-inside-edges))
 232                 (win-height (- (nth 3 edges) (nth 1 edges))))
 233            (image-next-line
 234             (max 0 (- win-height next-screen-context-lines)))))
 235         (t (image-next-line (- (prefix-numeric-value n))))))
 236
 237 (defun image-bol (arg)
 238   "Scroll horizontally to the left edge of the image in the current window.
 239 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 240 stopping if the top or bottom edge of the image is reached."
 241   (interactive "p")
 242   (and arg
 243        (/= (setq arg (prefix-numeric-value arg)) 1)
 244        (image-next-line (- arg 1)))
 245   (image-set-window-hscroll 0))
 246
 247 (defun image-eol (arg)
 248   "Scroll horizontally to the right edge of the image in the current window.
 249 With argument ARG not nil or 1, move forward ARG - 1 lines first,
 250 stopping if the top or bottom edge of the image is reached."
 251   (interactive "p")
 252   (and arg
 253        (/= (setq arg (prefix-numeric-value arg)) 1)
 254        (image-next-line (- arg 1)))
 255   (let* ((image (image-get-display-property))
 256          (edges (window-inside-edges))
 257          (win-width (- (nth 2 edges) (nth 0 edges)))
 258          (img-width (ceiling (car (image-display-size image)))))
 259     (image-set-window-hscroll (max 0 (- img-width win-width)))))
 260
 261 (defun image-bob ()
 262   "Scroll to the top-left corner of the image in the current window."
 263   (interactive)
 264   (image-set-window-hscroll 0)
 265   (image-set-window-vscroll 0))
 266
 267 (defun image-eob ()
 268   "Scroll to the bottom-right corner of the image in the current window."
 269   (interactive)
 270   (let* ((image (image-get-display-property))
 271          (edges (window-inside-edges))
 272          (win-width (- (nth 2 edges) (nth 0 edges)))
 273          (img-width (ceiling (car (image-display-size image))))
 274          (win-height (- (nth 3 edges) (nth 1 edges)))
 275          (img-height (ceiling (cdr (image-display-size image)))))
 276     (image-set-window-hscroll (max 0 (- img-width win-width)))
 277     (image-set-window-vscroll (max 0 (- img-height win-height)))))
 278
 279 ;; Adjust frame and image size.
 280
 281 (defun image-mode-fit-frame (&optional frame toggle)
 282   "Fit FRAME to the current image.
 283 If FRAME is omitted or nil, it defaults to the selected frame.
 284 All other windows on the frame are deleted.
 285
 286 If called interactively, or if TOGGLE is non-nil, toggle between
 287 fitting FRAME to the current image and restoring the size and
 288 window configuration prior to the last `image-mode-fit-frame'
 289 call."
 290   (interactive (list nil t))
 291   (let* ((buffer (current-buffer))
 292          (display (image-get-display-property))
 293          (size (image-display-size display))
 294          (saved (frame-parameter frame 'image-mode-saved-params))
 295          (window-configuration (current-window-configuration frame))
 296          (width  (frame-width  frame))
 297          (height (frame-height frame)))
 298     (with-selected-frame (or frame (selected-frame))
 299       (if (and toggle saved
 300                (= (caar saved) width)
 301                (= (cdar saved) height))
 302           (progn
 303             (set-frame-width  frame (car (nth 1 saved)))
 304             (set-frame-height frame (cdr (nth 1 saved)))
 305             (set-window-configuration (nth 2 saved))
 306             (set-frame-parameter frame 'image-mode-saved-params nil))
 307         (delete-other-windows)
 308         (switch-to-buffer buffer t t)
 309         (let* ((edges (window-inside-edges))
 310                (inner-width  (- (nth 2 edges) (nth 0 edges)))
 311                (inner-height (- (nth 3 edges) (nth 1 edges))))
 312           (set-frame-width  frame (+ (ceiling (car size))
 313                                      width (- inner-width)))
 314           (set-frame-height frame (+ (ceiling (cdr size))
 315                                      height (- inner-height)))
 316           ;; The frame size after the above `set-frame-*' calls may
 317           ;; differ from what we specified, due to window manager
 318           ;; interference.  We have to call `frame-width' and
 319           ;; `frame-height' to get the actual results.
 320           (set-frame-parameter frame 'image-mode-saved-params
 321                                (list (cons (frame-width)
 322                                            (frame-height))
 323                                      (cons width height)
 324                                      window-configuration)))))))
 325
 326 ;;; Image Mode setup
 327
 328 (defvar image-type nil
 329   "The image type for the current Image mode buffer.")
 330 (make-variable-buffer-local 'image-type)
 331
 332 (defvar image-mode-previous-major-mode nil
 333   "Internal variable to keep the previous non-image major mode.")
 334
 335 (defvar image-mode-map
 336   (let ((map (make-sparse-keymap)))
 337     (set-keymap-parent map special-mode-map)
 338     (define-key map "\C-c\C-c" 'image-toggle-display)
 339     (define-key map (kbd "SPC")       'image-scroll-up)
 340     (define-key map (kbd "S-SPC")     'image-scroll-down)
 341     (define-key map (kbd "DEL")       'image-scroll-down)
 342     (define-key map (kbd "RET")       'image-toggle-animation)
 343     (define-key map "F" 'image-goto-frame)
 344     (define-key map "f" 'image-next-frame)
 345     (define-key map "b" 'image-previous-frame)
 346     (define-key map "n" 'image-next-file)
 347     (define-key map "p" 'image-previous-file)
 348     (define-key map [remap forward-char] 'image-forward-hscroll)
 349     (define-key map [remap backward-char] 'image-backward-hscroll)
 350     (define-key map [remap right-char] 'image-forward-hscroll)
 351     (define-key map [remap left-char] 'image-backward-hscroll)
 352     (define-key map [remap previous-line] 'image-previous-line)
 353     (define-key map [remap next-line] 'image-next-line)
 354     (define-key map [remap scroll-up] 'image-scroll-up)
 355     (define-key map [remap scroll-down] 'image-scroll-down)
 356     (define-key map [remap scroll-up-command] 'image-scroll-up)
 357     (define-key map [remap scroll-down-command] 'image-scroll-down)
 358     (define-key map [remap move-beginning-of-line] 'image-bol)
 359     (define-key map [remap move-end-of-line] 'image-eol)
 360     (define-key map [remap beginning-of-buffer] 'image-bob)
 361     (define-key map [remap end-of-buffer] 'image-eob)
 362     map)
 363   "Mode keymap for `image-mode'.")
 364
 365 (defvar image-minor-mode-map
 366   (let ((map (make-sparse-keymap)))
 367     (define-key map "\C-c\C-c" 'image-toggle-display)
 368     map)
 369   "Mode keymap for `image-minor-mode'.")
 370
 371 (defvar bookmark-make-record-function)
 372
 373 (put 'image-mode 'mode-class 'special)
 374
 375 ;;;###autoload
 376 (defun image-mode ()
 377   "Major mode for image files.
 378 You can use \\<image-mode-map>\\[image-toggle-display]
 379 to toggle between display as an image and display as text."
 380   (interactive)
 381   (condition-case err
 382       (progn
 383         (unless (display-images-p)
 384           (error "Display does not support images"))
 385
 386         (kill-all-local-variables)
 387         (setq major-mode 'image-mode)
 388
 389         (if (not (image-get-display-property))
 390             (progn
 391               (image-toggle-display-image)
 392               ;; If attempt to display the image fails.
 393               (if (not (image-get-display-property))
 394                   (error "Invalid image")))
 395           ;; Set next vars when image is already displayed but local
 396           ;; variables were cleared by kill-all-local-variables
 397           (setq cursor-type nil truncate-lines t
 398                 image-type (plist-get (cdr (image-get-display-property)) :type)))
 399
 400         (setq mode-name (if image-type (format "Image[%s]" image-type) "Image"))
 401         (use-local-map image-mode-map)
 402
 403         ;; Use our own bookmarking function for images.
 404         (set (make-local-variable 'bookmark-make-record-function)
 405              'image-bookmark-make-record)
 406
 407         ;; Keep track of [vh]scroll when switching buffers
 408         (image-mode-setup-winprops)
 409
 410         (add-hook 'change-major-mode-hook 'image-toggle-display-text nil t)
 411         (add-hook 'after-revert-hook 'image-after-revert-hook nil t)
 412         (run-mode-hooks 'image-mode-hook)
 413         (let ((image (image-get-display-property))
 414               (msg1 (substitute-command-keys
 415                      "Type \\[image-toggle-display] to view the image as "))
 416               animated)
 417           (cond
 418            ((null image)
 419             (message "%s" (concat msg1 "an image.")))
 420            ((setq animated (image-animated-p image))
 421             (setq image-current-frame (or (plist-get (cdr image) :index) 0)
 422                   mode-line-process
 423                   `(:eval (propertize (format " [%s/%s]"
 424                                               (1+ image-current-frame)
 425                                               ,(car animated))
 426                                       'help-echo "Frame number")))
 427             (message "%s"
 428                      (concat msg1 "text, or "
 429                              (substitute-command-keys
 430                               "\\[image-toggle-animation] to animate."))))
 431            (t
 432             (message "%s" (concat msg1 "text."))))))
 433
 434     (error
 435      (image-mode-as-text)
 436      (funcall
 437       (if (called-interactively-p 'any) 'error 'message)
 438       "Cannot display image: %s" (cdr err)))))
 439
 440 ;;;###autoload
 441 (define-minor-mode image-minor-mode
 442   "Toggle Image minor mode in this buffer.
 443 With a prefix argument ARG, enable Image minor mode if ARG is
 444 positive, and disable it otherwise.  If called from Lisp, enable
 445 the mode if ARG is omitted or nil.
 446
 447 Image minor mode provides the key \\<image-mode-map>\\[image-toggle-display],
 448 to switch back to `image-mode' and display an image file as the
 449 actual image."
 450   nil (:eval (if image-type (format " Image[%s]" image-type) " Image"))
 451   image-minor-mode-map
 452   :group 'image
 453   :version "22.1"
 454   (if image-minor-mode
 455       (add-hook 'change-major-mode-hook (lambda () (image-minor-mode -1)) nil t)))
 456
 457 ;;;###autoload
 458 (defun image-mode-as-text ()
 459   "Set a non-image mode as major mode in combination with image minor mode.
 460 A non-image major mode found from `auto-mode-alist' or Fundamental mode
 461 displays an image file as text.  `image-minor-mode' provides the key
 462 \\<image-mode-map>\\[image-toggle-display] to switch back to `image-mode'
 463 to display an image file as the actual image.
 464
 465 You can use `image-mode-as-text' in `auto-mode-alist' when you want
 466 to display an image file as text initially.
 467
 468 See commands `image-mode' and `image-minor-mode' for more information
 469 on these modes."
 470   (interactive)
 471   ;; image-mode-as-text = normal-mode + image-minor-mode
 472   (let ((previous-image-type image-type)) ; preserve `image-type'
 473     (if image-mode-previous-major-mode
 474         ;; Restore previous major mode that was already found by this
 475         ;; function and cached in `image-mode-previous-major-mode'
 476         (funcall image-mode-previous-major-mode)
 477       (let ((auto-mode-alist
 478              (delq nil (mapcar
 479                         (lambda (elt)
 480                           (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 481                                         '(image-mode image-mode-maybe image-mode-as-text))
 482                             elt))
 483                         auto-mode-alist)))
 484             (magic-fallback-mode-alist
 485              (delq nil (mapcar
 486                         (lambda (elt)
 487                           (unless (memq (or (car-safe (cdr elt)) (cdr elt))
 488                                         '(image-mode image-mode-maybe image-mode-as-text))
 489                             elt))
 490                         magic-fallback-mode-alist))))
 491         (normal-mode)
 492         (set (make-local-variable 'image-mode-previous-major-mode) major-mode)))
 493     ;; Restore `image-type' after `kill-all-local-variables' in `normal-mode'.
 494     (setq image-type previous-image-type)
 495     ;; Enable image minor mode with `C-c C-c'.
 496     (image-minor-mode 1)
 497     ;; Show the image file as text.
 498     (image-toggle-display-text)
 499     (message "%s" (concat
 500                    (substitute-command-keys
 501                     "Type \\[image-toggle-display] to view the image as ")
 502                    (if (image-get-display-property)
 503                        "text" "an image") "."))))
 504
 505 (define-obsolete-function-alias 'image-mode-maybe 'image-mode "23.2")
 506
 507 (defun image-toggle-display-text ()
 508   "Show the image file as text.
 509 Remove text properties that display the image."
 510   (let ((inhibit-read-only t)
 511         (buffer-undo-list t)
 512         (modified (buffer-modified-p)))
 513     (remove-list-of-text-properties (point-min) (point-max)
 514                                     '(display read-nonsticky ;; intangible
 515                                               read-only front-sticky))
 516     (set-buffer-modified-p modified)
 517     (if (called-interactively-p 'any)
 518         (message "Repeat this command to go back to displaying the image"))))
 519
 520 (defvar archive-superior-buffer)
 521 (defvar tar-superior-buffer)
 522 (declare-function image-flush "image.c" (spec &optional frame))
 523
 524 (defun image-toggle-display-image ()
 525   "Show the image of the image file.
 526 Turn the image data into a real image, but only if the whole file
 527 was inserted."
 528   (unless (derived-mode-p 'image-mode)
 529     (error "The buffer is not in Image mode"))
 530   (let* ((filename (buffer-file-name))
 531          (data-p (not (and filename
 532                            (file-readable-p filename)
 533                            (not (file-remote-p filename))
 534                            (not (buffer-modified-p))
 535                            (not (and (boundp 'archive-superior-buffer)
 536                                      archive-superior-buffer))
 537                            (not (and (boundp 'tar-superior-buffer)
 538                                      tar-superior-buffer)))))
 539          (file-or-data (if data-p
 540                            (string-make-unibyte
 541                             (buffer-substring-no-properties (point-min) (point-max)))
 542                          filename))
 543          (type (image-type file-or-data nil data-p))
 544          (image (create-image file-or-data type data-p))
 545          (inhibit-read-only t)
 546          (buffer-undo-list t)
 547          (modified (buffer-modified-p))
 548          props)
 549
 550     ;; Discard any stale image data before looking it up again.
 551     (image-flush image)
 552     (setq image (append image (image-transform-properties image)))
 553     (setq props
 554           `(display ,image
 555                     ;; intangible ,image
 556                     rear-nonsticky (display) ;; intangible
 557                     read-only t front-sticky (read-only)))
 558
 559     (let ((buffer-file-truename nil)) ; avoid changing dir mtime by lock_file
 560       (add-text-properties (point-min) (point-max) props)
 561       (restore-buffer-modified-p modified))
 562     ;; Inhibit the cursor when the buffer contains only an image,
 563     ;; because cursors look very strange on top of images.
 564     (setq cursor-type nil)
 565     ;; This just makes the arrow displayed in the right fringe
 566     ;; area look correct when the image is wider than the window.
 567     (setq truncate-lines t)
 568     ;; Disable adding a newline at the end of the image file when it
 569     ;; is written with, e.g., C-x C-w.
 570     (if (coding-system-equal (coding-system-base buffer-file-coding-system)
 571                              'no-conversion)
 572         (set (make-local-variable 'find-file-literally) t))
 573     ;; Allow navigation of large images
 574     (set (make-local-variable 'auto-hscroll-mode) nil)
 575     (setq image-type type)
 576     (if (eq major-mode 'image-mode)
 577         (setq mode-name (format "Image[%s]" type)))
 578     (image-transform-check-size)
 579     (if (called-interactively-p 'any)
 580         (message "Repeat this command to go back to displaying the file as text"))))
 581
 582 (defun image-toggle-display ()
 583   "Toggle between image and text display.
 584 If the current buffer is displaying an image file as an image,
 585 call `image-mode-as-text' to switch to text.  Otherwise, display
 586 the image by calling `image-mode'."
 587   (interactive)
 588   (if (image-get-display-property)
 589       (image-mode-as-text)
 590     (image-mode)))
 591
 592 (defun image-after-revert-hook ()
 593   (when (image-get-display-property)
 594     (image-toggle-display-text)
 595     ;; Update image display.
 596     (mapc (lambda (window) (redraw-frame (window-frame window)))
 597           (get-buffer-window-list (current-buffer) 'nomini 'visible))
 598     (image-toggle-display-image)))
 599
 600 \f
 601 ;;; Animated images
 602
 603 (defcustom image-animate-loop nil
 604   "Non-nil means animated images loop forever, rather than playing once."
 605   :type 'boolean
 606   :version "24.1"
 607   :group 'image)
 608
 609 (defun image-toggle-animation ()
 610   "Start or stop animating the current image.
 611 If `image-animate-loop' is non-nil, animation loops forever.
 612 Otherwise it plays once, then stops."
 613   (interactive)
 614   (let ((image (image-get-display-property))
 615         animation)
 616     (cond
 617      ((null image)
 618       (error "No image is present"))
 619      ((null (setq animation (image-animated-p image)))
 620       (message "No image animation."))
 621      (t
 622       (let ((timer (image-animate-timer image)))
 623         (if timer
 624             (cancel-timer timer)
 625           (let ((index (plist-get (cdr image) :index)))
 626             ;; If we're at the end, restart.
 627             (and index
 628                  (>= index (1- (car animation)))
 629                  (setq index nil))
 630             (image-animate image index
 631                            (if image-animate-loop t)))))))))
 632
 633 (defun image-goto-frame (n &optional relative)
 634   "Show frame N of a multi-frame image.
 635 Optional argument OFFSET non-nil means interpret N as relative to the
 636 current frame.  Frames are indexed from 1."
 637   (interactive
 638    (list (or current-prefix-arg
 639              (read-number "Show frame number: "))))
 640   (let ((image (image-get-display-property))
 641         animation)
 642     (cond
 643      ((null image)
 644       (error "No image is present"))
 645      ((null image-current-frame)
 646       (message "No image animation."))
 647      (t
 648       (image-nth-frame image (if relative (+ n image-current-frame) (1- n)))))))
 649
 650 (defun image-next-frame (&optional n)
 651   "Switch to the next frame of a multi-frame image.
 652 With optional argument N, switch to the Nth frame after the current one.
 653 If N is negative, switch to the Nth frame before the current one."
 654   (interactive "p")
 655   (image-goto-frame n t))
 656
 657 (defun image-previous-frame (&optional n)
 658   "Switch to the previous frame of a multi-frame image.
 659 With optional argument N, switch to the Nth frame before the current one.
 660 If N is negative, switch to the Nth frame after the current one."
 661   (interactive "p")
 662   (image-next-frame (- n)))
 663
 664 \f
 665 ;;; Switching to the next/previous image
 666
 667 (defun image-next-file (&optional n)
 668   "Visit the next image in the same directory as the current image file.
 669 With optional argument N, visit the Nth image file after the
 670 current one, in cyclic alphabetical order.
 671
 672 This command visits the specified file via `find-alternate-file',
 673 replacing the current Image mode buffer."
 674   (interactive "p")
 675   (unless (derived-mode-p 'image-mode)
 676     (error "The buffer is not in Image mode"))
 677   (unless buffer-file-name
 678     (error "The current image is not associated with a file"))
 679   (let* ((file (file-name-nondirectory buffer-file-name))
 680          (images (image-mode--images-in-directory file))
 681          (idx 0))
 682     (catch 'image-visit-next-file
 683       (dolist (f images)
 684         (if (string= f file)
 685             (throw 'image-visit-next-file (1+ idx)))
 686         (setq idx (1+ idx))))
 687     (setq idx (mod (+ idx (or n 1)) (length images)))
 688     (find-alternate-file (nth idx images))))
 689
 690 (defun image-previous-file (&optional n)
 691   "Visit the preceding image in the same directory as the current file.
 692 With optional argument N, visit the Nth image file preceding the
 693 current one, in cyclic alphabetical order.
 694
 695 This command visits the specified file via `find-alternate-file',
 696 replacing the current Image mode buffer."
 697   (interactive "p")
 698   (image-next-file (- n)))
 699
 700 (defun image-mode--images-in-directory (file)
 701   (let* ((dir (file-name-directory buffer-file-name))
 702          (files (directory-files dir nil
 703                                  (image-file-name-regexp) t)))
 704     ;; Add the current file to the list of images if necessary, in
 705     ;; case it does not match `image-file-name-regexp'.
 706     (unless (member file files)
 707       (push file files))
 708     (sort files 'string-lessp)))
 709
 710 \f
 711 ;;; Support for bookmark.el
 712 (declare-function bookmark-make-record-default
 713                   "bookmark" (&optional no-file no-context posn))
 714 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 715 (declare-function bookmark-default-handler "bookmark" (bmk))
 716
 717 (defun image-bookmark-make-record ()
 718   `(,@(bookmark-make-record-default nil 'no-context 0)
 719       (image-type . ,image-type)
 720       (handler    . image-bookmark-jump)))
 721
 722 ;;;###autoload
 723 (defun image-bookmark-jump (bmk)
 724   ;; This implements the `handler' function interface for record type
 725   ;; returned by `bookmark-make-record-function', which see.
 726   (prog1 (bookmark-default-handler bmk)
 727     (when (not (string= image-type (bookmark-prop-get bmk 'image-type)))
 728       (image-toggle-display))))
 729 \f
 730
 731 ;; Not yet implemented.
 732 ;; (defvar image-transform-minor-mode-map
 733 ;;   (let ((map (make-sparse-keymap)))
 734 ;;     ;; (define-key map  [(control ?+)] 'image-scale-in)
 735 ;;     ;; (define-key map  [(control ?-)] 'image-scale-out)
 736 ;;     ;; (define-key map  [(control ?=)] 'image-scale-none)
 737 ;;     ;; (define-key map "c f h" 'image-scale-fit-height)
 738 ;;     ;; (define-key map "c ]" 'image-rotate-right)
 739 ;;     map)
 740 ;;   "Minor mode keymap `image-transform-mode'.")
 741 ;;
 742 ;; (define-minor-mode image-transform-mode
 743 ;;   "Minor mode for scaling and rotating images.
 744 ;; With a prefix argument ARG, enable the mode if ARG is positive,
 745 ;; and disable it otherwise.  If called from Lisp, enable the mode
 746 ;; if ARG is omitted or nil.  This minor mode requires Emacs to have
 747 ;; been compiled with ImageMagick support."
 748 ;;   nil "image-transform" image-transform-minor-mode-map)
 749
 750
 751 ;; FIXME this doesn't seem mature yet. Document in manual when it is.
 752 (defvar image-transform-resize nil
 753   "The image resize operation.
 754 Its value should be one of the following:
 755  - nil, meaning no resizing.
 756  - `fit-height', meaning to fit the image to the window height.
 757  - `fit-width', meaning to fit the image to the window width.
 758  - A number, which is a scale factor (the default size is 1).")
 759
 760 (defvar image-transform-scale 1.0
 761   "The scale factor of the image being displayed.")
 762
 763 (defvar image-transform-rotation 0.0
 764   "Rotation angle for the image in the current Image mode buffer.")
 765
 766 (defvar image-transform-right-angle-fudge 0.0001
 767   "Snap distance to a multiple of a right angle.
 768 There's no deep theory behind the default value, it should just
 769 be somewhat larger than ImageMagick's MagickEpsilon.")
 770
 771 (defsubst image-transform-width (width height)
 772   "Return the bounding box width of a rotated WIDTH x HEIGHT rectangle.
 773 The rotation angle is the value of `image-transform-rotation' in degrees."
 774   (let ((angle (degrees-to-radians image-transform-rotation)))
 775     ;; Assume, w.l.o.g., that the vertices of the rectangle have the
 776     ;; coordinates (+-w/2, +-h/2) and that (0, 0) is the center of the
 777     ;; rotation by the angle A.  The projections onto the first axis
 778     ;; of the vertices of the rotated rectangle are +- (w/2) cos A +-
 779     ;; (h/2) sin A, and the difference between the largest and the
 780     ;; smallest of the four values is the expression below.
 781     (+ (* width (abs (cos angle))) (* height (abs (sin angle))))))
 782
 783 ;; The following comment and code snippet are from
 784 ;; ImageMagick-6.7.4-4/magick/distort.c
 785
 786 ;;    /* Set the output image geometry to calculated 'best fit'.
 787 ;;       Yes this tends to 'over do' the file image size, ON PURPOSE!
 788 ;;       Do not do this for DePolar which needs to be exact for virtual tiling.
 789 ;;    */
 790 ;;    if ( fix_bounds ) {
 791 ;;      geometry.x = (ssize_t) floor(min.x-0.5);
 792 ;;      geometry.y = (ssize_t) floor(min.y-0.5);
 793 ;;      geometry.width=(size_t) ceil(max.x-geometry.x+0.5);
 794 ;;      geometry.height=(size_t) ceil(max.y-geometry.y+0.5);
 795 ;;    }
 796
 797 ;; Other parts of the same file show that here the origin is in the
 798 ;; left lower corner of the image rectangle, the center of the
 799 ;; rotation is the center of the rectangle and min.x and max.x
 800 ;; (resp. min.y and max.y) are the smallest and the largest of the
 801 ;; projections of the vertices onto the first (resp. second) axis.
 802
 803 (defun image-transform-fit-width (width height length)
 804   "Return (w . h) so that a rotated w x h image has exactly width LENGTH.
 805 The rotation angle is the value of `image-transform-rotation'.
 806 Write W for WIDTH and H for HEIGHT.  Then the w x h rectangle is
 807 an \"approximately uniformly\" scaled W x H rectangle, which
 808 currently means that w is one of floor(s W) + {0, 1, -1} and h is
 809 floor(s H), where s can be recovered as the value of `image-transform-scale'.
 810 The value of `image-transform-rotation' may be replaced by
 811 a slightly different angle.  Currently this is done for values
 812 close to a multiple of 90, see `image-transform-right-angle-fudge'."
 813   (cond ((< (abs (- (mod (+ image-transform-rotation 90) 180) 90))
 814             image-transform-right-angle-fudge)
 815          (cl-assert (not (zerop width)) t)
 816          (setq image-transform-rotation
 817                (float (round image-transform-rotation))
 818                image-transform-scale (/ (float length) width))
 819          (cons length nil))
 820         ((< (abs (- (mod (+ image-transform-rotation 45) 90) 45))
 821             image-transform-right-angle-fudge)
 822          (cl-assert (not (zerop height)) t)
 823          (setq image-transform-rotation
 824                (float (round image-transform-rotation))
 825                image-transform-scale (/ (float length) height))
 826          (cons nil length))
 827         (t
 828          (cl-assert (not (and (zerop width) (zerop height))) t)
 829          (setq image-transform-scale
 830                (/ (float (1- length)) (image-transform-width width height)))
 831          ;; Assume we have a w x h image and an angle A, and let l =
 832          ;; l(w, h) = w |cos A| + h |sin A|, which is the actual width
 833          ;; of the bounding box of the rotated image, as calculated by
 834          ;; `image-transform-width'.  The code snippet quoted above
 835          ;; means that ImageMagick puts the rotated image in
 836          ;; a bounding box of width L = 2 ceil((w+l+1)/2) - w.
 837          ;; Elementary considerations show that this is equivalent to
 838          ;; L - w being even and L-3 < l(w, h) <= L-1.  In our case, L is
 839          ;; the given `length' parameter and our job is to determine
 840          ;; reasonable values for w and h which satisfy these
 841          ;; conditions.
 842          (let ((w (floor (* image-transform-scale width)))
 843                (h (floor (* image-transform-scale height))))
 844            ;; Let w and h as bound above.  Then l(w, h) <= l(s W, s H)
 845            ;; = L-1 < l(w+1, h+1) = l(w, h) + l(1, 1) <= l(w, h) + 2,
 846            ;; hence l(w, h) > (L-1) - 2 = L-3.
 847            (cons
 848             (cond ((= (mod w 2) (mod length 2))
 849                    w)
 850                   ;; l(w+1, h) >= l(w, h) > L-3, but does l(w+1, h) <=
 851                   ;; L-1 hold?
 852                   ((<= (image-transform-width (1+ w) h) (1- length))
 853                    (1+ w))
 854                   ;; No, it doesn't, but this implies that l(w-1, h) =
 855                   ;; l(w+1, h) - l(2, 0) >= l(w+1, h) - 2 > (L-1) -
 856                   ;; 2 = L-3.  Clearly, l(w-1, h) <= l(w, h) <= L-1.
 857                   (t
 858                    (1- w)))
 859             h)))))
 860
 861 (defun image-transform-check-size ()
 862   "Check that the image exactly fits the width/height of the window.
 863
 864 Do this for an image of type `imagemagick' to make sure that the
 865 elisp code matches the way ImageMagick computes the bounding box
 866 of a rotated image."
 867   (when (and (not (numberp image-transform-resize))
 868              (boundp 'image-type)
 869              (eq image-type 'imagemagick))
 870     (let ((size (image-display-size (image-get-display-property) t)))
 871       (cond ((eq image-transform-resize 'fit-width)
 872              (cl-assert (= (car size)
 873                         (- (nth 2 (window-inside-pixel-edges))
 874                            (nth 0 (window-inside-pixel-edges))))
 875                      t))
 876             ((eq image-transform-resize 'fit-height)
 877              (cl-assert (= (cdr size)
 878                         (- (nth 3 (window-inside-pixel-edges))
 879                            (nth 1 (window-inside-pixel-edges))))
 880                      t))))))
 881
 882 (defun image-transform-properties (spec)
 883   "Return rescaling/rotation properties for image SPEC.
 884 These properties are determined by the Image mode variables
 885 `image-transform-resize' and `image-transform-rotation'.  The
 886 return value is suitable for appending to an image spec.
 887
 888 Rescaling and rotation properties only take effect if Emacs is
 889 compiled with ImageMagick support."
 890   (setq image-transform-scale 1.0)
 891   (when (or image-transform-resize
 892             (/= image-transform-rotation 0.0))
 893     ;; Note: `image-size' looks up and thus caches the untransformed
 894     ;; image.  There's no easy way to prevent that.
 895     (let* ((size (image-size spec t))
 896            (resized
 897             (cond
 898              ((numberp image-transform-resize)
 899               (unless (= image-transform-resize 1)
 900                 (setq image-transform-scale image-transform-resize)
 901                 (cons nil (floor (* image-transform-resize (cdr size))))))
 902              ((eq image-transform-resize 'fit-width)
 903               (image-transform-fit-width
 904                (car size) (cdr size)
 905                (- (nth 2 (window-inside-pixel-edges))
 906                   (nth 0 (window-inside-pixel-edges)))))
 907              ((eq image-transform-resize 'fit-height)
 908               (let ((res (image-transform-fit-width
 909                           (cdr size) (car size)
 910                           (- (nth 3 (window-inside-pixel-edges))
 911                              (nth 1 (window-inside-pixel-edges))))))
 912                 (cons (cdr res) (car res)))))))
 913       `(,@(when (car resized)
 914             (list :width (car resized)))
 915         ,@(when (cdr resized)
 916             (list :height (cdr resized)))
 917         ,@(unless (= 0.0 image-transform-rotation)
 918             (list :rotation image-transform-rotation))))))
 919
 920 (defun image-transform-set-scale (scale)
 921   "Prompt for a number, and resize the current image by that amount.
 922 This command has no effect unless Emacs is compiled with
 923 ImageMagick support."
 924   (interactive "nScale: ")
 925   (setq image-transform-resize scale)
 926   (image-toggle-display-image))
 927
 928 (defun image-transform-fit-to-height ()
 929   "Fit the current image to the height of the current window.
 930 This command has no effect unless Emacs is compiled with
 931 ImageMagick support."
 932   (interactive)
 933   (setq image-transform-resize 'fit-height)
 934   (image-toggle-display-image))
 935
 936 (defun image-transform-fit-to-width ()
 937   "Fit the current image to the width of the current window.
 938 This command has no effect unless Emacs is compiled with
 939 ImageMagick support."
 940   (interactive)
 941   (setq image-transform-resize 'fit-width)
 942   (image-toggle-display-image))
 943
 944 (defun image-transform-set-rotation (rotation)
 945   "Prompt for an angle ROTATION, and rotate the image by that amount.
 946 ROTATION should be in degrees.  This command has no effect unless
 947 Emacs is compiled with ImageMagick support."
 948   (interactive "nRotation angle (in degrees): ")
 949   (setq image-transform-rotation (float (mod rotation 360)))
 950   (image-toggle-display-image))
 951
 952 (provide 'image-mode)
 953
 954 ;;; image-mode.el ends here