lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1995, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package is a major mode for editing nroff source code.  It knows
  29 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  30 ;; and indent paragraphs properly in their presence.  It also includes
  31 ;; a command to count text lines (excluding nroff constructs), a command
  32 ;; to center a line, and movement commands that know how to skip macros.
  33
  34 ;; Paragraph filling and line-counting currently don't respect comments,
  35 ;; as they should.
  36
  37 ;;; Code:
  38
  39 (defgroup nroff nil
  40   "Nroff mode."
  41   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  42   :group 'wp
  43   :prefix "nroff-")
  44
  45
  46 (defcustom nroff-electric-mode nil
  47   "Non-nil means automatically closing requests when you insert an open."
  48   :group 'nroff
  49   :type 'boolean)
  50
  51 (defvar nroff-mode-map
  52   (let ((map (make-sparse-keymap)))
  53     (define-key map "\t"  'tab-to-tab-stop)
  54     (define-key map "\es" 'center-line)
  55     (define-key map "\e?" 'nroff-count-text-lines)
  56     (define-key map "\n"  'nroff-electric-newline)
  57     (define-key map "\en" 'nroff-forward-text-line)
  58     (define-key map "\ep" 'nroff-backward-text-line)
  59     map)
  60   "Major mode keymap for `nroff-mode'.")
  61
  62 (defvar nroff-mode-syntax-table
  63   (let ((st (copy-syntax-table text-mode-syntax-table)))
  64     ;; " isn't given string quote syntax in text-mode but it
  65     ;; (arguably) should be for use round nroff arguments (with ` and
  66     ;; ' used otherwise).
  67     (modify-syntax-entry ?\" "\"  2" st)
  68     ;; Comments are delimited by \" and newline.
  69     ;; And in groff also \# to newline.
  70     (modify-syntax-entry ?# ".  2"  st)
  71     (modify-syntax-entry ?\\ "\\  1" st)
  72     (modify-syntax-entry ?\n ">" st)
  73     st)
  74   "Syntax table used while in `nroff-mode'.")
  75
  76 (defvar nroff-imenu-expression
  77   ;; man headers:
  78   '((nil "^\\.SH \"?\\([^\"\n]*\\)\"?$" 1)))
  79
  80 (defcustom nroff-font-lock-keywords
  81   (list
  82    ;; Directives are . or ' at start of line, followed by
  83    ;; optional whitespace, then command (which my be longer than
  84    ;; 2 characters in groff).  Perhaps the arguments should be
  85    ;; fontified as well.
  86    "^[.']\\s-*\\sw+"
  87    ;; There are numerous groff escapes; the following get things
  88    ;; like \-, \(em (standard troff) and \f[bar] (groff
  89    ;; variants).  This won't currently do groff's \A'foo' and
  90    ;; the like properly.  One might expect it to highlight an escape's
  91    ;; arguments in common cases, like \f.
  92    (concat "\\\\"                     ; backslash
  93          "\\("                        ; followed by various possibilities
  94          (mapconcat 'identity
  95                     '("[f*n]*\\[.+?]" ; some groff extensions
  96                       "(.."           ; two chars after (
  97                       "[^(\"#]"       ; single char escape
  98                       ) "\\|")
  99          "\\)")
 100    )
 101   "Font-lock highlighting control in `nroff-mode'."
 102   :group 'nroff
 103   :type '(repeat regexp))
 104
 105 (defcustom nroff-mode-hook nil
 106   "Hook run by function `nroff-mode'."
 107   :type 'hook
 108   :group 'nroff)
 109
 110 ;;;###autoload
 111 (define-derived-mode nroff-mode text-mode "Nroff"
 112   "Major mode for editing text intended for nroff to format.
 113 \\{nroff-mode-map}
 114 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
 115 Also, try `nroff-electric-mode', for automatically inserting
 116 closing requests for requests that are used in matched pairs."
 117   (set (make-local-variable 'font-lock-defaults)
 118        ;; SYNTAX-BEGIN is set to backward-paragraph to avoid slow-down
 119        ;; near the end of large buffers due to searching to buffer's
 120        ;; beginning.
 121        '(nroff-font-lock-keywords nil t nil backward-paragraph))
 122   (set (make-local-variable 'outline-regexp) "\\.H[ ]+[1-7]+ ")
 123   (set (make-local-variable 'outline-level) 'nroff-outline-level)
 124   ;; now define a bunch of variables for use by commands in this mode
 125   (set (make-local-variable 'page-delimiter) "^\\.\\(bp\\|SK\\|OP\\)")
 126   (set (make-local-variable 'paragraph-start)
 127        (concat "[.']\\|" paragraph-start))
 128   (set (make-local-variable 'paragraph-separate)
 129        (concat "[.']\\|" paragraph-separate))
 130   ;; comment syntax added by mit-erl!gildea 18 Apr 86
 131   (set (make-local-variable 'comment-start) "\\\" ")
 132   (set (make-local-variable 'comment-start-skip) "\\\\[\"#][ \t]*")
 133   (set (make-local-variable 'comment-column) 24)
 134   (set (make-local-variable 'comment-indent-function) 'nroff-comment-indent)
 135   (set (make-local-variable 'imenu-generic-expression) nroff-imenu-expression))
 136
 137 (defun nroff-outline-level ()
 138   (save-excursion
 139     (looking-at outline-regexp)
 140     (skip-chars-forward ".H ")
 141     (string-to-number (buffer-substring (point) (+ 1 (point))))))
 142
 143 ;; Compute how much to indent a comment in nroff/troff source.
 144 ;; By mit-erl!gildea April 86
 145 (defun nroff-comment-indent ()
 146   "Compute indent for an nroff/troff comment.
 147 Puts a full-stop before comments on a line by themselves."
 148   (let ((pt (point)))
 149     (unwind-protect
 150         (progn
 151           (skip-chars-backward " \t")
 152           (if (bolp)
 153               (progn
 154                 (setq pt (1+ pt))
 155                 (insert ?.)
 156                 1)
 157             (if (save-excursion
 158                   (backward-char 1)
 159                   (looking-at "^[.']"))
 160                 1
 161               (max comment-column
 162                    (* 8 (/ (+ (current-column)
 163                               9) 8)))))) ; add 9 to ensure at least two blanks
 164       (goto-char pt))))
 165
 166 (defun nroff-count-text-lines (start end &optional print)
 167   "Count lines in region, except for nroff request lines.
 168 All lines not starting with a period are counted up.
 169 Interactively, print result in echo area.
 170 Noninteractively, return number of non-request lines from START to END."
 171   (interactive "r\np")
 172   (if print
 173       (message "Region has %d text lines" (nroff-count-text-lines start end))
 174     (save-excursion
 175       (save-restriction
 176         (narrow-to-region start end)
 177         (goto-char (point-min))
 178         (- (buffer-size) (forward-text-line (buffer-size)))))))
 179
 180 (defun nroff-forward-text-line (&optional cnt)
 181   "Go forward one nroff text line, skipping lines of nroff requests.
 182 An argument is a repeat count; if negative, move backward."
 183   (interactive "p")
 184   (if (not cnt) (setq cnt 1))
 185   (while (and (> cnt 0) (not (eobp)))
 186     (forward-line 1)
 187     (while (and (not (eobp)) (looking-at "[.']."))
 188       (forward-line 1))
 189     (setq cnt (- cnt 1)))
 190   (while (and (< cnt 0) (not (bobp)))
 191     (forward-line -1)
 192     (while (and (not (bobp))
 193                 (looking-at "[.']."))
 194       (forward-line -1))
 195     (setq cnt (+ cnt 1)))
 196   cnt)
 197
 198 (defun nroff-backward-text-line (&optional cnt)
 199   "Go backward one nroff text line, skipping lines of nroff requests.
 200 An argument is a repeat count; negative means move forward."
 201   (interactive "p")
 202   (nroff-forward-text-line (- cnt)))
 203
 204 (defconst nroff-brace-table
 205   '((".(b" . ".)b")
 206     (".(l" . ".)l")
 207     (".(q" . ".)q")
 208     (".(c" . ".)c")
 209     (".(x" . ".)x")
 210     (".(z" . ".)z")
 211     (".(d" . ".)d")
 212     (".(f" . ".)f")
 213     (".LG" . ".NL")
 214     (".SM" . ".NL")
 215     (".LD" . ".DE")
 216     (".CD" . ".DE")
 217     (".BD" . ".DE")
 218     (".DS" . ".DE")
 219     (".DF" . ".DE")
 220     (".FS" . ".FE")
 221     (".KS" . ".KE")
 222     (".KF" . ".KE")
 223     (".LB" . ".LE")
 224     (".AL" . ".LE")
 225     (".BL" . ".LE")
 226     (".DL" . ".LE")
 227     (".ML" . ".LE")
 228     (".RL" . ".LE")
 229     (".VL" . ".LE")
 230     (".RS" . ".RE")
 231     (".TS" . ".TE")
 232     (".EQ" . ".EN")
 233     (".PS" . ".PE")
 234     (".BS" . ".BE")
 235     (".G1" . ".G2")                     ; grap
 236     (".na" . ".ad b")
 237     (".nf" . ".fi")
 238     (".de" . "..")))
 239
 240 (defun nroff-electric-newline (arg)
 241   "Insert newline for nroff mode; special if electric-nroff mode.
 242 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 243 automatically inserts the matching closing request after point."
 244   (interactive "P")
 245   (let ((completion (save-excursion
 246                       (beginning-of-line)
 247                       (and (null arg)
 248                            nroff-electric-mode
 249                            (<= (point) (- (point-max) 3))
 250                            (cdr (assoc (buffer-substring (point)
 251                                                          (+ 3 (point)))
 252                                        nroff-brace-table)))))
 253         (needs-nl (not (looking-at "[ \t]*$"))))
 254     (if (null completion)
 255         (newline (prefix-numeric-value arg))
 256       (save-excursion
 257         (insert "\n\n" completion)
 258         (if needs-nl (insert "\n")))
 259       (forward-char 1))))
 260
 261 (define-minor-mode nroff-electric-mode
 262   "Toggle `nroff-electric-newline' minor mode.
 263 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 264 beginning of the line, and insert the matching closing request if necessary.
 265 This command toggles that mode (off->on, on->off), with an argument,
 266 turns it on if arg is positive, otherwise off."
 267   :lighter " Electric"
 268   (or (derived-mode-p 'nroff-mode) (error "Must be in nroff mode")))
 269
 270 ;; Old names that were not namespace clean.
 271 (define-obsolete-function-alias 'count-text-lines 'nroff-count-text-lines "22.1")
 272 (define-obsolete-function-alias 'forward-text-line 'nroff-forward-text-line "22.1")
 273 (define-obsolete-function-alias 'backward-text-line 'nroff-backward-text-line "22.1")
 274 (define-obsolete-function-alias 'electric-nroff-newline 'nroff-electric-newline "22.1")
 275 (define-obsolete-function-alias 'electric-nroff-mode 'nroff-electric-mode "22.1")
 276
 277 (provide 'nroff-mode)
 278
 279 ;; arch-tag: 6e276340-6c65-4f65-b4e3-0ca431ddfb6c
 280 ;;; nroff-mode.el ends here