lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992,1993,1994,1995,1996,1998,1999,2000,2001,2002,2004
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned."
 200   (or (facep name)
 201       (check-face name)))
 202 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 203
 204 \f
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;;; Predicates, type checks.
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208
 209 (defun facep (face)
 210   "Return non-nil if FACE is a face name."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 If optional argument FRAME is nil or omitted, use the selected frame."
 229   (check-face face)
 230   (get face 'face))
 231
 232
 233 (defun face-equal (face1 face2 &optional frame)
 234   "Non-nil if faces FACE1 and FACE2 are equal.
 235 Faces are considered equal if all their attributes are equal.
 236 If the optional argument FRAME is given, report on face FACE in that frame.
 237 If FRAME is t, report on the defaults for face FACE (for new frames).
 238 If FRAME is omitted or nil, use the selected frame."
 239   (internal-lisp-face-equal-p face1 face2 frame))
 240
 241
 242 (defun face-differs-from-default-p (face &optional frame)
 243   "Return non-nil if FACE displays differently from the default face.
 244 If the optional argument FRAME is given, report on face FACE in that frame.
 245 If FRAME is t, report on the defaults for face FACE (for new frames).
 246 If FRAME is omitted or nil, use the selected frame."
 247   (let ((attrs
 248          '(:family :width :height :weight :slant :foreground
 249            :foreground :background :underline :overline
 250            :strike-through :box :inverse-video))
 251         (differs nil))
 252     (while (and attrs (not differs))
 253       (let* ((attr (pop attrs))
 254              (attr-val (face-attribute face attr frame t)))
 255         (when (and
 256                (not (eq attr-val 'unspecified))
 257                (display-supports-face-attributes-p (list attr attr-val)
 258                                                    frame))
 259           (setq differs attr))))
 260     differs))
 261
 262
 263 (defun face-nontrivial-p (face &optional frame)
 264   "True if face FACE has some non-nil attribute.
 265 If the optional argument FRAME is given, report on face FACE in that frame.
 266 If FRAME is t, report on the defaults for face FACE (for new frames).
 267 If FRAME is omitted or nil, use the selected frame."
 268   (not (internal-lisp-face-empty-p face frame)))
 269
 270
 271 \f
 272 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 273 ;;; Setting face attributes from X resources.
 274 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 275
 276 (defcustom face-x-resources
 277   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 278     (:width (".attributeWidth" . "Face.AttributeWidth"))
 279     (:height (".attributeHeight" . "Face.AttributeHeight"))
 280     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 281     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 282     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 283     (:background (".attributeBackground" . "Face.AttributeBackground"))
 284     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 285     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 286     (:box (".attributeBox" . "Face.AttributeBox"))
 287     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 288     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 289     (:stipple
 290      (".attributeStipple" . "Face.AttributeStipple")
 291      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 292     (:bold (".attributeBold" . "Face.AttributeBold"))
 293     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 294     (:font (".attributeFont" . "Face.AttributeFont"))
 295     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 296   "*List of X resources and classes for face attributes.
 297 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 298 the name of a face attribute, and each ENTRY is a cons of the form
 299 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 300 X resource class for the attribute."
 301   :type '(repeat (cons symbol (repeat (cons string string))))
 302   :group 'faces)
 303
 304
 305 (defun set-face-attribute-from-resource (face attribute resource class frame)
 306   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 307 Value is the attribute value specified by the resource, or nil
 308 if not present.  This function displays a message if the resource
 309 specifies an invalid attribute."
 310   (let* ((face-name (face-name face))
 311          (value (internal-face-x-get-resource (concat face-name resource)
 312                                               class frame)))
 313     (when value
 314       (condition-case ()
 315           (internal-set-lisp-face-attribute-from-resource
 316            face attribute (downcase value) frame)
 317         (error
 318          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 319                   face-name frame attribute value))))
 320     value))
 321
 322
 323 (defun set-face-attributes-from-resources (face frame)
 324   "Set attributes of FACE from X resources for FRAME."
 325   (when (memq (framep frame) '(x w32 mac))
 326     (dolist (definition face-x-resources)
 327       (let ((attribute (car definition)))
 328         (dolist (entry (cdr definition))
 329           (set-face-attribute-from-resource face attribute (car entry)
 330                                             (cdr entry) frame))))))
 331
 332
 333 (defun make-face-x-resource-internal (face &optional frame)
 334   "Fill frame-local FACE on FRAME from X resources.
 335 FRAME nil or not specified means do it for all frames."
 336   (if (null frame)
 337       (dolist (frame (frame-list))
 338         (set-face-attributes-from-resources face frame))
 339     (set-face-attributes-from-resources face frame)))
 340
 341
 342 \f
 343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 344 ;;; Retrieving face attributes.
 345 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 346
 347 (defun face-name (face)
 348   "Return the name of face FACE."
 349   (symbol-name (check-face face)))
 350
 351
 352 (defun face-attribute (face attribute &optional frame inherit)
 353   "Return the value of FACE's ATTRIBUTE on FRAME.
 354 If the optional argument FRAME is given, report on face FACE in that frame.
 355 If FRAME is t, report on the defaults for face FACE (for new frames).
 356 If FRAME is omitted or nil, use the selected frame.
 357
 358 If INHERIT is nil, only attributes directly defined by FACE are considered,
 359   so the return value may be `unspecified', or a relative value.
 360 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 361   faces specified by its `:inherit' attribute; however the return value
 362   may still be `unspecified' or relative.
 363 If INHERIT is a face or a list of faces, then the result is further merged
 364   with that face (or faces), until it becomes specified and absolute.
 365
 366 To ensure that the return value is always specified and absolute, use a
 367 value of `default' for INHERIT; this will resolve any unspecified or
 368 relative values by merging with the `default' face (which is always
 369 completely specified)."
 370   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 371     (when (and inherit (face-attribute-relative-p attribute value))
 372       ;; VALUE is relative, so merge with inherited faces
 373       (let ((inh-from (face-attribute face :inherit frame)))
 374         (unless (or (null inh-from) (eq inh-from 'unspecified))
 375           (setq value
 376                 (face-attribute-merged-with attribute value inh-from frame)))))
 377     (when (and inherit
 378                (not (eq inherit t))
 379                (face-attribute-relative-p attribute value))
 380       ;; We should merge with INHERIT as well
 381       (setq value (face-attribute-merged-with attribute value inherit frame)))
 382     value))
 383
 384 (defun face-attribute-merged-with (attribute value faces &optional frame)
 385   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 386 FACES may be either a single face or a list of faces.
 387 \[This is an internal function]"
 388   (cond ((not (face-attribute-relative-p attribute value))
 389          value)
 390         ((null faces)
 391          value)
 392         ((consp faces)
 393          (face-attribute-merged-with
 394           attribute
 395           (face-attribute-merged-with attribute value (car faces) frame)
 396           (cdr faces)
 397           frame))
 398         (t
 399          (merge-face-attribute attribute
 400                                value
 401                                (face-attribute faces attribute frame t)))))
 402
 403
 404 (defmacro face-attribute-specified-or (value &rest body)
 405   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 406   (let ((temp (make-symbol "value")))
 407     `(let ((,temp ,value))
 408        (if (not (eq ,temp 'unspecified))
 409            ,temp
 410          ,@body))))
 411
 412 (defun face-foreground (face &optional frame inherit)
 413   "Return the foreground color name of FACE, or nil if unspecified.
 414 If the optional argument FRAME is given, report on face FACE in that frame.
 415 If FRAME is t, report on the defaults for face FACE (for new frames).
 416 If FRAME is omitted or nil, use the selected frame.
 417
 418 If INHERIT is nil, only a foreground color directly defined by FACE is
 419   considered, so the return value may be nil.
 420 If INHERIT is t, and FACE doesn't define a foreground color, then any
 421   foreground color that FACE inherits through its `:inherit' attribute
 422   is considered as well; however the return value may still be nil.
 423 If INHERIT is a face or a list of faces, then it is used to try to
 424   resolve an unspecified foreground color.
 425
 426 To ensure that a valid color is always returned, use a value of
 427 `default' for INHERIT; this will resolve any unspecified values by
 428 merging with the `default' face (which is always completely specified)."
 429   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 430                                nil))
 431
 432 (defun face-background (face &optional frame inherit)
 433   "Return the background color name of FACE, or nil if unspecified.
 434 If the optional argument FRAME is given, report on face FACE in that frame.
 435 If FRAME is t, report on the defaults for face FACE (for new frames).
 436 If FRAME is omitted or nil, use the selected frame.
 437
 438 If INHERIT is nil, only a background color directly defined by FACE is
 439   considered, so the return value may be nil.
 440 If INHERIT is t, and FACE doesn't define a background color, then any
 441   background color that FACE inherits through its `:inherit' attribute
 442   is considered as well; however the return value may still be nil.
 443 If INHERIT is a face or a list of faces, then it is used to try to
 444   resolve an unspecified background color.
 445
 446 To ensure that a valid color is always returned, use a value of
 447 `default' for INHERIT; this will resolve any unspecified values by
 448 merging with the `default' face (which is always completely specified)."
 449   (face-attribute-specified-or (face-attribute face :background frame inherit)
 450                                nil))
 451
 452 (defun face-stipple (face &optional frame inherit)
 453  "Return the stipple pixmap name of FACE, or nil if unspecified.
 454 If the optional argument FRAME is given, report on face FACE in that frame.
 455 If FRAME is t, report on the defaults for face FACE (for new frames).
 456 If FRAME is omitted or nil, use the selected frame.
 457
 458 If INHERIT is nil, only a stipple directly defined by FACE is
 459   considered, so the return value may be nil.
 460 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 461   that FACE inherits through its `:inherit' attribute is considered as
 462   well; however the return value may still be nil.
 463 If INHERIT is a face or a list of faces, then it is used to try to
 464   resolve an unspecified stipple.
 465
 466 To ensure that a valid stipple or nil is always returned, use a value of
 467 `default' for INHERIT; this will resolve any unspecified values by merging
 468 with the `default' face (which is always completely specified)."
 469   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 470                                nil))
 471
 472
 473 (defalias 'face-background-pixmap 'face-stipple)
 474
 475
 476 (defun face-underline-p (face &optional frame)
 477  "Return non-nil if FACE is underlined.
 478 If the optional argument FRAME is given, report on face FACE in that frame.
 479 If FRAME is t, report on the defaults for face FACE (for new frames).
 480 If FRAME is omitted or nil, use the selected frame."
 481  (eq (face-attribute face :underline frame) t))
 482
 483
 484 (defun face-inverse-video-p (face &optional frame)
 485  "Return non-nil if FACE is in inverse video on FRAME.
 486 If the optional argument FRAME is given, report on face FACE in that frame.
 487 If FRAME is t, report on the defaults for face FACE (for new frames).
 488 If FRAME is omitted or nil, use the selected frame."
 489  (eq (face-attribute face :inverse-video frame) t))
 490
 491
 492 (defun face-bold-p (face &optional frame)
 493   "Return non-nil if the font of FACE is bold on FRAME.
 494 If the optional argument FRAME is given, report on face FACE in that frame.
 495 If FRAME is t, report on the defaults for face FACE (for new frames).
 496 If FRAME is omitted or nil, use the selected frame.
 497 Use `face-attribute' for finer control."
 498   (let ((bold (face-attribute face :weight frame)))
 499     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 500
 501
 502 (defun face-italic-p (face &optional frame)
 503   "Return non-nil if the font of FACE is italic on FRAME.
 504 If the optional argument FRAME is given, report on face FACE in that frame.
 505 If FRAME is t, report on the defaults for face FACE (for new frames).
 506 If FRAME is omitted or nil, use the selected frame.
 507 Use `face-attribute' for finer control."
 508   (let ((italic (face-attribute face :slant frame)))
 509     (memq italic '(italic oblique))))
 510
 511
 512 \f
 513 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 514 ;;; Face documentation.
 515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 516
 517 (defun face-documentation (face)
 518   "Get the documentation string for FACE."
 519   (get face 'face-documentation))
 520
 521
 522 (defun set-face-documentation (face string)
 523   "Set the documentation string for FACE to STRING."
 524   ;; Perhaps the text should go in DOC.
 525   (put face 'face-documentation (purecopy string)))
 526
 527
 528 (defalias 'face-doc-string 'face-documentation)
 529 (defalias 'set-face-doc-string 'set-face-documentation)
 530
 531
 532 \f
 533 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 534 ;; Setting face attributes.
 535 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 536
 537
 538 (defun set-face-attribute (face frame &rest args)
 539   "Set attributes of FACE on FRAME from ARGS.
 540
 541 FRAME nil means change attributes on all frames.  FRAME t means change
 542 the default for new frames (this is done automatically each time an
 543 attribute is changed on all frames).
 544
 545 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 546 face attribute name.  All attributes can be set to `unspecified';
 547 this fact is not further mentioned below.
 548
 549 The following attributes are recognized:
 550
 551 `:family'
 552
 553 VALUE must be a string specifying the font family, e.g. ``courier'',
 554 or a fontset alias name.  If a font family is specified, wild-cards `*'
 555 and `?' are allowed.
 556
 557 `:width'
 558
 559 VALUE specifies the relative proportionate width of the font to use.
 560 It must be one of the symbols `ultra-condensed', `extra-condensed',
 561 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 562 `extra-expanded', or `ultra-expanded'.
 563
 564 `:height'
 565
 566 VALUE must be either an integer specifying the height of the font to use
 567 in 1/10 pt, a floating point number specifying the amount by which to
 568 scale any underlying face, or a function, which is called with the old
 569 height (from the underlying face), and should return the new height.
 570
 571 `:weight'
 572
 573 VALUE specifies the weight of the font to use.  It must be one of the
 574 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 575 `semi-light', `light', `extra-light', `ultra-light'.
 576
 577 `:slant'
 578
 579 VALUE specifies the slant of the font to use.  It must be one of the
 580 symbols `italic', `oblique', `normal', `reverse-italic', or
 581 `reverse-oblique'.
 582
 583 `:foreground', `:background'
 584
 585 VALUE must be a color name, a string.
 586
 587 `:underline'
 588
 589 VALUE specifies whether characters in FACE should be underlined.  If
 590 VALUE is t, underline with foreground color of the face.  If VALUE is
 591 a string, underline with that color.  If VALUE is nil, explicitly
 592 don't underline.
 593
 594 `:overline'
 595
 596 VALUE specifies whether characters in FACE should be overlined.  If
 597 VALUE is t, overline with foreground color of the face.  If VALUE is a
 598 string, overline with that color.  If VALUE is nil, explicitly don't
 599 overline.
 600
 601 `:strike-through'
 602
 603 VALUE specifies whether characters in FACE should be drawn with a line
 604 striking through them.  If VALUE is t, use the foreground color of the
 605 face.  If VALUE is a string, strike-through with that color.  If VALUE
 606 is nil, explicitly don't strike through.
 607
 608 `:box'
 609
 610 VALUE specifies whether characters in FACE should have a box drawn
 611 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 612 VALUE is t, draw a box with lines of width 1 in the foreground color
 613 of the face.  If VALUE is a string, the string must be a color name,
 614 and the box is drawn in that color with a line width of 1.  Otherwise,
 615 VALUE must be a property list of the form `(:line-width WIDTH
 616 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 617 the property list, a default value will be used for the value, as
 618 specified below.  WIDTH specifies the width of the lines to draw; it
 619 defaults to 1.  If WIDTH is negative, the absolute value is the width
 620 of the lines, and draw top/bottom lines inside the characters area,
 621 not around it.  COLOR is the name of the color to draw in, default is
 622 the foreground color of the face for simple boxes, and the background
 623 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 624 should be draw.  If STYLE is `released-button', draw a box looking
 625 like a released 3D button.  If STYLE is `pressed-button' draw a box
 626 that appears like a pressed button.  If STYLE is nil, the default if
 627 the property list doesn't contain a style specification, draw a 2D
 628 box.
 629
 630 `:inverse-video'
 631
 632 VALUE specifies whether characters in FACE should be displayed in
 633 inverse video.  VALUE must be one of t or nil.
 634
 635 `:stipple'
 636
 637 If VALUE is a string, it must be the name of a file of pixmap data.
 638 The directories listed in the `x-bitmap-file-path' variable are
 639 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 640 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 641 is a string containing the raw bits of the bitmap.  VALUE nil means
 642 explicitly don't use a stipple pattern.
 643
 644 For convenience, attributes `:family', `:width', `:height', `:weight',
 645 and `:slant' may also be set in one step from an X font name:
 646
 647 `:font'
 648
 649 Set font-related face attributes from VALUE.  VALUE must be a valid
 650 XLFD font name.  If it is a font name pattern, the first matching font
 651 will be used.
 652
 653 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 654 be used to specify that a bold or italic font should be used.  VALUE
 655 must be t or nil in that case.  A value of `unspecified' is not allowed.
 656
 657 `:inherit'
 658
 659 VALUE is the name of a face from which to inherit attributes, or a list
 660 of face names.  Attributes from inherited faces are merged into the face
 661 like an underlying face would be, with higher priority than underlying faces."
 662   (let ((where (if (null frame) 0 frame)))
 663     (setq args (purecopy args))
 664     ;; If we set the new-frame defaults, this face is modified outside Custom.
 665     (if (memq where '(0 t))
 666         (put face 'face-modified t))
 667     (while args
 668       (internal-set-lisp-face-attribute face (car args)
 669                                         (purecopy (cadr args))
 670                                         where)
 671       (setq args (cdr (cdr args))))))
 672
 673
 674 (defun make-face-bold (face &optional frame noerror)
 675   "Make the font of FACE be bold, if possible.
 676 FRAME nil or not specified means change face on all frames.
 677 Argument NOERROR is ignored and retained for compatibility.
 678 Use `set-face-attribute' for finer control of the font weight."
 679   (interactive (list (read-face-name "Make which face bold")))
 680   (set-face-attribute face frame :weight 'bold))
 681
 682
 683 (defun make-face-unbold (face &optional frame noerror)
 684   "Make the font of FACE be non-bold, if possible.
 685 FRAME nil or not specified means change face on all frames.
 686 Argument NOERROR is ignored and retained for compatibility."
 687   (interactive (list (read-face-name "Make which face non-bold")))
 688   (set-face-attribute face frame :weight 'normal))
 689
 690
 691 (defun make-face-italic (face &optional frame noerror)
 692   "Make the font of FACE be italic, if possible.
 693 FRAME nil or not specified means change face on all frames.
 694 Argument NOERROR is ignored and retained for compatibility.
 695 Use `set-face-attribute' for finer control of the font slant."
 696   (interactive (list (read-face-name "Make which face italic")))
 697   (set-face-attribute face frame :slant 'italic))
 698
 699
 700 (defun make-face-unitalic (face &optional frame noerror)
 701   "Make the font of FACE be non-italic, if possible.
 702 FRAME nil or not specified means change face on all frames.
 703 Argument NOERROR is ignored and retained for compatibility."
 704   (interactive (list (read-face-name "Make which face non-italic")))
 705   (set-face-attribute face frame :slant 'normal))
 706
 707
 708 (defun make-face-bold-italic (face &optional frame noerror)
 709   "Make the font of FACE be bold and italic, if possible.
 710 FRAME nil or not specified means change face on all frames.
 711 Argument NOERROR is ignored and retained for compatibility.
 712 Use `set-face-attribute' for finer control of font weight and slant."
 713   (interactive (list (read-face-name "Make which face bold-italic")))
 714   (set-face-attribute face frame :weight 'bold :slant 'italic))
 715
 716
 717 (defun set-face-font (face font &optional frame)
 718   "Change font-related attributes of FACE to those of FONT (a string).
 719 FRAME nil or not specified means change face on all frames.
 720 This sets the attributes `:family', `:width', `:height', `:weight',
 721 and `:slant'.  When called interactively, prompt for the face and font."
 722   (interactive (read-face-and-attribute :font))
 723   (set-face-attribute face frame :font font))
 724
 725
 726 ;; Implementation note: Emulating gray background colors with a
 727 ;; stipple pattern is now part of the face realization process, and is
 728 ;; done in C depending on the frame on which the face is realized.
 729
 730 (defun set-face-background (face color &optional frame)
 731   "Change the background color of face FACE to COLOR (a string).
 732 FRAME nil or not specified means change face on all frames.
 733 COLOR can be a system-defined color name (see `list-colors-display')
 734 or a hex spec of the form #RRGGBB.
 735 When called interactively, prompts for the face and color."
 736   (interactive (read-face-and-attribute :background))
 737   (set-face-attribute face frame :background (or color 'unspecified)))
 738
 739
 740 (defun set-face-foreground (face color &optional frame)
 741   "Change the foreground color of face FACE to COLOR (a string).
 742 FRAME nil or not specified means change face on all frames.
 743 COLOR can be a system-defined color name (see `list-colors-display')
 744 or a hex spec of the form #RRGGBB.
 745 When called interactively, prompts for the face and color."
 746   (interactive (read-face-and-attribute :foreground))
 747   (set-face-attribute face frame :foreground (or color 'unspecified)))
 748
 749
 750 (defun set-face-stipple (face stipple &optional frame)
 751   "Change the stipple pixmap of face FACE to STIPPLE.
 752 FRAME nil or not specified means change face on all frames.
 753 STIPPLE should be a string, the name of a file of pixmap data.
 754 The directories listed in the `x-bitmap-file-path' variable are searched.
 755
 756 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 757 where WIDTH and HEIGHT are the size in pixels,
 758 and DATA is a string, containing the raw bits of the bitmap."
 759   (interactive (read-face-and-attribute :stipple))
 760   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 761
 762
 763 (defun set-face-underline (face underline &optional frame)
 764   "Specify whether face FACE is underlined.
 765 UNDERLINE nil means FACE explicitly doesn't underline.
 766 UNDERLINE non-nil means FACE explicitly does underlining
 767 with the same of the foreground color.
 768 If UNDERLINE is a string, underline with the color named UNDERLINE.
 769 FRAME nil or not specified means change face on all frames.
 770 Use `set-face-attribute' to ``unspecify'' underlining."
 771   (interactive
 772    (let ((list (read-face-and-attribute :underline)))
 773      (list (car list) (eq (car (cdr list)) t))))
 774   (set-face-attribute face frame :underline underline))
 775
 776
 777 (defun set-face-underline-p (face underline-p &optional frame)
 778   "Specify whether face FACE is underlined.
 779 UNDERLINE-P nil means FACE explicitly doesn't underline.
 780 UNDERLINE-P non-nil means FACE explicitly does underlining.
 781 FRAME nil or not specified means change face on all frames.
 782 Use `set-face-attribute' to ``unspecify'' underlining."
 783   (interactive
 784    (let ((list (read-face-and-attribute :underline)))
 785      (list (car list) (eq (car (cdr list)) t))))
 786   (set-face-attribute face frame :underline underline-p))
 787
 788
 789 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 790   "Specify whether face FACE is in inverse video.
 791 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 792 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 793 FRAME nil or not specified means change face on all frames.
 794 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 795   (interactive
 796    (let ((list (read-face-and-attribute :inverse-video)))
 797      (list (car list) (eq (car (cdr list)) t))))
 798   (set-face-attribute face frame :inverse-video inverse-video-p))
 799
 800
 801 (defun set-face-bold-p (face bold-p &optional frame)
 802   "Specify whether face FACE is bold.
 803 BOLD-P non-nil means FACE should explicitly display bold.
 804 BOLD-P nil means FACE should explicitly display non-bold.
 805 FRAME nil or not specified means change face on all frames.
 806 Use `set-face-attribute' or `modify-face' for finer control."
 807   (if (null bold-p)
 808       (make-face-unbold face frame)
 809     (make-face-bold face frame)))
 810
 811
 812 (defun set-face-italic-p (face italic-p &optional frame)
 813   "Specify whether face FACE is italic.
 814 ITALIC-P non-nil means FACE should explicitly display italic.
 815 ITALIC-P nil means FACE should explicitly display non-italic.
 816 FRAME nil or not specified means change face on all frames.
 817 Use `set-face-attribute' or `modify-face' for finer control."
 818   (if (null italic-p)
 819       (make-face-unitalic face frame)
 820     (make-face-italic face frame)))
 821
 822
 823 (defalias 'set-face-background-pixmap 'set-face-stipple)
 824
 825
 826 (defun invert-face (face &optional frame)
 827   "Swap the foreground and background colors of FACE.
 828 If FRAME is omitted or nil, it means change face on all frames.
 829 If FACE specifies neither foreground nor background color,
 830 set its foreground and background to the background and foreground
 831 of the default face.  Value is FACE."
 832   (interactive (list (read-face-name "Invert face")))
 833   (let ((fg (face-attribute face :foreground frame))
 834         (bg (face-attribute face :background frame)))
 835     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 836         (set-face-attribute face frame :foreground bg :background fg)
 837       (set-face-attribute face frame
 838                           :foreground
 839                           (face-attribute 'default :background frame)
 840                           :background
 841                           (face-attribute 'default :foreground frame))))
 842   face)
 843
 844 \f
 845 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 846 ;;; Interactively modifying faces.
 847 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 848
 849 (defun read-face-name (prompt &optional string-describing-default multiple)
 850   "Read a face, defaulting to the face or faces on the char after point.
 851 If it has a `read-face-name' property, that overrides the `face' property.
 852 PROMPT describes what you will do with the face (don't end in a space).
 853 STRING-DESCRIBING-DEFAULT describes what default you will use
 854 if this function returns nil.
 855 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 856 Otherwise, return a single face."
 857   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 858                       (get-char-property (point) 'face)))
 859         faces)
 860     ;; Make a list of the named faces that the `face' property uses.
 861     (if (and (listp faceprop)
 862              ;; Don't treat an attribute spec as a list of faces.
 863              (not (keywordp (car faceprop)))
 864              (not (memq (car faceprop) '(foreground-color background-color))))
 865         (dolist (f faceprop)
 866           (if (symbolp f)
 867               (push f faces)))
 868       (if (symbolp faceprop)
 869           (push faceprop faces)))
 870     ;; If there are none, try to get a face name from the buffer.
 871     (if (and (null faces)
 872              (memq (intern-soft (thing-at-point 'symbol)) (face-list)))
 873         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 874
 875     ;; If we only want one, and the default is more than one,
 876     ;; discard the unwanted ones now.
 877     (unless multiple
 878       (if faces
 879           (setq faces (list (car faces)))))
 880     (let* ((input
 881             ;; Read the input.
 882             (completing-read
 883              (if (or faces string-describing-default)
 884                  (format "%s (default %s): " prompt
 885                          (if faces (mapconcat 'symbol-name faces ", ")
 886                            string-describing-default))
 887                (format "%s: " prompt))
 888              obarray 'custom-facep t))
 889            ;; Canonicalize the output.
 890            (output
 891             (if (equal input "")
 892                 faces
 893               (if (stringp input)
 894                   (list (intern input))
 895                 input))))
 896       ;; Return either a list of faces or just one face.
 897       (if multiple
 898           output
 899         (car output)))))
 900
 901
 902 (defun face-valid-attribute-values (attribute &optional frame)
 903   "Return valid values for face attribute ATTRIBUTE.
 904 The optional argument FRAME is used to determine available fonts
 905 and colors.  If it is nil or not specified, the selected frame is
 906 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 907 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 908 an integer value."
 909   (let ((valid
 910          (case attribute
 911            (:family
 912             (if window-system
 913                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 914                         (x-font-family-list))
 915               ;; Only one font on TTYs.
 916               (list (cons "default" "default"))))
 917            ((:width :weight :slant :inverse-video)
 918             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 919                     (internal-lisp-face-attribute-values attribute)))
 920            ((:underline :overline :strike-through :box)
 921             (if window-system
 922                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 923                                (internal-lisp-face-attribute-values attribute))
 924                        (mapcar #'(lambda (c) (cons c c))
 925                                (x-defined-colors frame)))
 926               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 927                       (internal-lisp-face-attribute-values attribute))))
 928            ((:foreground :background)
 929             (mapcar #'(lambda (c) (cons c c))
 930                     (defined-colors frame)))
 931            ((:height)
 932             'integerp)
 933            (:stipple
 934             (and (memq window-system '(x w32 mac))
 935                  (mapcar #'list
 936                          (apply #'nconc
 937                                 (mapcar (lambda (dir)
 938                                           (and (file-readable-p dir)
 939                                                (file-directory-p dir)
 940                                                (directory-files dir)))
 941                                         x-bitmap-file-path)))))
 942            (:inherit
 943             (cons '("none" . nil)
 944                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 945                           (face-list))))
 946            (t
 947             (error "Internal error")))))
 948     (if (and (listp valid) (not (memq attribute '(:inherit))))
 949         (nconc (list (cons "unspecified" 'unspecified)) valid)
 950       valid)))
 951
 952
 953 (defvar face-attribute-name-alist
 954   '((:family . "font family")
 955     (:width . "character set width")
 956     (:height . "height in 1/10 pt")
 957     (:weight . "weight")
 958     (:slant . "slant")
 959     (:underline . "underline")
 960     (:overline . "overline")
 961     (:strike-through . "strike-through")
 962     (:box . "box")
 963     (:inverse-video . "inverse-video display")
 964     (:foreground . "foreground color")
 965     (:background . "background color")
 966     (:stipple . "background stipple")
 967     (:inherit . "inheritance"))
 968   "An alist of descriptive names for face attributes.
 969 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 970 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 971 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 972
 973
 974 (defun face-descriptive-attribute-name (attribute)
 975   "Return a descriptive name for ATTRIBUTE."
 976   (cdr (assq attribute face-attribute-name-alist)))
 977
 978
 979 (defun face-read-string (face default name &optional completion-alist)
 980   "Interactively read a face attribute string value.
 981 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 982 default string to return if no new value is entered.  NAME is a
 983 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 984 alist of valid values, if non-nil.
 985
 986 Entering nothing accepts the default string DEFAULT.
 987 Value is the new attribute value."
 988   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 989   ;; each word in a string separately).
 990   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 991   (let* ((completion-ignore-case t)
 992          (value (completing-read
 993                  (if default
 994                      (format "%s for face `%s' (default %s): "
 995                              name face default)
 996                    (format "%s for face `%s': " name face))
 997                  completion-alist)))
 998     (if (equal value "") default value)))
 999
1000
1001 (defun face-read-integer (face default name)
1002   "Interactively read an integer face attribute value.
1003 FACE is the face whose attribute is read.  DEFAULT is the default
1004 value to return if no new value is entered.  NAME is a descriptive
1005 name of the attribute for prompting.  Value is the new attribute value."
1006   (let ((new-value
1007          (face-read-string face
1008                            (format "%s" default)
1009                            name
1010                            (list (cons "unspecified" 'unspecified)))))
1011     (cond ((equal new-value "unspecified")
1012            'unspecified)
1013           ((member new-value '("unspecified-fg" "unspecified-bg"))
1014            new-value)
1015           (t
1016            (string-to-int new-value)))))
1017
1018
1019 (defun read-face-attribute (face attribute &optional frame)
1020   "Interactively read a new value for FACE's ATTRIBUTE.
1021 Optional argument FRAME nil or unspecified means read an attribute value
1022 of a global face.  Value is the new attribute value."
1023   (let* ((old-value (face-attribute face attribute frame))
1024          (attribute-name (face-descriptive-attribute-name attribute))
1025          (valid (face-valid-attribute-values attribute frame))
1026          new-value)
1027     ;; Represent complex attribute values as strings by printing them
1028     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1029     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1030     ;; SHADOW)'.
1031     (when (and (or (eq attribute :stipple)
1032                    (eq attribute :box))
1033                (or (consp old-value)
1034                    (vectorp old-value)))
1035       (setq old-value (prin1-to-string old-value)))
1036     (cond ((listp valid)
1037            (let ((default
1038                    (or (car (rassoc old-value valid))
1039                        (format "%s" old-value))))
1040              (setq new-value
1041                    (face-read-string face default attribute-name valid))
1042              (if (equal new-value default)
1043                  ;; Nothing changed, so don't bother with all the stuff
1044                  ;; below.  In particular, this avoids a non-tty color
1045                  ;; from being canonicalized for a tty when the user
1046                  ;; just uses the default.
1047                  (setq new-value old-value)
1048                ;; Terminal frames can support colors that don't appear
1049                ;; explicitly in VALID, using color approximation code
1050                ;; in tty-colors.el.
1051                (when (and (memq attribute '(:foreground :background))
1052                           (not (memq window-system '(x w32 mac)))
1053                           (not (member new-value
1054                                        '("unspecified"
1055                                          "unspecified-fg" "unspecified-bg"))))
1056                  (setq new-value (car (tty-color-desc new-value frame))))
1057                (when (assoc new-value valid)
1058                  (setq new-value (cdr (assoc new-value valid)))))))
1059           ((eq valid 'integerp)
1060            (setq new-value (face-read-integer face old-value attribute-name)))
1061           (t (error "Internal error")))
1062     ;; Convert stipple and box value text we read back to a list or
1063     ;; vector if it looks like one.  This makes the assumption that a
1064     ;; pixmap file name won't start with an open-paren.
1065     (when (and (or (eq attribute :stipple)
1066                    (eq attribute :box))
1067                (stringp new-value)
1068                (string-match "^[[(]" new-value))
1069       (setq new-value (read new-value)))
1070     new-value))
1071
1072
1073 (defun read-face-font (face &optional frame)
1074   "Read the name of a font for FACE on FRAME.
1075 If optional argument FRAME Is nil or omitted, use the selected frame."
1076   (let ((completion-ignore-case t))
1077     (completing-read (format "Set font attributes of face `%s' from font: " face)
1078                      (x-list-fonts "*" nil frame))))
1079
1080
1081 (defun read-all-face-attributes (face &optional frame)
1082   "Interactively read all attributes for FACE.
1083 If optional argument FRAME Is nil or omitted, use the selected frame.
1084 Value is a property list of attribute names and new values."
1085   (let (result)
1086     (dolist (attribute face-attribute-name-alist result)
1087       (setq result (cons (car attribute)
1088                          (cons (read-face-attribute face (car attribute) frame)
1089                                result))))))
1090
1091 (defun modify-face (&optional face foreground background stipple
1092                               bold-p italic-p underline-p inverse-p frame)
1093   "Modify attributes of faces interactively.
1094 If optional argument FRAME is nil or omitted, modify the face used
1095 for newly created frame, i.e. the global face.
1096 For non-interactive use, `set-face-attribute' is preferred.
1097 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1098 and the face and its settings are obtained by querying the user."
1099   (interactive)
1100   (if face
1101       (set-face-attribute face frame
1102                           :foreground (or foreground 'unspecified)
1103                           :background (or background 'unspecified)
1104                           :stipple stipple
1105                           :bold bold-p
1106                           :italic italic-p
1107                           :underline underline-p
1108                           :inverse-video inverse-p)
1109     (setq face (read-face-name "Modify face"))
1110     (apply #'set-face-attribute face frame
1111            (read-all-face-attributes face frame))))
1112
1113 (defun read-face-and-attribute (attribute &optional frame)
1114   "Read face name and face attribute value.
1115 ATTRIBUTE is the attribute whose new value is read.
1116 FRAME nil or unspecified means read attribute value of global face.
1117 Value is a list (FACE NEW-VALUE) where FACE is the face read
1118 \(a symbol), and NEW-VALUE is value read."
1119   (cond ((eq attribute :font)
1120          (let* ((prompt "Set font-related attributes of face")
1121                 (face (read-face-name prompt))
1122                 (font (read-face-font face frame)))
1123            (list face font)))
1124         (t
1125          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1126                 (prompt (format "Set %s of face" attribute-name))
1127                 (face (read-face-name prompt))
1128                 (new-value (read-face-attribute face attribute frame)))
1129            (list face new-value)))))
1130
1131
1132 \f
1133 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1134 ;;; Listing faces.
1135 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1136
1137 (defvar list-faces-sample-text
1138   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1139   "*Text string to display as the sample text for `list-faces-display'.")
1140
1141
1142 ;; The name list-faces would be more consistent, but let's avoid a
1143 ;; conflict with Lucid, which uses that name differently.
1144
1145 (defvar help-xref-stack)
1146 (defun list-faces-display (&optional regexp)
1147   "List all faces, using the same sample text in each.
1148 The sample text is a string that comes from the variable
1149 `list-faces-sample-text'.
1150
1151 If REGEXP is non-nil, list only those faces with names matching
1152 this regular expression.  When called interactively with a prefix
1153 arg, prompt for a regular expression."
1154   (interactive (list (and current-prefix-arg
1155                           (read-string "List faces matching regexp: "))))
1156   (let ((faces (sort (face-list) #'string-lessp))
1157         (frame (selected-frame))
1158         disp-frame window face-name)
1159     (when (> (length regexp) 0)
1160       (setq faces
1161             (delq nil
1162                   (mapcar (lambda (f)
1163                             (when (string-match regexp (symbol-name f))
1164                               f))
1165                           faces))))
1166     (with-output-to-temp-buffer "*Faces*"
1167       (save-excursion
1168         (set-buffer standard-output)
1169         (setq truncate-lines t)
1170         (insert
1171          (substitute-command-keys
1172           (concat
1173            "Use "
1174            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1175            "\\[help-follow] on a face name to customize it\n"
1176            "or on its sample text for a description of the face.\n\n")))
1177         (setq help-xref-stack nil)
1178         (dolist (face faces)
1179           (setq face-name (symbol-name face))
1180           (insert (format "%25s " face-name))
1181           ;; Hyperlink to a customization buffer for the face.  Using
1182           ;; the help xref mechanism may not be the best way.
1183           (save-excursion
1184             (save-match-data
1185               (search-backward face-name)
1186               (help-xref-button 0 'help-customize-face face)))
1187           (let ((beg (point))
1188                 (line-beg (line-beginning-position)))
1189             (insert list-faces-sample-text)
1190             ;; Hyperlink to a help buffer for the face.
1191             (save-excursion
1192               (save-match-data
1193                 (search-backward list-faces-sample-text)
1194                 (help-xref-button 0 'help-face face)))
1195             (insert "\n")
1196             (put-text-property beg (1- (point)) 'face face)
1197             ;; Make all face commands default to the proper face
1198             ;; anywhere in the line.
1199             (put-text-property line-beg (1- (point)) 'read-face-name face)
1200             ;; If the sample text has multiple lines, line up all of them.
1201             (goto-char beg)
1202             (forward-line 1)
1203             (while (not (eobp))
1204               (insert "                          ")
1205               (forward-line 1))))
1206         (goto-char (point-min)))
1207       (print-help-return-message))
1208     ;; If the *Faces* buffer appears in a different frame,
1209     ;; copy all the face definitions from FRAME,
1210     ;; so that the display will reflect the frame that was selected.
1211     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1212     (setq disp-frame (if window (window-frame window)
1213                        (car (frame-list))))
1214     (or (eq frame disp-frame)
1215         (let ((faces (face-list)))
1216           (while faces
1217             (copy-face (car faces) (car faces) frame disp-frame)
1218             (setq faces (cdr faces)))))))
1219
1220
1221 (defun describe-face (face &optional frame)
1222   "Display the properties of face FACE on FRAME.
1223 Interactively, FACE defaults to the faces of the character after point
1224 and FRAME defaults to the selected frame.
1225
1226 If the optional argument FRAME is given, report on face FACE in that frame.
1227 If FRAME is t, report on the defaults for face FACE (for new frames).
1228 If FRAME is omitted or nil, use the selected frame."
1229   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1230   (let* ((attrs '((:family . "Family")
1231                   (:width . "Width")
1232                   (:height . "Height")
1233                   (:weight . "Weight")
1234                   (:slant . "Slant")
1235                   (:foreground . "Foreground")
1236                   (:background . "Background")
1237                   (:underline . "Underline")
1238                   (:overline . "Overline")
1239                   (:strike-through . "Strike-through")
1240                   (:box . "Box")
1241                   (:inverse-video . "Inverse")
1242                   (:stipple . "Stipple")
1243                   (:font . "Font or fontset")
1244                   (:inherit . "Inherit")))
1245         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1246                                         attrs))))
1247     (help-setup-xref (list #'describe-face face) (interactive-p))
1248     (unless face
1249       (setq face 'default))
1250     (if (not (listp face))
1251         (setq face (list face)))
1252     (with-output-to-temp-buffer (help-buffer)
1253       (save-excursion
1254         (set-buffer standard-output)
1255         (dolist (f face)
1256           (insert "Face: " (symbol-name f))
1257           (if (not (facep f))
1258               (insert "   undefined face.\n")
1259             (let ((customize-label "customize this face"))
1260               (princ (concat " (" customize-label ")\n"))
1261               (insert "Documentation: "
1262                       (or (face-documentation f)
1263                           "Not documented as a face.")
1264                       "\n\n")
1265               (with-current-buffer standard-output
1266                 (save-excursion
1267                   (re-search-backward
1268                    (concat "\\(" customize-label "\\)") nil t)
1269                   (help-xref-button 1 'help-customize-face f)))
1270               (dolist (a attrs)
1271                 (let ((attr (face-attribute f (car a) frame)))
1272                   (insert (make-string (- max-width (length (cdr a))) ?\ )
1273                           (cdr a) ": " (format "%s" attr) "\n")))))
1274           (terpri)))
1275       (print-help-return-message))))
1276
1277 \f
1278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1279 ;;; Face specifications (defface).
1280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1281
1282 ;; Parameter FRAME Is kept for call compatibility to with previous
1283 ;; face implementation.
1284
1285 (defun face-attr-construct (face &optional frame)
1286   "Return a defface-style attribute list for FACE on FRAME.
1287 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1288 face attributes of FACE where ATTRIBUTE is the attribute name and
1289 VALUE is the specified value of that attribute."
1290   (let (result)
1291     (dolist (entry face-attribute-name-alist result)
1292       (let* ((attribute (car entry))
1293              (value (face-attribute face attribute)))
1294         (unless (eq value 'unspecified)
1295           (setq result (nconc (list attribute value) result)))))))
1296
1297
1298 (defun face-spec-set-match-display (display frame)
1299   "Non-nil if DISPLAY matches FRAME.
1300 DISPLAY is part of a spec such as can be used in `defface'.
1301 If FRAME is nil, the current FRAME is used."
1302   (let* ((conjuncts display)
1303          conjunct req options
1304          ;; t means we have succeeded against all the conjuncts in
1305          ;; DISPLAY that have been tested so far.
1306          (match t))
1307     (if (eq conjuncts t)
1308         (setq conjuncts nil))
1309     (while (and conjuncts match)
1310       (setq conjunct (car conjuncts)
1311             conjuncts (cdr conjuncts)
1312             req (car conjunct)
1313             options (cdr conjunct)
1314             match (cond ((eq req 'type)
1315                          (or (memq window-system options)
1316                              ;; FIXME: This should be revisited to use
1317                              ;; display-graphic-p, provided that the
1318                              ;; color selection depends on the number
1319                              ;; of supported colors, and all defface's
1320                              ;; are changed to look at number of colors
1321                              ;; instead of (type graphic) etc.
1322                              (and (null window-system)
1323                                   (memq 'tty options))
1324                              (and (memq 'motif options)
1325                                   (featurep 'motif))
1326                              (and (memq 'gtk options)
1327                                   (featurep 'gtk))
1328                              (and (memq 'lucid options)
1329                                   (featurep 'x-toolkit)
1330                                   (not (featurep 'motif))
1331                                   (not (featurep 'gtk)))
1332                              (and (memq 'x-toolkit options)
1333                                   (featurep 'x-toolkit))))
1334                         ((eq req 'min-colors)
1335                          (>= (display-color-cells frame) (car options)))
1336                         ((eq req 'class)
1337                          (memq (frame-parameter frame 'display-type) options))
1338                         ((eq req 'background)
1339                          (memq (frame-parameter frame 'background-mode)
1340                                options))
1341                         ((eq req 'supports)
1342                          (display-supports-face-attributes-p options frame))
1343                         (t (error "Unknown req `%S' with options `%S'"
1344                                   req options)))))
1345     match))
1346
1347
1348 (defun face-spec-choose (spec &optional frame)
1349   "Choose the proper attributes for FRAME, out of SPEC.
1350 If SPEC is nil, return nil."
1351   (unless frame
1352     (setq frame (selected-frame)))
1353   (let ((tail spec)
1354         result defaults)
1355     (while tail
1356       (let* ((entry (pop tail))
1357              (display (car entry))
1358              (attrs (cdr entry))
1359              thisval)
1360         ;; Get the attributes as actually specified by this alternative.
1361         (setq thisval
1362               (if (null (cdr attrs)) ;; was (listp (car attrs))
1363                   ;; Old-style entry, the attribute list is the
1364                   ;; first element.
1365                   (car attrs)
1366                 attrs))
1367
1368         ;; If the condition is `default', that sets the default
1369         ;; for following conditions.
1370         (if (eq display 'default)
1371             (setq defaults thisval)
1372           ;; Otherwise, if it matches, use it.
1373           (when (face-spec-set-match-display display frame)
1374             (setq result thisval)
1375             (setq tail nil)))))
1376     (if defaults (append result defaults) result)))
1377
1378
1379 (defun face-spec-reset-face (face &optional frame)
1380   "Reset all attributes of FACE on FRAME to unspecified."
1381   (let ((attrs face-attribute-name-alist))
1382     (while attrs
1383       (let ((attr-and-name (car attrs)))
1384         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1385       (setq attrs (cdr attrs)))))
1386
1387
1388 (defun face-spec-set (face spec &optional frame)
1389   "Set FACE's attributes according to the first matching entry in SPEC.
1390 FRAME is the frame whose frame-local face is set.  FRAME nil means
1391 do it on all frames.  See `defface' for information about SPEC.
1392 If SPEC is nil, do nothing."
1393   (let ((attrs (face-spec-choose spec frame)))
1394     (when attrs
1395       (face-spec-reset-face face frame))
1396     (while attrs
1397       (let ((attribute (car attrs))
1398             (value (car (cdr attrs))))
1399         ;; Support some old-style attribute names and values.
1400         (case attribute
1401           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1402           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1403           ((:foreground :background)
1404            ;; Compatibility with 20.x.  Some bogus face specs seem to
1405            ;; exist containing things like `:foreground nil'.
1406            (if (null value) (setq value 'unspecified)))
1407           (t (unless (assq attribute face-x-resources)
1408                (setq attribute nil))))
1409         (when attribute
1410           (set-face-attribute face frame attribute value)))
1411       (setq attrs (cdr (cdr attrs)))))
1412   ;; When we reset the face based on its spec, then it is unmodified
1413   ;; as far as Custom is concerned.
1414   (if (null frame)
1415       (put face 'face-modified nil)))
1416
1417
1418 (defun face-attr-match-p (face attrs &optional frame)
1419   "Return t if attributes of FACE match values in plist ATTRS.
1420 Optional parameter FRAME is the frame whose definition of FACE
1421 is used.  If nil or omitted, use the selected frame."
1422   (unless frame
1423     (setq frame (selected-frame)))
1424   (let ((list face-attribute-name-alist)
1425         (match t))
1426     (while (and match (not (null list)))
1427       (let* ((attr (car (car list)))
1428              (specified-value
1429               (if (plist-member attrs attr)
1430                   (plist-get attrs attr)
1431                 'unspecified))
1432              (value-now (face-attribute face attr frame)))
1433         (setq match (equal specified-value value-now))
1434         (setq list (cdr list))))
1435     match))
1436
1437 (defun face-spec-match-p (face spec &optional frame)
1438   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1439   (face-attr-match-p face (face-spec-choose spec frame) frame))
1440
1441 (defsubst face-default-spec (face)
1442   "Return the default face-spec for FACE, ignoring any user customization.
1443 If there is no default for FACE, return nil."
1444   (get face 'face-defface-spec))
1445
1446 (defsubst face-user-default-spec (face)
1447   "Return the user's customized face-spec for FACE, or the default if none.
1448 If there is neither a user setting nor a default for FACE, return nil."
1449   (or (get face 'saved-face)
1450       (face-default-spec face)))
1451
1452 \f
1453 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1454 ;;; Frame-type independent color support.
1455 ;;; We keep the old x-* names as aliases for back-compatibility.
1456 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1457
1458 (defun defined-colors (&optional frame)
1459   "Return a list of colors supported for a particular frame.
1460 The argument FRAME specifies which frame to try.
1461 The value may be different for frames on different display types.
1462 If FRAME doesn't support colors, the value is nil."
1463   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1464       (xw-defined-colors frame)
1465     (mapcar 'car (tty-color-alist frame))))
1466 (defalias 'x-defined-colors 'defined-colors)
1467
1468 (defun color-defined-p (color &optional frame)
1469   "Return non-nil if color COLOR is supported on frame FRAME.
1470 If FRAME is omitted or nil, use the selected frame.
1471 If COLOR is the symbol `unspecified' or one of the strings
1472 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1473   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1474       nil
1475     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1476         (xw-color-defined-p color frame)
1477       (numberp (tty-color-translate color frame)))))
1478 (defalias 'x-color-defined-p 'color-defined-p)
1479
1480 (defun color-values (color &optional frame)
1481   "Return a description of the color named COLOR on frame FRAME.
1482 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1483 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1484 If FRAME is omitted or nil, use the selected frame.
1485 If FRAME cannot display COLOR, the value is nil.
1486 If COLOR is the symbol `unspecified' or one of the strings
1487 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1488   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1489       nil
1490     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1491         (xw-color-values color frame)
1492       (tty-color-values color frame))))
1493 (defalias 'x-color-values 'color-values)
1494
1495 (defun display-color-p (&optional display)
1496   "Return t if DISPLAY supports color.
1497 The optional argument DISPLAY specifies which display to ask about.
1498 DISPLAY should be either a frame or a display name (a string).
1499 If omitted or nil, that stands for the selected frame's display."
1500   (if (memq (framep-on-display display) '(x w32 mac))
1501       (xw-display-color-p display)
1502     (tty-display-color-p display)))
1503 (defalias 'x-display-color-p 'display-color-p)
1504
1505 (defun display-grayscale-p (&optional display)
1506   "Return non-nil if frames on DISPLAY can display shades of gray."
1507   (let ((frame-type (framep-on-display display)))
1508     (cond
1509      ((memq frame-type '(x w32 mac))
1510       (x-display-grayscale-p display))
1511      (t
1512       (> (tty-color-gray-shades display) 2)))))
1513
1514 \f
1515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1516 ;;; Background mode.
1517 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1518
1519 (defcustom frame-background-mode nil
1520   "*The brightness of the background.
1521 Set this to the symbol `dark' if your background color is dark, `light' if
1522 your background is light, or nil (default) if you want Emacs to
1523 examine the brightness for you.  Don't set this variable with `setq';
1524 this won't have the expected effect."
1525   :group 'faces
1526   :set #'(lambda (var value)
1527            (set-default var value)
1528            (mapc 'frame-set-background-mode (frame-list)))
1529   :initialize 'custom-initialize-changed
1530   :type '(choice (choice-item dark)
1531                  (choice-item light)
1532                  (choice-item :tag "default" nil)))
1533
1534
1535 (defun frame-set-background-mode (frame)
1536   "Set up display-dependent faces on FRAME.
1537 Display-dependent faces are those which have different definitions
1538 according to the `background-mode' and `display-type' frame parameters."
1539   (let* ((bg-resource
1540           (and window-system
1541                (x-get-resource "backgroundMode" "BackgroundMode")))
1542          (bg-color (frame-parameter frame 'background-color))
1543          (bg-mode
1544           (cond (frame-background-mode)
1545                 (bg-resource
1546                  (intern (downcase bg-resource)))
1547                 ((and (null window-system) (null bg-color))
1548                  ;; No way to determine this automatically (?).
1549                  'dark)
1550                 ;; Unspecified frame background color can only happen
1551                 ;; on tty's.
1552                 ((member bg-color '(unspecified "unspecified-bg"))
1553                  'dark)
1554                 ((equal bg-color "unspecified-fg") ; inverted colors
1555                  'light)
1556                 ((>= (apply '+ (x-color-values bg-color frame))
1557                     ;; Just looking at the screen, colors whose
1558                     ;; values add up to .6 of the white total
1559                     ;; still look dark to me.
1560                     (* (apply '+ (x-color-values "white" frame)) .6))
1561                  'light)
1562                 (t 'dark)))
1563          (display-type
1564           (cond ((null window-system)
1565                  (if (tty-display-color-p frame) 'color 'mono))
1566                 ((x-display-color-p frame)
1567                  'color)
1568                 ((x-display-grayscale-p frame)
1569                  'grayscale)
1570                 (t 'mono)))
1571          (old-bg-mode
1572           (frame-parameter frame 'background-mode))
1573          (old-display-type
1574           (frame-parameter frame 'display-type)))
1575
1576     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1577       (let ((locally-modified-faces nil))
1578         ;; Before modifying the frame parameters, we collect a list of
1579         ;; faces that don't match what their face-spec says they should
1580         ;; look like; we then avoid changing these faces below.  A
1581         ;; negative list is used on the assumption that most faces will
1582         ;; be unmodified, so we can avoid consing in the common case.
1583         (dolist (face (face-list))
1584           (when (not (face-spec-match-p face
1585                                         (face-user-default-spec face)
1586                                         (selected-frame)))
1587             (push face locally-modified-faces)))
1588         ;; Now change to the new frame parameters
1589         (modify-frame-parameters frame
1590                                  (list (cons 'background-mode bg-mode)
1591                                        (cons 'display-type display-type)))
1592         ;; For all named faces, choose face specs matching the new frame
1593         ;; parameters, unless they have been locally modified.
1594         (dolist (face (face-list))
1595           (unless (memq face locally-modified-faces)
1596             (face-spec-set face (face-user-default-spec face) frame)))))))
1597
1598 \f
1599 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1600 ;;; Frame creation.
1601 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1602
1603 (defun x-handle-named-frame-geometry (parameters)
1604   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1605 Value is the new parameter list."
1606   (let* ((name (or (cdr (assq 'name parameters))
1607                    (cdr (assq 'name default-frame-alist))))
1608          (x-resource-name name)
1609          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1610     (when res-geometry
1611       (let ((parsed (x-parse-geometry res-geometry)))
1612         ;; If the resource specifies a position, call the position
1613         ;; and size "user-specified".
1614         (when (or (assq 'top parsed)
1615                   (assq 'left parsed))
1616           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1617         ;; Put the geometry parameters at the end.  Copy
1618         ;; default-frame-alist so that they go after it.
1619         (setq parameters (append parameters default-frame-alist parsed))))
1620     parameters))
1621
1622
1623 (defun x-handle-reverse-video (frame parameters)
1624   "Handle the reverse-video frame parameter and X resource.
1625 `x-create-frame' does not handle this one."
1626   (when (cdr (or (assq 'reverse parameters)
1627                  (assq 'reverse default-frame-alist)
1628                  (let ((resource (x-get-resource "reverseVideo"
1629                                                  "ReverseVideo")))
1630                    (if resource
1631                        (cons nil (member (downcase resource)
1632                                          '("on" "true")))))))
1633       (let* ((params (frame-parameters frame))
1634              (bg (cdr (assq 'foreground-color params)))
1635              (fg (cdr (assq 'background-color params))))
1636         (modify-frame-parameters frame
1637                                  (list (cons 'foreground-color fg)
1638                                        (cons 'background-color bg)))
1639         (if (equal bg (cdr (assq 'border-color params)))
1640             (modify-frame-parameters frame
1641                                      (list (cons 'border-color fg))))
1642         (if (equal bg (cdr (assq 'mouse-color params)))
1643             (modify-frame-parameters frame
1644                                      (list (cons 'mouse-color fg))))
1645         (if (equal bg (cdr (assq 'cursor-color params)))
1646             (modify-frame-parameters frame
1647                                      (list (cons 'cursor-color fg)))))))
1648
1649
1650 (defun x-create-frame-with-faces (&optional parameters)
1651   "Create a frame from optional frame parameters PARAMETERS.
1652 Parameters not specified by PARAMETERS are taken from
1653 `default-frame-alist'.  If PARAMETERS specify a frame name,
1654 handle X geometry resources for that name.  If either PARAMETERS
1655 or `default-frame-alist' contains a `reverse' parameter, or
1656 the X resource ``reverseVideo'' is present, handle that.
1657 Value is the new frame created."
1658   (setq parameters (x-handle-named-frame-geometry parameters))
1659   (let ((visibility-spec (assq 'visibility parameters))
1660         (frame-list (frame-list))
1661         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1662         success)
1663     (unwind-protect
1664         (progn
1665           (x-handle-reverse-video frame parameters)
1666           (frame-set-background-mode frame)
1667           (face-set-after-frame-default frame)
1668           (if (or (null frame-list) (null visibility-spec))
1669               (make-frame-visible frame)
1670             (modify-frame-parameters frame (list visibility-spec)))
1671           (setq success t))
1672       (unless success
1673         (delete-frame frame)))
1674     frame))
1675
1676
1677 (defun face-set-after-frame-default (frame)
1678   "Set frame-local faces of FRAME from face specs and resources.
1679 Initialize colors of certain faces from frame parameters."
1680   (if (face-attribute 'default :font t)
1681       (set-face-attribute 'default frame :font
1682                           (face-attribute 'default :font t))
1683     (set-face-attribute 'default frame :family
1684                         (face-attribute 'default :family t))
1685     (set-face-attribute 'default frame :height
1686                         (face-attribute 'default :height t))
1687     (set-face-attribute 'default frame :slant
1688                         (face-attribute 'default :slant t))
1689     (set-face-attribute 'default frame :weight
1690                         (face-attribute 'default :weight t))
1691     (set-face-attribute 'default frame :width
1692                         (face-attribute 'default :width t)))
1693   (dolist (face (face-list))
1694     ;; Don't let frame creation fail because of an invalid face spec.
1695     (condition-case ()
1696         (when (not (equal face 'default))
1697           (face-spec-set face (face-user-default-spec face) frame)
1698           (internal-merge-in-global-face face frame)
1699           (when (and (memq window-system '(x w32 mac))
1700                      (or (not (boundp 'inhibit-default-face-x-resources))
1701                          (not (eq face 'default))))
1702             (make-face-x-resource-internal face frame)))
1703       (error nil)))
1704   ;; Initialize attributes from frame parameters.
1705   (let ((params '((foreground-color default :foreground)
1706                   (background-color default :background)
1707                   (border-color border :background)
1708                   (cursor-color cursor :background)
1709                   (scroll-bar-foreground scroll-bar :foreground)
1710                   (scroll-bar-background scroll-bar :background)
1711                   (mouse-color mouse :background))))
1712     (dolist (param params)
1713       (let ((frame-param (frame-parameter frame (nth 0 param)))
1714             (face (nth 1 param))
1715             (attr (nth 2 param)))
1716         (when (and frame-param
1717                    ;; Don't override face attributes explicitly
1718                    ;; specified for new frames.
1719                    (eq (face-attribute face attr t) 'unspecified))
1720           (set-face-attribute face frame attr frame-param))))))
1721
1722
1723 (defun tty-handle-reverse-video (frame parameters)
1724   "Handle the reverse-video frame parameter for terminal frames."
1725   (when (cdr (or (assq 'reverse parameters)
1726                  (assq 'reverse default-frame-alist)))
1727     (let* ((params (frame-parameters frame))
1728            (bg (cdr (assq 'foreground-color params)))
1729            (fg (cdr (assq 'background-color params))))
1730       (modify-frame-parameters frame
1731                                (list (cons 'foreground-color fg)
1732                                      (cons 'background-color bg)))
1733       (if (equal bg (cdr (assq 'mouse-color params)))
1734           (modify-frame-parameters frame
1735                                    (list (cons 'mouse-color fg))))
1736       (if (equal bg (cdr (assq 'cursor-color params)))
1737           (modify-frame-parameters frame
1738                                    (list (cons 'cursor-color fg)))))))
1739
1740
1741 (defun tty-create-frame-with-faces (&optional parameters)
1742   "Create a frame from optional frame parameters PARAMETERS.
1743 Parameters not specified by PARAMETERS are taken from
1744 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1745 contains a `reverse' parameter, handle that.  Value is the new frame
1746 created."
1747   (let ((frame (make-terminal-frame parameters))
1748         success)
1749     (unwind-protect
1750         (progn
1751           (tty-handle-reverse-video frame (frame-parameters frame))
1752           (frame-set-background-mode frame)
1753           (face-set-after-frame-default frame)
1754           (setq success t))
1755       (unless success
1756         (delete-frame frame)))
1757     frame))
1758
1759
1760 ;; Called from C function init_display to initialize faces of the
1761 ;; dumped terminal frame on startup.
1762
1763 (defun tty-set-up-initial-frame-faces ()
1764   (let ((frame (selected-frame)))
1765     (frame-set-background-mode frame)
1766     (face-set-after-frame-default frame)))
1767
1768
1769
1770 \f
1771 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1772 ;;; Compatiblity with 20.2
1773 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1774
1775 ;; Update a frame's faces when we change its default font.
1776
1777 (defalias 'frame-update-faces 'ignore "")
1778 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1779
1780 ;; Update the colors of FACE, after FRAME's own colors have been
1781 ;; changed.
1782
1783 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1784 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1785
1786 \f
1787 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1788 ;;; Standard faces.
1789 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1790
1791 (defgroup basic-faces nil
1792   "The standard faces of Emacs."
1793   :group 'faces)
1794
1795
1796 (defface default
1797   '((t nil))
1798   "Basic default face."
1799   :group 'basic-faces)
1800
1801
1802 (defface mode-line
1803   '((((class color) (min-colors 88))
1804      :box (:line-width -1 :style released-button)
1805      :background "grey75" :foreground "black")
1806     (t
1807      :inverse-video t))
1808   "Basic mode line face for selected window."
1809   :version "21.1"
1810   :group 'modeline
1811   :group 'basic-faces)
1812
1813 (defface mode-line-inactive
1814   '((default
1815      :inherit mode-line)
1816     (((class color) (min-colors 88) (background light))
1817      :weight light
1818      :box (:line-width -1 :color "grey75" :style nil)
1819      :foreground "grey20" :background "grey90")
1820     (((class color) (min-colors 88) (background dark) )
1821      :weight light
1822      :box (:line-width -1 :color "grey40" :style nil)
1823      :foreground "grey80" :background "grey30"))
1824   "Basic mode line face for non-selected windows."
1825   :version "22.1"
1826   :group 'modeline
1827   :group 'basic-faces)
1828
1829 ;; Make `modeline' an alias for `mode-line', for compatibility.
1830 (put 'modeline 'face-alias 'mode-line)
1831 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1832
1833 (defface header-line
1834   '((default
1835      :inherit mode-line)
1836     (((type tty))
1837      ;; This used to be `:inverse-video t', but that doesn't look very
1838      ;; good when combined with inverse-video mode-lines and multiple
1839      ;; windows.  Underlining looks better, and is more consistent with
1840      ;; the window-system face variants, which deemphasize the
1841      ;; header-line in relation to the mode-line face.  If a terminal
1842      ;; can't underline, then the header-line will end up without any
1843      ;; highlighting; this may be too confusing in general, although it
1844      ;; happens to look good with the only current use of header-lines,
1845      ;; the info browser. XXX
1846      :inverse-video nil        ;Override the value inherited from mode-line.
1847      :underline t)
1848     (((class color grayscale) (background light))
1849      :background "grey90" :foreground "grey20"
1850      :box nil)
1851     (((class color grayscale) (background dark))
1852      :background "grey20" :foreground "grey90"
1853      :box nil)
1854     (((class mono) (background light))
1855      :background "white" :foreground "black"
1856      :inverse-video nil
1857      :box nil
1858      :underline t)
1859     (((class mono) (background dark))
1860      :background "black" :foreground "white"
1861      :inverse-video nil
1862      :box nil
1863      :underline t))
1864   "Basic header-line face."
1865   :version "21.1"
1866   :group 'basic-faces)
1867
1868
1869 (defface tool-bar
1870   '((default
1871      :box (:line-width 1 :style released-button)
1872      :foreground "black")
1873     (((type x w32 mac) (class color))
1874      :background "grey75")
1875     (((type x) (class mono))
1876      :background "grey"))
1877   "Basic tool-bar face."
1878   :version "21.1"
1879   :group 'basic-faces)
1880
1881
1882 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1883                              (((type pc)) :foreground "magenta")
1884                              (t :foreground "dark blue"))
1885   "Face for minibuffer prompts."
1886   :version "22.1"
1887   :group 'basic-faces)
1888
1889 (setq minibuffer-prompt-properties
1890       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1891
1892 (defface region
1893   '((((class color) (min-colors 88) (background dark))
1894      :background "blue3")
1895     (((class color) (min-colors 88) (background light))
1896      :background "lightgoldenrod2")
1897     (((class color) (min-colors 16) (background dark))
1898      :background "blue3")
1899     (((class color) (min-colors 16) (background light))
1900      :background "lightgoldenrod2")
1901     (((class color) (min-colors 8))
1902      :background "blue" :foreground "white")
1903     (((type tty) (class mono))
1904      :inverse-video t)
1905     (t :background "gray"))
1906   "Basic face for highlighting the region."
1907   :version "21.1"
1908   :group 'basic-faces)
1909
1910
1911 (defface fringe
1912   '((((class color) (background light))
1913      :background "grey95")
1914     (((class color) (background dark))
1915      :background "grey10")
1916     (t
1917      :background "gray"))
1918   "Basic face for the fringes to the left and right of windows under X."
1919   :version "21.1"
1920   :group 'frames
1921   :group 'basic-faces)
1922
1923
1924 (defface scroll-bar '()
1925   "Basic face for the scroll bar colors under X."
1926   :version "21.1"
1927   :group 'frames
1928   :group 'basic-faces)
1929
1930
1931 (defface menu
1932   '((((type tty))
1933      :inverse-video t)
1934     (((type x-toolkit))
1935      )
1936     (t
1937      :inverse-video t))
1938   "Basic face for the font and colors of the menu bar and popup menus."
1939   :version "21.1"
1940   :group 'menu
1941   :group 'basic-faces)
1942
1943
1944 (defface border '()
1945   "Basic face for the frame border under X."
1946   :version "21.1"
1947   :group 'frames
1948   :group 'basic-faces)
1949
1950
1951 (defface cursor '()
1952   "Basic face for the cursor color under X.
1953 Note: Other faces cannot inherit from the cursor face."
1954   :version "21.1"
1955   :group 'cursor
1956   :group 'basic-faces)
1957
1958 (put 'cursor 'face-no-inherit t)
1959
1960 (defface mouse '()
1961   "Basic face for the mouse color under X."
1962   :version "21.1"
1963   :group 'mouse
1964   :group 'basic-faces)
1965
1966
1967 (defface bold '((t :weight bold))
1968   "Basic bold face."
1969   :group 'basic-faces)
1970
1971
1972 (defface italic
1973   '((((supports :slant italic))
1974      :slant italic)
1975     (((supports :underline t))
1976      :underline t)
1977     (t
1978      ;; default to italic, even it doesn't appear to be supported,
1979      ;; because in some cases the display engine will do it's own
1980      ;; workaround (to `dim' on ttys)
1981      :slant italic))
1982   "Basic italic font."
1983   :group 'basic-faces)
1984
1985
1986 (defface bold-italic '((t :weight bold :slant italic))
1987   "Basic bold-italic face."
1988   :group 'basic-faces)
1989
1990
1991 (defface underline '((t :underline t))
1992   "Basic underlined face."
1993   :group 'basic-faces)
1994
1995
1996 (defface highlight
1997   '((((class color) (min-colors 88) (background light))
1998      :background "darkseagreen2")
1999     (((class color) (min-colors 88) (background dark))
2000      :background "darkolivegreen")
2001     (((class color) (min-colors 16) (background light))
2002      :background "darkseagreen2")
2003     (((class color) (min-colors 16) (background dark))
2004      :background "darkolivegreen")
2005     (((class color) (min-colors 8))
2006      :background "green" :foreground "black")
2007     (t :inverse-video t))
2008   "Basic face for highlighting."
2009   :group 'basic-faces)
2010
2011
2012 (defface secondary-selection
2013   '((((class color) (min-colors 88) (background light))
2014      :background "yellow")
2015     (((class color) (min-colors 88) (background dark))
2016      :background "SkyBlue4")
2017     (((class color) (min-colors 16) (background light))
2018      :background "yellow")
2019     (((class color) (min-colors 16) (background dark))
2020      :background "SkyBlue4")
2021     (((class color) (min-colors 8))
2022      :background "cyan" :foreground "black")
2023     (t :inverse-video t))
2024   "Basic face for displaying the secondary selection."
2025   :group 'basic-faces)
2026
2027
2028 (defface fixed-pitch '((t :family "courier"))
2029   "The basic fixed-pitch face."
2030   :group 'basic-faces)
2031
2032
2033 (defface variable-pitch '((t :family "helv"))
2034   "The basic variable-pitch face."
2035   :group 'basic-faces)
2036
2037
2038 (defface trailing-whitespace
2039   '((((class color) (background light))
2040      :background "red")
2041     (((class color) (background dark))
2042      :background "red")
2043     (t :inverse-video t))
2044   "Basic face for highlighting trailing whitespace."
2045   :version "21.1"
2046   :group 'font-lock                     ; like `show-trailing-whitespace'
2047   :group 'basic-faces)
2048
2049 (defface escape-glyph '((((background dark)) :foreground "cyan")
2050                         (((type pc)) :foreground "magenta")
2051                         (t :foreground "blue"))
2052   "Face for characters displayed as ^-sequences or \-sequences."
2053   :group 'basic-faces)
2054 \f
2055 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2056 ;;; Manipulating font names.
2057 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2058
2059 ;; This is here for compatibilty with Emacs 20.2.  For example,
2060 ;; international/fontset.el uses x-resolve-font-name.  The following
2061 ;; functions are not used in the face implementation itself.
2062
2063 (defvar x-font-regexp nil)
2064 (defvar x-font-regexp-head nil)
2065 (defvar x-font-regexp-weight nil)
2066 (defvar x-font-regexp-slant nil)
2067
2068 (defconst x-font-regexp-weight-subnum 1)
2069 (defconst x-font-regexp-slant-subnum 2)
2070 (defconst x-font-regexp-swidth-subnum 3)
2071 (defconst x-font-regexp-adstyle-subnum 4)
2072
2073 ;;; Regexps matching font names in "Host Portable Character Representation."
2074 ;;;
2075 (let ((-                "[-?]")
2076       (foundry          "[^-]+")
2077       (family           "[^-]+")
2078       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2079 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2080       (weight\?         "\\([^-]*\\)")                                  ; 1
2081       (slant            "\\([ior]\\)")                                  ; 2
2082 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2083       (slant\?          "\\([^-]?\\)")                                  ; 2
2084 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2085       (swidth           "\\([^-]*\\)")                                  ; 3
2086 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2087       (adstyle          "\\([^-]*\\)")                                  ; 4
2088       (pixelsize        "[0-9]+")
2089       (pointsize        "[0-9][0-9]+")
2090       (resx             "[0-9][0-9]+")
2091       (resy             "[0-9][0-9]+")
2092       (spacing          "[cmp?*]")
2093       (avgwidth         "[0-9]+")
2094       (registry         "[^-]+")
2095       (encoding         "[^-]+")
2096       )
2097   (setq x-font-regexp
2098         (concat "\\`\\*?[-?*]"
2099                 foundry - family - weight\? - slant\? - swidth - adstyle -
2100                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2101                 registry - encoding "\\*?\\'"
2102                 ))
2103   (setq x-font-regexp-head
2104         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2105                 "\\([-*?]\\|\\'\\)"))
2106   (setq x-font-regexp-slant (concat - slant -))
2107   (setq x-font-regexp-weight (concat - weight -))
2108   nil)
2109
2110
2111 (defun x-resolve-font-name (pattern &optional face frame)
2112   "Return a font name matching PATTERN.
2113 All wildcards in PATTERN are instantiated.
2114 If PATTERN is nil, return the name of the frame's base font, which never
2115 contains wildcards.
2116 Given optional arguments FACE and FRAME, return a font which is
2117 also the same size as FACE on FRAME, or fail."
2118   (or (symbolp face)
2119       (setq face (face-name face)))
2120   (and (eq frame t)
2121        (setq frame nil))
2122   (if pattern
2123       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2124       (let ((fonts (x-list-fonts pattern face frame 1)))
2125         (or fonts
2126             (if face
2127                 (if (string-match "\\*" pattern)
2128                     (if (null (face-font face))
2129                         (error "No matching fonts are the same height as the frame default font")
2130                       (error "No matching fonts are the same height as face `%s'" face))
2131                   (if (null (face-font face))
2132                       (error "Height of font `%s' doesn't match the frame default font"
2133                              pattern)
2134                     (error "Height of font `%s' doesn't match face `%s'"
2135                            pattern face)))
2136               (error "No fonts match `%s'" pattern)))
2137         (car fonts))
2138     (cdr (assq 'font (frame-parameters (selected-frame))))))
2139
2140
2141 (defun x-frob-font-weight (font which)
2142   (let ((case-fold-search t))
2143     (cond ((string-match x-font-regexp font)
2144            (concat (substring font 0
2145                               (match-beginning x-font-regexp-weight-subnum))
2146                    which
2147                    (substring font (match-end x-font-regexp-weight-subnum)
2148                               (match-beginning x-font-regexp-adstyle-subnum))
2149                    ;; Replace the ADD_STYLE_NAME field with *
2150                    ;; because the info in it may not be the same
2151                    ;; for related fonts.
2152                    "*"
2153                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2154           ((string-match x-font-regexp-head font)
2155            (concat (substring font 0 (match-beginning 1)) which
2156                    (substring font (match-end 1))))
2157           ((string-match x-font-regexp-weight font)
2158            (concat (substring font 0 (match-beginning 1)) which
2159                    (substring font (match-end 1)))))))
2160 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2161
2162 (defun x-frob-font-slant (font which)
2163   (let ((case-fold-search t))
2164     (cond ((string-match x-font-regexp font)
2165            (concat (substring font 0
2166                               (match-beginning x-font-regexp-slant-subnum))
2167                    which
2168                    (substring font (match-end x-font-regexp-slant-subnum)
2169                               (match-beginning x-font-regexp-adstyle-subnum))
2170                    ;; Replace the ADD_STYLE_NAME field with *
2171                    ;; because the info in it may not be the same
2172                    ;; for related fonts.
2173                    "*"
2174                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2175           ((string-match x-font-regexp-head font)
2176            (concat (substring font 0 (match-beginning 2)) which
2177                    (substring font (match-end 2))))
2178           ((string-match x-font-regexp-slant font)
2179            (concat (substring font 0 (match-beginning 1)) which
2180                    (substring font (match-end 1)))))))
2181 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2182
2183 ;; These aliases are here so that we don't get warnings about obsolete
2184 ;; functions from the byte compiler.
2185 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2186 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2187
2188 (defun x-make-font-bold (font)
2189   "Given an X font specification, make a bold version of it.
2190 If that can't be done, return nil."
2191   (internal-frob-font-weight font "bold"))
2192 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2193
2194 (defun x-make-font-demibold (font)
2195   "Given an X font specification, make a demibold version of it.
2196 If that can't be done, return nil."
2197   (internal-frob-font-weight font "demibold"))
2198 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2199
2200 (defun x-make-font-unbold (font)
2201   "Given an X font specification, make a non-bold version of it.
2202 If that can't be done, return nil."
2203   (internal-frob-font-weight font "medium"))
2204 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2205
2206 (defun x-make-font-italic (font)
2207   "Given an X font specification, make an italic version of it.
2208 If that can't be done, return nil."
2209   (internal-frob-font-slant font "i"))
2210 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2211
2212 (defun x-make-font-oblique (font) ; you say tomayto...
2213   "Given an X font specification, make an oblique version of it.
2214 If that can't be done, return nil."
2215   (internal-frob-font-slant font "o"))
2216 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2217
2218 (defun x-make-font-unitalic (font)
2219   "Given an X font specification, make a non-italic version of it.
2220 If that can't be done, return nil."
2221   (internal-frob-font-slant font "r"))
2222 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2223
2224 (defun x-make-font-bold-italic (font)
2225   "Given an X font specification, make a bold and italic version of it.
2226 If that can't be done, return nil."
2227   (and (setq font (internal-frob-font-weight font "bold"))
2228        (internal-frob-font-slant font "i")))
2229 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2230
2231 (provide 'faces)
2232
2233 ;;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2234 ;;; faces.el ends here