lisp/textmodes/page.el

   1 ;;; page.el --- page motion commands for emacs.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This code provides the page-oriented movement and selection commands
  27 ;; documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defun forward-page (&optional count)
  32   "Move forward to page boundary.  With arg, repeat, or go back if negative.
  33 A page boundary is any line whose beginning matches the regexp
  34 `page-delimiter'."
  35   (interactive "p")
  36   (or count (setq count 1))
  37   (while (and (> count 0) (not (eobp)))
  38     ;; In case the page-delimiter matches the null string,
  39     ;; don't find a match without moving.
  40     (if (bolp) (forward-char 1))
  41     (if (re-search-forward page-delimiter nil t)
  42         nil
  43       (goto-char (point-max)))
  44     (setq count (1- count)))
  45   (while (and (< count 0) (not (bobp)))
  46     ;; In case the page-delimiter matches the null string,
  47     ;; don't find a match without moving.
  48     (and (save-excursion (re-search-backward page-delimiter nil t))
  49          (= (match-end 0) (point))
  50          (goto-char (match-beginning 0)))
  51     (forward-char -1)
  52     (if (re-search-backward page-delimiter nil t)
  53         ;; We found one--move to the end of it.
  54         (goto-char (match-end 0))
  55       ;; We found nothing--go to beg of buffer.
  56       (goto-char (point-min)))
  57     (setq count (1+ count))))
  58
  59 (defun backward-page (&optional count)
  60   "Move backward to page boundary.  With arg, repeat, or go fwd if negative.
  61 A page boundary is any line whose beginning matches the regexp
  62 `page-delimiter'."
  63   (interactive "p")
  64   (or count (setq count 1))
  65   (forward-page (- count)))
  66
  67 (defun mark-page (&optional arg)
  68   "Put mark at end of page, point at beginning.
  69 A numeric arg specifies to move forward or backward by that many pages,
  70 thus marking a page other than the one point was originally in."
  71   (interactive "P")
  72   (setq arg (if arg (prefix-numeric-value arg) 0))
  73   (if (> arg 0)
  74       (forward-page arg)
  75     (if (< arg 0)
  76         (forward-page (1- arg))))
  77   (forward-page)
  78   (push-mark nil t t)
  79   (forward-page -1))
  80
  81 (defun narrow-to-page (&optional arg)
  82   "Make text outside current page invisible.
  83 A numeric arg specifies to move forward or backward by that many pages,
  84 thus showing a page other than the one point was originally in."
  85   (interactive "P")
  86   (setq arg (if arg (prefix-numeric-value arg) 0))
  87   (save-excursion
  88     (widen)
  89     (if (> arg 0)
  90         (forward-page arg)
  91       (if (< arg 0)
  92           (forward-page (1- arg))))
  93     ;; Find the end of the page.
  94     (forward-page)
  95     ;; If we stopped due to end of buffer, stay there.
  96     ;; If we stopped after a page delimiter, put end of restriction
  97     ;; at the beginning of that line.
  98     (if (save-excursion
  99           (goto-char (match-beginning 0)) ; was (beginning-of-line)
 100           (looking-at page-delimiter))
 101         (beginning-of-line))
 102     (narrow-to-region (point)
 103                       (progn
 104                         ;; Find the top of the page.
 105                         (forward-page -1)
 106                         ;; If we found beginning of buffer, stay there.
 107                         ;; If extra text follows page delimiter on same line,
 108                         ;; include it.
 109                         ;; Otherwise, show text starting with following line.
 110                         (if (and (eolp) (not (bobp)))
 111                             (forward-line 1))
 112                         (point)))))
 113 (put 'narrow-to-page 'disabled t)
 114
 115 (defun count-lines-page ()
 116   "Report number of lines on current page, and how many are before or after point."
 117   (interactive)
 118   (save-excursion
 119     (let ((opoint (point)) beg end
 120           total before after)
 121       (forward-page)
 122       (beginning-of-line)
 123       (or (looking-at page-delimiter)
 124           (end-of-line))
 125       (setq end (point))
 126       (backward-page)
 127       (setq beg (point))
 128       (setq total (count-lines beg end)
 129             before (count-lines beg opoint)
 130             after (count-lines opoint end))
 131       (message "Page has %d lines (%d + %d)" total before after))))
 132
 133 (defun what-page ()
 134   "Print page and line number of point."
 135   (interactive)
 136   (save-restriction
 137     (widen)
 138     (save-excursion
 139       (beginning-of-line)
 140       (let ((count 1)
 141             (opoint (point)))
 142         (goto-char 1)
 143         (while (re-search-forward page-delimiter opoint t)
 144           (setq count (1+ count)))
 145         (message "Page %d, line %d"
 146                  count
 147                  (1+ (count-lines (point) opoint)))))))
 148 \f
 149 ;;; Place `provide' at end of file.
 150 (provide 'page)
 151
 152 ;;; page.el ends here