lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems.
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 (defvar frame-creation-function nil
  28   "Window-system dependent function to call to create a new frame.
  29 The window system startup file should set this to its frame creation
  30 function, which should take an alist of parameters as its argument.")
  31
  32 ;;; The initial value given here for used to ask for a minibuffer.
  33 ;;; But that's not necessary, because the default is to have one.
  34 ;;; By not specifying it here, we let an X resource specify it.
  35 (defcustom initial-frame-alist nil
  36   "*Alist of frame parameters for creating the initial X window frame.
  37 You can set this in your `.emacs' file; for example,
  38  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  39 Parameters specified here supersede the values given in `default-frame-alist'.
  40
  41 If the value calls for a frame without a minibuffer, and you have not created
  42 a minibuffer frame on your own, one is created according to
  43 `minibuffer-frame-alist'.
  44
  45 You can specify geometry-related options for just the initial frame
  46 by setting this variable in your `.emacs' file; however, they won't
  47 take effect until Emacs reads `.emacs', which happens after first creating
  48 the frame.  If you want the frame to have the proper geometry as soon
  49 as it appears, you need to use this three-step process:
  50 * Specify X resources to give the geometry you want.
  51 * Set `default-frame-alist' to override these options so that they
  52   don't affect subsequent frames.
  53 * Set `initial-frame-alist' in a way that matches the X resources,
  54   to override what you put in `default-frame-alist'."
  55   :type '(repeat (cons :format "%v"
  56                        (symbol :tag "Parameter")
  57                        (sexp :tag "Value")))
  58   :group 'frames)
  59
  60 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  61   "*Alist of frame parameters for initially creating a minibuffer frame.
  62 You can set this in your `.emacs' file; for example,
  63  (setq minibuffer-frame-alist
  64    '((top . 1) (left . 1) (width . 80) (height . 2)))
  65 Parameters specified here supersede the values given in
  66 `default-frame-alist', for a minibuffer frame."
  67   :type '(repeat (cons :format "%v"
  68                        (symbol :tag "Parameter")
  69                        (sexp :tag "Value")))
  70   :group 'frames)
  71
  72 (defcustom pop-up-frame-alist nil
  73   "*Alist of frame parameters used when creating pop-up frames.
  74 Pop-up frames are used for completions, help, and the like.
  75 This variable can be set in your init file, like this:
  76   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  77 These supersede the values given in `default-frame-alist',
  78 for pop-up frames."
  79   :type '(repeat (cons :format "%v"
  80                        (symbol :tag "Parameter")
  81                        (sexp :tag "Value")))
  82   :group 'frames)
  83
  84 (setq pop-up-frame-function
  85       (function (lambda ()
  86                   (make-frame pop-up-frame-alist))))
  87
  88 (defcustom special-display-frame-alist
  89   '((height . 14) (width . 80) (unsplittable . t))
  90   "*Alist of frame parameters used when creating special frames.
  91 Special frames are used for buffers whose names are in
  92 `special-display-buffer-names' and for buffers whose names match
  93 one of the regular expressions in `special-display-regexps'.
  94 This variable can be set in your init file, like this:
  95   (setq special-display-frame-alist '((width . 80) (height . 20)))
  96 These supersede the values given in `default-frame-alist'."
  97   :type '(repeat (cons :format "%v"
  98                          (symbol :tag "Parameter")
  99                          (sexp :tag "Value")))
 100   :group 'frames)
 101
 102 (defun special-display-popup-frame (buffer &optional args)
 103   "Display BUFFER in its own frame, reusing an existing window if any.
 104 Return the window chosen.
 105 Currently we do not insist on selecting the window within its frame.
 106 If ARGS is an alist, use it as a list of frame parameter specs.
 107 If ARGS is a list whose car is a symbol,
 108 use (car ARGS) as a function to do the work.
 109 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 110   (if (and args (symbolp (car args)))
 111       (apply (car args) buffer (cdr args))
 112     (let ((window (get-buffer-window buffer t)))
 113       (if window
 114           ;; If we have a window already, make it visible.
 115           (let ((frame (window-frame window)))
 116             (make-frame-visible frame)
 117             (raise-frame frame)
 118             window)
 119         ;; If no window yet, make one in a new frame.
 120         (let ((frame (make-frame (append args special-display-frame-alist))))
 121           (set-window-buffer (frame-selected-window frame) buffer)
 122           (set-window-dedicated-p (frame-selected-window frame) t)
 123           (frame-selected-window frame))))))
 124
 125 (defun handle-delete-frame (event)
 126   "Handle delete-frame events from the X server."
 127   (interactive "e")
 128   (let ((frame (posn-window (event-start event)))
 129         (i 0)
 130         (tail (frame-list)))
 131     (while tail
 132       (and (frame-visible-p (car tail))
 133            (not (eq (car tail) frame))
 134           (setq i (1+ i)))
 135       (setq tail (cdr tail)))
 136     (if (> i 0)
 137         (delete-frame frame t)
 138       ;; Gildea@x.org says it is ok to ask questions before terminating.
 139       (save-buffers-kill-emacs))))
 140 \f
 141 ;;;; Arrangement of frames at startup
 142
 143 ;;; 1) Load the window system startup file from the lisp library and read the
 144 ;;; high-priority arguments (-q and the like).  The window system startup
 145 ;;; file should create any frames specified in the window system defaults.
 146 ;;;
 147 ;;; 2) If no frames have been opened, we open an initial text frame.
 148 ;;;
 149 ;;; 3) Once the init file is done, we apply any newly set parameters
 150 ;;; in initial-frame-alist to the frame.
 151
 152 ;; These are now called explicitly at the proper times,
 153 ;; since that is easier to understand.
 154 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 155 ;; (add-hook 'before-init-hook 'frame-initialize)
 156 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 157
 158 ;;; If we create the initial frame, this is it.
 159 (defvar frame-initial-frame nil)
 160
 161 ;; Record the parameters used in frame-initialize to make the initial frame.
 162 (defvar frame-initial-frame-alist)
 163
 164 (defvar frame-initial-geometry-arguments nil)
 165
 166 ;;; startup.el calls this function before loading the user's init
 167 ;;; file - if there is no frame with a minibuffer open now, create
 168 ;;; one to display messages while loading the init file.
 169 (defun frame-initialize ()
 170   "Create an in initial frame if necessary."
 171   ;; Are we actually running under a window system at all?
 172   (if (and window-system (not noninteractive) (not (eq window-system 'pc)))
 173       (progn
 174         ;; Turn on special-display processing only if there's a window system.
 175         (setq special-display-function 'special-display-popup-frame)
 176
 177         ;; If there is no frame with a minibuffer besides the terminal
 178         ;; frame, then we need to create the opening frame.  Make sure
 179         ;; it has a minibuffer, but let initial-frame-alist omit the
 180         ;; minibuffer spec.
 181         (or (delq terminal-frame (minibuffer-frame-list))
 182             (progn
 183               (setq frame-initial-frame-alist
 184                     (append initial-frame-alist default-frame-alist nil))
 185               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 186                   (setq frame-initial-frame-alist
 187                         (cons '(horizontal-scroll-bars . t)
 188                               frame-initial-frame-alist)))
 189               (setq default-minibuffer-frame
 190                     (setq frame-initial-frame
 191                           (make-frame frame-initial-frame-alist)))
 192               ;; Delete any specifications for window geometry parameters
 193               ;; so that we won't reapply them in frame-notice-user-settings.
 194               ;; It would be wrong to reapply them then,
 195               ;; because that would override explicit user resizing.
 196               (setq initial-frame-alist
 197                     (frame-remove-geometry-params initial-frame-alist))))
 198         ;; At this point, we know that we have a frame open, so we
 199         ;; can delete the terminal frame.
 200         (delete-frame terminal-frame)
 201         (setq terminal-frame nil))
 202
 203     ;; No, we're not running a window system.  Use make-terminal-frame if
 204     ;; we support that feature, otherwise arrange to cause errors.
 205     (or (eq window-system 'pc)
 206         (setq frame-creation-function
 207               (if (fboundp 'tty-create-frame-with-faces)
 208                   'tty-create-frame-with-faces
 209                 (function
 210                  (lambda (parameters)
 211                    (error
 212                     "Can't create multiple frames without a window system"))))))))
 213
 214 (defvar frame-notice-user-settings t
 215   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 216
 217 ;;; startup.el calls this function after loading the user's init
 218 ;;; file.  Now default-frame-alist and initial-frame-alist contain
 219 ;;; information to which we must react; do what needs to be done.
 220 (defun frame-notice-user-settings ()
 221   "Act on user's init file settings of frame parameters.
 222 React to settings of `default-frame-alist', `initial-frame-alist' there."
 223   ;; Make menu-bar-mode and default-frame-alist consistent.
 224   (if (boundp 'menu-bar-mode)
 225       (let ((default (assq 'menu-bar-lines default-frame-alist)))
 226         (if default
 227             (setq menu-bar-mode (not (eq (cdr default) 0)))
 228           (setq default-frame-alist
 229                 (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 230                       default-frame-alist)))))
 231
 232   ;; Creating and deleting frames may shift the selected frame around,
 233   ;; and thus the current buffer.  Protect against that.  We don't
 234   ;; want to use save-excursion here, because that may also try to set
 235   ;; the buffer of the selected window, which fails when the selected
 236   ;; window is the minibuffer.
 237   (let ((old-buffer (current-buffer)))
 238
 239     (when (and frame-notice-user-settings
 240                (null frame-initial-frame))
 241       ;; This case happens when we don't have a window system.
 242       (let ((parms (frame-parameters frame-initial-frame)))
 243         ;; Don't change the frame names.
 244         (setq parms (delq (assq 'name parms) parms))
 245         ;; Can't modify the minibuffer parameter, so don't try.
 246         (setq parms (delq (assq 'minibuffer parms) parms))
 247         (modify-frame-parameters nil
 248                                  (append initial-frame-alist
 249                                          default-frame-alist
 250                                          parms
 251                                          nil))))
 252
 253     ;; If the initial frame is still around, apply initial-frame-alist
 254     ;; and default-frame-alist to it.
 255     (if (frame-live-p frame-initial-frame)
 256
 257         ;; The initial frame we create above always has a minibuffer.
 258         ;; If the user wants to remove it, or make it a minibuffer-only
 259         ;; frame, then we'll have to delete the current frame and make a
 260         ;; new one; you can't remove or add a root window to/from an
 261         ;; existing frame.
 262         ;;
 263         ;; NOTE: default-frame-alist was nil when we created the
 264         ;; existing frame.  We need to explicitly include
 265         ;; default-frame-alist in the parameters of the screen we
 266         ;; create here, so that its new value, gleaned from the user's
 267         ;; .emacs file, will be applied to the existing screen.
 268         (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 269                               (assq 'minibuffer default-frame-alist)
 270                               '(minibuffer . t)))
 271                      t))
 272             ;; Create the new frame.
 273             (let (parms new)
 274               ;; If the frame isn't visible yet, wait till it is.
 275               ;; If the user has to position the window,
 276               ;; Emacs doesn't know its real position until
 277               ;; the frame is seen to be visible.
 278               (while (not (cdr (assq 'visibility
 279                                      (frame-parameters frame-initial-frame))))
 280                 (sleep-for 1))
 281               (setq parms (frame-parameters frame-initial-frame))
 282               ;; Get rid of `name' unless it was specified explicitly before.
 283               (or (assq 'name frame-initial-frame-alist)
 284                   (setq parms (delq (assq 'name parms) parms)))
 285               (setq parms (append initial-frame-alist
 286                                   default-frame-alist
 287                                   parms
 288                                   nil))
 289               ;; Get rid of `reverse', because that was handled
 290               ;; when we first made the frame.
 291               (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 292               (if (assq 'height frame-initial-geometry-arguments)
 293                   (setq parms (assoc-delete-all 'height parms)))
 294               (if (assq 'width frame-initial-geometry-arguments)
 295                   (setq parms (assoc-delete-all 'width parms)))
 296               (if (assq 'left frame-initial-geometry-arguments)
 297                   (setq parms (assoc-delete-all 'left parms)))
 298               (if (assq 'top frame-initial-geometry-arguments)
 299                   (setq parms (assoc-delete-all 'top parms)))
 300               (setq new
 301                     (make-frame
 302                      ;; Use the geometry args that created the existing
 303                      ;; frame, rather than the parms we get for it.
 304                      (append frame-initial-geometry-arguments
 305                              '((user-size . t) (user-position . t))
 306                              parms)))
 307               ;; The initial frame, which we are about to delete, may be
 308               ;; the only frame with a minibuffer.  If it is, create a
 309               ;; new one.
 310               (or (delq frame-initial-frame (minibuffer-frame-list))
 311                   (make-initial-minibuffer-frame nil))
 312
 313               ;; If the initial frame is serving as a surrogate
 314               ;; minibuffer frame for any frames, we need to wean them
 315               ;; onto a new frame.  The default-minibuffer-frame
 316               ;; variable must be handled similarly.
 317               (let ((users-of-initial
 318                      (filtered-frame-list
 319                       (function (lambda (frame)
 320                                   (and (not (eq frame frame-initial-frame))
 321                                        (eq (window-frame
 322                                             (minibuffer-window frame))
 323                                            frame-initial-frame)))))))
 324                 (if (or users-of-initial
 325                         (eq default-minibuffer-frame frame-initial-frame))
 326
 327                     ;; Choose an appropriate frame.  Prefer frames which
 328                     ;; are only minibuffers.
 329                     (let* ((new-surrogate
 330                             (car
 331                              (or (filtered-frame-list
 332                                   (function
 333                                    (lambda (frame)
 334                                      (eq (cdr (assq 'minibuffer
 335                                                     (frame-parameters frame)))
 336                                          'only))))
 337                                  (minibuffer-frame-list))))
 338                            (new-minibuffer (minibuffer-window new-surrogate)))
 339
 340                       (if (eq default-minibuffer-frame frame-initial-frame)
 341                           (setq default-minibuffer-frame new-surrogate))
 342
 343                       ;; Wean the frames using frame-initial-frame as
 344                       ;; their minibuffer frame.
 345                       (mapcar
 346                        (function
 347                         (lambda (frame)
 348                           (modify-frame-parameters
 349                            frame (list (cons 'minibuffer new-minibuffer)))))
 350                        users-of-initial))))
 351
 352               ;; Redirect events enqueued at this frame to the new frame.
 353               ;; Is this a good idea?
 354               (redirect-frame-focus frame-initial-frame new)
 355
 356               ;; Finally, get rid of the old frame.
 357               (delete-frame frame-initial-frame t))
 358
 359           ;; Otherwise, we don't need all that rigamarole; just apply
 360           ;; the new parameters.
 361           (let (newparms allparms tail)
 362             (setq allparms (append initial-frame-alist
 363                                    default-frame-alist))
 364             (if (assq 'height frame-initial-geometry-arguments)
 365                 (setq allparms (assoc-delete-all 'height allparms)))
 366             (if (assq 'width frame-initial-geometry-arguments)
 367                 (setq allparms (assoc-delete-all 'width allparms)))
 368             (if (assq 'left frame-initial-geometry-arguments)
 369                 (setq allparms (assoc-delete-all 'left allparms)))
 370             (if (assq 'top frame-initial-geometry-arguments)
 371                 (setq allparms (assoc-delete-all 'top allparms)))
 372             (setq tail allparms)
 373             ;; Find just the parms that have changed since we first
 374             ;; made this frame.  Those are the ones actually set by
 375             ;; the init file.  For those parms whose values we already knew
 376             ;; (such as those spec'd by command line options)
 377             ;; it is undesirable to specify the parm again
 378             ;; once the user has seen the frame and been able to alter it
 379             ;; manually.
 380             (while tail
 381               (let (newval oldval)
 382                 (setq oldval (assq (car (car tail))
 383                                    frame-initial-frame-alist))
 384                 (setq newval (cdr (assq (car (car tail)) allparms)))
 385                 (or (and oldval (eq (cdr oldval) newval))
 386                     (setq newparms
 387                           (cons (cons (car (car tail)) newval) newparms))))
 388               (setq tail (cdr tail)))
 389             (setq newparms (nreverse newparms))
 390             (modify-frame-parameters frame-initial-frame
 391                                      newparms)
 392             ;; If we changed the background color,
 393             ;; we need to update the background-mode parameter
 394             ;; and maybe some faces too.
 395             (when (assq 'background-color newparms)
 396               (unless (assq 'background-mode newparms)
 397                 (frame-set-background-mode frame-initial-frame))
 398               (face-set-after-frame-default frame-initial-frame))
 399             (if (assq 'font newparms)
 400                 (frame-update-faces frame-initial-frame)))))
 401
 402     ;; Restore the original buffer.
 403     (set-buffer old-buffer)
 404
 405     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 406     ;; Make sure frame-notice-user-settings does nothing if called twice.
 407     (setq frame-notice-user-settings nil)
 408     (setq frame-initial-frame nil)))
 409
 410 (defun make-initial-minibuffer-frame (display)
 411   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 412     (if display
 413         (make-frame-on-display display parms)
 414       (make-frame parms))))
 415
 416 ;;;; Creation of additional frames, and other frame miscellanea
 417
 418 (defun get-other-frame ()
 419   "Return some frame other than the current frame.
 420 Create one if necessary.  Note that the minibuffer frame, if separate,
 421 is not considered (see `next-frame')."
 422   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 423                (make-frame)
 424              (next-frame (selected-frame)))))
 425     s))
 426
 427 (defun next-multiframe-window ()
 428   "Select the next window, regardless of which frame it is on."
 429   (interactive)
 430   (select-window (next-window (selected-window)
 431                               (> (minibuffer-depth) 0)
 432                               t)))
 433
 434 (defun previous-multiframe-window ()
 435   "Select the previous window, regardless of which frame it is on."
 436   (interactive)
 437   (select-window (previous-window (selected-window)
 438                                   (> (minibuffer-depth) 0)
 439                                   t)))
 440
 441 (defun make-frame-on-display (display &optional parameters)
 442   "Make a frame on display DISPLAY.
 443 The optional second argument PARAMETERS specifies additional frame parameters."
 444   (interactive "sMake frame on display: ")
 445   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 446       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 447   (make-frame (cons (cons 'display display) parameters)))
 448
 449 (defun make-frame-command ()
 450   "Make a new frame, and select it if the terminal displays only one frame."
 451   (interactive)
 452   (if (and window-system (not (eq window-system 'pc)))
 453       (make-frame)
 454     (select-frame (make-frame))))
 455
 456 (defvar before-make-frame-hook nil
 457   "Functions to run before a frame is created.")
 458
 459 (defvar after-make-frame-functions nil
 460   "Functions to run after a frame is created.
 461 The functions are run with one arg, the newly created frame.")
 462
 463 (defvar after-setting-font-hooks nil
 464   "Functions to run after a frame's font has been changed.")
 465
 466 ;; Alias, kept temporarily.
 467 (defalias 'new-frame 'make-frame)
 468
 469 (defun make-frame (&optional parameters)
 470   "Return a newly created frame displaying the current buffer.
 471 Optional argument PARAMETERS is an alist of parameters for the new frame.
 472 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 473
 474  (name . STRING)        The frame should be named STRING.
 475
 476  (width . NUMBER)       The frame should be NUMBER characters in width.
 477  (height . NUMBER)      The frame should be NUMBER text lines high.
 478
 479 You cannot specify either `width' or `height', you must use neither or both.
 480
 481  (minibuffer . t)       The frame should have a minibuffer.
 482  (minibuffer . nil)     The frame should have no minibuffer.
 483  (minibuffer . only)    The frame should contain only a minibuffer.
 484  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 485
 486 Before the frame is created (via `frame-creation-function'), functions on the
 487 hook `before-make-frame-hook' are run.  After the frame is created, functions
 488 on `after-make-frame-functions' are run with one arg, the newly created frame."
 489   (interactive)
 490   (run-hooks 'before-make-frame-hook)
 491   (let ((frame (funcall frame-creation-function parameters)))
 492     (run-hook-with-args 'after-make-frame-functions frame)
 493     frame))
 494
 495 (defun filtered-frame-list (predicate)
 496   "Return a list of all live frames which satisfy PREDICATE."
 497   (let ((frames (frame-list))
 498         good-frames)
 499     (while (consp frames)
 500       (if (funcall predicate (car frames))
 501           (setq good-frames (cons (car frames) good-frames)))
 502       (setq frames (cdr frames)))
 503     good-frames))
 504
 505 (defun minibuffer-frame-list ()
 506   "Return a list of all frames with their own minibuffers."
 507   (filtered-frame-list
 508    (function (lambda (frame)
 509                (eq frame (window-frame (minibuffer-window frame)))))))
 510
 511 (defun frame-remove-geometry-params (param-list)
 512   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 513 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 514 `height', `user-size' and `user-position' parameters.
 515 Emacs uses this to avoid overriding explicit moves and resizings from
 516 the user during startup."
 517   (setq param-list (cons nil param-list))
 518   (let ((tail param-list))
 519     (while (consp (cdr tail))
 520       (if (and (consp (car (cdr tail)))
 521                (memq (car (car (cdr tail)))
 522                      '(height width top left user-position user-size)))
 523           (progn
 524             (setq frame-initial-geometry-arguments
 525                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 526             (setcdr tail (cdr (cdr tail))))
 527         (setq tail (cdr tail)))))
 528   (setq frame-initial-geometry-arguments
 529         (nreverse frame-initial-geometry-arguments))
 530   (cdr param-list))
 531
 532
 533 (defcustom focus-follows-mouse t
 534   "*Non-nil if window system changes focus when you move the mouse."
 535   :type 'boolean
 536   :group 'frames
 537   :version "20.3")
 538
 539 (defun other-frame (arg)
 540   "Select the ARG'th different visible frame, and raise it.
 541 All frames are arranged in a cyclic order.
 542 This command selects the frame ARG steps away in that order.
 543 A negative ARG moves in the opposite order."
 544   (interactive "p")
 545   (let ((frame (selected-frame)))
 546     (while (> arg 0)
 547       (setq frame (next-frame frame))
 548       (while (not (eq (frame-visible-p frame) t))
 549         (setq frame (next-frame frame)))
 550       (setq arg (1- arg)))
 551     (while (< arg 0)
 552       (setq frame (previous-frame frame))
 553       (while (not (eq (frame-visible-p frame) t))
 554         (setq frame (previous-frame frame)))
 555       (setq arg (1+ arg)))
 556     (raise-frame frame)
 557     (select-frame frame)
 558     ;; Ensure, if possible, that frame gets input focus.
 559     (if (eq window-system 'w32)
 560         (w32-focus-frame frame)
 561       (when focus-follows-mouse
 562         (set-mouse-position (selected-frame) (1- (frame-width)) 0)))))
 563
 564 (defun make-frame-names-alist ()
 565   (let* ((current-frame (selected-frame))
 566          (falist
 567           (cons
 568            (cons (frame-parameter current-frame 'name) current-frame) nil))
 569          (frame (next-frame nil t)))
 570     (while (not (eq frame current-frame))
 571       (progn
 572         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 573         (setq frame (next-frame frame t))))
 574     falist))
 575
 576 (defvar frame-name-history nil)
 577 (defun select-frame-by-name (name)
 578   "Select the frame whose name is NAME and raise it.
 579 If there is no frame by that name, signal an error."
 580   (interactive
 581    (let* ((frame-names-alist (make-frame-names-alist))
 582            (default (car (car frame-names-alist)))
 583            (input (completing-read
 584                    (format "Select Frame (default %s): " default)
 585                    frame-names-alist nil t nil 'frame-name-history)))
 586      (if (= (length input) 0)
 587          (list default)
 588        (list input))))
 589   (let* ((frame-names-alist (make-frame-names-alist))
 590          (frame (cdr (assoc name frame-names-alist))))
 591     (or frame
 592         (error "There is no frame named `%s'" name))
 593     (make-frame-visible frame)
 594     (raise-frame frame)
 595     (select-frame frame)
 596     ;; Ensure, if possible, that frame gets input focus.
 597     (if (eq window-system 'w32)
 598         (w32-focus-frame frame)
 599       (when focus-follows-mouse
 600         (set-mouse-position (selected-frame) (1- (frame-width)) 0)))))
 601 \f
 602 ;;;; Frame configurations
 603
 604 (defun current-frame-configuration ()
 605   "Return a list describing the positions and states of all frames.
 606 Its car is `frame-configuration'.
 607 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 608 where
 609   FRAME is a frame object,
 610   ALIST is an association list specifying some of FRAME's parameters, and
 611   WINDOW-CONFIG is a window configuration object for FRAME."
 612   (cons 'frame-configuration
 613         (mapcar (function
 614                  (lambda (frame)
 615                    (list frame
 616                          (frame-parameters frame)
 617                          (current-window-configuration frame))))
 618                 (frame-list))))
 619
 620 (defun set-frame-configuration (configuration &optional nodelete)
 621   "Restore the frames to the state described by CONFIGURATION.
 622 Each frame listed in CONFIGURATION has its position, size, window
 623 configuration, and other parameters set as specified in CONFIGURATION.
 624 Ordinarily, this function deletes all existing frames not
 625 listed in CONFIGURATION.  But if optional second argument NODELETE
 626 is given and non-nil, the unwanted frames are iconified instead."
 627   (or (frame-configuration-p configuration)
 628       (signal 'wrong-type-argument
 629               (list 'frame-configuration-p configuration)))
 630   (let ((config-alist (cdr configuration))
 631         frames-to-delete)
 632     (mapcar (function
 633              (lambda (frame)
 634                (let ((parameters (assq frame config-alist)))
 635                  (if parameters
 636                      (progn
 637                        (modify-frame-parameters
 638                         frame
 639                         ;; Since we can't set a frame's minibuffer status,
 640                         ;; we might as well omit the parameter altogether.
 641                         (let* ((parms (nth 1 parameters))
 642                                (mini (assq 'minibuffer parms)))
 643                           (if mini (setq parms (delq mini parms)))
 644                           parms))
 645                        (set-window-configuration (nth 2 parameters)))
 646                    (setq frames-to-delete (cons frame frames-to-delete))))))
 647             (frame-list))
 648     (if nodelete
 649         ;; Note: making frames invisible here was tried
 650         ;; but led to some strange behavior--each time the frame
 651         ;; was made visible again, the window manager asked afresh
 652         ;; for where to put it.
 653         (mapcar 'iconify-frame frames-to-delete)
 654       (mapcar 'delete-frame frames-to-delete))))
 655 \f
 656 ;;;; Convenience functions for accessing and interactively changing
 657 ;;;; frame parameters.
 658
 659 (defun frame-parameter (frame parameter)
 660   "Return FRAME's value for parameter PARAMETER.
 661 If FRAME is nil, describe the currently selected frame."
 662   (cdr (assq parameter (frame-parameters frame))))
 663
 664 (defun frame-height (&optional frame)
 665   "Return number of lines available for display on FRAME.
 666 If FRAME is omitted, describe the currently selected frame."
 667   (cdr (assq 'height (frame-parameters frame))))
 668
 669 (defun frame-width (&optional frame)
 670   "Return number of columns available for display on FRAME.
 671 If FRAME is omitted, describe the currently selected frame."
 672   (cdr (assq 'width (frame-parameters frame))))
 673
 674 (defalias 'set-default-font 'set-frame-font)
 675 (defun set-frame-font (font-name)
 676   "Set the font of the selected frame to FONT-NAME.
 677 When called interactively, prompt for the name of the font to use.
 678 To get the frame's current default font, use `frame-parameters'."
 679   (interactive "sFont name: ")
 680   (modify-frame-parameters (selected-frame)
 681                            (list (cons 'font font-name)))
 682   ;; Update faces that want a bold or italic version of the default font.
 683   (frame-update-faces (selected-frame))
 684   (run-hooks 'after-setting-font-hooks))
 685
 686 (defun set-background-color (color-name)
 687   "Set the background color of the selected frame to COLOR-NAME.
 688 When called interactively, prompt for the name of the color to use.
 689 To get the frame's current background color, use `frame-parameters'."
 690   (interactive (list (facemenu-read-color)))
 691   (modify-frame-parameters (selected-frame)
 692                            (list (cons 'background-color color-name)))
 693   (frame-update-face-colors (selected-frame)))
 694
 695 (defun set-foreground-color (color-name)
 696   "Set the foreground color of the selected frame to COLOR-NAME.
 697 When called interactively, prompt for the name of the color to use.
 698 To get the frame's current foreground color, use `frame-parameters'."
 699   (interactive (list (facemenu-read-color)))
 700   (modify-frame-parameters (selected-frame)
 701                            (list (cons 'foreground-color color-name)))
 702   (frame-update-face-colors (selected-frame)))
 703
 704 (defun set-cursor-color (color-name)
 705   "Set the text cursor color of the selected frame to COLOR-NAME.
 706 When called interactively, prompt for the name of the color to use.
 707 To get the frame's current cursor color, use `frame-parameters'."
 708   (interactive (list (facemenu-read-color)))
 709   (modify-frame-parameters (selected-frame)
 710                            (list (cons 'cursor-color color-name))))
 711
 712 (defun set-mouse-color (color-name)
 713   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
 714 When called interactively, prompt for the name of the color to use.
 715 To get the frame's current mouse color, use `frame-parameters'."
 716   (interactive (list (facemenu-read-color)))
 717   (modify-frame-parameters (selected-frame)
 718                            (list (cons 'mouse-color
 719                                        (or color-name
 720                                            (cdr (assq 'mouse-color
 721                                                       (frame-parameters))))))))
 722
 723 (defun set-border-color (color-name)
 724   "Set the color of the border of the selected frame to COLOR-NAME.
 725 When called interactively, prompt for the name of the color to use.
 726 To get the frame's current border color, use `frame-parameters'."
 727   (interactive (list (facemenu-read-color)))
 728   (modify-frame-parameters (selected-frame)
 729                            (list (cons 'border-color color-name))))
 730
 731 (defun auto-raise-mode (arg)
 732   "Toggle whether or not the selected frame should auto-raise.
 733 With arg, turn auto-raise mode on if and only if arg is positive.
 734 Note that this controls Emacs's own auto-raise feature.
 735 Some window managers allow you to enable auto-raise for certain windows.
 736 You can use that for Emacs windows if you wish, but if you do,
 737 that is beyond the control of Emacs and this command has no effect on it."
 738   (interactive "P")
 739   (if (null arg)
 740       (setq arg
 741             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
 742                 -1 1)))
 743   (if (> arg 0)
 744       (raise-frame (selected-frame)))
 745   (modify-frame-parameters (selected-frame)
 746                            (list (cons 'auto-raise (> arg 0)))))
 747
 748 (defun auto-lower-mode (arg)
 749   "Toggle whether or not the selected frame should auto-lower.
 750 With arg, turn auto-lower mode on if and only if arg is positive.
 751 Note that this controls Emacs's own auto-lower feature.
 752 Some window managers allow you to enable auto-lower for certain windows.
 753 You can use that for Emacs windows if you wish, but if you do,
 754 that is beyond the control of Emacs and this command has no effect on it."
 755   (interactive "P")
 756   (if (null arg)
 757       (setq arg
 758             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
 759                 -1 1)))
 760   (modify-frame-parameters (selected-frame)
 761                            (list (cons 'auto-lower (> arg 0)))))
 762 (defun set-frame-name (name)
 763   "Set the name of the selected frame to NAME.
 764 When called interactively, prompt for the name of the frame.
 765 The frame name is displayed on the modeline if the terminal displays only
 766 one frame, otherwise the name is displayed on the frame's caption bar."
 767   (interactive "sFrame name: ")
 768   (modify-frame-parameters (selected-frame)
 769                            (list (cons 'name name))))
 770 \f
 771 ;;;; Aliases for backward compatibility with Emacs 18.
 772 (defalias 'screen-height 'frame-height)
 773 (defalias 'screen-width 'frame-width)
 774
 775 (defun set-screen-width (cols &optional pretend)
 776   "Obsolete function to change the size of the screen to COLS columns.
 777 Optional second arg non-nil means that redisplay should use COLS columns
 778 but that the idea of the actual width of the frame should not be changed.
 779 This function is provided only for compatibility with Emacs 18; new code
 780 should use `set-frame-width instead'."
 781   (set-frame-width (selected-frame) cols pretend))
 782
 783 (defun set-screen-height (lines &optional pretend)
 784   "Obsolete function to change the height of the screen to LINES lines.
 785 Optional second arg non-nil means that redisplay should use LINES lines
 786 but that the idea of the actual height of the screen should not be changed.
 787 This function is provided only for compatibility with Emacs 18; new code
 788 should use `set-frame-height' instead."
 789   (set-frame-height (selected-frame) lines pretend))
 790
 791 (make-obsolete 'screen-height 'frame-height)
 792 (make-obsolete 'screen-width  'frame-width)
 793 (make-obsolete 'set-screen-width 'set-frame-width)
 794 (make-obsolete 'set-screen-height 'set-frame-height)
 795
 796 \f
 797 ;;; Highlighting trailing whitespace.
 798
 799 (make-variable-buffer-local 'show-trailing-whitespace)
 800
 801 (defcustom show-trailing-whitespace nil
 802   "*Non-nil means highlight trailing whitespace in face `trailing-whitespace'."
 803   :tag "Highlight trailing whitespace."
 804   :set #'(lambda (symbol value) (set-default symbol value))
 805   :type 'boolean
 806   :group 'font-lock)
 807
 808
 809 \f
 810 ;;; Blinking cursor
 811
 812 (defgroup cursor nil
 813   "Displaying text cursors."
 814   :version "21.1"
 815   :group 'frames)
 816
 817 (defcustom blink-cursor-delay 0.5
 818   "*Seconds of idle time after which cursor starts to blink."
 819   :tag "Delay in seconds."
 820   :type 'number
 821   :group 'cursor)
 822
 823 (defcustom blink-cursor-interval 0.5
 824   "*Length of cursor blink interval in seconds."
 825   :tag "Blink interval in seconds."
 826   :type 'number
 827   :group 'cursor)
 828
 829 (defvar blink-cursor-idle-timer nil
 830   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
 831 The function `blink-cursor-start' is called when the timer fires.")
 832
 833 (defvar blink-cursor-timer nil
 834   "Timer started from `blink-cursor-start'.
 835 This timer calls `blink-cursor' every `blink-cursor-interval' seconds.")
 836
 837 (defvar blink-cursor-mode nil
 838   "Non-nil means blinking cursor is active.")
 839
 840 (defun blink-cursor-mode (arg)
 841   "Toggle blinking cursor mode.
 842 With arg, turn blinking cursor mode on iff arg is positive.
 843 When blinking cursor mode is enabled, the cursor of the selected
 844 window blinks."
 845   (interactive "P")
 846   (let ((on-p (if (null arg)
 847                   (not blink-cursor-mode)
 848                 (> (prefix-numeric-value arg) 0))))
 849     (if blink-cursor-idle-timer
 850         (cancel-timer blink-cursor-idle-timer))
 851     (if blink-cursor-timer
 852         (cancel-timer blink-cursor-timer))
 853     (setq blink-cursor-idle-timer nil
 854           blink-cursor-timer nil
 855           blink-cursor-mode nil)
 856     (if on-p
 857         (progn
 858           ;; Hide the cursor.
 859           (internal-show-cursor nil nil)
 860           (setq blink-cursor-idle-timer
 861                 (run-with-idle-timer blink-cursor-delay
 862                                      blink-cursor-delay
 863                                      'blink-cursor-start))
 864           (setq blink-cursor-mode t)))))
 865
 866 (defcustom blink-cursor (not (eq system-type 'ms-dos))
 867   "*Non-nil means blinking cursor mode is active."
 868   :tag "Blinking cursor"
 869   :type 'boolean
 870   :group 'cursor
 871   :set #'(lambda (symbol value)
 872            (set-default symbol value)
 873            (blink-cursor-mode (or value 0))))
 874
 875 (defun blink-cursor-start ()
 876   "Timer function called from the timer `blink-cursor-idle-timer'.
 877 This starts the timer `blink-cursor-timer', which makes the cursor blink
 878 if appropriate.  It also arranges to cancel that timer when the next
 879 command starts, by installing a pre-command hook."
 880   (when (null blink-cursor-timer)
 881     (add-hook 'pre-command-hook 'blink-cursor-end)
 882     (setq blink-cursor-timer
 883           (run-with-timer blink-cursor-interval blink-cursor-interval
 884                           'blink-cursor-timer-function))))
 885
 886 (defun blink-cursor-timer-function ()
 887   "Timer function of timer `blink-cursor-timer'."
 888   (internal-show-cursor nil (not (internal-show-cursor-p))))
 889
 890 (defun blink-cursor-end ()
 891   "Stop cursor blinking.
 892 This is installed as a pre-command hook by `blink-cursor-start'.
 893 When run, it cancels the timer `blink-cursor-timer' and removes
 894 itself as a pre-command hook."
 895   (remove-hook 'pre-command-hook 'blink-cursor-end)
 896   (internal-show-cursor nil t)
 897   (cancel-timer blink-cursor-timer)
 898   (setq blink-cursor-timer nil))
 899
 900
 901 \f
 902 ;;; Busy-cursor.
 903
 904 (defcustom busy-cursor t
 905   "*Non-nil means show a busy-cursor when running under a window system."
 906   :tag "Busy-cursor"
 907   :type 'boolean
 908   :group 'cursor
 909   :get #'(lambda (symbol) display-busy-cursor)
 910   :set #'(lambda (symbol value)
 911            (set-default symbol value)
 912            (setq display-busy-cursor value)))
 913
 914
 915 \f
 916 ;;;; Key bindings
 917
 918 (define-key ctl-x-5-map "2" 'make-frame-command)
 919 (define-key ctl-x-5-map "0" 'delete-frame)
 920 (define-key ctl-x-5-map "o" 'other-frame)
 921
 922 (provide 'frame)
 923
 924 ;;; frame.el ends here
 925 (frame-notice-user-settings):