lisp/dired-x.el

   1 ;;; dired-x.el --- Sebastian Kremer's Extra DIRED hacked up for GNU Emacs19
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Lawrence R. Dodd <dodd@roebling.poly.edu>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions
   9
  10 ;; Copyright (C) 1993, 1994 Free Software Foundation
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  32 ;; 1.191, hacked up for GNU Emacs 19.  Redundant or conflicting material
  33 ;; has been removed or renamed in order to work properly with dired of
  34 ;; GNU Emacs 19.  All suggestions or comments are most welcomed.
  35
  36 ;;
  37 ;; Please, PLEASE, *PLEASE* see the info pages.
  38 ;;
  39
  40 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  41
  42 ;; INSTALLATION: In your ~/.emacs,
  43 ;;
  44 ;; (add-hook 'dired-load-hook
  45 ;;           (function (lambda ()
  46 ;;                       (load "dired-x")
  47 ;;                       ;; Set global variables here.  For example:
  48 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  49 ;;                       )))
  50 ;; (add-hook 'dired-mode-hook
  51 ;;           (function (lambda ()
  52 ;;                       ;; Set buffer-local variables here.  For example:
  53 ;;                       ;; (setq dired-omit-files-p t)
  54 ;;                       )))
  55 ;;
  56 ;; At load time dired-x.el will install itself, redefine some functions, and
  57 ;; bind some dired keys.  *Please* see the info pages for more details.
  58
  59 ;; CAUTION: If you are using a version of GNU Emacs earlier than 19.20 than
  60 ;; you may have to edit dired.el.  The copy of dired.el in GNU Emacs versions
  61 ;; earlier than 19.20 incorrectly had the call to run-hooks *before* the call
  62 ;; to provide.  In such a case, it is possible that byte-compiling and/or
  63 ;; loading dired can cause an infinite loop.  To prevent this, make sure the
  64 ;; line of code
  65 ;;
  66 ;;         (run-hooks 'dired-load-hook)
  67 ;;
  68 ;; is the *last* executable line in the file dired.el.  That is, make sure it
  69 ;; comes *after* the line
  70 ;;
  71 ;;         (provide 'dired)
  72 ;;
  73 ;; *Please* see the info pages for more details.
  74
  75 ;; User defined variables:
  76 ;;
  77 ;;      dired-bind-vm
  78 ;;      dired-vm-read-only-folders
  79 ;;      dired-bind-jump
  80 ;;      dired-bind-info
  81 ;;      dired-bind-man
  82 ;;      dired-x-hands-off-my-keys
  83 ;;      dired-find-subdir
  84 ;;      dired-enable-local-variables
  85 ;;      dired-local-variables-file
  86 ;;      dired-guess-shell-gnutar
  87 ;;      dired-guess-shell-gzip-quiet
  88 ;;      dired-guess-shell-znew-switches
  89 ;;      dired-guess-shell-alist-user
  90 ;;      dired-clean-up-buffers-too
  91 ;;      dired-omit-files-p
  92 ;;      dired-omit-files
  93 ;;      dired-omit-extensions
  94 ;;
  95 ;; To find out more about these variables, load this file, put your cursor at
  96 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  97 ;; the info pages for more details.
  98
  99 ;; When loaded this code redefines the following functions of GNU Emacs
 100 ;;
 101 ;;   Function                         Found in this file of GNU Emacs
 102 ;;   --------                         -------------------------------
 103 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
 104 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
 105 ;;   dired-initial-position           ../lisp/dired.el
 106 ;;
 107 ;;   dired-add-entry                  ../lisp/dired-aux.el
 108 ;;   dired-read-shell-command         ../lisp/dired-aux.el
 109 ;;
 110 ;; One drawback is that dired-x.el will load dired-aux.el as soon as dired is
 111 ;; loaded.  Thus, the advantage of separating out non-essential dired stuff
 112 ;; into dired-aux.el and only loading when necessary will be lost.  Please
 113 ;; note also that some of the comments in dired.el and dired-aux.el are
 114 ;; Kremer's that referred to the old dired-x.el.  This now should be referring
 115 ;; to this program.  (This is also a good reason to call this dired-x.el
 116 ;; instead of dired-x19.el.)
 117
 118 \f
 119 ;;; Code:
 120
 121 ;; LOAD.
 122
 123 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 124 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 125 ;; (instead of autoloading to dired as is suggested in the info-pages).
 126
 127 (require 'dired)
 128
 129 ;; We will redefine some functions and also need some macros so we need to
 130 ;; load dired stuff of GNU Emacs.
 131
 132 (require 'dired-aux)
 133
 134 ;;; User-defined variables.
 135
 136 (defvar dired-bind-vm nil
 137   "*t says \"V\" in dired-mode will `dired-vm', otherwise \"V\" is `dired-rmail'.
 138 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 139 `dired-advertised-find-file', will run rmail.")
 140
 141 (defvar dired-bind-jump t
 142   "*t says bind `dired-jump' to C-x C-j, otherwise do not.")
 143
 144 (defvar dired-bind-man t
 145   "*t says bind `dired-man' to \"N\" in dired-mode, otherwise do not.")
 146
 147 (defvar dired-bind-info t
 148   "*t says bind `dired-info' to \"I\" in dired-mode, otherwise do not.")
 149
 150 (defvar dired-vm-read-only-folders nil
 151   "*If t, \\[dired-vm] will visit all folders read-only.
 152 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 153 files not writable by you are visited read-only.
 154
 155 Read-only folders only work in VM 5, not in VM 4.")
 156
 157 (defvar dired-omit-files-p nil
 158   "*If non-nil, \"uninteresting\" files are not listed (buffer-local).
 159 Use \\[dired-omit-toggle] to toggle its value.
 160 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 161 plus those ending with extensions in `dired-omit-extensions'.")
 162 (make-variable-buffer-local 'dired-omit-files-p)
 163
 164 (defvar dired-omit-files "^#\\|^\\.$\\|^\\.\\.$"
 165   "*Filenames matching this regexp will not be displayed.
 166 This only has effect when `dired-omit-files-p' is t.  See interactive function
 167 `dired-omit-toggle' \(\\[dired-omit-toggle]\) and variable
 168 `dired-omit-extensions'.  The default is to omit  `.', `..', and auto-save
 169 files.")
 170
 171 (defvar dired-find-subdir nil           ; t is pretty near to DWIM...
 172   "*If non-nil, Dired always finds a directory in a buffer of its own.
 173 If nil, Dired finds the directory as a subdirectory in some other buffer
 174 if it is present as one.
 175
 176 If there are several Dired buffers for a directory, the most recently
 177 used is chosen.
 178
 179 Dired avoids switching to the current buffer, so that if you have
 180 a normal and a wildcard buffer for the same directory, C-x d RET will
 181 toggle between those two.")
 182
 183 (defvar dired-enable-local-variables t
 184   "*Control use of local-variables lists in dired.
 185 The value can be t, nil or something else.
 186 A value of t means local-variables lists are obeyed;
 187 nil means they are ignored; anything else means query.
 188
 189 This temporarily overrides the value of `enable-local-variables' when listing
 190 a directory.  See also `dired-local-variables-file'.")
 191
 192 (defvar dired-guess-shell-gnutar nil
 193   "*If non-nil, name of GNU tar executable (e.g., \"tar\" or \"gtar\") and `z'
 194 switch will be used for compressed or gzip'ed tar files.  If no GNU tar, set
 195 to nil: a pipe using `zcat' or `gunzip -c' will be used.")
 196
 197 (defvar dired-guess-shell-gzip-quiet t
 198   "*non-nil says pass -q to gzip overriding verbose GZIP environment.")
 199
 200 (defvar dired-guess-shell-znew-switches nil
 201   "*If non-nil, then string of switches passed to `znew', example: \"-K\"")
 202
 203 (defvar dired-clean-up-buffers-too t
 204   "*t says offer to kill buffers visiting files and dirs deleted in dired.")
 205
 206 ;;; KEY BINDINGS.
 207
 208 (define-key dired-mode-map "\M-o" 'dired-omit-toggle)
 209 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 210 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 211 (define-key dired-mode-map "T" 'dired-do-toggle)
 212 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 213 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 214 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 215 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 216 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 217 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 218 (define-key dired-mode-map "V" 'dired-do-run-mail)
 219
 220 (if dired-bind-man
 221     (define-key dired-mode-map "N" 'dired-man))
 222
 223 (if dired-bind-info
 224     (define-key dired-mode-map "I" 'dired-info))
 225
 226 ;;; GLOBAL BINDING.
 227 (if dired-bind-jump
 228     (progn
 229       (define-key global-map "\C-x\C-j" 'dired-jump)
 230       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 231
 232 \f
 233 ;;; Install into appropriate hooks.
 234
 235 (add-hook 'dired-mode-hook 'dired-extra-startup)
 236 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 237
 238 (defun dired-extra-startup ()
 239   "Automatically put on dired-mode-hook to get extra dired features:
 240 \\<dired-mode-map>
 241
 242   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 243   \\[dired-info]\t-- run info on file
 244   \\[dired-man]\t-- run man on file
 245   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 246   \\[dired-omit-toggle]\t-- toggle omitting of files
 247   \\[dired-do-toggle]\t-- toggle marks
 248   \\[dired-mark-sexp]\t-- mark by lisp expression
 249   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring.
 250   \t   You can feed it to other commands using \\[yank].
 251
 252 For more features, see variables
 253
 254   dired-bind-vm
 255   dired-bind-jump
 256   dired-bind-info
 257   dired-bind-man
 258   dired-vm-read-only-folders
 259   dired-omit-files-p
 260   dired-omit-files
 261   dired-omit-extensions
 262   dired-find-subdir
 263   dired-enable-local-variables
 264   dired-local-variables-file
 265   dired-guess-shell-gnutar
 266   dired-guess-shell-gzip-quiet
 267   dired-guess-shell-znew-switches
 268   dired-guess-shell-alist-user
 269   dired-clean-up-buffers-too
 270
 271 See also functions
 272
 273   dired-flag-extension
 274   dired-virtual
 275   dired-jump
 276   dired-man
 277   dired-vm
 278   dired-rmail
 279   dired-info
 280   dired-do-find-marked-files
 281 "
 282   (interactive)
 283
 284   ;; These must be done in each new dired buffer.
 285   (dired-hack-local-variables)
 286   (dired-omit-startup))
 287
 288 \f
 289 ;;; BUFFER CLEANING.
 290
 291 ;; REDEFINE.
 292 (defun dired-clean-up-after-deletion (fn)
 293
 294   ;; Clean up after a deleted file or directory FN.
 295   ;; Remove expanded subdir of deleted dir, if any.
 296   (save-excursion (and (cdr dired-subdir-alist)
 297                        (dired-goto-subdir fn)
 298                        (dired-kill-subdir)))
 299
 300   ;; Offer to kill buffer of deleted file FN.
 301   (if dired-clean-up-buffers-too
 302       (progn
 303         (let ((buf (get-file-buffer fn)))
 304           (and buf
 305                (funcall (function y-or-n-p)
 306                         (format "Kill buffer of %s, too? "
 307                                 (file-name-nondirectory fn)))
 308                (save-excursion ; you never know where kill-buffer leaves you
 309                  (kill-buffer buf))))
 310         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 311               (buf nil))
 312           (and buf-list
 313                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 314                                  (dired-plural-s (length buf-list))
 315                                  (file-name-nondirectory fn)))
 316                (while buf-list
 317                  (save-excursion (kill-buffer (car buf-list)))
 318                  (setq buf-list (cdr buf-list)))))))
 319   ;; Anything else?
 320   )
 321
 322 \f
 323 ;;; EXTENSION MARKING FUNCTIONS.
 324
 325 ;;; Mark files with some extension.
 326 (defun dired-mark-extension (extension &optional marker-char)
 327   "Mark all files with a certain extension for use in later commands.
 328 A `.' is not automatically prepended to the string entered."
 329   ;; EXTENSION may also be a list of extensions instead of a single one.
 330   ;; Optional MARKER-CHAR is marker to use.
 331   (interactive "sMarking extension: \nP")
 332   (or (listp extension)
 333       (setq extension (list extension)))
 334   (dired-mark-files-regexp
 335    (concat ".";; don't match names with nothing but an extension
 336            "\\("
 337            (mapconcat 'regexp-quote extension "\\|")
 338            "\\)$")
 339    marker-char))
 340
 341 (defun dired-flag-extension (extension)
 342   "In dired, flag all files with a certain extension for deletion.
 343 A `.' is *not* automatically prepended to the string entered."
 344   (interactive "sFlagging extension: ")
 345   (dired-mark-extension extension dired-del-marker))
 346
 347 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 348
 349 (defvar dired-patch-unclean-extensions
 350   '(".rej" ".orig")
 351   "List of extensions of dispensable files created by the `patch' program.")
 352
 353 (defvar dired-tex-unclean-extensions
 354   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 355   "List of extensions of dispensable files created by TeX.")
 356
 357 (defvar dired-latex-unclean-extensions
 358   '(".idx" ".lof" ".lot" ".glo")
 359   "List of extensions of dispensable files created by LaTeX.")
 360
 361 (defvar dired-bibtex-unclean-extensions
 362   '(".blg" ".bbl")
 363   "List of extensions of dispensable files created by BibTeX.")
 364
 365 (defvar dired-texinfo-unclean-extensions
 366   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 367     ".tp" ".tps" ".vr" ".vrs")
 368   "List of extensions of dispensable files created by texinfo.")
 369
 370 (defun dired-clean-patch ()
 371   "Flag dispensable files created by patch for deletion.
 372 See variable `dired-patch-unclean-extensions'."
 373   (interactive)
 374   (dired-flag-extension dired-patch-unclean-extensions))
 375
 376 (defun dired-clean-tex ()
 377   "Flag dispensable files created by [La]TeX etc. for deletion.
 378 See variables `dired-texinfo-unclean-extensions',
 379 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 380 `dired-texinfo-unclean-extensions'."
 381   (interactive)
 382   (dired-flag-extension (append dired-texinfo-unclean-extensions
 383                                 dired-latex-unclean-extensions
 384                                 dired-bibtex-unclean-extensions
 385                                 dired-tex-unclean-extensions)))
 386
 387 (defun dired-very-clean-tex ()
 388   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 389 See variables `dired-texinfo-unclean-extensions',
 390 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 391 `dired-texinfo-unclean-extensions'."
 392   (interactive)
 393   (dired-flag-extension (append dired-texinfo-unclean-extensions
 394                                 dired-latex-unclean-extensions
 395                                 dired-bibtex-unclean-extensions
 396                                 dired-tex-unclean-extensions
 397                                 (list ".dvi"))))
 398 \f
 399 ;;; JUMP.
 400
 401 ;;;###autoload
 402 (defun dired-jump (&optional other-window)
 403   "Jump to dired buffer corresponding to current buffer.
 404 If in a file, dired the current directory and move to file's line.
 405 If in dired already, pop up a level and goto old directory's line.
 406 In case the proper dired file line cannot be found, refresh the dired
 407 buffer and try again."
 408   (interactive "P")
 409   (let* ((file buffer-file-name)
 410          (dir (if file (file-name-directory file) default-directory)))
 411     (if (eq major-mode 'dired-mode)
 412         (progn
 413           (setq dir (dired-current-directory))
 414           (dired-up-directory other-window)
 415           (or (dired-goto-file dir)
 416               ;; refresh and try again
 417               (progn
 418                 (dired-insert-subdir (file-name-directory dir))
 419                 (dired-goto-file dir))))
 420       (if other-window
 421           (dired-other-window dir)
 422         (dired dir))
 423       (if file
 424           (or (dired-goto-file file)
 425               ;; Toggle omitting, if necessary, and try again.
 426               (progn
 427                 (dired-omit-toggle t)
 428                 (dired-goto-file file))
 429               ;; refresh and try again
 430               (progn
 431                 (dired-insert-subdir (file-name-directory file))
 432                 (dired-goto-file file)))))))
 433
 434 (defun dired-jump-other-window ()
 435   "Like \\[dired-jump] (dired-jump) but in other window."
 436   (interactive)
 437   (dired-jump t))
 438 \f
 439 ;;; TOGGLE.
 440 ;;; Toggle marked files with unmarked files.
 441
 442 (defun dired-do-toggle ()
 443   "Toggle marks.
 444 That is, currently marked files become unmarked and vice versa.
 445 Files marked with other flags (such as `D') are not affected.
 446 `.' and `..' are never toggled.
 447 As always, hidden subdirs are not affected."
 448   (interactive)
 449   (save-excursion
 450     (goto-char (point-min))
 451     (let (buffer-read-only)
 452       (while (not (eobp))
 453         (or (dired-between-files)
 454             (looking-at dired-re-dot)
 455             ;; use subst instead of insdel because it does not move
 456             ;; the gap and thus should be faster and because
 457             ;; other characters are left alone automatically
 458             (apply 'subst-char-in-region
 459                    (point) (1+ (point))
 460                    (if (eq ?\040 (following-char)) ; SPC
 461                        (list ?\040 dired-marker-char)
 462                      (list dired-marker-char ?\040))))
 463         (forward-line 1)))))
 464
 465 \f
 466 ;;; COPY NAMES OF MARKED FILES INTO KILL-RING.
 467
 468 (defun dired-copy-filename-as-kill (&optional arg)
 469   "Copy names of marked (or next ARG) files into the kill ring.
 470 The names are separated by a space.
 471 With a zero prefix arg, use the complete pathname of each marked file.
 472 With \\[universal-argument], use the relative pathname of each marked file.
 473
 474 If on a subdir headerline, use subdirname instead; prefix arg is ignored
 475 in this case.
 476
 477 You can then feed the file name(s) to other commands with \\[yank]."
 478   (interactive "P")
 479   (let ((string
 480          (or (dired-get-subdir)
 481              (mapconcat (function identity)
 482                         (if arg
 483                             (cond ((zerop (prefix-numeric-value arg))
 484                                    (dired-get-marked-files))
 485                                   ((integerp arg)
 486                                    (dired-get-marked-files 'no-dir arg))
 487                                   (t    ; else a raw arg
 488                                    (dired-get-marked-files t)))
 489                           (dired-get-marked-files 'no-dir))
 490                         " "))))
 491     (kill-new string)
 492     (message "%s" string)))
 493
 494 \f
 495 ;;; OMITTING.
 496
 497 ;;; Enhanced omitting of lines from directory listings.
 498 ;;; Marked files are never omitted.
 499
 500 ;; should probably get rid of this and always use 'no-dir.
 501 ;; sk 28-Aug-1991 09:37
 502 (defvar dired-omit-localp 'no-dir
 503   "The LOCALP argument dired-omit-expunge passes to dired-get-filename.
 504 If it is 'no-dir, omitting is much faster, but you can only match
 505 against the basename of the file.  Set it to nil if you need to match the
 506 whole pathname.")
 507
 508 ;; \017=^O for Omit - other packages can chose other control characters.
 509 (defvar dired-omit-marker-char ?\017
 510   "Temporary marker used by by dired-omit.
 511 Should never be used as marker by the user or other packages.")
 512
 513 (defun dired-omit-startup ()
 514   (or (assq 'dired-omit-files-p minor-mode-alist)
 515       (setq minor-mode-alist
 516             (append '((dired-omit-files-p " Omit")) minor-mode-alist))))
 517
 518 (defun dired-omit-toggle (&optional flag)
 519   "Toggle omitting files matching `dired-omit-files' and `dired-omit-extensions'.
 520 With an arg, and if omitting was off, don't toggle and just mark the
 521   files but don't actually omit them.
 522 With an arg, and if omitting was on, turn it off but don't refresh the buffer."
 523   (interactive "P")
 524   (if flag
 525       (if dired-omit-files-p
 526           (setq dired-omit-files-p (not dired-omit-files-p))
 527         (dired-mark-unmarked-files (dired-omit-regexp) nil nil
 528                                    dired-omit-localp))
 529     ;; no FLAG
 530     (setq dired-omit-files-p (not dired-omit-files-p))
 531     (if (not dired-omit-files-p)
 532         (revert-buffer)
 533       ;; this will mention how many were omitted:
 534       (dired-omit-expunge))))
 535
 536 (defvar dired-omit-extensions
 537   (append completion-ignored-extensions
 538           dired-latex-unclean-extensions
 539           dired-bibtex-unclean-extensions
 540           dired-texinfo-unclean-extensions)
 541   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 542 Defaults to elements of `completion-ignored-extensions',
 543 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 544 `dired-texinfo-unclean-extensions'.
 545
 546 See interactive function `dired-omit-toggle' \(\\[dired-omit-toggle]\) and
 547 variables `dired-omit-files-p' and `dired-omit-files'.")
 548
 549 (defun dired-omit-expunge (&optional regexp)
 550   "Erases all unmarked files matching REGEXP.
 551 Does nothing if global variable `dired-omit-files-p' is nil.
 552 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 553   filenames ending in `dired-omit-extensions'.
 554 If REGEXP is the empty string, this function is a no-op.
 555
 556 This functions works by temporarily binding `dired-marker-char' to
 557 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 558   (interactive "sOmit files (regexp): ")
 559   (if dired-omit-files-p
 560       (let ((omit-re (or regexp (dired-omit-regexp)))
 561             (old-modified-p (buffer-modified-p))
 562             count)
 563         (or (string= omit-re "")
 564             (let ((dired-marker-char dired-omit-marker-char))
 565               (message "Omitting...")
 566               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 567                   (progn
 568                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 569                     (force-mode-line-update))
 570                 (message "(Nothing to omit)"))))
 571         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 572         ;; in mode-line of omitted buffers.
 573         (set-buffer-modified-p (and old-modified-p
 574                                     (save-excursion
 575                                       (goto-char (point-min))
 576                                       (re-search-forward dired-re-mark nil t))))
 577         count)))
 578
 579 (defun dired-omit-regexp ()
 580   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 581           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 582           (if dired-omit-extensions
 583               (concat ".";; a non-extension part should exist
 584                       "\\("
 585                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 586                       "\\)$")
 587             "")))
 588
 589 ;; Returns t if any work was done, nil otherwise.
 590 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 591   "Marks unmarked files matching REGEXP, displaying MSG.
 592 REGEXP is matched against the complete pathname.
 593 Does not re-mark files which already have a mark.
 594 With prefix argument, unflag all those files.
 595 Second optional argument LOCALP is as in `dired-get-filename'."
 596   (interactive "P")
 597   (let ((dired-marker-char (if unflag-p ?\  dired-marker-char)))
 598     (dired-mark-if
 599      (and
 600       ;; not already marked
 601       (looking-at " ")
 602       ;; uninteresting
 603       (let ((fn (dired-get-filename localp t)))
 604         (and fn (string-match regexp fn))))
 605      msg)))
 606
 607 ;;; REDEFINE.
 608 (defun dired-omit-new-add-entry (filename &optional marker-char)
 609   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 610   ;; files that are going to be omitted anyway.
 611   (if dired-omit-files-p
 612       ;; perhaps return t without calling ls
 613       (let ((omit-re (dired-omit-regexp)))
 614         (if (or (string= omit-re "")
 615                 (not
 616                  (string-match omit-re
 617                                (cond
 618                                 ((eq 'no-dir dired-omit-localp)
 619                                  filename)
 620                                 ((eq t dired-omit-localp)
 621                                  (dired-make-relative filename))
 622                                 (t
 623                                  (dired-make-absolute
 624                                   filename
 625                                   (file-name-directory filename)))))))
 626             ;; if it didn't match, go ahead and add the entry
 627             (dired-omit-old-add-entry filename marker-char)
 628           ;; dired-add-entry returns t for success, perhaps we should
 629           ;; return file-exists-p
 630           t))
 631     ;; omitting is not turned on at all
 632     (dired-omit-old-add-entry filename marker-char)))
 633
 634 ;;; REDEFINE.
 635 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 636 ;;; Save old defun if not already done:
 637 (or (fboundp 'dired-omit-old-add-entry)
 638     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 639 ;; Redefine it.
 640 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 641
 642 \f
 643 ;;; VIRTUAL DIRED MODE.
 644
 645 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 646
 647 (fset 'virtual-dired 'dired-virtual)
 648 (defun dired-virtual (dirname &optional switches)
 649   "Put this buffer into Virtual Dired mode.
 650
 651 In Virtual Dired mode, all commands that do not actually consult the
 652 filesystem will work.
 653
 654 This is useful if you want to peruse and move around in an ls -lR
 655 output file, for example one you got from an ftp server.  With
 656 ange-ftp, you can even dired a directory containing an ls-lR file,
 657 visit that file and turn on virtual dired mode.  But don't try to save
 658 this file, as dired-virtual indents the listing and thus changes the
 659 buffer.
 660
 661 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 662 resume it in a later session.
 663
 664 Type \\<dired-mode-map>\\[revert-buffer] in the
 665 Virtual Dired buffer and answer `y' to convert the virtual to a real
 666 dired buffer again.  You don't have to do this, though: you can relist
 667 single subdirs using \\[dired-do-redisplay].
 668 "
 669
 670   ;; DIRNAME is the top level directory of the buffer.  It will become
 671   ;; its `default-directory'.  If nil, the old value of
 672   ;; default-directory is used.
 673
 674   ;; Optional SWITCHES are the ls switches to use.
 675
 676   ;; Shell wildcards will be used if there already is a `wildcard'
 677   ;; line in the buffer (thus it is a saved Dired buffer), but there
 678   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 679   ;; hand if you want them.
 680
 681   (interactive
 682    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 683   (goto-char (point-min))
 684   (or (looking-at "  ")
 685       ;; if not already indented, do it now:
 686       (indent-region (point-min) (point-max) 2))
 687   (or dirname (setq dirname default-directory))
 688   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 689   (setq default-directory dirname)      ; contains no wildcards
 690   (let ((wildcard (save-excursion
 691                     (goto-char (point-min))
 692                     (forward-line 1)
 693                     (and (looking-at "^  wildcard ")
 694                          (buffer-substring (match-end 0)
 695                                            (progn (end-of-line) (point)))))))
 696   (if wildcard
 697         (setq dirname (expand-file-name wildcard default-directory))))
 698   ;; If raw ls listing (not a saved old dired buffer), give it a
 699   ;; decent subdir headerline:
 700   (goto-char (point-min))
 701   (or (looking-at dired-subdir-regexp)
 702       (dired-insert-headerline default-directory))
 703   (dired-mode dirname (or switches dired-listing-switches))
 704   (setq mode-name "Virtual Dired"
 705         revert-buffer-function 'dired-virtual-revert)
 706   (set (make-local-variable 'dired-subdir-alist) nil)
 707   (dired-build-subdir-alist)
 708   (goto-char (point-min))
 709   (dired-initial-position dirname))
 710
 711 (defun dired-virtual-guess-dir ()
 712
 713   ;; Guess and return appropriate working directory of this buffer,
 714   ;; assumed to be in Dired or ls -lR format.
 715   ;; The guess is based upon buffer contents.
 716   ;; If nothing could be guessed, returns nil.
 717
 718   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 719         (subexpr 2))
 720     (goto-char (point-min))
 721     (cond ((looking-at regexp)
 722            ;; If a saved dired buffer, look to which dir and
 723            ;; perhaps wildcard it belongs:
 724            (let ((dir (buffer-substring (match-beginning subexpr)
 725                                         (match-end subexpr))))
 726              (file-name-as-directory dir)))
 727           ;; Else no match for headerline found.  It's a raw ls listing.
 728           ;; In raw ls listings the directory does not have a headerline
 729           ;; try parent of first subdir, if any
 730           ((re-search-forward regexp nil t)
 731            (file-name-directory
 732             (directory-file-name
 733              (file-name-as-directory
 734               (buffer-substring (match-beginning subexpr)
 735                                 (match-end subexpr))))))
 736           (t                            ; if all else fails
 737            nil))))
 738
 739
 740 (defun dired-virtual-revert (&optional arg noconfirm)
 741   (if (not
 742        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 743       (error "Cannot revert a Virtual Dired buffer.")
 744     (setq mode-name "Dired"
 745           revert-buffer-function 'dired-revert)
 746     (revert-buffer)))
 747
 748 ;; A zero-arg version of dired-virtual.
 749 ;; You need my modified version of set-auto-mode for the
 750 ;; `buffer-contents-mode-alist'.
 751 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 752 (defun dired-virtual-mode ()
 753   "Put current buffer into virtual dired mode (see `dired-virtual').
 754 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 755
 756     \"^  \\(/[^ /]+\\)/?+:$\"
 757
 758 to put saved dired buffers automatically into virtual dired mode.
 759
 760 Also useful for `auto-mode-alist' (which see) like this:
 761
 762   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 763                               auto-mode-alist)\)"
 764   (interactive)
 765   (dired-virtual (dired-virtual-guess-dir)))
 766
 767 \f
 768 ;;; SMART SHELL.
 769
 770 ;;; An Emacs buffer can have but one working directory, stored in the
 771 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 772 ;;; several subdirectories inserted, but still has but one working directory:
 773 ;;; that of the top level Dired directory in that buffer.  For some commands
 774 ;;; it is appropriate that they use the current Dired directory instead of
 775 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 776 ;;; mechanism is provided for special handling of the working directory in
 777 ;;; special major modes.
 778
 779 ;; It's easier to add to this alist than redefine function
 780 ;; default-directory while keeping the old information.
 781 (defconst default-directory-alist
 782   '((dired-mode . (if (fboundp 'dired-current-directory)
 783                       (dired-current-directory)
 784                     default-directory)))
 785   "Alist of major modes and their opinion on default-directory, as a
 786 lisp expression to evaluate.  A resulting value of nil is ignored in
 787 favor of default-directory.")
 788
 789 (defun default-directory ()
 790   "Usage like variable `default-directory', but knows about the special
 791 cases in variable `default-directory-alist' (which see)."
 792   (or (eval (cdr (assq major-mode default-directory-alist)))
 793       default-directory))
 794
 795 (defun dired-smart-shell-command (cmd &optional insert)
 796   "Like function `shell-command', but in the current Tree Dired directory."
 797   (interactive "sShell command: \nP")
 798   (let ((default-directory (default-directory)))
 799     (shell-command cmd insert)))
 800
 801 \f
 802 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 803
 804 ;;; Brief Description:
 805 ;;;
 806 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 807 ;;;
 808 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 809 ;;;
 810 ;;; * `dired-hack-local-variables' checks the value of
 811 ;;;   `dired-local-variables-file'
 812 ;;;
 813 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 814 ;;;   filename found in the directory of the Dired Buffer being created.
 815 ;;;
 816 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 817 ;;;   include it in the Dired Buffer at the bottom.
 818 ;;;
 819 ;;; * Set `enable-local-variables' temporarily to the user variable
 820 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 821 ;;;   Dired Buffer.
 822
 823 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 824   "Filename, as string, containing local dired buffer variables to be hacked.
 825 If this file found in current directory, then it will be inserted into dired
 826 buffer and `hack-local-variables' will be run.  See Emacs Info pages for more
 827 information on local variables.  See also `dired-enable-local-variables'.")
 828
 829 (defun dired-hack-local-variables ()
 830   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 831   (if (and dired-local-variables-file
 832            (stringp dired-local-variables-file)
 833            (file-exists-p dired-local-variables-file))
 834       (let ((opoint (point-max))
 835             buffer-read-only
 836             ;; In case user has `enable-local-variables' set to nil we
 837             ;; override it locally with dired's variable.
 838             (enable-local-variables dired-enable-local-variables))
 839         ;; Insert 'em.
 840         (save-excursion
 841           (goto-char opoint)
 842           (insert "\^L\n")
 843           (insert-file-contents dired-local-variables-file))
 844         ;; Hack 'em.
 845         (let ((buffer-file-name dired-local-variables-file))
 846           (hack-local-variables))
 847         ;; Make sure that the modeline shows the proper information.
 848         (dired-sort-set-modeline)
 849         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 850         (delete-region opoint (point-max)))))
 851
 852 (defun dired-omit-here-always ()
 853   "Creates `dired-local-variables-file' for omitting and reverts directory.
 854 Sets dired-omit-file-p to t in a local variables file that is readable by
 855 dired."
 856   (interactive)
 857   (if (file-exists-p dired-local-variables-file)
 858       (message "File `./%s' already exists." dired-local-variables-file)
 859
 860     ;; Create `dired-local-variables-file'.
 861     (save-excursion
 862       (set-buffer (get-buffer-create " *dot-dired*"))
 863       (erase-buffer)
 864       (insert "Local Variables:\ndired-omit-files-p: t\nEnd:\n")
 865       (write-file dired-local-variables-file)
 866       (kill-buffer (current-buffer)))
 867
 868     ;; Run extra-hooks and revert directory.
 869     (dired-extra-startup)
 870     (dired-revert)))
 871
 872 \f
 873 ;;; GUESS SHELL COMMAND.
 874
 875 ;;; Brief Description:
 876 ;;;
 877 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 878 ;;;
 879 ;;; * Redefine `dired-do-shell-command' so it calls
 880 ;;;   `dired-guess-shell-command'.
 881 ;;;
 882 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 883 ;;;    marked files.
 884 ;;;
 885 ;;; * Parse `dired-guess-shell-alist-user' and
 886 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 887 ;;;   that matches the first file in the file list.
 888 ;;;
 889 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 890 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 891 ;;;   string.  COMMAND may be a list of commands.
 892 ;;;
 893 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 894 ;;;   with it.  The list of commands is temporarily put into the history list.
 895 ;;;   If a command is used successfully then it is stored permanently in
 896 ;;;   `dired-shell-command-history'.
 897
 898 ;;; Guess what shell command to apply to a file.
 899 (defvar dired-shell-command-history nil
 900   "History list for commands that read dired-shell commands.")
 901
 902 ;;; Default list of shell commands.
 903
 904 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 905 ;;; install GNU zip's version of zcat.
 906
 907 (defvar dired-guess-shell-alist-default
 908   (list
 909    (list "\\.tar$" '(if dired-guess-shell-gnutar
 910                         (concat dired-guess-shell-gnutar " xvf")
 911                       "tar xvf"))
 912
 913    ;; REGEXPS for compressed archives must come before the .Z rule to
 914    ;; be recognized:
 915    (list "\\.tar\\.Z$"
 916          ;; Untar it.
 917          '(if dired-guess-shell-gnutar
 918               (concat dired-guess-shell-gnutar " zxvf")
 919             (concat "zcat * | tar xvf -"))
 920          ;; Optional conversion to gzip format.
 921          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 922                   " " dired-guess-shell-znew-switches))
 923
 924    ;; gzip'ed archives
 925    (list "\\.tar\\.g?z$"
 926          '(if dired-guess-shell-gnutar
 927               (concat dired-guess-shell-gnutar " zxvf")
 928             (concat "gunzip -qc * | tar xvf -"))
 929          ;; Optional decompression.
 930          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 931
 932    '("\\.shar.Z$" "zcat * | unshar")
 933    '("\\.shar.g?z$" "gunzip -qc * | unshar")
 934
 935    '("\\.ps$" "ghostview" "xv" "lpr")
 936    (list "\\.ps.g?z$" "gunzip -qc * | ghostview -"
 937          ;; Optional decompression.
 938          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 939    (list "\\.ps.Z$" "zcat * | ghostview -"
 940          ;; Optional conversion to gzip format.
 941          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 942                   " " dired-guess-shell-znew-switches))
 943    '("\\.patch$" "cat * | patch")
 944    '("\\.patch.g?z$" "gunzip -qc * | patch")
 945    (list "\\.patch.Z$" "zcat * | patch"
 946          ;; Optional conversion to gzip format.
 947          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 948                   " " dired-guess-shell-znew-switches))
 949
 950    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
 951    '("\\.au$" "play")                   ; play Sun audiofiles
 952    '("\\.mpg$" "mpeg_play")
 953    '("\\.uu$" "uudecode")               ; for uudecoded files
 954    '("\\.hqx$" "mcvert")
 955    '("\\.sh$" "sh")                     ; execute shell scripts
 956    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
 957    '("\\.gp$" "gnuplot")
 958    '("\\.p[bgpn]m$" "xv")
 959    '("\\.gif$" "xv")                    ; view gif pictures
 960    '("\\.tif$" "xv")
 961    '("\\.jpg$" "xv")
 962    '("\\.fig$" "xfig")                  ; edit fig pictures
 963    '("\\.out$" "xgraph")                ; for plotting purposes.
 964    '("\\.tex$" "latex" "tex")
 965    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
 966
 967    ;; Some other popular archivers.
 968    '("\\.zoo$" "zoo x//")
 969    '("\\.zip$" "unzip")
 970    '("\\.lzh$" "lharc x")
 971    '("\\.arc$" "arc x")
 972    '("\\.shar$" "unshar")
 973
 974    ;; Compression.
 975    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 976    (list "\\.Z$" "uncompress"
 977          ;; Optional conversion to gzip format.
 978          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 979                   " " dired-guess-shell-znew-switches))
 980    )
 981
 982   "Default alist used for shell command guessing.
 983 See `dired-guess-shell-alist-user'")
 984
 985 (defvar dired-guess-shell-alist-user nil
 986   "User-defined alist of rules for suggested commands. These rules take
 987 precedence over the predefined rules in the variable
 988 `dired-guess-shell-alist-default' (to which they are prepended).
 989
 990 Each element of this list looks like
 991
 992     \(REGEXP COMMAND...\)
 993
 994 where each COMMAND can either be a string or a lisp expression that evaluates
 995 to a string.  If several COMMANDs are given, the first one will be the default
 996 and the rest will be added temporarily to the history and can be retrieved
 997 with \\[previous-history-element] (M-p) .
 998
 999 You can set this variable in your ~/.emacs.  For example, to add rules for
1000 `.foo' and `.bar' files, write
1001
1002  \(setq dired-guess-shell-alist-user
1003        (list (list \"\\\\.foo$\" \"FOO-COMMAND\");; fixed rule
1004               ;; possibly more rules ...
1005               (list \"\\\\.bar$\";; rule with condition test
1006                     '(if condition
1007                           \"BAR-COMMAND-1\"
1008                         \"BAR-COMMAND-2\")))\)
1009 ")
1010
1011 (defun dired-guess-default (files)
1012
1013   ;; Guess a shell commands for FILES.  Return command or list of commands.
1014   ;; See `dired-guess-shell-alist-user'.
1015
1016   (let* ((case-fold-search nil) ; case-sensitive matching
1017          ;; Prepend the user's alist to the default alist.
1018          (alist (append dired-guess-shell-alist-user
1019                         dired-guess-shell-alist-default))
1020          (file (car files))
1021          (flist (cdr files))
1022          elt regexp cmds)
1023
1024     ;; Find the first match in the alist for first file in FILES.
1025     (while alist
1026       (setq elt (car alist)
1027             regexp (car elt)
1028             alist (cdr alist))
1029       (if (string-match regexp file)
1030           (setq cmds (cdr elt)
1031                 alist nil)))
1032
1033     ;; If more than one file, see if all of FILES match regular expression.
1034     (while (and flist
1035                 (string-match regexp (car flist)))
1036       (setq flist (cdr flist)))
1037
1038     ;; If flist is still non-nil, then do not guess since this means that not
1039     ;; all the files in FILES were matched by the regexp.
1040     (setq cmds (and (not flist) cmds))
1041
1042     ;; Return commands or nil if flist is still non-nil.
1043     ;; Evaluate the commands in order that any logical testing will be done.
1044     (cond ((not (cdr cmds))
1045            (eval (car cmds))) ; single command
1046           (t
1047            (mapcar (function eval) cmds)))))
1048
1049 (defun dired-guess-shell-command (prompt files)
1050
1051   ;; Ask user with PROMPT for a shell command, guessing a default from FILES.
1052
1053   (let ((default (dired-guess-default files))
1054         default-list old-history val (failed t))
1055
1056     (if (null default)
1057         ;; Nothing to guess
1058         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1059
1060       ;; Save current history list
1061       (setq old-history dired-shell-command-history)
1062
1063       (if (listp default)
1064
1065           ;; More than one guess
1066           (setq default-list default
1067                 default (car default)
1068                 prompt (concat
1069                         prompt
1070                         (format "{%d guesses} " (length default-list))))
1071
1072         ;; Just one guess
1073         (setq default-list (list default)))
1074
1075       ;; Push all guesses onto history so that they can be retrieved with M-p
1076       ;; and put the first guess in the prompt but not in the initial value.
1077       (setq dired-shell-command-history
1078             (append default-list dired-shell-command-history)
1079             prompt (concat prompt (format "[%s] " default)))
1080
1081       ;; The unwind-protect returns VAL, and we too.
1082       (unwind-protect
1083           ;; BODYFORM
1084           (progn
1085             (setq val (read-from-minibuffer prompt nil nil nil
1086                                             'dired-shell-command-history)
1087                   failed nil)
1088             ;; If we got a return, then use default.
1089             (if (equal val "")
1090                 (setq val default))
1091             val)
1092
1093         ;; UNWINDFORMS
1094         ;; Undo pushing onto the history list so that an aborted
1095         ;; command doesn't get the default in the next command.
1096         (setq dired-shell-command-history old-history)
1097         (if (not failed)
1098             (or (equal val (car-safe dired-shell-command-history))
1099                 (setq dired-shell-command-history
1100                       (cons val dired-shell-command-history))))))))
1101
1102
1103 ;;; REDEFINE.
1104 ;;; Redefine dired-aux.el's version:
1105 (defun dired-read-shell-command (prompt arg files)
1106 ;;  "Read a dired shell command prompting with PROMPT (using read-string).
1107 ;;ARG is the prefix arg and may be used to indicate in the prompt which
1108 ;;  files are affected.
1109 ;;This is an extra function so that you can redefine it, e.g., to use gmhist."
1110   (dired-mark-pop-up
1111    nil 'shell files
1112    'dired-guess-shell-command
1113    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1114    files))                                       ; FILES
1115
1116 \f
1117 ;;; RELATIVE SYMBOLIC LINKS.
1118
1119 (defvar dired-keep-marker-relsymlink ?S
1120   "See variable `dired-keep-marker-move'.")
1121
1122 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1123   "Three arguments: FILE1 FILE2 &optional OK-IF-ALREADY-EXISTS
1124 Make a symbolic link (pointing to FILE1) in FILE2.
1125 The link is relative (if possible), for example
1126
1127     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1128
1129 results in
1130
1131     \"../../tex/bin/foo\" \"/vol/local/bin/foo\"
1132 "
1133   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1134   (let (name1 name2 len1 len2 (index 0) sub)
1135     (setq file1 (expand-file-name file1)
1136           file2 (expand-file-name file2)
1137           len1 (length file1)
1138           len2 (length file2))
1139     ;; Find common initial pathname components:
1140     (let (next)
1141       (while (and (setq next (string-match "/" file1 index))
1142                   (setq next (1+ next))
1143                   (< next (min len1 len2))
1144                   ;; For the comparison, both substrings must end in
1145                   ;; `/', so NEXT is *one plus* the result of the
1146                   ;; string-match.
1147                   ;; E.g., consider the case of linking "/tmp/a/abc"
1148                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1149                   ;; of "/tmp/" as common initial component
1150                   (string-equal (substring file1 0 next)
1151                                 (substring file2 0 next)))
1152         (setq index next))
1153       (setq name2 file2
1154             sub (substring file1 0 index)
1155             name1 (substring file1 index)))
1156     (if (string-equal sub "/")
1157         ;; No common initial pathname found
1158         (setq name1 file1)
1159       ;; Else they have a common parent directory
1160       (let ((tem (substring file2 index))
1161             (start 0)
1162             (count 0))
1163         ;; Count number of slashes we must compensate for ...
1164         (while (setq start (string-match "/" tem start))
1165           (setq count (1+ count)
1166                 start (1+ start)))
1167         ;; ... and prepend a "../" for each slash found:
1168         (while (> count 0)
1169           (setq count (1- count)
1170                 name1 (concat "../" name1)))))
1171     (make-symbolic-link
1172      (directory-file-name name1)        ; must not link to foo/
1173                                         ; (trailing slash!)
1174      name2 ok-if-already-exists)))
1175
1176 (defun dired-do-relsymlink (&optional arg)
1177    "Relative symlink all marked (or next ARG) files into a directory,
1178 or make a relative symbolic link to the current file.
1179 This creates relative symbolic links like
1180
1181     foo -> ../bar/foo
1182
1183 not absolute ones like
1184
1185     foo -> /ugly/path/that/may/change/any/day/bar/foo"
1186   (interactive "P")
1187   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1188                            "RelSymLink" arg dired-keep-marker-relsymlink))
1189
1190 (defun dired-do-relsymlink-regexp (regexp newname &optional whole-path)
1191   "RelSymlink all marked files containing REGEXP to NEWNAME.
1192 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1193 for more info."
1194   (interactive (dired-mark-read-regexp "RelSymLink"))
1195   (dired-do-create-files-regexp
1196    (function dired-make-relative-symlink)
1197    "RelSymLink" nil regexp newname whole-path dired-keep-marker-relsymlink))
1198
1199 \f
1200 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1201
1202 ;;; Brief Description:
1203 ;;;
1204 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1205 ;;;
1206 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1207 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1208 ;;;
1209 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1210 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1211 ;;;
1212 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1213 ;;;   list each time.
1214 ;;;
1215 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1216 ;;;   element of FILE-LIST.
1217 ;;;
1218 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1219 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1220 ;;;   cognizant of the window-configuration.
1221 ;;;
1222 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1223 ;;;   of FILE-LIST giving each a window of height `size'.
1224
1225 (defun dired-do-find-marked-files (&optional noselect)
1226   "Find all marked files displaying all of them simultaneously.
1227 With optional NOSELECT just find files but do not select them.
1228
1229 The current window is split across all files marked, as evenly as possible.
1230 Remaining lines go to bottom-most window.  The number of files that can be
1231 displayed this way is restricted by the height of the current window and
1232 `window-min-height'.
1233
1234 To keep dired buffer displayed, type \\[split-window-vertically] first.
1235 To display just marked files, type \\[delete-other-windows] first."
1236
1237   (interactive "P")
1238   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1239
1240 (defun dired-simultaneous-find-file (file-list noselect)
1241
1242   ;; Visit all files in FILE-LIST and display them simultaneously.  The
1243   ;; current window is split across all files in FILE-LIST, as evenly as
1244   ;; possible.  Remaining lines go to the bottom-most window.  The number of
1245   ;; files that can be displayed this way is restricted by the height of the
1246   ;; current window and the variable `window-min-height'.  With non-nil
1247   ;; NOSELECT the files are merely found but not selected.
1248
1249   ;; We don't make this function interactive because it is usually too clumsy
1250   ;; to specify FILE-LIST interactively unless via dired.
1251
1252   (let (size)
1253
1254     (if noselect
1255         ;; Do not select the buffer.
1256         (find-file-noselect (car file-list))
1257
1258       ;; We will have to select the buffer.  Calculate and check window size.
1259       (setq size (/ (window-height) (length file-list)))
1260       (or (<= window-min-height size)
1261           (error "Too many files to visit simultaneously.  Try C-u prefix."))
1262       (find-file (car file-list)))
1263
1264     ;; Decrement.
1265     (setq file-list (cdr file-list))
1266
1267     (while file-list
1268
1269       (if noselect
1270           ;; Do not select the buffer.
1271           (find-file-noselect (car file-list))
1272
1273         ;; Vertically split off a window of desired size.  Upper window will
1274         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1275         (select-window (split-window nil size))
1276         (find-file (car file-list)))
1277
1278       ;; Decrement.
1279       (setq file-list (cdr file-list)))))
1280
1281 \f
1282 ;;; MISCELLANEOUS COMMANDS.
1283
1284 ;;; Run man on files.
1285
1286 (defun dired-man ()
1287   "Run man on this file.  Display old buffer if buffer name matches filename.
1288 Uses ../lisp/man.el of \\[manual-entry] fame."
1289   (interactive)
1290   (require 'man)
1291   (let ((file (dired-get-filename))
1292         (manual-program "nroff -man -h"))
1293     (Man-getpage-in-background file)))
1294
1295 ;;; Run Info on files.
1296
1297 (defun dired-info ()
1298   "Run info on this file."
1299   (interactive)
1300   (info (dired-get-filename)))
1301
1302 ;;; Run mail on mail folders.
1303
1304 ;;; (and (not (fboundp 'vm-visit-folder))
1305 ;;;      (defun vm-visit-folder (file &optional arg)
1306 ;;;        nil))
1307
1308 (defun dired-vm (&optional read-only)
1309   "Run VM on this file.
1310 With prefix arg, visit folder read-only (this requires at least VM 5).
1311 See also variable `dired-vm-read-only-folders'."
1312   (interactive "P")
1313   (let ((dir (dired-current-directory))
1314         (fil (dired-get-filename)))
1315     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1316     (cond (read-only (vm-visit-folder fil t))
1317           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1318           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1319           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1320     ;; so that pressing `v' inside VM does prompt within current directory:
1321     (set (make-local-variable 'vm-folder-directory) dir)))
1322
1323 (defun dired-rmail ()
1324   "Run RMAIL on this file."
1325   (interactive)
1326   (rmail (dired-get-filename)))
1327
1328 (defun dired-do-run-mail ()
1329   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1330   (interactive)
1331   (if dired-bind-vm
1332       ;; Read mail folder using vm.
1333       (dired-vm)
1334     ;; Read mail folder using rmail.
1335     (dired-rmail)))
1336
1337 \f
1338 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1339
1340 (or (fboundp 'dired-old-find-buffer-nocreate)
1341     (fset 'dired-old-find-buffer-nocreate
1342           (symbol-function 'dired-find-buffer-nocreate)))
1343
1344 ;;; REDEFINE.
1345 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1346 (defun dired-find-buffer-nocreate (dirname &optional mode)
1347   (if (and dired-find-subdir
1348            ;; don't try to find a wildcard as a subdirectory
1349            (string-equal dirname (file-name-directory dirname)))
1350       (let* ((cur-buf (current-buffer))
1351              (buffers (nreverse
1352                        (dired-buffers-for-dir (expand-file-name dirname))))
1353              (cur-buf-matches (and (memq cur-buf buffers)
1354                                    ;; wildcards must match, too:
1355                                    (equal dired-directory dirname))))
1356         ;; We don't want to switch to the same buffer---
1357         (setq buffers (delq cur-buf buffers));;need setq with delq
1358         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1359             ;; ---unless it's the only possibility:
1360             (and cur-buf-matches cur-buf)))
1361     (dired-old-find-buffer-nocreate dirname mode)))
1362
1363 ;; This should be a builtin
1364 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1365   "Return t if BUFFER1 is more recently used than BUFFER2."
1366   (if (equal buffer1 buffer2)
1367       nil
1368     (let ((more-recent nil)
1369           (list (buffer-list)))
1370       (while (and list
1371                   (not (setq more-recent (equal buffer1 (car list))))
1372                   (not (equal buffer2 (car list))))
1373         (setq list (cdr list)))
1374       more-recent)))
1375
1376 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1377 ;;; (defun dired-buffers-for-dir-exact (dir)
1378 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1379 ;;; ;; at top level, or as subdirectory.
1380 ;;; ;; Top level matches must match the wildcard part too, if any.
1381 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1382 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1383 ;;; ;; dired-buffers.
1384 ;;;   (let ((alist dired-buffers) result elt)
1385 ;;;     (while alist
1386 ;;;       (setq elt (car alist)
1387 ;;;             alist (cdr alist))
1388 ;;;       (let ((buf (cdr elt)))
1389 ;;;         (if (buffer-name buf)
1390 ;;;             ;; Top level must match exactly against dired-directory in
1391 ;;;             ;; case one of them is a wildcard.
1392 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1393 ;;;                                                dired-directory))
1394 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1395 ;;;                                                dired-subdir-alist)))
1396 ;;;                 (setq result (cons buf result)))
1397 ;;;           ;; else buffer is killed - clean up:
1398 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1399 ;;;     result))
1400
1401 ;;; REDEFINE.
1402 ;;; Redefines dired.el's version of `dired-initial-position'
1403 (defun dired-initial-position (dirname)
1404   (end-of-line)
1405   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1406   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1407
1408 \f
1409 ;; Does anyone use this? - lrd 6/29/93.
1410 (defun dired-mark-sexp (predicate &optional unflag-p)
1411   "Mark files for which PREDICATE returns non-nil.
1412 With a prefix arg, unflag those files instead.
1413
1414 PREDICATE is a lisp expression that can refer to the following symbols:
1415
1416     inode  [integer] the inode of the file (only for ls -i output)
1417     s      [integer] the size of the file for ls -s output
1418                      (usually in blocks or, with -k, in KByte)
1419     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1420     nlink  [integer] number of links to file
1421     uid    [string]  owner
1422     gid    [string]  group  (If the gid is not displayed by ls,
1423                      this will still be set (to the same as uid))
1424     size   [integer] file size in bytes
1425     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1426     name   [string]  the name of the file
1427     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1428
1429 For example, use
1430
1431         (equal 0 size)
1432
1433 to mark all zero length files."
1434   ;; Using sym="" instead of nil avoids the trap of
1435   ;; (string-match "foo" sym) into which a user would soon fall.
1436   ;; Give `equal' instead of `=' in the example, as this works on
1437   ;; integers and strings.
1438   (interactive "xMark if (lisp expr): \nP")
1439   (message "%s" predicate)
1440   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1441         inode s mode nlink uid gid size time name sym)
1442     (dired-mark-if
1443      (save-excursion
1444        (and
1445         ;; Sets vars
1446         ;;                inode s mode nlink uid gid size time name sym
1447
1448         ;; according to current file line.  Returns t for success, nil if
1449         ;; there is no file line.  Upon success, all variables are set, either
1450         ;; to nil or the appropriate value, so they need not be initialized.
1451         ;; Moves point within the current line.
1452         (if (dired-move-to-filename)
1453             (let (pos
1454                   (mode-len 10) ; length of mode string
1455                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1456                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1457               (beginning-of-line)
1458               (forward-char 2)
1459               (if (looking-at dired-re-inode-size)
1460                   (progn
1461                     (goto-char (match-end 0))
1462                     (setq inode (string-to-int (buffer-substring (match-beginning 1)
1463                                                                  (match-end 1)))
1464                           s (string-to-int (buffer-substring (match-beginning 2)
1465                                                              (match-end 2)))))
1466                 (setq inode nil
1467                       s nil))
1468               (setq mode (buffer-substring (point) (+ mode-len (point))))
1469               (forward-char mode-len)
1470               (setq nlink (read (current-buffer)))
1471               (setq uid (buffer-substring (point) (progn (forward-word 1) (point))))
1472               (re-search-forward "\\(Jan\\|Feb\\|Mar\\|Apr\\|May\\|Jun\\|Jul\\|Aug\\|Sep\\|Oct\\|Nov\\|Dec\\)")
1473               (goto-char (match-beginning 1))
1474               (forward-char -1)
1475               (setq size (string-to-int (buffer-substring (save-excursion
1476                                                             (backward-word 1)
1477                                                             (setq pos (point)))
1478                                                           (point))))
1479               (goto-char pos)
1480               (backward-word 1)
1481               ;; if no gid is displayed, gid will be set to uid
1482               ;; but user will then not reference it anyway in PREDICATE.
1483               (setq gid (buffer-substring (save-excursion (forward-word 1) (point))
1484                                           (point))
1485                     time (buffer-substring (match-beginning 1)
1486                                            (1- (dired-move-to-filename)))
1487                     name (buffer-substring (point)
1488                                            (or (dired-move-to-end-of-filename t)
1489                                                (point)))
1490                     sym  (progn
1491                            (if (looking-at " -> ")
1492                                (buffer-substring (progn (forward-char 4) (point))
1493                                                  (progn (end-of-line) (point)))
1494                              "")))
1495               t)
1496           nil)
1497                       (eval predicate)))
1498      (format "'%s file" predicate))))
1499
1500 \f
1501 ;;; FIND FILE AT POINT.
1502
1503 (defvar dired-x-hands-off-my-keys t
1504   "*t means don't bind `dired-x-find-file' over `find-file' on keyboard.
1505 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1506 If you change this variable after dired-x.el is loaded then do
1507 \\[dired-x-bind-find-file].")
1508
1509 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1510 ;;; `find-file{-other-window}' is bound?
1511 (defun dired-x-bind-find-file ()
1512   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1513 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1514 Binding direction based on `dired-x-hands-off-my-keys'.
1515 This function part of `after-init-hook'."
1516   (interactive)
1517   (if (interactive-p)
1518       (setq dired-x-hands-off-my-keys
1519             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1520   (cond ((not dired-x-hands-off-my-keys)
1521          (substitute-key-definition 'find-file
1522                                     'dired-x-find-file
1523                                     (current-global-map))
1524          (substitute-key-definition 'find-file-other-window
1525                                     'dired-x-find-file-other-window
1526                                     (current-global-map)))
1527         (t
1528          (substitute-key-definition 'dired-x-find-file
1529                                     'find-file
1530                                     (current-global-map))
1531          (substitute-key-definition 'dired-x-find-file-other-window
1532                                     'find-file-other-window
1533                                     (current-global-map))))
1534   ;; Clear mini-buffer.
1535   (message nil))
1536
1537 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1538 ;;; user changes binding.
1539 (dired-x-bind-find-file)
1540 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1541
1542 (defun dired-x-find-file (filename)
1543   "Edit file FILENAME.
1544 May create a new window, or reuse an existing one.
1545 See the function `display-buffer'.
1546
1547 Identical to `find-file' except when called interactively, with a prefix arg
1548 \(e.g., \\[universal-argument]\), in which case it guesses filename near
1549 point.  Useful for editing file mentioned in buffer you are viewing, or to
1550 test if that file exists.  Use minibuffer after snatching filename."
1551   (interactive (list (read-filename-at-point "Find file: ")))
1552   (find-file (expand-file-name filename)))
1553
1554 (defun dired-x-find-file-other-window (filename)
1555   "Edit file FILENAME, in another window.
1556 May create a new window, or reuse an existing one.
1557 See the function `display-buffer'.
1558
1559 Identical to `find-file-other-window' except when called interactively, with a
1560 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename
1561 near point.  Useful for editing file mentioned in buffer you are viewing, or
1562 to test if that file exists.  Use minibuffer after snatching filename."
1563   (interactive (list (read-filename-at-point "Find file: ")))
1564   (find-file-other-window (expand-file-name filename)))
1565
1566 ;;; Internal functions.
1567 (defun dired-filename-at-point ()
1568
1569   ;; Get the filename closest to point, but do not change position.  Has a
1570   ;; preference for looking backward when not directly on a symbol.  Not
1571   ;; perfect - point must be in middle of or end of filename.
1572
1573   (let ((filename-chars ".a-zA-Z0-9---_/:$+")
1574         (bol (save-excursion (beginning-of-line) (point)))
1575         (eol (save-excursion (end-of-line) (point)))
1576         start end filename)
1577
1578     (save-excursion
1579       ;; First see if just past a filename.
1580       (if (not (eobp))
1581           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1582               (progn
1583                 (skip-chars-backward " \n\t\r({[]})")
1584                 (if (not (bobp))
1585                     (backward-char 1)))))
1586
1587       (if (string-match (concat "[" filename-chars "]")
1588                         (char-to-string (following-char)))
1589           (progn
1590             (skip-chars-backward filename-chars)
1591             (setq start (point))
1592             (if (string-match "[/~]" (char-to-string (preceding-char)))
1593                 (setq start (1- start)))
1594             (skip-chars-forward filename-chars))
1595
1596         (error "No file found around point!"))
1597
1598       ;; Return string.
1599       (expand-file-name (buffer-substring start (point))))))
1600
1601 (defun read-filename-at-point (prompt)
1602   ;;; Returns filename prompting with PROMPT with completion.  If
1603   ;;; `current-prefix-arg' is non-nil, uses name at point as guess.
1604   (if current-prefix-arg
1605       (let ((guess (dired-filename-at-point)))
1606         (read-file-name prompt
1607                         (file-name-directory guess)
1608                         guess
1609                         nil (file-name-nondirectory guess)))
1610     (read-file-name prompt default-directory)))
1611
1612 \f
1613 ;;; BUG REPORTS
1614
1615 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1616 ;;; reporter.el which is bundled with GNU Emacs v19.
1617
1618 (defconst dired-x-version "2.37"
1619   "Revision number of dired-x.el -- dired extra for GNU Emacs v19.
1620 Type \\[dired-x-submit-report] to send a bug report.  Available via anonymous
1621 ftp in
1622
1623    /roebling.poly.edu:/pub/packages/dired-x.tar.gz")
1624
1625 (defconst dired-x-help-address "dodd@roebling.poly.edu"
1626   "Address(es) accepting submission of reports on dired-x.el.")
1627
1628 (defconst dired-x-maintainer "Larry"
1629   "First name(s) of people accepting submission of reports on dired-x.el.")
1630
1631 (defconst dired-x-file "dired-x.el"
1632   "Name of file containing emacs lisp code.")
1633
1634 (defconst dired-x-variable-list
1635   (list
1636    'dired-bind-vm
1637    'dired-vm-read-only-folders
1638    'dired-bind-jump
1639    'dired-bind-info
1640    'dired-bind-man
1641    'dired-find-subdir
1642    'dired-enable-local-variables
1643    'dired-local-variables-file
1644    'dired-guess-shell-gnutar
1645    'dired-guess-shell-gzip-quiet
1646    'dired-guess-shell-znew-switches
1647    'dired-guess-shell-alist-user
1648    'dired-clean-up-buffers-too
1649    'dired-omit-files-p
1650    'dired-omit-files
1651    'dired-omit-extensions
1652    )
1653   "List of variables to be appended to reports sent by `dired-x-submit-report.'")
1654
1655 (defun dired-x-submit-report ()
1656   "Submit via reporter.el a bug report on program.  Send report on `dired-x-file'
1657 version `dired-x-version,' to `dired-x-maintainer' at address `dired-x-help-address'
1658 listing variables `dired-x-variable-list' in the message."
1659   (interactive)
1660
1661   ;; In case we can't find reporter...
1662   (condition-case err
1663       (progn
1664         ;; Get it if we can.
1665         (require 'reporter)
1666
1667         (reporter-submit-bug-report
1668          dired-x-help-address                           ; address
1669          (concat dired-x-file " (" dired-x-version ")") ; pkgname
1670          dired-x-variable-list                          ; varlist
1671          nil nil                                        ; pre-/post-hooks
1672          (concat dired-x-maintainer ",")))              ; salutation
1673
1674     ;; ...fail gracefully.
1675     (error
1676      (beep)
1677      (message "Sorry, reporter.el not found."))))
1678
1679 \f
1680 ;; As Barry Warsaw would say: "This might be useful..."
1681 (provide 'dired-x)
1682
1683 ;;; dired-x.el ends here