lisp/whitespace.el

   1 ;;; whitespace.el --- warn about and clean bogus whitespaces in the file
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Rajesh Vaidheeswarran <rv@gnu.org>
   7 ;; Keywords: convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; URL: http://www.dsmit.com/lisp/
  29 ;;
  30 ;; The whitespace library is intended to find and help fix five different types
  31 ;; of whitespace problems that commonly exist in source code.
  32 ;;
  33 ;; 1. Leading space (empty lines at the top of a file).
  34 ;; 2. Trailing space (empty lines at the end of a file).
  35 ;; 3. Indentation space (8 or more spaces at beginning of line, that should be
  36 ;;                    replaced with TABS).
  37 ;; 4. Spaces followed by a TAB.  (Almost always, we never want that).
  38 ;; 5. Spaces or TABS at the end of a line.
  39 ;;
  40 ;; Whitespace errors are reported in a buffer, and on the modeline.
  41 ;;
  42 ;; Modeline will show a W:<x>!<y> to denote a particular type of whitespace,
  43 ;; where `x' and `y' can be one (or more) of:
  44 ;;
  45 ;; e - End-of-Line whitespace.
  46 ;; i - Indentation whitespace.
  47 ;; l - Leading whitespace.
  48 ;; s - Space followed by Tab.
  49 ;; t - Trailing whitespace.
  50 ;;
  51 ;; If any of the whitespace checks is turned off, the modeline will display a
  52 ;; !<y>.
  53 ;;
  54 ;;     (since (3) is the most controversial one, here is the rationale: Most
  55 ;;     terminal drivers and printer drivers have TAB configured or even
  56 ;;     hardcoded to be 8 spaces.  (Some of them allow configuration, but almost
  57 ;;     always they default to 8.)
  58 ;;
  59 ;;     Changing `tab-width' to other than 8 and editing will cause your code to
  60 ;;     look different from within Emacs, and say, if you cat it or more it, or
  61 ;;     even print it.
  62 ;;
  63 ;;     Almost all the popular programming modes let you define an offset (like
  64 ;;     c-basic-offset or perl-indent-level) to configure the offset, so you
  65 ;;     should never have to set your `tab-width' to be other than 8 in all
  66 ;;     these modes.  In fact, with an indent level of say, 4, 2 TABS will cause
  67 ;;     Emacs to replace your 8 spaces with one \t (try it).  If vi users in
  68 ;;     your office complain, tell them to use vim, which distinguishes between
  69 ;;     tabstop and shiftwidth (vi equivalent of our offsets), and also ask them
  70 ;;     to set smarttab.)
  71 ;;
  72 ;; All the above have caused (and will cause) unwanted codeline integration and
  73 ;; merge problems.
  74 ;;
  75 ;; whitespace.el will complain if it detects whitespaces on opening a file, and
  76 ;; warn you on closing a file also (in case you had inserted any
  77 ;; whitespaces during the process of your editing).
  78 ;;
  79 ;; Exported functions:
  80 ;;
  81 ;; `whitespace-buffer' - To check the current buffer for whitespace problems.
  82 ;; `whitespace-cleanup' - To cleanup all whitespaces in the current buffer.
  83 ;; `whitespace-region' - To check between point and mark for whitespace
  84 ;;                       problems.
  85 ;; `whitespace-cleanup-region' - To cleanup all whitespaces between point
  86 ;;                               and mark in the current buffer.
  87
  88 ;;; Code:
  89
  90 (defvar whitespace-version "3.5" "Version of the whitespace library.")
  91
  92 (defvar whitespace-all-buffer-files nil
  93   "An associated list of buffers and files checked for whitespace cleanliness.
  94
  95 This is to enable periodic checking of whitespace cleanliness in the files
  96 visited by the buffers.")
  97
  98 (defvar whitespace-rescan-timer nil
  99   "Timer object used to rescan the files in buffers that have been modified.")
 100
 101 ;; Tell Emacs about this new kind of minor mode
 102 (defvar whitespace-mode nil
 103   "Non-nil when Whitespace mode (a minor mode) is enabled.")
 104 (make-variable-buffer-local 'whitespace-mode)
 105
 106 (defvar whitespace-mode-line nil
 107   "String to display in the mode line for Whitespace mode.")
 108 (make-variable-buffer-local 'whitespace-mode-line)
 109
 110 (defvar whitespace-check-buffer-leading nil
 111   "Test leading whitespace for file in current buffer if t.")
 112 (make-variable-buffer-local 'whitespace-check-buffer-leading)
 113
 114 (defvar whitespace-check-buffer-trailing nil
 115   "Test trailing whitespace for file in current buffer if t.")
 116 (make-variable-buffer-local 'whitespace-check-buffer-trailing)
 117
 118 (defvar whitespace-check-buffer-indent nil
 119   "Test indentation whitespace for file in current buffer if t.")
 120 (make-variable-buffer-local 'whitespace-check-buffer-indent)
 121
 122 (defvar whitespace-check-buffer-spacetab nil
 123   "Test Space-followed-by-TABS whitespace for file in current buffer if t.")
 124 (make-variable-buffer-local 'whitespace-check-buffer-spacetab)
 125
 126 (defvar whitespace-check-buffer-ateol nil
 127   "Test end-of-line whitespace for file in current buffer if t.")
 128 (make-variable-buffer-local 'whitespace-check-buffer-ateol)
 129
 130 (defvar whitespace-highlighted-space nil
 131   "The variable to store the extent to highlight.")
 132 (make-variable-buffer-local 'whitespace-highlighted-space)
 133
 134 ;; For flavors of Emacs which don't define `defgroup' and `defcustom'.
 135 (eval-when-compile
 136   (if (not (fboundp 'defgroup))
 137       (defmacro defgroup (sym memb doc &rest args)
 138         "Null macro for `defgroup' in all versions of Emacs that don't define it."
 139         t))
 140   (if (not (fboundp 'defcustom))
 141       (defmacro defcustom (sym val doc &rest args)
 142         "Macro to alias `defcustom' to `defvar' in all versions of Emacs that
 143 don't define it."
 144         `(defvar ,sym ,val ,doc))))
 145
 146 (defalias 'whitespace-make-overlay
 147   (if (featurep 'xemacs) 'make-extent 'make-overlay))
 148 (defalias 'whitespace-overlay-put
 149   (if (featurep 'xemacs) 'set-extent-property 'overlay-put))
 150 (defalias 'whitespace-delete-overlay
 151   (if (featurep 'xemacs) 'delete-extent 'delete-overlay))
 152 (defalias 'whitespace-overlay-start
 153   (if (featurep 'xemacs) 'extent-start 'overlay-start))
 154 (defalias 'whitespace-overlay-end
 155   (if (featurep 'xemacs) 'extent-end 'overlay-end))
 156 (defalias 'whitespace-mode-line-update
 157   (if (featurep 'xemacs) 'redraw-modeline 'force-mode-line-update))
 158
 159 (defgroup whitespace nil
 160   "Check for and fix five different types of whitespaces in source code."
 161   :version "21.1"
 162   :link '(emacs-commentary-link "whitespace.el")
 163   ;; Since XEmacs doesn't have a 'convenience group, use the next best group
 164   ;; which is 'editing?
 165   :group (if (featurep 'xemacs) 'editing 'convenience))
 166
 167 (defcustom whitespace-check-leading-whitespace t
 168   "Flag to check leading whitespace.  This is the global for the system.
 169 It can be overriden by setting a buffer local variable
 170 `whitespace-check-buffer-leading'."
 171   :type 'boolean
 172   :group 'whitespace)
 173
 174 (defcustom whitespace-check-trailing-whitespace t
 175   "Flag to check trailing whitespace.  This is the global for the system.
 176 It can be overriden by setting a buffer local variable
 177 `whitespace-check-buffer-trailing'."
 178   :type 'boolean
 179   :group 'whitespace)
 180
 181 (defcustom whitespace-check-spacetab-whitespace t
 182   "Flag to check space followed by a TAB.  This is the global for the system.
 183 It can be overriden by setting a buffer local variable
 184 `whitespace-check-buffer-spacetab'."
 185   :type 'boolean
 186   :group 'whitespace)
 187
 188 (defcustom whitespace-spacetab-regexp "[ ]+\t"
 189   "Regexp to match one or more spaces followed by a TAB."
 190   :type 'regexp
 191   :group 'whitespace)
 192
 193 (defcustom whitespace-check-indent-whitespace indent-tabs-mode
 194   "Flag to check indentation whitespace.  This is the global for the system.
 195 It can be overriden by setting a buffer local variable
 196 `whitespace-check-buffer-indent'."
 197   :type 'boolean
 198   :group 'whitespace)
 199
 200 (defcustom whitespace-indent-regexp "^\t*\\(        \\)+"
 201   "Regexp to match multiples of eight spaces near line beginnings.
 202 The default value ignores leading TABs."
 203   :type 'regexp
 204   :group 'whitespace)
 205
 206 (defcustom whitespace-check-ateol-whitespace t
 207   "Flag to check end-of-line whitespace.  This is the global for the system.
 208 It can be overriden by setting a buffer local variable
 209 `whitespace-check-buffer-ateol'."
 210   :type 'boolean
 211   :group 'whitespace)
 212
 213 (defcustom whitespace-ateol-regexp "[ \t]+$"
 214   "Regexp to match one or more TABs or spaces at line ends."
 215   :type 'regexp
 216   :group 'whitespace)
 217
 218 (defcustom whitespace-errbuf "*Whitespace Errors*"
 219   "The name of the buffer where whitespace related messages will be logged."
 220   :type 'string
 221   :group 'whitespace)
 222
 223 (defcustom whitespace-clean-msg "clean."
 224   "If non-nil, this message will be displayed after a whitespace check
 225 determines a file to be clean."
 226   :type 'string
 227   :group 'whitespace)
 228
 229 (defcustom whitespace-abort-on-error nil
 230   "While writing a file, abort if the file is unclean.
 231 If `whitespace-auto-cleanup' is set, that takes precedence over
 232 this variable."
 233   :type  'boolean
 234   :group 'whitespace)
 235
 236 (defcustom whitespace-auto-cleanup nil
 237   "Cleanup a buffer automatically on finding it whitespace unclean."
 238   :type  'boolean
 239   :group 'whitespace)
 240
 241 (defcustom whitespace-silent nil
 242   "All whitespace errors will be shown only in the modeline when t.
 243
 244 Note that setting this may cause all whitespaces introduced in a file to go
 245 unnoticed when the buffer is killed, unless the user visits the `*Whitespace
 246 Errors*' buffer before opening (or closing) another file."
 247   :type 'boolean
 248   :group 'whitespace)
 249
 250 (defcustom whitespace-modes '(ada-mode asm-mode autoconf-mode awk-mode
 251                                        c-mode c++-mode cc-mode
 252                                        change-log-mode cperl-mode
 253                                        electric-nroff-mode emacs-lisp-mode
 254                                        f90-mode fortran-mode html-mode
 255                                        html3-mode java-mode jde-mode
 256                                        ksh-mode latex-mode LaTeX-mode
 257                                        lisp-mode m4-mode makefile-mode
 258                                        modula-2-mode nroff-mode objc-mode
 259                                        pascal-mode perl-mode prolog-mode
 260                                        python-mode scheme-mode sgml-mode
 261                                        sh-mode shell-script-mode simula-mode
 262                                        tcl-mode tex-mode texinfo-mode
 263                                        vrml-mode xml-mode)
 264
 265   "Major modes in which we turn on whitespace checking.
 266
 267 These are mostly programming and documentation modes.  But you may add other
 268 modes that you want whitespaces checked in by adding something like the
 269 following to your `.emacs':
 270
 271 \(setq whitespace-modes (cons 'my-mode (cons 'my-other-mode
 272                                             whitespace-modes))\)
 273
 274 Or, alternately, you can use the Emacs `customize' command to set this."
 275   :type '(repeat symbol)
 276   :group 'whitespace)
 277
 278 (defcustom whitespace-rescan-timer-time 600
 279   "Period in seconds to rescan modified buffers for whitespace creep.
 280
 281 This is the period after which the timer will fire causing
 282 `whitespace-rescan-files-in-buffers' to check for whitespace creep in
 283 modified buffers.
 284
 285 To disable timer scans, set this to zero."
 286   :type 'integer
 287   :group 'whitespace)
 288
 289 (defcustom whitespace-display-in-modeline t
 290   "Display whitespace errors on the modeline."
 291   :type 'boolean
 292   :group 'whitespace)
 293
 294 (defcustom whitespace-display-spaces-in-color t
 295   "Display the bogus whitespaces by coloring them with the face
 296 `whitespace-highlight'."
 297   :type 'boolean
 298   :group 'whitespace)
 299
 300 (defgroup whitespace-faces nil
 301   "Faces used in whitespace."
 302   :prefix "whitespace-"
 303   :group 'whitespace
 304   :group 'faces)
 305
 306 (defface whitespace-highlight '((((class color) (background light))
 307                                  (:background "green1"))
 308                                 (((class color) (background dark))
 309                                  (:background "sea green"))
 310                                 (((class grayscale mono)
 311                                   (background light))
 312                                  (:background "black"))
 313                                 (((class grayscale mono)
 314                                   (background dark))
 315                                  (:background "white")))
 316   "Face used for highlighting the bogus whitespaces that exist in the buffer."
 317   :group 'whitespace-faces)
 318 ;; backward-compatibility alias
 319 (put 'whitespace-highlight-face 'face-alias 'whitespace-highlight)
 320
 321 (if (not (assoc 'whitespace-mode minor-mode-alist))
 322     (setq minor-mode-alist (cons '(whitespace-mode whitespace-mode-line)
 323                                  minor-mode-alist)))
 324
 325 (set-default 'whitespace-check-buffer-leading
 326              whitespace-check-leading-whitespace)
 327 (set-default 'whitespace-check-buffer-trailing
 328              whitespace-check-trailing-whitespace)
 329 (set-default 'whitespace-check-buffer-indent
 330              whitespace-check-indent-whitespace)
 331 (set-default 'whitespace-check-buffer-spacetab
 332              whitespace-check-spacetab-whitespace)
 333 (set-default 'whitespace-check-buffer-ateol
 334              whitespace-check-ateol-whitespace)
 335
 336 (defun whitespace-check-whitespace-mode (&optional arg)
 337   "Test and set the whitespace-mode in qualifying buffers."
 338   (if (null whitespace-mode)
 339       (setq whitespace-mode
 340             (if (or arg (member major-mode whitespace-modes))
 341                 t
 342               nil))))
 343
 344 ;;;###autoload
 345 (defun whitespace-toggle-leading-check ()
 346   "Toggle the check for leading space in the local buffer."
 347   (interactive)
 348   (let ((current-val whitespace-check-buffer-leading))
 349     (setq whitespace-check-buffer-leading (not current-val))
 350     (message "Will%s check for leading space in buffer."
 351              (if whitespace-check-buffer-leading "" " not"))
 352     (if whitespace-check-buffer-leading (whitespace-buffer-leading))))
 353
 354 ;;;###autoload
 355 (defun whitespace-toggle-trailing-check ()
 356   "Toggle the check for trailing space in the local buffer."
 357   (interactive)
 358   (let ((current-val whitespace-check-buffer-trailing))
 359     (setq whitespace-check-buffer-trailing (not current-val))
 360     (message "Will%s check for trailing space in buffer."
 361              (if whitespace-check-buffer-trailing "" " not"))
 362     (if whitespace-check-buffer-trailing (whitespace-buffer-trailing))))
 363
 364 ;;;###autoload
 365 (defun whitespace-toggle-indent-check ()
 366   "Toggle the check for indentation space in the local buffer."
 367   (interactive)
 368   (let ((current-val whitespace-check-buffer-indent))
 369     (setq whitespace-check-buffer-indent (not current-val))
 370     (message "Will%s check for indentation space in buffer."
 371              (if whitespace-check-buffer-indent "" " not"))
 372     (if whitespace-check-buffer-indent
 373         (whitespace-buffer-search whitespace-indent-regexp))))
 374
 375 ;;;###autoload
 376 (defun whitespace-toggle-spacetab-check ()
 377   "Toggle the check for space-followed-by-TABs in the local buffer."
 378   (interactive)
 379   (let ((current-val whitespace-check-buffer-spacetab))
 380     (setq whitespace-check-buffer-spacetab (not current-val))
 381     (message "Will%s check for space-followed-by-TABs in buffer."
 382              (if whitespace-check-buffer-spacetab "" " not"))
 383     (if whitespace-check-buffer-spacetab
 384         (whitespace-buffer-search whitespace-spacetab-regexp))))
 385
 386
 387 ;;;###autoload
 388 (defun whitespace-toggle-ateol-check ()
 389   "Toggle the check for end-of-line space in the local buffer."
 390   (interactive)
 391   (let ((current-val whitespace-check-buffer-ateol))
 392     (setq whitespace-check-buffer-ateol (not current-val))
 393     (message "Will%s check for end-of-line space in buffer."
 394              (if whitespace-check-buffer-ateol "" " not"))
 395     (if whitespace-check-buffer-ateol
 396         (whitespace-buffer-search whitespace-ateol-regexp))))
 397
 398
 399 ;;;###autoload
 400 (defun whitespace-buffer (&optional quiet)
 401   "Find five different types of white spaces in buffer.
 402 These are:
 403 1. Leading space \(empty lines at the top of a file\).
 404 2. Trailing space \(empty lines at the end of a file\).
 405 3. Indentation space \(8 or more spaces, that should be replaced with TABS\).
 406 4. Spaces followed by a TAB. \(Almost always, we never want that\).
 407 5. Spaces or TABS at the end of a line.
 408
 409 Check for whitespace only if this buffer really contains a non-empty file
 410 and:
 411 1. the major mode is one of the whitespace-modes, or
 412 2. `whitespace-buffer' was explicitly called with a prefix argument."
 413   (interactive)
 414   (let ((whitespace-error nil))
 415     (whitespace-check-whitespace-mode current-prefix-arg)
 416     (if (and buffer-file-name (> (buffer-size) 0) whitespace-mode)
 417         (progn
 418           (whitespace-check-buffer-list (buffer-name) buffer-file-name)
 419           (whitespace-tickle-timer)
 420           (overlay-recenter (point-max))
 421           (remove-overlays nil nil 'face 'whitespace-highlight)
 422           (if whitespace-auto-cleanup
 423               (if buffer-read-only
 424                   (if (not quiet)
 425                       (message "Can't cleanup: %s is read-only" (buffer-name)))
 426                 (whitespace-cleanup-internal))
 427             (let ((whitespace-leading (if whitespace-check-buffer-leading
 428                                           (whitespace-buffer-leading)
 429                                         nil))
 430                   (whitespace-trailing (if whitespace-check-buffer-trailing
 431                                            (whitespace-buffer-trailing)
 432                                          nil))
 433                   (whitespace-indent (if whitespace-check-buffer-indent
 434                                          (whitespace-buffer-search
 435                                           whitespace-indent-regexp)
 436                                        nil))
 437                   (whitespace-spacetab (if whitespace-check-buffer-spacetab
 438                                            (whitespace-buffer-search
 439                                             whitespace-spacetab-regexp)
 440                                          nil))
 441                   (whitespace-ateol (if whitespace-check-buffer-ateol
 442                                         (whitespace-buffer-search
 443                                          whitespace-ateol-regexp)
 444                                       nil))
 445                   (whitespace-errmsg nil)
 446                   (whitespace-filename buffer-file-name)
 447                   (whitespace-this-modeline ""))
 448
 449               ;; Now let's complain if we found any of the above.
 450               (setq whitespace-error (or whitespace-leading whitespace-indent
 451                                          whitespace-spacetab whitespace-ateol
 452                                          whitespace-trailing))
 453
 454               (if whitespace-error
 455                   (progn
 456                     (setq whitespace-errmsg
 457                           (concat whitespace-filename " contains:\n"
 458                                   (if whitespace-leading
 459                                       "Leading whitespace\n")
 460                                   (if whitespace-indent
 461                                       (concat "Indentation whitespace"
 462                                               whitespace-indent "\n"))
 463                                   (if whitespace-spacetab
 464                                       (concat "Space followed by Tab"
 465                                               whitespace-spacetab "\n"))
 466                                   (if whitespace-ateol
 467                                       (concat "End-of-line whitespace"
 468                                               whitespace-ateol "\n"))
 469                                   (if whitespace-trailing
 470                                       "Trailing whitespace\n")
 471                                   "\ntype `M-x whitespace-cleanup' to "
 472                                   "cleanup the file."))
 473                     (setq whitespace-this-modeline
 474                           (concat (if whitespace-ateol "e")
 475                                   (if whitespace-indent "i")
 476                                   (if whitespace-leading "l")
 477                                   (if whitespace-spacetab "s")
 478                                   (if whitespace-trailing "t")))))
 479               (whitespace-update-modeline whitespace-this-modeline)
 480               (if (get-buffer whitespace-errbuf)
 481                   (kill-buffer whitespace-errbuf))
 482               (with-current-buffer (get-buffer-create whitespace-errbuf)
 483                 (if whitespace-errmsg
 484                     (progn
 485                       (insert whitespace-errmsg)
 486                       (if (not (or quiet whitespace-silent))
 487                           (display-buffer (current-buffer) t))
 488                       (if (not quiet)
 489                           (message "Whitespaces: [%s%s] in %s"
 490                                    whitespace-this-modeline
 491                                    (let ((whitespace-unchecked
 492                                           (whitespace-unchecked-whitespaces)))
 493                                      (if whitespace-unchecked
 494                                          (concat "!" whitespace-unchecked)
 495                                        ""))
 496                                    whitespace-filename)))
 497                   (if (and (not quiet) (not (equal whitespace-clean-msg "")))
 498                       (message "%s %s" whitespace-filename
 499                                whitespace-clean-msg))))))))
 500     whitespace-error))
 501
 502 ;;;###autoload
 503 (defun whitespace-region (s e)
 504   "Check the region for whitespace errors."
 505   (interactive "r")
 506   (save-excursion
 507     (save-restriction
 508       (narrow-to-region s e)
 509       (whitespace-buffer))))
 510
 511 ;;;###autoload
 512 (defun whitespace-cleanup ()
 513   "Cleanup the five different kinds of whitespace problems.
 514 It normally applies to the whole buffer, but in Transient Mark mode
 515 when the mark is active it applies to the region.
 516 See `whitespace-buffer' docstring for a summary of the problems."
 517   (interactive)
 518   (if (and transient-mark-mode mark-active)
 519       (whitespace-cleanup-region (region-beginning) (region-end))
 520     (whitespace-cleanup-internal)))
 521
 522 (defun whitespace-cleanup-internal (&optional region-only)
 523   ;; If this buffer really contains a file, then run, else quit.
 524   (whitespace-check-whitespace-mode current-prefix-arg)
 525   (if (and buffer-file-name whitespace-mode)
 526       (let ((whitespace-any nil)
 527             (whitespace-tabwith 8)
 528             (whitespace-tabwith-saved tab-width))
 529
 530         ;; since all printable TABS should be 8, irrespective of how
 531         ;; they are displayed.
 532         (setq tab-width whitespace-tabwith)
 533
 534         (if (and whitespace-check-buffer-leading
 535                  (whitespace-buffer-leading))
 536             (progn
 537               (whitespace-buffer-leading-cleanup)
 538               (setq whitespace-any t)))
 539
 540         (if (and whitespace-check-buffer-trailing
 541                  (whitespace-buffer-trailing))
 542             (progn
 543               (whitespace-buffer-trailing-cleanup)
 544               (setq whitespace-any t)))
 545
 546         (if (and whitespace-check-buffer-indent
 547                  (whitespace-buffer-search whitespace-indent-regexp))
 548             (progn
 549               (whitespace-indent-cleanup)
 550               (setq whitespace-any t)))
 551
 552         (if (and whitespace-check-buffer-spacetab
 553                  (whitespace-buffer-search whitespace-spacetab-regexp))
 554             (progn
 555               (whitespace-buffer-cleanup whitespace-spacetab-regexp "\t")
 556               (setq whitespace-any t)))
 557
 558         (if (and whitespace-check-buffer-ateol
 559                  (whitespace-buffer-search whitespace-ateol-regexp))
 560             (progn
 561               (whitespace-buffer-cleanup whitespace-ateol-regexp "")
 562               (setq whitespace-any t)))
 563
 564         ;; Call this recursively till everything is taken care of
 565         (if whitespace-any
 566             (whitespace-cleanup-internal region-only)
 567           ;; if we are done, talk to the user
 568           (progn
 569             (unless whitespace-silent
 570               (if region-only
 571                   (message "The region is now clean")
 572                 (message "%s is now clean" buffer-file-name)))
 573             (whitespace-update-modeline)))
 574         (setq tab-width whitespace-tabwith-saved))))
 575
 576 ;;;###autoload
 577 (defun whitespace-cleanup-region (s e)
 578   "Whitespace cleanup on the region."
 579   (interactive "r")
 580   (save-excursion
 581     (save-restriction
 582       (narrow-to-region s e)
 583       (whitespace-cleanup-internal t))
 584     (whitespace-buffer t)))
 585
 586 (defun whitespace-buffer-leading ()
 587   "Return t if the current buffer has leading newline characters.
 588 If highlighting is enabled, highlight these characters."
 589   (save-excursion
 590     (goto-char (point-min))
 591     (skip-chars-forward "\n")
 592     (unless (bobp)
 593       (whitespace-highlight-the-space (point-min) (point))
 594       t)))
 595
 596 (defun whitespace-buffer-leading-cleanup ()
 597   "Remove any leading newline characters from current buffer."
 598   (save-excursion
 599     (goto-char (point-min))
 600     (skip-chars-forward "\n")
 601     (delete-region (point-min) (point))))
 602
 603 (defun whitespace-buffer-trailing ()
 604   "Return t if the current buffer has extra trailing newline characters.
 605 If highlighting is enabled, highlight these characters."
 606   (save-excursion
 607     (goto-char (point-max))
 608     (skip-chars-backward "\n")
 609     (forward-line)
 610     (unless (eobp)
 611       (whitespace-highlight-the-space (point) (point-max))
 612       t)))
 613
 614 (defun whitespace-buffer-trailing-cleanup ()
 615   "Remove extra trailing newline characters from current buffer."
 616   (save-excursion
 617     (goto-char (point-max))
 618     (skip-chars-backward "\n")
 619     (unless (eobp)
 620       (forward-line)
 621       (delete-region (point) (point-max)))))
 622
 623 (defun whitespace-buffer-search (regexp)
 624   "Search for any given whitespace REGEXP."
 625   (with-local-quit
 626     (let (whitespace-retval)
 627       (save-excursion
 628         (goto-char (point-min))
 629         (while (re-search-forward regexp nil t)
 630           (whitespace-highlight-the-space (match-beginning 0) (match-end 0))
 631           (push (match-beginning 0) whitespace-retval)))
 632       (when whitespace-retval
 633         (format " %s" (nreverse whitespace-retval))))))
 634
 635 (defun whitespace-buffer-cleanup (regexp newregexp)
 636   "Search for any given whitespace REGEXP and replace it with the NEWREGEXP."
 637   (save-excursion
 638     (goto-char (point-min))
 639     (while (re-search-forward regexp nil t)
 640       (replace-match newregexp))))
 641
 642 (defun whitespace-indent-cleanup ()
 643   "Search for 8/more spaces at the start of a line and replace it with tabs."
 644   (save-excursion
 645     (goto-char (point-min))
 646     (while (re-search-forward whitespace-indent-regexp nil t)
 647       (let ((column (current-column))
 648             (indent-tabs-mode t))
 649         (delete-region (match-beginning 0) (point))
 650         (indent-to column)))))
 651
 652 (defun whitespace-unchecked-whitespaces ()
 653   "Return the list of whitespaces whose testing has been suppressed."
 654   (let ((unchecked-spaces
 655          (concat (if (not whitespace-check-buffer-ateol) "e")
 656                  (if (not whitespace-check-buffer-indent) "i")
 657                  (if (not whitespace-check-buffer-leading) "l")
 658                  (if (not whitespace-check-buffer-spacetab) "s")
 659                  (if (not whitespace-check-buffer-trailing) "t"))))
 660     (if (not (equal unchecked-spaces ""))
 661         unchecked-spaces
 662       nil)))
 663
 664 (defun whitespace-update-modeline (&optional whitespace-err)
 665   "Update modeline with whitespace errors.
 666 Also with whitespaces whose testing has been turned off."
 667   (if whitespace-display-in-modeline
 668       (progn
 669         (setq whitespace-mode-line nil)
 670         ;; Whitespace errors
 671         (if (and whitespace-err (not (equal whitespace-err "")))
 672             (setq whitespace-mode-line whitespace-err))
 673         ;; Whitespace suppressed errors
 674         (let ((whitespace-unchecked (whitespace-unchecked-whitespaces)))
 675           (if whitespace-unchecked
 676               (setq whitespace-mode-line
 677                     (concat whitespace-mode-line "!" whitespace-unchecked))))
 678         ;; Add the whitespace modeline prefix
 679         (setq whitespace-mode-line (if whitespace-mode-line
 680                                        (concat " W:" whitespace-mode-line)
 681                                      nil))
 682         (whitespace-mode-line-update))))
 683
 684 (defun whitespace-highlight-the-space (b e)
 685   "Highlight the current line, unhighlighting a previously jumped to line."
 686   (if whitespace-display-spaces-in-color
 687       (let ((ol (whitespace-make-overlay b e)))
 688         (whitespace-overlay-put ol 'face 'whitespace-highlight))))
 689
 690 (defun whitespace-unhighlight-the-space()
 691   "Unhighlight the currently highlight line."
 692   (if (and whitespace-display-spaces-in-color whitespace-highlighted-space)
 693       (progn
 694         (mapc 'whitespace-delete-overlay whitespace-highlighted-space)
 695         (setq whitespace-highlighted-space nil))))
 696
 697 (defun whitespace-check-buffer-list (buf-name buf-file)
 698   "Add a buffer and its file to the whitespace monitor list.
 699
 700 The buffer named BUF-NAME and its associated file BUF-FILE are now monitored
 701 periodically for whitespace."
 702   (if (and whitespace-mode (not (member (list buf-file buf-name)
 703                                         whitespace-all-buffer-files)))
 704       (add-to-list 'whitespace-all-buffer-files (list buf-file buf-name))))
 705
 706 (defun whitespace-tickle-timer ()
 707   "Tickle timer to periodically to scan qualifying files for whitespace creep.
 708
 709 If timer is not set, then set it to scan the files in
 710 `whitespace-all-buffer-files' periodically (defined by
 711 `whitespace-rescan-timer-time') for whitespace creep."
 712   (if (and whitespace-rescan-timer-time
 713            (/= whitespace-rescan-timer-time 0)
 714            (not whitespace-rescan-timer))
 715       (setq whitespace-rescan-timer
 716             (add-timeout whitespace-rescan-timer-time
 717                          'whitespace-rescan-files-in-buffers nil
 718                          whitespace-rescan-timer-time))))
 719
 720 (defun whitespace-rescan-files-in-buffers (&optional arg)
 721   "Check monitored files for whitespace creep since last scan."
 722   (let ((whitespace-all-my-files whitespace-all-buffer-files)
 723         buffile bufname thiselt buf)
 724     (if (not whitespace-all-my-files)
 725         (progn
 726           (disable-timeout whitespace-rescan-timer)
 727           (setq whitespace-rescan-timer nil))
 728       (while whitespace-all-my-files
 729         (setq thiselt (car whitespace-all-my-files))
 730         (setq whitespace-all-my-files (cdr whitespace-all-my-files))
 731         (setq buffile (car thiselt))
 732         (setq bufname (cadr thiselt))
 733         (setq buf (get-buffer bufname))
 734         (if (buffer-live-p buf)
 735             (save-excursion
 736               ;;(message "buffer %s live" bufname)
 737               (set-buffer bufname)
 738               (if whitespace-mode
 739                   (progn
 740                     ;;(message "checking for whitespace in %s" bufname)
 741                     (if whitespace-auto-cleanup
 742                         (progn
 743                           ;;(message "cleaning up whitespace in %s" bufname)
 744                           (whitespace-cleanup-internal))
 745                       (progn
 746                         ;;(message "whitespace-buffer %s." (buffer-name))
 747                         (whitespace-buffer t))))
 748                 ;;(message "Removing %s from refresh list" bufname)
 749                 (whitespace-refresh-rescan-list buffile bufname)))
 750           ;;(message "Removing %s from refresh list" bufname)
 751           (whitespace-refresh-rescan-list buffile bufname))))))
 752
 753 (defun whitespace-refresh-rescan-list (buffile bufname)
 754   "Refresh the list of files to be rescanned for whitespace creep."
 755   (if whitespace-all-buffer-files
 756       (setq whitespace-all-buffer-files
 757             (delete (list buffile bufname) whitespace-all-buffer-files))
 758     (when whitespace-rescan-timer
 759       (disable-timeout whitespace-rescan-timer)
 760       (setq whitespace-rescan-timer nil))))
 761
 762 ;;;###autoload
 763 (defalias 'global-whitespace-mode 'whitespace-global-mode)
 764
 765 ;;;###autoload
 766 (define-minor-mode whitespace-global-mode
 767   "Toggle using Whitespace mode in new buffers.
 768 With ARG, turn the mode on if ARG is positive, otherwise turn it off.
 769
 770 When this mode is active, `whitespace-buffer' is added to
 771 `find-file-hook' and `kill-buffer-hook'."
 772   :global t
 773   :group 'whitespace
 774   (if whitespace-global-mode
 775       (progn
 776         (add-hook 'find-file-hook 'whitespace-buffer)
 777         (add-hook 'write-file-functions 'whitespace-write-file-hook nil t)
 778         (add-hook 'kill-buffer-hook 'whitespace-buffer))
 779     (remove-hook 'find-file-hook 'whitespace-buffer)
 780     (remove-hook 'write-file-functions 'whitespace-write-file-hook t)
 781     (remove-hook 'kill-buffer-hook 'whitespace-buffer)))
 782
 783 ;;;###autoload
 784 (defun whitespace-write-file-hook ()
 785   "Hook function to be called on the buffer when whitespace check is enabled.
 786 This is meant to be added buffer-locally to `write-file-functions'."
 787   (interactive)
 788   (let ((werr nil))
 789     (if whitespace-auto-cleanup
 790         (whitespace-cleanup-internal)
 791       (setq werr (whitespace-buffer)))
 792     (if (and whitespace-abort-on-error werr)
 793         (error (concat "Abort write due to whitespaces in "
 794                        buffer-file-name))))
 795   nil)
 796
 797 (defun whitespace-unload-hook ()
 798   (remove-hook 'find-file-hook 'whitespace-buffer)
 799   (remove-hook 'write-file-functions 'whitespace-write-file-hook t)
 800   (remove-hook 'kill-buffer-hook 'whitespace-buffer))
 801
 802 (add-hook 'whitespace-unload-hook 'whitespace-unload-hook)
 803
 804 (provide 'whitespace)
 805
 806 ;; arch-tag: 4ff44e87-b63c-402d-95a6-15e51e58bd0c
 807 ;;; whitespace.el ends here