configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 3, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.61)dnl
  27 AC_INIT(emacs, 23.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" = yes; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" = yes; then
  88   if test "${with_kerberos}" != yes; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 if test "$with_hesiod" = yes; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 101
 102 dnl FIXME currently it is not the last.
 103 dnl This should be the last --with option, because --with-x is
 104 dnl added later on when we find the path of X, and it's best to
 105 dnl keep them together visually.
 106 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 107  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 108 [         case "${withval}" in
 109             y | ye | yes )      val=gtk ;;
 110             n | no )            val=no  ;;
 111             l | lu | luc | luci | lucid )       val=lucid ;;
 112             a | at | ath | athe | athen | athena )      val=athena ;;
 113             m | mo | mot | moti | motif )       val=motif ;;
 114             g | gt | gtk  )     val=gtk ;;
 115             * )
 116 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 117 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 118 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 119             ;;
 120           esac
 121           with_x_toolkit=$val
 122 ])
 123
 124 dnl _ON results in a '--without' option in the --help output, so
 125 dnl the help text should refer to "don't compile", etc.
 126 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 127 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 128 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 129 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 130 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 131 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 132
 133 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 134 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 135 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 136 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 137
 138 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 139 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 140 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 141 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 142
 143 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 144 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 145
 146 dnl Can remove these in Emacs 24.
 147 AC_ARG_WITH([gtk],,
 148   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 149 specify a toolkit.]),,)
 150
 151 AC_ARG_WITH([gcc],,
 152   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 153   variable to specify a compiler.]),,)
 154
 155 AC_ARG_WITH([pkg-config-prog],dnl
 156 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 157                   [Path to pkg-config for finding GTK and librsvg])])
 158 if test "X${with_pkg_config_prog}" != X; then
 159    if test "${with_pkg_config_prog}" != yes; then
 160       PKG_CONFIG="${with_pkg_config_prog}"
 161    fi
 162 fi
 163
 164 AC_ARG_ENABLE(carbon-app,
 165 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 166                 [specify install directory for Emacs.app on Mac OS X
 167                  [DIR=/Application]])],
 168 [ carbon_appdir_x=${enableval}])
 169
 170 AC_ARG_ENABLE(font-backend,
 171 [  --enable-font-backend   compile code of font-backend support],
 172       USE_FONT_BACKEND=$enableval,
 173       USE_FONT_BACKEND=no)
 174
 175 AC_ARG_ENABLE(asserts,
 176 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 177       USE_XASSERTS=$enableval,
 178       USE_XASSERTS=no)
 179
 180 AC_ARG_ENABLE(maintainer-mode,
 181 [AS_HELP_STRING([--enable-maintainer-mode],
 182                 [enable make rules and dependencies not useful (and sometimes
 183                  confusing) to the casual installer])],
 184       USE_MAINTAINER_MODE=$enableval,
 185       USE_MAINTAINER_MODE=no)
 186 if test $USE_MAINTAINER_MODE = yes; then
 187   MAINT=
 188 else
 189   MAINT=#
 190 fi
 191 AC_SUBST(MAINT)
 192
 193 AC_ARG_ENABLE(locallisppath,
 194 [AS_HELP_STRING([--enable-locallisppath=PATH],
 195                 [directories Emacs should search for lisp files specific
 196                  to this site])],
 197 if test "${enableval}" = "no"; then
 198   locallisppath=
 199 elif test "${enableval}" != "yes"; then
 200   locallisppath=${enableval}
 201 fi)
 202
 203 #### Make srcdir absolute, if it isn't already.  It's important to
 204 #### avoid running the path through pwd unnecessarily, since pwd can
 205 #### give you automounter prefixes, which can go away.  We do all this
 206 #### so Emacs can find its files when run uninstalled.
 207 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 208 unset CDPATH
 209 case "${srcdir}" in
 210   /* ) ;;
 211   . )
 212     ## We may be able to use the $PWD environment variable to make this
 213     ## absolute.  But sometimes PWD is inaccurate.
 214     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 215     ## but that tested only for a well-formed and valid PWD,
 216     ## it did not object when PWD was well-formed and valid but just wrong.
 217     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 218     then
 219       srcdir="$PWD"
 220     else
 221       srcdir="`(cd ${srcdir}; pwd)`"
 222     fi
 223   ;;
 224   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 225 esac
 226
 227 #### Check if the source directory already has a configured system in it.
 228 if test `pwd` != `(cd ${srcdir} && pwd)` \
 229    && test -f "${srcdir}/src/config.h" ; then
 230   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 231    as a build directory right now; it has been configured in its own
 232    right.  To configure in another directory as well, you MUST
 233    use GNU make.  If you do not have GNU make, then you must
 234    now do `make distclean' in ${srcdir},
 235    and then run $0 again.]])
 236 fi
 237
 238 #### Given the configuration name, set machfile and opsysfile to the
 239 #### names of the m/*.h and s/*.h files we should use.
 240
 241 ### Canonicalize the configuration name.
 242
 243 AC_CANONICAL_HOST
 244 canonical=$host
 245 configuration=${host_alias-${build_alias-$host}}
 246
 247 dnl This used to use changequote, but, apart from `changequote is evil'
 248 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 249 dnl the great gob of text.  Thus it's not processed for possible expansion.
 250 dnl Just make sure the brackets remain balanced.
 251 dnl
 252 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 253 dnl indicated by comments.
 254 dnl quotation begins
 255 [
 256
 257 ### If you add support for a new configuration, add code to this
 258 ### switch statement to recognize your configuration name and select
 259 ### the appropriate operating system and machine description files.
 260
 261 ### You would hope that you could choose an m/*.h file pretty much
 262 ### based on the machine portion of the configuration name, and an s-
 263 ### file based on the operating system portion.  However, it turns out
 264 ### that each m/*.h file is pretty manufacturer-specific - for
 265 ### example hp9000s300.h is a 68000 machine;
 266 ### mips.h, pmax.h are all MIPS
 267 ### machines.  So we basically have to have a special case for each
 268 ### configuration name.
 269 ###
 270 ### As far as handling version numbers on operating systems is
 271 ### concerned, make sure things will fail in a fixable way.  If
 272 ### /etc/MACHINES doesn't say anything about version numbers, be
 273 ### prepared to handle anything reasonably.  If version numbers
 274 ### matter, be sure /etc/MACHINES says something about it.
 275 ###
 276 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 277 ### "System V Release 4"; he writes, "The old convention encouraged
 278 ### confusion between `system' and `release' levels'."
 279
 280 machine='' opsys='' unported=no
 281 case "${canonical}" in
 282
 283   ## FreeBSD ports
 284   *-*-freebsd* )
 285     opsys=freebsd
 286     case "${canonical}" in
 287       alpha*-*-freebsd*)        machine=alpha ;;
 288       arm*-*-freebsd*)          machine=arm ;;
 289       ia64-*-freebsd*)          machine=ia64 ;;
 290       sparc64-*-freebsd*)       machine=sparc ;;
 291       powerpc-*-freebsd*)       machine=macppc ;;
 292       i[3456]86-*-freebsd*)     machine=intel386 ;;
 293       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 294     esac
 295   ;;
 296
 297   ## FreeBSD kernel + glibc based userland
 298   *-*-kfreebsd*gnu* )
 299     opsys=gnu-kfreebsd
 300     case "${canonical}" in
 301       alpha*-*-kfreebsd*)       machine=alpha ;;
 302       ia64-*-kfreebsd*)         machine=ia64 ;;
 303       sparc64-*-kfreebsd*)      machine=sparc ;;
 304       powerpc-*-kfreebsd*)      machine=macppc ;;
 305       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 306       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 307     esac
 308   ;;
 309
 310   ## NetBSD ports
 311   *-*-netbsd* )
 312     opsys=netbsd
 313     if test -f /usr/lib/crti.o; then]
 314 dnl The close and open brackets here are because this section is quoted --
 315 dnl see the `changequote' comment above.
 316       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 317 [   fi
 318
 319     case "${canonical}" in
 320       alpha*-*-netbsd*) machine=alpha ;;
 321       i[3456]86-*-netbsd*) machine=intel386 ;;
 322       m68k-*-netbsd*)
 323                         # This is somewhat bogus.
 324                         machine=hp9000s300 ;;
 325       mips-*-netbsd*)   machine=pmax ;;
 326       mipsel-*-netbsd*) machine=pmax ;;
 327       mipseb-*-netbsd*) machine=pmax ;;
 328       powerpc-*-netbsd*) machine=macppc ;;
 329       sparc*-*-netbsd*) machine=sparc ;;
 330       vax-*-netbsd*)    machine=vax ;;
 331       arm-*-netbsd*)    machine=arm ;;
 332       x86_64-*-netbsd*) machine=amdx86-64 ;;
 333       hppa-*-netbsd*)   machine=hp800 ;;
 334     esac
 335   ;;
 336
 337   ## OpenBSD ports
 338   *-*-openbsd* )
 339     opsys=openbsd
 340     case "${canonical}" in
 341       alpha*-*-openbsd*)        machine=alpha ;;
 342       arm-*-openbsd*)          machine=arm ;;
 343       hppa-*-openbsd*)         machine=hp9000s300 ;;
 344       i386-*-openbsd*)         machine=intel386 ;;
 345       m68k-*-openbsd*)         machine=hp9000s300 ;;
 346       mips64-*-openbsd*)       machine=mips64 ;;
 347       powerpc-*-openbsd*)      machine=macppc ;;
 348       sparc*-*-openbsd*)       machine=sparc ;;
 349       vax-*-openbsd*)          machine=vax ;;
 350       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 351     esac
 352   ;;
 353
 354   ## LynxOS ports
 355   *-*-lynxos* )
 356     opsys=lynxos
 357     case "${canonical}" in
 358       i[3456]86-*-lynxos*) machine=intel386 ;;
 359       powerpc-*-lynxos*) machine=powerpc ;;
 360     esac
 361   ;;
 362
 363   ## BSDI ports
 364   *-*-bsdi* )
 365     opsys=bsdi
 366     case "${canonical}" in
 367       i[345]86-*-bsdi*) machine=intel386 ;;
 368       sparc-*-bsdi*)  machine=sparc ;;
 369       powerpc-*-bsdi*)  machine=macppc ;;
 370     esac
 371     case "${canonical}" in
 372       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 373       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 374       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 375       *-*-bsdi3* )              opsys=bsdos3 ;;
 376       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 377     esac
 378   ;;
 379
 380   ## Alpha (DEC) machines.
 381   alpha*-dec-osf* )
 382     machine=alpha opsys=osf1
 383     # This is needed to find X11R6.1 libraries for certain tests.
 384     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 385     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 386     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 387     # due to non-traditional preprocessing with the current compiler
 388     # defaults.  OSF 4 can also have that compiler version, and there
 389     # seems always to have been a usable /usr/bin/cpp.
 390     NON_GNU_CPP=/usr/bin/cpp
 391     case "${canonical}" in
 392     alpha*-dec-osf[5-9]*)
 393       opsys=osf5-0 ;;
 394     esac
 395   ;;
 396
 397   alpha*-*-linux-gnu* )
 398     machine=alpha opsys=gnu-linux
 399   ;;
 400
 401   arm*-*-linux-gnu* )
 402     machine=arm opsys=gnu-linux
 403   ;;
 404
 405   ## Apple Darwin / Mac OS X
 406   *-apple-darwin* )
 407     case "${canonical}" in
 408       i[3456]86-* )  machine=intel386 ;;
 409       powerpc-* )    machine=powermac ;;
 410       * )            unported=yes ;;
 411     esac
 412     opsys=darwin
 413     # Define CPP as follows to make autoconf work correctly.
 414     CPP="${CC-cc} -E -no-cpp-precomp"
 415     # Use fink packages if available.
 416     if test -d /sw/include && test -d /sw/lib; then
 417       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 418       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 419       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 420     fi
 421   ;;
 422
 423   ## Compaq Nonstop
 424   mips-compaq-nonstopux* )
 425     machine=nonstopux opsys=nonstopux
 426     ;;
 427
 428   ## Cubix QBx/386
 429   i[3456]86-cubix-sysv* )
 430     machine=intel386 opsys=usg5-3
 431   ;;
 432
 433   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 434     machine=pmax opsys=bsd4-2
 435   ;;
 436   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 437     machine=pmax opsys=bsd4-3
 438   ;;
 439   mips-dec-ultrix* )
 440     machine=pmax opsys=ultrix4-3
 441   ;;
 442   mips-dec-osf* )
 443     machine=pmax opsys=osf1
 444   ;;
 445   mips-dec-mach_bsd4.3* )
 446     machine=pmax opsys=mach-bsd4-3
 447   ;;
 448
 449   ## HP 9000 series 200 or 300
 450   m68*-hp-bsd* )
 451     machine=hp9000s300 opsys=bsd4-3
 452   ;;
 453   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 454   m68*-hp-hpux* )
 455     case "`uname -r`" in
 456       ## Someone's system reports A.B8.05 for this.
 457       ## I wonder what other possibilities there are.
 458       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 459       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 460       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 461       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 462       *) machine=hp9000s300 opsys=hpux ;;
 463     esac
 464   ;;
 465
 466   ## HP 9000 series 700 and 800, running HP/UX
 467   hppa*-hp-hpux7* )
 468     machine=hp800 opsys=hpux
 469   ;;
 470   hppa*-hp-hpux8* )
 471     machine=hp800 opsys=hpux8
 472   ;;
 473   hppa*-hp-hpux9shr* )
 474     machine=hp800 opsys=hpux9shr
 475   ;;
 476   hppa*-hp-hpux9* )
 477     machine=hp800 opsys=hpux9
 478   ;;
 479   hppa*-hp-hpux10.2* )
 480     machine=hp800 opsys=hpux10-20
 481   ;;
 482   hppa*-hp-hpux10* )
 483     machine=hp800 opsys=hpux10
 484   ;;
 485   hppa*-hp-hpux1[1-9]* )
 486     machine=hp800 opsys=hpux11
 487     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 488   ;;
 489
 490   hppa*-*-linux-gnu* )
 491     machine=hp800 opsys=gnu-linux
 492   ;;
 493
 494   ## HP 9000 series 700 and 800, running HP/UX
 495   hppa*-hp-hpux* )
 496     ## Cross-compilation?  Nah!
 497     case "`uname -r`" in
 498       ## Someone's system reports A.B8.05 for this.
 499       ## I wonder what other possibilities there are.
 500       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 501       *.08.* ) machine=hp800 opsys=hpux8 ;;
 502       *.09.* ) machine=hp800 opsys=hpux9 ;;
 503       *) machine=hp800 opsys=hpux10 ;;
 504     esac
 505   ;;
 506   hppa*-*-nextstep* )
 507     machine=hp800 opsys=nextstep
 508   ;;
 509
 510   ## IBM machines
 511   i370-ibm-aix*)
 512     machine=ibm370aix opsys=usg5-3
 513   ;;
 514   s390-*-linux-gnu* )
 515     machine=ibms390 opsys=gnu-linux
 516   ;;
 517   s390x-*-linux-gnu* )
 518     machine=ibms390x opsys=gnu-linux
 519   ;;
 520   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 521     machine=ibmrs6000 opsys=aix3-1
 522   ;;
 523   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 524     machine=ibmrs6000 opsys=aix3-2-5
 525   ;;
 526   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 527     machine=ibmrs6000 opsys=aix4-1
 528   ;;
 529   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 530     machine=ibmrs6000 opsys=aix4-2
 531   ;;
 532   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 533     machine=ibmrs6000 opsys=aix4-2
 534   ;;
 535   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 536     machine=ibmrs6000 opsys=aix4-2
 537   ;;
 538   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 539     machine=ibmrs6000 opsys=aix4
 540   ;;
 541   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 542     machine=ibmrs6000 opsys=aix4-1
 543   ;;
 544   rs6000-ibm-aix* | powerpc-ibm-aix* )
 545     machine=ibmrs6000 opsys=aix3-2
 546   ;;
 547
 548   ## Prime EXL
 549   i[3456]86-prime-sysv* )
 550     machine=i386 opsys=usg5-3
 551   ;;
 552
 553   ## ncr machine running svr4.3.
 554   i[3456]86-ncr-sysv4.3 )
 555     machine=ncr386 opsys=usg5-4-3
 556   ;;
 557
 558   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 559   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 560   i[3456]86-ncr-sysv* )
 561     machine=ncr386 opsys=usg5-4-2
 562   ;;
 563
 564   ## Macintosh PowerPC
 565   powerpc*-*-linux-gnu* )
 566     machine=macppc opsys=gnu-linux
 567   ;;
 568
 569   ## Workstations sold by MIPS
 570   ## This is not necessarily all workstations using the MIPS processor -
 571   ## Irises are produced by SGI, and DECstations by DEC.
 572
 573   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 574   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 575   ## it gives for choosing between the alternatives seems to be "Use
 576   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 577   ## the BSD world."  I'll assume that these are instructions for
 578   ## handling two odd situations, and that every other situation
 579   ## should use mips.h and usg5-2-2, they being listed first.
 580   mips-mips-usg* )
 581     machine=mips4
 582     ## Fall through to the general code at the bottom to decide on the OS.
 583   ;;
 584   mips-mips-riscos4* )
 585     machine=mips4 opsys=bsd4-3
 586     NON_GNU_CC="cc -systype bsd43"
 587     NON_GNU_CPP="cc -systype bsd43 -E"
 588   ;;
 589   mips-mips-riscos5* )
 590     machine=mips4 opsys=riscos5
 591     NON_GNU_CC="cc -systype bsd43"
 592     NON_GNU_CPP="cc -systype bsd43 -E"
 593   ;;
 594   mips-mips-bsd* )
 595     machine=mips opsys=bsd4-3
 596   ;;
 597   mips-mips-* )
 598     machine=mips opsys=usg5-2-2
 599   ;;
 600
 601   ## NeXT
 602   m68*-next-* | m68k-*-nextstep* )
 603     machine=m68k opsys=nextstep
 604   ;;
 605
 606   ## NEC EWS4800
 607   mips-nec-sysv4*)
 608   machine=ews4800 opsys=ux4800
 609   ;;
 610
 611   ## Siemens Nixdorf
 612   mips-siemens-sysv* | mips-sni-sysv*)
 613     machine=mips-siemens opsys=usg5-4
 614     NON_GNU_CC=/usr/ccs/bin/cc
 615     NON_GNU_CPP=/usr/ccs/lib/cpp
 616   ;;
 617
 618   ## Silicon Graphics machines
 619   ## Iris 4D
 620   mips-sgi-irix6.5 )
 621     machine=iris4d opsys=irix6-5
 622     # Without defining _LANGUAGE_C, things get masked out in the headers
 623     # so that, for instance, grepping for `free' in stdlib.h fails and
 624     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 625     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 626     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 627   ;;
 628   mips-sgi-irix6* )
 629     machine=iris4d opsys=irix6-0
 630     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 631     # but presumably it does no harm.
 632     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 633     # -32 probably isn't necessary in later v.6s -- anyone know which?
 634     NON_GCC_TEST_OPTIONS=-32
 635   ;;
 636   mips-sgi-irix5.[01]* )
 637     machine=iris4d opsys=irix5-0
 638   ;;
 639   mips-sgi-irix5* | mips-sgi-irix* )
 640     machine=iris4d opsys=irix5-2
 641   ;;
 642
 643   ## Suns
 644   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 645     machine=sparc opsys=gnu-linux
 646   ;;
 647
 648   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 649     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 650     | rs6000-*-solaris2*)
 651     case "${canonical}" in
 652       i[3456]86-*-* )     machine=intel386 ;;
 653       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 654       powerpcle* )      machine=powerpcle ;;
 655       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 656       sparc* )          machine=sparc ;;
 657       * )               unported=yes ;;
 658     esac
 659     case "${canonical}" in
 660       *-sunos5.3* | *-solaris2.3* )
 661                 opsys=sol2-3
 662                 NON_GNU_CPP=/usr/ccs/lib/cpp
 663                 ;;
 664       *-sunos5.4* | *-solaris2.4* )
 665                 opsys=sol2-4
 666                 NON_GNU_CPP=/usr/ccs/lib/cpp
 667                 RANLIB="ar -ts"
 668                 ;;
 669       *-sunos5.5* | *-solaris2.5* )
 670                 opsys=sol2-5
 671                 NON_GNU_CPP=/usr/ccs/lib/cpp
 672                 RANLIB="ar -ts"
 673                 ;;
 674       *-sunos5.6* | *-solaris2.6* )
 675                 opsys=sol2-6
 676                 NON_GNU_CPP=/usr/ccs/lib/cpp
 677                 RANLIB="ar -ts"
 678                 ;;
 679       *-sunos5* | *-solaris* )
 680                 opsys=sol2-6
 681                 emacs_check_sunpro_c=yes
 682                 NON_GNU_CPP=/usr/ccs/lib/cpp
 683                 ;;
 684       *                   ) opsys=bsd4-2   ;;
 685     esac
 686     ## Watch out for a compiler that we know will not work.
 687     case "${canonical}" in
 688      *-solaris* | *-sunos5* )
 689                 if [ "x$CC" = x/usr/ucb/cc ]; then
 690                   ## /usr/ucb/cc doesn't work;
 691                   ## we should find some other compiler that does work.
 692                   unset CC
 693                 fi
 694                 ;;
 695       *) ;;
 696     esac
 697   ;;
 698   sparc-*-nextstep* )
 699     machine=sparc opsys=nextstep
 700   ;;
 701
 702   ## Tandem Integrity S2
 703   mips-tandem-sysv* )
 704     machine=tandem-s2 opsys=usg5-3
 705   ;;
 706
 707   ## Vaxen.
 708   vax-dec-* )
 709     machine=vax
 710     case "${canonical}" in
 711       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 712       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 713       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 714       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 715       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 716       *-vms* )                                          opsys=vms ;;
 717       * )                                               unported=yes
 718     esac
 719   ;;
 720
 721   ## IA-64
 722   ia64*-*-linux* )
 723     machine=ia64 opsys=gnu-linux
 724   ;;
 725
 726   ## Intel 386 machines where we don't care about the manufacturer
 727   i[3456]86-*-* )
 728     machine=intel386
 729     case "${canonical}" in
 730       *-cygwin )                opsys=cygwin ;;
 731       *-darwin* )               opsys=darwin
 732                                 CPP="${CC-cc} -E -no-cpp-precomp"
 733                                 ;;
 734       *-xenix* )                opsys=xenix ;;
 735       *-linux-gnu* )            opsys=gnu-linux ;;
 736       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 737       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 738       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 739       *-386bsd* )               opsys=386bsd ;;
 740       *-nextstep* )             opsys=nextstep ;;
 741       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 742     esac
 743   ;;
 744
 745   ## m68k Linux-based GNU system
 746   m68k-*-linux-gnu* )
 747     machine=m68k opsys=gnu-linux
 748   ;;
 749
 750   ## Mips Linux-based GNU system
 751   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 752     machine=mips opsys=gnu-linux
 753   ;;
 754
 755   ## UXP/DS
 756   sparc-fujitsu-sysv4* )
 757     machine=sparc opsys=uxpds
 758     NON_GNU_CPP=/usr/ccs/lib/cpp
 759     RANLIB="ar -ts"
 760   ;;
 761
 762   ## AMD x86-64 Linux-based GNU system
 763   x86_64-*-linux-gnu* )
 764     machine=amdx86-64 opsys=gnu-linux
 765   ;;
 766
 767   ## Tensilica Xtensa Linux-based GNU system
 768   xtensa*-*-linux-gnu* )
 769     machine=xtensa opsys=gnu-linux
 770     ;;
 771
 772   * )
 773     unported=yes
 774   ;;
 775 esac
 776
 777 ### If the code above didn't choose an operating system, just choose
 778 ### an operating system based on the configuration name.  You really
 779 ### only want to use this when you have no idea what the right
 780 ### operating system is; if you know what operating systems a machine
 781 ### runs, it's cleaner to make it explicit in the case statement
 782 ### above.
 783 if test x"${opsys}" = x; then
 784   case "${canonical}" in
 785     *-gnu* )                            opsys=gnu ;;
 786     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 787     *-bsd4.2 )                          opsys=bsd4-2 ;;
 788     *-bsd4.3 )                          opsys=bsd4-3 ;;
 789     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 790     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 791     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 792     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 793     *-sysv4.2uw* )                      opsys=unixware ;;
 794     *-sysv5uw* )                        opsys=unixware ;;
 795     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 796     *-sysv4.1* | *-sysvr4.1* )
 797         NON_GNU_CPP=/usr/lib/cpp
 798         opsys=usg5-4 ;;
 799     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 800         if [ x$NON_GNU_CPP = x ]; then
 801           if [ -f /usr/ccs/lib/cpp ]; then
 802             NON_GNU_CPP=/usr/ccs/lib/cpp
 803           else
 804             NON_GNU_CPP=/lib/cpp
 805           fi
 806         fi
 807         opsys=usg5-4-2 ;;
 808     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 809     * )
 810       unported=yes
 811     ;;
 812   esac
 813 fi
 814
 815 ]
 816 dnl quotation ends
 817
 818 if test $unported = yes; then
 819   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 820 Check `etc/MACHINES' for recognized configuration names.])
 821 fi
 822
 823 machfile="m/${machine}.h"
 824 opsysfile="s/${opsys}.h"
 825
 826
 827 #### Choose a compiler.
 828 test -n "$CC" && cc_specified=yes
 829
 830 # Save the value of CFLAGS that the user specified.
 831 SPECIFIED_CFLAGS="$CFLAGS"
 832
 833 dnl Sets GCC=yes if using gcc.
 834 AC_PROG_CC
 835
 836 # On Suns, sometimes $CPP names a directory.
 837 if test -n "$CPP" && test -d "$CPP"; then
 838   CPP=
 839 fi
 840
 841 ## If not using gcc, and on Solaris, and no CPP specified, see if
 842 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 843 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 844  test x"$CPP" = x; then
 845   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 846   AC_CACHE_VAL(emacs_cv_sunpro_c,
 847   [AC_TRY_LINK([],
 848 [#ifndef __SUNPRO_C
 849 fail;
 850 #endif
 851 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 852   AC_MSG_RESULT($emacs_cv_sunpro_c)
 853
 854   if test x"$emacs_cv_sunpro_c" = xyes; then
 855     NON_GNU_CPP="$CC -E -Xs"
 856   fi
 857 fi
 858
 859 #### Some systems specify a CPP to use unless we are using GCC.
 860 #### Now that we know whether we are using GCC, we can decide whether
 861 #### to use that one.
 862 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 863 then
 864   CPP="$NON_GNU_CPP"
 865 fi
 866
 867 #### Some systems specify a CC to use unless we are using GCC.
 868 #### Now that we know whether we are using GCC, we can decide whether
 869 #### to use that one.
 870 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 871   test x$cc_specified != xyes
 872 then
 873   CC="$NON_GNU_CC"
 874 fi
 875
 876 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 877 then
 878   CC="$CC $GCC_TEST_OPTIONS"
 879 fi
 880
 881 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 882 then
 883   CC="$CC $NON_GCC_TEST_OPTIONS"
 884 fi
 885
 886 dnl checks for Unix variants
 887 AC_AIX
 888 AC_GNU_SOURCE
 889
 890 ### Use -Wno-pointer-sign if the compiler supports it
 891 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 892 SAVE_CFLAGS="$CFLAGS"
 893 CFLAGS="$CFLAGS -Wno-pointer-sign"
 894 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 895 if test $has_option = yes; then
 896    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 897 fi
 898 AC_MSG_RESULT($has_option)
 899 CFLAGS="$SAVE_CFLAGS"
 900 unset has_option
 901 unset SAVE_CFLAGS
 902
 903 #### Some other nice autoconf tests.
 904
 905 dnl checks for programs
 906 AC_PROG_LN_S
 907 AC_PROG_CPP
 908 AC_PROG_INSTALL
 909 if test "x$RANLIB" = x; then
 910   AC_PROG_RANLIB
 911 fi
 912 AC_PATH_PROG(INSTALL_INFO, install-info)
 913 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 914 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 915 dnl Don't use GZIP, which is used by gzip for additional parameters.
 916 AC_PATH_PROG(GZIP_PROG, gzip)
 917
 918
 919 ## Need makeinfo >= 4.6 (?) to build the manuals.
 920 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 921 dnl By this stage, configure has already checked for egrep and set EGREP,
 922 dnl or exited with an error if no egrep was found.
 923 if test "$MAKEINFO" != "no" && \
 924   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 925    MAKEINFO=no
 926 fi
 927
 928 if test "$MAKEINFO" = "no"; then
 929   AC_MSG_ERROR( [makeinfo >= 4.6 is required] )
 930 fi
 931
 932
 933 dnl Add our options to ac_link now, after it is set up.
 934
 935 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 936 then
 937   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 938 fi
 939
 940 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 941 then
 942   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 943 fi
 944
 945 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 946 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 947 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 948 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 949 dnl if not built to support GNU ld.
 950
 951 late_LDFLAGS=$LDFLAGS
 952 if test "$GCC" = yes; then
 953   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 954 else
 955   LDFLAGS="$LDFLAGS -znocombreloc"
 956 fi
 957
 958 AC_MSG_CHECKING([for -znocombreloc])
 959 AC_LINK_IFELSE([main(){return 0;}],
 960   [AC_MSG_RESULT(yes)],
 961   LDFLAGS=$late_LDFLAGS
 962   [AC_MSG_RESULT(no)])
 963
 964 #### Extract some information from the operating system and machine files.
 965
 966 AC_CHECKING([the machine- and system-dependent files to find out
 967  - which libraries the lib-src programs will want, and
 968  - whether the GNU malloc routines are usable])
 969
 970 ### First figure out CFLAGS (which we use for running the compiler here)
 971 ### and REAL_CFLAGS (which we use for real compilation).
 972 ### The two are the same except on a few systems, where they are made
 973 ### different to work around various lossages.  For example,
 974 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 975 ### as implying static linking.
 976
 977 ### If the CFLAGS env var is specified, we use that value
 978 ### instead of the default.
 979
 980 ### It's not important that this name contain the PID; you can't run
 981 ### two configures in the same directory and have anything work
 982 ### anyway.
 983 tempcname="conftest.c"
 984
 985 echo '
 986 #include "'${srcdir}'/src/'${opsysfile}'"
 987 #include "'${srcdir}'/src/'${machfile}'"
 988 #ifndef LIBS_MACHINE
 989 #define LIBS_MACHINE
 990 #endif
 991 #ifndef LIBS_SYSTEM
 992 #define LIBS_SYSTEM
 993 #endif
 994 #ifndef C_SWITCH_SYSTEM
 995 #define C_SWITCH_SYSTEM
 996 #endif
 997 #ifndef C_SWITCH_MACHINE
 998 #define C_SWITCH_MACHINE
 999 #endif
1000 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1001 configure___ c_switch_system=C_SWITCH_SYSTEM
1002 configure___ c_switch_machine=C_SWITCH_MACHINE
1003
1004 #ifndef LIB_X11_LIB
1005 #define LIB_X11_LIB -lX11
1006 #endif
1007
1008 #ifndef LIBX11_SYSTEM
1009 #define LIBX11_SYSTEM
1010 #endif
1011 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
1012
1013 #ifdef UNEXEC
1014 configure___ unexec=UNEXEC
1015 #else
1016 configure___ unexec=unexec.o
1017 #endif
1018
1019 #ifdef SYSTEM_MALLOC
1020 configure___ system_malloc=yes
1021 #else
1022 configure___ system_malloc=no
1023 #endif
1024
1025 #ifdef USE_MMAP_FOR_BUFFERS
1026 configure___ use_mmap_for_buffers=yes
1027 #else
1028 configure___ use_mmap_for_buffers=no
1029 #endif
1030
1031 #ifndef C_DEBUG_SWITCH
1032 #define C_DEBUG_SWITCH -g
1033 #endif
1034
1035 #ifndef C_OPTIMIZE_SWITCH
1036 #ifdef __GNUC__
1037 #define C_OPTIMIZE_SWITCH -O2
1038 #else
1039 #define C_OPTIMIZE_SWITCH -O
1040 #endif
1041 #endif
1042
1043 #ifndef C_WARNINGS_SWITCH
1044 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1045 #endif
1046
1047 #ifndef LD_SWITCH_MACHINE
1048 #define LD_SWITCH_MACHINE
1049 #endif
1050
1051 #ifndef LD_SWITCH_SYSTEM
1052 #define LD_SWITCH_SYSTEM
1053 #endif
1054
1055 #ifndef LD_SWITCH_X_SITE_AUX
1056 #define LD_SWITCH_X_SITE_AUX
1057 #endif
1058
1059 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1060 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1061
1062 #ifdef THIS_IS_CONFIGURE
1063
1064 /* Get the CFLAGS for tests in configure.  */
1065 #ifdef __GNUC__
1066 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1067 #else
1068 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1069 #endif
1070
1071 #else /* not THIS_IS_CONFIGURE */
1072
1073 /* Get the CFLAGS for real compilation.  */
1074 #ifdef __GNUC__
1075 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1076 #else
1077 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1078 #endif
1079
1080 #endif /* not THIS_IS_CONFIGURE */
1081 ' > ${tempcname}
1082
1083 # The value of CPP is a quoted variable reference, so we need to do this
1084 # to get its actual value...
1085 CPP=`eval "echo $CPP"`
1086 [eval `${CPP} -Isrc ${tempcname} \
1087        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1088 if test "x$SPECIFIED_CFLAGS" = x; then
1089   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1090          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1091 else
1092   REAL_CFLAGS="$CFLAGS"
1093 fi]
1094 rm ${tempcname}
1095
1096 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1097
1098 ### Make sure subsequent tests use flags consistent with the build flags.
1099
1100 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1101   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1102 else
1103   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1104 fi
1105
1106 dnl For AC_FUNC_GETLOADAVG, at least:
1107 AC_CONFIG_LIBOBJ_DIR(src)
1108
1109 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1110 AC_SYS_LARGEFILE
1111
1112
1113 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1114 ### be located in either /usr/lib64 or /usr/lib.
1115 case "${canonical}" in
1116   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1117     if test -d /usr/lib64; then
1118       AC_DEFINE(HAVE_LIB64_DIR, 1,
1119         [Define to 1 if the directory /usr/lib64 exists.])
1120 fi
1121 esac
1122
1123 dnl This function defintion taken from Gnome 2.0
1124 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1125 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1126 dnl also defines GSTUFF_PKG_ERRORS on error
1127 AC_DEFUN([PKG_CHECK_MODULES], [
1128   succeeded=no
1129
1130   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1131
1132   if test "$PKG_CONFIG" = "no" ; then
1133      ifelse([$4], , [AC_MSG_ERROR([
1134       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1135   else
1136      PKG_CONFIG_MIN_VERSION=0.9.0
1137      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1138         AC_MSG_CHECKING(for $2)
1139
1140         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1141             AC_MSG_RESULT(yes)
1142             succeeded=yes
1143
1144             AC_MSG_CHECKING($1_CFLAGS)
1145             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1146             AC_MSG_RESULT($$1_CFLAGS)
1147
1148             AC_MSG_CHECKING($1_LIBS)
1149             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1150             AC_MSG_RESULT($$1_LIBS)
1151         else
1152             AC_MSG_RESULT(no)
1153             $1_CFLAGS=""
1154             $1_LIBS=""
1155             ## If we have a custom action on failure, don't print errors, but
1156             ## do set a variable so people can do so.
1157             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1158             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1159         fi
1160
1161         AC_SUBST($1_CFLAGS)
1162         AC_SUBST($1_LIBS)
1163      else
1164         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1165         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1166      fi
1167   fi
1168
1169   if test $succeeded = yes; then
1170      ifelse([$3], , :, [$3])
1171   else
1172      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1173   fi
1174 ])
1175
1176
1177 if test "${with_sound}" != "no"; then
1178   # Sound support for GNU/Linux and the free BSDs.
1179   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1180   # Emulation library used on NetBSD.
1181   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1182   AC_SUBST(LIBSOUND)
1183
1184   ALSA_REQUIRED=1.0.0
1185   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1186   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1187   if test $HAVE_ALSA = yes; then
1188     SAVE_CFLAGS="$CFLAGS"
1189     SAVE_LDFLAGS="$LDFLAGS"
1190     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1191     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1192     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1193                     emacs_alsa_normal=yes,
1194                     emacs_alsa_normal=no)
1195     if test "$emacs_alsa_normal" != yes; then
1196       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1197                      [snd_lib_error_set_handler (0);],
1198                      emacs_alsa_subdir=yes,
1199                      emacs_alsa_subdir=no)
1200       if test "$emacs_alsa_subdir" != yes; then
1201         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1202       fi
1203       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1204     fi
1205
1206     CFLAGS="$SAVE_CFLAGS"
1207     LDFLAGS="$SAVE_LDFLAGS"
1208     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1209     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1210     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1211   fi
1212   AC_SUBST(CFLAGS_SOUND)
1213 fi
1214
1215 dnl checks for header files
1216 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1217   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1218   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1219   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1220   sys/utsname.h pwd.h)
1221
1222 AC_MSG_CHECKING(if personality LINUX32 can be set)
1223 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1224                emacs_cv_personality_linux32=yes,
1225                emacs_cv_personality_linux32=no)
1226 AC_MSG_RESULT($emacs_cv_personality_linux32)
1227
1228 if test $emacs_cv_personality_linux32 = yes; then
1229   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1230             [Define to 1 if personality LINUX32 can be set.])
1231 fi
1232
1233 dnl On Solaris 8 there's a compilation warning for term.h because
1234 dnl it doesn't define `bool'.
1235 AC_CHECK_HEADERS(term.h, , , -)
1236 AC_HEADER_STDC
1237 AC_HEADER_TIME
1238 AC_CHECK_DECLS([sys_siglist])
1239 if test $ac_cv_have_decl_sys_siglist != yes; then
1240   # For Tru64, at least:
1241   AC_CHECK_DECLS([__sys_siglist])
1242   if test $ac_cv_have_decl___sys_siglist = yes; then
1243     AC_DEFINE(sys_siglist, __sys_siglist,
1244               [Define to any substitute for sys_siglist.])
1245   fi
1246 fi
1247 AC_HEADER_SYS_WAIT
1248
1249 dnl Some systems have utime.h but don't declare the struct anyplace.
1250 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1251 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1252 #include <sys/time.h>
1253 #include <time.h>
1254 #else
1255 #ifdef HAVE_SYS_TIME_H
1256 #include <sys/time.h>
1257 #else
1258 #include <time.h>
1259 #endif
1260 #endif
1261 #ifdef HAVE_UTIME_H
1262 #include <utime.h>
1263 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1264   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1265 if test $emacs_cv_struct_utimbuf = yes; then
1266   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1267 fi
1268
1269 dnl checks for typedefs
1270 AC_TYPE_SIGNAL
1271
1272 dnl Check for speed_t typedef.
1273 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1274   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1275     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1276 if test $emacs_cv_speed_t = yes; then
1277   AC_DEFINE(HAVE_SPEED_T, 1,
1278            [Define to 1 if `speed_t' is declared by <termios.h>.])
1279 fi
1280
1281 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1282 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1283 #include <sys/time.h>
1284 #include <time.h>
1285 #else
1286 #ifdef HAVE_SYS_TIME_H
1287 #include <sys/time.h>
1288 #else
1289 #include <time.h>
1290 #endif
1291 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1292   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1293 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1294 if test $emacs_cv_struct_timeval = yes; then
1295   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1296 fi
1297
1298 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1299 AC_TRY_COMPILE([#include <math.h>],
1300 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1301   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1302 HAVE_EXCEPTION=$emacs_cv_struct_exception
1303 if test $emacs_cv_struct_exception != yes; then
1304   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1305 fi
1306
1307 AC_CHECK_HEADERS(sys/socket.h)
1308 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1309 #if HAVE_SYS_SOCKET_H
1310 #include <sys/socket.h>
1311 #endif])
1312
1313 dnl checks for structure members
1314 AC_STRUCT_TM
1315 AC_STRUCT_TIMEZONE
1316 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1317                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1318                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1319                 [#include <time.h>])
1320 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1321                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1322                   struct ifreq.ifr_addr], , ,
1323                  [AC_INCLUDES_DEFAULT
1324 #if HAVE_SYS_SOCKET_H
1325 #include <sys/socket.h>
1326 #endif
1327 #if HAVE_NET_IF_H
1328 #include <net/if.h>
1329 #endif])
1330
1331 dnl checks for compiler characteristics
1332
1333 dnl Testing __STDC__ to determine prototype support isn't good enough.
1334 dnl DEC C, for instance, doesn't define it with default options, and
1335 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1336 dnl and void *.
1337 AC_C_PROTOTYPES
1338 AC_C_VOLATILE
1339 AC_C_CONST
1340 dnl This isn't useful because we can't turn on use of `inline' unless
1341 dnl the compiler groks `extern inline'.
1342 dnl AC_C_INLINE
1343 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1344   [AC_TRY_COMPILE(, [void * foo;],
1345                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1346 if test $emacs_cv_void_star = yes; then
1347   AC_DEFINE(POINTER_TYPE, void)
1348 else
1349   AC_DEFINE(POINTER_TYPE, char)
1350 fi
1351 AH_TEMPLATE(POINTER_TYPE,
1352             [Define as `void' if your compiler accepts `void *'; otherwise
1353              define as `char'.])dnl
1354
1355
1356
1357 dnl This could be used for targets which can have both byte sexes.
1358 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1359 dnl AC_C_BIGENDIAN
1360
1361 dnl check for Make feature
1362 AC_PROG_MAKE_SET
1363
1364 dnl checks for operating system services
1365 AC_SYS_LONG_FILE_NAMES
1366
1367 #### Choose a window system.
1368
1369 AC_PATH_X
1370 if test "$no_x" = yes; then
1371   window_system=none
1372 else
1373   window_system=x11
1374 fi
1375
1376 if test "${x_libraries}" != NONE; then
1377   if test -n "${x_libraries}"; then
1378     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1379     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1380   fi
1381   x_default_search_path=""
1382   x_search_path=${x_libraries}
1383   if test -z "${x_search_path}"; then
1384     x_search_path=/usr/lib
1385   fi
1386   for x_library in `echo ${x_search_path}: | \
1387                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1388     x_search_path="\
1389 ${x_library}/X11/%L/%T/%N%C%S:\
1390 ${x_library}/X11/%l/%T/%N%C%S:\
1391 ${x_library}/X11/%T/%N%C%S:\
1392 ${x_library}/X11/%L/%T/%N%S:\
1393 ${x_library}/X11/%l/%T/%N%S:\
1394 ${x_library}/X11/%T/%N%S"
1395     if test x"${x_default_search_path}" = x; then
1396       x_default_search_path=${x_search_path}
1397     else
1398       x_default_search_path="${x_search_path}:${x_default_search_path}"
1399     fi
1400   done
1401 fi
1402 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1403   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1404 fi
1405
1406 if test x"${x_includes}" = x; then
1407   bitmapdir=/usr/include/X11/bitmaps
1408 else
1409   # accumulate include directories that have X11 bitmap subdirectories
1410   bmd_acc="dummyval"
1411   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1412     if test -d "${bmd}/X11/bitmaps"; then
1413       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1414     fi
1415     if test -d "${bmd}/bitmaps"; then
1416       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1417     fi
1418   done
1419   if test ${bmd_acc} != "dummyval"; then
1420     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1421   fi
1422 fi
1423
1424 HAVE_CARBON=no
1425 if test "${with_carbon}" != no; then
1426   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1427 fi
1428 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1429   if test "${with_carbon+set}" != set \
1430      && test "${carbon_appdir_x+set}" != set; then
1431     for var in with_x with_x_toolkit with_xim \
1432                with_xpm with_jpeg with_tiff with_gif with_png; do
1433       if eval test \"\${$var+set}\" = set; then
1434         HAVE_CARBON=no
1435         break
1436       fi
1437     done
1438   fi
1439 fi
1440 if test "${HAVE_CARBON}" = yes; then
1441   window_system=mac
1442 fi
1443
1444 case "${window_system}" in
1445   x11 )
1446     HAVE_X_WINDOWS=yes
1447     HAVE_X11=yes
1448     case "${with_x_toolkit}" in
1449       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1450       motif ) USE_X_TOOLKIT=MOTIF ;;
1451       gtk ) with_gtk=yes
1452 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1453 dnl USE_X_TOOLKIT is set.
1454             USE_X_TOOLKIT=none ;;
1455       no ) USE_X_TOOLKIT=none ;;
1456 dnl If user did not say whether to use a toolkit, make this decision later:
1457 dnl use the toolkit if we have gtk, or X11R5 or newer.
1458       * ) USE_X_TOOLKIT=maybe ;;
1459     esac
1460   ;;
1461   mac | none )
1462     HAVE_X_WINDOWS=no
1463     HAVE_X11=no
1464     USE_X_TOOLKIT=none
1465   ;;
1466 esac
1467
1468 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1469    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1470    if test "$HAVE_XSERVER" = true ||
1471       test -n "$DISPLAY" ||
1472       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1473         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1474 were found.  You should install the relevant development files for X
1475 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1476 sure you have development files for image handling, i.e.
1477 tiff, gif, jpeg, png and xpm.
1478 If you are sure you want Emacs compiled without X window support, pass
1479   --without-x
1480 to configure.])
1481    fi
1482 fi
1483
1484 ### If we're using X11, we should use the X menu package.
1485 HAVE_MENUS=no
1486 case ${HAVE_X11} in
1487   yes ) HAVE_MENUS=yes ;;
1488 esac
1489
1490 ### Compute the unexec source name from the object name.
1491 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1492
1493 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1494 # Assume not, until told otherwise.
1495 GNU_MALLOC=yes
1496 doug_lea_malloc=yes
1497 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1498 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1499 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1500                emacs_cv_var___after_morecore_hook,
1501 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1502   emacs_cv_var___after_morecore_hook=yes,
1503   emacs_cv_var___after_morecore_hook=no)])
1504 if test $emacs_cv_var___after_morecore_hook = no; then
1505   doug_lea_malloc=no
1506 fi
1507 if test "${system_malloc}" = "yes"; then
1508   GNU_MALLOC=no
1509   GNU_MALLOC_reason="
1510     (The GNU allocators don't work with this system configuration.)"
1511 fi
1512 if test "$doug_lea_malloc" = "yes" ; then
1513   if test "$GNU_MALLOC" = yes ; then
1514     GNU_MALLOC_reason="
1515       (Using Doug Lea's new malloc from the GNU C Library.)"
1516   fi
1517   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1518             [Define to 1 if you are using the GNU C Library.])
1519 fi
1520
1521 if test x"${REL_ALLOC}" = x; then
1522   REL_ALLOC=${GNU_MALLOC}
1523 fi
1524
1525 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1526 dnl the system configuration file (s/*.h) to turn the use of mmap
1527 dnl in the relocating allocator on.
1528
1529 AC_FUNC_MMAP
1530 if test $use_mmap_for_buffers = yes; then
1531   REL_ALLOC=no
1532 fi
1533
1534 LIBS="$libsrc_libs $LIBS"
1535
1536 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1537 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1538 AC_CHECK_LIB(dnet, dnet_ntoa)
1539 dnl This causes -lresolv to get used in subsequent tests,
1540 dnl which causes failures on some systems such as HPUX 9.
1541 dnl AC_CHECK_LIB(resolv, gethostbyname)
1542
1543 dnl FIXME replace main with a function we actually want from this library.
1544 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1545
1546 AC_CHECK_LIB(pthreads, cma_open)
1547
1548 dnl Check for need for bigtoc support on IBM AIX
1549
1550 case ${host_os} in
1551 aix*)
1552   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1553     case $GCC in
1554     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1555     *) gdb_cv_bigtoc=-bbigtoc ;;
1556     esac
1557
1558     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1559     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1560   ])
1561   ;;
1562 esac
1563
1564 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1565 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1566 # REAL_CPPFLAGS later on.
1567
1568 REAL_CPPFLAGS="$CPPFLAGS"
1569
1570 if test "${HAVE_X11}" = "yes"; then
1571   DEFS="$C_SWITCH_X_SITE $DEFS"
1572   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1573   LIBS="$LIBX $LIBS"
1574   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1575   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1576
1577   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1578   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1579   # but it's more convenient here to set LD_RUN_PATH
1580   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1581   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1582     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1583     export LD_RUN_PATH
1584   fi
1585
1586   if test "${opsys}" = "gnu-linux"; then
1587     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1588     AC_TRY_LINK([],
1589      [XOpenDisplay ("foo");],
1590      [xlinux_first_failure=no],
1591      [xlinux_first_failure=yes])
1592     if test "${xlinux_first_failure}" = "yes"; then
1593       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1594       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1595       OLD_CPPFLAGS="$CPPFLAGS"
1596       OLD_LIBS="$LIBS"
1597       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1598       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1599       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1600       LIBS="$LIBS -b i486-linuxaout"
1601       AC_TRY_LINK([],
1602        [XOpenDisplay ("foo");],
1603        [xlinux_second_failure=no],
1604        [xlinux_second_failure=yes])
1605       if test "${xlinux_second_failure}" = "yes"; then
1606         # If we get the same failure with -b, there is no use adding -b.
1607         # So take it out.  This plays safe.
1608         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1609         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1610         CPPFLAGS="$OLD_CPPFLAGS"
1611         LIBS="$OLD_LIBS"
1612         AC_MSG_RESULT(no)
1613       else
1614         AC_MSG_RESULT(yes)
1615       fi
1616     else
1617       AC_MSG_RESULT(no)
1618     fi
1619   fi
1620
1621   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1622   # header files included from there.
1623   AC_MSG_CHECKING(for Xkb)
1624   AC_TRY_LINK([#include <X11/Xlib.h>
1625 #include <X11/XKBlib.h>],
1626         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1627         emacs_xkb=yes, emacs_xkb=no)
1628   AC_MSG_RESULT($emacs_xkb)
1629   if test $emacs_xkb = yes; then
1630     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1631   fi
1632
1633   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1634 XScreenNumberOfScreen XSetWMProtocols)
1635 fi
1636
1637 if test "${window_system}" = "x11"; then
1638   AC_MSG_CHECKING(X11 version 6)
1639   AC_CACHE_VAL(emacs_cv_x11_version_6,
1640   [AC_TRY_LINK([#include <X11/Xlib.h>],
1641 [#if XlibSpecificationRelease < 6
1642 fail;
1643 #endif
1644 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1645   if test $emacs_cv_x11_version_6 = yes; then
1646     AC_MSG_RESULT(6 or newer)
1647     AC_DEFINE(HAVE_X11R6, 1,
1648               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1649   else
1650     AC_MSG_RESULT(before 6)
1651   fi
1652 fi
1653
1654
1655 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1656 HAVE_RSVG=no
1657 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1658   if test "${with_rsvg}" != "no"; then
1659     RSVG_REQUIRED=2.0.0
1660     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1661
1662     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1663     AC_SUBST(RSVG_CFLAGS)
1664     AC_SUBST(RSVG_LIBS)
1665
1666     if test ".${RSVG_CFLAGS}" != "."; then
1667       HAVE_RSVG=yes
1668       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1669       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1670       LIBS="$RSVG_LIBS $LIBS"
1671     fi
1672   fi
1673 fi
1674
1675
1676 HAVE_GTK=no
1677 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1678   GLIB_REQUIRED=2.6
1679   GTK_REQUIRED=2.6
1680   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1681
1682   dnl Checks for libraries.
1683   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1684   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1685      AC_MSG_ERROR($GTK_PKG_ERRORS)
1686   fi
1687 fi
1688
1689
1690 if test x"$pkg_check_gtk" = xyes; then
1691
1692   AC_SUBST(GTK_CFLAGS)
1693   AC_SUBST(GTK_LIBS)
1694   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1695   CFLAGS="$CFLAGS $GTK_CFLAGS"
1696   LIBS="$GTK_LIBS $LIBS"
1697   dnl Try to compile a simple GTK program.
1698   GTK_COMPILES=no
1699   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1700   if test "${GTK_COMPILES}" != "yes"; then
1701     if test "$USE_X_TOOLKIT" != "maybe"; then
1702       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1703     fi
1704   else
1705     HAVE_GTK=yes
1706     AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1707     USE_X_TOOLKIT=none
1708   fi
1709
1710 fi
1711
1712
1713 if test "${HAVE_GTK}" = "yes"; then
1714
1715   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1716   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1717   if test "$with_toolkit_scroll_bars" != no; then
1718     with_toolkit_scroll_bars=yes
1719   fi
1720
1721   dnl  Check if we can use multiple displays with this GTK version.
1722   dnl  If gdk_display_open exists, assume all others are there also.
1723   HAVE_GTK_MULTIDISPLAY=no
1724   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1725   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1726     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1727               [Define to 1 if GTK can handle more than one display.])
1728   fi
1729
1730   dnl  Check if we have the old file selection dialog.
1731   dnl  If gdk_display_open exists, assume all others are there also.
1732   HAVE_GTK_FILE_SELECTION=no
1733   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1734
1735   dnl  Check if we have the new file chooser dialog
1736   dnl  If gdk_display_open exists, assume all others are there also.
1737   HAVE_GTK_FILE_CHOOSER=no
1738   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1739
1740   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1741      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1742     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1743               [Define to 1 if GTK has both file selection and chooser dialog.])
1744   fi
1745
1746   dnl Check if pthreads are available.  Emacs only needs this when using
1747   dnl gtk_file_chooser under Gnome.
1748   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1749     HAVE_GTK_AND_PTHREAD=no
1750     AC_CHECK_HEADERS(pthread.h)
1751     if test "$ac_cv_header_pthread_h"; then
1752       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1753     fi
1754     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1755       case "${canonical}" in
1756         *-hpux*) ;;
1757         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1758       esac
1759       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1760                [Define to 1 if you have GTK and pthread (-lpthread).])
1761     fi
1762   fi
1763 fi
1764
1765 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1766 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1767 dnl also not configured.
1768 HAVE_DBUS=no
1769 if test "${with_dbus}" = "yes"; then
1770    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1771    if test "$HAVE_DBUS" = yes; then
1772       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1773    fi
1774 fi
1775
1776 dnl Do not put whitespace before the #include statements below.
1777 dnl Older compilers (eg sunos4 cc) choke on it.
1778 HAVE_XAW3D=no
1779 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1780   if test "$with_xaw3d" != no; then
1781     AC_MSG_CHECKING(for xaw3d)
1782     AC_CACHE_VAL(emacs_cv_xaw3d,
1783     [AC_TRY_LINK([
1784 #include <X11/Intrinsic.h>
1785 #include <X11/Xaw3d/Simple.h>],
1786       [],
1787       emacs_cv_xaw3d=yes,
1788       emacs_cv_xaw3d=no)])
1789   else
1790     emacs_cv_xaw3d=no
1791   fi
1792   if test $emacs_cv_xaw3d = yes; then
1793     AC_MSG_RESULT([yes; using Lucid toolkit])
1794     USE_X_TOOLKIT=LUCID
1795     HAVE_XAW3D=yes
1796     AC_DEFINE(HAVE_XAW3D, 1,
1797               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1798   else
1799     AC_MSG_RESULT(no)
1800     AC_MSG_CHECKING(for libXaw)
1801     AC_CACHE_VAL(emacs_cv_xaw,
1802     [AC_TRY_LINK([
1803 #include <X11/Intrinsic.h>
1804 #include <X11/Xaw/Simple.h>],
1805       [],
1806       emacs_cv_xaw=yes,
1807       emacs_cv_xaw=no)])
1808     if test $emacs_cv_xaw = yes; then
1809       AC_MSG_RESULT([yes; using Lucid toolkit])
1810       USE_X_TOOLKIT=LUCID
1811     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1812       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1813     else
1814       AC_MSG_RESULT([no; do not use toolkit by default])
1815       USE_X_TOOLKIT=none
1816     fi
1817   fi
1818 fi
1819
1820 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1821
1822 if test "${USE_X_TOOLKIT}" != "none"; then
1823   AC_MSG_CHECKING(X11 toolkit version)
1824   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1825   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1826 [#if XtSpecificationRelease < 6
1827 fail;
1828 #endif
1829 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1830   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1831   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1832     AC_MSG_RESULT(6 or newer)
1833     AC_DEFINE(HAVE_X11XTR6, 1,
1834               [Define to 1 if you have the X11R6 or newer version of Xt.])
1835   else
1836     AC_MSG_RESULT(before 6)
1837   fi
1838
1839 dnl If using toolkit, check whether libXmu.a exists.
1840 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1841   OLDLIBS="$LIBS"
1842   if test x$HAVE_X11XTR6 = xyes; then
1843     LIBS="-lXt -lSM -lICE $LIBS"
1844   else
1845     LIBS="-lXt $LIBS"
1846   fi
1847   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1848   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1849 fi
1850
1851 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1852 if test "${HAVE_X11}" = "yes"; then
1853   if test "${USE_X_TOOLKIT}" != "none"; then
1854     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1855   fi
1856 fi
1857
1858 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1859   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1860   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1861     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1862 int x = 5;
1863 #else
1864 Motif version prior to 2.1.
1865 #endif],
1866     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1867   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1868   if test $emacs_cv_motif_version_2_1 = yes; then
1869     HAVE_LIBXP=no
1870     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1871               [Define to 1 if you have Motif 2.1 or newer.])
1872     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1873     if test ${HAVE_LIBXP} = yes; then
1874       AC_DEFINE(HAVE_LIBXP, 1,
1875                 [Define to 1 if you have the Xp library (-lXp).])
1876     fi
1877   else
1878     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1879     # We put this in CFLAGS temporarily to precede other -I options
1880     # that might be in CFLAGS temporarily.
1881     # We put this in CPPFLAGS where it precedes the other -I options.
1882     OLD_CPPFLAGS=$CPPFLAGS
1883     OLD_CFLAGS=$CFLAGS
1884     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1885     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1886     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1887       [int x = 5;],
1888       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1889     if test $emacs_cv_lesstif = yes; then
1890       # Make sure this -I option remains in CPPFLAGS after it is set
1891       # back to REAL_CPPFLAGS.
1892       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1893       # have those other -I options anyway.  Ultimately, having this
1894       # directory ultimately in CPPFLAGS will be enough.
1895       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1896       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1897     else
1898       CFLAGS=$OLD_CFLAGS
1899       CPPFLAGS=$OLD_CPPFLAGS
1900     fi
1901   fi
1902 fi
1903
1904 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1905 dnl using Motif or Xaw3d is available, and unless
1906 dnl --with-toolkit-scroll-bars=no was specified.
1907
1908 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1909             [Define to 1 if we should use toolkit scroll bars.])dnl
1910 USE_TOOLKIT_SCROLL_BARS=no
1911 if test "${with_toolkit_scroll_bars}" != "no"; then
1912   if test "${USE_X_TOOLKIT}" != "none"; then
1913     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1914       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1915       HAVE_XAW3D=no
1916       USE_TOOLKIT_SCROLL_BARS=yes
1917     elif test "${HAVE_XAW3D}" = "yes"; then
1918       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1919       USE_TOOLKIT_SCROLL_BARS=yes
1920     fi
1921   elif test "${HAVE_GTK}" = "yes"; then
1922     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1923     USE_TOOLKIT_SCROLL_BARS=yes
1924   elif test "${HAVE_CARBON}" = "yes"; then
1925     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1926     USE_TOOLKIT_SCROLL_BARS=yes
1927   fi
1928 fi
1929
1930 dnl See if XIM is available.
1931 AC_TRY_COMPILE([
1932           #include <X11/Xlib.h>
1933           #include <X11/Xresource.h>],
1934          [XIMProc  callback;],
1935          [HAVE_XIM=yes
1936          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1937          HAVE_XIM=no)
1938
1939 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1940
1941 if test "${with_xim}" != "no"; then
1942   AC_DEFINE(USE_XIM, 1,
1943             [Define to 1 if we should use XIM, if it is available.])
1944 fi
1945
1946
1947 if test "${HAVE_XIM}" != "no"; then
1948   late_CFLAGS=$CFLAGS
1949   if test "$GCC" = yes; then
1950     CFLAGS="$CFLAGS --pedantic-errors"
1951   fi
1952   AC_TRY_COMPILE([
1953 #include <X11/Xlib.h>
1954 #include <X11/Xresource.h>],
1955 [Display *display;
1956 XrmDatabase db;
1957 char *res_name;
1958 char *res_class;
1959 XIMProc  callback;
1960 XPointer *client_data;
1961 #ifndef __GNUC__
1962 /* If we're not using GCC, it's probably not XFree86, and this is
1963    probably right, but we can't use something like --pedantic-errors.  */
1964 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1965                                            char*, XIMProc, XPointer*);
1966 #endif
1967 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1968    client_data);],
1969     [emacs_cv_arg6_star=yes])
1970   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1971          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1972 either XPointer or XPointer*.])dnl
1973   if test "$emacs_cv_arg6_star" = yes; then
1974     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1975   else
1976     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1977   fi
1978   CFLAGS=$late_CFLAGS
1979 fi
1980
1981 #### For font-backend
1982 if test "${USE_FONT_BACKEND}" = "yes"; then
1983
1984 AC_DEFINE(USE_FONT_BACKEND, 1,
1985           [Define to 1 if we should use font-backend.])
1986
1987 ### Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1988 HAVE_XFT=maybe
1989 if test "${HAVE_X11}" = "yes"; then
1990   if test "x${with_freetype}" = "xno"; then
1991     with_xft="no";
1992   fi
1993   if test "x${with_xft}" != "xno"; then
1994
1995     dnl Check if --with-pkg-config-prog has been given.
1996     if test "X${with_pkg_config_prog}" != X; then
1997       PKG_CONFIG="${with_pkg_config_prog}"
1998     fi
1999
2000     PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2001     if test "$HAVE_XFT" != no; then
2002       OLD_CPPFLAGS="$CPPFLAGS"
2003       OLD_CFLAGS="$CFLAGS"
2004       OLD_LIBS="$LIBS"
2005       CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2006       CFLAGS="$CFLAGS $XFT_CFLAGS"
2007       LIBS="$XFT_LIBS $LIBS"
2008       AC_CHECK_HEADER(X11/Xft/Xft.h,
2009         AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2010
2011       if test "${HAVE_XFT}" = "yes"; then
2012         AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2013         AC_SUBST(XFT_LIBS)
2014         C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2015       else
2016         CPPFLAGS="$OLD_CPPFLAGS"
2017         CFLAGS="$OLD_CFLAGS"
2018         LIBS="$OLD_LIBS"
2019       fi
2020     fi
2021   fi
2022 fi
2023 dnl For the "Does Emacs use" message at the end.
2024 if test "$HAVE_XFT" != "yes"; then
2025    HAVE_XFT=no
2026 fi
2027
2028
2029 HAVE_FREETYPE=no
2030 ### Use -lfreetype if available, unless `--with-freetype=no'.
2031 if test "${HAVE_XFT}" = "yes"; then
2032   dnl As we use Xft, we anyway use freetype.
2033   dnl In this case, there's no need of additional CFLAGS and LIBS.
2034   HAVE_FREETYPE=yes
2035 elif test "x${with_freetype}" != "xno"; then
2036   dnl Check if --with-pkg-config-prog has been given.
2037   if test "X${with_pkg_config_prog}" != X; then
2038     PKG_CONFIG="${with_pkg_config_prog}"
2039   fi
2040
2041   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
2042   if test "${HAVE_FREETYPE}" = "yes"; then
2043     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
2044     if test "${HAVE_FC}" = "no"; then
2045       dnl Witout fontconfig, we can't use freetype at the moment.
2046       HAVE_FREETYPE=no
2047     fi
2048   fi
2049 fi
2050
2051 HAVE_LIBOTF=no
2052 if test "${HAVE_FREETYPE}" = "yes"; then
2053   AC_DEFINE(HAVE_FREETYPE, 1,
2054             [Define to 1 if you have freetype and fontconfig libraries.])
2055   if test "${with_libotf}" != "no"; then
2056     dnl Check if --with-pkg-config-prog has been given.
2057     if test "X${with_pkg_config_prog}" != X; then
2058       PKG_CONFIG="${with_pkg_config_prog}"
2059     fi
2060     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2061                       HAVE_LIBOTF=no)
2062     if test "$HAVE_LIBOTF" = "yes"; then
2063       AC_DEFINE(HAVE_LIBOTF, 1,
2064                 [Define to 1 if you have libotf library.])
2065     fi
2066   fi
2067 fi
2068
2069 HAVE_M17N_FLT=no
2070 if test "${with_m17n_flt}" != "no"; then
2071   dnl Check if --with-pkg-config-prog has been given.
2072   if test "X${with_pkg_config_prog}" != X; then
2073     PKG_CONFIG="${with_pkg_config_prog}"
2074   fi
2075   dnl Checks for libraries.
2076   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes,
2077                     HAVE_M17N_FLT=no)
2078   if test "$HAVE_M17N_FLT" = "yes"; then
2079     AC_DEFINE(HAVE_M17N_FLT, 1,
2080               [Define to 1 if you have m17n-flt library.])
2081   fi
2082 fi
2083
2084 AC_SUBST(FREETYPE_CFLAGS)
2085 AC_SUBST(FREETYPE_LIBS)
2086 AC_SUBST(FONTCONFIG_CFLAGS)
2087 AC_SUBST(FONTCONFIG_LIBS)
2088 AC_SUBST(LIBOTF_CFLAGS)
2089 AC_SUBST(LIBOTF_LIBS)
2090 AC_SUBST(M17N_FLT_CFLAGS)
2091 AC_SUBST(M17N_FLT_LIBS)
2092
2093 fi
2094 #### End for font-backend
2095
2096 ### Use -lXpm if available, unless `--with-xpm=no'.
2097 HAVE_XPM=no
2098 if test "${HAVE_X11}" = "yes"; then
2099   if test "${with_xpm}" != "no"; then
2100     AC_CHECK_HEADER(X11/xpm.h,
2101       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2102     if test "${HAVE_XPM}" = "yes"; then
2103       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2104       AC_EGREP_CPP(no_return_alloc_pixels,
2105       [#include "X11/xpm.h"
2106 #ifndef XpmReturnAllocPixels
2107 no_return_alloc_pixels
2108 #endif
2109       ], HAVE_XPM=no, HAVE_XPM=yes)
2110
2111       if test "${HAVE_XPM}" = "yes"; then
2112         AC_MSG_RESULT(yes)
2113       else
2114         AC_MSG_RESULT(no)
2115       fi
2116     fi
2117   fi
2118
2119   if test "${HAVE_XPM}" = "yes"; then
2120     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2121   fi
2122 fi
2123
2124 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2125 HAVE_JPEG=no
2126 if test "${HAVE_X11}" = "yes"; then
2127   if test "${with_jpeg}" != "no"; then
2128     dnl Checking for jpeglib.h can lose because of a redefinition of
2129     dnl  HAVE_STDLIB_H.
2130     AC_CHECK_HEADER(jerror.h,
2131       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2132   fi
2133
2134   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2135   if test "${HAVE_JPEG}" = "yes"; then
2136     AC_DEFINE(HAVE_JPEG)
2137     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2138         [#include <jpeglib.h>
2139          version=JPEG_LIB_VERSION
2140 ],
2141         [AC_DEFINE(HAVE_JPEG)],
2142         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2143         HAVE_JPEG=no])
2144   fi
2145 fi
2146
2147 ### Use -lpng if available, unless `--with-png=no'.
2148 HAVE_PNG=no
2149 if test "${HAVE_X11}" = "yes"; then
2150   if test "${with_png}" != "no"; then
2151     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2152     # in /usr/include/libpng.
2153     AC_CHECK_HEADERS(png.h libpng/png.h)
2154     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2155       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2156     fi
2157   fi
2158
2159   if test "${HAVE_PNG}" = "yes"; then
2160     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2161   fi
2162 fi
2163
2164 ### Use -ltiff if available, unless `--with-tiff=no'.
2165 HAVE_TIFF=no
2166 if test "${HAVE_X11}" = "yes"; then
2167   if test "${with_tiff}" != "no"; then
2168     AC_CHECK_HEADER(tiffio.h,
2169       [tifflibs="-lz -lm"
2170       # At least one tiff package requires the jpeg library.
2171       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2172       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2173   fi
2174
2175   if test "${HAVE_TIFF}" = "yes"; then
2176     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2177   fi
2178 fi
2179
2180 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2181 HAVE_GIF=no
2182 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2183   AC_CHECK_HEADER(gif_lib.h,
2184 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2185 # Earlier versions can crash Emacs.
2186     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2187
2188   if test "$HAVE_GIF" = yes; then
2189       ac_gif_lib_name="-lgif"
2190   fi
2191
2192 # If gif_lib.h but no libgif, try libungif.
2193   if test x"$try_libungif" = xyes; then
2194     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2195
2196     if test "$HAVE_GIF" = yes; then
2197       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2198       ac_gif_lib_name="-lungif"
2199     fi
2200   fi
2201
2202   if test "${HAVE_GIF}" = "yes"; then
2203     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2204   fi
2205 fi
2206
2207 dnl Check for required libraries.
2208 if test "${HAVE_X11}" = "yes"; then
2209   MISSING=""
2210   WITH_NO=""
2211   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2212     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2213   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2214     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2215   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2216     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2217   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2218     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2219   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2220     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2221
2222   if test "X${MISSING}" != X; then
2223     AC_MSG_ERROR([The following required libraries were not found:
2224     $MISSING
2225 Maybe some development libraries/packages are missing?
2226 If you don't want to link with them give
2227     $WITH_NO
2228 as options to configure])
2229   fi
2230 fi
2231
2232 ### Use -lgpm if available, unless `--with-gpm=no'.
2233 HAVE_GPM=no
2234 if test "${with_gpm}" != "no"; then
2235   AC_CHECK_HEADER(gpm.h,
2236     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2237 fi
2238
2239 if test "${HAVE_GPM}" = "yes"; then
2240   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2241 fi
2242
2243 dnl Check for malloc/malloc.h on darwin
2244 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2245
2246 ### Use Mac OS X Carbon API to implement GUI.
2247 if test "${HAVE_CARBON}" = "yes"; then
2248   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2249   ## Specify the install directory
2250   carbon_appdir=
2251   if test "${carbon_appdir_x}" != ""; then
2252     case ${carbon_appdir_x} in
2253       y | ye | yes)  carbon_appdir=/Applications ;;
2254       * ) carbon_appdir=${carbon_appdir_x} ;;
2255     esac
2256   fi
2257   # We also have mouse menus.
2258   HAVE_MENUS=yes
2259 fi
2260
2261 ### Use session management (-lSM -lICE) if available
2262 HAVE_X_SM=no
2263 if test "${HAVE_X11}" = "yes"; then
2264   AC_CHECK_HEADER(X11/SM/SMlib.h,
2265     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2266
2267   if test "${HAVE_X_SM}" = "yes"; then
2268     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2269     case "$LIBS" in
2270       *-lSM*) ;;
2271       *)      LIBS="-lSM -lICE $LIBS" ;;
2272     esac
2273   fi
2274 fi
2275
2276 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2277 AC_CACHE_CHECK(whether netdb declares h_errno,
2278                emacs_cv_netdb_declares_h_errno,
2279 [AC_TRY_LINK([#include <netdb.h>],
2280   [return h_errno;],
2281   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2282 if test $emacs_cv_netdb_declares_h_errno = yes; then
2283   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2284 fi
2285
2286 AC_FUNC_ALLOCA
2287
2288 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2289 dnl FIXME is there an autoconf test that does the right thing, without
2290 dnl needing to call A_M_E afterwards?
2291 if test x"$ac_cv_func_alloca_works" != xyes; then
2292    AC_MSG_ERROR( [a system implementation of alloca is required] )
2293 fi
2294
2295 # fmod, logb, and frexp are found in -lm on most systems.
2296 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2297 AC_CHECK_LIB(m, sqrt)
2298
2299 # Check for mail-locking functions in a "mail" library.  Probably this should
2300 # have the same check as for liblockfile below.
2301 AC_CHECK_LIB(mail, maillock)
2302 dnl Debian, at least:
2303 AC_CHECK_LIB(lockfile, maillock)
2304 # If we have the shared liblockfile, assume we must use it for mail
2305 # locking (e.g. Debian).  If we couldn't link against liblockfile
2306 # (no liblockfile.a installed), ensure that we don't need to.
2307 if test "$ac_cv_lib_lockfile_maillock" = no; then
2308   dnl This works for files generally, not just executables.
2309   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2310   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2311                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2312   if test $ac_cv_prog_liblockfile = yes; then
2313     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2314 This probably means that movemail could lose mail.
2315 There may be a `development' package to install containing liblockfile.])
2316   else :
2317   fi
2318 fi
2319 AC_CHECK_FUNCS(touchlock)
2320 AC_CHECK_HEADERS(maillock.h)
2321
2322 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2323 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2324 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2325 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2326 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2327 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2328 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2329 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2330 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2331
2332 AC_CHECK_HEADERS(sys/un.h)
2333
2334 AC_FUNC_MKTIME
2335 if test "$ac_cv_func_working_mktime" = no; then
2336   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2337 fi
2338
2339 AC_FUNC_GETLOADAVG
2340
2341 AC_FUNC_FSEEKO
2342
2343 # Configure getopt.
2344 m4_include([m4/getopt.m4])
2345 gl_GETOPT_IFELSE([
2346   gl_GETOPT_SUBSTITUTE_HEADER
2347   gl_PREREQ_GETOPT
2348   GETOPTOBJS='getopt.o getopt1.o'
2349 ])
2350 AC_SUBST(GETOPTOBJS)
2351
2352 AC_FUNC_GETPGRP
2353
2354 AC_FUNC_STRFTIME
2355
2356 # UNIX98 PTYs.
2357 AC_CHECK_FUNCS(grantpt)
2358
2359 # PTY-related GNU extensions.
2360 AC_CHECK_FUNCS(getpt)
2361
2362 # Check this now, so that we will NOT find the above functions in ncurses.
2363 # That is because we have not set up to link ncurses in lib-src.
2364 # It's better to believe a function is not available
2365 # than to expect to find it in ncurses.
2366 AC_CHECK_LIB(ncurses, tparm)
2367
2368 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2369
2370 resolv=no
2371 AC_TRY_LINK([#include <netinet/in.h>
2372 #include <arpa/nameser.h>
2373 #include <resolv.h>],
2374     [return res_init();],
2375     have_res_init=yes, have_res_init=no)
2376 if test "$have_res_init" = no; then
2377   OLIBS="$LIBS"
2378   LIBS="$LIBS -lresolv"
2379   AC_MSG_CHECKING(for res_init with -lresolv)
2380   AC_TRY_LINK([#include <netinet/in.h>
2381 #include <arpa/nameser.h>
2382 #include <resolv.h>],
2383     [return res_init();],
2384     have_res_init=yes, have_res_init=no)
2385   AC_MSG_RESULT($have_res_init)
2386   if test "$have_res_init" = yes ; then
2387     resolv=yes
2388   fi
2389   LIBS="$OLIBS"
2390 fi
2391
2392 if test "$have_res_init" = yes; then
2393   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2394 fi
2395
2396 # Do we need the Hesiod library to provide the support routines?
2397 if test "$with_hesiod" = yes ; then
2398   # Don't set $LIBS here -- see comments above.
2399   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2400      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2401                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2402   if test "$resolv" = yes ; then
2403     RESOLVLIB=-lresolv
2404   else
2405     RESOLVLIB=
2406   fi
2407   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2408         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2409                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2410         :, $RESOLVLIB)])
2411 fi
2412
2413 # Do we need libresolv (due to res_init or Hesiod)?
2414 if test "$resolv" = yes ; then
2415   AC_DEFINE(HAVE_LIBRESOLV, 1,
2416             [Define to 1 if you have the resolv library (-lresolv).])
2417 fi
2418
2419 # These tell us which Kerberos-related libraries to use.
2420 if test "${with_kerberos+set}" = set; then
2421   AC_CHECK_LIB(com_err, com_err)
2422   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2423   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2424   AC_CHECK_LIB(krb5, krb5_init_context)
2425   if test "${with_kerberos5+set}" != set; then
2426     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2427                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2428     AC_CHECK_LIB(krb4, krb_get_cred,,
2429                  [AC_CHECK_LIB(krb, krb_get_cred)])
2430   fi
2431
2432   if test "${with_kerberos5+set}" = set; then
2433     AC_CHECK_HEADERS(krb5.h)
2434   else
2435     AC_CHECK_HEADERS(des.h,,
2436                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2437                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2438     AC_CHECK_HEADERS(krb.h,,
2439                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2440                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2441   fi
2442   AC_CHECK_HEADERS(com_err.h)
2443 fi
2444
2445 # Solaris requires -lintl if you want strerror (which calls dgettext)
2446 # to return localized messages.
2447 AC_CHECK_LIB(intl, dgettext)
2448
2449 AC_MSG_CHECKING(whether localtime caches TZ)
2450 AC_CACHE_VAL(emacs_cv_localtime_cache,
2451 [if test x$ac_cv_func_tzset = xyes; then
2452 AC_TRY_RUN([#include <time.h>
2453 extern char **environ;
2454 unset_TZ ()
2455 {
2456   char **from, **to;
2457   for (to = from = environ; (*to = *from); from++)
2458     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2459       to++;
2460 }
2461 char TZ_GMT0[] = "TZ=GMT0";
2462 char TZ_PST8[] = "TZ=PST8";
2463 main()
2464 {
2465   time_t now = time ((time_t *) 0);
2466   int hour_GMT0, hour_unset;
2467   if (putenv (TZ_GMT0) != 0)
2468     exit (1);
2469   hour_GMT0 = localtime (&now)->tm_hour;
2470   unset_TZ ();
2471   hour_unset = localtime (&now)->tm_hour;
2472   if (putenv (TZ_PST8) != 0)
2473     exit (1);
2474   if (localtime (&now)->tm_hour == hour_GMT0)
2475     exit (1);
2476   unset_TZ ();
2477   if (localtime (&now)->tm_hour != hour_unset)
2478     exit (1);
2479   exit (0);
2480 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2481 [# If we have tzset, assume the worst when cross-compiling.
2482 emacs_cv_localtime_cache=yes])
2483 else
2484         # If we lack tzset, report that localtime does not cache TZ,
2485         # since we can't invalidate the cache if we don't have tzset.
2486         emacs_cv_localtime_cache=no
2487 fi])dnl
2488 AC_MSG_RESULT($emacs_cv_localtime_cache)
2489 if test $emacs_cv_localtime_cache = yes; then
2490   AC_DEFINE(LOCALTIME_CACHE, 1,
2491             [Define to 1 if localtime caches TZ.])
2492 fi
2493
2494 if test "x$HAVE_TIMEVAL" = xyes; then
2495   AC_CHECK_FUNCS(gettimeofday)
2496   if test $ac_cv_func_gettimeofday = yes; then
2497     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2498                    emacs_cv_gettimeofday_two_arguments,
2499     [AC_TRY_COMPILE([
2500 #ifdef TIME_WITH_SYS_TIME
2501 #include <sys/time.h>
2502 #include <time.h>
2503 #else
2504 #ifdef HAVE_SYS_TIME_H
2505 #include <sys/time.h>
2506 #else
2507 #include <time.h>
2508 #endif
2509 #endif],
2510       [struct timeval time;
2511        gettimeofday (&time, 0);],
2512       emacs_cv_gettimeofday_two_arguments=yes,
2513       emacs_cv_gettimeofday_two_arguments=no)])
2514     if test $emacs_cv_gettimeofday_two_arguments = no; then
2515       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2516                 [Define to 1 if gettimeofday accepts only one argument.])
2517     fi
2518   fi
2519 fi
2520
2521 ok_so_far=yes
2522 AC_CHECK_FUNC(socket, , ok_so_far=no)
2523 if test $ok_so_far = yes; then
2524   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2525 fi
2526 if test $ok_so_far = yes; then
2527   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2528 fi
2529 if test $ok_so_far = yes; then
2530 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2531   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2532             [Define to 1 if you have inet sockets.])
2533 fi
2534
2535 AC_CHECK_HEADERS(sys/ioctl.h)
2536
2537 if test -f /usr/lpp/X11/bin/smt.exp; then
2538   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2539             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2540 fi
2541
2542 AC_MSG_CHECKING(whether system supports dynamic ptys)
2543 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2544   AC_MSG_RESULT(yes)
2545   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2546 else
2547   AC_MSG_RESULT(no)
2548 fi
2549
2550 AC_FUNC_FORK
2551
2552 dnl Adapted from Haible's version.
2553 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2554   [AC_TRY_LINK([#include <langinfo.h>],
2555     [char* cs = nl_langinfo(CODESET);],
2556     emacs_cv_langinfo_codeset=yes,
2557     emacs_cv_langinfo_codeset=no)
2558   ])
2559 if test $emacs_cv_langinfo_codeset = yes; then
2560   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2561     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2562 fi
2563
2564 AC_CHECK_TYPES(size_t)
2565
2566 AC_TYPE_MBSTATE_T
2567
2568 dnl Restrict could probably be used effectively other than in regex.c.
2569 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2570   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2571                   emacs_cv_c_restrict=yes,
2572                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2573                                   emacs_cv_c_restrict=__restrict,
2574                                   emacs_cv_c_restrict=no)])])
2575 case "$emacs_cv_c_restrict" in
2576   yes) emacs_restrict=restrict;;
2577   no) emacs_restrict="";;
2578   *) emacs_restrict="$emacs_cv_c_restrict";;
2579 esac
2580 if test "$emacs_restrict" != __restrict; then
2581   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2582     [Define to compiler's equivalent of C99 restrict keyword.
2583      Don't define if equivalent is `__restrict'.])
2584 fi
2585
2586 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2587   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2588                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2589 if test "$emacs_cv_c_restrict_arr" = yes; then
2590   AC_DEFINE(__restrict_arr, __restrict,
2591     [Define to compiler's equivalent of C99 restrict keyword in array
2592      declarations.  Define as empty for no equivalent.])
2593 fi
2594
2595 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2596 dnl how the tty code is related to POSIX and/or other versions of termios.
2597 dnl The following looks like a useful start.
2598 dnl
2599 dnl AC_SYS_POSIX_TERMIOS
2600 dnl if test $ac_cv_sys_posix_termios = yes; then
2601 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2602 dnl                                and macros for terminal control.])
2603 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2604 dnl fi
2605
2606 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2607
2608 # Set up the CFLAGS for real compilation, so we can substitute it.
2609 CFLAGS="$REAL_CFLAGS"
2610 CPPFLAGS="$REAL_CPPFLAGS"
2611
2612 #### Find out which version of Emacs this is.
2613 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2614          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2615 if test x"${version}" = x; then
2616   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2617 fi
2618
2619 ### Specify what sort of things we'll be editing into Makefile and config.h.
2620 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2621 AC_SUBST(version)
2622 AC_SUBST(configuration)
2623 AC_SUBST(canonical)
2624 AC_SUBST(srcdir)
2625 AC_SUBST(prefix)
2626 AC_SUBST(exec_prefix)
2627 AC_SUBST(bindir)
2628 AC_SUBST(datadir)
2629 AC_SUBST(sharedstatedir)
2630 AC_SUBST(libexecdir)
2631 AC_SUBST(mandir)
2632 AC_SUBST(infodir)
2633 AC_SUBST(lispdir)
2634 AC_SUBST(locallisppath)
2635 AC_SUBST(lisppath)
2636 AC_SUBST(x_default_search_path)
2637 AC_SUBST(etcdir)
2638 AC_SUBST(archlibdir)
2639 AC_SUBST(docdir)
2640 AC_SUBST(bitmapdir)
2641 AC_SUBST(gamedir)
2642 AC_SUBST(gameuser)
2643 AC_SUBST(c_switch_system)
2644 AC_SUBST(c_switch_machine)
2645 AC_SUBST(LD_SWITCH_X_SITE)
2646 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2647 AC_SUBST(C_SWITCH_X_SITE)
2648 AC_SUBST(CFLAGS)
2649 AC_SUBST(X_TOOLKIT_TYPE)
2650 AC_SUBST(machfile)
2651 AC_SUBST(opsysfile)
2652 AC_SUBST(GETLOADAVG_LIBS)
2653 AC_SUBST(carbon_appdir)
2654
2655 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2656                    [Define to the canonical Emacs configuration name.])
2657 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2658                    [Define to the options passed to configure.])
2659 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2660                    [Define to the used machine dependent file.])
2661 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2662                    [Define to the used os dependent file.])
2663 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2664 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2665  may need to deal with X Windows.  For instance, if you've defined
2666  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2667  your loader can find on its own, you might want to add "-L/..." or
2668  something similar.])
2669 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2670                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2671                     in case it's needed (for Solaris, for example).])
2672 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2673 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2674  may need to deal with X Windows.  For instance, if you've defined
2675  HAVE_X_WINDOWS above and your X include files aren't in a place
2676  that your compiler can find on its own, you might want to add
2677  "-I/..." or something similar.])
2678 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2679                    [Define to the unexec source file name.])
2680
2681 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2682   AC_DEFINE(HAVE_X_WINDOWS, 1,
2683             [Define to 1 if you want to use the X window system.])
2684 fi
2685 if test "${USE_X_TOOLKIT}" != "none" ; then
2686   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2687 fi
2688 if test "${HAVE_X11}" = "yes" ; then
2689   AC_DEFINE(HAVE_X11, 1,
2690             [Define to 1 if you want to use version 11 of X windows.
2691              Otherwise, Emacs expects to use version 10.])
2692 fi
2693 if test "${HAVE_MENUS}" = "yes" ; then
2694   AC_DEFINE(HAVE_MENUS, 1,
2695             [Define to 1 if you have mouse menus.
2696              (This is automatic if you use X, but the option to specify it remains.)
2697              It is also defined with other window systems that support xmenu.c.])
2698 fi
2699 if test "${GNU_MALLOC}" = "yes" ; then
2700   AC_DEFINE(GNU_MALLOC, 1,
2701             [Define to 1 if you want to use the GNU memory allocator.])
2702 fi
2703 if test "${REL_ALLOC}" = "yes" ; then
2704   AC_DEFINE(REL_ALLOC, 1,
2705             [Define REL_ALLOC if you want to use the relocating allocator for
2706              buffer space.])
2707 fi
2708
2709
2710 AH_TOP([/* GNU Emacs site configuration template file.
2711    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2712      2006, 2007, 2008  Free Software Foundation, Inc.
2713
2714 This file is part of GNU Emacs.
2715
2716 GNU Emacs is free software; you can redistribute it and/or modify
2717 it under the terms of the GNU General Public License as published by
2718 the Free Software Foundation; either version 3, or (at your option)
2719 any later version.
2720
2721 GNU Emacs is distributed in the hope that it will be useful,
2722 but WITHOUT ANY WARRANTY; without even the implied warranty of
2723 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2724 GNU General Public License for more details.
2725
2726 You should have received a copy of the GNU General Public License
2727 along with GNU Emacs; see the file COPYING.  If not, write to the
2728 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2729 Boston, MA 02110-1301, USA.  */
2730
2731
2732 /* No code in Emacs #includes config.h twice, but some bits of code
2733    intended to work with other packages as well (like gmalloc.c)
2734    think they can include it as many times as they like.  */
2735 #ifndef EMACS_CONFIG_H
2736 #define EMACS_CONFIG_H
2737 ])dnl
2738
2739 AH_BOTTOM([
2740 /* If we're using any sort of window system, define some consequences.  */
2741 #ifdef HAVE_X_WINDOWS
2742 #define HAVE_WINDOW_SYSTEM
2743 #define MULTI_KBOARD
2744 #define HAVE_MOUSE
2745 #endif
2746
2747 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2748    on unconditionally. */
2749 #ifndef MULTI_KBOARD
2750 #define MULTI_KBOARD
2751 #endif
2752
2753 /* If we're using the Carbon API on Mac OS X, define a few more
2754    variables as well.  */
2755 #ifdef HAVE_CARBON
2756 #define HAVE_WINDOW_SYSTEM
2757 #define HAVE_MOUSE
2758 #endif
2759
2760 /* Define USER_FULL_NAME to return a string
2761    that is the user's full name.
2762    It can assume that the variable `pw'
2763    points to the password file entry for this user.
2764
2765    At some sites, the pw_gecos field contains
2766    the user's full name.  If neither this nor any other
2767    field contains the right thing, use pw_name,
2768    giving the user's login name, since that is better than nothing.  */
2769 #define USER_FULL_NAME pw->pw_gecos
2770
2771 /* Define AMPERSAND_FULL_NAME if you use the convention
2772    that & in the full name stands for the login id.  */
2773 /* Turned on June 1996 supposing nobody will mind it.  */
2774 #define AMPERSAND_FULL_NAME
2775
2776 /* We have blockinput.h.  */
2777 #define DO_BLOCK_INPUT
2778
2779 /* Define HAVE_SOUND if we have sound support.  We know it works
2780    and compiles only on the specified platforms.   For others,
2781    it probably doesn't make sense to try.  */
2782
2783 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2784 #ifdef HAVE_MACHINE_SOUNDCARD_H
2785 #define HAVE_SOUND 1
2786 #endif
2787 #ifdef HAVE_SYS_SOUNDCARD_H
2788 #define HAVE_SOUND 1
2789 #endif
2790 #ifdef HAVE_SOUNDCARD_H
2791 #define HAVE_SOUND 1
2792 #endif
2793 #ifdef HAVE_ALSA
2794 #define HAVE_SOUND 1
2795 #endif
2796 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2797
2798 /* If using GNU, then support inline function declarations. */
2799 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2800    generally, because even if non-gcc compilers accept `inline', they
2801    may reject `extern inline'.  */
2802 #if defined (__GNUC__) && defined (OPTIMIZE)
2803 #define INLINE __inline__
2804 #else
2805 #define INLINE
2806 #endif
2807
2808 /* Include the os and machine dependent files.  */
2809 #include config_opsysfile
2810 #include config_machfile
2811
2812 /* Load in the conversion definitions if this system
2813    needs them and the source file being compiled has not
2814    said to inhibit this.  There should be no need for you
2815    to alter these lines.  */
2816
2817 #ifdef SHORTNAMES
2818 #ifndef NO_SHORTNAMES
2819 #include "../shortnames/remap.h"
2820 #endif /* not NO_SHORTNAMES */
2821 #endif /* SHORTNAMES */
2822
2823 /* If no remapping takes place, static variables cannot be dumped as
2824    pure, so don't worry about the `static' keyword. */
2825 #ifdef NO_REMAP
2826 #undef static
2827 #endif
2828
2829 /* Define `subprocesses' should be defined if you want to
2830    have code for asynchronous subprocesses
2831    (as used in M-x compile and M-x shell).
2832    These do not work for some USG systems yet;
2833    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2834
2835 #ifndef VMS
2836 #ifndef USG
2837 /* #define subprocesses */
2838 #endif
2839 #endif
2840
2841 /* SIGTYPE is the macro we actually use.  */
2842 #ifndef SIGTYPE
2843 #define SIGTYPE RETSIGTYPE
2844 #endif
2845
2846 #ifdef emacs /* Don't do this for lib-src.  */
2847 /* Tell regex.c to use a type compatible with Emacs.  */
2848 #define RE_TRANSLATE_TYPE Lisp_Object
2849 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2850 #ifdef make_number
2851 /* If make_number is a macro, use it.  */
2852 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2853 #else
2854 /* If make_number is a function, avoid it.  */
2855 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2856 #endif
2857 #endif
2858
2859 /* Avoid link-time collision with system mktime if we will use our own.  */
2860 #if ! HAVE_MKTIME || BROKEN_MKTIME
2861 #define mktime emacs_mktime
2862 #endif
2863
2864 #define my_strftime nstrftime   /* for strftime.c */
2865
2866 /* The rest of the code currently tests the CPP symbol BSTRING.
2867    Override any claims made by the system-description files.
2868    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2869 #undef BSTRING
2870 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2871 #define BSTRING
2872 #endif
2873
2874 /* Some of the files of Emacs which are intended for use with other
2875    programs assume that if you have a config.h file, you must declare
2876    the type of getenv.
2877
2878    This declaration shouldn't appear when alloca.s or Makefile.in
2879    includes config.h.  */
2880 #ifndef NOT_C_CODE
2881 extern char *getenv ();
2882 #endif
2883
2884 /* These default definitions are good for almost all machines.
2885    The exceptions override them in m/MACHINE.h.  */
2886
2887 #ifndef BITS_PER_CHAR
2888 #define BITS_PER_CHAR 8
2889 #endif
2890
2891 #ifndef BITS_PER_SHORT
2892 #define BITS_PER_SHORT 16
2893 #endif
2894
2895 /* Note that lisp.h uses this in a preprocessor conditional, so it
2896    would not work to use sizeof.  That being so, we do all of them
2897    without sizeof, for uniformity's sake.  */
2898 #ifndef BITS_PER_INT
2899 #define BITS_PER_INT 32
2900 #endif
2901
2902 #ifndef BITS_PER_LONG
2903 #ifdef _LP64
2904 #define BITS_PER_LONG 64
2905 #else
2906 #define BITS_PER_LONG 32
2907 #endif
2908 #endif
2909
2910 /* Define if the compiler supports function prototypes.  It may do so
2911    but not define __STDC__ (e.g. DEC C by default) or may define it as
2912    zero.  */
2913 #undef PROTOTYPES
2914 /* For mktime.c:  */
2915 #ifndef __P
2916 # if defined PROTOTYPES
2917 #  define __P(args) args
2918 # else
2919 #  define __P(args) ()
2920 # endif  /* GCC.  */
2921 #endif /* __P */
2922
2923 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2924 #ifndef NOT_C_CODE
2925 #ifdef HAVE_STRING_H
2926 #include "string.h"
2927 #endif
2928 #ifdef HAVE_STRINGS_H
2929 #include "strings.h"  /* May be needed for bcopy & al. */
2930 #endif
2931 #ifdef HAVE_STDLIB_H
2932 #include <stdlib.h>
2933 #endif
2934 #ifndef __GNUC__
2935 # ifdef HAVE_ALLOCA_H
2936 #  include <alloca.h>
2937 # else /* AIX files deal with #pragma.  */
2938 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2939 char *alloca ();
2940 #  endif
2941 # endif /* HAVE_ALLOCA_H */
2942 #endif /* __GNUC__ */
2943 #ifndef HAVE_SIZE_T
2944 typedef unsigned size_t;
2945 #endif
2946 #endif /* NOT_C_CODE */
2947
2948 /* Define HAVE_X_I18N if we have usable i18n support.  */
2949
2950 #ifdef HAVE_X11R6
2951 #define HAVE_X_I18N
2952 #elif !defined X11R5_INHIBIT_I18N
2953 #define HAVE_X_I18N
2954 #endif
2955
2956 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2957
2958 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2959 #define HAVE_X11R6_XIM
2960 #endif
2961
2962 /* Should we enable expensive run-time checking of data types?  */
2963 #undef ENABLE_CHECKING
2964
2965 #if defined __GNUC__ && (__GNUC__ > 2 \
2966                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2967 #define NO_RETURN       __attribute__ ((__noreturn__))
2968 #else
2969 #define NO_RETURN       /* nothing */
2970 #endif
2971
2972 /* These won't be used automatically yet.  We also need to know, at least,
2973    that the stack is continuous.  */
2974 #ifdef __GNUC__
2975 #  ifndef GC_SETJMP_WORKS
2976   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2977      see NON_SAVING_SETJMP in the target descriptions.  */
2978   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2979      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2980      Fixme: Deal with SVR3.  */
2981 #    define GC_SETJMP_WORKS 1
2982 #  endif
2983 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2984 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2985 #  endif
2986 #endif
2987
2988 #ifndef HAVE_BCOPY
2989 #define bcopy(a,b,s) memcpy (b,a,s)
2990 #endif
2991 #ifndef HAVE_BZERO
2992 #define bzero(a,s) memset (a,0,s)
2993 #endif
2994 #ifndef HAVE_BCMP
2995 #define BCMP memcmp
2996 #endif
2997
2998 #endif /* EMACS_CONFIG_H */
2999
3000 /*
3001 Local Variables:
3002 mode: c
3003 End:
3004 */
3005 ])dnl
3006
3007 #### Report on what we decided to do.
3008 #### Report GTK as a toolkit, even if it doesn't use Xt.
3009 #### It makes printing result more understandable as using GTK sets
3010 #### toolkit_scroll_bars to yes by default.
3011 if test "${HAVE_GTK}" = "yes"; then
3012   USE_X_TOOLKIT=GTK
3013 fi
3014
3015 echo "
3016 Configured for \`${canonical}'.
3017
3018   Where should the build process find the source code?    ${srcdir}
3019   What operating system and machine description files should Emacs use?
3020         \`${opsysfile}' and \`${machfile}'
3021   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3022   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3023   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3024   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3025   What window system should Emacs use?                    ${window_system}
3026   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3027
3028 if test -n "${x_includes}"; then
3029 echo "  Where do we find X Windows header files?                ${x_includes}"
3030 else
3031 echo "  Where do we find X Windows header files?                Standard dirs"
3032 fi
3033 if test -n "${x_libraries}"; then
3034 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3035 else
3036 echo "  Where do we find X Windows libraries?                   Standard dirs"
3037 fi
3038
3039 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3040 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3041 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3042 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3043 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3044 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3045 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3046 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3047 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3048 echo "  Does Emacs use a font backend?                          ${USE_FONT_BACKEND}"
3049
3050 if test "${USE_FONT_BACKEND}" = "yes"; then
3051   echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3052   echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3053   echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3054   echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3055 fi
3056 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3057 echo
3058
3059 if test $USE_XASSERTS = yes; then
3060    echo "  Compiling with asserts turned on."
3061    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3062    echo
3063 fi
3064
3065 if test "$USE_X_TOOLKIT" = GTK; then
3066   case "$canonical" in
3067   *cygwin*)
3068     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3069   will probably get a crash on startup.  If this happens, please use another
3070   toolkit for Emacs.  See etc/PROBLEMS for more information."
3071   ;;
3072   esac
3073 fi
3074
3075
3076 if test "$HAVE_CARBON" = "yes"; then
3077    echo
3078    echo "Warning: The Mac Carbon port is currently unsupported and has
3079 known problems.  It is not recommended for use by non-developers.
3080 Read the emacs-devel archives for more information."
3081    echo
3082 fi
3083
3084 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3085   echo "D-Bus integration has been tested for GNU/Linux only."
3086   echo
3087 fi
3088
3089
3090 # Remove any trailing slashes in these variables.
3091 [test "${prefix}" != NONE &&
3092   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3093 test "${exec_prefix}" != NONE &&
3094   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3095
3096 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3097 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3098 ## from Makefile.c can correctly provide the arg `-traditional' to the
3099 ## C preprocessor.
3100
3101 AC_EGREP_CPP(yes..yes,
3102         [yes..yes],
3103         CPP_NEED_TRADITIONAL=no,
3104         CPP_NEED_TRADITIONAL=yes)
3105
3106 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3107         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3108         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3109         lwlib/Makefile lisp/Makefile leim/Makefile, [
3110
3111 ### Make the necessary directories, if they don't exist.
3112 for dir in etc lisp ; do
3113   test -d ${dir} || mkdir ${dir}
3114 done
3115
3116 # Build src/Makefile from ${srcdir}/src/Makefile.c
3117 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3118 # This must be done after src/config.h is built, since we rely on that file.
3119
3120 # Now get this: Some word that is part of the ${srcdir} directory name
3121 # or the ${configuration} value might, just might, happen to be an
3122 # identifier like `sun4' or `i386' or something, and be predefined by
3123 # the C preprocessor to some helpful value like 1, or maybe the empty
3124 # string.  Needless to say consequent macro substitutions are less
3125 # than conducive to the makefile finding the correct directory.
3126 [undefs="`echo $top_srcdir $configuration $canonical |
3127 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3128     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3129 `"]
3130
3131 echo creating src/epaths.h
3132 ${MAKE-make} epaths-force
3133
3134 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3135 # `..' to `. .'  unless invoked with -traditional
3136
3137 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3138   CPPFLAGS="$CPPFLAGS -traditional"
3139 fi
3140
3141 echo creating lib-src/Makefile
3142 ( cd lib-src
3143   rm -f junk.c junk1.c junk2.c
3144   sed -e '/start of cpp stuff/q' \
3145       < Makefile.c > junk1.c
3146   sed -e '1,/start of cpp stuff/d'\
3147       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3148       < Makefile.c > junk.c
3149   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3150       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3151   cat junk1.c junk2.c > Makefile.new
3152   rm -f junk.c junk1.c junk2.c
3153   chmod 444 Makefile.new
3154   mv -f Makefile.new Makefile
3155 )
3156
3157 echo creating src/Makefile
3158 ( cd src
3159   rm -f junk.c junk1.c junk2.c
3160   sed -e '/start of cpp stuff/q' \
3161       < Makefile.c > junk1.c
3162   sed -e '1,/start of cpp stuff/d'\
3163       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3164       < Makefile.c > junk.c
3165   if test -f ${srcdir}/admin/unidata/UnicodeData.txt; then
3166     echo creating ${srcdir}/admin/unidata/Makefile
3167     cp ${srcdir}/admin/unidata/Makefile.in ${srcdir}/admin/unidata/Makefile
3168     CPPFLAGS="$CPPFLAGS -DHAVE_UNIDATA"
3169   fi
3170   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3171       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3172   cat junk1.c junk2.c > Makefile.new
3173   rm -f junk.c junk1.c junk2.c
3174   chmod 444 Makefile.new
3175   mv -f Makefile.new Makefile
3176 )
3177
3178 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3179   echo creating src/.gdbinit
3180   echo source $srcdir/src/.gdbinit > src/.gdbinit
3181 fi
3182
3183 # This is how we know whether to re-run configure in certain cases.
3184 touch src/config.stamp
3185
3186 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3187
3188 m4_if(dnl       Do not change this comment
3189    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3190 )dnl