lisp/doc-view.el

   1 ;;; doc-view.el --- View PDF/PostScript/DVI files in Emacs
   2
   3 ;; Copyright (C) 2007, 2008 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Tassilo Horn <tassilo@member.fsf.org>
   6 ;; Maintainer: Tassilo Horn <tassilo@member.fsf.org>
   7 ;; Keywords: files, pdf, ps, dvi
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Requirements:
  25
  26 ;; doc-view.el requires GNU Emacs 22.1 or newer.  You also need Ghostscript,
  27 ;; `dvipdf' (comes with Ghostscript) or `dvipdfm' (comes with teTeX or TeXLive)
  28 ;; and `pdftotext', which comes with xpdf (http://www.foolabs.com/xpdf/) or
  29 ;; poppler (http://poppler.freedesktop.org/).
  30
  31 ;;; Commentary:
  32
  33 ;; DocView is a document viewer for Emacs.  It converts PDF, PS and DVI files
  34 ;; to a set of PNG files, one PNG for each page, and displays the PNG images
  35 ;; inside an Emacs buffer.  This buffer uses `doc-view-mode' which provides
  36 ;; convenient key bindings for browsing the document.
  37 ;;
  38 ;; To use it simply open a document file with
  39 ;;
  40 ;;     C-x C-f ~/path/to/document RET
  41 ;;
  42 ;; and the document will be converted and displayed, if your emacs supports png
  43 ;; images.  With `C-c C-c' you can toggle between the rendered images
  44 ;; representation and the source text representation of the document.
  45 ;;
  46 ;; Since conversion may take some time all the PNG images are cached in a
  47 ;; subdirectory of `doc-view-cache-directory' and reused when you want to view
  48 ;; that file again.  To reconvert a document hit `g' (`doc-view-reconvert-doc')
  49 ;; when displaying the document.  To delete all cached files use
  50 ;; `doc-view-clear-cache'.  To open the cache with dired, so that you can tidy
  51 ;; it out use `doc-view-dired-cache'.
  52 ;;
  53 ;; When conversion in underway the first page will be displayed as soon as it
  54 ;; is available and the available pages are refreshed every
  55 ;; `doc-view-conversion-refresh-interval' seconds.  If that variable is nil the
  56 ;; pages won't be displayed before conversion of the document finished
  57 ;; completely.
  58 ;;
  59 ;; DocView lets you select a slice of the displayed pages.  This slice will be
  60 ;; remembered and applied to all pages of the current document.  This enables
  61 ;; you to cut away the margins of a document to save some space.  To select a
  62 ;; slice you can use `doc-view-set-slice' (bound to `s s') which will query you
  63 ;; for the coordinates of the slice's top-left corner and its width and height.
  64 ;; A much more convenient way to do the same is offered by the command
  65 ;; `doc-view-set-slice-using-mouse' (bound to `s m').  After invokation you
  66 ;; only have to press mouse-1 at the top-left corner and drag it to the
  67 ;; bottom-right corner of the desired slice.  To reset the slice use
  68 ;; `doc-view-reset-slice' (bound to `s r').
  69 ;;
  70 ;; You can also search within the document.  The command `doc-view-search'
  71 ;; (bound to `C-s') queries for a search regexp and initializes a list of all
  72 ;; matching pages and messages how many match-pages were found.  After that you
  73 ;; can jump to the next page containing a match with an additional `C-s'.  With
  74 ;; `C-r' you can do the same, but backwards.  To search for a new regexp give a
  75 ;; prefix arg to one of the search functions, e.g. by typing `C-u C-s'.  The
  76 ;; searching works by using a plain text representation of the document.  If
  77 ;; that doesn't already exist the first invokation of `doc-view-search' (or
  78 ;; `doc-view-search-backward') starts the conversion.  When that finishes and
  79 ;; you're still viewing the document (i.e. you didn't switch to another buffer)
  80 ;; you're queried for the regexp then.
  81 ;;
  82 ;; Dired users can simply hit `v' on a document file.  If it's a PS, PDF or DVI
  83 ;; it will be opened using `doc-view-mode'.
  84 ;;
  85
  86 ;;; Configuration:
  87
  88 ;; If the images are too small or too big you should set the "-rXXX" option in
  89 ;; `doc-view-ghostscript-options' to another value.  (The bigger your screen,
  90 ;; the higher the value.)
  91 ;;
  92 ;; This and all other options can be set with the customization interface.
  93 ;; Simply do
  94 ;;
  95 ;;     M-x customize-group RET doc-view RET
  96 ;;
  97 ;; and modify them to your needs.
  98
  99 ;;; Todo:
 100
 101 ;; - add print command.
 102 ;; - share more code with image-mode.
 103 ;; - better menu.
 104 ;; - Bind slicing to a drag event.
 105 ;; - doc-view-fit-doc-to-window and doc-view-fit-window-to-doc?
 106 ;; - zoom the region around the cursor (like xdvi).
 107 ;; - get rid of the silly arrow in the fringe.
 108 ;; - improve anti-aliasing (pdf-utils gets it better).
 109
 110 ;;;; About isearch support
 111
 112 ;; I tried implementing isearch by setting
 113 ;; `isearch-search-fun-function' buffer-locally, but that didn't
 114 ;; work too good.  The function doing the real search was called
 115 ;; endlessly somehow.  But even if we'd get that working no real
 116 ;; isearch feeling comes up due to the missing match highlighting.
 117 ;; Currently I display all lines containing a match in a tooltip and
 118 ;; each C-s or C-r jumps directly to the next/previous page with a
 119 ;; match.  With isearch we could only display the current match.  So
 120 ;; we had to decide if another C-s jumps to the next page with a
 121 ;; match (thus only the first match in a page will be displayed in a
 122 ;; tooltip) or to the next match, which would do nothing visible
 123 ;; (except the tooltip) if the next match is on the same page.
 124
 125 ;; And it's much slower than the current search facility, because
 126 ;; isearch really searches for each step forward or backward wheras
 127 ;; the current approach searches once and then it knows to which
 128 ;; pages to jump.
 129
 130 ;; Anyway, if someone with better isearch knowledge wants to give it a try,
 131 ;; feel free to do it.  --Tassilo
 132
 133 ;;; Code:
 134
 135 (eval-when-compile (require 'cl))
 136 (require 'dired)
 137 (require 'image-mode)
 138 (require 'jka-compr)
 139
 140 ;;;; Customization Options
 141
 142 (defgroup doc-view nil
 143   "In-buffer viewer for PDF, PostScript and DVI files."
 144   :link '(function-link doc-view)
 145   :version "22.2"
 146   :group 'applications
 147   :group 'multimedia
 148   :prefix "doc-view-")
 149
 150 (defcustom doc-view-ghostscript-program (executable-find "gs")
 151   "Program to convert PS and PDF files to PNG."
 152   :type 'file
 153   :group 'doc-view)
 154
 155 (defcustom doc-view-ghostscript-options
 156   '("-dSAFER" ;; Avoid security problems when rendering files from untrusted
 157               ;; sources.
 158     "-dNOPAUSE" "-sDEVICE=png16m" "-dTextAlphaBits=4"
 159     "-dBATCH" "-dGraphicsAlphaBits=4" "-dQUIET")
 160   "A list of options to give to ghostscript."
 161   :type '(repeat string)
 162   :group 'doc-view)
 163
 164 (defcustom doc-view-resolution 100
 165   "Dots per inch resolution used to render the documents.
 166 Higher values result in larger images."
 167   :type 'number
 168   :group 'doc-view)
 169
 170 (defcustom doc-view-dvipdfm-program (executable-find "dvipdfm")
 171   "Program to convert DVI files to PDF.
 172
 173 DVI file will be converted to PDF before the resulting PDF is
 174 converted to PNG.
 175
 176 If this and `doc-view-dvipdf-program' are set,
 177 `doc-view-dvipdf-program' will be preferred."
 178   :type 'file
 179   :group 'doc-view)
 180
 181 (defcustom doc-view-dvipdf-program (executable-find "dvipdf")
 182   "Program to convert DVI files to PDF.
 183
 184 DVI file will be converted to PDF before the resulting PDF is
 185 converted to PNG.
 186
 187 If this and `doc-view-dvipdfm-program' are set,
 188 `doc-view-dvipdf-program' will be preferred."
 189   :type 'file
 190   :group 'doc-view)
 191
 192 (defcustom doc-view-ps2pdf-program (executable-find "ps2pdf")
 193   "Program to convert PS files to PDF.
 194
 195 PS files will be converted to PDF before searching is possible."
 196   :type 'file
 197   :group 'doc-view)
 198
 199 (defcustom doc-view-pdftotext-program (executable-find "pdftotext")
 200   "Program to convert PDF files to plain text.
 201
 202 Needed for searching."
 203   :type 'file
 204   :group 'doc-view)
 205
 206 (defcustom doc-view-cache-directory
 207   (expand-file-name (format "docview%d" (user-uid))
 208                     temporary-file-directory)
 209   "The base directory, where the PNG images will be saved."
 210   :type 'directory
 211   :group 'doc-view)
 212
 213 (defvar doc-view-conversion-buffer " *doc-view conversion output*"
 214   "The buffer where messages from the converter programs go to.")
 215
 216 (defcustom doc-view-conversion-refresh-interval 1
 217   "Interval in seconds between refreshes of the DocView buffer while converting.
 218 After such a refresh newly converted pages will be available for
 219 viewing.  If set to nil there won't be any refreshes and the
 220 pages won't be displayed before conversion of the whole document
 221 has finished."
 222   :type 'integer
 223   :group 'doc-view)
 224
 225 ;;;; Internal Variables
 226
 227 (defun doc-view-new-window-function (winprops)
 228   (let ((ol (image-mode-window-get 'overlay winprops)))
 229     (if ol
 230         (setq ol (copy-overlay ol))
 231       (assert (not (get-char-property (point-min) 'display)))
 232       (setq ol (make-overlay (point-min) (point-max) nil t))
 233       (overlay-put ol 'doc-view t))
 234     (overlay-put ol 'window (car winprops))
 235     (image-mode-window-put 'overlay ol winprops)))
 236
 237 (defvar doc-view-current-files nil
 238   "Only used internally.")
 239 (make-variable-buffer-local 'doc-view-current-files)
 240
 241 (defvar doc-view-current-converter-processes nil
 242   "Only used internally.")
 243 (make-variable-buffer-local 'doc-view-current-converter-processes)
 244
 245 (defvar doc-view-current-timer nil
 246   "Only used internally.")
 247 (make-variable-buffer-local 'doc-view-current-timer)
 248
 249 (defvar doc-view-current-cache-dir nil
 250   "Only used internally.")
 251 (make-variable-buffer-local 'doc-view-current-cache-dir)
 252
 253 (defvar doc-view-current-search-matches nil
 254   "Only used internally.")
 255 (make-variable-buffer-local 'doc-view-current-search-matches)
 256
 257 (defvar doc-view-pending-cache-flush nil
 258   "Only used internally.")
 259
 260 (defvar doc-view-previous-major-mode nil
 261   "Only used internally.")
 262
 263 (defvar doc-view-buffer-file-name nil
 264   "Only used internally.
 265 The file name used for conversion.  Normally it's the same as
 266 `buffer-file-name', but for remote files, compressed files and
 267 files inside an archive it is a temporary copy of
 268 the (uncompressed, extracted) file residing in
 269 `doc-view-cache-directory'.")
 270
 271 (defvar doc-view-doc-type nil
 272   "The type of document in the current buffer.
 273 Can be `dvi', `pdf', or `ps'.")
 274
 275 ;;;; DocView Keymaps
 276
 277 (defvar doc-view-mode-map
 278   (let ((map (make-sparse-keymap)))
 279     (set-keymap-parent map image-mode-map)
 280     ;; Navigation in the document
 281     (define-key map (kbd "n")         'doc-view-next-page)
 282     (define-key map (kbd "p")         'doc-view-previous-page)
 283     (define-key map (kbd "<next>")    'forward-page)
 284     (define-key map (kbd "<prior>")   'backward-page)
 285     (define-key map [remap forward-page]  'doc-view-next-page)
 286     (define-key map [remap backward-page] 'doc-view-previous-page)
 287     (define-key map (kbd "SPC")       'doc-view-scroll-up-or-next-page)
 288     (define-key map (kbd "DEL")       'doc-view-scroll-down-or-previous-page)
 289     (define-key map (kbd "M-<")       'doc-view-first-page)
 290     (define-key map (kbd "M->")       'doc-view-last-page)
 291     (define-key map [remap goto-line] 'doc-view-goto-page)
 292     ;; Zoom in/out.
 293     (define-key map "+"               'doc-view-enlarge)
 294     (define-key map "-"               'doc-view-shrink)
 295     ;; Killing the buffer (and the process)
 296     (define-key map (kbd "k")         'doc-view-kill-proc-and-buffer)
 297     (define-key map (kbd "K")         'doc-view-kill-proc)
 298     ;; Slicing the image
 299     (define-key map (kbd "s s")       'doc-view-set-slice)
 300     (define-key map (kbd "s m")       'doc-view-set-slice-using-mouse)
 301     (define-key map (kbd "s r")       'doc-view-reset-slice)
 302     ;; Searching
 303     (define-key map (kbd "C-s")       'doc-view-search)
 304     (define-key map (kbd "<find>")    'doc-view-search)
 305     (define-key map (kbd "C-r")       'doc-view-search-backward)
 306     ;; Show the tooltip
 307     (define-key map (kbd "C-t")       'doc-view-show-tooltip)
 308     ;; Toggle between text and image display or editing
 309     (define-key map (kbd "C-c C-c")   'doc-view-toggle-display)
 310     ;; Open a new buffer with doc's text contents
 311     (define-key map (kbd "C-c C-t")   'doc-view-open-text)
 312     ;; Reconvert the current document
 313     (define-key map (kbd "g")         'revert-buffer)
 314     (define-key map (kbd "r")         'revert-buffer)
 315     map)
 316   "Keymap used by `doc-view-mode' when displaying a doc as a set of images.")
 317
 318 (easy-menu-define doc-view-menu doc-view-mode-map
 319   "Menu for Doc View mode."
 320   '("DocView"
 321     ["Set Slice"                doc-view-set-slice-using-mouse]
 322     ["Set Slice (manual)"       doc-view-set-slice]
 323     ["Reset Slice"              doc-view-reset-slice]
 324     "---"
 325     ["Search"                   doc-view-search]
 326     ["Search Backwards"         doc-view-search-backward]
 327     ["Toggle display"           doc-view-toggle-display]
 328     ))
 329
 330 (defvar doc-view-minor-mode-map
 331   (let ((map (make-sparse-keymap)))
 332     ;; Toggle between text and image display or editing
 333     (define-key map (kbd "C-c C-c") 'doc-view-toggle-display)
 334     map)
 335   "Keymap used by `doc-minor-view-mode'.")
 336
 337 ;;;; Navigation Commands
 338
 339 (defmacro doc-view-current-page (&optional win)
 340   `(image-mode-window-get 'page ,win))
 341 (defmacro doc-view-current-info () `(image-mode-window-get 'info))
 342 (defmacro doc-view-current-overlay () `(image-mode-window-get 'overlay))
 343 (defmacro doc-view-current-image () `(image-mode-window-get 'image))
 344 (defmacro doc-view-current-slice () `(image-mode-window-get 'slice))
 345
 346 (defun doc-view-goto-page (page)
 347   "View the page given by PAGE."
 348   (interactive "nPage: ")
 349   (let ((len (length doc-view-current-files)))
 350     (if (< page 1)
 351         (setq page 1)
 352       (when (and (> page len)
 353                  ;; As long as the converter is running, we don't know
 354                  ;; how many pages will be available.
 355                  (null doc-view-current-converter-processes))
 356         (setq page len)))
 357     (setf (doc-view-current-page) page
 358           (doc-view-current-info)
 359           (concat
 360            (propertize
 361             (format "Page %d of %d." page len) 'face 'bold)
 362            ;; Tell user if converting isn't finished yet
 363            (if doc-view-current-converter-processes
 364                " (still converting...)\n"
 365              "\n")
 366            ;; Display context infos if this page matches the last search
 367            (when (and doc-view-current-search-matches
 368                       (assq page doc-view-current-search-matches))
 369              (concat (propertize "Search matches:\n" 'face 'bold)
 370                      (let ((contexts ""))
 371                        (dolist (m (cdr (assq page
 372                                              doc-view-current-search-matches)))
 373                          (setq contexts (concat contexts "  - \"" m "\"\n")))
 374                        contexts)))))
 375     ;; Update the buffer
 376     ;; We used to find the file name from doc-view-current-files but
 377     ;; that's not right if the pages are not generated sequentially
 378     ;; or if the page isn't in doc-view-current-files yet.
 379     (let ((file (expand-file-name (format "page-%d.png" page)
 380                                   (doc-view-current-cache-dir))))
 381       (doc-view-insert-image file :pointer 'arrow)
 382       (when (and (not (file-exists-p file))
 383                  doc-view-current-converter-processes)
 384         ;; The PNG file hasn't been generated yet.
 385         (doc-view-pdf->png-1 doc-view-buffer-file-name file page
 386                              (lexical-let ((page page)
 387                                            (win (selected-window)))
 388                                (lambda ()
 389                                  (and (eq (current-buffer) (window-buffer win))
 390                                       ;; If we changed page in the mean
 391                                       ;; time, don't mess things up.
 392                                       (eq (doc-view-current-page win) page)
 393                                       (with-selected-window win
 394                                         (doc-view-goto-page page))))))))
 395     (overlay-put (doc-view-current-overlay)
 396                  'help-echo (doc-view-current-info))))
 397
 398 (defun doc-view-next-page (&optional arg)
 399   "Browse ARG pages forward."
 400   (interactive "p")
 401   (doc-view-goto-page (+ (doc-view-current-page) (or arg 1))))
 402
 403 (defun doc-view-previous-page (&optional arg)
 404   "Browse ARG pages backward."
 405   (interactive "p")
 406   (doc-view-goto-page (- (doc-view-current-page) (or arg 1))))
 407
 408 (defun doc-view-first-page ()
 409   "View the first page."
 410   (interactive)
 411   (doc-view-goto-page 1))
 412
 413 (defun doc-view-last-page ()
 414   "View the last page."
 415   (interactive)
 416   (doc-view-goto-page (length doc-view-current-files)))
 417
 418 (defun doc-view-scroll-up-or-next-page ()
 419   "Scroll page up if possible, else goto next page."
 420   (interactive)
 421   (when (= (window-vscroll) (image-scroll-up nil))
 422     (let ((cur-page (doc-view-current-page)))
 423       (doc-view-next-page)
 424       (when (/= cur-page (doc-view-current-page))
 425         (image-bob)
 426         (image-bol 1)))))
 427
 428 (defun doc-view-scroll-down-or-previous-page ()
 429   "Scroll page down if possible, else goto previous page."
 430   (interactive)
 431   (when (= (window-vscroll) (image-scroll-down nil))
 432     (let ((cur-page (doc-view-current-page)))
 433       (doc-view-previous-page)
 434       (when (/= cur-page (doc-view-current-page))
 435         (image-eob)
 436         (image-bol 1)))))
 437
 438 ;;;; Utility Functions
 439
 440 (defun doc-view-kill-proc ()
 441   "Kill the current converter process(es)."
 442   (interactive)
 443   (while doc-view-current-converter-processes
 444     (ignore-errors ;; Maybe it's dead already?
 445       (kill-process (pop doc-view-current-converter-processes))))
 446   (when doc-view-current-timer
 447     (cancel-timer doc-view-current-timer)
 448     (setq doc-view-current-timer nil))
 449   (setq mode-line-process nil))
 450
 451 (defun doc-view-kill-proc-and-buffer ()
 452   "Kill the current converter process and buffer."
 453   (interactive)
 454   (doc-view-kill-proc)
 455   (when (eq major-mode 'doc-view-mode)
 456     (kill-buffer (current-buffer))))
 457
 458 (defun doc-view-make-safe-dir (dir)
 459   (condition-case nil
 460       (let ((umask (default-file-modes)))
 461         (unwind-protect
 462             (progn
 463               ;; Create temp files with strict access rights.  It's easy to
 464               ;; loosen them later, whereas it's impossible to close the
 465               ;; time-window of loose permissions otherwise.
 466               (set-default-file-modes #o0700)
 467               (make-directory dir))
 468           ;; Reset the umask.
 469           (set-default-file-modes umask)))
 470     (file-already-exists
 471      (if (file-symlink-p dir)
 472          (error "Danger: %s points to a symbolic link" dir))
 473      ;; In case it was created earlier with looser rights.
 474      ;; We could check the mode info returned by file-attributes, but it's
 475      ;; a pain to parse and it may not tell you what we want under
 476      ;; non-standard file-systems.  So let's just say what we want and let
 477      ;; the underlying C code and file-system figure it out.
 478      ;; This also ends up checking a bunch of useful conditions: it makes
 479      ;; sure we have write-access to the directory and that we own it, thus
 480      ;; closing a bunch of security holes.
 481      (set-file-modes dir #o0700))))
 482
 483 (defun doc-view-current-cache-dir ()
 484   "Return the directory where the png files of the current doc should be saved.
 485 It's a subdirectory of `doc-view-cache-directory'."
 486   (if doc-view-current-cache-dir
 487       doc-view-current-cache-dir
 488     ;; Try and make sure doc-view-cache-directory exists and is safe.
 489     (doc-view-make-safe-dir doc-view-cache-directory)
 490     ;; Now compute the subdirectory to use.
 491     (setq doc-view-current-cache-dir
 492           (file-name-as-directory
 493            (expand-file-name
 494             (concat (file-name-nondirectory buffer-file-name)
 495                     "-"
 496                     (let ((file doc-view-buffer-file-name))
 497                       (with-temp-buffer
 498                         (set-buffer-multibyte nil)
 499                         (insert-file-contents-literally file)
 500                         (md5 (current-buffer)))))
 501             doc-view-cache-directory)))))
 502
 503 (defun doc-view-remove-if (predicate list)
 504   "Return LIST with all items removed that satisfy PREDICATE."
 505   (let (new-list)
 506     (dolist (item list (nreverse new-list))
 507       (when (not (funcall predicate item))
 508         (setq new-list (cons item new-list))))))
 509
 510 ;;;###autoload
 511 (defun doc-view-mode-p (type)
 512   "Return non-nil if image type TYPE is available for `doc-view'.
 513 Image types are symbols like `dvi', `postscript' or `pdf'."
 514   (and (display-graphic-p)
 515        (image-type-available-p 'png)
 516        (cond
 517         ((eq type 'dvi)
 518          (and (doc-view-mode-p 'pdf)
 519               (or (and doc-view-dvipdf-program
 520                        (executable-find doc-view-dvipdf-program))
 521                   (and doc-view-dvipdfm-program
 522                        (executable-find doc-view-dvipdfm-program)))))
 523         ((or (eq type 'postscript) (eq type 'ps) (eq type 'eps)
 524              (eq type 'pdf))
 525          (and doc-view-ghostscript-program
 526               (executable-find doc-view-ghostscript-program)))
 527         (t ;; unknown image type
 528          nil))))
 529
 530 ;;;; Conversion Functions
 531
 532 (defvar doc-view-shrink-factor 1.125)
 533
 534 (defun doc-view-enlarge (factor)
 535   "Enlarge the document."
 536   (interactive (list doc-view-shrink-factor))
 537   (set (make-local-variable 'doc-view-resolution)
 538        (* factor doc-view-resolution))
 539   (doc-view-reconvert-doc))
 540
 541 (defun doc-view-shrink (factor)
 542   "Shrink the document."
 543   (interactive (list doc-view-shrink-factor))
 544   (doc-view-enlarge (/ 1.0 factor)))
 545
 546 (defun doc-view-reconvert-doc ()
 547   "Reconvert the current document.
 548 Should be invoked when the cached images aren't up-to-date."
 549   (interactive)
 550   (doc-view-kill-proc)
 551   ;; Clear the old cached files
 552   (when (file-exists-p (doc-view-current-cache-dir))
 553     (dired-delete-file (doc-view-current-cache-dir) 'always))
 554   (doc-view-initiate-display))
 555
 556 (defun doc-view-sentinel (proc event)
 557   "Generic sentinel for doc-view conversion processes."
 558   (if (not (string-match "finished" event))
 559       (message "DocView: process %s changed status to %s."
 560                (process-name proc) event)
 561     (when (buffer-live-p (process-get proc 'buffer))
 562       (with-current-buffer (process-get proc 'buffer)
 563         (setq doc-view-current-converter-processes
 564               (delq proc doc-view-current-converter-processes))
 565         (setq mode-line-process
 566               (if doc-view-current-converter-processes
 567                   (format ":%s" (car doc-view-current-converter-processes))))
 568         (funcall (process-get proc 'callback))))))
 569
 570 (defun doc-view-start-process (name program args callback)
 571   ;; Make sure the process is started in an existing directory, (rather than
 572   ;; some file-name-handler-managed dir, for example).
 573   (let* ((default-directory (if (file-readable-p default-directory)
 574                                 default-directory
 575                               (expand-file-name "~/")))
 576          (proc (apply 'start-process name doc-view-conversion-buffer
 577                       program args)))
 578     (push proc doc-view-current-converter-processes)
 579     (setq mode-line-process (list (format ":%s" proc)))
 580     (set-process-sentinel proc 'doc-view-sentinel)
 581     (process-put proc 'buffer   (current-buffer))
 582     (process-put proc 'callback callback)))
 583
 584 (defun doc-view-dvi->pdf (dvi pdf callback)
 585   "Convert DVI to PDF asynchronously and call CALLBACK when finished."
 586   ;; Prefer dvipdf over dvipdfm, because the latter has problems if the DVI
 587   ;; references and includes other PS files.
 588   (if (and doc-view-dvipdf-program
 589            (executable-find doc-view-dvipdf-program))
 590       (doc-view-start-process "dvi->pdf" doc-view-dvipdf-program
 591                             (list dvi pdf)
 592                             callback)
 593     (doc-view-start-process "dvi->pdf" doc-view-dvipdfm-program
 594                             (list "-o" pdf dvi)
 595                             callback)))
 596
 597
 598 (defun doc-view-pdf/ps->png (pdf-ps png)
 599   "Convert PDF-PS to PNG asynchronously."
 600   (doc-view-start-process
 601    "pdf/ps->png" doc-view-ghostscript-program
 602    (append doc-view-ghostscript-options
 603            (list (format "-r%d" (round doc-view-resolution))
 604                  (concat "-sOutputFile=" png)
 605                  pdf-ps))
 606    (lambda ()
 607      (when doc-view-current-timer
 608        (cancel-timer doc-view-current-timer)
 609        (setq doc-view-current-timer nil))
 610      (doc-view-display (current-buffer) 'force)))
 611   ;; Update the displayed pages as soon as they're done generating.
 612   (when doc-view-conversion-refresh-interval
 613     (setq doc-view-current-timer
 614           (run-at-time "1 secs" doc-view-conversion-refresh-interval
 615                        'doc-view-display
 616                        (current-buffer)))))
 617
 618 (defun doc-view-pdf->png-1 (pdf png page callback)
 619   "Convert a PAGE of a PDF file to PNG asynchronously.
 620 Call CALLBACK with no arguments when done."
 621   (doc-view-start-process
 622    "pdf->png-1" doc-view-ghostscript-program
 623    (append doc-view-ghostscript-options
 624            (list (format "-r%d" (round doc-view-resolution))
 625                  ;; Sadly, `gs' only supports the page-range
 626                  ;; for PDF files.
 627                  (format "-dFirstPage=%d" page)
 628                  (format "-dLastPage=%d" page)
 629                  (concat "-sOutputFile=" png)
 630                  pdf))
 631    callback))
 632
 633 (declare-function clear-image-cache "image.c" (&optional filter))
 634
 635 (defun doc-view-pdf->png (pdf png pages)
 636   "Convert a PDF file to PNG asynchronously.
 637 Start by converting PAGES, and then the rest."
 638   (if (null pages)
 639       (doc-view-pdf/ps->png pdf png)
 640     ;; We could render several `pages' with a single process if they're
 641     ;; (almost) consecutive, but since in 99% of the cases, there'll be only
 642     ;; a single page anyway, and of the remaining 1%, few cases will have
 643     ;; consecutive pages, it's not worth the trouble.
 644     (lexical-let ((pdf pdf) (png png) (rest (cdr pages)))
 645       (doc-view-pdf->png-1
 646        pdf (format png (car pages)) (car pages)
 647        (lambda ()
 648          (if rest
 649              (doc-view-pdf->png pdf png rest)
 650            ;; Yippie, the important pages are done, update the display.
 651            (clear-image-cache)
 652            ;; Convert the rest of the pages.
 653            (doc-view-pdf/ps->png pdf png)))))))
 654
 655 (defun doc-view-pdf->txt (pdf txt callback)
 656   "Convert PDF to TXT asynchronously and call CALLBACK when finished."
 657   (doc-view-start-process "pdf->txt" doc-view-pdftotext-program
 658                           (list "-raw" pdf txt)
 659                           callback))
 660
 661 (defun doc-view-doc->txt (txt callback)
 662   "Convert the current document to text and call CALLBACK when done."
 663   (make-directory (doc-view-current-cache-dir) t)
 664   (case doc-view-doc-type
 665     (pdf
 666      ;; Doc is a PDF, so convert it to TXT
 667      (doc-view-pdf->txt doc-view-buffer-file-name txt callback))
 668     (ps
 669      ;; Doc is a PS, so convert it to PDF (which will be converted to
 670      ;; TXT thereafter).
 671      (lexical-let ((pdf (expand-file-name "doc.pdf"
 672                                           (doc-view-current-cache-dir)))
 673                    (txt txt)
 674                    (callback callback))
 675        (doc-view-ps->pdf doc-view-buffer-file-name pdf
 676                          (lambda () (doc-view-pdf->txt pdf txt callback)))))
 677     (dvi
 678      ;; Doc is a DVI.  This means that a doc.pdf already exists in its
 679      ;; cache subdirectory.
 680      (doc-view-pdf->txt (expand-file-name "doc.pdf"
 681                                           (doc-view-current-cache-dir))
 682                         txt callback))
 683     (t (error "DocView doesn't know what to do"))))
 684
 685 (defun doc-view-ps->pdf (ps pdf callback)
 686   "Convert PS to PDF asynchronously and call CALLBACK when finished."
 687   (doc-view-start-process "ps->pdf" doc-view-ps2pdf-program
 688                           (list
 689                            ;; Avoid security problems when rendering files from
 690                            ;; untrusted sources.
 691                            "-dSAFER"
 692                            ;; in-file and out-file
 693                            ps pdf)
 694                           callback))
 695
 696 (defun doc-view-active-pages ()
 697   (let ((pages ()))
 698     (dolist (win (get-buffer-window-list (current-buffer) nil 'visible))
 699       (let ((page (image-mode-window-get 'page win)))
 700         (unless (memq page pages) (push page pages))))
 701     pages))
 702
 703 (defun doc-view-convert-current-doc ()
 704   "Convert `doc-view-buffer-file-name' to a set of png files, one file per page.
 705 Those files are saved in the directory given by the function
 706 `doc-view-current-cache-dir'."
 707   ;; Let stale files still display while we recompute the new ones, so only
 708   ;; flush the cache when the conversion is over.  One of the reasons why it
 709   ;; is important to keep displaying the stale page is so that revert-buffer
 710   ;; preserves the horizontal/vertical scroll settings (which are otherwise
 711   ;; resets during the redisplay).
 712   (setq doc-view-pending-cache-flush t)
 713   (let ((png-file (expand-file-name "page-%d.png"
 714                                     (doc-view-current-cache-dir))))
 715     (make-directory (doc-view-current-cache-dir) t)
 716     (case doc-view-doc-type
 717       (dvi
 718        ;; DVI files have to be converted to PDF before Ghostscript can process
 719        ;; it.
 720        (lexical-let
 721            ((pdf (expand-file-name "doc.pdf" doc-view-current-cache-dir))
 722             (png-file png-file))
 723          (doc-view-dvi->pdf doc-view-buffer-file-name pdf
 724                             (lambda () (doc-view-pdf/ps->png pdf png-file)))))
 725      (pdf
 726       (let ((pages (doc-view-active-pages)))
 727         ;; Convert PDF to PNG images starting with the active pages.
 728         (doc-view-pdf->png doc-view-buffer-file-name png-file pages)))
 729       (t
 730        ;; Convert to PNG images.
 731        (doc-view-pdf/ps->png doc-view-buffer-file-name png-file)))))
 732
 733 ;;;; Slicing
 734
 735 (declare-function image-size "image.c" (spec &optional pixels frame))
 736
 737 (defun doc-view-set-slice (x y width height)
 738   "Set the slice of the images that should be displayed.
 739 You can use this function to tell doc-view not to display the
 740 margins of the document.  It prompts for the top-left corner (X
 741 and Y) of the slice to display and its WIDTH and HEIGHT.
 742
 743 See `doc-view-set-slice-using-mouse' for a more convenient way to
 744 do that.  To reset the slice use `doc-view-reset-slice'."
 745   (interactive
 746    (let* ((size (image-size (doc-view-current-image) t))
 747           (a (read-number (format "Top-left X (0..%d): " (car size))))
 748           (b (read-number (format "Top-left Y (0..%d): " (cdr size))))
 749           (c (read-number (format "Width (0..%d): " (- (car size) a))))
 750           (d (read-number (format "Height (0..%d): " (- (cdr size) b)))))
 751      (list a b c d)))
 752   (setf (doc-view-current-slice) (list x y width height))
 753   ;; Redisplay
 754   (doc-view-goto-page (doc-view-current-page)))
 755
 756 (defun doc-view-set-slice-using-mouse ()
 757   "Set the slice of the images that should be displayed.
 758 You set the slice by pressing mouse-1 at its top-left corner and
 759 dragging it to its bottom-right corner.  See also
 760 `doc-view-set-slice' and `doc-view-reset-slice'."
 761   (interactive)
 762   (let (x y w h done)
 763     (while (not done)
 764       (let ((e (read-event
 765                 (concat "Press mouse-1 at the top-left corner and "
 766                         "drag it to the bottom-right corner!"))))
 767         (when (eq (car e) 'drag-mouse-1)
 768           (setq x (car (posn-object-x-y (event-start e))))
 769           (setq y (cdr (posn-object-x-y (event-start e))))
 770           (setq w (- (car (posn-object-x-y (event-end e))) x))
 771           (setq h (- (cdr (posn-object-x-y (event-end e))) y))
 772           (setq done t))))
 773     (doc-view-set-slice x y w h)))
 774
 775 (defun doc-view-reset-slice ()
 776   "Reset the current slice.
 777 After calling this function whole pages will be visible again."
 778   (interactive)
 779   (setf (doc-view-current-slice) nil)
 780   ;; Redisplay
 781   (doc-view-goto-page (doc-view-current-page)))
 782
 783 ;;;; Display
 784
 785 (defun doc-view-insert-image (file &rest args)
 786   "Insert the given png FILE.
 787 ARGS is a list of image descriptors."
 788   (when doc-view-pending-cache-flush
 789     (clear-image-cache)
 790     (setq doc-view-pending-cache-flush nil))
 791   (let ((ol (doc-view-current-overlay))
 792         (image (if (and file (file-readable-p file))
 793                    (apply 'create-image file 'png nil args)))
 794         (slice (doc-view-current-slice)))
 795     (setf (doc-view-current-image) image)
 796     (move-overlay ol (point-min) (point-max))
 797     (overlay-put ol 'display
 798                  (cond
 799                   (image
 800                    (if slice
 801                        (list (cons 'slice slice) image)
 802                      image))
 803                   ;; We're trying to display a page that doesn't exist.
 804                   (doc-view-current-converter-processes
 805                    ;; Maybe the page doesn't exist *yet*.
 806                    "Cannot display this page (yet)!")
 807                   (t
 808                    ;; Typically happens if the conversion process somehow
 809                    ;; failed.  Better not signal an error here because it
 810                    ;; could prevent a subsequent reconversion from fixing
 811                    ;; the problem.
 812                    (concat "Cannot display this page!\n"
 813                            "Maybe because of a conversion failure!"))))
 814     (let ((win (overlay-get ol 'window)))
 815       (if (stringp (overlay-get ol 'display))
 816           (progn            ;Make sure the text is not scrolled out of view.
 817             (set-window-hscroll win 0)
 818             (set-window-vscroll win 0))
 819         (let ((hscroll (image-mode-window-get 'hscroll win))
 820               (vscroll (image-mode-window-get 'vscroll win)))
 821           ;; Reset scroll settings, in case they were changed.
 822           (if hscroll (set-window-hscroll win hscroll))
 823           (if vscroll (set-window-vscroll win vscroll)))))))
 824
 825 (defun doc-view-sort (a b)
 826   "Return non-nil if A should be sorted before B.
 827 Predicate for sorting `doc-view-current-files'."
 828   (or (< (length a) (length b))
 829       (and (= (length a) (length b))
 830            (string< a b))))
 831
 832 (defun doc-view-display (buffer &optional force)
 833   "Start viewing the document in BUFFER.
 834 If FORCE is non-nil, start viewing even if the document does not
 835 have the page we want to view."
 836   (with-current-buffer buffer
 837     (let ((prev-pages doc-view-current-files))
 838       (setq doc-view-current-files
 839             (sort (directory-files (doc-view-current-cache-dir) t
 840                                    "page-[0-9]+\\.png" t)
 841                   'doc-view-sort))
 842       (dolist (win (or (get-buffer-window-list buffer nil t)
 843                        (list (selected-window))))
 844         (let* ((page (doc-view-current-page win))
 845                (pagefile (expand-file-name (format "page-%d.png" page)
 846                                            (doc-view-current-cache-dir))))
 847           (when (or force
 848                     (and (not (member pagefile prev-pages))
 849                          (member pagefile doc-view-current-files)))
 850             (with-selected-window win
 851               (assert (eq (current-buffer) buffer))
 852               (doc-view-goto-page page))))))))
 853
 854 (defun doc-view-buffer-message ()
 855   ;; Only show this message initially, not when refreshing the buffer (in which
 856   ;; case it's better to keep displaying the "stale" page while computing
 857   ;; the fresh new ones).
 858   (unless (overlay-get (doc-view-current-overlay) 'display)
 859     (overlay-put (doc-view-current-overlay) 'display
 860                  (concat (propertize "Welcome to DocView!" 'face 'bold)
 861                          "\n"
 862                          "
 863 If you see this buffer it means that the document you want to view is being
 864 converted to PNG and the conversion of the first page hasn't finished yet or
 865 `doc-view-conversion-refresh-interval' is set to nil.
 866
 867 For now these keys are useful:
 868
 869 `q' : Bury this buffer.  Conversion will go on in background.
 870 `k' : Kill the conversion process and this buffer.
 871 `K' : Kill the conversion process.\n"))))
 872
 873 (declare-function tooltip-show "tooltip" (text &optional use-echo-area))
 874
 875 (defun doc-view-show-tooltip ()
 876   (interactive)
 877   (tooltip-show (doc-view-current-info)))
 878
 879 (defun doc-view-open-text ()
 880   "Open a buffer with the current doc's contents as text."
 881   (interactive)
 882   (if doc-view-current-converter-processes
 883       (message "DocView: please wait till conversion finished.")
 884     (let ((txt (expand-file-name "doc.txt" (doc-view-current-cache-dir))))
 885       (if (file-readable-p txt)
 886           (find-file txt)
 887         (doc-view-doc->txt txt 'doc-view-open-text)))))
 888
 889 ;;;;; Toggle between editing and viewing
 890
 891
 892 (defun doc-view-toggle-display ()
 893   "Toggle between editing a document as text or viewing it."
 894   (interactive)
 895   (if (eq major-mode 'doc-view-mode)
 896       ;; Switch to editing mode
 897       (progn
 898         (doc-view-kill-proc)
 899         (setq buffer-read-only nil)
 900         (remove-overlays (point-min) (point-max) 'doc-view t)
 901         (set (make-local-variable 'image-mode-winprops-alist) t)
 902         ;; Switch to the previously used major mode or fall back to fundamental
 903         ;; mode.
 904         (if doc-view-previous-major-mode
 905             (funcall doc-view-previous-major-mode)
 906           (fundamental-mode))
 907         (doc-view-minor-mode 1))
 908     ;; Switch to doc-view-mode
 909     (when (and (buffer-modified-p)
 910                (y-or-n-p "The buffer has been modified.  Save the changes? "))
 911       (save-buffer))
 912     (doc-view-mode)))
 913
 914 ;;;; Searching
 915
 916
 917 (defun doc-view-search-internal (regexp file)
 918   "Return a list of FILE's pages that contain text matching REGEXP.
 919 The value is an alist of the form (PAGE CONTEXTS) where PAGE is
 920 the pagenumber and CONTEXTS are all lines of text containing a match."
 921   (with-temp-buffer
 922     (insert-file-contents file)
 923     (let ((page 1)
 924           (lastpage 1)
 925           matches)
 926       (while (re-search-forward (concat "\\(?:\\([\f]\\)\\|\\("
 927                                         regexp "\\)\\)") nil t)
 928         (when (match-string 1) (setq page (1+ page)))
 929         (when (match-string 2)
 930           (if (/= page lastpage)
 931               (push (cons page
 932                           (list (buffer-substring
 933                                  (line-beginning-position)
 934                                  (line-end-position))))
 935                     matches)
 936             (setq matches (cons
 937                            (append
 938                             (or
 939                              ;; This page already is a match.
 940                              (car matches)
 941                              ;; This is the first match on page.
 942                              (list page))
 943                             (list (buffer-substring
 944                                    (line-beginning-position)
 945                                    (line-end-position))))
 946                            (cdr matches))))
 947           (setq lastpage page)))
 948       (nreverse matches))))
 949
 950 (defun doc-view-search-no-of-matches (list)
 951   "Extract the number of matches from the search result LIST."
 952   (let ((no 0))
 953     (dolist (p list)
 954       (setq no (+ no (1- (length p)))))
 955     no))
 956
 957 (defun doc-view-search-backward (new-query)
 958   "Call `doc-view-search' for backward search.
 959 If prefix NEW-QUERY is given, ask for a new regexp."
 960   (interactive "P")
 961   (doc-view-search new-query t))
 962
 963 (defun doc-view-search (new-query &optional backward)
 964   "Jump to the next match or initiate a new search if NEW-QUERY is given.
 965 If the current document hasn't been transformed to plain text
 966 till now do that first.
 967 If BACKWARD is non-nil, jump to the previous match."
 968   (interactive "P")
 969   (if (and (not new-query)
 970            doc-view-current-search-matches)
 971       (if backward
 972           (doc-view-search-previous-match 1)
 973         (doc-view-search-next-match 1))
 974     ;; New search, so forget the old results.
 975     (setq doc-view-current-search-matches nil)
 976     (let ((txt (expand-file-name "doc.txt"
 977                                  (doc-view-current-cache-dir))))
 978       (if (file-readable-p txt)
 979           (progn
 980             (setq doc-view-current-search-matches
 981                   (doc-view-search-internal
 982                    (read-from-minibuffer "Regexp: ")
 983                    txt))
 984             (message "DocView: search yielded %d matches."
 985                      (doc-view-search-no-of-matches
 986                       doc-view-current-search-matches)))
 987         ;; We must convert to TXT first!
 988         (if doc-view-current-converter-processes
 989             (message "DocView: please wait till conversion finished.")
 990           (doc-view-doc->txt txt (lambda () (doc-view-search nil))))))))
 991
 992 (defun doc-view-search-next-match (arg)
 993   "Go to the ARGth next matching page."
 994   (interactive "p")
 995   (let* ((next-pages (doc-view-remove-if
 996                       (lambda (i) (<= (car i) (doc-view-current-page)))
 997                       doc-view-current-search-matches))
 998          (page (car (nth (1- arg) next-pages))))
 999     (if page
1000         (doc-view-goto-page page)
1001       (when (and
1002              doc-view-current-search-matches
1003              (y-or-n-p "No more matches after current page.  Wrap to first match? "))
1004         (doc-view-goto-page (caar doc-view-current-search-matches))))))
1005
1006 (defun doc-view-search-previous-match (arg)
1007   "Go to the ARGth previous matching page."
1008   (interactive "p")
1009   (let* ((prev-pages (doc-view-remove-if
1010                       (lambda (i) (>= (car i) (doc-view-current-page)))
1011                       doc-view-current-search-matches))
1012          (page (car (nth (1- arg) (nreverse prev-pages)))))
1013     (if page
1014         (doc-view-goto-page page)
1015       (when (and
1016              doc-view-current-search-matches
1017              (y-or-n-p "No more matches before current page.  Wrap to last match? "))
1018         (doc-view-goto-page (caar (last doc-view-current-search-matches)))))))
1019
1020 ;;;; User interface commands and the mode
1021
1022 ;; (put 'doc-view-mode 'mode-class 'special)
1023
1024 (defun doc-view-already-converted-p ()
1025   "Return non-nil if the current doc was already converted."
1026   (and (file-exists-p (doc-view-current-cache-dir))
1027        (> (length (directory-files (doc-view-current-cache-dir) nil "\\.png$")) 0)))
1028
1029 (defun doc-view-initiate-display ()
1030   ;; Switch to image display if possible
1031   (if (doc-view-mode-p doc-view-doc-type)
1032       (progn
1033         (doc-view-buffer-message)
1034         (setf (doc-view-current-page) (or (doc-view-current-page) 1))
1035         (if (doc-view-already-converted-p)
1036             (progn
1037               (message "DocView: using cached files!")
1038               (doc-view-display (current-buffer) 'force))
1039           (doc-view-convert-current-doc))
1040         (message
1041          "%s"
1042          (substitute-command-keys
1043           (concat "Type \\[doc-view-toggle-display] to toggle between "
1044                   "editing or viewing the document."))))
1045     (message
1046      "%s"
1047      (substitute-command-keys
1048       (concat "No image (png) support available or some conversion utility for "
1049               (file-name-extension doc-view-buffer-file-name)" files is missing.  "
1050               "Type \\[doc-view-toggle-display] to switch to an editing mode or "
1051               "\\[doc-view-open-text] to open a buffer showing the doc as text.")))))
1052
1053 (defvar bookmark-make-record-function)
1054
1055 (defun doc-view-clone-buffer-hook ()
1056   ;; FIXME: There are several potential problems linked with reconversion
1057   ;; and auto-revert when we have indirect buffers because they share their
1058   ;; /tmp cache directory.  This sharing is good (you'd rather not reconvert
1059   ;; for each clone), but that means that clones need to collaborate a bit.
1060   ;; I guess it mostly means: detect when a reconversion process is already
1061   ;; running, and run the sentinel in all clones.
1062   ;;
1063   ;; Maybe the clones should really have a separate /tmp directory
1064   ;; so they could have a different resolution and you could use clones
1065   ;; for zooming.
1066   (remove-overlays (point-min) (point-max) 'doc-view t)
1067   (if (consp image-mode-winprops-alist) (setq image-mode-winprops-alist nil)))
1068
1069 (defun doc-view-intersection (l1 l2)
1070   (let ((l ()))
1071     (dolist (x l1) (if (memq x l2) (push x l)))
1072     l))
1073
1074 ;;;###autoload
1075 (defun doc-view-mode ()
1076   "Major mode in DocView buffers.
1077 You can use \\<doc-view-mode-map>\\[doc-view-toggle-display] to
1078 toggle between displaying the document or editing it as text.
1079 \\{doc-view-mode-map}"
1080   (interactive)
1081
1082   (let* ((prev-major-mode (if (eq major-mode 'doc-view-mode)
1083                               doc-view-previous-major-mode
1084                             major-mode)))
1085     (kill-all-local-variables)
1086     (set (make-local-variable 'doc-view-previous-major-mode) prev-major-mode))
1087
1088   ;; Figure out the document type.
1089   (let ((name-types
1090          (when buffer-file-name
1091            (cdr (assoc (file-name-extension buffer-file-name)
1092                        '(("dvi" dvi)
1093                          ("pdf" pdf)
1094                          ("epdf" pdf)
1095                          ("ps" ps)
1096                          ("eps" ps))))))
1097         (content-types
1098          (save-excursion
1099            (goto-char (point-min))
1100            (cond
1101             ((looking-at "%!") '(ps))
1102             ((looking-at "%PDF") '(pdf))
1103             ((looking-at "\367\002") '(dvi))))))
1104     (set (make-local-variable 'doc-view-doc-type)
1105          (car (or (doc-view-intersection name-types content-types)
1106                   (when (and name-types content-types)
1107                     (error "Conflicting types: name says %s but content says %s"
1108                            name-types content-types))
1109                   name-types content-types
1110                   (error "Cannot determine the document type")))))
1111
1112   (doc-view-make-safe-dir doc-view-cache-directory)
1113   ;; Handle compressed files, remote files, files inside archives
1114   (set (make-local-variable 'doc-view-buffer-file-name)
1115        (cond
1116         (jka-compr-really-do-compress
1117          (expand-file-name
1118           (file-name-nondirectory
1119            (file-name-sans-extension buffer-file-name))
1120           doc-view-cache-directory))
1121         ;; Is the file readable by local processes?
1122         ;; We used to use `file-remote-p' but it's unclear what it's
1123         ;; supposed to return nil for things like local files accessed via
1124         ;; `su' or via file://...
1125         ((let ((file-name-handler-alist nil))
1126            (not (file-readable-p buffer-file-name)))
1127          (expand-file-name
1128           (file-name-nondirectory buffer-file-name)
1129           doc-view-cache-directory))
1130         (t buffer-file-name)))
1131   (when (not (string= doc-view-buffer-file-name buffer-file-name))
1132     (write-region nil nil doc-view-buffer-file-name))
1133
1134   (add-hook 'change-major-mode-hook
1135             (lambda ()
1136               (doc-view-kill-proc)
1137               (remove-overlays (point-min) (point-max) 'doc-view t))
1138             nil t)
1139   (add-hook 'clone-indirect-buffer-hook 'doc-view-clone-buffer-hook nil t)
1140   (add-hook 'kill-buffer 'doc-view-kill-proc nil t)
1141
1142   (remove-overlays (point-min) (point-max) 'doc-view t) ;Just in case.
1143   ;; Keep track of display info ([vh]scroll, page number, overlay, ...)
1144   ;; for each window in which this document is shown.
1145   (add-hook 'image-mode-new-window-functions
1146             'doc-view-new-window-function nil t)
1147   (image-mode-setup-winprops)
1148
1149   (set (make-local-variable 'mode-line-position)
1150        '(" P" (:eval (number-to-string (doc-view-current-page)))
1151          "/" (:eval (number-to-string (length doc-view-current-files)))))
1152   ;; Don't scroll unless the user specifically asked for it.
1153   (set (make-local-variable 'auto-hscroll-mode) nil)
1154   (set (make-local-variable 'cursor-type) nil)
1155   (use-local-map doc-view-mode-map)
1156   (set (make-local-variable 'after-revert-hook) 'doc-view-reconvert-doc)
1157   (set (make-local-variable 'bookmark-make-record-function)
1158        'doc-view-bookmark-make-record)
1159   (setq mode-name "DocView"
1160         buffer-read-only t
1161         major-mode 'doc-view-mode)
1162   (doc-view-initiate-display)
1163   (run-mode-hooks 'doc-view-mode-hook))
1164
1165 ;;;###autoload
1166 (define-minor-mode doc-view-minor-mode
1167   "Toggle Doc view minor mode.
1168 With arg, turn Doc view minor mode on if arg is positive, off otherwise.
1169 See the command `doc-view-mode' for more information on this mode."
1170   nil " DocView" doc-view-minor-mode-map
1171   :group 'doc-view
1172   (when doc-view-minor-mode
1173     (add-hook 'change-major-mode-hook (lambda () (doc-view-minor-mode -1)) nil t)
1174     (message
1175      "%s"
1176      (substitute-command-keys
1177       "Type \\[doc-view-toggle-display] to toggle between editing or viewing the document."))))
1178
1179 (defun doc-view-clear-cache ()
1180   "Delete the whole cache (`doc-view-cache-directory')."
1181   (interactive)
1182   (dired-delete-file doc-view-cache-directory 'always))
1183
1184 (defun doc-view-dired-cache ()
1185   "Open `dired' in `doc-view-cache-directory'."
1186   (interactive)
1187   (dired doc-view-cache-directory))
1188
1189
1190 ;;;; Bookmark integration
1191
1192 (declare-function bookmark-make-record-default "bookmark"
1193                   (&optional point-only))
1194 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
1195 (declare-function bookmark-default-handler "bookmark" (bmk))
1196
1197 (defun doc-view-bookmark-make-record ()
1198   (nconc (bookmark-make-record-default)
1199          `((page     . ,(doc-view-current-page))
1200            (handler  . doc-view-bookmark-jump))))
1201
1202
1203 ;;;###autoload
1204 (defun doc-view-bookmark-jump (bmk)
1205   ;; This implements the `handler' function interface for record type
1206   ;; returned by `doc-view-bookmark-make-record', which see.
1207   (prog1 (bookmark-default-handler bmk)
1208     (let ((page (bookmark-prop-get bmk 'page)))
1209       (when (not (eq major-mode 'doc-view-mode))
1210         (doc-view-toggle-display))
1211       (with-selected-window
1212           (or (get-buffer-window (current-buffer) 0)
1213               (selected-window))
1214         (doc-view-goto-page page)))))
1215
1216
1217 (provide 'doc-view)
1218
1219 ;; Local Variables:
1220 ;; mode: outline-minor
1221 ;; End:
1222
1223 ;; arch-tag: 5d6e5c5e-095f-489e-b4e4-1ca90a7d79be
1224 ;;; doc-view.el ends here