lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el.
   2
   3 ;; Copyright (C) 1988, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; Code:
  69
  70 (require 'scheme)
  71 (require 'comint)
  72
  73 ;;; INFERIOR SCHEME MODE STUFF
  74 ;;;============================================================================
  75
  76 (defvar inferior-scheme-mode-hook nil
  77   "*Hook for customising inferior-scheme mode.")
  78 (defvar inferior-scheme-mode-map nil)
  79
  80 (cond ((not inferior-scheme-mode-map)
  81        (setq inferior-scheme-mode-map
  82              (copy-keymap comint-mode-map))
  83        (define-key inferior-scheme-mode-map "\M-\C-x" ;gnu convention
  84                    'scheme-send-definition)
  85        (define-key inferior-scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp)
  86        (define-key inferior-scheme-mode-map "\C-c\C-l" 'scheme-load-file)
  87        (define-key inferior-scheme-mode-map "\C-c\C-k" 'scheme-compile-file)
  88        (scheme-mode-commands inferior-scheme-mode-map)))
  89
  90 ;; Install the process communication commands in the scheme-mode keymap.
  91 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
  92 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
  93 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
  94 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
  95 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
  96 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
  97 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
  98 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
  99 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 100 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 101 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 102
 103 (defvar scheme-buffer)
 104
 105 (defun inferior-scheme-mode ()
 106   "Major mode for interacting with an inferior Scheme process.
 107
 108 The following commands are available:
 109 \\{inferior-scheme-mode-map}
 110
 111 A Scheme process can be fired up with M-x run-scheme.
 112
 113 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 114 inferior-scheme-mode-hook (in that order).
 115
 116 You can send text to the inferior Scheme process from other buffers containing
 117 Scheme source.
 118     switch-to-scheme switches the current buffer to the Scheme process buffer.
 119     scheme-send-definition sends the current definition to the Scheme process.
 120     scheme-compile-definition compiles the current definition.
 121     scheme-send-region sends the current region to the Scheme process.
 122     scheme-compile-region compiles the current region.
 123
 124     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 125         scheme-send-region-and-go, and scheme-compile-region-and-go
 126         switch to the Scheme process buffer after sending their text.
 127 For information on running multiple processes in multiple buffers, see
 128 documentation for variable scheme-buffer.
 129
 130 Commands:
 131 Return after the end of the process' output sends the text from the
 132     end of process to point.
 133 Return before the end of the process' output copies the sexp ending at point
 134     to the end of the process' output, and sends it.
 135 Delete converts tabs to spaces as it moves back.
 136 Tab indents for Scheme; with argument, shifts rest
 137     of expression rigidly with the current line.
 138 C-M-q does Tab on each line starting within following expression.
 139 Paragraphs are separated only by blank lines.  Semicolons start comments.
 140 If you accidentally suspend your process, use \\[comint-continue-subjob]
 141 to continue it."
 142   (interactive)
 143   (comint-mode)
 144   ;; Customise in inferior-scheme-mode-hook
 145   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 146   (scheme-mode-variables)
 147   (setq major-mode 'inferior-scheme-mode)
 148   (setq mode-name "Inferior Scheme")
 149   (setq mode-line-process '(":%s"))
 150   (use-local-map inferior-scheme-mode-map)
 151   (setq comint-input-filter (function scheme-input-filter))
 152   (setq comint-get-old-input (function scheme-get-old-input))
 153   (run-hooks 'inferior-scheme-mode-hook))
 154
 155 (defvar inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 156   "*Input matching this regexp are not saved on the history list.
 157 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters.")
 158
 159 (defun scheme-input-filter (str)
 160   "Don't save anything matching inferior-scheme-filter-regexp"
 161   (not (string-match inferior-scheme-filter-regexp str)))
 162
 163 (defun scheme-get-old-input ()
 164   "Snarf the sexp ending at point"
 165   (save-excursion
 166     (let ((end (point)))
 167       (backward-sexp)
 168       (buffer-substring (point) end))))
 169
 170 (defun scheme-args-to-list (string)
 171   (let ((where (string-match "[ \t]" string)))
 172     (cond ((null where) (list string))
 173           ((not (= where 0))
 174            (cons (substring string 0 where)
 175                  (scheme-args-to-list (substring string (+ 1 where)
 176                                                  (length string)))))
 177           (t (let ((pos (string-match "[^ \t]" string)))
 178                (if (null pos)
 179                    nil
 180                  (scheme-args-to-list (substring string pos
 181                                                  (length string)))))))))
 182
 183 (defvar scheme-program-name "scheme"
 184   "*Program invoked by the run-scheme command")
 185
 186 ;;;###autoload
 187 (defun run-scheme (cmd)
 188   "Run an inferior Scheme process, input and output via buffer *scheme*.
 189 If there is a process already running in `*scheme*', switch to that buffer.
 190 With argument, allows you to edit the command line (default is value
 191 of `scheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 192 \(after the `comint-mode-hook' is run).
 193 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 194
 195   (interactive (list (if current-prefix-arg
 196                          (read-string "Run Scheme: " scheme-program-name)
 197                          scheme-program-name)))
 198   (if (not (comint-check-proc "*scheme*"))
 199       (let ((cmdlist (scheme-args-to-list cmd)))
 200         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 201                            nil (cdr cmdlist)))
 202         (inferior-scheme-mode)))
 203   (setq scheme-program-name cmd)
 204   (setq scheme-buffer "*scheme*")
 205   (pop-to-buffer "*scheme*"))
 206 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 207
 208 (defun scheme-send-region (start end)
 209   "Send the current region to the inferior Scheme process."
 210   (interactive "r")
 211   (comint-send-region (scheme-proc) start end)
 212   (comint-send-string (scheme-proc) "\n"))
 213
 214 (defun scheme-send-definition ()
 215   "Send the current definition to the inferior Scheme process."
 216   (interactive)
 217   (save-excursion
 218    (end-of-defun)
 219    (let ((end (point)))
 220      (beginning-of-defun)
 221      (scheme-send-region (point) end))))
 222
 223 (defun scheme-send-last-sexp ()
 224   "Send the previous sexp to the inferior Scheme process."
 225   (interactive)
 226   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 227
 228 (defvar scheme-compile-exp-command "(compile '%s)"
 229   "*Template for issuing commands to compile arbitrary Scheme expressions.")
 230
 231 (defun scheme-compile-region (start end)
 232   "Compile the current region in the inferior Scheme process.
 233 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 234   (interactive "r")
 235   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 236                                             (format "(begin %s)"
 237                                                     (buffer-substring start end))))
 238   (comint-send-string (scheme-proc) "\n"))
 239
 240 (defun scheme-compile-definition ()
 241   "Compile the current definition in the inferior Scheme process."
 242   (interactive)
 243   (save-excursion
 244    (end-of-defun)
 245    (let ((end (point)))
 246      (beginning-of-defun)
 247      (scheme-compile-region (point) end))))
 248
 249 (defun switch-to-scheme (eob-p)
 250   "Switch to the scheme process buffer.
 251 With argument, positions cursor at end of buffer."
 252   (interactive "P")
 253   (if (get-buffer scheme-buffer)
 254       (pop-to-buffer scheme-buffer)
 255       (error "No current process buffer. See variable scheme-buffer."))
 256   (cond (eob-p
 257          (push-mark)
 258          (goto-char (point-max)))))
 259
 260 (defun scheme-send-region-and-go (start end)
 261   "Send the current region to the inferior Scheme process.
 262 Then switch to the process buffer."
 263   (interactive "r")
 264   (scheme-send-region start end)
 265   (switch-to-scheme t))
 266
 267 (defun scheme-send-definition-and-go ()
 268   "Send the current definition to the inferior Scheme.
 269 Then switch to the process buffer."
 270   (interactive)
 271   (scheme-send-definition)
 272   (switch-to-scheme t))
 273
 274 (defun scheme-compile-definition-and-go ()
 275   "Compile the current definition in the inferior Scheme.
 276 Then switch to the process buffer."
 277   (interactive)
 278   (scheme-compile-definition)
 279   (switch-to-scheme t))
 280
 281 (defun scheme-compile-region-and-go (start end)
 282   "Compile the current region in the inferior Scheme.
 283 Then switch to the process buffer."
 284   (interactive "r")
 285   (scheme-compile-region start end)
 286   (switch-to-scheme t))
 287
 288 (defvar scheme-source-modes '(scheme-mode)
 289   "*Used to determine if a buffer contains Scheme source code.
 290 If it's loaded into a buffer that is in one of these major modes, it's
 291 considered a scheme source file by scheme-load-file and scheme-compile-file.
 292 Used by these commands to determine defaults.")
 293
 294 (defvar scheme-prev-l/c-dir/file nil
 295   "Caches the last (directory . file) pair.
 296 Caches the last pair used in the last scheme-load-file or
 297 scheme-compile-file command. Used for determining the default in the
 298 next one.")
 299
 300 (defun scheme-load-file (file-name)
 301   "Load a Scheme file into the inferior Scheme process."
 302   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 303                                   scheme-source-modes t)) ; T because LOAD
 304                                                           ; needs an exact name
 305   (comint-check-source file-name) ; Check to see if buffer needs saved.
 306   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 307                                        (file-name-nondirectory file-name)))
 308   (comint-send-string (scheme-proc) (concat "(load \""
 309                                             file-name
 310                                             "\"\)\n")))
 311
 312 (defun scheme-compile-file (file-name)
 313   "Compile a Scheme file in the inferior Scheme process."
 314   (interactive (comint-get-source "Compile Scheme file: "
 315                                   scheme-prev-l/c-dir/file
 316                                   scheme-source-modes
 317                                   nil)) ; NIL because COMPILE doesn't
 318                                         ; need an exact name.
 319   (comint-check-source file-name) ; Check to see if buffer needs saved.
 320   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 321                                        (file-name-nondirectory file-name)))
 322   (comint-send-string (scheme-proc) (concat "(compile-file \""
 323                                             file-name
 324                                             "\"\)\n")))
 325
 326 \f
 327 (defvar scheme-buffer nil "*The current scheme process buffer.
 328
 329 MULTIPLE PROCESS SUPPORT
 330 ===========================================================================
 331 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 332 processes. To run multiple Scheme processes, you start the first up with
 333 \\[run-scheme]. It will be in a buffer named *scheme*. Rename this buffer
 334 with \\[rename-buffer]. You may now start up a new process with another
 335 \\[run-scheme]. It will be in a new buffer, named *scheme*. You can
 336 switch between the different process buffers with \\[switch-to-buffer].
 337
 338 Commands that send text from source buffers to Scheme processes --
 339 like scheme-send-definition or scheme-compile-region -- have to choose a
 340 process to send to, when you have more than one Scheme process around. This
 341 is determined by the global variable scheme-buffer. Suppose you
 342 have three inferior Schemes running:
 343     Buffer      Process
 344     foo         scheme
 345     bar         scheme<2>
 346     *scheme*    scheme<3>
 347 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 348 code, what process do you send it to?
 349
 350 - If you're in a process buffer (foo, bar, or *scheme*),
 351   you send it to that process.
 352 - If you're in some other buffer (e.g., a source file), you
 353   send it to the process attached to buffer scheme-buffer.
 354 This process selection is performed by function scheme-proc.
 355
 356 Whenever \\[run-scheme] fires up a new process, it resets scheme-buffer
 357 to be the new process's buffer. If you only run one process, this will
 358 do the right thing. If you run multiple processes, you can change
 359 scheme-buffer to another process buffer with \\[set-variable].
 360
 361 More sophisticated approaches are, of course, possible. If you find yourself
 362 needing to switch back and forth between multiple processes frequently,
 363 you may wish to consider ilisp.el, a larger, more sophisticated package
 364 for running inferior Lisp and Scheme processes. The approach taken here is
 365 for a minimal, simple implementation. Feel free to extend it.")
 366
 367 (defun scheme-proc ()
 368   "Returns the current scheme process. See variable scheme-buffer."
 369   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 370                                       (current-buffer)
 371                                       scheme-buffer))))
 372     (or proc
 373         (error "No current process. See variable scheme-buffer"))))
 374
 375
 376 ;;; Do the user's customisation...
 377
 378 (defvar cmuscheme-load-hook nil
 379   "This hook is run when cmuscheme is loaded in.
 380 This is a good place to put keybindings.")
 381
 382 (run-hooks 'cmuscheme-load-hook)
 383
 384
 385 ;;; CHANGE LOG
 386 ;;; ===========================================================================
 387 ;;; 8/88 Olin
 388 ;;; Created.
 389 ;;;
 390 ;;; 2/15/89 Olin
 391 ;;; Removed -emacs flag from process invocation. It's only useful for
 392 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
 393 ;;; which messes things up royally. A bug.
 394 ;;;
 395 ;;; 5/22/90 Olin
 396 ;;; - Upgraded to use comint-send-string and comint-send-region.
 397 ;;; - run-scheme now offers to let you edit the command line if
 398 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
 399 ;;;   has been removed.
 400 ;;; - Explicit references to process "scheme" have been replaced with
 401 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
 402 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
 403 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
 404 ;;;   and friends, but interested hackers might find a useful application
 405 ;;;   of this facility.
 406 ;;;
 407 ;;; 3/12/90 Olin
 408 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
 409 ;;;   Tale suggested this.
 410
 411 (provide 'cmuscheme)
 412
 413 ;;; cmuscheme.el ends here