lisp/userlock.el

   1 ;;; userlock.el --- handle file access contention between multiple users
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file is autoloaded to handle certain conditions
  28 ;; detected by the file-locking code within Emacs.
  29 ;; The two entry points are `ask-user-about-lock' and
  30 ;; `ask-user-about-supersession-threat'.
  31
  32 ;;; Code:
  33
  34 (put 'file-locked 'error-conditions '(file-locked file-error error))
  35
  36 ;;;###autoload
  37 (defun ask-user-about-lock (fn opponent)
  38   "Ask user what to do when he wants to edit FILE but it is locked by USER.
  39 This function has a choice of three things to do:
  40   do (signal 'buffer-file-locked (list FILE USER))
  41     to refrain from editing the file
  42   return t (grab the lock on the file)
  43   return nil (edit the file even though it is locked).
  44 You can rewrite it to use any criterion you like to choose which one to do."
  45   (discard-input)
  46   (save-window-excursion
  47     (let (answer)
  48       (while (null answer)
  49         (message "%s is locking %s: action (s, q, p, ?)? " opponent fn)
  50         (let ((tem (let ((inhibit-quit t)
  51                          (cursor-in-echo-area t))
  52                      (prog1 (downcase (read-char))
  53                             (setq quit-flag nil)))))
  54           (if (= tem help-char)
  55               (ask-user-about-lock-help)
  56             (setq answer (assoc tem '((?s . t)
  57                                       (?q . yield)
  58                                       (?\C-g . yield)
  59                                       (?p . nil)
  60                                       (?? . help))))
  61             (cond ((null answer)
  62                    (beep)
  63                    (message "Please type q, s, or p; or ? for help")
  64                    (sit-for 3))
  65                   ((eq (cdr answer) 'help)
  66                    (ask-user-about-lock-help)
  67                    (setq answer nil))
  68                   ((eq (cdr answer) 'yield)
  69                    (signal 'file-locked (list "File is locked" fn opponent)))))))
  70       (cdr answer))))
  71
  72 (defun ask-user-about-lock-help ()
  73   (with-output-to-temp-buffer "*Help*"
  74     (princ "It has been detected that you want to modify a file that someone else has
  75 already started modifying in EMACS.
  76
  77 You can <s>teal the file; The other user becomes the
  78   intruder if (s)he ever unmodifies the file and then changes it again.
  79 You can <p>roceed; you edit at your own (and the other user's) risk.
  80 You can <q>uit; don't modify this file.")
  81     (save-excursion
  82       (set-buffer standard-output)
  83       (help-mode))))
  84
  85 (put
  86  'file-supersession 'error-conditions '(file-supersession file-error error))
  87
  88 ;;;###autoload
  89 (defun ask-user-about-supersession-threat (fn)
  90   "Ask a user who is about to modify an obsolete buffer what to do.
  91 This function has two choices: it can return, in which case the modification
  92 of the buffer will proceed, or it can (signal 'file-supersession (file)),
  93 in which case the proposed buffer modification will not be made.
  94
  95 You can rewrite this to use any criterion you like to choose which one to do.
  96 The buffer in question is current when this function is called."
  97   (discard-input)
  98   (save-window-excursion
  99     (let (answer)
 100       (while (null answer)
 101         (message "%s changed on disk; really edit the buffer? (y, n or C-h) "
 102                  (file-name-nondirectory fn))
 103         (let ((tem (downcase (let ((cursor-in-echo-area t))
 104                                (read-char)))))
 105           (setq answer
 106                 (if (= tem help-char)
 107                     'help
 108                   (cdr (assoc tem '((?n . yield)
 109                                     (?\C-g . yield)
 110                                     (?y . proceed)
 111                                     (?? . help))))))
 112           (cond ((null answer)
 113                  (beep)
 114                  (message "Please type y or n; or ? for help")
 115                  (sit-for 3))
 116                 ((eq answer 'help)
 117                  (ask-user-about-supersession-help)
 118                  (setq answer nil))
 119                 ((eq answer 'yield)
 120                  (signal 'file-supersession
 121                          (list "File changed on disk" fn))))))
 122       (message
 123         "File on disk now will become a backup file if you save these changes.")
 124       (setq buffer-backed-up nil))))
 125
 126 (defun ask-user-about-supersession-help ()
 127   (with-output-to-temp-buffer "*Help*"
 128     (princ "You want to modify a buffer whose disk file has changed
 129 since you last read it in or saved it with this buffer.
 130
 131 If you say `y' to go ahead and modify this buffer,
 132 you risk ruining the work of whoever rewrote the file.
 133 If you say `n', the change you started to make will be aborted.
 134
 135 Usually, you should type `n' and then `M-x revert-buffer',
 136 to get the latest version of the file, then make the change again.")
 137     (save-excursion
 138       (set-buffer standard-output)
 139       (help-mode))))
 140
 141 ;;; userlock.el ends here