configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 AC_ARG_WITH([gnustep-conf],dnl
 190 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 191 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 192   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 193 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 194      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 195
 196 AC_ARG_ENABLE(ns-self-contained,
 197 [AS_HELP_STRING([--disable-ns-self-contained],
 198                 [disable self contained build under NeXTstep])],
 199    EN_NS_SELF_CONTAINED=$enableval,
 200    EN_NS_SELF_CONTAINED=yes)
 201
 202 AC_ARG_ENABLE(asserts,
 203 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 204       USE_XASSERTS=$enableval,
 205       USE_XASSERTS=no)
 206
 207 AC_ARG_ENABLE(maintainer-mode,
 208 [AS_HELP_STRING([--enable-maintainer-mode],
 209                 [enable make rules and dependencies not useful (and sometimes
 210                  confusing) to the casual installer])],
 211       USE_MAINTAINER_MODE=$enableval,
 212       USE_MAINTAINER_MODE=no)
 213 if test $USE_MAINTAINER_MODE = yes; then
 214   MAINT=
 215 else
 216   MAINT=#
 217 fi
 218 AC_SUBST(MAINT)
 219
 220 AC_ARG_ENABLE(locallisppath,
 221 [AS_HELP_STRING([--enable-locallisppath=PATH],
 222                 [directories Emacs should search for lisp files specific
 223                  to this site])],
 224 if test "${enableval}" = "no"; then
 225   locallisppath=
 226 elif test "${enableval}" != "yes"; then
 227   locallisppath=${enableval}
 228 fi)
 229
 230 AC_ARG_ENABLE(checking,
 231 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 232                 [enable expensive run-time checks.  With LIST,
 233                  enable only specific categories of checks.
 234                  Categories are: all,yes,no.
 235                  Flags are: stringbytes, stringoverrun, stringfreelist,
 236                  xmallocoverrun, conslist])],
 237 [ac_checking_flags="${enableval}"],[])
 238 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 239 for check in $ac_checking_flags
 240 do
 241         case $check in
 242         # these set all the flags to specific states
 243         yes)            ac_enable_checking=1 ;;
 244         no)             ac_enable_checking= ;
 245                         ac_gc_check_stringbytes= ;
 246                         ac_gc_check_string_overrun= ;
 247                         ac_gc_check_string_free_list= ;
 248                         ac_xmalloc_overrun= ;
 249                         ac_gc_check_cons_list= ;;
 250         all)            ac_enable_checking=1 ;
 251                         ac_gc_check_stringbytes=1 ;
 252                         ac_gc_check_string_overrun=1 ;
 253                         ac_gc_check_string_free_list=1 ;
 254                         ac_xmalloc_overrun=1 ;
 255                         ac_gc_check_cons_list=1 ;;
 256         # these enable particular checks
 257         stringbytes)    ac_gc_check_stringbytes=1 ;;
 258         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 259         stringfreelist) ac_gc_check_string_free_list=1 ;;
 260         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 261         conslist)       ac_gc_check_cons_list=1 ;;
 262         *)      AC_MSG_ERROR(unknown check category $check) ;;
 263         esac
 264 done
 265 IFS="$ac_save_IFS"
 266
 267 if test x$ac_enable_checking != x ; then
 268   AC_DEFINE(ENABLE_CHECKING, 1,
 269 [Enable expensive run-time checking of data types?])
 270 fi
 271 if test x$ac_gc_check_stringbytes != x ; then
 272   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 273 [Define this temporarily to hunt a bug.  If defined, the size of
 274    strings is redundantly recorded in sdata structures so that it can
 275    be compared to the sizes recorded in Lisp strings.])
 276 fi
 277 if test x$ac_gc_check_stringoverrun != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 279 [Define this to check for short string overrun.])
 280 fi
 281 if test x$ac_gc_check_string_free_list != x ; then
 282   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 283 [Define this to check the string free list.])
 284 fi
 285 if test x$ac_xmalloc_overrun != x ; then
 286   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 287 [Define this to check for malloc buffer overrun.])
 288 fi
 289 if test x$ac_gc_check_cons_list != x ; then
 290   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 291 [Define this to check for errors in cons list.])
 292 fi
 293
 294 AC_ARG_ENABLE(profiling,
 295 [AS_HELP_STRING([--enable-profiling],
 296                 [build emacs with profiling support.
 297                  This might not work on all platforms])],
 298 [ac_enable_profiling="${enableval}"],[])
 299 if test x$ac_enable_profiling != x ; then
 300    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 301    PROFILING_LDFLAGS="-pg"
 302 else
 303    PROFILING_CFLAGS=
 304    PROFILING_LDFLAGS=
 305 fi
 306
 307 AC_ARG_ENABLE(autodepend,
 308 [AS_HELP_STRING([--enable-autodepend],
 309                 [automatically generate dependencies to .h-files.
 310                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 311                  found])],
 312 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 313
 314 #### Make srcdir absolute, if it isn't already.  It's important to
 315 #### avoid running the path through pwd unnecessarily, since pwd can
 316 #### give you automounter prefixes, which can go away.  We do all this
 317 #### so Emacs can find its files when run uninstalled.
 318 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 319 unset CDPATH
 320 case "${srcdir}" in
 321   /* ) ;;
 322   . )
 323     ## We may be able to use the $PWD environment variable to make this
 324     ## absolute.  But sometimes PWD is inaccurate.
 325     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 326     ## but that tested only for a well-formed and valid PWD,
 327     ## it did not object when PWD was well-formed and valid but just wrong.
 328     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 329     then
 330       srcdir="$PWD"
 331     else
 332       srcdir="`(cd ${srcdir}; pwd)`"
 333     fi
 334   ;;
 335   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 336 esac
 337
 338 #### Check if the source directory already has a configured system in it.
 339 if test `pwd` != `(cd ${srcdir} && pwd)` \
 340    && test -f "${srcdir}/src/config.h" ; then
 341   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 342    as a build directory right now; it has been configured in its own
 343    right.  To configure in another directory as well, you MUST
 344    use GNU make.  If you do not have GNU make, then you must
 345    now do `make distclean' in ${srcdir},
 346    and then run $0 again.]])
 347 fi
 348
 349 #### Given the configuration name, set machfile and opsysfile to the
 350 #### names of the m/*.h and s/*.h files we should use.
 351
 352 ### Canonicalize the configuration name.
 353
 354 AC_CANONICAL_HOST
 355 canonical=$host
 356 configuration=${host_alias-${build_alias-$host}}
 357
 358 dnl This used to use changequote, but, apart from `changequote is evil'
 359 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 360 dnl the great gob of text.  Thus it's not processed for possible expansion.
 361 dnl Just make sure the brackets remain balanced.
 362 dnl
 363 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 364 dnl indicated by comments.
 365 dnl quotation begins
 366 [
 367
 368 ### If you add support for a new configuration, add code to this
 369 ### switch statement to recognize your configuration name and select
 370 ### the appropriate operating system and machine description files.
 371
 372 ### You would hope that you could choose an m/*.h file pretty much
 373 ### based on the machine portion of the configuration name, and an s-
 374 ### file based on the operating system portion.  However, it turns out
 375 ### that each m/*.h file is pretty manufacturer-specific - for
 376 ### example mips.h is MIPS
 377 ### So we basically have to have a special case for each
 378 ### configuration name.
 379 ###
 380 ### As far as handling version numbers on operating systems is
 381 ### concerned, make sure things will fail in a fixable way.  If
 382 ### /etc/MACHINES doesn't say anything about version numbers, be
 383 ### prepared to handle anything reasonably.  If version numbers
 384 ### matter, be sure /etc/MACHINES says something about it.
 385 ###
 386 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 387 ### "System V Release 4"; he writes, "The old convention encouraged
 388 ### confusion between `system' and `release' levels'."
 389
 390 machine='' opsys='' unported=no
 391 case "${canonical}" in
 392
 393   ## FreeBSD ports
 394   *-*-freebsd* )
 395     opsys=freebsd
 396     case "${canonical}" in
 397       alpha*-*-freebsd*)        machine=alpha ;;
 398       arm*-*-freebsd*)          machine=arm ;;
 399       ia64-*-freebsd*)          machine=ia64 ;;
 400       sparc-*-freebsd*)         machine=sparc ;;
 401       sparc64-*-freebsd*)       machine=sparc ;;
 402       powerpc-*-freebsd*)       machine=macppc ;;
 403       i[3456]86-*-freebsd*)     machine=intel386 ;;
 404       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 405     esac
 406   ;;
 407
 408   ## FreeBSD kernel + glibc based userland
 409   *-*-kfreebsd*gnu* )
 410     opsys=gnu-kfreebsd
 411     case "${canonical}" in
 412       alpha*-*-kfreebsd*)       machine=alpha ;;
 413       ia64-*-kfreebsd*)         machine=ia64 ;;
 414       sparc-*-kfreebsd*)        machine=sparc ;;
 415       sparc64-*-kfreebsd*)      machine=sparc ;;
 416       powerpc-*-kfreebsd*)      machine=macppc ;;
 417       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 418       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 419     esac
 420   ;;
 421
 422   ## NetBSD ports
 423   *-*-netbsd* )
 424     opsys=netbsd
 425     if test -f /usr/lib/crti.o; then]
 426 dnl The close and open brackets here are because this section is quoted --
 427 dnl see the `changequote' comment above.
 428       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 429 [   fi
 430
 431     case "${canonical}" in
 432       alpha*-*-netbsd*) machine=alpha ;;
 433       i[3456]86-*-netbsd*) machine=intel386 ;;
 434       mips-*-netbsd*)   machine=mips ;;
 435       mipsel-*-netbsd*) machine=mips ;;
 436       mipseb-*-netbsd*) machine=mips ;;
 437       powerpc-*-netbsd*) machine=macppc ;;
 438       sparc*-*-netbsd*) machine=sparc ;;
 439       vax-*-netbsd*)    machine=vax ;;
 440       arm-*-netbsd*)    machine=arm ;;
 441       x86_64-*-netbsd*) machine=amdx86-64 ;;
 442       hppa-*-netbsd*)   machine=hp800 ;;
 443       m68k-*-netbsd*)   machine=m68k ;;
 444     esac
 445   ;;
 446
 447   ## OpenBSD ports
 448   *-*-openbsd* )
 449     opsys=openbsd
 450     case "${canonical}" in
 451       alpha*-*-openbsd*)        machine=alpha ;;
 452       arm-*-openbsd*)          machine=arm ;;
 453       i386-*-openbsd*)         machine=intel386 ;;
 454       powerpc-*-openbsd*)      machine=macppc ;;
 455       sparc*-*-openbsd*)       machine=sparc ;;
 456       vax-*-openbsd*)          machine=vax ;;
 457       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 458       hppa-*-openbsd*)         machine=hp800 ;;
 459     esac
 460   ;;
 461
 462   alpha*-*-linux-gnu* )
 463     machine=alpha opsys=gnu-linux
 464   ;;
 465
 466   arm*-*-linux-gnu* )
 467     machine=arm opsys=gnu-linux
 468   ;;
 469
 470   ## Apple Darwin / Mac OS X
 471   *-apple-darwin* )
 472     case "${canonical}" in
 473       i[3456]86-* )  machine=intel386 ;;
 474       powerpc-* )    machine=macppc ;;
 475       x86_64-* )     machine=amdx86-64 ;;
 476       * )            unported=yes ;;
 477     esac
 478     opsys=darwin
 479     # Define CPP as follows to make autoconf work correctly.
 480     CPP="${CC-cc} -E -no-cpp-precomp"
 481     # Use fink packages if available.
 482     if test -d /sw/include && test -d /sw/lib; then
 483       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 484       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 485       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 486     fi
 487   ;;
 488
 489   ## HP 9000 series 700 and 800, running HP/UX
 490   hppa*-hp-hpux10.2* )
 491     machine=hp800 opsys=hpux10-20
 492   ;;
 493   hppa*-hp-hpux1[1-9]* )
 494     machine=hp800 opsys=hpux11
 495     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 496   ;;
 497
 498   hppa*-*-linux-gnu* )
 499     machine=hp800 opsys=gnu-linux
 500   ;;
 501
 502   ## IBM machines
 503   s390-*-linux-gnu* )
 504     machine=ibms390 opsys=gnu-linux
 505   ;;
 506   s390x-*-linux-gnu* )
 507     machine=ibms390x opsys=gnu-linux
 508   ;;
 509   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521
 522   ## Macintosh PowerPC
 523   powerpc*-*-linux-gnu* )
 524     machine=macppc opsys=gnu-linux
 525   ;;
 526
 527   ## Silicon Graphics machines
 528   ## Iris 4D
 529   mips-sgi-irix6.5 )
 530     machine=iris4d opsys=irix6-5
 531     # Without defining _LANGUAGE_C, things get masked out in the headers
 532     # so that, for instance, grepping for `free' in stdlib.h fails and
 533     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 534     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 535     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 536   ;;
 537
 538   ## Suns
 539   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 540     machine=sparc opsys=gnu-linux
 541   ;;
 542
 543   *-sun-solaris* \
 544     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 545     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## IA-64
 583   ia64*-*-linux* )
 584     machine=ia64 opsys=gnu-linux
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-linux-gnu* )            opsys=gnu-linux ;;
 596       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 600     esac
 601   ;;
 602
 603   ## m68k Linux-based GNU system
 604   m68k-*-linux-gnu* )
 605     machine=m68k opsys=gnu-linux
 606   ;;
 607
 608   ## Mips Linux-based GNU system
 609   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 610     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 611     machine=mips opsys=gnu-linux
 612   ;;
 613
 614   ## AMD x86-64 Linux-based GNU system
 615   x86_64-*-linux-gnu* )
 616     machine=amdx86-64 opsys=gnu-linux
 617   ;;
 618
 619   ## Tensilica Xtensa Linux-based GNU system
 620   xtensa*-*-linux-gnu* )
 621     machine=xtensa opsys=gnu-linux
 622     ;;
 623
 624   ## SuperH Linux-based GNU system
 625   sh[34]*-*-linux-gnu* )
 626     machine=sh3 opsys=gnu-linux
 627   ;;
 628
 629   * )
 630     unported=yes
 631   ;;
 632 esac
 633
 634 ### If the code above didn't choose an operating system, just choose
 635 ### an operating system based on the configuration name.  You really
 636 ### only want to use this when you have no idea what the right
 637 ### operating system is; if you know what operating systems a machine
 638 ### runs, it's cleaner to make it explicit in the case statement
 639 ### above.
 640 if test x"${opsys}" = x; then
 641   case "${canonical}" in
 642     *-gnu* )                            opsys=gnu ;;
 643     * )
 644       unported=yes
 645     ;;
 646   esac
 647 fi
 648
 649 ]
 650 dnl quotation ends
 651
 652 if test $unported = yes; then
 653   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 654 Check `etc/MACHINES' for recognized configuration names.])
 655 fi
 656
 657 machfile="m/${machine}.h"
 658 opsysfile="s/${opsys}.h"
 659
 660
 661 #### Choose a compiler.
 662 test -n "$CC" && cc_specified=yes
 663
 664 # Save the value of CFLAGS that the user specified.
 665 SPECIFIED_CFLAGS="$CFLAGS"
 666
 667 dnl Sets GCC=yes if using gcc.
 668 AC_PROG_CC
 669
 670 # On Suns, sometimes $CPP names a directory.
 671 if test -n "$CPP" && test -d "$CPP"; then
 672   CPP=
 673 fi
 674
 675 ## If not using gcc, and on Solaris, and no CPP specified, see if
 676 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 677 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 678  test x"$CPP" = x; then
 679   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 680   AC_CACHE_VAL(emacs_cv_sunpro_c,
 681   [AC_TRY_LINK([],
 682 [#ifndef __SUNPRO_C
 683 fail;
 684 #endif
 685 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 686   AC_MSG_RESULT($emacs_cv_sunpro_c)
 687
 688   if test x"$emacs_cv_sunpro_c" = xyes; then
 689     NON_GNU_CPP="$CC -E -Xs"
 690   fi
 691 fi
 692
 693 #### Some systems specify a CPP to use unless we are using GCC.
 694 #### Now that we know whether we are using GCC, we can decide whether
 695 #### to use that one.
 696 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 697 then
 698   CPP="$NON_GNU_CPP"
 699 fi
 700
 701 #### Some systems specify a CC to use unless we are using GCC.
 702 #### Now that we know whether we are using GCC, we can decide whether
 703 #### to use that one.
 704 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 705   test x$cc_specified != xyes
 706 then
 707   CC="$NON_GNU_CC"
 708 fi
 709
 710 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 711 then
 712   CC="$CC $GCC_TEST_OPTIONS"
 713 fi
 714
 715 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 716 then
 717   CC="$CC $NON_GCC_TEST_OPTIONS"
 718 fi
 719
 720 dnl checks for Unix variants
 721 AC_USE_SYSTEM_EXTENSIONS
 722
 723 ### Use -Wno-pointer-sign if the compiler supports it
 724 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 725 SAVE_CFLAGS="$CFLAGS"
 726 CFLAGS="$CFLAGS -Wno-pointer-sign"
 727 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 728 if test $has_option = yes; then
 729    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 730 fi
 731 AC_MSG_RESULT($has_option)
 732 CFLAGS="$SAVE_CFLAGS"
 733 unset has_option
 734 unset SAVE_CFLAGS
 735
 736 ### Use -Wdeclaration-after-statement if the compiler supports it
 737 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 738 SAVE_CFLAGS="$CFLAGS"
 739 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 740 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 741 if test $has_option = yes; then
 742    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 743 fi
 744 AC_MSG_RESULT($has_option)
 745 CFLAGS="$SAVE_CFLAGS"
 746 unset has_option
 747 unset SAVE_CFLAGS
 748
 749 #### Some other nice autoconf tests.
 750
 751 dnl checks for programs
 752 AC_PROG_LN_S
 753 AC_PROG_CPP
 754 AC_PROG_INSTALL
 755 if test "x$RANLIB" = x; then
 756   AC_PROG_RANLIB
 757 fi
 758 AC_PATH_PROG(INSTALL_INFO, install-info)
 759 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 760 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 761 dnl Don't use GZIP, which is used by gzip for additional parameters.
 762 AC_PATH_PROG(GZIP_PROG, gzip)
 763
 764
 765 ## Need makeinfo >= 4.6 (?) to build the manuals.
 766 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 767 dnl By this stage, configure has already checked for egrep and set EGREP,
 768 dnl or exited with an error if no egrep was found.
 769 if test "$MAKEINFO" != "no" && \
 770   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 771    MAKEINFO=no
 772 fi
 773
 774 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 775 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 776 ## therefore in the category of "special tools" not normally required, which
 777 ## configure does not have to check for (eg autoconf itself).
 778 ## In a Bazaar checkout on the other hand, the manuals are not included.
 779 ## So makeinfo is a requirement to build from Bazaar, and configure
 780 ## should test for it as it does for any other build requirement.
 781 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 782 ## with pre-built manuals, from a Bazaar checkout.
 783 if test "$MAKEINFO" = "no"; then
 784   if test "x${with_makeinfo}" = "xno"; then
 785     MAKEINFO=off
 786   elif test ! -e $srcdir/info/emacs; then
 787     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 788 source tree does not seem to have pre-built manuals in the `info' directory.
 789 Either install a suitable version of makeinfo, or re-run configure
 790 with the `--without-makeinfo' option to build without the manuals.] )
 791   fi
 792 fi
 793
 794 dnl Add our options to ac_link now, after it is set up.
 795
 796 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 797 then
 798   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 799 fi
 800
 801 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 802 then
 803   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 804 fi
 805
 806 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 807 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 808 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 809 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 810 dnl if not built to support GNU ld.
 811
 812 late_LDFLAGS=$LDFLAGS
 813 if test "$GCC" = yes; then
 814   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 815 else
 816   LDFLAGS="$LDFLAGS -znocombreloc"
 817 fi
 818
 819 AC_MSG_CHECKING([for -znocombreloc])
 820 AC_LINK_IFELSE([main(){return 0;}],
 821   [AC_MSG_RESULT(yes)],
 822   LDFLAGS=$late_LDFLAGS
 823   [AC_MSG_RESULT(no)])
 824
 825 #### Extract some information from the operating system and machine files.
 826
 827 AC_CHECKING([the machine- and system-dependent files to find out
 828  - which libraries the lib-src programs will want, and
 829  - whether the GNU malloc routines are usable])
 830
 831 ### First figure out CFLAGS (which we use for running the compiler here)
 832 ### and REAL_CFLAGS (which we use for real compilation).
 833 ### The two are the same except on a few systems, where they are made
 834 ### different to work around various lossages.  For example,
 835 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 836 ### as implying static linking.
 837
 838 ### If the CFLAGS env var is specified, we use that value
 839 ### instead of the default.
 840
 841 ### It's not important that this name contain the PID; you can't run
 842 ### two configures in the same directory and have anything work
 843 ### anyway.
 844 tempcname="conftest.c"
 845
 846 echo '
 847 #include "'${srcdir}'/src/'${opsysfile}'"
 848 #include "'${srcdir}'/src/'${machfile}'"
 849 #ifndef LIBS_MACHINE
 850 #define LIBS_MACHINE
 851 #endif
 852 #ifndef LIBS_SYSTEM
 853 #define LIBS_SYSTEM
 854 #endif
 855 #ifndef C_SWITCH_SYSTEM
 856 #define C_SWITCH_SYSTEM
 857 #endif
 858 #ifndef C_SWITCH_MACHINE
 859 #define C_SWITCH_MACHINE
 860 #endif
 861 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 862 configure___ c_switch_system=C_SWITCH_SYSTEM
 863 configure___ c_switch_machine=C_SWITCH_MACHINE
 864
 865 #ifndef LIB_X11_LIB
 866 #define LIB_X11_LIB -lX11
 867 #endif
 868
 869 configure___ LIBX=LIB_X11_LIB
 870
 871 #ifdef UNEXEC
 872 configure___ unexec=UNEXEC
 873 #else
 874 configure___ unexec=unexec.o
 875 #endif
 876
 877 #ifdef SYSTEM_MALLOC
 878 configure___ system_malloc=yes
 879 #else
 880 configure___ system_malloc=no
 881 #endif
 882
 883 #ifdef USE_MMAP_FOR_BUFFERS
 884 configure___ use_mmap_for_buffers=yes
 885 #else
 886 configure___ use_mmap_for_buffers=no
 887 #endif
 888
 889 #ifndef C_OPTIMIZE_SWITCH
 890 #ifdef __GNUC__
 891 #define C_OPTIMIZE_SWITCH -O2
 892 #else
 893 #define C_OPTIMIZE_SWITCH -O
 894 #endif
 895 #endif
 896
 897 #ifndef C_WARNINGS_SWITCH
 898 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 899 #endif
 900
 901 #ifndef LD_SWITCH_MACHINE
 902 #define LD_SWITCH_MACHINE
 903 #endif
 904
 905 #ifndef LD_SWITCH_SYSTEM
 906 #define LD_SWITCH_SYSTEM
 907 #endif
 908
 909 #ifndef LD_SWITCH_X_SITE_AUX
 910 #define LD_SWITCH_X_SITE_AUX
 911 #endif
 912
 913 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 914 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 915
 916 #ifdef THIS_IS_CONFIGURE
 917
 918 /* Get the CFLAGS for tests in configure.  */
 919 #ifdef __GNUC__
 920 configure___ CFLAGS=C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 921 #else
 922 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 923 #endif
 924
 925 #else /* not THIS_IS_CONFIGURE */
 926
 927 /* Get the CFLAGS for real compilation.  */
 928 #ifdef __GNUC__
 929 configure___ REAL_CFLAGS=C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 930 #else
 931 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 932 #endif
 933
 934 #endif /* not THIS_IS_CONFIGURE */
 935 ' > ${tempcname}
 936
 937 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 938
 939 # The value of CPP is a quoted variable reference, so we need to do this
 940 # to get its actual value...
 941 CPP=`eval "echo $CPP"`
 942 [eval `${CPP} -Isrc ${tempcname} \
 943        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 944 if test "x$SPECIFIED_CFLAGS" = x; then
 945   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 946          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 947 else
 948   REAL_CFLAGS="$CFLAGS"
 949 fi]
 950 rm ${tempcname}
 951
 952 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 953
 954 ### Make sure subsequent tests use flags consistent with the build flags.
 955
 956 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 957   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 958 else
 959   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 960 fi
 961
 962 dnl For AC_FUNC_GETLOADAVG, at least:
 963 AC_CONFIG_LIBOBJ_DIR(src)
 964
 965 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 966 AC_SYS_LARGEFILE
 967
 968
 969 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 970 ### be located in either /usr/lib64 or /usr/lib.
 971 ### In some rare cases, /usr/lib64 exists but does not contain the
 972 ### relevant files (bug#1287).  Hence test for crtn.o.
 973 case "${canonical}" in
 974   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 975     if test -e /usr/lib64/crtn.o; then
 976       AC_DEFINE(HAVE_LIB64_DIR, 1,
 977         [Define to 1 if the directory /usr/lib64 exists.])
 978 fi
 979 esac
 980
 981 dnl This function defintion taken from Gnome 2.0
 982 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 983 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 984 dnl also defines GSTUFF_PKG_ERRORS on error
 985 AC_DEFUN([PKG_CHECK_MODULES], [
 986   succeeded=no
 987
 988   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 989
 990   if test "$PKG_CONFIG" = "no" ; then
 991      ifelse([$4], , [AC_MSG_ERROR([
 992       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 993   else
 994      PKG_CONFIG_MIN_VERSION=0.9.0
 995      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 996         AC_MSG_CHECKING(for $2)
 997
 998         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 999             AC_MSG_RESULT(yes)
1000             succeeded=yes
1001
1002             AC_MSG_CHECKING($1_CFLAGS)
1003             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1004             AC_MSG_RESULT($$1_CFLAGS)
1005
1006             AC_MSG_CHECKING($1_LIBS)
1007             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1008             AC_MSG_RESULT($$1_LIBS)
1009         else
1010             AC_MSG_RESULT(no)
1011             $1_CFLAGS=""
1012             $1_LIBS=""
1013             ## If we have a custom action on failure, don't print errors, but
1014             ## do set a variable so people can do so.
1015             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1016             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1017         fi
1018
1019         AC_SUBST($1_CFLAGS)
1020         AC_SUBST($1_LIBS)
1021      else
1022         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1023         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1024      fi
1025   fi
1026
1027   if test $succeeded = yes; then
1028      ifelse([$3], , :, [$3])
1029   else
1030      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1031   fi
1032 ])
1033
1034
1035 if test "${with_sound}" != "no"; then
1036   # Sound support for GNU/Linux and the free BSDs.
1037   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1038   # Emulation library used on NetBSD.
1039   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1040   AC_SUBST(LIBSOUND)
1041
1042   ALSA_REQUIRED=1.0.0
1043   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1044   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1045   if test $HAVE_ALSA = yes; then
1046     SAVE_CFLAGS="$CFLAGS"
1047     SAVE_LDFLAGS="$LDFLAGS"
1048     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1049     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1050     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1051                     emacs_alsa_normal=yes,
1052                     emacs_alsa_normal=no)
1053     if test "$emacs_alsa_normal" != yes; then
1054       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1055                      [snd_lib_error_set_handler (0);],
1056                      emacs_alsa_subdir=yes,
1057                      emacs_alsa_subdir=no)
1058       if test "$emacs_alsa_subdir" != yes; then
1059         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1060       fi
1061       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1062     fi
1063
1064     CFLAGS="$SAVE_CFLAGS"
1065     LDFLAGS="$SAVE_LDFLAGS"
1066     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1067     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1068     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1069   fi
1070   AC_SUBST(CFLAGS_SOUND)
1071 fi
1072
1073 dnl checks for header files
1074 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1075   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1076   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1077   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1078   sys/utsname.h pwd.h utmp.h)
1079
1080 AC_MSG_CHECKING(if personality LINUX32 can be set)
1081 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1082                emacs_cv_personality_linux32=yes,
1083                emacs_cv_personality_linux32=no)
1084 AC_MSG_RESULT($emacs_cv_personality_linux32)
1085
1086 if test $emacs_cv_personality_linux32 = yes; then
1087   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1088             [Define to 1 if personality LINUX32 can be set.])
1089 fi
1090
1091 dnl On Solaris 8 there's a compilation warning for term.h because
1092 dnl it doesn't define `bool'.
1093 AC_CHECK_HEADERS(term.h, , , -)
1094 AC_HEADER_STDC
1095 AC_HEADER_TIME
1096 AC_CHECK_DECLS([sys_siglist])
1097 if test $ac_cv_have_decl_sys_siglist != yes; then
1098   # For Tru64, at least:
1099   AC_CHECK_DECLS([__sys_siglist])
1100   if test $ac_cv_have_decl___sys_siglist = yes; then
1101     AC_DEFINE(sys_siglist, __sys_siglist,
1102               [Define to any substitute for sys_siglist.])
1103   fi
1104 fi
1105 AC_HEADER_SYS_WAIT
1106
1107 dnl Some systems have utime.h but don't declare the struct anyplace.
1108 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1109 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1110 #include <sys/time.h>
1111 #include <time.h>
1112 #else
1113 #ifdef HAVE_SYS_TIME_H
1114 #include <sys/time.h>
1115 #else
1116 #include <time.h>
1117 #endif
1118 #endif
1119 #ifdef HAVE_UTIME_H
1120 #include <utime.h>
1121 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1122   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1123 if test $emacs_cv_struct_utimbuf = yes; then
1124   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1125 fi
1126
1127 dnl checks for typedefs
1128 AC_TYPE_SIGNAL
1129
1130 dnl Check for speed_t typedef.
1131 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1132   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1133     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1134 if test $emacs_cv_speed_t = yes; then
1135   AC_DEFINE(HAVE_SPEED_T, 1,
1136            [Define to 1 if `speed_t' is declared by <termios.h>.])
1137 fi
1138
1139 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1140 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1141 #include <sys/time.h>
1142 #include <time.h>
1143 #else
1144 #ifdef HAVE_SYS_TIME_H
1145 #include <sys/time.h>
1146 #else
1147 #include <time.h>
1148 #endif
1149 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1150   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1151 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1152 if test $emacs_cv_struct_timeval = yes; then
1153   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1154 fi
1155
1156 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1157 AC_TRY_COMPILE([#include <math.h>],
1158 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1159   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1160 HAVE_EXCEPTION=$emacs_cv_struct_exception
1161 if test $emacs_cv_struct_exception != yes; then
1162   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1163 fi
1164
1165 AC_CHECK_HEADERS(sys/socket.h)
1166 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1167 #if HAVE_SYS_SOCKET_H
1168 #include <sys/socket.h>
1169 #endif])
1170
1171 dnl checks for structure members
1172 AC_STRUCT_TM
1173 AC_STRUCT_TIMEZONE
1174 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1175                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1176                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1177                 [#include <time.h>])
1178 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1179                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1180                   struct ifreq.ifr_addr], , ,
1181                  [AC_INCLUDES_DEFAULT
1182 #if HAVE_SYS_SOCKET_H
1183 #include <sys/socket.h>
1184 #endif
1185 #if HAVE_NET_IF_H
1186 #include <net/if.h>
1187 #endif])
1188
1189 dnl checks for compiler characteristics
1190
1191 dnl Testing __STDC__ to determine prototype support isn't good enough.
1192 dnl DEC C, for instance, doesn't define it with default options, and
1193 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1194 dnl and void *.
1195 AC_C_PROTOTYPES
1196 AC_C_VOLATILE
1197 AC_C_CONST
1198 dnl This isn't useful because we can't turn on use of `inline' unless
1199 dnl the compiler groks `extern inline'.
1200 dnl AC_C_INLINE
1201 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1202   [AC_TRY_COMPILE(, [void * foo;],
1203                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1204 if test $emacs_cv_void_star = yes; then
1205   AC_DEFINE(POINTER_TYPE, void)
1206 else
1207   AC_DEFINE(POINTER_TYPE, char)
1208 fi
1209 AH_TEMPLATE(POINTER_TYPE,
1210             [Define as `void' if your compiler accepts `void *'; otherwise
1211              define as `char'.])dnl
1212
1213
1214
1215 dnl This could be used for targets which can have both byte sexes.
1216 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1217 dnl AC_C_BIGENDIAN
1218
1219 dnl check for Make feature
1220 AC_PROG_MAKE_SET
1221
1222 dnl check for GNU Make if we have GCC and autodepend is on.
1223 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1224    AC_MSG_CHECKING([whether we are using GNU Make])
1225    HAVE_GNU_MAKE=no
1226    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1227    if test "x$testval" != x; then
1228       HAVE_GNU_MAKE=yes
1229    else
1230       ac_enable_autodepend=no
1231    fi
1232    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1233    if test $HAVE_GNU_MAKE = yes; then
1234       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1235       SAVE_CFLAGS="$CFLAGS"
1236       CFLAGS="$CFLAGS -MMD -MF deps.d"
1237       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1238       CFLAGS="$SAVE_CFLAGS"
1239       test -f deps.d || ac_enable_autodepend=no
1240       rm -rf deps.d
1241       AC_MSG_RESULT([$ac_enable_autodepend])
1242    fi
1243    if test $ac_enable_autodepend = yes; then
1244       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1245    fi
1246 fi
1247
1248 dnl checks for operating system services
1249 AC_SYS_LONG_FILE_NAMES
1250
1251 #### Choose a window system.
1252
1253 AC_PATH_X
1254 if test "$no_x" = yes; then
1255   window_system=none
1256 else
1257   window_system=x11
1258 fi
1259
1260 ## Workaround for bug in autoconf <= 2.62.
1261 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1262 ## No need to do anything special for these standard directories.
1263 ## This is an experiment, take it out if it causes problems.
1264 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1265
1266    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1267
1268 fi
1269
1270 if test "${x_libraries}" != NONE; then
1271   if test -n "${x_libraries}"; then
1272     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1273     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1274   fi
1275   x_default_search_path=""
1276   x_search_path=${x_libraries}
1277   if test -z "${x_search_path}"; then
1278     x_search_path=/usr/lib
1279   fi
1280   for x_library in `echo ${x_search_path}: | \
1281                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1282     x_search_path="\
1283 ${x_library}/X11/%L/%T/%N%C%S:\
1284 ${x_library}/X11/%l/%T/%N%C%S:\
1285 ${x_library}/X11/%T/%N%C%S:\
1286 ${x_library}/X11/%L/%T/%N%S:\
1287 ${x_library}/X11/%l/%T/%N%S:\
1288 ${x_library}/X11/%T/%N%S"
1289     if test x"${x_default_search_path}" = x; then
1290       x_default_search_path=${x_search_path}
1291     else
1292       x_default_search_path="${x_search_path}:${x_default_search_path}"
1293     fi
1294   done
1295 fi
1296 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1297   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1298 fi
1299
1300 if test x"${x_includes}" = x; then
1301   bitmapdir=/usr/include/X11/bitmaps
1302 else
1303   # accumulate include directories that have X11 bitmap subdirectories
1304   bmd_acc="dummyval"
1305   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1306     if test -d "${bmd}/X11/bitmaps"; then
1307       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1308     fi
1309     if test -d "${bmd}/bitmaps"; then
1310       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1311     fi
1312   done
1313   if test ${bmd_acc} != "dummyval"; then
1314     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1315   fi
1316 fi
1317
1318 HAVE_NS=no
1319 NS_IMPL_COCOA=no
1320 NS_IMPL_GNUSTEP=no
1321 tmp_CPPFLAGS="$CPPFLAGS"
1322 tmp_CFLAGS="$CFLAGS"
1323 CPPFLAGS="$CPPFLAGS -x objective-c"
1324 CFLAGS="$CFLAGS -x objective-c"
1325 if test "${with_ns}" != no; then
1326   if test "${opsys}" = darwin; then
1327      NS_IMPL_COCOA=yes
1328      ns_appdir=`pwd`/nextstep/Emacs.app
1329      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1330      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1331      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1332   elif test -f $GNUSTEP_CONFIG_FILE; then
1333      NS_IMPL_GNUSTEP=yes
1334      ns_appdir=`pwd`/nextstep/Emacs.app
1335      ns_appbindir=`pwd`/nextstep/Emacs.app
1336      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1337      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1338      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1339      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1340      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1341      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1342      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1343      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1344      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1345      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1346   fi
1347   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1348                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1349   files are missing or cannot be compiled.])])
1350   NS_HAVE_NSINTEGER=yes
1351   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1352                                      [NSInteger i;])],
1353                     ns_have_nsinteger=yes,
1354                     ns_have_nsinteger=no)
1355   if test $ns_have_nsinteger = no; then
1356     NS_HAVE_NSINTEGER=no
1357   fi
1358 fi
1359 if test "${HAVE_NS}" = yes; then
1360   window_system=nextstep
1361   with_xft=no
1362   # set up packaging dirs
1363   exec_prefix=${ns_appbindir}
1364   libexecdir=${ns_appbindir}/libexec
1365   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1366      prefix=${ns_appresdir}
1367   fi
1368 fi
1369 CFLAGS="$tmp_CFLAGS"
1370 CPPFLAGS="$tmp_CPPFLAGS"
1371
1372 case "${window_system}" in
1373   x11 )
1374     HAVE_X_WINDOWS=yes
1375     HAVE_X11=yes
1376     case "${with_x_toolkit}" in
1377       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1378       motif ) USE_X_TOOLKIT=MOTIF ;;
1379       gtk ) with_gtk=yes
1380 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1381 dnl USE_X_TOOLKIT is set.
1382             USE_X_TOOLKIT=none ;;
1383       no ) USE_X_TOOLKIT=none ;;
1384 dnl If user did not say whether to use a toolkit, make this decision later:
1385 dnl use the toolkit if we have gtk, or X11R5 or newer.
1386       * ) USE_X_TOOLKIT=maybe ;;
1387     esac
1388   ;;
1389   nextstep | none )
1390     HAVE_X_WINDOWS=no
1391     HAVE_X11=no
1392     USE_X_TOOLKIT=none
1393   ;;
1394 esac
1395
1396 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1397    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1398    if test "$HAVE_XSERVER" = true ||
1399       test -n "$DISPLAY" ||
1400       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1401         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1402 were found.  You should install the relevant development files for X
1403 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1404 sure you have development files for image handling, i.e.
1405 tiff, gif, jpeg, png and xpm.
1406 If you are sure you want Emacs compiled without X window support, pass
1407   --without-x
1408 to configure.])
1409    fi
1410 fi
1411
1412 ### If we're using X11, we should use the X menu package.
1413 HAVE_MENUS=no
1414 case ${HAVE_X11} in
1415   yes ) HAVE_MENUS=yes ;;
1416 esac
1417
1418 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1419 # Assume not, until told otherwise.
1420 GNU_MALLOC=yes
1421 doug_lea_malloc=yes
1422 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1423 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1424 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1425                emacs_cv_var___after_morecore_hook,
1426 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1427   emacs_cv_var___after_morecore_hook=yes,
1428   emacs_cv_var___after_morecore_hook=no)])
1429 if test $emacs_cv_var___after_morecore_hook = no; then
1430   doug_lea_malloc=no
1431 fi
1432 if test "${system_malloc}" = "yes"; then
1433   GNU_MALLOC=no
1434   GNU_MALLOC_reason="
1435     (The GNU allocators don't work with this system configuration.)"
1436 fi
1437 if test "$doug_lea_malloc" = "yes" ; then
1438   if test "$GNU_MALLOC" = yes ; then
1439     GNU_MALLOC_reason="
1440       (Using Doug Lea's new malloc from the GNU C Library.)"
1441   fi
1442   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1443             [Define to 1 if you are using the GNU C Library.])
1444 fi
1445
1446 if test x"${REL_ALLOC}" = x; then
1447   REL_ALLOC=${GNU_MALLOC}
1448 fi
1449
1450 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1451 dnl the system configuration file (s/*.h) to turn the use of mmap
1452 dnl in the relocating allocator on.
1453
1454 AC_FUNC_MMAP
1455 if test $use_mmap_for_buffers = yes; then
1456   REL_ALLOC=no
1457 fi
1458
1459 LIBS="$libsrc_libs $LIBS"
1460
1461 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1462 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1463 AC_CHECK_LIB(dnet, dnet_ntoa)
1464 dnl This causes -lresolv to get used in subsequent tests,
1465 dnl which causes failures on some systems such as HPUX 9.
1466 dnl AC_CHECK_LIB(resolv, gethostbyname)
1467
1468 dnl FIXME replace main with a function we actually want from this library.
1469 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1470
1471 AC_CHECK_LIB(pthreads, cma_open)
1472
1473 dnl Check for need for bigtoc support on IBM AIX
1474
1475 case ${host_os} in
1476 aix*)
1477   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1478     case $GCC in
1479     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1480     *) gdb_cv_bigtoc=-bbigtoc ;;
1481     esac
1482
1483     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1484     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1485   ])
1486   ;;
1487 esac
1488
1489 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1490 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1491 # REAL_CPPFLAGS later on.
1492
1493 REAL_CPPFLAGS="$CPPFLAGS"
1494
1495 if test "${HAVE_X11}" = "yes"; then
1496   DEFS="$C_SWITCH_X_SITE $DEFS"
1497   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1498   LIBS="$LIBX $LIBS"
1499   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1500   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1501
1502   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1503   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1504   # but it's more convenient here to set LD_RUN_PATH
1505   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1506   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1507     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1508     export LD_RUN_PATH
1509   fi
1510
1511   if test "${opsys}" = "gnu-linux"; then
1512     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1513     AC_TRY_LINK([],
1514      [XOpenDisplay ("foo");],
1515      [xlinux_first_failure=no],
1516      [xlinux_first_failure=yes])
1517     if test "${xlinux_first_failure}" = "yes"; then
1518       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1519       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1520       OLD_CPPFLAGS="$CPPFLAGS"
1521       OLD_LIBS="$LIBS"
1522       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1523       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1524       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1525       LIBS="$LIBS -b i486-linuxaout"
1526       AC_TRY_LINK([],
1527        [XOpenDisplay ("foo");],
1528        [xlinux_second_failure=no],
1529        [xlinux_second_failure=yes])
1530       if test "${xlinux_second_failure}" = "yes"; then
1531         # If we get the same failure with -b, there is no use adding -b.
1532         # So take it out.  This plays safe.
1533         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1534         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1535         CPPFLAGS="$OLD_CPPFLAGS"
1536         LIBS="$OLD_LIBS"
1537         AC_MSG_RESULT(no)
1538       else
1539         AC_MSG_RESULT(yes)
1540       fi
1541     else
1542       AC_MSG_RESULT(no)
1543     fi
1544   fi
1545
1546   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1547   # header files included from there.
1548   AC_MSG_CHECKING(for Xkb)
1549   AC_TRY_LINK([#include <X11/Xlib.h>
1550 #include <X11/XKBlib.h>],
1551         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1552         emacs_xkb=yes, emacs_xkb=no)
1553   AC_MSG_RESULT($emacs_xkb)
1554   if test $emacs_xkb = yes; then
1555     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1556   fi
1557
1558   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1559 XScreenNumberOfScreen XSetWMProtocols)
1560 fi
1561
1562 if test "${window_system}" = "x11"; then
1563   AC_MSG_CHECKING(X11 version 6)
1564   AC_CACHE_VAL(emacs_cv_x11_version_6,
1565   [AC_TRY_LINK([#include <X11/Xlib.h>],
1566 [#if XlibSpecificationRelease < 6
1567 fail;
1568 #endif
1569 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1570   if test $emacs_cv_x11_version_6 = yes; then
1571     AC_MSG_RESULT(6 or newer)
1572     AC_DEFINE(HAVE_X11R6, 1,
1573               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1574   else
1575     AC_MSG_RESULT(before 6)
1576   fi
1577 fi
1578
1579
1580 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1581 HAVE_RSVG=no
1582 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1583   if test "${with_rsvg}" != "no"; then
1584     RSVG_REQUIRED=2.11.0
1585     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1586
1587     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1588     AC_SUBST(RSVG_CFLAGS)
1589     AC_SUBST(RSVG_LIBS)
1590
1591     if test ".${RSVG_CFLAGS}" != "."; then
1592       HAVE_RSVG=yes
1593       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1594       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1595       LIBS="$RSVG_LIBS $LIBS"
1596     fi
1597   fi
1598 fi
1599
1600
1601 HAVE_GTK=no
1602 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1603   GLIB_REQUIRED=2.6
1604   GTK_REQUIRED=2.6
1605   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1606
1607   dnl Checks for libraries.
1608   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1609   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1610      AC_MSG_ERROR($GTK_PKG_ERRORS)
1611   fi
1612 fi
1613
1614
1615 GTK_OBJ=
1616 if test x"$pkg_check_gtk" = xyes; then
1617
1618   AC_SUBST(GTK_CFLAGS)
1619   AC_SUBST(GTK_LIBS)
1620   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1621   CFLAGS="$CFLAGS $GTK_CFLAGS"
1622   LIBS="$GTK_LIBS $LIBS"
1623   dnl Try to compile a simple GTK program.
1624   GTK_COMPILES=no
1625   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1626   if test "${GTK_COMPILES}" != "yes"; then
1627     if test "$USE_X_TOOLKIT" != "maybe"; then
1628       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1629     fi
1630   else
1631     HAVE_GTK=yes
1632     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1633     GTK_OBJ=gtkutil.o
1634     USE_X_TOOLKIT=none
1635     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1636       :
1637     else
1638       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1639        closing open displays.  This is no problem if you just use
1640        one display, but if you use more than one and close one of them
1641        Emacs may crash.]])
1642       sleep 3
1643     fi
1644   fi
1645
1646 fi
1647 AC_SUBST(GTK_OBJ)
1648
1649
1650 if test "${HAVE_GTK}" = "yes"; then
1651
1652   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1653   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1654   if test "$with_toolkit_scroll_bars" != no; then
1655     with_toolkit_scroll_bars=yes
1656   fi
1657
1658   dnl  Check if we can use multiple displays with this GTK version.
1659   dnl  If gdk_display_open exists, assume all others are there also.
1660   HAVE_GTK_MULTIDISPLAY=no
1661   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1662   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1663     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1664               [Define to 1 if GTK can handle more than one display.])
1665   fi
1666
1667   dnl  Check if we have the old file selection dialog declared and
1668   dnl  in the link library.  In 2.x it may be in the library,
1669   dnl  but not declared if deprecated featured has been selected out.
1670   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1671   HAVE_GTK_FILE_SELECTION=no
1672   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1673                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1674 #include <gtk/gtk.h>])
1675   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1676     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1677                    HAVE_GTK_FILE_SELECTION=no)
1678   fi
1679
1680   dnl  Check if we have the new file chooser dialog
1681   HAVE_GTK_FILE_CHOOSER=no
1682   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1683                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1684 #include <gtk/gtk.h>])
1685   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1686     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1687                    HAVE_GTK_FILE_CHOOSER=no)
1688   fi
1689
1690   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1691      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1692     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1693               [Define to 1 if GTK has both file selection and chooser dialog.])
1694   fi
1695
1696   dnl Check if pthreads are available.  Emacs only needs this when using
1697   dnl gtk_file_chooser under Gnome.
1698   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1699     HAVE_GTK_AND_PTHREAD=no
1700     AC_CHECK_HEADERS(pthread.h)
1701     if test "$ac_cv_header_pthread_h"; then
1702       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1703     fi
1704     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1705       case "${canonical}" in
1706         *-hpux*) ;;
1707         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1708       esac
1709       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1710                [Define to 1 if you have GTK and pthread (-lpthread).])
1711     fi
1712   fi
1713 fi
1714
1715 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1716 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1717 dnl also not configured.
1718 HAVE_DBUS=no
1719 DBUS_OBJ=
1720 if test "${with_dbus}" = "yes"; then
1721    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1722    if test "$HAVE_DBUS" = yes; then
1723      LIBS="$LIBS $DBUS_LIBS"
1724      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1725      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1726      DBUS_OBJ=dbusbind.o
1727    fi
1728 fi
1729 AC_SUBST(DBUS_OBJ)
1730
1731 dnl GConf has been tested under GNU/Linux only.
1732 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1733 HAVE_GCONF=no
1734 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1735    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1736    if test "$HAVE_GCONF" = yes; then
1737       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1738    fi
1739 fi
1740
1741 dnl SELinux is available for GNU/Linux only.
1742 HAVE_LIBSELINUX=no
1743 LIBSELINUX_LIBS=
1744 if test "${with_selinux}" = "yes"; then
1745    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1746    if test "$HAVE_LIBSELINUX" = yes; then
1747       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1748       LIBSELINUX_LIBS=-lselinux
1749    fi
1750 fi
1751 AC_SUBST(LIBSELINUX_LIBS)
1752
1753 dnl Do not put whitespace before the #include statements below.
1754 dnl Older compilers (eg sunos4 cc) choke on it.
1755 HAVE_XAW3D=no
1756 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1757   if test "$with_xaw3d" != no; then
1758     AC_MSG_CHECKING(for xaw3d)
1759     AC_CACHE_VAL(emacs_cv_xaw3d,
1760     [AC_TRY_LINK([
1761 #include <X11/Intrinsic.h>
1762 #include <X11/Xaw3d/Simple.h>],
1763       [],
1764       emacs_cv_xaw3d=yes,
1765       emacs_cv_xaw3d=no)])
1766   else
1767     emacs_cv_xaw3d=no
1768   fi
1769   if test $emacs_cv_xaw3d = yes; then
1770     AC_MSG_RESULT([yes; using Lucid toolkit])
1771     USE_X_TOOLKIT=LUCID
1772     HAVE_XAW3D=yes
1773     AC_DEFINE(HAVE_XAW3D, 1,
1774               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1775   else
1776     AC_MSG_RESULT(no)
1777     AC_MSG_CHECKING(for libXaw)
1778     AC_CACHE_VAL(emacs_cv_xaw,
1779     [AC_TRY_LINK([
1780 #include <X11/Intrinsic.h>
1781 #include <X11/Xaw/Simple.h>],
1782       [],
1783       emacs_cv_xaw=yes,
1784       emacs_cv_xaw=no)])
1785     if test $emacs_cv_xaw = yes; then
1786       AC_MSG_RESULT([yes; using Lucid toolkit])
1787       USE_X_TOOLKIT=LUCID
1788     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1789       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1790     else
1791       AC_MSG_RESULT([no; do not use toolkit by default])
1792       USE_X_TOOLKIT=none
1793     fi
1794   fi
1795 fi
1796
1797 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1798
1799 if test "${USE_X_TOOLKIT}" != "none"; then
1800   AC_MSG_CHECKING(X11 toolkit version)
1801   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1802   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1803 [#if XtSpecificationRelease < 6
1804 fail;
1805 #endif
1806 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1807   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1808   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1809     AC_MSG_RESULT(6 or newer)
1810     AC_DEFINE(HAVE_X11XTR6, 1,
1811               [Define to 1 if you have the X11R6 or newer version of Xt.])
1812   else
1813     AC_MSG_RESULT(before 6)
1814   fi
1815
1816 dnl If using toolkit, check whether libXmu.a exists.
1817 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1818   OLDLIBS="$LIBS"
1819   if test x$HAVE_X11XTR6 = xyes; then
1820     LIBS="-lXt -lSM -lICE $LIBS"
1821   else
1822     LIBS="-lXt $LIBS"
1823   fi
1824   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1825   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1826 fi
1827
1828 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1829 if test "${HAVE_X11}" = "yes"; then
1830   if test "${USE_X_TOOLKIT}" != "none"; then
1831     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1832   fi
1833 fi
1834
1835 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1836   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1837   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1838     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1839 int x = 5;
1840 #else
1841 Motif version prior to 2.1.
1842 #endif],
1843     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1844   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1845   if test $emacs_cv_motif_version_2_1 = yes; then
1846     HAVE_LIBXP=no
1847     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1848               [Define to 1 if you have Motif 2.1 or newer.])
1849     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1850     if test ${HAVE_LIBXP} = yes; then
1851       AC_DEFINE(HAVE_LIBXP, 1,
1852                 [Define to 1 if you have the Xp library (-lXp).])
1853     fi
1854   else
1855     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1856     # We put this in CFLAGS temporarily to precede other -I options
1857     # that might be in CFLAGS temporarily.
1858     # We put this in CPPFLAGS where it precedes the other -I options.
1859     OLD_CPPFLAGS=$CPPFLAGS
1860     OLD_CFLAGS=$CFLAGS
1861     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1862     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1863     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1864       [int x = 5;],
1865       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1866     if test $emacs_cv_lesstif = yes; then
1867       # Make sure this -I option remains in CPPFLAGS after it is set
1868       # back to REAL_CPPFLAGS.
1869       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1870       # have those other -I options anyway.  Ultimately, having this
1871       # directory ultimately in CPPFLAGS will be enough.
1872       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1873       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1874     else
1875       CFLAGS=$OLD_CFLAGS
1876       CPPFLAGS=$OLD_CPPFLAGS
1877     fi
1878   fi
1879 fi
1880
1881 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1882 dnl using Motif or Xaw3d is available, and unless
1883 dnl --with-toolkit-scroll-bars=no was specified.
1884
1885 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1886             [Define to 1 if we should use toolkit scroll bars.])dnl
1887 USE_TOOLKIT_SCROLL_BARS=no
1888 if test "${with_toolkit_scroll_bars}" != "no"; then
1889   if test "${USE_X_TOOLKIT}" != "none"; then
1890     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1891       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1892       HAVE_XAW3D=no
1893       USE_TOOLKIT_SCROLL_BARS=yes
1894     elif test "${HAVE_XAW3D}" = "yes"; then
1895       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1896       USE_TOOLKIT_SCROLL_BARS=yes
1897     fi
1898   elif test "${HAVE_GTK}" = "yes"; then
1899     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1900     USE_TOOLKIT_SCROLL_BARS=yes
1901   elif test "${HAVE_NS}" = "yes"; then
1902     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1903     USE_TOOLKIT_SCROLL_BARS=yes
1904   fi
1905 fi
1906
1907 dnl See if XIM is available.
1908 AC_TRY_COMPILE([
1909           #include <X11/Xlib.h>
1910           #include <X11/Xresource.h>],
1911          [XIMProc  callback;],
1912          [HAVE_XIM=yes
1913          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1914          HAVE_XIM=no)
1915
1916 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1917
1918 if test "${with_xim}" != "no"; then
1919   AC_DEFINE(USE_XIM, 1,
1920             [Define to 1 if we should use XIM, if it is available.])
1921 fi
1922
1923
1924 if test "${HAVE_XIM}" != "no"; then
1925   late_CFLAGS=$CFLAGS
1926   if test "$GCC" = yes; then
1927     CFLAGS="$CFLAGS --pedantic-errors"
1928   fi
1929   AC_TRY_COMPILE([
1930 #include <X11/Xlib.h>
1931 #include <X11/Xresource.h>],
1932 [Display *display;
1933 XrmDatabase db;
1934 char *res_name;
1935 char *res_class;
1936 XIMProc  callback;
1937 XPointer *client_data;
1938 #ifndef __GNUC__
1939 /* If we're not using GCC, it's probably not XFree86, and this is
1940    probably right, but we can't use something like --pedantic-errors.  */
1941 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1942                                            char*, XIMProc, XPointer*);
1943 #endif
1944 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1945    client_data);],
1946     [emacs_cv_arg6_star=yes])
1947   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1948          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1949 either XPointer or XPointer*.])dnl
1950   if test "$emacs_cv_arg6_star" = yes; then
1951     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1952   else
1953     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1954   fi
1955   CFLAGS=$late_CFLAGS
1956 fi
1957
1958 ### Start of font-backend (under any platform) section.
1959 # (nothing here yet -- this is a placeholder)
1960 ### End of font-backend (under any platform) section.
1961
1962 ### Start of font-backend (under X11) section.
1963 if test "${HAVE_X11}" = "yes"; then
1964    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1965
1966    ## Use -lXft if available, unless `--with-xft=no'.
1967    HAVE_XFT=maybe
1968     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1969       with_xft="no";
1970     fi
1971     if test "x${with_xft}" != "xno"; then
1972
1973       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1974       ## Because xftfont.c uses XRenderQueryExtension, we also
1975       ## need to link to -lXrender.
1976       HAVE_XRENDER=no
1977       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
1978       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
1979         OLD_CPPFLAGS="$CPPFLAGS"
1980         OLD_CFLAGS="$CFLAGS"
1981         OLD_LIBS="$LIBS"
1982         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1983         CFLAGS="$CFLAGS $XFT_CFLAGS"
1984         XFT_LIBS="-lXrender $XFT_LIBS"
1985         LIBS="$XFT_LIBS $LIBS"
1986         AC_CHECK_HEADER(X11/Xft/Xft.h,
1987           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1988
1989         if test "${HAVE_XFT}" = "yes"; then
1990           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1991             AC_SUBST(XFT_LIBS)
1992           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1993         else
1994           CPPFLAGS="$OLD_CPPFLAGS"
1995           CFLAGS="$OLD_CFLAGS"
1996           LIBS="$OLD_LIBS"
1997         fi                        # "${HAVE_XFT}" = "yes"
1998       fi                          # "$HAVE_XFT" != no
1999     fi                            # "x${with_xft}" != "xno"
2000
2001     dnl For the "Does Emacs use" message at the end.
2002     if test "$HAVE_XFT" != "yes"; then
2003        HAVE_XFT=no
2004     fi
2005
2006
2007     HAVE_FREETYPE=no
2008     ## We used to allow building with FreeType and without Xft.
2009     ## However, the ftx font backend driver is not in good shape.
2010     if test "${HAVE_XFT}" = "yes"; then
2011       dnl As we use Xft, we anyway use freetype.
2012       dnl There's no need for additional CFLAGS and LIBS.
2013       HAVE_FREETYPE=yes
2014       FONTCONFIG_CFLAGS=
2015       FONTCONFIG_LIBS=
2016     fi
2017
2018     HAVE_LIBOTF=no
2019     if test "${HAVE_FREETYPE}" = "yes"; then
2020       AC_DEFINE(HAVE_FREETYPE, 1,
2021                 [Define to 1 if using the freetype and fontconfig libraries.])
2022       if test "${with_libotf}" != "no"; then
2023         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2024                           HAVE_LIBOTF=no)
2025         if test "$HAVE_LIBOTF" = "yes"; then
2026           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2027           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2028                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2029                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2030           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2031             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2032                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2033           fi
2034         fi
2035       fi
2036     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2037     dnl Does the new font backend require it, or can it work without it?
2038     fi
2039
2040     HAVE_M17N_FLT=no
2041     if test "${HAVE_LIBOTF}" = yes; then
2042       if test "${with_m17n_flt}" != "no"; then
2043         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2044         if test "$HAVE_M17N_FLT" = "yes"; then
2045           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2046         fi
2047       fi
2048     fi
2049 else
2050     HAVE_XFT=no
2051     HAVE_FREETYPE=no
2052     HAVE_LIBOTF=no
2053     HAVE_M17N_FLT=no
2054 fi
2055 ### End of font-backend (under X11) section.
2056
2057 AC_SUBST(FREETYPE_CFLAGS)
2058 AC_SUBST(FREETYPE_LIBS)
2059 AC_SUBST(FONTCONFIG_CFLAGS)
2060 AC_SUBST(FONTCONFIG_LIBS)
2061 AC_SUBST(LIBOTF_CFLAGS)
2062 AC_SUBST(LIBOTF_LIBS)
2063 AC_SUBST(M17N_FLT_CFLAGS)
2064 AC_SUBST(M17N_FLT_LIBS)
2065
2066 ### Use -lXpm if available, unless `--with-xpm=no'.
2067 HAVE_XPM=no
2068 LIBXPM=
2069 if test "${HAVE_X11}" = "yes"; then
2070   if test "${with_xpm}" != "no"; then
2071     AC_CHECK_HEADER(X11/xpm.h,
2072       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2073     if test "${HAVE_XPM}" = "yes"; then
2074       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2075       AC_EGREP_CPP(no_return_alloc_pixels,
2076       [#include "X11/xpm.h"
2077 #ifndef XpmReturnAllocPixels
2078 no_return_alloc_pixels
2079 #endif
2080       ], HAVE_XPM=no, HAVE_XPM=yes)
2081
2082       if test "${HAVE_XPM}" = "yes"; then
2083         AC_MSG_RESULT(yes)
2084       else
2085         AC_MSG_RESULT(no)
2086       fi
2087     fi
2088   fi
2089
2090   if test "${HAVE_XPM}" = "yes"; then
2091     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2092     LIBXPM=-lXpm
2093   fi
2094 fi
2095 AC_SUBST(LIBXPM)
2096
2097 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2098 HAVE_JPEG=no
2099 LIBJPEG=
2100 if test "${HAVE_X11}" = "yes"; then
2101   if test "${with_jpeg}" != "no"; then
2102     dnl Checking for jpeglib.h can lose because of a redefinition of
2103     dnl  HAVE_STDLIB_H.
2104     AC_CHECK_HEADER(jerror.h,
2105       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2106   fi
2107
2108   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2109   if test "${HAVE_JPEG}" = "yes"; then
2110     AC_DEFINE(HAVE_JPEG)
2111     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2112         [#include <jpeglib.h>
2113          version=JPEG_LIB_VERSION
2114 ],
2115         [AC_DEFINE(HAVE_JPEG)],
2116         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2117         HAVE_JPEG=no])
2118   fi
2119   if test "${HAVE_JPEG}" = "yes"; then
2120     LIBJPEG=-ljpeg
2121   fi
2122 fi
2123 AC_SUBST(LIBJPEG)
2124
2125 ### Use -lpng if available, unless `--with-png=no'.
2126 HAVE_PNG=no
2127 LIBPNG=
2128 if test "${HAVE_X11}" = "yes"; then
2129   if test "${with_png}" != "no"; then
2130     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2131     # in /usr/include/libpng.
2132     AC_CHECK_HEADERS(png.h libpng/png.h)
2133     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2134       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2135     fi
2136   fi
2137
2138   if test "${HAVE_PNG}" = "yes"; then
2139     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2140     LIBPNG="-lpng -lz -lm"
2141   fi
2142 fi
2143 AC_SUBST(LIBPNG)
2144
2145 ### Use -ltiff if available, unless `--with-tiff=no'.
2146 HAVE_TIFF=no
2147 LIBTIFF=
2148 if test "${HAVE_X11}" = "yes"; then
2149   if test "${with_tiff}" != "no"; then
2150     AC_CHECK_HEADER(tiffio.h,
2151       [tifflibs="-lz -lm"
2152       # At least one tiff package requires the jpeg library.
2153       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2154       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2155   fi
2156
2157   if test "${HAVE_TIFF}" = "yes"; then
2158     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2159     dnl FIXME -lz -lm, as per libpng?
2160     LIBTIFF=-ltiff
2161   fi
2162 fi
2163 AC_SUBST(LIBTIFF)
2164
2165 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2166 HAVE_GIF=no
2167 LIBGIF=
2168 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2169   AC_CHECK_HEADER(gif_lib.h,
2170 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2171 # Earlier versions can crash Emacs.
2172     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2173
2174   if test "$HAVE_GIF" = yes; then
2175     LIBGIF=-lgif
2176   elif test "$HAVE_GIF" = maybe; then
2177 # If gif_lib.h but no libgif, try libungif.
2178     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2179     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2180   fi
2181
2182   if test "${HAVE_GIF}" = "yes"; then
2183     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2184   fi
2185 fi
2186 AC_SUBST(LIBGIF)
2187
2188 dnl Check for required libraries.
2189 if test "${HAVE_X11}" = "yes"; then
2190   MISSING=""
2191   WITH_NO=""
2192   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2193     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2194   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2195     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2196   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2197     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2198   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2199     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2200   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2201     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2202
2203   if test "X${MISSING}" != X; then
2204     AC_MSG_ERROR([The following required libraries were not found:
2205     $MISSING
2206 Maybe some development libraries/packages are missing?
2207 If you don't want to link with them give
2208     $WITH_NO
2209 as options to configure])
2210   fi
2211 fi
2212
2213 ### Use -lgpm if available, unless `--with-gpm=no'.
2214 HAVE_GPM=no
2215 LIBGPM=
2216 if test "${with_gpm}" != "no"; then
2217   AC_CHECK_HEADER(gpm.h,
2218     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2219
2220   if test "${HAVE_GPM}" = "yes"; then
2221     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2222     LIBGPM=-lgpm
2223   fi
2224 fi
2225 AC_SUBST(LIBGPM)
2226
2227 dnl Check for malloc/malloc.h on darwin
2228 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2229
2230 ### Use NeXTstep API to implement GUI.
2231 if test "${HAVE_NS}" = "yes"; then
2232   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2233   if test "${NS_IMPL_COCOA}" = "yes"; then
2234     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2235     GNU_OBJC_CFLAGS=
2236   fi
2237   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2238     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2239     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2240   fi
2241   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2242     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2243   fi
2244   # We also have mouse menus.
2245   HAVE_MENUS=yes
2246   OTHER_FILES=ns-app
2247 fi
2248
2249
2250 ### Use session management (-lSM -lICE) if available
2251 HAVE_X_SM=no
2252 LIBXSM=
2253 if test "${HAVE_X11}" = "yes"; then
2254   AC_CHECK_HEADER(X11/SM/SMlib.h,
2255     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2256
2257   if test "${HAVE_X_SM}" = "yes"; then
2258     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2259     LIBXSM="-lSM -lICE"
2260     case "$LIBS" in
2261       *-lSM*) ;;
2262       *)      LIBS="$LIBXSM $LIBS" ;;
2263     esac
2264   fi
2265 fi
2266 AC_SUBST(LIBXSM)
2267
2268 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2269 AC_CACHE_CHECK(whether netdb declares h_errno,
2270                emacs_cv_netdb_declares_h_errno,
2271 [AC_TRY_LINK([#include <netdb.h>],
2272   [return h_errno;],
2273   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2274 if test $emacs_cv_netdb_declares_h_errno = yes; then
2275   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2276 fi
2277
2278 AC_FUNC_ALLOCA
2279
2280 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2281 dnl FIXME is there an autoconf test that does the right thing, without
2282 dnl needing to call A_M_E afterwards?
2283 if test x"$ac_cv_func_alloca_works" != xyes; then
2284    AC_MSG_ERROR( [a system implementation of alloca is required] )
2285 fi
2286
2287 # fmod, logb, and frexp are found in -lm on most systems.
2288 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2289 AC_CHECK_LIB(m, sqrt)
2290
2291 # Check for mail-locking functions in a "mail" library.  Probably this should
2292 # have the same check as for liblockfile below.
2293 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2294 if test $have_mail = yes; then
2295   LIBS_MAIL=-lmail
2296   LIBS="$LIBS_MAIL $LIBS"
2297   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2298 else
2299   LIBS_MAIL=
2300 fi
2301 dnl Debian, at least:
2302 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2303 if test $have_lockfile = yes; then
2304    LIBS_MAIL=-llockfile
2305    LIBS="$LIBS_MAIL $LIBS"
2306    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2307 else
2308 # If we have the shared liblockfile, assume we must use it for mail
2309 # locking (e.g. Debian).  If we couldn't link against liblockfile
2310 # (no liblockfile.a installed), ensure that we don't need to.
2311   dnl This works for files generally, not just executables.
2312   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2313   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2314                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2315   if test $ac_cv_prog_liblockfile = yes; then
2316     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2317 This probably means that movemail could lose mail.
2318 There may be a `development' package to install containing liblockfile.])
2319   fi
2320 fi
2321 AC_CHECK_FUNCS(touchlock)
2322 AC_CHECK_HEADERS(maillock.h)
2323 AC_SUBST(LIBS_MAIL)
2324
2325 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2326 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2327 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2328 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2329 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2330 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2331 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2332 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2333 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2334 cfmakeraw cfsetspeed)
2335
2336 AC_CHECK_HEADERS(sys/un.h)
2337
2338 AC_FUNC_MKTIME
2339 if test "$ac_cv_func_working_mktime" = no; then
2340   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2341 fi
2342
2343 AC_FUNC_GETLOADAVG
2344
2345 AC_FUNC_FSEEKO
2346
2347 # Configure getopt.
2348 m4_include([m4/getopt.m4])
2349 gl_GETOPT_IFELSE([
2350   gl_GETOPT_SUBSTITUTE_HEADER
2351   gl_PREREQ_GETOPT
2352   GETOPTOBJS='getopt.o getopt1.o'
2353 ])
2354 AC_SUBST(GETOPTOBJS)
2355
2356 AC_FUNC_GETPGRP
2357
2358 AC_FUNC_STRFTIME
2359
2360 # UNIX98 PTYs.
2361 AC_CHECK_FUNCS(grantpt)
2362
2363 # PTY-related GNU extensions.
2364 AC_CHECK_FUNCS(getpt)
2365
2366 # Check this now, so that we will NOT find the above functions in ncurses.
2367 # That is because we have not set up to link ncurses in lib-src.
2368 # It's better to believe a function is not available
2369 # than to expect to find it in ncurses.
2370 # Also we need tputs and frieds to be able to build at all.
2371 have_tputs_et_al=true
2372 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2373 if test "$have_tputs_et_al" != true; then
2374   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2375 Maybe some development libraries/packages are missing?  Try installing
2376 libncurses-dev(el), libterminfo-dev(el) or similar.])
2377 fi
2378 # Must define this when any termcap library is found.
2379 AC_DEFINE(HAVE_LIBNCURSES, 1,
2380           [Define to 1 if you have the `ncurses' library (-lncurses).])
2381
2382 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2383
2384 resolv=no
2385 AC_TRY_LINK([#include <netinet/in.h>
2386 #include <arpa/nameser.h>
2387 #include <resolv.h>],
2388     [return res_init();],
2389     have_res_init=yes, have_res_init=no)
2390 if test "$have_res_init" = no; then
2391   OLIBS="$LIBS"
2392   LIBS="$LIBS -lresolv"
2393   AC_MSG_CHECKING(for res_init with -lresolv)
2394   AC_TRY_LINK([#include <netinet/in.h>
2395 #include <arpa/nameser.h>
2396 #include <resolv.h>],
2397     [return res_init();],
2398     have_res_init=yes, have_res_init=no)
2399   AC_MSG_RESULT($have_res_init)
2400   if test "$have_res_init" = yes ; then
2401     resolv=yes
2402   fi
2403   LIBS="$OLIBS"
2404 fi
2405
2406 if test "$have_res_init" = yes; then
2407   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2408 fi
2409
2410 # Do we need the Hesiod library to provide the support routines?
2411 LIBHESIOD=
2412 if test "$with_hesiod" != no ; then
2413   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2414   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2415      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2416                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2417   if test "$resolv" = yes ; then
2418     RESOLVLIB=-lresolv
2419   else
2420     RESOLVLIB=
2421   fi
2422   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2423         hesiod=yes, :, $RESOLVLIB)])
2424
2425   if test x"$hesiod" = xyes; then
2426     AC_DEFINE(HAVE_LIBHESIOD, 1,
2427               [Define to 1 if you have the hesiod library (-lhesiod).])
2428     LIBHESIOD=-lhesiod
2429   fi
2430 fi
2431 AC_SUBST(LIBHESIOD)
2432
2433 # Do we need libresolv (due to res_init or Hesiod)?
2434 if test "$resolv" = yes ; then
2435   AC_DEFINE(HAVE_LIBRESOLV, 1,
2436             [Define to 1 if you have the resolv library (-lresolv).])
2437   LIBRESOLV=-lresolv
2438 else
2439   LIBRESOLV=
2440 fi
2441 AC_SUBST(LIBRESOLV)
2442
2443 # These tell us which Kerberos-related libraries to use.
2444 COM_ERRLIB=
2445 CRYPTOLIB=
2446 KRB5LIB=
2447 DESLIB=
2448 KRB4LIB=
2449
2450 if test "${with_kerberos}" != no; then
2451   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2452   if test $have_com_err = yes; then
2453     COM_ERRLIB=-lcom_err
2454     LIBS="$COM_ERRLIB $LIBS"
2455     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2456   fi
2457   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2458   if test $have_crypto = yes; then
2459     CRYPTOLIB=-lcrypto
2460     LIBS="$CRYPTOLIB $LIBS"
2461     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2462   fi
2463   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2464   if test $have_k5crypto = yes; then
2465     CRYPTOLIB=-lk5crypto
2466     LIBS="$CRYPTOLIB $LIBS"
2467     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2468   fi
2469   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2470   if test $have_krb5=yes; then
2471     KRB5LIB=-lkrb5
2472     LIBS="$KRB5LIB $LIBS"
2473     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2474   fi
2475   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2476   if test "${with_kerberos5}" = no; then
2477     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2478     if test $have_des425 = yes; then
2479       DESLIB=-ldes425
2480       LIBS="$DESLIB $LIBS"
2481       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2482     else
2483       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2484       if test $have_des = yes; then
2485         DESLIB=-ldes
2486         LIBS="$DESLIB $LIBS"
2487         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2488       fi
2489     fi
2490     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2491     if test $have_krb4 = yes; then
2492       KRB4LIB=-lkrb4
2493       LIBS="$KRB4LIB $LIBS"
2494       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2495     else
2496       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2497       if test $have_krb = yes; then
2498         KRB4LIB=-lkrb
2499         LIBS="$KRB4LIB $LIBS"
2500         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2501       fi
2502     fi
2503   fi
2504
2505   if test "${with_kerberos5}" != no; then
2506     AC_CHECK_HEADERS(krb5.h,
2507       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2508                         [#include <krb5.h>])])
2509   else
2510     AC_CHECK_HEADERS(des.h,,
2511                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2512                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2513     AC_CHECK_HEADERS(krb.h,,
2514                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2515                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2516   fi
2517   AC_CHECK_HEADERS(com_err.h)
2518 fi
2519
2520 AC_SUBST(COM_ERRLIB)
2521 AC_SUBST(CRYPTOLIB)
2522 AC_SUBST(KRB5LIB)
2523 AC_SUBST(DESLIB)
2524 AC_SUBST(KRB4LIB)
2525
2526 # Solaris requires -lintl if you want strerror (which calls dgettext)
2527 # to return localized messages.
2528 AC_CHECK_LIB(intl, dgettext)
2529
2530 AC_MSG_CHECKING(whether localtime caches TZ)
2531 AC_CACHE_VAL(emacs_cv_localtime_cache,
2532 [if test x$ac_cv_func_tzset = xyes; then
2533 AC_TRY_RUN([#include <time.h>
2534 extern char **environ;
2535 unset_TZ ()
2536 {
2537   char **from, **to;
2538   for (to = from = environ; (*to = *from); from++)
2539     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2540       to++;
2541 }
2542 char TZ_GMT0[] = "TZ=GMT0";
2543 char TZ_PST8[] = "TZ=PST8";
2544 main()
2545 {
2546   time_t now = time ((time_t *) 0);
2547   int hour_GMT0, hour_unset;
2548   if (putenv (TZ_GMT0) != 0)
2549     exit (1);
2550   hour_GMT0 = localtime (&now)->tm_hour;
2551   unset_TZ ();
2552   hour_unset = localtime (&now)->tm_hour;
2553   if (putenv (TZ_PST8) != 0)
2554     exit (1);
2555   if (localtime (&now)->tm_hour == hour_GMT0)
2556     exit (1);
2557   unset_TZ ();
2558   if (localtime (&now)->tm_hour != hour_unset)
2559     exit (1);
2560   exit (0);
2561 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2562 [# If we have tzset, assume the worst when cross-compiling.
2563 emacs_cv_localtime_cache=yes])
2564 else
2565         # If we lack tzset, report that localtime does not cache TZ,
2566         # since we can't invalidate the cache if we don't have tzset.
2567         emacs_cv_localtime_cache=no
2568 fi])dnl
2569 AC_MSG_RESULT($emacs_cv_localtime_cache)
2570 if test $emacs_cv_localtime_cache = yes; then
2571   AC_DEFINE(LOCALTIME_CACHE, 1,
2572             [Define to 1 if localtime caches TZ.])
2573 fi
2574
2575 if test "x$HAVE_TIMEVAL" = xyes; then
2576   AC_CHECK_FUNCS(gettimeofday)
2577   if test $ac_cv_func_gettimeofday = yes; then
2578     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2579                    emacs_cv_gettimeofday_two_arguments,
2580     [AC_TRY_COMPILE([
2581 #ifdef TIME_WITH_SYS_TIME
2582 #include <sys/time.h>
2583 #include <time.h>
2584 #else
2585 #ifdef HAVE_SYS_TIME_H
2586 #include <sys/time.h>
2587 #else
2588 #include <time.h>
2589 #endif
2590 #endif],
2591       [struct timeval time;
2592        gettimeofday (&time, 0);],
2593       emacs_cv_gettimeofday_two_arguments=yes,
2594       emacs_cv_gettimeofday_two_arguments=no)])
2595     if test $emacs_cv_gettimeofday_two_arguments = no; then
2596       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2597                 [Define to 1 if gettimeofday accepts only one argument.])
2598     fi
2599   fi
2600 fi
2601
2602 ok_so_far=yes
2603 AC_CHECK_FUNC(socket, , ok_so_far=no)
2604 if test $ok_so_far = yes; then
2605   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2606 fi
2607 if test $ok_so_far = yes; then
2608   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2609 fi
2610 if test $ok_so_far = yes; then
2611 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2612   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2613             [Define to 1 if you have inet sockets.])
2614 fi
2615
2616 AC_CHECK_HEADERS(sys/ioctl.h)
2617
2618 if test -f /usr/lpp/X11/bin/smt.exp; then
2619   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2620             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2621 fi
2622
2623 AC_MSG_CHECKING(whether system supports dynamic ptys)
2624 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2625   AC_MSG_RESULT(yes)
2626   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2627 else
2628   AC_MSG_RESULT(no)
2629 fi
2630
2631 AC_FUNC_FORK
2632
2633 dnl Adapted from Haible's version.
2634 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2635   [AC_TRY_LINK([#include <langinfo.h>],
2636     [char* cs = nl_langinfo(CODESET);],
2637     emacs_cv_langinfo_codeset=yes,
2638     emacs_cv_langinfo_codeset=no)
2639   ])
2640 if test $emacs_cv_langinfo_codeset = yes; then
2641   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2642     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2643 fi
2644
2645 AC_CHECK_TYPES(size_t)
2646
2647 AC_TYPE_MBSTATE_T
2648
2649 dnl Restrict could probably be used effectively other than in regex.c.
2650 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2651   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2652                   emacs_cv_c_restrict=yes,
2653                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2654                                   emacs_cv_c_restrict=__restrict,
2655                                   emacs_cv_c_restrict=no)])])
2656 case "$emacs_cv_c_restrict" in
2657   yes) emacs_restrict=restrict;;
2658   no) emacs_restrict="";;
2659   *) emacs_restrict="$emacs_cv_c_restrict";;
2660 esac
2661 if test "$emacs_restrict" != __restrict; then
2662   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2663     [Define to compiler's equivalent of C99 restrict keyword.
2664      Don't define if equivalent is `__restrict'.])
2665 fi
2666
2667 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2668   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2669                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2670 if test "$emacs_cv_c_restrict_arr" = yes; then
2671   AC_DEFINE(__restrict_arr, __restrict,
2672     [Define to compiler's equivalent of C99 restrict keyword in array
2673      declarations.  Define as empty for no equivalent.])
2674 fi
2675
2676 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2677 dnl how the tty code is related to POSIX and/or other versions of termios.
2678 dnl The following looks like a useful start.
2679 dnl
2680 dnl AC_SYS_POSIX_TERMIOS
2681 dnl if test $ac_cv_sys_posix_termios = yes; then
2682 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2683 dnl                                and macros for terminal control.])
2684 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2685 dnl fi
2686
2687 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2688
2689 # Set up the CFLAGS for real compilation, so we can substitute it.
2690 CFLAGS="$REAL_CFLAGS"
2691 CPPFLAGS="$REAL_CPPFLAGS"
2692
2693 #### Find out which version of Emacs this is.
2694 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2695          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2696 if test x"${version}" = x; then
2697   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2698 fi
2699 if test x"${version}" != x"$PACKAGE_VERSION"; then
2700   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2701 fi
2702
2703 ### Specify what sort of things we'll be editing into Makefile and config.h.
2704 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2705 AC_SUBST(version)
2706 AC_SUBST(configuration)
2707 AC_SUBST(canonical)
2708 AC_SUBST(srcdir)
2709 AC_SUBST(prefix)
2710 AC_SUBST(exec_prefix)
2711 AC_SUBST(bindir)
2712 AC_SUBST(datadir)
2713 AC_SUBST(sharedstatedir)
2714 AC_SUBST(libexecdir)
2715 AC_SUBST(mandir)
2716 AC_SUBST(infodir)
2717 AC_SUBST(lispdir)
2718 AC_SUBST(locallisppath)
2719 AC_SUBST(lisppath)
2720 AC_SUBST(x_default_search_path)
2721 AC_SUBST(etcdir)
2722 AC_SUBST(archlibdir)
2723 AC_SUBST(docdir)
2724 AC_SUBST(bitmapdir)
2725 AC_SUBST(gamedir)
2726 AC_SUBST(gameuser)
2727 AC_SUBST(c_switch_system)
2728 AC_SUBST(c_switch_machine)
2729 AC_SUBST(LD_SWITCH_X_SITE)
2730 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2731 AC_SUBST(C_SWITCH_X_SITE)
2732 AC_SUBST(CFLAGS)
2733 AC_SUBST(X_TOOLKIT_TYPE)
2734 AC_SUBST(machfile)
2735 AC_SUBST(opsysfile)
2736 AC_SUBST(GETLOADAVG_LIBS)
2737 AC_SUBST(ns_appdir)
2738 AC_SUBST(ns_appbindir)
2739 AC_SUBST(ns_appresdir)
2740 AC_SUBST(ns_appsrc)
2741 AC_SUBST(GNUSTEP_MAKEFILES)
2742 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2743 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2744 AC_SUBST(GNU_OBJC_CFLAGS)
2745 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2746 AC_SUBST(OTHER_FILES)
2747
2748 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2749                    [Define to the canonical Emacs configuration name.])
2750 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2751                    [Define to the options passed to configure.])
2752 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2753                    [Define to the used machine dependent file.])
2754 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2755                    [Define to the used os dependent file.])
2756 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2757 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2758  may need to deal with X Windows.  For instance, if you've defined
2759  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2760  your loader can find on its own, you might want to add "-L/..." or
2761  something similar.])
2762 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2763                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2764                     in case it's needed (for Solaris, for example).])
2765 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2766 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2767  may need to deal with X Windows.  For instance, if you've defined
2768  HAVE_X_WINDOWS above and your X include files aren't in a place
2769  that your compiler can find on its own, you might want to add
2770  "-I/..." or something similar.])
2771 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2772                    [Define to the unexec source file name.])
2773
2774 XMENU_OBJ=
2775 XOBJ=
2776 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2777   AC_DEFINE(HAVE_X_WINDOWS, 1,
2778             [Define to 1 if you want to use the X window system.])
2779   XMENU_OBJ=xmenu.o
2780   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
2781 fi
2782 AC_SUBST(XMENU_OBJ)
2783 AC_SUBST(XOBJ)
2784
2785 if test "${USE_X_TOOLKIT}" != "none" ; then
2786   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2787   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2788     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2789   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2790     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2791   fi
2792 fi
2793 if test "${HAVE_X11}" = "yes" ; then
2794   AC_DEFINE(HAVE_X11, 1,
2795             [Define to 1 if you want to use version 11 of X windows.
2796              Otherwise, Emacs expects to use version 10.])
2797 fi
2798 if test "${HAVE_MENUS}" = "yes" ; then
2799   AC_DEFINE(HAVE_MENUS, 1,
2800             [Define to 1 if you have mouse menus.
2801              (This is automatic if you use X, but the option to specify it remains.)
2802              It is also defined with other window systems that support xmenu.c.])
2803 fi
2804 if test "${GNU_MALLOC}" = "yes" ; then
2805   AC_DEFINE(GNU_MALLOC, 1,
2806             [Define to 1 if you want to use the GNU memory allocator.])
2807 fi
2808 if test "${REL_ALLOC}" = "yes" ; then
2809   AC_DEFINE(REL_ALLOC, 1,
2810             [Define REL_ALLOC if you want to use the relocating allocator for
2811              buffer space.])
2812 fi
2813
2814
2815 AH_TOP([/* GNU Emacs site configuration template file.
2816    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2817      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2818
2819 This file is part of GNU Emacs.
2820
2821 GNU Emacs is free software: you can redistribute it and/or modify
2822 it under the terms of the GNU General Public License as published by
2823 the Free Software Foundation, either version 3 of the License, or
2824 (at your option) any later version.
2825
2826 GNU Emacs is distributed in the hope that it will be useful,
2827 but WITHOUT ANY WARRANTY; without even the implied warranty of
2828 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2829 GNU General Public License for more details.
2830
2831 You should have received a copy of the GNU General Public License
2832 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2833
2834
2835 /* No code in Emacs #includes config.h twice, but some bits of code
2836    intended to work with other packages as well (like gmalloc.c)
2837    think they can include it as many times as they like.  */
2838 #ifndef EMACS_CONFIG_H
2839 #define EMACS_CONFIG_H
2840 ])dnl
2841
2842 AH_BOTTOM([
2843 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2844 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2845 #define HAVE_WINDOW_SYSTEM
2846 #define HAVE_MOUSE
2847 #endif
2848
2849 /* Define AMPERSAND_FULL_NAME if you use the convention
2850    that & in the full name stands for the login id.  */
2851 /* Turned on June 1996 supposing nobody will mind it.  */
2852 #define AMPERSAND_FULL_NAME
2853
2854 /* Define HAVE_SOUND if we have sound support.  We know it works
2855    and compiles only on the specified platforms.   For others,
2856    it probably doesn't make sense to try.  */
2857
2858 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2859 #ifdef HAVE_MACHINE_SOUNDCARD_H
2860 #define HAVE_SOUND 1
2861 #endif
2862 #ifdef HAVE_SYS_SOUNDCARD_H
2863 #define HAVE_SOUND 1
2864 #endif
2865 #ifdef HAVE_SOUNDCARD_H
2866 #define HAVE_SOUND 1
2867 #endif
2868 #ifdef HAVE_ALSA
2869 #define HAVE_SOUND 1
2870 #endif
2871 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2872
2873 /* If using GNU, then support inline function declarations. */
2874 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2875    generally, because even if non-gcc compilers accept `inline', they
2876    may reject `extern inline'.  */
2877 #if defined (__GNUC__) && defined (OPTIMIZE)
2878 #define INLINE __inline__
2879 #else
2880 #define INLINE
2881 #endif
2882
2883 /* `subprocesses' should be defined if you want to
2884    have code for asynchronous subprocesses
2885    (as used in M-x compile and M-x shell).
2886    Only MSDOS does not support this (it overrides
2887    this in its config_opsysfile below).  */
2888
2889 #define subprocesses
2890
2891 /* Include the os and machine dependent files.  */
2892 #include config_opsysfile
2893 #include config_machfile
2894
2895 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2896   (There is probably a better place to do this, but right now the Cocoa
2897    side does this in s/darwin.h and we cannot
2898    parallel this exactly since GNUstep is multi-OS. */
2899 #ifdef HAVE_NS
2900 # ifdef NS_IMPL_GNUSTEP
2901 /* See also .m.o rule in Makefile.in */
2902 /* FIXME: are all these flags really needed?  Document here why.  */
2903 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2904 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2905 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2906 #  define SYSTEM_PURESIZE_EXTRA 30000
2907 # endif /* NS_IMPL_GNUSTEP */
2908 #endif /* HAVE_NS */
2909
2910 /* SIGTYPE is the macro we actually use.  */
2911 #ifndef SIGTYPE
2912 #define SIGTYPE RETSIGTYPE
2913 #endif
2914
2915 #ifdef emacs /* Don't do this for lib-src.  */
2916 /* Tell regex.c to use a type compatible with Emacs.  */
2917 #define RE_TRANSLATE_TYPE Lisp_Object
2918 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2919 #ifdef make_number
2920 /* If make_number is a macro, use it.  */
2921 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2922 #else
2923 /* If make_number is a function, avoid it.  */
2924 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2925 #endif
2926 #endif
2927
2928 /* Avoid link-time collision with system mktime if we will use our own.  */
2929 #if ! HAVE_MKTIME || BROKEN_MKTIME
2930 #define mktime emacs_mktime
2931 #endif
2932
2933 #define my_strftime nstrftime   /* for strftime.c */
2934
2935 /* The rest of the code currently tests the CPP symbol BSTRING.
2936    Override any claims made by the system-description files.
2937    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2938 #undef BSTRING
2939 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2940 #define BSTRING
2941 #endif
2942
2943 /* Some of the files of Emacs which are intended for use with other
2944    programs assume that if you have a config.h file, you must declare
2945    the type of getenv.
2946
2947    This declaration shouldn't appear when alloca.s or Makefile.in
2948    includes config.h.  */
2949 #ifndef NOT_C_CODE
2950 extern char *getenv ();
2951 #endif
2952
2953 /* These default definitions are good for almost all machines.
2954    The exceptions override them in m/MACHINE.h.  */
2955
2956 #ifndef BITS_PER_CHAR
2957 #define BITS_PER_CHAR 8
2958 #endif
2959
2960 #ifndef BITS_PER_SHORT
2961 #define BITS_PER_SHORT 16
2962 #endif
2963
2964 /* Note that lisp.h uses this in a preprocessor conditional, so it
2965    would not work to use sizeof.  That being so, we do all of them
2966    without sizeof, for uniformity's sake.  */
2967 #ifndef BITS_PER_INT
2968 #define BITS_PER_INT 32
2969 #endif
2970
2971 #ifndef BITS_PER_LONG
2972 #ifdef _LP64
2973 #define BITS_PER_LONG 64
2974 #else
2975 #define BITS_PER_LONG 32
2976 #endif
2977 #endif
2978
2979 /* Define if the compiler supports function prototypes.  It may do so
2980    but not define __STDC__ (e.g. DEC C by default) or may define it as
2981    zero.  */
2982 #undef PROTOTYPES
2983 /* For mktime.c:  */
2984 #ifndef __P
2985 # if defined PROTOTYPES
2986 #  define __P(args) args
2987 # else
2988 #  define __P(args) ()
2989 # endif  /* GCC.  */
2990 #endif /* __P */
2991
2992 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2993 #ifndef NOT_C_CODE
2994 #ifdef HAVE_STRING_H
2995 #include "string.h"
2996 #endif
2997 #ifdef HAVE_STRINGS_H
2998 #include "strings.h"  /* May be needed for bcopy & al. */
2999 #endif
3000 #ifdef HAVE_STDLIB_H
3001 #include <stdlib.h>
3002 #endif
3003 #ifndef __GNUC__
3004 # ifdef HAVE_ALLOCA_H
3005 #  include <alloca.h>
3006 # else /* AIX files deal with #pragma.  */
3007 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3008 char *alloca ();
3009 #  endif
3010 # endif /* HAVE_ALLOCA_H */
3011 #endif /* __GNUC__ */
3012 #ifndef HAVE_SIZE_T
3013 typedef unsigned size_t;
3014 #endif
3015 #endif /* NOT_C_CODE */
3016
3017 /* Define HAVE_X_I18N if we have usable i18n support.  */
3018
3019 #ifdef HAVE_X11R6
3020 #define HAVE_X_I18N
3021 #elif !defined X11R5_INHIBIT_I18N
3022 #define HAVE_X_I18N
3023 #endif
3024
3025 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3026
3027 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3028 #define HAVE_X11R6_XIM
3029 #endif
3030
3031 #if defined __GNUC__ && (__GNUC__ > 2 \
3032                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3033 #define NO_RETURN       __attribute__ ((__noreturn__))
3034 #else
3035 #define NO_RETURN       /* nothing */
3036 #endif
3037
3038 /* These won't be used automatically yet.  We also need to know, at least,
3039    that the stack is continuous.  */
3040 #ifdef __GNUC__
3041 #  ifndef GC_SETJMP_WORKS
3042   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3043      see NON_SAVING_SETJMP in the target descriptions.  */
3044   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3045      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3046      Fixme: Deal with SVR3.  */
3047 #    define GC_SETJMP_WORKS 1
3048 #  endif
3049 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3050 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3051 #  endif
3052 #endif
3053
3054 #ifndef HAVE_BCOPY
3055 #define bcopy(a,b,s) memcpy (b,a,s)
3056 #endif
3057 #ifndef HAVE_BZERO
3058 #define bzero(a,s) memset (a,0,s)
3059 #endif
3060 #ifndef HAVE_BCMP
3061 #define BCMP memcmp
3062 #endif
3063
3064 #endif /* EMACS_CONFIG_H */
3065
3066 /*
3067 Local Variables:
3068 mode: c
3069 End:
3070 */
3071 ])dnl
3072
3073 #### Report on what we decided to do.
3074 #### Report GTK as a toolkit, even if it doesn't use Xt.
3075 #### It makes printing result more understandable as using GTK sets
3076 #### toolkit_scroll_bars to yes by default.
3077 if test "${HAVE_GTK}" = "yes"; then
3078   USE_X_TOOLKIT=GTK
3079 fi
3080
3081 echo "
3082 Configured for \`${canonical}'.
3083
3084   Where should the build process find the source code?    ${srcdir}
3085   What operating system and machine description files should Emacs use?
3086         \`${opsysfile}' and \`${machfile}'
3087   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3088   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3089   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3090   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3091   What window system should Emacs use?                    ${window_system}
3092   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3093
3094 if test -n "${x_includes}"; then
3095 echo "  Where do we find X Windows header files?                ${x_includes}"
3096 else
3097 echo "  Where do we find X Windows header files?                Standard dirs"
3098 fi
3099 if test -n "${x_libraries}"; then
3100 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3101 else
3102 echo "  Where do we find X Windows libraries?                   Standard dirs"
3103 fi
3104
3105 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3106 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3107 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3108 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3109 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3110 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3111 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3112 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3113 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3114 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3115 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3116
3117 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3118 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3119 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3120 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3121
3122 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3123 echo
3124
3125 if test $USE_XASSERTS = yes; then
3126    echo "  Compiling with asserts turned on."
3127    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3128 fi
3129
3130 echo
3131
3132 if test "$HAVE_NS" = "yes"; then
3133    echo
3134    echo "You must run \"make install\" in order to test the built application.
3135 The installed application will go to nextstep/Emacs.app and can be
3136 run or moved from there."
3137    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3138       echo "The application will be fully self-contained."
3139     else
3140       echo "The lisp resources for the application will be installed under ${prefix}.
3141 You may need to run \"make install\" with sudo.  The application will fail
3142 to run if these resources are not installed."
3143    fi
3144    echo
3145 fi
3146
3147 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3148   echo "D-Bus integration has been tested for GNU/Linux only."
3149   echo
3150 fi
3151
3152
3153 # Remove any trailing slashes in these variables.
3154 [test "${prefix}" != NONE &&
3155   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3156 test "${exec_prefix}" != NONE &&
3157   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3158
3159 # Now get this: Some word that is part of the ${srcdir} directory name
3160 # or the ${configuration} value might, just might, happen to be an
3161 # identifier like `sun4' or `i386' or something, and be predefined by
3162 # the C preprocessor to some helpful value like 1, or maybe the empty
3163 # string.  Needless to say consequent macro substitutions are less
3164 # than conducive to the makefile finding the correct directory.
3165 [cpp_undefs="`echo $srcdir $configuration $canonical |
3166   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3167   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3168
3169 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3170 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3171 ## from Makefile.c can correctly provide the arg `-traditional' to the
3172 ## C preprocessor.
3173
3174 AC_EGREP_CPP(yes..yes,
3175         [yes..yes],
3176         CPP_NEED_TRADITIONAL=no,
3177         CPP_NEED_TRADITIONAL=yes)
3178
3179 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3180         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3181         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3182         lwlib/Makefile lisp/Makefile leim/Makefile, [
3183
3184 ### Make the necessary directories, if they don't exist.
3185 for dir in etc lisp ; do
3186   test -d ${dir} || mkdir ${dir}
3187 done
3188
3189 # Build src/Makefile from ${srcdir}/src/Makefile.c
3190 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3191 # This must be done after src/config.h is built, since we rely on that file.
3192
3193 echo creating src/epaths.h
3194 ${MAKE-make} epaths-force
3195
3196 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3197 # `..' to `. .'  unless invoked with -traditional
3198
3199 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3200   CPPFLAGS="$CPPFLAGS -traditional"
3201 fi
3202
3203 echo creating lib-src/Makefile
3204 ( cd lib-src
3205   rm -f junk.c junk1.c junk2.c
3206   sed -e '/start of cpp stuff/q' \
3207       < Makefile.c > junk1.c
3208   sed -e '1,/start of cpp stuff/d'\
3209       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3210       < Makefile.c > junk.c
3211   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3212       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3213   cat junk1.c junk2.c > Makefile.new
3214   rm -f junk.c junk1.c junk2.c
3215   chmod 444 Makefile.new
3216   mv -f Makefile.new Makefile
3217 )
3218
3219 echo creating src/Makefile
3220 ( cd src
3221   rm -f junk.c junk1.c junk2.c
3222   sed -e '/start of cpp stuff/q' \
3223       < Makefile.c > junk1.c
3224   sed -e '1,/start of cpp stuff/d'\
3225       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3226       < Makefile.c > junk.c
3227   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3228       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3229   cat junk1.c junk2.c > Makefile.new
3230   rm -f junk.c junk1.c junk2.c
3231   chmod 444 Makefile.new
3232   mv -f Makefile.new Makefile
3233 )
3234
3235 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3236   echo creating src/.gdbinit
3237   echo source $srcdir/src/.gdbinit > src/.gdbinit
3238 fi
3239
3240 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3241
3242 m4_if(dnl       Do not change this comment
3243    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3244 )dnl