lisp/textmodes/reftex-global.el

   1 ;;; reftex-global.el --- operations on entire documents with RefTeX
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <dominik@science.uva.nl>
   7 ;; Version: 4.28
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31 (provide 'reftex-global)
  32 (require 'reftex)
  33 ;;;
  34
  35 (defun reftex-create-tags-file ()
  36   "Create TAGS file by running `etags' on the current document.
  37 The TAGS file is also immediately visited with `visit-tags-table'."
  38   (interactive)
  39   (reftex-access-scan-info current-prefix-arg)
  40   (let* ((master (reftex-TeX-master-file))
  41          (files  (reftex-all-document-files))
  42          (cmd    (format "etags %s" (mapconcat 'identity files " "))))
  43     (save-excursion
  44       (set-buffer (reftex-get-file-buffer-force master))
  45       (message "Running etags to create TAGS file...")
  46       (shell-command cmd)
  47       (visit-tags-table "TAGS"))))
  48
  49 ;; History of grep commands.
  50 (defvar reftex-grep-history nil)
  51 (defvar reftex-grep-command "grep -n "
  52   "Last grep command used in \\[reftex-grep-document]; default for next grep.")
  53
  54 (defun reftex-grep-document (grep-cmd)
  55   "Run grep query through all files related to this document.
  56 With prefix arg, force to rescan document.
  57 No active TAGS table is required."
  58
  59   (interactive
  60    (list (read-from-minibuffer "Run grep on document (like this): "
  61                                reftex-grep-command nil nil
  62                                'reftex-grep-history)))
  63   (reftex-access-scan-info current-prefix-arg)
  64   (let* ((files  (reftex-all-document-files t))
  65          (cmd    (format
  66                   "%s %s" grep-cmd
  67                   (mapconcat 'identity files " "))))
  68     (grep cmd)))
  69
  70 (defun reftex-search-document (&optional regexp)
  71   "Regexp search through all files of the current document.
  72 Starts always in the master file.  Stops when a match is found.
  73 To continue searching for next match, use command \\[tags-loop-continue].
  74 No active TAGS table is required."
  75   (interactive)
  76   (let ((default (reftex-this-word)))
  77     (unless regexp
  78       (setq regexp (read-string (format "Search regexp in document [%s]: "
  79                                         default))))
  80     (if (string= regexp "") (setq regexp (regexp-quote default)))
  81
  82     (reftex-access-scan-info current-prefix-arg)
  83     (tags-search regexp (list 'reftex-all-document-files))))
  84
  85 (defun reftex-query-replace-document (&optional from to delimited)
  86   "Do `query-replace-regexp' of FROM with TO over the entire document.
  87 Third arg DELIMITED (prefix arg) means replace only word-delimited matches.
  88 If you exit (\\[keyboard-quit], RET or q), you can resume the query replace
  89 with the command \\[tags-loop-continue].
  90 No active TAGS table is required."
  91   (interactive)
  92   (let ((default (reftex-this-word)))
  93     (unless from
  94       (setq from (read-string (format "Replace regexp in document [%s]: "
  95                                       default)))
  96       (if (string= from "") (setq from (regexp-quote default))))
  97     (unless to
  98       (setq to (read-string (format "Replace regexp %s with: " from))))
  99     (reftex-access-scan-info current-prefix-arg)
 100     (tags-query-replace from to (or delimited current-prefix-arg)
 101                         (list 'reftex-all-document-files))))
 102
 103 (defun reftex-find-duplicate-labels ()
 104   "Produce a list of all duplicate labels in the document."
 105
 106   (interactive)
 107
 108   ;; Rescan the document to make sure
 109   (reftex-access-scan-info t)
 110
 111   (let ((master (reftex-TeX-master-file))
 112         (cnt 0)
 113         (dlist
 114          (mapcar
 115           (lambda (x)
 116             (let (x1)
 117               (cond
 118                ((memq (car x)
 119                       '(toc bof eof bib thebib label-numbers xr xr-doc
 120                             master-dir file-error bibview-cache appendix
 121                             is-multi index))
 122                 nil)
 123                (t
 124                 (setq x1 (reftex-all-assoc-string
 125                           (car x) (symbol-value reftex-docstruct-symbol)))
 126                 (if (< 1 (length x1))
 127                     (append (list (car x))
 128                             (mapcar (lambda(x)
 129                                       (abbreviate-file-name (nth 3 x)))
 130                                     x1))
 131                   (list nil))))))
 132           (reftex-uniquify-by-car (symbol-value reftex-docstruct-symbol)))))
 133
 134     (setq dlist (reftex-uniquify-by-car dlist))
 135     (if (null dlist) (error "No duplicate labels in document"))
 136     (switch-to-buffer-other-window "*Duplicate Labels*")
 137     (set (make-local-variable 'TeX-master) master)
 138     (erase-buffer)
 139     (insert "                MULTIPLE LABELS IN CURRENT DOCUMENT:\n")
 140     (insert
 141      " Move point to label and type `r' to run a query-replace on the label\n"
 142      " and its references.  Type `q' to exit this buffer.\n\n")
 143     (insert " LABEL               FILE\n")
 144     (insert " -------------------------------------------------------------\n")
 145     (use-local-map (make-sparse-keymap))
 146     (local-set-key [?q] (lambda () "Kill this buffer." (interactive)
 147                           (kill-buffer (current-buffer)) (delete-window)))
 148     (local-set-key [?r] 'reftex-change-label)
 149     (while dlist
 150       (when (and (car (car dlist))
 151                  (cdr (car dlist)))
 152         (incf cnt)
 153         (insert (mapconcat 'identity (car dlist) "\n    ") "\n"))
 154       (pop dlist))
 155     (goto-char (point-min))
 156     (when (= cnt 0)
 157       (kill-buffer (current-buffer))
 158       (delete-window)
 159       (message "Document does not contain duplicate labels."))))
 160
 161 (defun reftex-change-label (&optional from to)
 162   "Run `query-replace-regexp' of FROM with TO in all macro arguments.
 163 Works on the entire multifile document.
 164 If you exit (\\[keyboard-quit], RET or q), you can resume the query replace
 165 with the command \\[tags-loop-continue].
 166 No active TAGS table is required."
 167   (interactive)
 168   (let ((default (reftex-this-word "-a-zA-Z0-9_*.:")))
 169     (unless from
 170       (setq from (read-string (format "Replace label globally [%s]: "
 171                                       default))))
 172     (if (string= from "") (setq from default))
 173     (unless to
 174       (setq to (read-string (format "Replace label %s with: "
 175                                     from))))
 176     (reftex-query-replace-document
 177      (concat "{" (regexp-quote from) "}")
 178      (format "{%s}" to))))
 179
 180 (defun reftex-renumber-simple-labels ()
 181   "Renumber all simple labels in the document to make them sequentially.
 182 Simple labels are the ones created by RefTeX, consisting only of the
 183 prefix and a number.  After the command completes, all these labels will
 184 have sequential numbers throughout the document.  Any references to
 185 the labels will be changed as well.  For this, RefTeX looks at the
 186 arguments of any macros which either start or end in the string `ref'.
 187 This command should be used with care, in particular in multifile
 188 documents.  You should not use it if another document refers to this
 189 one with the `xr' package."
 190   (interactive)
 191   ;; Resan the entire document
 192   (reftex-access-scan-info 1)
 193   ;; Get some insurance
 194   (if (and (reftex-is-multi)
 195            (not (yes-or-no-p "Replacing all simple labels in multiple files is risky.  Continue? ")))
 196       (error "Abort"))
 197   ;; Make the translation list
 198   (let* ((re-core (concat "\\("
 199                           (mapconcat 'cdr reftex-typekey-to-prefix-alist "\\|")
 200                           "\\)"))
 201          (label-re (concat "\\`" re-core "\\([0-9]+\\)\\'"))
 202          (search-re (concat "[{,]\\(" re-core "\\([0-9]+\\)\\)[,}]"))
 203          (error-fmt "Undefined label or reference %s. Ignore and continue? ")
 204          (label-numbers-alist (mapcar (lambda (x) (cons (cdr x) 0))
 205                                       reftex-typekey-to-prefix-alist))
 206          (files (reftex-all-document-files))
 207          (list (symbol-value reftex-docstruct-symbol))
 208          translate-alist n entry label new-label nr-cell changed-sequence)
 209
 210     (while (setq entry (pop list))
 211       (when (and (stringp (car entry))
 212                  (string-match label-re (car entry)))
 213         (setq label (car entry)
 214               nr-cell (assoc (match-string 1 (car entry))
 215                              label-numbers-alist))
 216         (if (assoc label translate-alist)
 217             (error "Duplicate label %s" label))
 218         (setq new-label (concat (match-string 1 (car entry))
 219                                 (int-to-string (incf (cdr nr-cell)))))
 220         (push (cons label new-label) translate-alist)
 221         (or (string= label new-label) (setq changed-sequence t))))
 222
 223     (unless changed-sequence
 224       (error "Simple labels are already in correct sequence"))
 225
 226     (reftex-ensure-write-access (reftex-all-document-files))
 227
 228     ;; Save all document buffers before this operation
 229     (reftex-save-all-document-buffers)
 230
 231     ;; First test to check for erros
 232     (setq n (reftex-translate
 233              files search-re translate-alist error-fmt 'test))
 234
 235     ;; Now the real thing.
 236     (if (yes-or-no-p
 237          (format "Replace %d items at %d places in %d files? "
 238                  (length translate-alist) n (length files)))
 239         (progn
 240           (let ((inhibit-quit t))  ;; Do not disturb...
 241             (reftex-translate
 242              files search-re translate-alist error-fmt nil)
 243             (setq quit-flag nil))
 244           (if (and (reftex-is-multi)
 245                    (yes-or-no-p "Save entire document? "))
 246               (reftex-save-all-document-buffers))
 247           ;; Rescan again...
 248           (reftex-access-scan-info 1)
 249           (message "Done replacing simple labels."))
 250       (message "No replacements done"))))
 251
 252 (defun reftex-translate (files search-re translate-alist error-fmt test)
 253   ;; In FILES, look for SEARCH-RE and replace match 1 of it with
 254   ;; its association in TRANSLATE-ALSIT.
 255   ;; If we do not find an association and TEST is non-nil, query
 256   ;; to ignore the problematic string.
 257   ;; If TEST is nil, it is ignored without query.
 258   ;; Return the number of replacements.
 259   (let ((n 0) file label match-data buf macro pos cell)
 260     (while (setq file (pop files))
 261       (setq buf (reftex-get-file-buffer-force file))
 262       (unless buf
 263         (error "No such file %s" file))
 264       (set-buffer buf)
 265       (save-excursion
 266         (save-restriction
 267           (widen)
 268           (goto-char (point-min))
 269           (while (re-search-forward search-re nil t)
 270             (backward-char)
 271             (save-excursion
 272               (setq label (reftex-match-string 1)
 273                     cell (assoc label translate-alist)
 274                     match-data (match-data)
 275                     macro (reftex-what-macro 1)
 276                     pos (cdr macro))
 277               (goto-char (or pos (point)))
 278               (when (and macro
 279                          (or (looking-at "\\\\ref")
 280                              (looking-at "\\\\[a-zA-Z]*ref\\(range\\)?[^a-zA-Z]")
 281                              (looking-at "\\\\ref[a-zA-Z]*[^a-zA-Z]")
 282                              (looking-at (format
 283                                           reftex-find-label-regexp-format
 284                                           (regexp-quote label)))))
 285                 ;; OK, we should replace it.
 286                 (set-match-data match-data)
 287                 (cond
 288                  ((and test (not cell))
 289                   ;; We've got a problem
 290                   (unwind-protect
 291                       (progn
 292                         (reftex-highlight 1 (match-beginning 0) (match-end 0))
 293                         (ding)
 294                         (or (y-or-n-p (format error-fmt label))
 295                             (error "Abort")))
 296                     (reftex-unhighlight 1)))
 297                  ((and test cell)
 298                   (incf n))
 299                  ((and (not test) cell)
 300                   ;; Replace
 301                   (goto-char (match-beginning 1))
 302                   (delete-region (match-beginning 1) (match-end 1))
 303                   (insert (cdr cell)))
 304                  (t nil))))))))
 305     n))
 306
 307 (defun reftex-save-all-document-buffers ()
 308   "Save all documents associated with the current document.
 309 The function is useful after a global action like replacing or renumbering
 310 labels."
 311   (interactive)
 312   (let ((files (reftex-all-document-files))
 313         file buffer)
 314     (save-excursion
 315       (while (setq file (pop files))
 316         (setq buffer (reftex-get-buffer-visiting file))
 317         (when buffer
 318           (set-buffer buffer)
 319           (save-buffer))))))
 320
 321 (defun reftex-ensure-write-access (files)
 322   "Make sure we have write access to all files in FILES.
 323 Also checks if buffers visiting the files are in read-only mode."
 324   (let (file buf)
 325     (while (setq file (pop files))
 326       (unless (file-exists-p file)
 327         (ding)
 328         (or (y-or-n-p (format "No such file %s. Continue? " file))
 329             (error "Abort")))
 330       (unless (file-writable-p file)
 331         (ding)
 332         (or (y-or-n-p (format "No write access to %s. Continue? " file))
 333             (error "Abort")))
 334       (when (and (setq buf (reftex-get-buffer-visiting file))
 335                  (save-excursion
 336                    (set-buffer buf)
 337                    buffer-read-only))
 338         (ding)
 339         (or (y-or-n-p (format "Buffer %s is read-only. Continue? "
 340                               (buffer-name buf)))
 341             (error "Abort"))))))
 342
 343 (defun reftex-isearch-wrap-function ()
 344   (if (not isearch-word)
 345       (switch-to-buffer
 346        (funcall isearch-next-buffer-function (current-buffer) t)))
 347   (goto-char (if isearch-forward (point-min) (point-max))))
 348
 349 (defun reftex-isearch-push-state-function ()
 350   `(lambda (cmd)
 351      (reftex-isearch-pop-state-function cmd ,(current-buffer))))
 352
 353 (defun reftex-isearch-pop-state-function (cmd buffer)
 354   (switch-to-buffer buffer))
 355
 356 (defun reftex-isearch-isearch-search (string bound noerror)
 357   (let ((nxt-buff nil)
 358         (search-fun
 359          (cond
 360           (isearch-word
 361            (if isearch-forward 'word-search-forward 'word-search-backward))
 362           (isearch-regexp
 363            (if isearch-forward 're-search-forward 're-search-backward))
 364           (t
 365            (if isearch-forward 'search-forward 'search-backward)))))
 366     (or
 367      (funcall search-fun string bound noerror)
 368      (unless bound
 369        (condition-case nil
 370            (when isearch-next-buffer-function
 371              (while (not (funcall search-fun string bound noerror))
 372                (cond
 373                 (isearch-forward
 374                  (setq nxt-buff
 375                        (funcall isearch-next-buffer-function
 376                                 (current-buffer)))
 377                  (if (not nxt-buff)
 378                      (progn
 379                        (error "Wrap forward"))
 380                    (switch-to-buffer nxt-buff)
 381                    (goto-char (point-min))))
 382                 (t
 383                  (setq nxt-buff
 384                        (funcall isearch-next-buffer-function
 385                                          (current-buffer)))
 386                  (if (not nxt-buff)
 387                      (progn
 388                        (error "Wrap backward"))
 389                    (switch-to-buffer nxt-buff)
 390                    (goto-char (point-max))))))
 391              (point))
 392          (error nil))))))
 393
 394 ;;; This function is called when isearch reaches the end of a
 395 ;;; buffer. For reftex what we want to do is not wrap to the
 396 ;;; beginning, but switch to the next buffer in the logical order of
 397 ;;; the document.  This function looks through list of files in the
 398 ;;; document (reftex-all-document-files), searches for the current
 399 ;;; buffer and switches to the next/previous one in the logical order
 400 ;;; of the document.  If WRAPP is true then wrap the search to the
 401 ;;; beginning/end of the file list, depending of the search direction.
 402 (defun reftex-isearch-switch-to-next-file (crt-buf &optional wrapp)
 403   (reftex-access-scan-info)
 404   (let* ((cb (buffer-file-name crt-buf))
 405          (flist (reftex-all-document-files))
 406          (orig-flist flist))
 407     (when flist
 408       (if wrapp
 409           (unless isearch-forward
 410               (setq flist (last flist)))
 411         (unless isearch-forward
 412           (setq flist (nreverse (copy-list flist)))
 413           (setq orig-flist flist))
 414         (while (not (string= (car flist) cb))
 415           (setq flist (cdr flist)))
 416         (setq flist (cdr flist)))
 417       (when flist
 418         (find-file  (car flist))))))
 419
 420 ;;;###autoload
 421 (defun reftex-isearch-minor-mode (&optional arg)
 422   "When on, isearch searches the whole document, not only the current file.
 423 This minor mode allows isearch to search through all the files of
 424 the current TeX document.
 425
 426 With no argument, this command toggles
 427 `reftex-isearch-minor-mode'.  With a prefix argument ARG, turn
 428 `reftex-isearch-minor-mode' on iff ARG is positive."
 429   (interactive "P")
 430   (let ((old-reftex-isearch-minor-mode reftex-isearch-minor-mode))
 431     (setq reftex-isearch-minor-mode
 432           (not (or (and (null arg) reftex-isearch-minor-mode)
 433                    (<= (prefix-numeric-value arg) 0))))
 434     (unless (eq reftex-isearch-minor-mode old-reftex-isearch-minor-mode)
 435       (if reftex-isearch-minor-mode
 436           (progn
 437             (dolist (crt-buf (buffer-list))
 438               (with-current-buffer crt-buf
 439                 (when reftex-mode
 440                   (set (make-local-variable 'isearch-wrap-function)
 441                        'reftex-isearch-wrap-function)
 442                   (set (make-local-variable 'isearch-search-fun-function)
 443                        (lambda () 'reftex-isearch-isearch-search))
 444                   (set (make-local-variable 'isearch-push-state-function)
 445                        'reftex-isearch-push-state-function)
 446                   (set (make-local-variable 'isearch-next-buffer-function)
 447                        'reftex-isearch-switch-to-next-file)
 448                   (setq reftex-isearch-minor-mode t))))
 449             (add-hook 'reftex-mode-hook 'reftex-isearch-minor-mode))
 450         (dolist (crt-buf (buffer-list))
 451           (with-current-buffer crt-buf
 452             (when reftex-mode
 453               (kill-local-variable 'isearch-wrap-function)
 454               (kill-local-variable 'isearch-search-fun-function)
 455               (kill-local-variable 'isearch-push-state-function)
 456               (kill-local-variable 'isearch-next-buffer-function)
 457               (setq reftex-isearch-minor-mode nil))))
 458         (remove-hook 'reftex-mode-hook 'reftex-isearch-minor-mode)))
 459     ;; Force modeline redisplay.
 460     (set-buffer-modified-p (buffer-modified-p))))
 461
 462 (add-minor-mode 'reftex-isearch-minor-mode "/I" nil nil
 463                 'reftex-isearch-minor-mode)
 464
 465 ;;; arch-tag: 2dbf7633-92c8-4340-8656-7aa019d0f80d
 466 ;;; reftex-global.el ends here