lisp/calendar/cal-iso.el

   1 ;;; cal-iso.el --- calendar functions for the ISO calendar.
   2
   3 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   6 ;; Keywords: calendar
   7 ;; Human-Keywords: ISO calendar, calendar, diary
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This collection of functions implements the features of calendar.el and
  29 ;; diary.el that deal with the ISO calendar.
  30
  31 ;; Comments, corrections, and improvements should be sent to
  32 ;;  Edward M. Reingold               Department of Computer Science
  33 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  34 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  35 ;;                                   Urbana, Illinois 61801
  36
  37 ;;; Code:
  38
  39 (require 'calendar)
  40
  41 (defun calendar-absolute-from-iso (date)
  42   "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
  43 The `ISO year' corresponds approximately to the Gregorian year, but
  44 weeks start on Monday and end on Sunday.  The first week of the ISO year is
  45 the first such week in which at least 4 days are in a year.  The ISO
  46 commercial DATE has the form (week day year) in which week is in the range
  47 1..52 and day is in the range 0..6 (1 = Monday, 2 = Tuesday, ..., 0 =
  48 Sunday).  The Gregorian date Sunday, December 31, 1 BC is imaginary."
  49   (let* ((week (extract-calendar-month date))
  50          (day (extract-calendar-day date))
  51          (year (extract-calendar-year date)))
  52     (+ (calendar-dayname-on-or-before
  53         1 (+ 3 (calendar-absolute-from-gregorian (list 1 1 year))))
  54        (* 7 (1- week))
  55        (if (= day 0) 6 (1- day)))))
  56
  57 (defun calendar-iso-from-absolute (date)
  58   "Compute the `ISO commercial date' corresponding to the absolute DATE.
  59 The ISO year corresponds approximately to the Gregorian year, but weeks
  60 start on Monday and end on Sunday.  The first week of the ISO year is the
  61 first such week in which at least 4 days are in a year.  The ISO commercial
  62 date has the form (week day year) in which week is in the range 1..52 and
  63 day is in the range 0..6 (1 = Monday, 2 = Tuesday, ..., 0 = Sunday).  The
  64 absolute date is the number of days elapsed since the (imaginary) Gregorian
  65 date Sunday, December 31, 1 BC."
  66   (let* ((approx (extract-calendar-year
  67                   (calendar-gregorian-from-absolute (- date 3))))
  68          (year (+ approx
  69                   (calendar-sum y approx
  70                       (>= date (calendar-absolute-from-iso (list 1 1 (1+ y))))
  71                       1))))
  72     (list
  73      (1+ (/ (- date (calendar-absolute-from-iso (list 1 1 year))) 7))
  74      (% date 7)
  75      year)))
  76
  77 (defun calendar-iso-date-string (&optional date)
  78   "String of ISO date of Gregorian DATE.
  79 Defaults to today's date if DATE is not given."
  80   (let* ((d (calendar-absolute-from-gregorian
  81              (or date (calendar-current-date))))
  82          (day (% d 7))
  83          (iso-date (calendar-iso-from-absolute d)))
  84     (format "Day %s of week %d of %d"
  85             (if (zerop day) 7 day)
  86             (extract-calendar-month iso-date)
  87             (extract-calendar-year iso-date))))
  88
  89 (defun calendar-print-iso-date ()
  90   "Show equivalent ISO date for the date under the cursor."
  91   (interactive)
  92   (message "ISO date: %s"
  93            (calendar-iso-date-string (calendar-cursor-to-date t))))
  94
  95 (defun calendar-goto-iso-date (date &optional noecho)
  96   "Move cursor to ISO DATE; echo ISO date unless NOECHO is t."
  97   (interactive
  98    (let* ((today (calendar-current-date))
  99           (year (calendar-read
 100                  "ISO calendar year (>0): "
 101                  '(lambda (x) (> x 0))
 102                  (int-to-string (extract-calendar-year today))))
 103           (no-weeks (extract-calendar-month
 104                      (calendar-iso-from-absolute
 105                       (1-
 106                        (calendar-dayname-on-or-before
 107                         1 (calendar-absolute-from-gregorian
 108                            (list 1 4 (1+ year))))))))
 109           (week (calendar-read
 110                  (format "ISO calendar week (1-%d): " no-weeks)
 111                  '(lambda (x) (and (> x 0) (<= x no-weeks)))))
 112           (day (calendar-read
 113                 "ISO day (1-7): "
 114                 '(lambda (x) (and (<= 1 x) (<= x 7))))))
 115      (list (list week day year))))
 116   (calendar-goto-date (calendar-gregorian-from-absolute
 117                        (calendar-absolute-from-iso date)))
 118   (or noecho (calendar-print-iso-date)))
 119
 120 (defun diary-iso-date ()
 121   "ISO calendar equivalent of date diary entry."
 122   (format "ISO date: %s" (calendar-iso-date-string date)))
 123
 124 (provide 'cal-iso)
 125
 126 ;;; cal-iso.el ends here