lisp/progmodes/executable.el

   1 ;;; executable.el --- base functionality for executable interpreter scripts
   2
   3 ;; Copyright (C) 1994, 1995, 1996 by Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel.Pfeiffer@Informatik.START.dbp.de, fax (+49 69) 7588-2389
   6 ;; Keywords: languages, unix
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; executable.el is used by certain major modes to insert a suitable
  28 ;; #! line at the beginning of the file, if the file does not already
  29 ;; have one.
  30
  31 ;; This is support code for the likes of sh-, awk-, perl-, tcl- or
  32 ;; makefile-mode.  Those mode-setting commands can call the like of
  33 ;; `(executable-set-magic "sh")' or `(executable-set-magic "perl" "-f")'.
  34 ;; Unless the file name matches `executable-magicless-file-regexp' this will
  35 ;; search $PATH if the given interpreter isn't absolute, and then insert a
  36 ;; first line like `#! /bin/sh' or `#! /usr/local/bin/perl -f'.
  37 ;; Also it makes the file executable as soon as it's saved, if it wasn't.
  38
  39 ;;; Code:
  40
  41 (defvar executable-insert 'not-modified
  42   "*What to do when newly found file has no or wrong magic number:
  43         nil     do nothing
  44         t       insert or update magic number
  45         other   insert or update magic number, but mark as unmodified.
  46 When the insertion is marked as unmodified, you can save it with  \\[write-file] RET.
  47 This variable is used when `executable-set-magic' is called as a function,
  48 e.g. when Emacs sets some Un*x interpreter script mode.
  49 With \\[executable-set-magic], this is always treated as if it were `t'.")
  50
  51
  52 (defvar executable-query 'function
  53   "*If non-`nil', ask user before inserting or changing magic number.
  54 When this is `function', only ask when called non-interactively.")
  55
  56
  57 (defvar executable-magicless-file-regexp "/[Mm]akefile$\\|/\\.\\(z?profile\\|bash_profile\\|z?login\\|bash_login\\|z?logout\\|bash_logout\\|.+shrc\\|esrc\\|rcrc\\|[kz]shenv\\)$"
  58   "*On files with this kind of name no magic is inserted or changed.")
  59
  60
  61 (defvar executable-prefix "#! "
  62   "*Interpreter magic number prefix inserted when there was no magic number.")
  63
  64
  65
  66 (defvar executable-chmod 73
  67   "*After saving, if the file is not executable, set this mode.
  68 This mode passed to `set-file-modes' is taken absolutely when negative, or
  69 relative to the files existing modes.  Do nothing if this is nil.
  70 Typical values are 73 (+x) or -493 (rwxr-xr-x).")
  71
  72
  73 (defvar executable-command nil)
  74
  75 (defvar executable-self-display "tail"
  76   "*Command you use with argument `+2' to make text files self-display.
  77 Note that the like of `more' doesn't work too well under Emacs  \\[shell].")
  78
  79
  80 (defvar executable-font-lock-keywords
  81   '(("\\`#!.*/\\([^ \t\n]+\\)" 1 font-lock-keyword-face t))
  82   "*Rules for highlighting executable scripts' magic number.
  83 This can be included in `font-lock-keywords' by modes that call `executable'.")
  84
  85
  86 (defvar executable-error-regexp-alist
  87   '(;; /bin/xyz: syntax error at line 14: `(' unexpected
  88     ;; /bin/xyz[5]: syntax error at line 8 : ``' unmatched
  89     ("^\\(.*[^[/]\\)\\(\\[[0-9]+\\]\\)?: .* error .* line \\([0-9]+\\)" 1 3)
  90     ;; /bin/xyz[27]: ehco:  not found
  91     ("^\\(.*[^/]\\)\\[\\([0-9]+\\)\\]: .*: " 1 2)
  92     ;; /bin/xyz: syntax error near unexpected token `)'
  93     ;; /bin/xyz: /bin/xyz: line 2: `)'
  94     ("^\\(.*[^/]\\): [^0-9\n]+\n\\1: \\1: line \\([0-9]+\\):" 1 2)
  95     ;; /usr/bin/awk: syntax error at line 5 of file /bin/xyz
  96     (" error .* line \\([0-9]+\\) of file \\(.+\\)$" 2 1)
  97     ;; /usr/bin/awk: calling undefined function toto
  98     ;;  input record number 3, file awktestdata
  99     ;;  source line 4 of file /bin/xyz
 100     ("^[^ ].+\n\\( .+\n\\)* line \\([0-9]+\\) of file \\(.+\\)$" 3 2)
 101     ;; makefile:1: *** target pattern contains no `%'.  Stop.
 102     ("^\\(.+\\):\\([0-9]+\\): " 1 2))
 103   "Alist of regexps used to match script errors.
 104 See `compilation-error-regexp-alist'.")
 105
 106 ;; The C function openp slightly modified would do the trick fine
 107 (defun executable-find (command)
 108   "Search for COMMAND in $PATH and return the absolute file name.
 109 Return nil if COMMAND is not found anywhere in $PATH."
 110   (let ((list exec-path)
 111         file)
 112     (while list
 113       (setq list (if (and (setq file (expand-file-name command (car list)))
 114                           (file-executable-p file)
 115                           (not (file-directory-p file)))
 116                      nil
 117                    (setq file nil)
 118                    (cdr list))))
 119     file))
 120
 121
 122 (defun executable-chmod ()
 123   "This gets called after saving a file to assure that it be executable.
 124 You can set the absolute or relative mode in variable `executable-chmod' for
 125 non-executable files."
 126   (and executable-chmod
 127        buffer-file-name
 128        (or (file-executable-p buffer-file-name)
 129            (set-file-modes buffer-file-name
 130                            (if (< executable-chmod 0)
 131                                (- executable-chmod)
 132                              (logior executable-chmod
 133                                      (file-modes buffer-file-name)))))))
 134
 135
 136 (defun executable-interpret (command)
 137   "Run script with user-specified args, and collect output in a buffer.
 138 While script runs asynchronously, you can use the \\[next-error] command
 139 to find the next error."
 140   (interactive (list (read-string "Run script: "
 141                                   (or executable-command
 142                                       buffer-file-name))))
 143   (require 'compile)
 144   (save-some-buffers (not compilation-ask-about-save))
 145   (make-local-variable 'executable-command)
 146   (compile-internal (setq executable-command command)
 147                     "No more errors." "Interpretation"
 148                     ;; Give it a simpler regexp to match.
 149                     nil executable-error-regexp-alist))
 150
 151
 152
 153 ;;;###autoload
 154 (defun executable-set-magic (interpreter &optional argument
 155                                          no-query-flag insert-flag)
 156   "Set this buffer's interpreter to INTERPRETER with optional ARGUMENT.
 157 The variables `executable-magicless-file-regexp', `executable-prefix',
 158 `executable-insert', `executable-query' and `executable-chmod' control
 159 when and how magic numbers are inserted or replaced and scripts made
 160 executable."
 161   (interactive
 162    (let* ((name (read-string "Name or file name of interpreter: "))
 163           (arg (read-string (format "Argument for %s: " name))))
 164      (list name arg (eq executable-query 'function) t)))
 165   (setq interpreter (if (file-name-absolute-p interpreter)
 166                         interpreter
 167                       (or (executable-find interpreter)
 168                           (error "Interpreter %s not recognized" interpreter)))
 169         argument (concat interpreter
 170                          (and argument (string< "" argument) " ")
 171                          argument))
 172   (or buffer-read-only
 173       (if buffer-file-name
 174           (string-match executable-magicless-file-regexp
 175                         buffer-file-name))
 176       (not (or insert-flag executable-insert))
 177       (> (point-min) 1)
 178       (save-excursion
 179         (let ((point (point-marker))
 180               (buffer-modified-p (buffer-modified-p)))
 181           (goto-char (point-min))
 182           (make-local-hook 'after-save-hook)
 183           (add-hook 'after-save-hook 'executable-chmod nil t)
 184           (if (looking-at "#![ \t]*\\(.*\\)$")
 185               (and (goto-char (match-beginning 1))
 186                    (not (string= argument
 187                                  (buffer-substring (point) (match-end 1))))
 188                    (or (not executable-query) no-query-flag
 189                        (save-window-excursion
 190                          ;; Make buffer visible before question.
 191                          (switch-to-buffer (current-buffer))
 192                          (y-or-n-p (concat "Replace magic number by `"
 193                                            executable-prefix argument "'? "))))
 194                    (progn
 195                      (replace-match argument t t nil 1)
 196                      (message "Magic number changed to `%s'"
 197                               (concat executable-prefix argument))))
 198             (insert executable-prefix argument ?\n)
 199             (message "Magic number changed to `%s'"
 200                      (concat executable-prefix argument)))
 201           (or insert-flag
 202               (eq executable-insert t)
 203               (set-buffer-modified-p buffer-modified-p)))))
 204   interpreter)
 205
 206
 207
 208 ;;;###autoload
 209 (defun executable-self-display ()
 210   "Turn a text file into a self-displaying Un*x command.
 211 The magic number of such a command displays all lines but itself."
 212   (interactive)
 213   (if (eq this-command 'executable-self-display)
 214       (setq this-command 'executable-set-magic))
 215   (executable-set-magic executable-self-display "+2"))
 216
 217
 218
 219 (provide 'executable)
 220
 221 ;; executable.el ends here