lisp/help-macro.el

   1 ;;; help-macro.el --- Makes command line help such as help-for-help
   2
   3 ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Lynn Slater <lrs@indetech.com>
   6 ;; Created: : Mon Oct  1 11:42:39 1990
   7 ;; Adapted-By: ESR
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file supplies the macro make-help-screen which constructs
  29 ;; single character dispatching with browsable help such as that provided
  30 ;; by help-for-help. This can be used to make many modes easier to use; for
  31 ;; example, the Gnu Emacs Empire Tool uses this for every "nested" mode map
  32 ;; called from the main mode map.
  33
  34 ;;       The name of this package was changed from help-screen.el to
  35 ;; help-macro.el in order to fit in a 14-character limit.
  36
  37 ;;-> ***********************  Example of use *********************************
  38
  39 ;;->(make-help-screen help-for-empire-redistribute-map
  40 ;;->              "c:civ m:mil p:population f:food ?"
  41 ;;->              "You have discovered the GEET redistribution commands
  42 ;;->   From here, you can use the following options:
  43 ;;->
  44 ;;->c   Redistribute civs from overfull sectors into connected underfull ones
  45 ;;->      The functions typically named by empire-ideal-civ-fcn control
  46 ;;->          based in part on empire-sector-civ-threshold
  47 ;;->m   Redistribute military using levels given by empire-ideal-mil-fcn
  48 ;;->p   Redistribute excess population to highways for max pop growth
  49 ;;->      Excess is any sector so full babies will not be born.
  50 ;;->f   Even out food on highways to highway min and leave levels
  51 ;;->      This is good to pump max food to all warehouses/dist pts
  52 ;;->
  53 ;;->
  54 ;;->Use \\[help-for-empire-redistribute-map] for help on redistribution.
  55 ;;->Use \\[help-for-empire-extract-map] for help on data extraction.
  56 ;;->Please use \\[describe-key] to find out more about any of the other keys."
  57 ;;->              empire-shell-redistribute-map)
  58
  59 ;;->  (define-key c-mp "\C-h" 'help-for-empire-redistribute-map)
  60 ;;->  (define-key c-mp help-character 'help-for-empire-redistribute-map)
  61
  62 ;;; Change Log:
  63 ;;
  64 ;; 22-Jan-1991          Lynn Slater x2048
  65 ;;    Last Modified: Mon Oct  1 11:43:52 1990 #3 (Lynn Slater)
  66 ;;    documented better
  67
  68 ;;; Code:
  69
  70 (provide 'help-macro)
  71 (require 'backquote)
  72
  73 ;;;###autoload
  74 (defvar three-step-help nil
  75   "*Non-nil means give more info about Help command in three steps.
  76 The three steps are simple prompt, prompt with all options,
  77 and window listing and describing the options.
  78 A value of nil means skip the middle step, so that
  79 \\[help-command] \\[help-command] gives the window that lists the options.")
  80
  81 (defmacro make-help-screen (fname help-line help-text helped-map)
  82   "Construct help-menu function name FNAME.
  83 When invoked, FNAME shows HELP-LINE and reads a command using HELPED-MAP.
  84 If the command is the help character, FNAME displays HELP-TEXT
  85 and continues trying to read a command using HELPED-MAP.
  86 When FNAME finally does get a command, it executes that command
  87 and then returns."
  88   (` (defun (, fname) ()
  89            (, help-text)
  90            (interactive)
  91            (let ((line-prompt
  92                   (substitute-command-keys (, help-line))))
  93              (if three-step-help
  94                  (message line-prompt))
  95              (let* ((help-screen (documentation (quote (, fname))))
  96                     ;; We bind overriding-local-map for very small
  97                     ;; sections, *excluding* where we switch buffers
  98                     ;; and where we execute the chosen help command.
  99                     (local-map (make-sparse-keymap))
 100                     (minor-mode-map-alist nil)
 101                     (prev-frame (selected-frame))
 102                     config new-frame key char)
 103                (unwind-protect
 104                    (progn
 105                      (setcdr local-map (, helped-map))
 106                      (define-key local-map [t] 'undefined)
 107                      (if three-step-help
 108                          (progn
 109                            (setq key (let ((overriding-local-map local-map))
 110                                      (read-key-sequence nil)))
 111                            ;; Make the HELP key translate to C-h.
 112                            (if (lookup-key function-key-map key)
 113                                (setq key (lookup-key function-key-map key)))
 114                            (setq char (aref key 0)))
 115                        (setq char ??))
 116                      (if (or (eq char ??) (eq char help-char)
 117                              (memq char help-event-list))
 118                          (progn
 119                            (setq config (current-window-configuration))
 120                            (switch-to-buffer-other-window "*Help*")
 121                            (and (fboundp 'make-frame)
 122                                 (not (eq (window-frame (selected-window))
 123                                          prev-frame))
 124                                 (setq new-frame (window-frame (selected-window))
 125                                       config nil))
 126                            (erase-buffer)
 127                            (insert help-screen)
 128                            (help-mode)
 129                            (goto-char (point-min))
 130                            (while (or (memq char (append help-event-list
 131                                                          (cons help-char '(?? ?\C-v ?\ ?\177 delete backspace ?\M-v))))
 132                                       (eq (car-safe char) 'switch-frame)
 133                                       (equal key "\M-v"))
 134                              (condition-case nil
 135                                  (progn
 136                                    (if (eq (car-safe char) 'switch-frame)
 137                                        (handle-switch-frame char))
 138                                    (if (memq char '(?\C-v ?\ ))
 139                                        (scroll-up))
 140                                    (if (or (memq char '(?\177 ?\M-v
 141                                                         delete backspace))
 142                                            (equal key "\M-v"))
 143                                        (scroll-down)))
 144                                (error nil))
 145                              (let ((cursor-in-echo-area t)
 146                                    (overriding-local-map local-map))
 147                                (setq key (read-key-sequence
 148                                           (format "Type one of the options listed%s: "
 149                                                   (if (pos-visible-in-window-p
 150                                                        (point-max))
 151                                                       "" " or Space to scroll")))
 152                                      char (aref key 0))))))
 153                      ;; Mouse clicks are not part of the help feature,
 154                      ;; so reexecute them in the standard environment.
 155                      (if (listp char)
 156                          (setq unread-command-events
 157                                (cons char unread-command-events)
 158                                config nil)
 159                        (let ((defn (lookup-key local-map key)))
 160                          (if defn
 161                              (progn
 162                                (if config
 163                                    (progn
 164                                      (set-window-configuration config)
 165                                      (setq config nil)))
 166                                (if new-frame
 167                                    (progn (iconify-frame new-frame)
 168                                           (setq new-frame nil)))
 169                                (call-interactively defn))
 170                            (ding)))))
 171                  (if new-frame (iconify-frame new-frame))
 172                  (if config
 173                      (set-window-configuration config))))))
 174      ))
 175
 176 ;;; help-macro.el
 177