configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([gcc],[don't use GCC to compile Emacs if GCC is found])
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" = yes; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" = yes; then
  90   if test "${with_kerberos}" != yes; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 if test "$with_hesiod" = yes; then
  99   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 100 fi
 101
 102 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 103
 104 dnl This should be the last --with option, because --with-x is
 105 dnl added later on when we find the path of X, and it's best to
 106 dnl keep them together visually.
 107 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 108  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 109 [         case "${withval}" in
 110             y | ye | yes )      val=gtk ;;
 111             n | no )            val=no  ;;
 112             l | lu | luc | luci | lucid )       val=lucid ;;
 113             a | at | ath | athe | athen | athena )      val=athena ;;
 114             m | mo | mot | moti | motif )       val=motif ;;
 115             g | gt | gtk  )     val=gtk ;;
 116             * )
 117 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 118 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 119 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 120             ;;
 121           esac
 122           with_x_toolkit=$val
 123 ])
 124
 125 OPTION_DEFAULT_OFF([xpm],[use -lXpm for displaying XPM images])
 126 OPTION_DEFAULT_OFF([jpeg],[use -ljpeg for displaying JPEG images])
 127 OPTION_DEFAULT_OFF([tiff],[use -ltiff for displaying TIFF images])
 128 OPTION_DEFAULT_OFF([gif],[use -lgif (or -lungif) for displaying GIF images])
 129 OPTION_DEFAULT_OFF([png],[use -lpng for displaying PNG images])
 130 OPTION_DEFAULT_OFF([gpm],[use -lgpm for mouse support on a GNU/Linux console])
 131 OPTION_DEFAULT_OFF([rsvg],[use -lrsvg-2 for displaying SVG images])
 132 OPTION_DEFAULT_OFF([gtk],[use GTK (same as --with-x-toolkit=gtk)])
 133 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 134 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 135 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 136 OPTION_DEFAULT_ON([carbon],[don't use Carbon GUI on Mac OS X])
 137 OPTION_DEFAULT_ON([dbus],[use D-Bus])
 138
 139 AC_ARG_WITH([pkg-config-prog],dnl
 140 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 141                   [Path to pkg-config for finding GTK and librsvg])])
 142 if test "X${with_pkg_config_prog}" != X; then
 143    if test "${with_pkg_config_prog}" != yes; then
 144       PKG_CONFIG="${with_pkg_config_prog}"
 145    fi
 146 fi
 147
 148 AC_ARG_ENABLE(carbon-app,
 149 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 150                 [specify install directory for Emacs.app on Mac OS X
 151                  [DIR=/Application]])],
 152 [ carbon_appdir_x=${enableval}])
 153
 154 AC_ARG_ENABLE(asserts,
 155 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 156       USE_XASSERTS=$enableval,
 157       USE_XASSERTS=no)
 158
 159 AC_ARG_ENABLE(maintainer-mode,
 160 [AS_HELP_STRING([--enable-maintainer-mode],
 161                 [enable make rules and dependencies not useful (and sometimes
 162                  confusing) to the casual installer])],
 163       USE_MAINTAINER_MODE=$enableval,
 164       USE_MAINTAINER_MODE=no)
 165 if test $USE_MAINTAINER_MODE = yes; then
 166   MAINT=
 167 else
 168   MAINT=#
 169 fi
 170 AC_SUBST(MAINT)
 171
 172 AC_ARG_ENABLE(locallisppath,
 173 [AS_HELP_STRING([--enable-locallisppath=PATH],
 174                 [directories Emacs should search for lisp files specific
 175                  to this site])],
 176 if test "${enableval}" = "no"; then
 177   locallisppath=
 178 elif test "${enableval}" != "yes"; then
 179   locallisppath=${enableval}
 180 fi)
 181
 182 #### Make srcdir absolute, if it isn't already.  It's important to
 183 #### avoid running the path through pwd unnecessarily, since pwd can
 184 #### give you automounter prefixes, which can go away.  We do all this
 185 #### so Emacs can find its files when run uninstalled.
 186 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 187 unset CDPATH
 188 case "${srcdir}" in
 189   /* ) ;;
 190   . )
 191     ## We may be able to use the $PWD environment variable to make this
 192     ## absolute.  But sometimes PWD is inaccurate.
 193     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 194     ## but that tested only for a well-formed and valid PWD,
 195     ## it did not object when PWD was well-formed and valid but just wrong.
 196     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 197     then
 198       srcdir="$PWD"
 199     else
 200       srcdir="`(cd ${srcdir}; pwd)`"
 201     fi
 202   ;;
 203   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 204 esac
 205
 206 #### Check if the source directory already has a configured system in it.
 207 if test `pwd` != `(cd ${srcdir} && pwd)` \
 208    && test -f "${srcdir}/src/config.h" ; then
 209   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 210    as a build directory right now; it has been configured in its own
 211    right.  To configure in another directory as well, you MUST
 212    use GNU make.  If you do not have GNU make, then you must
 213    now do `make distclean' in ${srcdir},
 214    and then run $0 again.]])
 215 fi
 216
 217 #### Given the configuration name, set machfile and opsysfile to the
 218 #### names of the m/*.h and s/*.h files we should use.
 219
 220 ### Canonicalize the configuration name.
 221
 222 AC_CANONICAL_HOST
 223 canonical=$host
 224 configuration=${host_alias-${build_alias-$host}}
 225
 226 dnl This used to use changequote, but, apart from `changequote is evil'
 227 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 228 dnl the great gob of text.  Thus it's not processed for possible expansion.
 229 dnl Just make sure the brackets remain balanced.
 230 dnl
 231 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 232 dnl indicated by comments.
 233 dnl quotation begins
 234 [
 235
 236 ### If you add support for a new configuration, add code to this
 237 ### switch statement to recognize your configuration name and select
 238 ### the appropriate operating system and machine description files.
 239
 240 ### You would hope that you could choose an m/*.h file pretty much
 241 ### based on the machine portion of the configuration name, and an s-
 242 ### file based on the operating system portion.  However, it turns out
 243 ### that each m/*.h file is pretty manufacturer-specific - for
 244 ### example hp9000s300.h is a 68000 machine;
 245 ### mips.h, pmax.h are all MIPS
 246 ### machines.  So we basically have to have a special case for each
 247 ### configuration name.
 248 ###
 249 ### As far as handling version numbers on operating systems is
 250 ### concerned, make sure things will fail in a fixable way.  If
 251 ### /etc/MACHINES doesn't say anything about version numbers, be
 252 ### prepared to handle anything reasonably.  If version numbers
 253 ### matter, be sure /etc/MACHINES says something about it.
 254 ###
 255 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 256 ### "System V Release 4"; he writes, "The old convention encouraged
 257 ### confusion between `system' and `release' levels'."
 258
 259 machine='' opsys='' unported=no
 260 case "${canonical}" in
 261
 262   ## FreeBSD ports
 263   *-*-freebsd* )
 264     opsys=freebsd
 265     case "${canonical}" in
 266       alpha*-*-freebsd*)        machine=alpha ;;
 267       ia64-*-freebsd*)          machine=ia64 ;;
 268       sparc64-*-freebsd*)       machine=sparc ;;
 269       powerpc-*-freebsd*)       machine=macppc ;;
 270       i[3456]86-*-freebsd*)     machine=intel386 ;;
 271       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 272     esac
 273   ;;
 274
 275   ## FreeBSD kernel + glibc based userland
 276   *-*-kfreebsd*gnu* )
 277     opsys=gnu-kfreebsd
 278     case "${canonical}" in
 279       alpha*-*-kfreebsd*)       machine=alpha ;;
 280       ia64-*-kfreebsd*)         machine=ia64 ;;
 281       sparc64-*-kfreebsd*)      machine=sparc ;;
 282       powerpc-*-kfreebsd*)      machine=macppc ;;
 283       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 284       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 285     esac
 286   ;;
 287
 288   ## NetBSD ports
 289   *-*-netbsd* )
 290     opsys=netbsd
 291     if test -f /usr/lib/crti.o; then]
 292 dnl The close and open brackets here are because this section is quoted --
 293 dnl see the `changequote' comment above.
 294       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 295 [   fi
 296
 297     case "${canonical}" in
 298       alpha*-*-netbsd*) machine=alpha ;;
 299       i[3456]86-*-netbsd*) machine=intel386 ;;
 300       m68k-*-netbsd*)
 301                         # This is somewhat bogus.
 302                         machine=hp9000s300 ;;
 303       mips-*-netbsd*)   machine=pmax ;;
 304       mipsel-*-netbsd*) machine=pmax ;;
 305       mipseb-*-netbsd*) machine=pmax ;;
 306       powerpc-*-netbsd*) machine=macppc ;;
 307       sparc*-*-netbsd*) machine=sparc ;;
 308       vax-*-netbsd*)    machine=vax ;;
 309       arm-*-netbsd*)    machine=arm ;;
 310       x86_64-*-netbsd*) machine=amdx86-64 ;;
 311       hppa-*-netbsd*)   machine=hp800 ;;
 312     esac
 313   ;;
 314
 315   ## OpenBSD ports
 316   *-*-openbsd* )
 317     opsys=openbsd
 318     case "${canonical}" in
 319       alpha*-*-openbsd*)        machine=alpha ;;
 320       arm-*-openbsd*)          machine=arm ;;
 321       hppa-*-openbsd*)         machine=hp9000s300 ;;
 322       i386-*-openbsd*)         machine=intel386 ;;
 323       m68k-*-openbsd*)         machine=hp9000s300 ;;
 324       mips64-*-openbsd*)       machine=mips64 ;;
 325       powerpc-*-openbsd*)      machine=macppc ;;
 326       sparc*-*-openbsd*)       machine=sparc ;;
 327       vax-*-openbsd*)          machine=vax ;;
 328       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 329     esac
 330   ;;
 331
 332   ## LynxOS ports
 333   *-*-lynxos* )
 334     opsys=lynxos
 335     case "${canonical}" in
 336       i[3456]86-*-lynxos*) machine=intel386 ;;
 337       powerpc-*-lynxos*) machine=powerpc ;;
 338     esac
 339   ;;
 340
 341   ## BSDI ports
 342   *-*-bsdi* )
 343     opsys=bsdi
 344     case "${canonical}" in
 345       i[345]86-*-bsdi*) machine=intel386 ;;
 346       sparc-*-bsdi*)  machine=sparc ;;
 347       powerpc-*-bsdi*)  machine=macppc ;;
 348     esac
 349     case "${canonical}" in
 350       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 351       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 352       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 353       *-*-bsdi3* )              opsys=bsdos3 ;;
 354       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 355     esac
 356   ;;
 357
 358   ## Alpha (DEC) machines.
 359   alpha*-dec-osf* )
 360     machine=alpha opsys=osf1
 361     # This is needed to find X11R6.1 libraries for certain tests.
 362     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 363     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 364     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 365     # due to non-traditional preprocessing with the current compiler
 366     # defaults.  OSF 4 can also have that compiler version, and there
 367     # seems always to have been a usable /usr/bin/cpp.
 368     NON_GNU_CPP=/usr/bin/cpp
 369     case "${canonical}" in
 370     alpha*-dec-osf[5-9]*)
 371       opsys=osf5-0 ;;
 372     esac
 373   ;;
 374
 375   alpha*-*-linux-gnu* )
 376     machine=alpha opsys=gnu-linux
 377   ;;
 378
 379   arm*-*-linux-gnu* )
 380     machine=arm opsys=gnu-linux
 381   ;;
 382
 383   ## Apple Darwin / Mac OS X
 384   *-apple-darwin* )
 385     case "${canonical}" in
 386       i[3456]86-* )  machine=intel386 ;;
 387       powerpc-* )    machine=powermac ;;
 388       * )            unported=yes ;;
 389     esac
 390     opsys=darwin
 391     # Define CPP as follows to make autoconf work correctly.
 392     CPP="${CC-cc} -E -no-cpp-precomp"
 393     # Use fink packages if available.
 394     if test -d /sw/include && test -d /sw/lib; then
 395       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 396       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 397       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 398     fi
 399   ;;
 400
 401   ## Compaq Nonstop
 402   mips-compaq-nonstopux* )
 403     machine=nonstopux opsys=nonstopux
 404     ;;
 405
 406   ## Cubix QBx/386
 407   i[3456]86-cubix-sysv* )
 408     machine=intel386 opsys=usg5-3
 409   ;;
 410
 411   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 412     machine=pmax opsys=bsd4-2
 413   ;;
 414   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 415     machine=pmax opsys=bsd4-3
 416   ;;
 417   mips-dec-ultrix* )
 418     machine=pmax opsys=ultrix4-3
 419   ;;
 420   mips-dec-osf* )
 421     machine=pmax opsys=osf1
 422   ;;
 423   mips-dec-mach_bsd4.3* )
 424     machine=pmax opsys=mach-bsd4-3
 425   ;;
 426
 427   ## HP 9000 series 200 or 300
 428   m68*-hp-bsd* )
 429     machine=hp9000s300 opsys=bsd4-3
 430   ;;
 431   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 432   m68*-hp-hpux* )
 433     case "`uname -r`" in
 434       ## Someone's system reports A.B8.05 for this.
 435       ## I wonder what other possibilities there are.
 436       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 437       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 438       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 439       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 440       *) machine=hp9000s300 opsys=hpux ;;
 441     esac
 442   ;;
 443
 444   ## HP 9000 series 700 and 800, running HP/UX
 445   hppa*-hp-hpux7* )
 446     machine=hp800 opsys=hpux
 447   ;;
 448   hppa*-hp-hpux8* )
 449     machine=hp800 opsys=hpux8
 450   ;;
 451   hppa*-hp-hpux9shr* )
 452     machine=hp800 opsys=hpux9shr
 453   ;;
 454   hppa*-hp-hpux9* )
 455     machine=hp800 opsys=hpux9
 456   ;;
 457   hppa*-hp-hpux10.2* )
 458     machine=hp800 opsys=hpux10-20
 459   ;;
 460   hppa*-hp-hpux10* )
 461     machine=hp800 opsys=hpux10
 462   ;;
 463   hppa*-hp-hpux1[1-9]* )
 464     machine=hp800 opsys=hpux11
 465     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 466   ;;
 467
 468   hppa*-*-linux-gnu* )
 469     machine=hp800 opsys=gnu-linux
 470   ;;
 471
 472   ## HP 9000 series 700 and 800, running HP/UX
 473   hppa*-hp-hpux* )
 474     ## Cross-compilation?  Nah!
 475     case "`uname -r`" in
 476       ## Someone's system reports A.B8.05 for this.
 477       ## I wonder what other possibilities there are.
 478       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 479       *.08.* ) machine=hp800 opsys=hpux8 ;;
 480       *.09.* ) machine=hp800 opsys=hpux9 ;;
 481       *) machine=hp800 opsys=hpux10 ;;
 482     esac
 483   ;;
 484   hppa*-*-nextstep* )
 485     machine=hp800 opsys=nextstep
 486   ;;
 487
 488   ## IBM machines
 489   i370-ibm-aix*)
 490     machine=ibm370aix opsys=usg5-3
 491   ;;
 492   s390-*-linux-gnu* )
 493     machine=ibms390 opsys=gnu-linux
 494   ;;
 495   s390x-*-linux-gnu* )
 496     machine=ibms390x opsys=gnu-linux
 497   ;;
 498   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 499     machine=ibmrs6000 opsys=aix3-1
 500   ;;
 501   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 502     machine=ibmrs6000 opsys=aix3-2-5
 503   ;;
 504   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 505     machine=ibmrs6000 opsys=aix4-1
 506   ;;
 507   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 508     machine=ibmrs6000 opsys=aix4-2
 509   ;;
 510   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 514     machine=ibmrs6000 opsys=aix4-2
 515   ;;
 516   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 517     machine=ibmrs6000 opsys=aix4
 518   ;;
 519   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 520     machine=ibmrs6000 opsys=aix4-1
 521   ;;
 522   rs6000-ibm-aix* | powerpc-ibm-aix* )
 523     machine=ibmrs6000 opsys=aix3-2
 524   ;;
 525
 526   ## Prime EXL
 527   i[3456]86-prime-sysv* )
 528     machine=i386 opsys=usg5-3
 529   ;;
 530
 531   ## ncr machine running svr4.3.
 532   i[3456]86-ncr-sysv4.3 )
 533     machine=ncr386 opsys=usg5-4-3
 534   ;;
 535
 536   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 537   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 538   i[3456]86-ncr-sysv* )
 539     machine=ncr386 opsys=usg5-4-2
 540   ;;
 541
 542   ## Macintosh PowerPC
 543   powerpc*-*-linux-gnu* )
 544     machine=macppc opsys=gnu-linux
 545   ;;
 546
 547   ## Workstations sold by MIPS
 548   ## This is not necessarily all workstations using the MIPS processor -
 549   ## Irises are produced by SGI, and DECstations by DEC.
 550
 551   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 552   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 553   ## it gives for choosing between the alternatives seems to be "Use
 554   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 555   ## the BSD world."  I'll assume that these are instructions for
 556   ## handling two odd situations, and that every other situation
 557   ## should use mips.h and usg5-2-2, they being listed first.
 558   mips-mips-usg* )
 559     machine=mips4
 560     ## Fall through to the general code at the bottom to decide on the OS.
 561   ;;
 562   mips-mips-riscos4* )
 563     machine=mips4 opsys=bsd4-3
 564     NON_GNU_CC="cc -systype bsd43"
 565     NON_GNU_CPP="cc -systype bsd43 -E"
 566   ;;
 567   mips-mips-riscos5* )
 568     machine=mips4 opsys=riscos5
 569     NON_GNU_CC="cc -systype bsd43"
 570     NON_GNU_CPP="cc -systype bsd43 -E"
 571   ;;
 572   mips-mips-bsd* )
 573     machine=mips opsys=bsd4-3
 574   ;;
 575   mips-mips-* )
 576     machine=mips opsys=usg5-2-2
 577   ;;
 578
 579   ## NeXT
 580   m68*-next-* | m68k-*-nextstep* )
 581     machine=m68k opsys=nextstep
 582   ;;
 583
 584   ## NEC EWS4800
 585   mips-nec-sysv4*)
 586   machine=ews4800 opsys=ux4800
 587   ;;
 588
 589   ## Siemens Nixdorf
 590   mips-siemens-sysv* | mips-sni-sysv*)
 591     machine=mips-siemens opsys=usg5-4
 592     NON_GNU_CC=/usr/ccs/bin/cc
 593     NON_GNU_CPP=/usr/ccs/lib/cpp
 594   ;;
 595
 596   ## Silicon Graphics machines
 597   ## Iris 4D
 598   mips-sgi-irix6.5 )
 599     machine=iris4d opsys=irix6-5
 600     # Without defining _LANGUAGE_C, things get masked out in the headers
 601     # so that, for instance, grepping for `free' in stdlib.h fails and
 602     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 603     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 604     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 605   ;;
 606   mips-sgi-irix6* )
 607     machine=iris4d opsys=irix6-0
 608     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 609     # but presumably it does no harm.
 610     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 611     # -32 probably isn't necessary in later v.6s -- anyone know which?
 612     NON_GCC_TEST_OPTIONS=-32
 613   ;;
 614   mips-sgi-irix5.[01]* )
 615     machine=iris4d opsys=irix5-0
 616   ;;
 617   mips-sgi-irix5* | mips-sgi-irix* )
 618     machine=iris4d opsys=irix5-2
 619   ;;
 620
 621   ## Suns
 622   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 623     machine=sparc opsys=gnu-linux
 624   ;;
 625
 626   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 627     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 628     | rs6000-*-solaris2*)
 629     case "${canonical}" in
 630       i[3456]86-*-* )     machine=intel386 ;;
 631       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 632       powerpcle* )      machine=powerpcle ;;
 633       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 634       sparc* )          machine=sparc ;;
 635       * )               unported=yes ;;
 636     esac
 637     case "${canonical}" in
 638       *-sunos5.3* | *-solaris2.3* )
 639                 opsys=sol2-3
 640                 NON_GNU_CPP=/usr/ccs/lib/cpp
 641                 ;;
 642       *-sunos5.4* | *-solaris2.4* )
 643                 opsys=sol2-4
 644                 NON_GNU_CPP=/usr/ccs/lib/cpp
 645                 RANLIB="ar -ts"
 646                 ;;
 647       *-sunos5.5* | *-solaris2.5* )
 648                 opsys=sol2-5
 649                 NON_GNU_CPP=/usr/ccs/lib/cpp
 650                 RANLIB="ar -ts"
 651                 ;;
 652       *-sunos5.6* | *-solaris2.6* )
 653                 opsys=sol2-6
 654                 NON_GNU_CPP=/usr/ccs/lib/cpp
 655                 RANLIB="ar -ts"
 656                 ;;
 657       *-sunos5* | *-solaris* )
 658                 opsys=sol2-6
 659                 emacs_check_sunpro_c=yes
 660                 NON_GNU_CPP=/usr/ccs/lib/cpp
 661                 ;;
 662       *                   ) opsys=bsd4-2   ;;
 663     esac
 664     ## Watch out for a compiler that we know will not work.
 665     case "${canonical}" in
 666      *-solaris* | *-sunos5* )
 667                 if [ "x$CC" = x/usr/ucb/cc ]; then
 668                   ## /usr/ucb/cc doesn't work;
 669                   ## we should find some other compiler that does work.
 670                   unset CC
 671                 fi
 672                 ;;
 673       *) ;;
 674     esac
 675   ;;
 676   sparc-*-nextstep* )
 677     machine=sparc opsys=nextstep
 678   ;;
 679
 680   ## Tandem Integrity S2
 681   mips-tandem-sysv* )
 682     machine=tandem-s2 opsys=usg5-3
 683   ;;
 684
 685   ## Vaxen.
 686   vax-dec-* )
 687     machine=vax
 688     case "${canonical}" in
 689       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 690       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 691       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 692       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 693       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 694       *-vms* )                                          opsys=vms ;;
 695       * )                                               unported=yes
 696     esac
 697   ;;
 698
 699   ## IA-64
 700   ia64*-*-linux* )
 701     machine=ia64 opsys=gnu-linux
 702   ;;
 703
 704   ## Intel 386 machines where we don't care about the manufacturer
 705   i[3456]86-*-* )
 706     machine=intel386
 707     case "${canonical}" in
 708       *-cygwin )                opsys=cygwin ;;
 709       *-darwin* )               opsys=darwin
 710                                 CPP="${CC-cc} -E -no-cpp-precomp"
 711                                 ;;
 712       *-xenix* )                opsys=xenix ;;
 713       *-linux-gnu* )            opsys=gnu-linux ;;
 714       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 715       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 716       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 717       *-386bsd* )               opsys=386bsd ;;
 718       *-nextstep* )             opsys=nextstep ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   ## m68k Linux-based GNU system
 724   m68k-*-linux-gnu* )
 725     machine=m68k opsys=gnu-linux
 726   ;;
 727
 728   ## Mips Linux-based GNU system
 729   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 730     machine=mips opsys=gnu-linux
 731   ;;
 732
 733   ## UXP/DS
 734   sparc-fujitsu-sysv4* )
 735     machine=sparc opsys=uxpds
 736     NON_GNU_CPP=/usr/ccs/lib/cpp
 737     RANLIB="ar -ts"
 738   ;;
 739
 740   ## AMD x86-64 Linux-based GNU system
 741   x86_64-*-linux-gnu* )
 742     machine=amdx86-64 opsys=gnu-linux
 743   ;;
 744
 745   ## Tensilica Xtensa Linux-based GNU system
 746   xtensa-*-linux-gnu* )
 747     machine=xtensa opsys=gnu-linux
 748     ;;
 749
 750   * )
 751     unported=yes
 752   ;;
 753 esac
 754
 755 ### If the code above didn't choose an operating system, just choose
 756 ### an operating system based on the configuration name.  You really
 757 ### only want to use this when you have no idea what the right
 758 ### operating system is; if you know what operating systems a machine
 759 ### runs, it's cleaner to make it explicit in the case statement
 760 ### above.
 761 if test x"${opsys}" = x; then
 762   case "${canonical}" in
 763     *-gnu* )                            opsys=gnu ;;
 764     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 765     *-bsd4.2 )                          opsys=bsd4-2 ;;
 766     *-bsd4.3 )                          opsys=bsd4-3 ;;
 767     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 768     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 769     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 770     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 771     *-sysv4.2uw* )                      opsys=unixware ;;
 772     *-sysv5uw* )                        opsys=unixware ;;
 773     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 774     *-sysv4.1* | *-sysvr4.1* )
 775         NON_GNU_CPP=/usr/lib/cpp
 776         opsys=usg5-4 ;;
 777     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 778         if [ x$NON_GNU_CPP = x ]; then
 779           if [ -f /usr/ccs/lib/cpp ]; then
 780             NON_GNU_CPP=/usr/ccs/lib/cpp
 781           else
 782             NON_GNU_CPP=/lib/cpp
 783           fi
 784         fi
 785         opsys=usg5-4-2 ;;
 786     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 787     * )
 788       unported=yes
 789     ;;
 790   esac
 791 fi
 792
 793 ]
 794 dnl quotation ends
 795
 796 if test $unported = yes; then
 797   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 798 Check `etc/MACHINES' for recognized configuration names.])
 799 fi
 800
 801 machfile="m/${machine}.h"
 802 opsysfile="s/${opsys}.h"
 803
 804
 805 #### Choose a compiler.
 806 test -n "$CC" && cc_specified=yes
 807
 808 # Save the value of CFLAGS that the user specified.
 809 SPECIFIED_CFLAGS="$CFLAGS"
 810
 811 case ${with_gcc} in
 812   "yes" ) CC="gcc" GCC=yes ;;
 813   "no"  ) : ${CC=cc} ;;
 814   * )
 815 esac
 816 AC_PROG_CC
 817
 818 # On Suns, sometimes $CPP names a directory.
 819 if test -n "$CPP" && test -d "$CPP"; then
 820   CPP=
 821 fi
 822
 823 ## If not using gcc, and on Solaris, and no CPP specified, see if
 824 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 825 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 826  test x"$CPP" = x; then
 827   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 828   AC_CACHE_VAL(emacs_cv_sunpro_c,
 829   [AC_TRY_LINK([],
 830 [#ifndef __SUNPRO_C
 831 fail;
 832 #endif
 833 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 834   AC_MSG_RESULT($emacs_cv_sunpro_c)
 835
 836   if test x"$emacs_cv_sunpro_c" = xyes; then
 837     NON_GNU_CPP="$CC -E -Xs"
 838   fi
 839 fi
 840
 841 #### Some systems specify a CPP to use unless we are using GCC.
 842 #### Now that we know whether we are using GCC, we can decide whether
 843 #### to use that one.
 844 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 845 then
 846   CPP="$NON_GNU_CPP"
 847 fi
 848
 849 #### Some systems specify a CC to use unless we are using GCC.
 850 #### Now that we know whether we are using GCC, we can decide whether
 851 #### to use that one.
 852 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 853   test x$cc_specified != xyes
 854 then
 855   CC="$NON_GNU_CC"
 856 fi
 857
 858 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 859 then
 860   CC="$CC $GCC_TEST_OPTIONS"
 861 fi
 862
 863 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 864 then
 865   CC="$CC $NON_GCC_TEST_OPTIONS"
 866 fi
 867
 868 dnl checks for Unix variants
 869 AC_AIX
 870 AC_GNU_SOURCE
 871
 872 ### Use -Wno-pointer-sign if the compiler supports it
 873 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 874 SAVE_CFLAGS="$CFLAGS"
 875 CFLAGS="$CFLAGS -Wno-pointer-sign"
 876 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 877 if test $has_option = yes; then
 878    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 879 fi
 880 AC_MSG_RESULT($has_option)
 881 CFLAGS="$SAVE_CFLAGS"
 882 unset has_option
 883 unset SAVE_CFLAGS
 884
 885 #### Some other nice autoconf tests.
 886
 887 dnl checks for programs
 888 AC_PROG_LN_S
 889 AC_PROG_CPP
 890 AC_PROG_INSTALL
 891 if test "x$RANLIB" = x; then
 892   AC_PROG_RANLIB
 893 fi
 894 AC_PATH_PROG(INSTALL_INFO, install-info)
 895 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 896 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 897 dnl Don't use GZIP, which is used by gzip for additional parameters.
 898 AC_PATH_PROG(GZIP_PROG, gzip)
 899
 900
 901 ## Need makeinfo >= 4.6 (?) to build the manuals.
 902 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 903 dnl By this stage, configure has already checked for egrep and set EGREP,
 904 dnl or exited with an error if no egrep was found.
 905 if test "$MAKEINFO" != "no" && \
 906   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 907    MAKEINFO=no
 908 fi
 909
 910 if test "$MAKEINFO" = "no"; then
 911   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 912 fi
 913
 914
 915 dnl Add our options to ac_link now, after it is set up.
 916
 917 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 918 then
 919   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 920 fi
 921
 922 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 923 then
 924   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 925 fi
 926
 927 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 928 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 929 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 930 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 931 dnl if not built to support GNU ld.
 932
 933 late_LDFLAGS=$LDFLAGS
 934 if test "$GCC" = yes; then
 935   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 936 else
 937   LDFLAGS="$LDFLAGS -znocombreloc"
 938 fi
 939
 940 AC_MSG_CHECKING([for -znocombreloc])
 941 AC_LINK_IFELSE([main(){return 0;}],
 942   [AC_MSG_RESULT(yes)],
 943   LDFLAGS=$late_LDFLAGS
 944   [AC_MSG_RESULT(no)])
 945
 946 #### Extract some information from the operating system and machine files.
 947
 948 AC_CHECKING([the machine- and system-dependent files to find out
 949  - which libraries the lib-src programs will want, and
 950  - whether the GNU malloc routines are usable])
 951
 952 ### First figure out CFLAGS (which we use for running the compiler here)
 953 ### and REAL_CFLAGS (which we use for real compilation).
 954 ### The two are the same except on a few systems, where they are made
 955 ### different to work around various lossages.  For example,
 956 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 957 ### as implying static linking.
 958
 959 ### If the CFLAGS env var is specified, we use that value
 960 ### instead of the default.
 961
 962 ### It's not important that this name contain the PID; you can't run
 963 ### two configures in the same directory and have anything work
 964 ### anyway.
 965 tempcname="conftest.c"
 966
 967 echo '
 968 #include "'${srcdir}'/src/'${opsysfile}'"
 969 #include "'${srcdir}'/src/'${machfile}'"
 970 #ifndef LIBS_MACHINE
 971 #define LIBS_MACHINE
 972 #endif
 973 #ifndef LIBS_SYSTEM
 974 #define LIBS_SYSTEM
 975 #endif
 976 #ifndef C_SWITCH_SYSTEM
 977 #define C_SWITCH_SYSTEM
 978 #endif
 979 #ifndef C_SWITCH_MACHINE
 980 #define C_SWITCH_MACHINE
 981 #endif
 982 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 983 configure___ c_switch_system=C_SWITCH_SYSTEM
 984 configure___ c_switch_machine=C_SWITCH_MACHINE
 985
 986 #ifndef LIB_X11_LIB
 987 #define LIB_X11_LIB -lX11
 988 #endif
 989
 990 #ifndef LIBX11_MACHINE
 991 #define LIBX11_MACHINE
 992 #endif
 993
 994 #ifndef LIBX11_SYSTEM
 995 #define LIBX11_SYSTEM
 996 #endif
 997 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
 998
 999 #ifdef UNEXEC
1000 configure___ unexec=UNEXEC
1001 #else
1002 configure___ unexec=unexec.o
1003 #endif
1004
1005 #ifdef SYSTEM_MALLOC
1006 configure___ system_malloc=yes
1007 #else
1008 configure___ system_malloc=no
1009 #endif
1010
1011 #ifdef USE_MMAP_FOR_BUFFERS
1012 configure___ use_mmap_for_buffers=yes
1013 #else
1014 configure___ use_mmap_for_buffers=no
1015 #endif
1016
1017 #ifndef C_DEBUG_SWITCH
1018 #define C_DEBUG_SWITCH -g
1019 #endif
1020
1021 #ifndef C_OPTIMIZE_SWITCH
1022 #ifdef __GNUC__
1023 #define C_OPTIMIZE_SWITCH -O2
1024 #else
1025 #define C_OPTIMIZE_SWITCH -O
1026 #endif
1027 #endif
1028
1029 #ifndef C_WARNINGS_SWITCH
1030 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1031 #endif
1032
1033 #ifndef LD_SWITCH_MACHINE
1034 #define LD_SWITCH_MACHINE
1035 #endif
1036
1037 #ifndef LD_SWITCH_SYSTEM
1038 #define LD_SWITCH_SYSTEM
1039 #endif
1040
1041 #ifndef LD_SWITCH_X_SITE_AUX
1042 #define LD_SWITCH_X_SITE_AUX
1043 #endif
1044
1045 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1046 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1047
1048 #ifdef THIS_IS_CONFIGURE
1049
1050 /* Get the CFLAGS for tests in configure.  */
1051 #ifdef __GNUC__
1052 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1053 #else
1054 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1055 #endif
1056
1057 #else /* not THIS_IS_CONFIGURE */
1058
1059 /* Get the CFLAGS for real compilation.  */
1060 #ifdef __GNUC__
1061 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1062 #else
1063 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1064 #endif
1065
1066 #endif /* not THIS_IS_CONFIGURE */
1067 ' > ${tempcname}
1068
1069 # The value of CPP is a quoted variable reference, so we need to do this
1070 # to get its actual value...
1071 CPP=`eval "echo $CPP"`
1072 [eval `${CPP} -Isrc ${tempcname} \
1073        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1074 if test "x$SPECIFIED_CFLAGS" = x; then
1075   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1076          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1077 else
1078   REAL_CFLAGS="$CFLAGS"
1079 fi]
1080 rm ${tempcname}
1081
1082 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1083
1084 ### Make sure subsequent tests use flags consistent with the build flags.
1085
1086 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1087   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1088 else
1089   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1090 fi
1091
1092 dnl For AC_FUNC_GETLOADAVG, at least:
1093 AC_CONFIG_LIBOBJ_DIR(src)
1094
1095 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1096 AC_SYS_LARGEFILE
1097
1098
1099 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1100 ### be located in either /usr/lib64 or /usr/lib.
1101 case "${canonical}" in
1102   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1103     if test -d /usr/lib64; then
1104       AC_DEFINE(HAVE_LIB64_DIR, 1,
1105         [Define to 1 if the directory /usr/lib64 exists.])
1106 fi
1107 esac
1108
1109 dnl This function defintion taken from Gnome 2.0
1110 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1111 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1112 dnl also defines GSTUFF_PKG_ERRORS on error
1113 AC_DEFUN([PKG_CHECK_MODULES], [
1114   succeeded=no
1115
1116   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1117
1118   if test "$PKG_CONFIG" = "no" ; then
1119      ifelse([$4], , [AC_MSG_ERROR([
1120       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1121   else
1122      PKG_CONFIG_MIN_VERSION=0.9.0
1123      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1124         AC_MSG_CHECKING(for $2)
1125
1126         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1127             AC_MSG_RESULT(yes)
1128             succeeded=yes
1129
1130             AC_MSG_CHECKING($1_CFLAGS)
1131             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1132             AC_MSG_RESULT($$1_CFLAGS)
1133
1134             AC_MSG_CHECKING($1_LIBS)
1135             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1136             AC_MSG_RESULT($$1_LIBS)
1137         else
1138             AC_MSG_RESULT(no)
1139             $1_CFLAGS=""
1140             $1_LIBS=""
1141             ## If we have a custom action on failure, don't print errors, but
1142             ## do set a variable so people can do so.
1143             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1144             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1145         fi
1146
1147         AC_SUBST($1_CFLAGS)
1148         AC_SUBST($1_LIBS)
1149      else
1150         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1151         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1152      fi
1153   fi
1154
1155   if test $succeeded = yes; then
1156      ifelse([$3], , :, [$3])
1157   else
1158      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1159   fi
1160 ])
1161
1162
1163 if test "${with_sound}" != "no"; then
1164   # Sound support for GNU/Linux and the free BSDs.
1165   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1166   # Emulation library used on NetBSD.
1167   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1168   AC_SUBST(LIBSOUND)
1169
1170   ALSA_REQUIRED=1.0.0
1171   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1172   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1173   if test $HAVE_ALSA = yes; then
1174     SAVE_CFLAGS="$CFLAGS"
1175     SAVE_LDFLAGS="$LDFLAGS"
1176     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1177     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1178     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1179                     emacs_alsa_normal=yes,
1180                     emacs_alsa_normal=no)
1181     if test "$emacs_alsa_normal" != yes; then
1182       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1183                      [snd_lib_error_set_handler (0);],
1184                      emacs_alsa_subdir=yes,
1185                      emacs_alsa_subdir=no)
1186       if test "$emacs_alsa_subdir" != yes; then
1187         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1188       fi
1189       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1190     fi
1191
1192     CFLAGS="$SAVE_CFLAGS"
1193     LDFLAGS="$SAVE_LDFLAGS"
1194     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1195     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1196     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1197   fi
1198   AC_SUBST(CFLAGS_SOUND)
1199 fi
1200
1201 dnl checks for header files
1202 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1203   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1204   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1205   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1206   sys/utsname.h pwd.h)
1207
1208 AC_MSG_CHECKING(if personality LINUX32 can be set)
1209 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1210                emacs_cv_personality_linux32=yes,
1211                emacs_cv_personality_linux32=no)
1212 AC_MSG_RESULT($emacs_cv_personality_linux32)
1213
1214 if test $emacs_cv_personality_linux32 = yes; then
1215   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1216             [Define to 1 if personality LINUX32 can be set.])
1217 fi
1218
1219 dnl On Solaris 8 there's a compilation warning for term.h because
1220 dnl it doesn't define `bool'.
1221 AC_CHECK_HEADERS(term.h, , , -)
1222 AC_HEADER_STDC
1223 AC_HEADER_TIME
1224 AC_CHECK_DECLS([sys_siglist])
1225 if test $ac_cv_have_decl_sys_siglist != yes; then
1226   # For Tru64, at least:
1227   AC_CHECK_DECLS([__sys_siglist])
1228   if test $ac_cv_have_decl___sys_siglist = yes; then
1229     AC_DEFINE(sys_siglist, __sys_siglist,
1230               [Define to any substitute for sys_siglist.])
1231   fi
1232 fi
1233 AC_HEADER_SYS_WAIT
1234
1235 dnl Some systems have utime.h but don't declare the struct anyplace.
1236 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1237 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1238 #include <sys/time.h>
1239 #include <time.h>
1240 #else
1241 #ifdef HAVE_SYS_TIME_H
1242 #include <sys/time.h>
1243 #else
1244 #include <time.h>
1245 #endif
1246 #endif
1247 #ifdef HAVE_UTIME_H
1248 #include <utime.h>
1249 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1250   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1251 if test $emacs_cv_struct_utimbuf = yes; then
1252   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1253 fi
1254
1255 dnl checks for typedefs
1256 AC_TYPE_SIGNAL
1257
1258 dnl Check for speed_t typedef.
1259 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1260   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1261     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1262 if test $emacs_cv_speed_t = yes; then
1263   AC_DEFINE(HAVE_SPEED_T, 1,
1264            [Define to 1 if `speed_t' is declared by <termios.h>.])
1265 fi
1266
1267 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1268 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1269 #include <sys/time.h>
1270 #include <time.h>
1271 #else
1272 #ifdef HAVE_SYS_TIME_H
1273 #include <sys/time.h>
1274 #else
1275 #include <time.h>
1276 #endif
1277 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1278   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1279 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1280 if test $emacs_cv_struct_timeval = yes; then
1281   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1282 fi
1283
1284 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1285 AC_TRY_COMPILE([#include <math.h>],
1286 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1287   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1288 HAVE_EXCEPTION=$emacs_cv_struct_exception
1289 if test $emacs_cv_struct_exception != yes; then
1290   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1291 fi
1292
1293 AC_CHECK_HEADERS(sys/socket.h)
1294 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1295 #if HAVE_SYS_SOCKET_H
1296 #include <sys/socket.h>
1297 #endif])
1298
1299 dnl checks for structure members
1300 AC_STRUCT_TM
1301 AC_STRUCT_TIMEZONE
1302 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1303                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1304                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1305                 [#include <time.h>])
1306 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1307                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1308                   struct ifreq.ifr_addr], , ,
1309                  [AC_INCLUDES_DEFAULT
1310 #if HAVE_SYS_SOCKET_H
1311 #include <sys/socket.h>
1312 #endif
1313 #if HAVE_NET_IF_H
1314 #include <net/if.h>
1315 #endif])
1316
1317 dnl checks for compiler characteristics
1318
1319 dnl Testing __STDC__ to determine prototype support isn't good enough.
1320 dnl DEC C, for instance, doesn't define it with default options, and
1321 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1322 dnl and void *.
1323 AC_C_PROTOTYPES
1324 AC_C_VOLATILE
1325 AC_C_CONST
1326 dnl This isn't useful because we can't turn on use of `inline' unless
1327 dnl the compiler groks `extern inline'.
1328 dnl AC_C_INLINE
1329 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1330   [AC_TRY_COMPILE(, [void * foo;],
1331                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1332 if test $emacs_cv_void_star = yes; then
1333   AC_DEFINE(POINTER_TYPE, void)
1334 else
1335   AC_DEFINE(POINTER_TYPE, char)
1336 fi
1337 AH_TEMPLATE(POINTER_TYPE,
1338             [Define as `void' if your compiler accepts `void *'; otherwise
1339              define as `char'.])dnl
1340
1341
1342
1343 dnl This could be used for targets which can have both byte sexes.
1344 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1345 dnl AC_C_BIGENDIAN
1346
1347 dnl check for Make feature
1348 AC_PROG_MAKE_SET
1349
1350 dnl checks for operating system services
1351 AC_SYS_LONG_FILE_NAMES
1352
1353 #### Choose a window system.
1354
1355 AC_PATH_X
1356 if test "$no_x" = yes; then
1357   window_system=none
1358 else
1359   window_system=x11
1360 fi
1361
1362 if test "${x_libraries}" != NONE; then
1363   if test -n "${x_libraries}"; then
1364     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1365     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1366   fi
1367   x_default_search_path=""
1368   x_search_path=${x_libraries}
1369   if test -z "${x_search_path}"; then
1370     x_search_path=/usr/lib
1371   fi
1372   for x_library in `echo ${x_search_path}: | \
1373                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1374     x_search_path="\
1375 ${x_library}/X11/%L/%T/%N%C%S:\
1376 ${x_library}/X11/%l/%T/%N%C%S:\
1377 ${x_library}/X11/%T/%N%C%S:\
1378 ${x_library}/X11/%L/%T/%N%S:\
1379 ${x_library}/X11/%l/%T/%N%S:\
1380 ${x_library}/X11/%T/%N%S"
1381     if test x"${x_default_search_path}" = x; then
1382       x_default_search_path=${x_search_path}
1383     else
1384       x_default_search_path="${x_search_path}:${x_default_search_path}"
1385     fi
1386   done
1387 fi
1388 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1389   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1390 fi
1391
1392 if test x"${x_includes}" = x; then
1393   bitmapdir=/usr/include/X11/bitmaps
1394 else
1395   # accumulate include directories that have X11 bitmap subdirectories
1396   bmd_acc="dummyval"
1397   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1398     if test -d "${bmd}/X11/bitmaps"; then
1399       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1400     fi
1401     if test -d "${bmd}/bitmaps"; then
1402       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1403     fi
1404   done
1405   if test ${bmd_acc} != "dummyval"; then
1406     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1407   fi
1408 fi
1409
1410 HAVE_CARBON=no
1411 if test "${with_carbon}" != no; then
1412   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1413 fi
1414 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1415   if test "${with_carbon+set}" != set \
1416      && test "${carbon_appdir_x+set}" != set; then
1417     for var in with_x with_x_toolkit with_gtk with_xim \
1418                with_xpm with_jpeg with_tiff with_gif with_png; do
1419       if eval test \"\${$var+set}\" = set; then
1420         HAVE_CARBON=no
1421         break
1422       fi
1423     done
1424   fi
1425 fi
1426 if test "${HAVE_CARBON}" = yes; then
1427   window_system=mac
1428 fi
1429
1430 case "${window_system}" in
1431   x11 )
1432     HAVE_X_WINDOWS=yes
1433     HAVE_X11=yes
1434     case "${with_x_toolkit}" in
1435       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1436       motif ) USE_X_TOOLKIT=MOTIF ;;
1437       gtk ) with_gtk=yes
1438 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1439 dnl USE_X_TOOLKIT is set.
1440             USE_X_TOOLKIT=none ;;
1441       no ) USE_X_TOOLKIT=none ;;
1442 dnl If user did not say whether to use a toolkit, make this decision later:
1443 dnl use the toolkit if we have gtk, or X11R5 or newer.
1444       * )
1445           if test x"$with_gtk" = xyes; then
1446              USE_X_TOOLKIT=none
1447           else
1448              USE_X_TOOLKIT=maybe
1449           fi
1450           ;;
1451     esac
1452   ;;
1453   mac | none )
1454     HAVE_X_WINDOWS=no
1455     HAVE_X11=no
1456     USE_X_TOOLKIT=none
1457   ;;
1458 esac
1459
1460 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1461    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1462    if test "$HAVE_XSERVER" = true ||
1463       test -n "$DISPLAY" ||
1464       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1465         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1466 were found.  You should install the relevant development files for X
1467 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1468 sure you have development files for image handling, i.e.
1469 tiff, gif, jpeg, png and xpm.
1470 If you are sure you want Emacs compiled without X window support, pass
1471   --without-x
1472 to configure.])
1473    fi
1474 fi
1475
1476 ### If we're using X11, we should use the X menu package.
1477 HAVE_MENUS=no
1478 case ${HAVE_X11} in
1479   yes ) HAVE_MENUS=yes ;;
1480 esac
1481
1482 ### Compute the unexec source name from the object name.
1483 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1484
1485 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1486 # Assume not, until told otherwise.
1487 GNU_MALLOC=yes
1488 doug_lea_malloc=yes
1489 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1490 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1491 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1492                emacs_cv_var___after_morecore_hook,
1493 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1494   emacs_cv_var___after_morecore_hook=yes,
1495   emacs_cv_var___after_morecore_hook=no)])
1496 if test $emacs_cv_var___after_morecore_hook = no; then
1497   doug_lea_malloc=no
1498 fi
1499 if test "${system_malloc}" = "yes"; then
1500   GNU_MALLOC=no
1501   GNU_MALLOC_reason="
1502     (The GNU allocators don't work with this system configuration.)"
1503 fi
1504 if test "$doug_lea_malloc" = "yes" ; then
1505   if test "$GNU_MALLOC" = yes ; then
1506     GNU_MALLOC_reason="
1507       (Using Doug Lea's new malloc from the GNU C Library.)"
1508   fi
1509   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1510             [Define to 1 if you are using the GNU C Library.])
1511 fi
1512
1513 if test x"${REL_ALLOC}" = x; then
1514   REL_ALLOC=${GNU_MALLOC}
1515 fi
1516
1517 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1518 dnl the system configuration file (s/*.h) to turn the use of mmap
1519 dnl in the relocating allocator on.
1520
1521 AC_FUNC_MMAP
1522 if test $use_mmap_for_buffers = yes; then
1523   REL_ALLOC=no
1524 fi
1525
1526 LIBS="$libsrc_libs $LIBS"
1527
1528 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1529 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1530 AC_CHECK_LIB(dnet, dnet_ntoa)
1531 dnl This causes -lresolv to get used in subsequent tests,
1532 dnl which causes failures on some systems such as HPUX 9.
1533 dnl AC_CHECK_LIB(resolv, gethostbyname)
1534
1535 dnl FIXME replace main with a function we actually want from this library.
1536 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1537
1538 AC_CHECK_LIB(pthreads, cma_open)
1539
1540 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1541 if test -d /usr/X386/include; then
1542   HAVE_XFREE386=yes
1543   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1544 else
1545   HAVE_XFREE386=no
1546 fi
1547 AC_MSG_RESULT($HAVE_XFREE386)
1548
1549 dnl Check for need for bigtoc support on IBM AIX
1550
1551 case ${host_os} in
1552 aix*)
1553   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1554     case $GCC in
1555     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1556     *) gdb_cv_bigtoc=-bbigtoc ;;
1557     esac
1558
1559     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1560     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1561   ])
1562   ;;
1563 esac
1564
1565 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1566 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1567 # REAL_CPPFLAGS later on.
1568
1569 REAL_CPPFLAGS="$CPPFLAGS"
1570
1571 if test "${HAVE_X11}" = "yes"; then
1572   DEFS="$C_SWITCH_X_SITE $DEFS"
1573   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1574   LIBS="$LIBX $LIBS"
1575   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1576   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1577
1578   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1579   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1580   # but it's more convenient here to set LD_RUN_PATH
1581   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1582   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1583     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1584     export LD_RUN_PATH
1585   fi
1586
1587   if test "${opsys}" = "gnu-linux"; then
1588     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1589     AC_TRY_LINK([],
1590      [XOpenDisplay ("foo");],
1591      [xlinux_first_failure=no],
1592      [xlinux_first_failure=yes])
1593     if test "${xlinux_first_failure}" = "yes"; then
1594       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1595       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1596       OLD_CPPFLAGS="$CPPFLAGS"
1597       OLD_LIBS="$LIBS"
1598       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1599       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1600       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1601       LIBS="$LIBS -b i486-linuxaout"
1602       AC_TRY_LINK([],
1603        [XOpenDisplay ("foo");],
1604        [xlinux_second_failure=no],
1605        [xlinux_second_failure=yes])
1606       if test "${xlinux_second_failure}" = "yes"; then
1607         # If we get the same failure with -b, there is no use adding -b.
1608         # So take it out.  This plays safe.
1609         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1610         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1611         CPPFLAGS="$OLD_CPPFLAGS"
1612         LIBS="$OLD_LIBS"
1613         AC_MSG_RESULT(no)
1614       else
1615         AC_MSG_RESULT(yes)
1616       fi
1617     else
1618       AC_MSG_RESULT(no)
1619     fi
1620   fi
1621
1622   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1623   # header files included from there.
1624   AC_MSG_CHECKING(for Xkb)
1625   AC_TRY_LINK([#include <X11/Xlib.h>
1626 #include <X11/XKBlib.h>],
1627         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1628         emacs_xkb=yes, emacs_xkb=no)
1629   AC_MSG_RESULT($emacs_xkb)
1630   if test $emacs_xkb = yes; then
1631     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1632   fi
1633
1634   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1635 XScreenNumberOfScreen XSetWMProtocols)
1636 fi
1637
1638 if test "${window_system}" = "x11"; then
1639   AC_MSG_CHECKING(X11 version 6)
1640   AC_CACHE_VAL(emacs_cv_x11_version_6,
1641   [AC_TRY_LINK([#include <X11/Xlib.h>],
1642 [#if XlibSpecificationRelease < 6
1643 fail;
1644 #endif
1645 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1646   if test $emacs_cv_x11_version_6 = yes; then
1647     AC_MSG_RESULT(6 or newer)
1648     AC_DEFINE(HAVE_X11R6, 1,
1649               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1650   else
1651     AC_MSG_RESULT(before 6)
1652   fi
1653 fi
1654
1655
1656 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1657 HAVE_RSVG=no
1658 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1659   if test "${with_rsvg}" != "no"; then
1660     RSVG_REQUIRED=2.0.0
1661     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1662
1663     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1664     AC_SUBST(RSVG_CFLAGS)
1665     AC_SUBST(RSVG_LIBS)
1666
1667     if test ".${RSVG_CFLAGS}" != "."; then
1668       HAVE_RSVG=yes
1669       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1670       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1671       LIBS="$RSVG_LIBS $LIBS"
1672     fi
1673   fi
1674 fi
1675
1676
1677 HAVE_GTK=no
1678 if test "${with_gtk}" = "yes" && test "$USE_X_TOOLKIT" = "gtk"; then
1679   USE_X_TOOLKIT=none
1680 fi
1681 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk" || \
1682  test "$USE_X_TOOLKIT" = "maybe"; then
1683   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1684     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1685   fi
1686   GLIB_REQUIRED=2.6
1687   GTK_REQUIRED=2.6
1688   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1689
1690   dnl Checks for libraries.
1691   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1692   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1693      AC_MSG_ERROR($GTK_PKG_ERRORS)
1694   fi
1695 fi
1696
1697
1698 if test x"$pkg_check_gtk" = xyes; then
1699
1700   AC_SUBST(GTK_CFLAGS)
1701   AC_SUBST(GTK_LIBS)
1702   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1703   CFLAGS="$CFLAGS $GTK_CFLAGS"
1704   LIBS="$GTK_LIBS $LIBS"
1705   dnl Try to compile a simple GTK program.
1706   GTK_COMPILES=no
1707   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1708   if test "${GTK_COMPILES}" != "yes"; then
1709     if test "$USE_X_TOOLKIT" != "maybe"; then
1710       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1711     fi
1712   else
1713     HAVE_GTK=yes
1714     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1715     USE_X_TOOLKIT=none
1716   fi
1717
1718 fi
1719
1720
1721 if test "${HAVE_GTK}" = "yes"; then
1722
1723   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1724   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1725   if test "$with_toolkit_scroll_bars" != no; then
1726     with_toolkit_scroll_bars=yes
1727   fi
1728
1729   dnl  Check if we can use multiple displays with this GTK version.
1730   dnl  If gdk_display_open exists, assume all others are there also.
1731   HAVE_GTK_MULTIDISPLAY=no
1732   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1733   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1734     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1735               [Define to 1 if GTK can handle more than one display.])
1736   fi
1737
1738   dnl  Check if we have the old file selection dialog.
1739   dnl  If gdk_display_open exists, assume all others are there also.
1740   HAVE_GTK_FILE_SELECTION=no
1741   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1742
1743   dnl  Check if we have the new file chooser dialog
1744   dnl  If gdk_display_open exists, assume all others are there also.
1745   HAVE_GTK_FILE_CHOOSER=no
1746   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1747
1748   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1749      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1750     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1751               [Define to 1 if GTK has both file selection and chooser dialog.])
1752   fi
1753
1754   dnl Check if pthreads are available.  Emacs only needs this when using
1755   dnl gtk_file_chooser under Gnome.
1756   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1757     HAVE_GTK_AND_PTHREAD=no
1758     AC_CHECK_HEADERS(pthread.h)
1759     if test "$ac_cv_header_pthread_h"; then
1760       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1761     fi
1762     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1763       case "${canonical}" in
1764         *-hpux*) ;;
1765         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1766       esac
1767       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1768                [Define to 1 if you have GTK and pthread (-lpthread).])
1769     fi
1770   fi
1771 fi
1772
1773 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1774 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1775 dnl also not configured.
1776 HAVE_DBUS=no
1777 if test "${with_dbus}" = "yes"; then
1778    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1779    if test "$HAVE_DBUS" = yes; then
1780       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1781    fi
1782 fi
1783
1784 ### Link with -lXft if available to work around a bug.
1785 HAVE_XFT=maybe
1786 if test "${HAVE_GTK}" = "yes"; then
1787   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1788   if test "$HAVE_XFT" != no; then
1789     OLD_CFLAGS="$CPPFLAGS"
1790     OLD_CPPFLAGS="$CFLAGS"
1791     OLD_LIBS="$LIBS"
1792     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1793     CFLAGS="$CFLAGS $XFT_CFLAGS"
1794     LIBS="$XFT_LIBS $LIBS"
1795     AC_CHECK_HEADER(X11/Xft/Xft.h,
1796       [AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS)])
1797
1798     if test "${HAVE_XFT}" = "yes"; then
1799       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1800       AC_SUBST(XFT_LIBS)
1801       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1802     else
1803       CFLAGS="$OLD_CPPFLAGS"
1804       CFLAGS="$OLD_CFLAGS"
1805       LIBS="$OLD_LIBS"
1806     fi
1807   fi
1808 fi
1809
1810 dnl Do not put whitespace before the #include statements below.
1811 dnl Older compilers (eg sunos4 cc) choke on it.
1812 HAVE_XAW3D=no
1813 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1814   if test "$with_xaw3d" != no; then
1815     AC_MSG_CHECKING(for xaw3d)
1816     AC_CACHE_VAL(emacs_cv_xaw3d,
1817     [AC_TRY_LINK([
1818 #include <X11/Intrinsic.h>
1819 #include <X11/Xaw3d/Simple.h>],
1820       [],
1821       emacs_cv_xaw3d=yes,
1822       emacs_cv_xaw3d=no)])
1823   else
1824     emacs_cv_xaw3d=no
1825   fi
1826   if test $emacs_cv_xaw3d = yes; then
1827     AC_MSG_RESULT([yes; using Lucid toolkit])
1828     USE_X_TOOLKIT=LUCID
1829     HAVE_XAW3D=yes
1830     AC_DEFINE(HAVE_XAW3D, 1,
1831               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1832   else
1833     AC_MSG_RESULT(no)
1834     AC_MSG_CHECKING(for libXaw)
1835     AC_CACHE_VAL(emacs_cv_xaw,
1836     [AC_TRY_LINK([
1837 #include <X11/Intrinsic.h>
1838 #include <X11/Xaw/Simple.h>],
1839       [],
1840       emacs_cv_xaw=yes,
1841       emacs_cv_xaw=no)])
1842     if test $emacs_cv_xaw = yes; then
1843       AC_MSG_RESULT([yes; using Lucid toolkit])
1844       USE_X_TOOLKIT=LUCID
1845     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1846       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1847     else
1848       AC_MSG_RESULT([no; do not use toolkit by default])
1849       USE_X_TOOLKIT=none
1850     fi
1851   fi
1852 fi
1853
1854 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1855
1856 if test "${USE_X_TOOLKIT}" != "none"; then
1857   AC_MSG_CHECKING(X11 toolkit version)
1858   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1859   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1860 [#if XtSpecificationRelease < 6
1861 fail;
1862 #endif
1863 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1864   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1865   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1866     AC_MSG_RESULT(6 or newer)
1867     AC_DEFINE(HAVE_X11XTR6, 1,
1868               [Define to 1 if you have the X11R6 or newer version of Xt.])
1869   else
1870     AC_MSG_RESULT(before 6)
1871   fi
1872
1873 dnl If using toolkit, check whether libXmu.a exists.
1874 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1875   OLDLIBS="$LIBS"
1876   if test x$HAVE_X11XTR6 = xyes; then
1877     LIBS="-lXt -lSM -lICE $LIBS"
1878   else
1879     LIBS="-lXt $LIBS"
1880   fi
1881   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1882   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1883 fi
1884
1885 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1886 if test "${HAVE_X11}" = "yes"; then
1887   if test "${USE_X_TOOLKIT}" != "none"; then
1888     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1889   fi
1890 fi
1891
1892 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1893   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1894   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1895     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1896 int x = 5;
1897 #else
1898 Motif version prior to 2.1.
1899 #endif],
1900     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1901   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1902   if test $emacs_cv_motif_version_2_1 = yes; then
1903     HAVE_LIBXP=no
1904     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1905               [Define to 1 if you have Motif 2.1 or newer.])
1906     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1907     if test ${HAVE_LIBXP} = yes; then
1908       AC_DEFINE(HAVE_LIBXP, 1,
1909                 [Define to 1 if you have the Xp library (-lXp).])
1910     fi
1911   else
1912     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1913     # We put this in CFLAGS temporarily to precede other -I options
1914     # that might be in CFLAGS temporarily.
1915     # We put this in CPPFLAGS where it precedes the other -I options.
1916     OLD_CPPFLAGS=$CPPFLAGS
1917     OLD_CFLAGS=$CFLAGS
1918     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1919     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1920     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1921       [int x = 5;],
1922       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1923     if test $emacs_cv_lesstif = yes; then
1924       # Make sure this -I option remains in CPPFLAGS after it is set
1925       # back to REAL_CPPFLAGS.
1926       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1927       # have those other -I options anyway.  Ultimately, having this
1928       # directory ultimately in CPPFLAGS will be enough.
1929       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1930       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1931     else
1932       CFLAGS=$OLD_CFLAGS
1933       CPPFLAGS=$OLD_CPPFLAGS
1934     fi
1935   fi
1936 fi
1937
1938 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1939 dnl using Motif or Xaw3d is available, and unless
1940 dnl --with-toolkit-scroll-bars=no was specified.
1941
1942 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1943             [Define to 1 if we should use toolkit scroll bars.])dnl
1944 USE_TOOLKIT_SCROLL_BARS=no
1945 if test "${with_toolkit_scroll_bars}" != "no"; then
1946   if test "${USE_X_TOOLKIT}" != "none"; then
1947     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1948       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1949       HAVE_XAW3D=no
1950       USE_TOOLKIT_SCROLL_BARS=yes
1951     elif test "${HAVE_XAW3D}" = "yes"; then
1952       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1953       USE_TOOLKIT_SCROLL_BARS=yes
1954     fi
1955   elif test "${HAVE_GTK}" = "yes"; then
1956     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1957     USE_TOOLKIT_SCROLL_BARS=yes
1958   elif test "${HAVE_CARBON}" = "yes"; then
1959     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1960     USE_TOOLKIT_SCROLL_BARS=yes
1961   fi
1962 fi
1963
1964 dnl See if XIM is available.
1965 AC_TRY_COMPILE([
1966           #include <X11/Xlib.h>
1967           #include <X11/Xresource.h>],
1968          [XIMProc  callback;],
1969          [HAVE_XIM=yes
1970          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1971          HAVE_XIM=no)
1972
1973 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1974
1975 if test "${with_xim}" != "no"; then
1976   AC_DEFINE(USE_XIM, 1,
1977             [Define to 1 if we should use XIM, if it is available.])
1978 fi
1979
1980
1981 if test "${HAVE_XIM}" != "no"; then
1982   late_CFLAGS=$CFLAGS
1983   if test "$GCC" = yes; then
1984     CFLAGS="$CFLAGS --pedantic-errors"
1985   fi
1986   AC_TRY_COMPILE([
1987 #include <X11/Xlib.h>
1988 #include <X11/Xresource.h>],
1989 [Display *display;
1990 XrmDatabase db;
1991 char *res_name;
1992 char *res_class;
1993 XIMProc  callback;
1994 XPointer *client_data;
1995 #ifndef __GNUC__
1996 /* If we're not using GCC, it's probably not XFree86, and this is
1997    probably right, but we can't use something like --pedantic-errors.  */
1998 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1999                                            char*, XIMProc, XPointer*);
2000 #endif
2001 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2002    client_data);],
2003     [emacs_cv_arg6_star=yes])
2004   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2005          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2006 either XPointer or XPointer*.])dnl
2007   if test "$emacs_cv_arg6_star" = yes; then
2008     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2009   else
2010     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2011   fi
2012   CFLAGS=$late_CFLAGS
2013 fi
2014
2015 ### Use -lXpm if available, unless `--with-xpm=no'.
2016 HAVE_XPM=no
2017 if test "${HAVE_X11}" = "yes"; then
2018   if test "${with_xpm}" != "no"; then
2019     AC_CHECK_HEADER(X11/xpm.h,
2020       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2021     if test "${HAVE_XPM}" = "yes"; then
2022       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2023       AC_EGREP_CPP(no_return_alloc_pixels,
2024       [#include "X11/xpm.h"
2025 #ifndef XpmReturnAllocPixels
2026 no_return_alloc_pixels
2027 #endif
2028       ], HAVE_XPM=no, HAVE_XPM=yes)
2029
2030       if test "${HAVE_XPM}" = "yes"; then
2031         AC_MSG_RESULT(yes)
2032       else
2033         AC_MSG_RESULT(no)
2034       fi
2035     fi
2036   fi
2037
2038   if test "${HAVE_XPM}" = "yes"; then
2039     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2040   fi
2041 fi
2042
2043 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2044 HAVE_JPEG=no
2045 if test "${HAVE_X11}" = "yes"; then
2046   if test "${with_jpeg}" != "no"; then
2047     dnl Checking for jpeglib.h can lose because of a redefinition of
2048     dnl  HAVE_STDLIB_H.
2049     AC_CHECK_HEADER(jerror.h,
2050       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2051   fi
2052
2053   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2054   if test "${HAVE_JPEG}" = "yes"; then
2055     AC_DEFINE(HAVE_JPEG)
2056     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2057         [#include <jpeglib.h>
2058          version=JPEG_LIB_VERSION
2059 ],
2060         [AC_DEFINE(HAVE_JPEG)],
2061         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2062         HAVE_JPEG=no])
2063   fi
2064 fi
2065
2066 ### Use -lpng if available, unless `--with-png=no'.
2067 HAVE_PNG=no
2068 if test "${HAVE_X11}" = "yes"; then
2069   if test "${with_png}" != "no"; then
2070     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2071     # in /usr/include/libpng.
2072     AC_CHECK_HEADERS(png.h libpng/png.h)
2073     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2074       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2075     fi
2076   fi
2077
2078   if test "${HAVE_PNG}" = "yes"; then
2079     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2080   fi
2081 fi
2082
2083 ### Use -ltiff if available, unless `--with-tiff=no'.
2084 HAVE_TIFF=no
2085 if test "${HAVE_X11}" = "yes"; then
2086   if test "${with_tiff}" != "no"; then
2087     AC_CHECK_HEADER(tiffio.h,
2088       [tifflibs="-lz -lm"
2089       # At least one tiff package requires the jpeg library.
2090       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2091       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2092   fi
2093
2094   if test "${HAVE_TIFF}" = "yes"; then
2095     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2096   fi
2097 fi
2098
2099 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2100 HAVE_GIF=no
2101 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2102   AC_CHECK_HEADER(gif_lib.h,
2103 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2104 # Earlier versions can crash Emacs.
2105     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2106
2107   if test "$HAVE_GIF" = yes; then
2108       ac_gif_lib_name="-lgif"
2109   fi
2110
2111 # If gif_lib.h but no libgif, try libungif.
2112   if test x"$try_libungif" = xyes; then
2113     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2114
2115     if test "$HAVE_GIF" = yes; then
2116       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2117       ac_gif_lib_name="-lungif"
2118     fi
2119   fi
2120
2121   if test "${HAVE_GIF}" = "yes"; then
2122     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2123   fi
2124 fi
2125
2126 dnl Check for required libraries.
2127 if test "${HAVE_X11}" = "yes"; then
2128   MISSING=""
2129   WITH_NO=""
2130   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2131     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2132   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2133     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2134   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2135     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2136   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2137     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2138   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2139     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2140
2141   if test "X${MISSING}" != X; then
2142     AC_MSG_ERROR([The following required libraries were not found:
2143     $MISSING
2144 Maybe some development libraries/packages are missing?
2145 If you don't want to link with them give
2146     $WITH_NO
2147 as options to configure])
2148   fi
2149 fi
2150
2151 ### Use -lgpm if available, unless `--with-gpm=no'.
2152 HAVE_GPM=no
2153 if test "${with_gpm}" != "no"; then
2154   AC_CHECK_HEADER(gpm.h,
2155     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2156 fi
2157
2158 if test "${HAVE_GPM}" = "yes"; then
2159   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2160 fi
2161
2162 dnl Check for malloc/malloc.h on darwin
2163 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2164
2165 ### Use Mac OS X Carbon API to implement GUI.
2166 if test "${HAVE_CARBON}" = "yes"; then
2167   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2168   ## Specify the install directory
2169   carbon_appdir=
2170   if test "${carbon_appdir_x}" != ""; then
2171     case ${carbon_appdir_x} in
2172       y | ye | yes)  carbon_appdir=/Applications ;;
2173       * ) carbon_appdir=${carbon_appdir_x} ;;
2174     esac
2175   fi
2176   # We also have mouse menus.
2177   HAVE_MENUS=yes
2178 fi
2179
2180 ### Use session management (-lSM -lICE) if available
2181 HAVE_X_SM=no
2182 if test "${HAVE_X11}" = "yes"; then
2183   AC_CHECK_HEADER(X11/SM/SMlib.h,
2184     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2185
2186   if test "${HAVE_X_SM}" = "yes"; then
2187     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2188     case "$LIBS" in
2189       *-lSM*) ;;
2190       *)      LIBS="-lSM -lICE $LIBS" ;;
2191     esac
2192   fi
2193 fi
2194
2195 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2196 AC_CACHE_CHECK(whether netdb declares h_errno,
2197                emacs_cv_netdb_declares_h_errno,
2198 [AC_TRY_LINK([#include <netdb.h>],
2199   [return h_errno;],
2200   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2201 if test $emacs_cv_netdb_declares_h_errno = yes; then
2202   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2203 fi
2204
2205 AC_FUNC_ALLOCA
2206
2207 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2208 dnl FIXME is there an autoconf test that does the right thing, without
2209 dnl needing to call A_M_E afterwards?
2210 if test x"$ac_cv_func_alloca_works" != xyes; then
2211    AC_MSG_ERROR( [a system implementation of alloca is required] )
2212 fi
2213
2214 # fmod, logb, and frexp are found in -lm on most systems.
2215 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2216 AC_CHECK_LIB(m, sqrt)
2217
2218 # Check for mail-locking functions in a "mail" library.  Probably this should
2219 # have the same check as for liblockfile below.
2220 AC_CHECK_LIB(mail, maillock)
2221 dnl Debian, at least:
2222 AC_CHECK_LIB(lockfile, maillock)
2223 # If we have the shared liblockfile, assume we must use it for mail
2224 # locking (e.g. Debian).  If we couldn't link against liblockfile
2225 # (no liblockfile.a installed), ensure that we don't need to.
2226 if test "$ac_cv_lib_lockfile_maillock" = no; then
2227   dnl This works for files generally, not just executables.
2228   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2229   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2230                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2231   if test $ac_cv_prog_liblockfile = yes; then
2232     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2233 This probably means that movemail could lose mail.
2234 There may be a `development' package to install containing liblockfile.])
2235   else :
2236   fi
2237 fi
2238 AC_CHECK_FUNCS(touchlock)
2239 AC_CHECK_HEADERS(maillock.h)
2240
2241 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2242 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2243 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2244 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2245 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2246 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2247 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2248 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2249 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2250
2251 AC_CHECK_HEADERS(sys/un.h)
2252
2253 AC_FUNC_MKTIME
2254 if test "$ac_cv_func_working_mktime" = no; then
2255   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2256 fi
2257
2258 AC_FUNC_GETLOADAVG
2259
2260 AC_FUNC_FSEEKO
2261
2262 # Configure getopt.
2263 m4_include([m4/getopt.m4])
2264 gl_GETOPT_IFELSE([
2265   gl_GETOPT_SUBSTITUTE_HEADER
2266   gl_PREREQ_GETOPT
2267   GETOPTOBJS='getopt.o getopt1.o'
2268 ])
2269 AC_SUBST(GETOPTOBJS)
2270
2271 AC_FUNC_GETPGRP
2272
2273 AC_FUNC_STRFTIME
2274
2275 # UNIX98 PTYs.
2276 AC_CHECK_FUNCS(grantpt)
2277
2278 # PTY-related GNU extensions.
2279 AC_CHECK_FUNCS(getpt)
2280
2281 # Check this now, so that we will NOT find the above functions in ncurses.
2282 # That is because we have not set up to link ncurses in lib-src.
2283 # It's better to believe a function is not available
2284 # than to expect to find it in ncurses.
2285 AC_CHECK_LIB(ncurses, tparm)
2286
2287 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2288
2289 resolv=no
2290 AC_TRY_LINK([#include <netinet/in.h>
2291 #include <arpa/nameser.h>
2292 #include <resolv.h>],
2293     [return res_init();],
2294     have_res_init=yes, have_res_init=no)
2295 if test "$have_res_init" = no; then
2296   OLIBS="$LIBS"
2297   LIBS="$LIBS -lresolv"
2298   AC_MSG_CHECKING(for res_init with -lresolv)
2299   AC_TRY_LINK([#include <netinet/in.h>
2300 #include <arpa/nameser.h>
2301 #include <resolv.h>],
2302     [return res_init();],
2303     have_res_init=yes, have_res_init=no)
2304   AC_MSG_RESULT($have_res_init)
2305   if test "$have_res_init" = yes ; then
2306     resolv=yes
2307   fi
2308   LIBS="$OLIBS"
2309 fi
2310
2311 if test "$have_res_init" = yes; then
2312   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2313 fi
2314
2315 # Do we need the Hesiod library to provide the support routines?
2316 if test "$with_hesiod" = yes ; then
2317   # Don't set $LIBS here -- see comments above.
2318   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2319      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2320                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2321   if test "$resolv" = yes ; then
2322     RESOLVLIB=-lresolv
2323   else
2324     RESOLVLIB=
2325   fi
2326   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2327         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2328                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2329         :, $RESOLVLIB)])
2330 fi
2331
2332 # Do we need libresolv (due to res_init or Hesiod)?
2333 if test "$resolv" = yes ; then
2334   AC_DEFINE(HAVE_LIBRESOLV, 1,
2335             [Define to 1 if you have the resolv library (-lresolv).])
2336 fi
2337
2338 # These tell us which Kerberos-related libraries to use.
2339 if test "${with_kerberos+set}" = set; then
2340   AC_CHECK_LIB(com_err, com_err)
2341   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2342   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2343   AC_CHECK_LIB(krb5, krb5_init_context)
2344   if test "${with_kerberos5+set}" != set; then
2345     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2346                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2347     AC_CHECK_LIB(krb4, krb_get_cred,,
2348                  [AC_CHECK_LIB(krb, krb_get_cred)])
2349   fi
2350
2351   if test "${with_kerberos5+set}" = set; then
2352     AC_CHECK_HEADERS(krb5.h)
2353   else
2354     AC_CHECK_HEADERS(des.h,,
2355                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2356                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2357     AC_CHECK_HEADERS(krb.h,,
2358                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2359                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2360   fi
2361   AC_CHECK_HEADERS(com_err.h)
2362 fi
2363
2364 # Solaris requires -lintl if you want strerror (which calls dgettext)
2365 # to return localized messages.
2366 AC_CHECK_LIB(intl, dgettext)
2367
2368 AC_MSG_CHECKING(whether localtime caches TZ)
2369 AC_CACHE_VAL(emacs_cv_localtime_cache,
2370 [if test x$ac_cv_func_tzset = xyes; then
2371 AC_TRY_RUN([#include <time.h>
2372 extern char **environ;
2373 unset_TZ ()
2374 {
2375   char **from, **to;
2376   for (to = from = environ; (*to = *from); from++)
2377     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2378       to++;
2379 }
2380 char TZ_GMT0[] = "TZ=GMT0";
2381 char TZ_PST8[] = "TZ=PST8";
2382 main()
2383 {
2384   time_t now = time ((time_t *) 0);
2385   int hour_GMT0, hour_unset;
2386   if (putenv (TZ_GMT0) != 0)
2387     exit (1);
2388   hour_GMT0 = localtime (&now)->tm_hour;
2389   unset_TZ ();
2390   hour_unset = localtime (&now)->tm_hour;
2391   if (putenv (TZ_PST8) != 0)
2392     exit (1);
2393   if (localtime (&now)->tm_hour == hour_GMT0)
2394     exit (1);
2395   unset_TZ ();
2396   if (localtime (&now)->tm_hour != hour_unset)
2397     exit (1);
2398   exit (0);
2399 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2400 [# If we have tzset, assume the worst when cross-compiling.
2401 emacs_cv_localtime_cache=yes])
2402 else
2403         # If we lack tzset, report that localtime does not cache TZ,
2404         # since we can't invalidate the cache if we don't have tzset.
2405         emacs_cv_localtime_cache=no
2406 fi])dnl
2407 AC_MSG_RESULT($emacs_cv_localtime_cache)
2408 if test $emacs_cv_localtime_cache = yes; then
2409   AC_DEFINE(LOCALTIME_CACHE, 1,
2410             [Define to 1 if localtime caches TZ.])
2411 fi
2412
2413 if test "x$HAVE_TIMEVAL" = xyes; then
2414   AC_CHECK_FUNCS(gettimeofday)
2415   if test $ac_cv_func_gettimeofday = yes; then
2416     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2417                    emacs_cv_gettimeofday_two_arguments,
2418     [AC_TRY_COMPILE([
2419 #ifdef TIME_WITH_SYS_TIME
2420 #include <sys/time.h>
2421 #include <time.h>
2422 #else
2423 #ifdef HAVE_SYS_TIME_H
2424 #include <sys/time.h>
2425 #else
2426 #include <time.h>
2427 #endif
2428 #endif],
2429       [struct timeval time;
2430        gettimeofday (&time, 0);],
2431       emacs_cv_gettimeofday_two_arguments=yes,
2432       emacs_cv_gettimeofday_two_arguments=no)])
2433     if test $emacs_cv_gettimeofday_two_arguments = no; then
2434       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2435                 [Define to 1 if gettimeofday accepts only one argument.])
2436     fi
2437   fi
2438 fi
2439
2440 ok_so_far=yes
2441 AC_CHECK_FUNC(socket, , ok_so_far=no)
2442 if test $ok_so_far = yes; then
2443   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2444 fi
2445 if test $ok_so_far = yes; then
2446   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2447 fi
2448 if test $ok_so_far = yes; then
2449 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2450   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2451             [Define to 1 if you have inet sockets.])
2452 fi
2453
2454 AC_CHECK_HEADERS(sys/ioctl.h)
2455
2456 if test -f /usr/lpp/X11/bin/smt.exp; then
2457   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2458             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2459 fi
2460
2461 AC_MSG_CHECKING(whether system supports dynamic ptys)
2462 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2463   AC_MSG_RESULT(yes)
2464   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2465 else
2466   AC_MSG_RESULT(no)
2467 fi
2468
2469 AC_FUNC_FORK
2470
2471 dnl Adapted from Haible's version.
2472 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2473   [AC_TRY_LINK([#include <langinfo.h>],
2474     [char* cs = nl_langinfo(CODESET);],
2475     emacs_cv_langinfo_codeset=yes,
2476     emacs_cv_langinfo_codeset=no)
2477   ])
2478 if test $emacs_cv_langinfo_codeset = yes; then
2479   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2480     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2481 fi
2482
2483 AC_CHECK_TYPES(size_t)
2484
2485 AC_TYPE_MBSTATE_T
2486
2487 dnl Restrict could probably be used effectively other than in regex.c.
2488 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2489   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2490                   emacs_cv_c_restrict=yes,
2491                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2492                                   emacs_cv_c_restrict=__restrict,
2493                                   emacs_cv_c_restrict=no)])])
2494 case "$emacs_cv_c_restrict" in
2495   yes) emacs_restrict=restrict;;
2496   no) emacs_restrict="";;
2497   *) emacs_restrict="$emacs_cv_c_restrict";;
2498 esac
2499 if test "$emacs_restrict" != __restrict; then
2500   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2501     [Define to compiler's equivalent of C99 restrict keyword.
2502      Don't define if equivalent is `__restrict'.])
2503 fi
2504
2505 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2506   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2507                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2508 if test "$emacs_cv_c_restrict_arr" = yes; then
2509   AC_DEFINE(__restrict_arr, __restrict,
2510     [Define to compiler's equivalent of C99 restrict keyword in array
2511      declarations.  Define as empty for no equivalent.])
2512 fi
2513
2514 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2515 dnl how the tty code is related to POSIX and/or other versions of termios.
2516 dnl The following looks like a useful start.
2517 dnl
2518 dnl AC_SYS_POSIX_TERMIOS
2519 dnl if test $ac_cv_sys_posix_termios = yes; then
2520 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2521 dnl                                and macros for terminal control.])
2522 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2523 dnl fi
2524
2525 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2526
2527 # Set up the CFLAGS for real compilation, so we can substitute it.
2528 CFLAGS="$REAL_CFLAGS"
2529 CPPFLAGS="$REAL_CPPFLAGS"
2530
2531 #### Find out which version of Emacs this is.
2532 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2533          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2534 if test x"${version}" = x; then
2535   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2536 fi
2537
2538 ### Specify what sort of things we'll be editing into Makefile and config.h.
2539 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2540 AC_SUBST(version)
2541 AC_SUBST(configuration)
2542 AC_SUBST(canonical)
2543 AC_SUBST(srcdir)
2544 AC_SUBST(prefix)
2545 AC_SUBST(exec_prefix)
2546 AC_SUBST(bindir)
2547 AC_SUBST(datadir)
2548 AC_SUBST(sharedstatedir)
2549 AC_SUBST(libexecdir)
2550 AC_SUBST(mandir)
2551 AC_SUBST(infodir)
2552 AC_SUBST(lispdir)
2553 AC_SUBST(locallisppath)
2554 AC_SUBST(lisppath)
2555 AC_SUBST(x_default_search_path)
2556 AC_SUBST(etcdir)
2557 AC_SUBST(archlibdir)
2558 AC_SUBST(docdir)
2559 AC_SUBST(bitmapdir)
2560 AC_SUBST(gamedir)
2561 AC_SUBST(gameuser)
2562 AC_SUBST(c_switch_system)
2563 AC_SUBST(c_switch_machine)
2564 AC_SUBST(LD_SWITCH_X_SITE)
2565 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2566 AC_SUBST(C_SWITCH_X_SITE)
2567 AC_SUBST(CFLAGS)
2568 AC_SUBST(X_TOOLKIT_TYPE)
2569 AC_SUBST(machfile)
2570 AC_SUBST(opsysfile)
2571 AC_SUBST(GETLOADAVG_LIBS)
2572 AC_SUBST(carbon_appdir)
2573
2574 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2575                    [Define to the canonical Emacs configuration name.])
2576 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2577                    [Define to the options passed to configure.])
2578 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2579                    [Define to the used machine dependent file.])
2580 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2581                    [Define to the used os dependent file.])
2582 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2583 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2584  may need to deal with X Windows.  For instance, if you've defined
2585  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2586  your loader can find on its own, you might want to add "-L/..." or
2587  something similar.])
2588 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2589                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2590                     in case it's needed (for Solaris, for example).])
2591 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2592 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2593  may need to deal with X Windows.  For instance, if you've defined
2594  HAVE_X_WINDOWS above and your X include files aren't in a place
2595  that your compiler can find on its own, you might want to add
2596  "-I/..." or something similar.])
2597 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2598                    [Define to the unexec source file name.])
2599
2600 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2601   AC_DEFINE(HAVE_X_WINDOWS, 1,
2602             [Define to 1 if you want to use the X window system.])
2603 fi
2604 if test "${USE_X_TOOLKIT}" != "none" ; then
2605   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2606 fi
2607 if test "${HAVE_X11}" = "yes" ; then
2608   AC_DEFINE(HAVE_X11, 1,
2609             [Define to 1 if you want to use version 11 of X windows.
2610              Otherwise, Emacs expects to use version 10.])
2611 fi
2612 if test "${HAVE_XFREE386}" = "yes" ; then
2613   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2614 fi
2615 if test "${HAVE_MENUS}" = "yes" ; then
2616   AC_DEFINE(HAVE_MENUS, 1,
2617             [Define to 1 if you have mouse menus.
2618              (This is automatic if you use X, but the option to specify it remains.)
2619              It is also defined with other window systems that support xmenu.c.])
2620 fi
2621 if test "${GNU_MALLOC}" = "yes" ; then
2622   AC_DEFINE(GNU_MALLOC, 1,
2623             [Define to 1 if you want to use the GNU memory allocator.])
2624 fi
2625 if test "${REL_ALLOC}" = "yes" ; then
2626   AC_DEFINE(REL_ALLOC, 1,
2627             [Define REL_ALLOC if you want to use the relocating allocator for
2628              buffer space.])
2629 fi
2630
2631
2632 AH_TOP([/* GNU Emacs site configuration template file.
2633    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2634      2006, 2007, 2008  Free Software Foundation, Inc.
2635
2636 This file is part of GNU Emacs.
2637
2638 GNU Emacs is free software; you can redistribute it and/or modify
2639 it under the terms of the GNU General Public License as published by
2640 the Free Software Foundation; either version 3, or (at your option)
2641 any later version.
2642
2643 GNU Emacs is distributed in the hope that it will be useful,
2644 but WITHOUT ANY WARRANTY; without even the implied warranty of
2645 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2646 GNU General Public License for more details.
2647
2648 You should have received a copy of the GNU General Public License
2649 along with GNU Emacs; see the file COPYING.  If not, write to the
2650 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2651 Boston, MA 02110-1301, USA.  */
2652
2653
2654 /* No code in Emacs #includes config.h twice, but some bits of code
2655    intended to work with other packages as well (like gmalloc.c)
2656    think they can include it as many times as they like.  */
2657 #ifndef EMACS_CONFIG_H
2658 #define EMACS_CONFIG_H
2659 ])dnl
2660
2661 AH_BOTTOM([
2662 /* If we're using any sort of window system, define some consequences.  */
2663 #ifdef HAVE_X_WINDOWS
2664 #define HAVE_WINDOW_SYSTEM
2665 #define MULTI_KBOARD
2666 #define HAVE_MOUSE
2667 #endif
2668
2669 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2670    on unconditionally.  Note that src/s/darwin.h disables this at
2671    present.  */
2672 #ifndef MULTI_KBOARD
2673 #define MULTI_KBOARD
2674 #endif
2675
2676 /* If we're using the Carbon API on Mac OS X, define a few more
2677    variables as well.  */
2678 #ifdef HAVE_CARBON
2679 #define HAVE_WINDOW_SYSTEM
2680 #define HAVE_MOUSE
2681 #endif
2682
2683 /* Define USER_FULL_NAME to return a string
2684    that is the user's full name.
2685    It can assume that the variable `pw'
2686    points to the password file entry for this user.
2687
2688    At some sites, the pw_gecos field contains
2689    the user's full name.  If neither this nor any other
2690    field contains the right thing, use pw_name,
2691    giving the user's login name, since that is better than nothing.  */
2692 #define USER_FULL_NAME pw->pw_gecos
2693
2694 /* Define AMPERSAND_FULL_NAME if you use the convention
2695    that & in the full name stands for the login id.  */
2696 /* Turned on June 1996 supposing nobody will mind it.  */
2697 #define AMPERSAND_FULL_NAME
2698
2699 /* We have blockinput.h.  */
2700 #define DO_BLOCK_INPUT
2701
2702 /* Define HAVE_SOUND if we have sound support.  We know it works
2703    and compiles only on the specified platforms.   For others,
2704    it probably doesn't make sense to try.  */
2705
2706 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2707 #ifdef HAVE_MACHINE_SOUNDCARD_H
2708 #define HAVE_SOUND 1
2709 #endif
2710 #ifdef HAVE_SYS_SOUNDCARD_H
2711 #define HAVE_SOUND 1
2712 #endif
2713 #ifdef HAVE_SOUNDCARD_H
2714 #define HAVE_SOUND 1
2715 #endif
2716 #ifdef HAVE_ALSA
2717 #define HAVE_SOUND 1
2718 #endif
2719 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2720
2721 /* If using GNU, then support inline function declarations. */
2722 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2723    generally, because even if non-gcc compilers accept `inline', they
2724    may reject `extern inline'.  */
2725 #if defined (__GNUC__) && defined (OPTIMIZE)
2726 #define INLINE __inline__
2727 #else
2728 #define INLINE
2729 #endif
2730
2731 /* Include the os and machine dependent files.  */
2732 #include config_opsysfile
2733 #include config_machfile
2734
2735 /* Load in the conversion definitions if this system
2736    needs them and the source file being compiled has not
2737    said to inhibit this.  There should be no need for you
2738    to alter these lines.  */
2739
2740 #ifdef SHORTNAMES
2741 #ifndef NO_SHORTNAMES
2742 #include "../shortnames/remap.h"
2743 #endif /* not NO_SHORTNAMES */
2744 #endif /* SHORTNAMES */
2745
2746 /* If no remapping takes place, static variables cannot be dumped as
2747    pure, so don't worry about the `static' keyword. */
2748 #ifdef NO_REMAP
2749 #undef static
2750 #endif
2751
2752 /* Define `subprocesses' should be defined if you want to
2753    have code for asynchronous subprocesses
2754    (as used in M-x compile and M-x shell).
2755    These do not work for some USG systems yet;
2756    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2757
2758 #ifndef VMS
2759 #ifndef USG
2760 /* #define subprocesses */
2761 #endif
2762 #endif
2763
2764 /* SIGTYPE is the macro we actually use.  */
2765 #ifndef SIGTYPE
2766 #define SIGTYPE RETSIGTYPE
2767 #endif
2768
2769 #ifdef emacs /* Don't do this for lib-src.  */
2770 /* Tell regex.c to use a type compatible with Emacs.  */
2771 #define RE_TRANSLATE_TYPE Lisp_Object
2772 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2773 #ifdef make_number
2774 /* If make_number is a macro, use it.  */
2775 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2776 #else
2777 /* If make_number is a function, avoid it.  */
2778 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2779 #endif
2780 #endif
2781
2782 /* Avoid link-time collision with system mktime if we will use our own.  */
2783 #if ! HAVE_MKTIME || BROKEN_MKTIME
2784 #define mktime emacs_mktime
2785 #endif
2786
2787 #define my_strftime nstrftime   /* for strftime.c */
2788
2789 /* The rest of the code currently tests the CPP symbol BSTRING.
2790    Override any claims made by the system-description files.
2791    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2792 #undef BSTRING
2793 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2794 #define BSTRING
2795 #endif
2796
2797 /* Some of the files of Emacs which are intended for use with other
2798    programs assume that if you have a config.h file, you must declare
2799    the type of getenv.
2800
2801    This declaration shouldn't appear when alloca.s or Makefile.in
2802    includes config.h.  */
2803 #ifndef NOT_C_CODE
2804 extern char *getenv ();
2805 #endif
2806
2807 /* These default definitions are good for almost all machines.
2808    The exceptions override them in m/MACHINE.h.  */
2809
2810 #ifndef BITS_PER_CHAR
2811 #define BITS_PER_CHAR 8
2812 #endif
2813
2814 #ifndef BITS_PER_SHORT
2815 #define BITS_PER_SHORT 16
2816 #endif
2817
2818 /* Note that lisp.h uses this in a preprocessor conditional, so it
2819    would not work to use sizeof.  That being so, we do all of them
2820    without sizeof, for uniformity's sake.  */
2821 #ifndef BITS_PER_INT
2822 #define BITS_PER_INT 32
2823 #endif
2824
2825 #ifndef BITS_PER_LONG
2826 #ifdef _LP64
2827 #define BITS_PER_LONG 64
2828 #else
2829 #define BITS_PER_LONG 32
2830 #endif
2831 #endif
2832
2833 /* Define if the compiler supports function prototypes.  It may do so
2834    but not define __STDC__ (e.g. DEC C by default) or may define it as
2835    zero.  */
2836 #undef PROTOTYPES
2837 /* For mktime.c:  */
2838 #ifndef __P
2839 # if defined PROTOTYPES
2840 #  define __P(args) args
2841 # else
2842 #  define __P(args) ()
2843 # endif  /* GCC.  */
2844 #endif /* __P */
2845
2846 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2847 #ifndef NOT_C_CODE
2848 #ifdef HAVE_STRING_H
2849 #include "string.h"
2850 #endif
2851 #ifdef HAVE_STRINGS_H
2852 #include "strings.h"  /* May be needed for bcopy & al. */
2853 #endif
2854 #ifdef HAVE_STDLIB_H
2855 #include <stdlib.h>
2856 #endif
2857 #ifndef __GNUC__
2858 # ifdef HAVE_ALLOCA_H
2859 #  include <alloca.h>
2860 # else /* AIX files deal with #pragma.  */
2861 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2862 char *alloca ();
2863 #  endif
2864 # endif /* HAVE_ALLOCA_H */
2865 #endif /* __GNUC__ */
2866 #ifndef HAVE_SIZE_T
2867 typedef unsigned size_t;
2868 #endif
2869 #endif /* NOT_C_CODE */
2870
2871 /* Define HAVE_X_I18N if we have usable i18n support.  */
2872
2873 #ifdef HAVE_X11R6
2874 #define HAVE_X_I18N
2875 #elif !defined X11R5_INHIBIT_I18N
2876 #define HAVE_X_I18N
2877 #endif
2878
2879 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2880
2881 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2882 #define HAVE_X11R6_XIM
2883 #endif
2884
2885 /* Should we enable expensive run-time checking of data types?  */
2886 #undef ENABLE_CHECKING
2887
2888 #if defined __GNUC__ && (__GNUC__ > 2 \
2889                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2890 #define NO_RETURN       __attribute__ ((__noreturn__))
2891 #else
2892 #define NO_RETURN       /* nothing */
2893 #endif
2894
2895 /* These won't be used automatically yet.  We also need to know, at least,
2896    that the stack is continuous.  */
2897 #ifdef __GNUC__
2898 #  ifndef GC_SETJMP_WORKS
2899   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2900      see NON_SAVING_SETJMP in the target descriptions.  */
2901   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2902      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2903      Fixme: Deal with SVR3.  */
2904 #    define GC_SETJMP_WORKS 1
2905 #  endif
2906 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2907 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2908 #  endif
2909 #endif
2910
2911 #ifndef HAVE_BCOPY
2912 #define bcopy(a,b,s) memcpy (b,a,s)
2913 #endif
2914 #ifndef HAVE_BZERO
2915 #define bzero(a,s) memset (a,0,s)
2916 #endif
2917 #ifndef HAVE_BCMP
2918 #define BCMP memcmp
2919 #endif
2920
2921 #endif /* EMACS_CONFIG_H */
2922
2923 /*
2924 Local Variables:
2925 mode: c
2926 End:
2927 */
2928 ])dnl
2929
2930 #### Report on what we decided to do.
2931 #### Report GTK as a toolkit, even if it doesn't use Xt.
2932 #### It makes printing result more understandable as using GTK sets
2933 #### toolkit_scroll_bars to yes by default.
2934 if test "${HAVE_GTK}" = "yes"; then
2935   USE_X_TOOLKIT=GTK
2936 fi
2937
2938 echo "
2939 Configured for \`${canonical}'.
2940
2941   Where should the build process find the source code?    ${srcdir}
2942   What operating system and machine description files should Emacs use?
2943         \`${opsysfile}' and \`${machfile}'
2944   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2945   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2946   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2947   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2948   What window system should Emacs use?                    ${window_system}
2949   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2950
2951 if test -n "${x_includes}"; then
2952 echo "  Where do we find X Windows header files?                ${x_includes}"
2953 else
2954 echo "  Where do we find X Windows header files?                Standard dirs"
2955 fi
2956 if test -n "${x_libraries}"; then
2957 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2958 else
2959 echo "  Where do we find X Windows libraries?                   Standard dirs"
2960 fi
2961
2962 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2963 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2964 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2965 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2966 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2967 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2968 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2969 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2970 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2971 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2972 echo
2973
2974 if test $USE_XASSERTS = yes; then
2975    echo "  Compiling with asserts turned on."
2976    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2977    echo
2978 fi
2979
2980 if test "$USE_X_TOOLKIT" = GTK; then
2981   case "$canonical" in
2982   *cygwin*)
2983     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2984   will probably get a crash on startup.  If this happens, please use another
2985   toolkit for Emacs.  See etc/PROBLEMS for more information."
2986   ;;
2987   esac
2988 fi
2989
2990
2991 if test "$HAVE_CARBON" = "yes"; then
2992    echo
2993    echo "Warning: The Mac Carbon port is currently unsupported and has
2994 known problems.  It is not recommended for use by non-developers.
2995 Read the emacs-devel archives for more information."
2996    echo
2997 fi
2998
2999 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3000   echo "D-Bus integration has been tested for GNU/Linux only."
3001   echo
3002 fi
3003
3004
3005 # Remove any trailing slashes in these variables.
3006 [test "${prefix}" != NONE &&
3007   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3008 test "${exec_prefix}" != NONE &&
3009   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3010
3011 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3012 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3013 ## from Makefile.c can correctly provide the arg `-traditional' to the
3014 ## C preprocessor.
3015
3016 AC_EGREP_CPP(yes..yes,
3017         [yes..yes],
3018         CPP_NEED_TRADITIONAL=no,
3019         CPP_NEED_TRADITIONAL=yes)
3020
3021 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3022         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3023         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3024         lwlib/Makefile lisp/Makefile leim/Makefile, [
3025
3026 ### Make the necessary directories, if they don't exist.
3027 for dir in etc lisp ; do
3028   test -d ${dir} || mkdir ${dir}
3029 done
3030
3031 # Build src/Makefile from ${srcdir}/src/Makefile.c
3032 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3033 # This must be done after src/config.h is built, since we rely on that file.
3034
3035 # Now get this: Some word that is part of the ${srcdir} directory name
3036 # or the ${configuration} value might, just might, happen to be an
3037 # identifier like `sun4' or `i386' or something, and be predefined by
3038 # the C preprocessor to some helpful value like 1, or maybe the empty
3039 # string.  Needless to say consequent macro substitutions are less
3040 # than conducive to the makefile finding the correct directory.
3041 [undefs="`echo $top_srcdir $configuration $canonical |
3042 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3043     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3044 `"]
3045
3046 echo creating src/epaths.h
3047 ${MAKE-make} epaths-force
3048
3049 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3050 # `..' to `. .'  unless invoked with -traditional
3051
3052 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3053   CPPFLAGS="$CPPFLAGS -traditional"
3054 fi
3055
3056 echo creating lib-src/Makefile
3057 ( cd lib-src
3058   rm -f junk.c junk1.c junk2.c
3059   sed -e '/start of cpp stuff/q' \
3060       < Makefile.c > junk1.c
3061   sed -e '1,/start of cpp stuff/d'\
3062       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3063       < Makefile.c > junk.c
3064   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3065       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3066   cat junk1.c junk2.c > Makefile.new
3067   rm -f junk.c junk1.c junk2.c
3068   chmod 444 Makefile.new
3069   mv -f Makefile.new Makefile
3070 )
3071
3072 echo creating src/Makefile
3073 ( cd src
3074   rm -f junk.c junk1.c junk2.c
3075   sed -e '/start of cpp stuff/q' \
3076       < Makefile.c > junk1.c
3077   sed -e '1,/start of cpp stuff/d'\
3078       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3079       < Makefile.c > junk.c
3080   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3081       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3082   cat junk1.c junk2.c > Makefile.new
3083   rm -f junk.c junk1.c junk2.c
3084   chmod 444 Makefile.new
3085   mv -f Makefile.new Makefile
3086 )
3087
3088 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3089   echo creating src/.gdbinit
3090   echo source $srcdir/src/.gdbinit > src/.gdbinit
3091 fi
3092
3093 # This is how we know whether to re-run configure in certain cases.
3094 touch src/config.stamp
3095
3096 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3097
3098 m4_if(dnl       Do not change this comment
3099    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3100 )dnl