lisp/vc-dir.el

   1 ;;; vc-dir.el --- Directory status display under VC
   2
   3 ;; Copyright (C) 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author:   Dan Nicolaescu <dann@ics.uci.edu>
   7 ;; Keywords: tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Credits:
  25
  26 ;; The original VC directory status implementation was based on dired.
  27 ;; This implementation was inspired by PCL-CVS.
  28 ;; Many people contributed comments, ideas and code to this
  29 ;; implementation.  These include:
  30 ;;
  31 ;;   Alexandre Julliard  <julliard@winehq.org>
  32 ;;   Stefan Monnier  <monnier@iro.umontreal.ca>
  33 ;;   Tom Tromey  <tromey@redhat.com>
  34
  35 ;;; Commentary:
  36 ;;
  37
  38 ;;; Todo:  see vc.el.
  39
  40 (require 'vc-hooks)
  41 (require 'vc)
  42 (require 'tool-bar)
  43 (require 'ewoc)
  44
  45 ;;; Code:
  46 (eval-when-compile
  47   (require 'cl))
  48
  49 (defcustom vc-dir-mode-hook nil
  50   "Normal hook run by `vc-dir-mode'.
  51 See `run-hooks'."
  52   :type 'hook
  53   :group 'vc)
  54
  55 ;; Used to store information for the files displayed in the directory buffer.
  56 ;; Each item displayed corresponds to one of these defstructs.
  57 (defstruct (vc-dir-fileinfo
  58             (:copier nil)
  59             (:type list)            ;So we can use `member' on lists of FIs.
  60             (:constructor
  61              ;; We could define it as an alias for `list'.
  62              vc-dir-create-fileinfo (name state &optional extra marked directory))
  63             (:conc-name vc-dir-fileinfo->))
  64   name                                  ;Keep it as first, for `member'.
  65   state
  66   ;; For storing backend specific information.
  67   extra
  68   marked
  69   ;; To keep track of not updated files during a global refresh
  70   needs-update
  71   ;; To distinguish files and directories.
  72   directory)
  73
  74 (defvar vc-ewoc nil)
  75
  76 (defvar vc-dir-process-buffer nil
  77   "The buffer used for the asynchronous call that computes status.")
  78
  79 (defvar vc-dir-backend nil
  80   "The backend used by the current *vc-dir* buffer.")
  81
  82 (defun vc-dir-move-to-goal-column ()
  83   ;; Used to keep the cursor on the file name column.
  84   (beginning-of-line)
  85   (unless (eolp)
  86     ;; Must be in sync with vc-default-dir-printer.
  87     (forward-char 25)))
  88
  89 (defun vc-dir-prepare-status-buffer (bname dir backend &optional create-new)
  90   "Find a buffer named BNAME showing DIR, or create a new one."
  91   (setq dir (file-name-as-directory (expand-file-name dir)))
  92   (let*
  93          ;; Look for another buffer name BNAME visiting the same directory.
  94          ((buf (save-excursion
  95                 (unless create-new
  96                   (dolist (buffer (buffer-list))
  97                     (set-buffer buffer)
  98                     (when (and (derived-mode-p 'vc-dir-mode)
  99                                (eq vc-dir-backend backend)
 100                                (string= (expand-file-name default-directory) dir))
 101                       (return buffer)))))))
 102     (or buf
 103         ;; Create a new buffer named BNAME.
 104         (with-current-buffer (create-file-buffer bname)
 105           (cd dir)
 106           (vc-setup-buffer (current-buffer))
 107           ;; Reset the vc-parent-buffer-name so that it does not appear
 108           ;; in the mode-line.
 109           (setq vc-parent-buffer-name nil)
 110           (current-buffer)))))
 111
 112 (defvar vc-dir-menu-map
 113   (let ((map (make-sparse-keymap "VC-dir")))
 114     (define-key map [quit]
 115       '(menu-item "Quit" quit-window
 116                   :help "Quit"))
 117     (define-key map [kill]
 118       '(menu-item "Kill Update Command" vc-dir-kill-dir-status-process
 119                   :enable (vc-dir-busy)
 120                   :help "Kill the command that updates the directory buffer"))
 121     (define-key map [refresh]
 122       '(menu-item "Refresh" revert-buffer
 123                   :enable (not (vc-dir-busy))
 124                   :help "Refresh the contents of the directory buffer"))
 125     (define-key map [remup]
 126       '(menu-item "Hide up-to-date" vc-dir-hide-up-to-date
 127                   :help "Hide up-to-date items from display"))
 128     ;; Movement.
 129     (define-key map [sepmv] '("--"))
 130     (define-key map [next-line]
 131       '(menu-item "Next line" vc-dir-next-line
 132                   :help "Go to the next line" :keys "n"))
 133     (define-key map [previous-line]
 134       '(menu-item "Previous line" vc-dir-previous-line
 135                   :help "Go to the previous line"))
 136     ;; Marking.
 137     (define-key map [sepmrk] '("--"))
 138     (define-key map [unmark-all]
 139       '(menu-item "Unmark All" vc-dir-unmark-all-files
 140                   :help "Unmark all files that are in the same state as the current file\
 141 \nWith prefix argument unmark all files"))
 142     (define-key map [unmark-previous]
 143       '(menu-item "Unmark previous " vc-dir-unmark-file-up
 144                   :help "Move to the previous line and unmark the file"))
 145
 146     (define-key map [mark-all]
 147       '(menu-item "Mark All" vc-dir-mark-all-files
 148                   :help "Mark all files that are in the same state as the current file\
 149 \nWith prefix argument mark all files"))
 150     (define-key map [unmark]
 151       '(menu-item "Unmark" vc-dir-unmark
 152                   :help "Unmark the current file or all files in the region"))
 153
 154     (define-key map [mark]
 155       '(menu-item "Mark" vc-dir-mark
 156                   :help "Mark the current file or all files in the region"))
 157
 158     (define-key map [sepopn] '("--"))
 159     (define-key map [qr]
 160       '(menu-item "Query Replace in Files..." vc-dir-query-replace-regexp
 161                   :help "Replace a string in the marked files"))
 162     (define-key map [se]
 163       '(menu-item "Search Files..." vc-dir-search
 164                   :help "Search a regexp in the marked files"))
 165     (define-key map [ires]
 166       '(menu-item "Isearch Regexp Files..." vc-dir-isearch-regexp
 167                   :help "Incremental search a regexp in the marked files"))
 168     (define-key map [ise]
 169       '(menu-item "Isearch Files..." vc-dir-isearch
 170                   :help "Incremental search a string in the marked files"))
 171     (define-key map [open-other]
 172       '(menu-item "Open in other window" vc-dir-find-file-other-window
 173                   :help "Find the file on the current line, in another window"))
 174     (define-key map [open]
 175       '(menu-item "Open file" vc-dir-find-file
 176                   :help "Find the file on the current line"))
 177     (define-key map [sepvcdet] '("--"))
 178     ;; FIXME: This needs a key binding.  And maybe a better name
 179     ;; ("Insert" like PCL-CVS uses does not sound that great either)...
 180     (define-key map [ins]
 181       '(menu-item "Show File" vc-dir-show-fileentry
 182                   :help "Show a file in the VC status listing even though it might be up to date"))
 183     (define-key map [annotate]
 184       '(menu-item "Annotate" vc-annotate
 185                   :help "Display the edit history of the current file using colors"))
 186     (define-key map [diff]
 187       '(menu-item "Compare with Base Version" vc-diff
 188                   :help "Compare file set with the base version"))
 189     (define-key map [log]
 190      '(menu-item "Show history" vc-print-log
 191      :help "List the change log of the current file set in a window"))
 192     ;; VC commands.
 193     (define-key map [sepvccmd] '("--"))
 194     (define-key map [update]
 195       '(menu-item "Update to latest version" vc-update
 196                   :help "Update the current fileset's files to their tip revisions"))
 197     (define-key map [revert]
 198       '(menu-item "Revert to base version" vc-revert
 199                   :help "Revert working copies of the selected fileset to their repository contents."))
 200     (define-key map [next-action]
 201       ;; FIXME: This really really really needs a better name!
 202       ;; And a key binding too.
 203       '(menu-item "Check In/Out" vc-next-action
 204                   :help "Do the next logical version control operation on the current fileset"))
 205     (define-key map [register]
 206       '(menu-item "Register" vc-register
 207                   :help "Register file set into the version control system"))
 208     map)
 209   "Menu for VC dir.")
 210
 211 ;; VC backends can use this to add mode-specific menu items to
 212 ;; vc-dir-menu-map.
 213 (defun vc-dir-menu-map-filter (orig-binding)
 214   (when (and (symbolp orig-binding) (fboundp orig-binding))
 215     (setq orig-binding (indirect-function orig-binding)))
 216   (let ((ext-binding
 217          (when (derived-mode-p 'vc-dir-mode)
 218            (vc-call-backend vc-dir-backend 'extra-status-menu))))
 219     (if (null ext-binding)
 220         orig-binding
 221       (append orig-binding
 222               '("----")
 223               ext-binding))))
 224
 225 (defvar vc-dir-mode-map
 226   (let ((map (make-sparse-keymap)))
 227     ;; VC commands
 228     (define-key map "v" 'vc-next-action)   ;; C-x v v
 229     (define-key map "=" 'vc-diff)          ;; C-x v =
 230     (define-key map "i" 'vc-register)      ;; C-x v i
 231     (define-key map "+" 'vc-update)        ;; C-x v +
 232     (define-key map "l" 'vc-print-log)     ;; C-x v l
 233     ;; More confusing than helpful, probably
 234     ;;(define-key map "R" 'vc-revert) ;; u is taken by vc-dir-unmark.
 235     ;;(define-key map "A" 'vc-annotate) ;; g is taken by revert-buffer
 236     ;;                                     bound by `special-mode'.
 237     ;; Marking.
 238     (define-key map "m" 'vc-dir-mark)
 239     (define-key map "M" 'vc-dir-mark-all-files)
 240     (define-key map "u" 'vc-dir-unmark)
 241     (define-key map "U" 'vc-dir-unmark-all-files)
 242     (define-key map "\C-?" 'vc-dir-unmark-file-up)
 243     (define-key map "\M-\C-?" 'vc-dir-unmark-all-files)
 244     ;; Movement.
 245     (define-key map "n" 'vc-dir-next-line)
 246     (define-key map " " 'vc-dir-next-line)
 247     (define-key map "\t" 'vc-dir-next-directory)
 248     (define-key map "p" 'vc-dir-previous-line)
 249     (define-key map [backtab] 'vc-dir-previous-directory)
 250     ;;; Rebind paragraph-movement commands.
 251     (define-key map "\M-}" 'vc-dir-next-directory)
 252     (define-key map "\M-{" 'vc-dir-previous-directory)
 253     (define-key map [C-down] 'vc-dir-next-directory)
 254     (define-key map [C-up] 'vc-dir-previous-directory)
 255     ;; The remainder.
 256     (define-key map "f" 'vc-dir-find-file)
 257     (define-key map "\C-m" 'vc-dir-find-file)
 258     (define-key map "o" 'vc-dir-find-file-other-window)
 259     (define-key map "\C-c\C-c" 'vc-dir-kill-dir-status-process)
 260     (define-key map [down-mouse-3] 'vc-dir-menu)
 261     (define-key map [mouse-2] 'vc-dir-toggle-mark)
 262     (define-key map [follow-link] 'mouse-face)
 263     (define-key map "x" 'vc-dir-hide-up-to-date)
 264     (define-key map "S" 'vc-dir-search) ;; FIXME: Maybe use A like dired?
 265     (define-key map "Q" 'vc-dir-query-replace-regexp)
 266     (define-key map (kbd "M-s a C-s")   'vc-dir-isearch)
 267     (define-key map (kbd "M-s a M-C-s") 'vc-dir-isearch-regexp)
 268
 269     ;; Hook up the menu.
 270     (define-key map [menu-bar vc-dir-mode]
 271       `(menu-item
 272         ;; VC backends can use this to add mode-specific menu items to
 273         ;; vc-dir-menu-map.
 274         "VC-dir" ,vc-dir-menu-map :filter vc-dir-menu-map-filter))
 275     map)
 276   "Keymap for directory buffer.")
 277
 278 (defmacro vc-dir-at-event (event &rest body)
 279   "Evaluate BODY with point located at event-start of EVENT.
 280 If BODY uses EVENT, it should be a variable,
 281  otherwise it will be evaluated twice."
 282   (let ((posn (make-symbol "vc-dir-at-event-posn")))
 283     `(save-excursion
 284        (unless (equal ,event '(tool-bar))
 285          (let ((,posn (event-start ,event)))
 286            (set-buffer (window-buffer (posn-window ,posn)))
 287            (goto-char (posn-point ,posn))))
 288        ,@body)))
 289
 290 (defun vc-dir-menu (e)
 291   "Popup the VC dir menu."
 292   (interactive "e")
 293   (vc-dir-at-event e (popup-menu vc-dir-menu-map e)))
 294
 295 (defvar vc-dir-tool-bar-map
 296   (let ((map (make-sparse-keymap)))
 297     (tool-bar-local-item-from-menu 'vc-dir-find-file "open"
 298                                    map vc-dir-mode-map)
 299     (tool-bar-local-item "bookmark_add"
 300                          'vc-dir-toggle-mark 'vc-dir-toggle-mark map
 301                          :help "Toggle mark on current item")
 302     (tool-bar-local-item-from-menu 'vc-dir-previous-line "left-arrow"
 303                                    map vc-dir-mode-map
 304                                    :rtl "right-arrow")
 305     (tool-bar-local-item-from-menu 'vc-dir-next-line "right-arrow"
 306                                    map vc-dir-mode-map
 307                                    :rtl "left-arrow")
 308     (tool-bar-local-item-from-menu 'vc-print-log "info"
 309                                    map vc-dir-mode-map)
 310     (tool-bar-local-item-from-menu 'revert-buffer "refresh"
 311                                    map vc-dir-mode-map)
 312     (tool-bar-local-item-from-menu 'nonincremental-search-forward
 313                                    "search" map)
 314     (tool-bar-local-item-from-menu 'vc-dir-query-replace-regexp
 315                                    "search-replace" map vc-dir-mode-map)
 316     (tool-bar-local-item-from-menu 'vc-dir-kill-dir-status-process "cancel"
 317                                    map vc-dir-mode-map)
 318     (tool-bar-local-item-from-menu 'quit-window "exit"
 319                                    map vc-dir-mode-map)
 320     map))
 321
 322 (defun vc-dir-node-directory (node)
 323   ;; Compute the directory for NODE.
 324   ;; If it's a directory node, get it from the the node.
 325   (let ((data (ewoc-data node)))
 326     (or (vc-dir-fileinfo->directory data)
 327         ;; Otherwise compute it from the file name.
 328         (file-name-directory
 329          (directory-file-name
 330           (expand-file-name
 331            (vc-dir-fileinfo->name data)))))))
 332
 333 (defun vc-dir-update (entries buffer &optional noinsert)
 334   "Update BUFFER's ewoc from the list of ENTRIES.
 335 If NOINSERT, ignore elements on ENTRIES which are not in the ewoc."
 336   ;; Add ENTRIES to the vc-dir buffer BUFFER.
 337   (with-current-buffer buffer
 338     ;; Insert the entries sorted by name into the ewoc.
 339     ;; We assume the ewoc is sorted too, which should be the
 340     ;; case if we always add entries with vc-dir-update.
 341     (setq entries
 342           ;; Sort: first files and then subdirectories.
 343           ;; XXX: this is VERY inefficient, it computes the directory
 344           ;; names too many times
 345           (sort entries
 346                 (lambda (entry1 entry2)
 347                   (let ((dir1 (file-name-directory
 348                                 (directory-file-name (expand-file-name (car entry1)))))
 349                         (dir2 (file-name-directory
 350                                (directory-file-name (expand-file-name (car entry2))))))
 351                     (cond
 352                      ((string< dir1 dir2) t)
 353                      ((not (string= dir1 dir2)) nil)
 354                      ((string< (car entry1) (car entry2))))))))
 355     ;; Insert directory entries in the right places.
 356     (let ((entry (car entries))
 357           (node (ewoc-nth vc-ewoc 0))
 358           (dotname (file-relative-name default-directory)))
 359       ;; Insert . if it is not present.
 360       (unless node
 361         (ewoc-enter-last
 362          vc-ewoc (vc-dir-create-fileinfo
 363                   dotname nil nil nil (expand-file-name default-directory)))
 364         (setq node (ewoc-nth vc-ewoc 0)))
 365
 366       (while (and entry node)
 367         (let* ((entryfile (car entry))
 368                (entrydir (file-name-directory (directory-file-name
 369                                                (expand-file-name entryfile))))
 370                (nodedir (vc-dir-node-directory node)))
 371           (message "entryfile %s entrydir %s" entryfile entrydir)
 372           (cond
 373            ;; First try to find the directory.
 374            ((string-lessp nodedir entrydir)
 375             (setq node (ewoc-next vc-ewoc node)))
 376            ((string-equal nodedir entrydir)
 377             ;; Found the directory, find the place for the file name.
 378             (let ((nodefile (vc-dir-fileinfo->name (ewoc-data node))))
 379               (cond
 380                ((string= nodefile dotname)
 381                 (setq node (ewoc-next vc-ewoc node)))
 382                ((string-lessp nodefile entryfile)
 383                 (setq node (ewoc-next vc-ewoc node)))
 384                ((string-equal nodefile entryfile)
 385                 (setf (vc-dir-fileinfo->state (ewoc-data node)) (nth 1 entry))
 386                 (setf (vc-dir-fileinfo->extra (ewoc-data node)) (nth 2 entry))
 387                 (setf (vc-dir-fileinfo->needs-update (ewoc-data node)) nil)
 388                 (ewoc-invalidate vc-ewoc node)
 389                 (setq entries (cdr entries))
 390                 (setq entry (car entries))
 391                 (setq node (ewoc-next vc-ewoc node)))
 392                (t
 393                 (ewoc-enter-before vc-ewoc node
 394                                    (apply 'vc-dir-create-fileinfo entry))
 395                 (setq entries (cdr entries))
 396                 (setq entry (car entries))))))
 397            (t
 398             ;; We might need to insert a directory node if the
 399             ;; previous node was in a different directory.
 400             (let* ((rd (file-relative-name entrydir))
 401                    (prev-node (ewoc-prev vc-ewoc node))
 402                    (prev-dir (vc-dir-node-directory prev-node)))
 403               (unless (string-equal entrydir prev-dir)
 404                 (ewoc-enter-before
 405                  vc-ewoc node (vc-dir-create-fileinfo rd nil nil nil entrydir))))
 406             ;; Now insert the node itself.
 407             (ewoc-enter-before vc-ewoc node
 408                                (apply 'vc-dir-create-fileinfo entry))
 409             (setq entries (cdr entries) entry (car entries))))))
 410       ;; We're past the last node, all remaining entries go to the end.
 411       (unless (or node noinsert)
 412         (let ((lastdir (vc-dir-node-directory (ewoc-nth vc-ewoc -1))))
 413           (dolist (entry entries)
 414             (let ((entrydir (file-name-directory
 415                              (directory-file-name (expand-file-name (car entry))))))
 416               ;; Insert a directory node if needed.
 417               (unless (string-equal lastdir entrydir)
 418                 (setq lastdir entrydir)
 419                 (let ((rd (file-relative-name entrydir)))
 420                   (ewoc-enter-last
 421                    vc-ewoc (vc-dir-create-fileinfo rd nil nil nil entrydir))))
 422               ;; Now insert the node itself.
 423               (ewoc-enter-last vc-ewoc
 424                                (apply 'vc-dir-create-fileinfo entry)))))))))
 425
 426 (defun vc-dir-busy ()
 427   (and (buffer-live-p vc-dir-process-buffer)
 428        (get-buffer-process vc-dir-process-buffer)))
 429
 430 (defun vc-dir-kill-dir-status-process ()
 431   "Kill the temporary buffer and associated process."
 432   (interactive)
 433   (when (buffer-live-p vc-dir-process-buffer)
 434     (let ((proc (get-buffer-process vc-dir-process-buffer)))
 435       (when proc (delete-process proc))
 436       (setq vc-dir-process-buffer nil)
 437       (setq mode-line-process nil))))
 438
 439 (defun vc-dir-kill-query ()
 440   ;; Make sure that when the status buffer is killed the update
 441   ;; process running in background is also killed.
 442   (if (vc-dir-busy)
 443     (when (y-or-n-p "Status update process running, really kill status buffer? ")
 444       (vc-dir-kill-dir-status-process)
 445       t)
 446     t))
 447
 448 (defun vc-dir-next-line (arg)
 449   "Go to the next line.
 450 If a prefix argument is given, move by that many lines."
 451   (interactive "p")
 452   (with-no-warnings
 453     (ewoc-goto-next vc-ewoc arg)
 454     (vc-dir-move-to-goal-column)))
 455
 456 (defun vc-dir-previous-line (arg)
 457   "Go to the previous line.
 458 If a prefix argument is given, move by that many lines."
 459   (interactive "p")
 460   (ewoc-goto-prev vc-ewoc arg)
 461   (vc-dir-move-to-goal-column))
 462
 463 (defun vc-dir-next-directory ()
 464   "Go to the next directory."
 465   (interactive)
 466   (let ((orig (point)))
 467     (if
 468         (catch 'foundit
 469           (while t
 470             (let* ((next (ewoc-next vc-ewoc (ewoc-locate vc-ewoc))))
 471               (cond ((not next)
 472                      (throw 'foundit t))
 473                     (t
 474                      (progn
 475                        (ewoc-goto-node vc-ewoc next)
 476                        (vc-dir-move-to-goal-column)
 477                        (if (vc-dir-fileinfo->directory (ewoc-data next))
 478                            (throw 'foundit nil))))))))
 479         (goto-char orig))))
 480
 481 (defun vc-dir-previous-directory ()
 482   "Go to the previous directory."
 483   (interactive)
 484   (let ((orig (point)))
 485     (if
 486         (catch 'foundit
 487           (while t
 488             (let* ((prev (ewoc-prev vc-ewoc (ewoc-locate vc-ewoc))))
 489               (cond ((not prev)
 490                      (throw 'foundit t))
 491                     (t
 492                      (progn
 493                        (ewoc-goto-node vc-ewoc prev)
 494                        (vc-dir-move-to-goal-column)
 495                        (if (vc-dir-fileinfo->directory (ewoc-data prev))
 496                            (throw 'foundit nil))))))))
 497         (goto-char orig))))
 498
 499 (defun vc-dir-mark-unmark (mark-unmark-function)
 500   (if (use-region-p)
 501       (let ((firstl (line-number-at-pos (region-beginning)))
 502             (lastl (line-number-at-pos (region-end))))
 503         (save-excursion
 504           (goto-char (region-beginning))
 505           (while (<= (line-number-at-pos) lastl)
 506             (funcall mark-unmark-function))))
 507     (funcall mark-unmark-function)))
 508
 509 (defun vc-dir-parent-marked-p (arg)
 510   ;; Return nil if none of the parent directories of arg is marked.
 511   (let* ((argdir (vc-dir-node-directory arg))
 512          (arglen (length argdir))
 513          (crt arg)
 514          data dir)
 515     ;; Go through the predecessors, checking if any directory that is
 516     ;; a parent is marked.
 517     (while (setq crt (ewoc-prev vc-ewoc crt))
 518       (setq data (ewoc-data crt))
 519       (setq dir (vc-dir-node-directory crt))
 520       (when (and (vc-dir-fileinfo->directory data)
 521                  (vc-string-prefix-p dir argdir))
 522         (when (vc-dir-fileinfo->marked data)
 523           (error "Cannot mark `%s', parent directory `%s' marked"
 524                  (vc-dir-fileinfo->name (ewoc-data arg))
 525                  (vc-dir-fileinfo->name data)))))
 526     nil))
 527
 528 (defun vc-dir-children-marked-p (arg)
 529   ;; Return nil if none of the children of arg is marked.
 530   (let* ((argdir-re (concat "\\`" (regexp-quote (vc-dir-node-directory arg))))
 531          (is-child t)
 532          (crt arg)
 533          data dir)
 534     (while (and is-child (setq crt (ewoc-next vc-ewoc crt)))
 535       (setq data (ewoc-data crt))
 536       (setq dir (vc-dir-node-directory crt))
 537       (if (string-match argdir-re dir)
 538           (when (vc-dir-fileinfo->marked data)
 539             (error "Cannot mark `%s', child `%s' marked"
 540                    (vc-dir-fileinfo->name (ewoc-data arg))
 541                    (vc-dir-fileinfo->name data)))
 542         ;; We are done, we got to an entry that is not a child of `arg'.
 543         (setq is-child nil)))
 544     nil))
 545
 546 (defun vc-dir-mark-file (&optional arg)
 547   ;; Mark ARG or the current file and move to the next line.
 548   (let* ((crt (or arg (ewoc-locate vc-ewoc)))
 549          (file (ewoc-data crt))
 550          (isdir (vc-dir-fileinfo->directory file)))
 551     (when (or (and isdir (not (vc-dir-children-marked-p crt)))
 552               (and (not isdir) (not (vc-dir-parent-marked-p crt))))
 553       (setf (vc-dir-fileinfo->marked file) t)
 554       (ewoc-invalidate vc-ewoc crt)
 555       (unless (or arg (mouse-event-p last-command-event))
 556         (vc-dir-next-line 1)))))
 557
 558 (defun vc-dir-mark ()
 559   "Mark the current file or all files in the region.
 560 If the region is active, mark all the files in the region.
 561 Otherwise mark the file on the current line and move to the next
 562 line."
 563   (interactive)
 564   (vc-dir-mark-unmark 'vc-dir-mark-file))
 565
 566 (defun vc-dir-mark-all-files (arg)
 567   "Mark all files with the same state as the current one.
 568 With a prefix argument mark all files.
 569 If the current entry is a directory, mark all child files.
 570
 571 The commands operate on files that are on the same state.
 572 This command is intended to make it easy to select all files that
 573 share the same state."
 574   (interactive "P")
 575   (if arg
 576       ;; Mark all files.
 577       (progn
 578         ;; First check that no directory is marked, we can't mark
 579         ;; files in that case.
 580         (ewoc-map
 581          (lambda (filearg)
 582            (when (and (vc-dir-fileinfo->directory filearg)
 583                       (vc-dir-fileinfo->marked filearg))
 584              (error "Cannot mark all files, directory `%s' marked"
 585                     (vc-dir-fileinfo->name filearg))))
 586          vc-ewoc)
 587         (ewoc-map
 588          (lambda (filearg)
 589            (unless (vc-dir-fileinfo->marked filearg)
 590              (setf (vc-dir-fileinfo->marked filearg) t)
 591              t))
 592          vc-ewoc))
 593     (let ((data (ewoc-data (ewoc-locate vc-ewoc))))
 594       (if (vc-dir-fileinfo->directory data)
 595           ;; It's a directory, mark child files.
 596           (let ((crt (ewoc-locate vc-ewoc)))
 597             (unless (vc-dir-children-marked-p crt)
 598               (while (setq crt (ewoc-next vc-ewoc crt))
 599                 (let ((crt-data (ewoc-data crt)))
 600                   (unless (vc-dir-fileinfo->directory crt-data)
 601                     (setf (vc-dir-fileinfo->marked crt-data) t)
 602                     (ewoc-invalidate vc-ewoc crt))))))
 603         ;; It's a file
 604         (let ((state (vc-dir-fileinfo->state data))
 605               (crt (ewoc-nth vc-ewoc 0)))
 606           (while crt
 607             (let ((crt-data (ewoc-data crt)))
 608               (when (and (not (vc-dir-fileinfo->marked crt-data))
 609                          (eq (vc-dir-fileinfo->state crt-data) state)
 610                          (not (vc-dir-fileinfo->directory crt-data)))
 611                 (vc-dir-mark-file crt)))
 612             (setq crt (ewoc-next vc-ewoc crt))))))))
 613
 614 (defun vc-dir-unmark-file ()
 615   ;; Unmark the current file and move to the next line.
 616   (let* ((crt (ewoc-locate vc-ewoc))
 617          (file (ewoc-data crt)))
 618     (setf (vc-dir-fileinfo->marked file) nil)
 619     (ewoc-invalidate vc-ewoc crt)
 620     (unless (mouse-event-p last-command-event)
 621       (vc-dir-next-line 1))))
 622
 623 (defun vc-dir-unmark ()
 624   "Unmark the current file or all files in the region.
 625 If the region is active, unmark all the files in the region.
 626 Otherwise mark the file on the current line and move to the next
 627 line."
 628   (interactive)
 629   (vc-dir-mark-unmark 'vc-dir-unmark-file))
 630
 631 (defun vc-dir-unmark-file-up ()
 632   "Move to the previous line and unmark the file."
 633   (interactive)
 634   ;; If we're on the first line, we won't move up, but we will still
 635   ;; remove the mark.  This seems a bit odd but it is what buffer-menu
 636   ;; does.
 637   (let* ((prev (ewoc-goto-prev vc-ewoc 1))
 638          (file (ewoc-data prev)))
 639     (setf (vc-dir-fileinfo->marked file) nil)
 640     (ewoc-invalidate vc-ewoc prev)
 641     (vc-dir-move-to-goal-column)))
 642
 643 (defun vc-dir-unmark-all-files (arg)
 644   "Unmark all files with the same state as the current one.
 645 With a prefix argument unmark all files.
 646 If the current entry is a directory, unmark all the child files.
 647
 648 The commands operate on files that are on the same state.
 649 This command is intended to make it easy to deselect all files
 650 that share the same state."
 651   (interactive "P")
 652   (if arg
 653       (ewoc-map
 654        (lambda (filearg)
 655          (when (vc-dir-fileinfo->marked filearg)
 656            (setf (vc-dir-fileinfo->marked filearg) nil)
 657            t))
 658        vc-ewoc)
 659     (let* ((crt (ewoc-locate vc-ewoc))
 660            (data (ewoc-data crt)))
 661       (if (vc-dir-fileinfo->directory data)
 662           ;; It's a directory, unmark child files.
 663           (while (setq crt (ewoc-next vc-ewoc crt))
 664             (let ((crt-data (ewoc-data crt)))
 665               (unless (vc-dir-fileinfo->directory crt-data)
 666                 (setf (vc-dir-fileinfo->marked crt-data) nil)
 667                 (ewoc-invalidate vc-ewoc crt))))
 668         ;; It's a file
 669         (let ((crt-state (vc-dir-fileinfo->state (ewoc-data crt))))
 670           (ewoc-map
 671            (lambda (filearg)
 672              (when (and (vc-dir-fileinfo->marked filearg)
 673                         (eq (vc-dir-fileinfo->state filearg) crt-state))
 674                (setf (vc-dir-fileinfo->marked filearg) nil)
 675                t))
 676            vc-ewoc))))))
 677
 678 (defun vc-dir-toggle-mark-file ()
 679   (let* ((crt (ewoc-locate vc-ewoc))
 680          (file (ewoc-data crt)))
 681     (if (vc-dir-fileinfo->marked file)
 682         (vc-dir-unmark-file)
 683       (vc-dir-mark-file))))
 684
 685 (defun vc-dir-toggle-mark (e)
 686   (interactive "e")
 687   (vc-dir-at-event e (vc-dir-mark-unmark 'vc-dir-toggle-mark-file)))
 688
 689 (defun vc-dir-delete-file ()
 690   "Delete the marked files, or the current file if no marks."
 691   (interactive)
 692   (mapc 'vc-delete-file (or (vc-dir-marked-files)
 693                             (list (vc-dir-current-file)))))
 694
 695 (defun vc-dir-find-file ()
 696   "Find the file on the current line."
 697   (interactive)
 698   (find-file (vc-dir-current-file)))
 699
 700 (defun vc-dir-find-file-other-window (&optional event)
 701   "Find the file on the current line, in another window."
 702   (interactive (list last-nonmenu-event))
 703   (if event (posn-set-point (event-end event)))
 704   (find-file-other-window (vc-dir-current-file)))
 705
 706 (defun vc-dir-isearch ()
 707   "Search for a string through all marked buffers using Isearch."
 708   (interactive)
 709   (multi-isearch-files
 710    (mapcar 'car (vc-dir-marked-only-files-and-states))))
 711
 712 (defun vc-dir-isearch-regexp ()
 713   "Search for a regexp through all marked buffers using Isearch."
 714   (interactive)
 715   (multi-isearch-files-regexp
 716    (mapcar 'car (vc-dir-marked-only-files-and-states))))
 717
 718 (defun vc-dir-search (regexp)
 719   "Search through all marked files for a match for REGEXP.
 720 For marked directories, use the files displayed from those directories.
 721 Stops when a match is found.
 722 To continue searching for next match, use command \\[tags-loop-continue]."
 723   (interactive "sSearch marked files (regexp): ")
 724   (tags-search regexp '(mapcar 'car (vc-dir-marked-only-files-and-states))))
 725
 726 (defun vc-dir-query-replace-regexp (from to &optional delimited)
 727   "Do `query-replace-regexp' of FROM with TO, on all marked files.
 728 For marked directories, use the files displayed from those directories.
 729 If a directory is marked, then use the files displayed for that directory.
 730 Third arg DELIMITED (prefix arg) means replace only word-delimited matches.
 731 If you exit (\\[keyboard-quit], RET or q), you can resume the query replace
 732 with the command \\[tags-loop-continue]."
 733   ;; FIXME: this is almost a copy of `dired-do-replace-regexp'.  This
 734   ;; should probably be made generic and used in both places instead of
 735   ;; duplicating it here.
 736   (interactive
 737    (let ((common
 738           (query-replace-read-args
 739            "Query replace regexp in marked files" t t)))
 740      (list (nth 0 common) (nth 1 common) (nth 2 common))))
 741   (dolist (file (mapcar 'car (vc-dir-marked-only-files-and-states)))
 742     (let ((buffer (get-file-buffer file)))
 743       (if (and buffer (with-current-buffer buffer
 744                         buffer-read-only))
 745           (error "File `%s' is visited read-only" file))))
 746   (tags-query-replace from to delimited
 747                       '(mapcar 'car (vc-dir-marked-only-files-and-states))))
 748
 749 (defun vc-dir-current-file ()
 750   (let ((node (ewoc-locate vc-ewoc)))
 751     (unless node
 752       (error "No file available"))
 753     (expand-file-name (vc-dir-fileinfo->name (ewoc-data node)))))
 754
 755 (defun vc-dir-marked-files ()
 756   "Return the list of marked files."
 757   (mapcar
 758    (lambda (elem) (expand-file-name (vc-dir-fileinfo->name elem)))
 759    (ewoc-collect vc-ewoc 'vc-dir-fileinfo->marked)))
 760
 761 (defun vc-dir-marked-only-files-and-states ()
 762   "Return the list of conses (FILE . STATE) for the marked files.
 763 For marked directories return the corresponding conses for the
 764 child files."
 765   (let ((crt (ewoc-nth vc-ewoc 0))
 766         result)
 767     (while crt
 768       (let ((crt-data (ewoc-data crt)))
 769         (if (vc-dir-fileinfo->marked crt-data)
 770             ;; FIXME: use vc-dir-child-files-and-states here instead of duplicating it.
 771             (if (vc-dir-fileinfo->directory crt-data)
 772                 (let* ((dir (vc-dir-fileinfo->directory crt-data))
 773                        (dirlen (length dir))
 774                        data)
 775                   (while
 776                       (and (setq crt (ewoc-next vc-ewoc crt))
 777                            (vc-string-prefix-p dir
 778                                                (progn
 779                                                  (setq data (ewoc-data crt))
 780                                                  (vc-dir-node-directory crt))))
 781                     (unless (vc-dir-fileinfo->directory data)
 782                       (push
 783                        (cons (expand-file-name (vc-dir-fileinfo->name data))
 784                              (vc-dir-fileinfo->state data))
 785                        result))))
 786               (push (cons (expand-file-name (vc-dir-fileinfo->name crt-data))
 787                           (vc-dir-fileinfo->state crt-data))
 788                     result)
 789               (setq crt (ewoc-next vc-ewoc crt)))
 790           (setq crt (ewoc-next vc-ewoc crt)))))
 791     (nreverse result)))
 792
 793 (defun vc-dir-child-files-and-states ()
 794   "Return the list of conses (FILE . STATE) for child files of the current entry if it's a directory.
 795 If it is a file, return the corresponding cons for the file itself."
 796   (let* ((crt (ewoc-locate vc-ewoc))
 797          (crt-data (ewoc-data crt))
 798          result)
 799     (if (vc-dir-fileinfo->directory crt-data)
 800         (let* ((dir (vc-dir-fileinfo->directory crt-data))
 801                (dirlen (length dir))
 802                data)
 803           (while
 804               (and (setq crt (ewoc-next vc-ewoc crt))
 805                    (vc-string-prefix-p dir (progn
 806                                              (setq data (ewoc-data crt))
 807                                              (vc-dir-node-directory crt))))
 808             (unless (vc-dir-fileinfo->directory data)
 809               (push
 810                (cons (expand-file-name (vc-dir-fileinfo->name data))
 811                      (vc-dir-fileinfo->state data))
 812                result))))
 813       (push
 814        (cons (expand-file-name (vc-dir-fileinfo->name crt-data))
 815              (vc-dir-fileinfo->state crt-data)) result))
 816     (nreverse result)))
 817
 818 (defun vc-dir-recompute-file-state (fname def-dir)
 819   (let* ((file-short (file-relative-name fname def-dir))
 820          (remove-me-when-CVS-works
 821           (when (eq vc-dir-backend 'CVS)
 822             ;; FIXME: Warning: UGLY HACK.  The CVS backend caches the state
 823             ;; info, this forces the backend to update it.
 824             (vc-call-backend vc-dir-backend 'registered fname)))
 825          (state (vc-call-backend vc-dir-backend 'state fname))
 826          (extra (vc-call-backend vc-dir-backend
 827                                  'status-fileinfo-extra fname)))
 828     (list file-short state extra)))
 829
 830 (defun vc-dir-find-child-files (dirname)
 831   ;; Give a DIRNAME string return the list of all child files shown in
 832   ;; the current *vc-dir* buffer.
 833   (let ((crt (ewoc-nth vc-ewoc 0))
 834         children
 835         dname)
 836     ;; Find DIR
 837     (while (and crt (not (vc-string-prefix-p
 838                           dirname (vc-dir-node-directory crt))))
 839       (setq crt (ewoc-next vc-ewoc crt)))
 840     (while (and crt (vc-string-prefix-p
 841                      dirname
 842                      (setq dname (vc-dir-node-directory crt))))
 843       (let ((data (ewoc-data crt)))
 844         (unless (vc-dir-fileinfo->directory data)
 845           (push (expand-file-name (vc-dir-fileinfo->name data)) children)))
 846       (setq crt (ewoc-next vc-ewoc crt)))
 847     children))
 848
 849 (defun vc-dir-resync-directory-files (dirname)
 850   ;; Update the entries for all the child files of DIRNAME shown in
 851   ;; the current *vc-dir* buffer.
 852   (let ((files (vc-dir-find-child-files dirname))
 853         (ddir (expand-file-name default-directory))
 854         fileentries)
 855     (when files
 856       (dolist (crt files)
 857         (push (vc-dir-recompute-file-state crt ddir)
 858               fileentries))
 859       (vc-dir-update fileentries (current-buffer)))))
 860
 861 (defun vc-dir-resynch-file (&optional fname)
 862   "Update the entries for FNAME in any directory buffers that list it."
 863   (let ((file (or fname (expand-file-name buffer-file-name)))
 864         (found-vc-dir-buf nil))
 865     (save-excursion
 866       (dolist (status-buf (buffer-list))
 867         (set-buffer status-buf)
 868         ;; look for a vc-dir buffer that might show this file.
 869         (when (derived-mode-p 'vc-dir-mode)
 870           (setq found-vc-dir-buf t)
 871           (let ((ddir (expand-file-name default-directory)))
 872             (when (vc-string-prefix-p ddir file)
 873               (if (file-directory-p file)
 874                   (vc-dir-resync-directory-files file)
 875                 (let ((state (vc-dir-recompute-file-state file ddir)))
 876                   (vc-dir-update
 877                    (list state)
 878                    status-buf (eq (cadr state) 'up-to-date)))))))))
 879     ;; We didn't find any vc-dir buffers, remove the hook, it is
 880     ;; not needed.
 881     (unless found-vc-dir-buf
 882       (remove-hook 'after-save-hook 'vc-dir-resynch-file))))
 883
 884 (defvar use-vc-backend)  ;; dynamically bound
 885
 886 (define-derived-mode vc-dir-mode special-mode "VC dir"
 887   "Major mode for VC directory buffers.
 888 Marking/Unmarking key bindings and actions:
 889 m - mark a file/directory
 890   - if the region is active, mark all the files in region.
 891     Restrictions: - a file cannot be marked if any parent directory is marked
 892                   - a directory cannot be marked if any child file or
 893                     directory is marked
 894 u - unmark a file/directory
 895   - if the region is active, unmark all the files in region.
 896 M - if the cursor is on a file: mark all the files with the same state as
 897       the current file
 898   - if the cursor is on a directory: mark all child files
 899   - with a prefix argument: mark all files
 900 U - if the cursor is on a file: unmark all the files with the same state
 901       as the current file
 902   - if the cursor is on a directory: unmark all child files
 903   - with a prefix argument: unmark all files
 904 mouse-2  - toggles the mark state
 905
 906 VC commands
 907 VC commands in the `C-x v' prefix can be used.
 908 VC commands act on the marked entries.  If nothing is marked, VC
 909 commands act on the current entry.
 910
 911 Search & Replace
 912 S - searches the marked files
 913 Q - does a query replace on the marked files
 914 M-s a C-s - does an isearch on the marked files
 915 M-s a C-M-s - does a regexp isearch on the marked files
 916 If nothing is marked, these commands act on the current entry.
 917 When a directory is current or marked, the Search & Replace
 918 commands act on the child files of that directory that are displayed in
 919 the *vc-dir* buffer.
 920
 921 \\{vc-dir-mode-map}"
 922   (set (make-local-variable 'vc-dir-backend) use-vc-backend)
 923   (setq buffer-read-only t)
 924   (when (boundp 'tool-bar-map)
 925     (set (make-local-variable 'tool-bar-map) vc-dir-tool-bar-map))
 926   (let ((buffer-read-only nil))
 927     (erase-buffer)
 928     (set (make-local-variable 'vc-dir-process-buffer) nil)
 929     (set (make-local-variable 'vc-ewoc) (ewoc-create #'vc-dir-printer))
 930     (set (make-local-variable 'revert-buffer-function)
 931          'vc-dir-revert-buffer-function)
 932     (set (make-local-variable 'list-buffers-directory)
 933          (expand-file-name default-directory))
 934     (add-hook 'after-save-hook 'vc-dir-resynch-file)
 935     ;; Make sure that if the directory buffer is killed, the update
 936     ;; process running in the background is also killed.
 937     (add-hook 'kill-buffer-query-functions 'vc-dir-kill-query nil t)
 938     (vc-dir-refresh)))
 939
 940 (defun vc-dir-headers (backend dir)
 941   "Display the headers in the *VC dir* buffer.
 942 It calls the `dir-extra-headers' backend method to display backend
 943 specific headers."
 944   (concat
 945    ;; First layout the common headers.
 946    (propertize "VC backend : " 'face 'font-lock-type-face)
 947    (propertize (format "%s\n" backend) 'face 'font-lock-variable-name-face)
 948    (propertize "Working dir: " 'face 'font-lock-type-face)
 949    (propertize (format "%s\n" dir) 'face 'font-lock-variable-name-face)
 950    ;; Then the backend specific ones.
 951    (vc-call-backend backend 'dir-extra-headers dir)
 952    "\n"))
 953
 954 (defun vc-dir-refresh-files (files default-state)
 955   "Refresh some files in the *VC-dir* buffer."
 956   (let ((def-dir default-directory)
 957         (backend vc-dir-backend))
 958     (vc-set-mode-line-busy-indicator)
 959     ;; Call the `dir-status-file' backend function.
 960     ;; `dir-status-file' is supposed to be asynchronous.
 961     ;; It should compute the results, and then call the function
 962     ;; passed as an argument in order to update the vc-dir buffer
 963     ;; with the results.
 964     (unless (buffer-live-p vc-dir-process-buffer)
 965       (setq vc-dir-process-buffer
 966             (generate-new-buffer (format " *VC-%s* tmp status" backend))))
 967     (lexical-let ((buffer (current-buffer)))
 968       (with-current-buffer vc-dir-process-buffer
 969         (cd def-dir)
 970         (erase-buffer)
 971         (vc-call-backend
 972          backend 'dir-status-files def-dir files default-state
 973          (lambda (entries &optional more-to-come)
 974            ;; ENTRIES is a list of (FILE VC_STATE EXTRA) items.
 975            ;; If MORE-TO-COME is true, then more updates will come from
 976            ;; the asynchronous process.
 977            (with-current-buffer buffer
 978              (vc-dir-update entries buffer)
 979              (unless more-to-come
 980                (setq mode-line-process nil)
 981                ;; Remove the ones that haven't been updated at all.
 982                ;; Those not-updated are those whose state is nil because the
 983                ;; file/dir doesn't exist and isn't versioned.
 984                (ewoc-filter vc-ewoc
 985                             (lambda (info)
 986                               ;; The state for directory entries might
 987                               ;; have been changed to 'up-to-date,
 988                               ;; reset it, othewise it will be removed when doing 'x'
 989                               ;; next time.
 990                               ;; FIXME: There should be a more elegant way to do this.
 991                               (when (and (vc-dir-fileinfo->directory info)
 992                                          (eq (vc-dir-fileinfo->state info)
 993                                              'up-to-date))
 994                                 (setf (vc-dir-fileinfo->state info) nil))
 995
 996                               (not (vc-dir-fileinfo->needs-update info))))))))))))
 997
 998 (defun vc-dir-revert-buffer-function (&optional ignore-auto noconfirm)
 999   (vc-dir-refresh))
1000
1001 (defun vc-dir-refresh ()
1002   "Refresh the contents of the *VC-dir* buffer.
1003 Throw an error if another update process is in progress."
1004   (interactive)
1005   (if (vc-dir-busy)
1006       (error "Another update process is in progress, cannot run two at a time")
1007     (let ((def-dir default-directory)
1008           (backend vc-dir-backend))
1009       (vc-set-mode-line-busy-indicator)
1010       ;; Call the `dir-status' backend function.
1011       ;; `dir-status' is supposed to be asynchronous.
1012       ;; It should compute the results, and then call the function
1013       ;; passed as an argument in order to update the vc-dir buffer
1014       ;; with the results.
1015
1016       ;; Create a buffer that can be used by `dir-status' and call
1017       ;; `dir-status' with this buffer as the current buffer.  Use
1018       ;; `vc-dir-process-buffer' to remember this buffer, so that
1019       ;; it can be used later to kill the update process in case it
1020       ;; takes too long.
1021       (unless (buffer-live-p vc-dir-process-buffer)
1022         (setq vc-dir-process-buffer
1023               (generate-new-buffer (format " *VC-%s* tmp status" backend))))
1024       ;; set the needs-update flag on all non-directory entries
1025       (ewoc-map (lambda (info)
1026                   (unless (vc-dir-fileinfo->directory info)
1027                     (setf (vc-dir-fileinfo->needs-update info) t) nil))
1028                 vc-ewoc)
1029       (lexical-let ((buffer (current-buffer)))
1030         (with-current-buffer vc-dir-process-buffer
1031           (cd def-dir)
1032           (erase-buffer)
1033           (vc-call-backend
1034            backend 'dir-status def-dir
1035            (lambda (entries &optional more-to-come)
1036              ;; ENTRIES is a list of (FILE VC_STATE EXTRA) items.
1037              ;; If MORE-TO-COME is true, then more updates will come from
1038              ;; the asynchronous process.
1039              (with-current-buffer buffer
1040                (vc-dir-update entries buffer)
1041                (unless more-to-come
1042                  (let ((remaining
1043                         (ewoc-collect
1044                          vc-ewoc 'vc-dir-fileinfo->needs-update)))
1045                    (if remaining
1046                        (vc-dir-refresh-files
1047                         (mapcar 'vc-dir-fileinfo->name remaining)
1048                         'up-to-date)
1049                      (setq mode-line-process nil)))))))))
1050       (ewoc-set-hf vc-ewoc (vc-dir-headers backend def-dir) ""))))
1051
1052 (defun vc-dir-show-fileentry (file)
1053   "Insert an entry for a specific file into the current *VC-dir* listing.
1054 This is typically used if the file is up-to-date (or has been added
1055 outside of VC) and one wants to do some operation on it."
1056   (interactive "fShow file: ")
1057   (vc-dir-update (list (list (file-relative-name file) (vc-state file))) (current-buffer)))
1058
1059 (defun vc-dir-hide-up-to-date ()
1060   "Hide up-to-date items from display."
1061   (interactive)
1062   (let ((crt (ewoc-nth vc-ewoc -1))
1063         (first (ewoc-nth vc-ewoc 0)))
1064     ;; Go over from the last item to the first and remove the
1065     ;; up-to-date files and directories with no child files.
1066     (while (not (eq crt first))
1067       (let* ((data (ewoc-data crt))
1068              (dir (vc-dir-fileinfo->directory data))
1069              (next (ewoc-next vc-ewoc crt))
1070              (prev (ewoc-prev vc-ewoc crt))
1071              ;; ewoc-delete does not work without this...
1072              (inhibit-read-only t))
1073           (when (or
1074                  ;; Remove directories with no child files.
1075                  (and dir
1076                       (or
1077                        ;; Nothing follows this directory.
1078                        (not next)
1079                        ;; Next item is a directory.
1080                        (vc-dir-fileinfo->directory (ewoc-data next))))
1081                  ;; Remove files in the up-to-date state.
1082                  (eq (vc-dir-fileinfo->state data) 'up-to-date))
1083             (ewoc-delete vc-ewoc crt))
1084           (setq crt prev)))))
1085
1086 (defun vc-dir-printer (fileentry)
1087   (vc-call-backend vc-dir-backend 'dir-printer fileentry))
1088
1089 (defun vc-dir-deduce-fileset (&optional state-model-only-files)
1090   (let ((marked (vc-dir-marked-files))
1091         files
1092         only-files-list
1093         state
1094         model)
1095     (if marked
1096         (progn
1097           (setq files marked)
1098           (when state-model-only-files
1099             (setq only-files-list (vc-dir-marked-only-files-and-states))))
1100       (let ((crt (vc-dir-current-file)))
1101         (setq files (list crt))
1102         (when state-model-only-files
1103           (setq only-files-list (vc-dir-child-files-and-states)))))
1104
1105     (when state-model-only-files
1106       (setq state (cdar only-files-list))
1107       ;; Check that all files are in a consistent state, since we use that
1108       ;; state to decide which operation to perform.
1109       (dolist (crt (cdr only-files-list))
1110         (unless (vc-compatible-state (cdr crt) state)
1111           (error "When applying VC operations to multiple files, the files are required\nto  be in similar VC states.\n%s in state %s clashes with %s in state %s"
1112                  (car crt) (cdr crt) (caar only-files-list) state)))
1113       (setq only-files-list (mapcar 'car only-files-list))
1114       (when (and state (not (eq state 'unregistered)))
1115         (setq model (vc-checkout-model vc-dir-backend only-files-list))))
1116     (list vc-dir-backend files only-files-list state model)))
1117
1118 ;;;###autoload
1119 (defun vc-dir (dir &optional backend)
1120   "Show the VC status for \"interesting\" files in and below DIR.
1121 This allows you to mark files and perform VC operations on them.
1122 The list omits files which are up to date, with no changes in your copy
1123 or the repository, if there is nothing in particular to say about them.
1124
1125 Preparing the list of file status takes time; when the buffer
1126 first appears, it has only the first few lines of summary information.
1127 The file lines appear later.
1128
1129 Optional second argument BACKEND specifies the VC backend to use.
1130 Interactively, a prefix argument means to ask for the backend.
1131
1132 These are the commands available for use in the file status buffer:
1133
1134 \\<vc-dir-mode-map>"
1135
1136   (interactive
1137    (list
1138     ;; When you hit C-x v d in a visited VC file,
1139     ;; the *vc-dir* buffer visits the directory under its truename;
1140     ;; therefore it makes sense to always do that.
1141     ;; Otherwise if you do C-x v d -> C-x C-f -> C-c v d
1142     ;; you may get a new *vc-dir* buffer, different from the original
1143     (file-truename (read-file-name "VC status for directory: "
1144                                    default-directory default-directory t
1145                                    nil #'file-directory-p))
1146     (if current-prefix-arg
1147         (intern
1148          (completing-read
1149           "Use VC backend: "
1150           (mapcar (lambda (b) (list (symbol-name b)))
1151                   vc-handled-backends)
1152           nil t nil nil)))))
1153   (unless backend
1154     (setq backend (vc-responsible-backend dir)))
1155   (pop-to-buffer (vc-dir-prepare-status-buffer "*vc-dir*" dir backend))
1156   (if (derived-mode-p 'vc-dir-mode)
1157       (vc-dir-refresh)
1158     ;; FIXME: find a better way to pass the backend to `vc-dir-mode'.
1159     (let ((use-vc-backend backend))
1160       (vc-dir-mode))))
1161
1162 (defun vc-default-dir-extra-headers (backend dir)
1163   ;; Be loud by default to remind people to add code to display
1164   ;; backend specific headers.
1165   ;; XXX: change this to return nil before the release.
1166   (concat
1167    (propertize "Extra      : " 'face 'font-lock-type-face)
1168    (propertize "Please add backend specific headers here.  It's easy!"
1169                'face 'font-lock-warning-face)))
1170
1171 (defvar vc-dir-filename-mouse-map
1172    (let ((map (make-sparse-keymap)))
1173      (define-key map [mouse-2] 'vc-dir-find-file-other-window)
1174     map)
1175   "Local keymap for visiting a file.")
1176
1177 (defun vc-default-dir-printer (backend fileentry)
1178   "Pretty print FILEENTRY."
1179   ;; If you change the layout here, change vc-dir-move-to-goal-column.
1180   ;; VC backends can implement backend specific versions of this
1181   ;; function.  Changes here might need to be reflected in the
1182   ;; vc-BACKEND-dir-printer functions.
1183   (let* ((isdir (vc-dir-fileinfo->directory fileentry))
1184         (state (if isdir "" (vc-dir-fileinfo->state fileentry)))
1185         (filename (vc-dir-fileinfo->name fileentry)))
1186     (insert
1187      (propertize
1188       (format "%c" (if (vc-dir-fileinfo->marked fileentry) ?* ? ))
1189       'face 'font-lock-type-face)
1190      "   "
1191      (propertize
1192       (format "%-20s" state)
1193       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
1194                   ((memq state '(missing conflict)) 'font-lock-warning-face)
1195                   (t 'font-lock-variable-name-face))
1196       'mouse-face 'highlight)
1197      " "
1198      (propertize
1199       (format "%s" filename)
1200       'face
1201       (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
1202       'help-echo
1203       (if isdir
1204           "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
1205         "File\nmouse-3: Pop-up menu")
1206       'mouse-face 'highlight
1207       'keymap vc-dir-filename-mouse-map))))
1208
1209 (defun vc-default-extra-status-menu (backend)
1210   nil)
1211
1212 (defun vc-default-status-fileinfo-extra (backend file)
1213   "Default absence of extra information returned for a file."
1214   nil)
1215
1216 (provide 'vc-dir)
1217
1218 ;; arch-tag: 0274a2e3-e8e9-4b1a-a73c-e8b9129d5d15
1219 ;;; vc-dir.el ends here