lisp/macros.el

   1 ;;; macros.el --- non-primitive commands for keyboard macros
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1995, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: abbrev
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extension commands for keyboard macros.  These permit you to assign
  27 ;; a name to the last-defined keyboard macro, expand and insert the
  28 ;; lisp corresponding to a macro, query the user from within a macro,
  29 ;; or apply a macro to each line in the reason.
  30
  31 ;;; Code:
  32
  33 ;;;###autoload
  34 (defun name-last-kbd-macro (symbol)
  35   "Assign a name to the last keyboard macro defined.
  36 Argument SYMBOL is the name to define.
  37 The symbol's function definition becomes the keyboard macro string.
  38 Such a \"function\" cannot be called from Lisp, but it is a valid editor command."
  39   (interactive "SName for last kbd macro: ")
  40   (or last-kbd-macro
  41       (error "No keyboard macro defined"))
  42   (and (fboundp symbol)
  43        (not (stringp (symbol-function symbol)))
  44        (not (vectorp (symbol-function symbol)))
  45        (error "Function %s is already defined and not a keyboard macro"
  46               symbol))
  47   (if (string-equal symbol "")
  48       (error "No command name given"))
  49   (fset symbol last-kbd-macro))
  50
  51 ;;;###autoload
  52 (defun insert-kbd-macro (macroname &optional keys)
  53   "Insert in buffer the definition of kbd macro NAME, as Lisp code.
  54 Optional second arg KEYS means also record the keys it is on
  55 \(this is the prefix argument, when calling interactively).
  56
  57 This Lisp code will, when executed, define the kbd macro with the same
  58 definition it has now.  If you say to record the keys, the Lisp code
  59 will also rebind those keys to the macro.  Only global key bindings
  60 are recorded since executing this Lisp code always makes global
  61 bindings.
  62
  63 To save a kbd macro, visit a file of Lisp code such as your `~/.emacs',
  64 use this command, and then save the file."
  65   (interactive (list (intern (completing-read "Insert kbd macro (name): "
  66                                               obarray
  67                                               (lambda (elt)
  68                                                 (and (fboundp elt)
  69                                                      (or (stringp (symbol-function elt))
  70                                                          (vectorp (symbol-function elt))
  71                                                          (get elt 'kmacro))))
  72                                               t))
  73                      current-prefix-arg))
  74   (let (definition)
  75     (if (string= (symbol-name macroname) "")
  76         (progn
  77           (setq macroname 'last-kbd-macro definition last-kbd-macro)
  78           (insert "(setq "))
  79       (setq definition (symbol-function macroname))
  80       (insert "(fset '"))
  81     (prin1 macroname (current-buffer))
  82     (insert "\n   ")
  83     (if (stringp definition)
  84         (let ((beg (point)) end)
  85           (prin1 definition (current-buffer))
  86           (setq end (point-marker))
  87           (goto-char beg)
  88           (while (< (point) end)
  89             (let ((char (following-char)))
  90               (cond ((= char 0)
  91                      (delete-region (point) (1+ (point)))
  92                      (insert "\\C-@"))
  93                     ((< char 27)
  94                      (delete-region (point) (1+ (point)))
  95                      (insert "\\C-" (+ 96 char)))
  96                     ((= char ?\C-\\)
  97                      (delete-region (point) (1+ (point)))
  98                      (insert "\\C-\\\\"))
  99                     ((< char 32)
 100                      (delete-region (point) (1+ (point)))
 101                      (insert "\\C-" (+ 64 char)))
 102                     ((< char 127)
 103                      (forward-char 1))
 104                     ((= char 127)
 105                      (delete-region (point) (1+ (point)))
 106                      (insert "\\C-?"))
 107                     ((= char 128)
 108                      (delete-region (point) (1+ (point)))
 109                      (insert "\\M-\\C-@"))
 110                     ((= char (aref "\M-\C-\\" 0))
 111                      (delete-region (point) (1+ (point)))
 112                      (insert "\\M-\\C-\\\\"))
 113                     ((< char 155)
 114                      (delete-region (point) (1+ (point)))
 115                      (insert "\\M-\\C-" (- char 32)))
 116                     ((< char 160)
 117                      (delete-region (point) (1+ (point)))
 118                      (insert "\\M-\\C-" (- char 64)))
 119                     ((= char (aref "\M-\\" 0))
 120                      (delete-region (point) (1+ (point)))
 121                      (insert "\\M-\\\\"))
 122                     ((< char 255)
 123                      (delete-region (point) (1+ (point)))
 124                      (insert "\\M-" (- char 128)))
 125                     ((= char 255)
 126                      (delete-region (point) (1+ (point)))
 127                      (insert "\\M-\\C-?"))))))
 128       (if (vectorp definition)
 129           (let ((len (length definition)) (i 0) char mods)
 130             (while (< i len)
 131               (insert (if (zerop i) ?\[ ?\s))
 132               (setq char (aref definition i)
 133                     i (1+ i))
 134               (if (not (numberp char))
 135                   (prin1 char (current-buffer))
 136                 (princ (prin1-char char) (current-buffer))))
 137             (insert ?\]))
 138         (prin1 definition (current-buffer))))
 139     (insert ")\n")
 140     (if keys
 141         (let ((keys (where-is-internal macroname '(keymap))))
 142           (while keys
 143             (insert "(global-set-key ")
 144             (prin1 (car keys) (current-buffer))
 145             (insert " '")
 146             (prin1 macroname (current-buffer))
 147             (insert ")\n")
 148             (setq keys (cdr keys)))))))
 149
 150 ;;;###autoload
 151 (defun kbd-macro-query (flag)
 152   "Query user during kbd macro execution.
 153   With prefix argument, enters recursive edit, reading keyboard
 154 commands even within a kbd macro.  You can give different commands
 155 each time the macro executes.
 156   Without prefix argument, asks whether to continue running the macro.
 157 Your options are: \\<query-replace-map>
 158 \\[act] Finish this iteration normally and continue with the next.
 159 \\[skip]        Skip the rest of this iteration, and start the next.
 160 \\[exit]        Stop the macro entirely right now.
 161 \\[recenter]    Redisplay the screen, then ask again.
 162 \\[edit]        Enter recursive edit; ask again when you exit from that."
 163   (interactive "P")
 164   (or executing-kbd-macro
 165       defining-kbd-macro
 166       (error "Not defining or executing kbd macro"))
 167   (if flag
 168       (let (executing-kbd-macro defining-kbd-macro)
 169         (recursive-edit))
 170     (if (not executing-kbd-macro)
 171         nil
 172       (let ((loop t)
 173             (msg (substitute-command-keys
 174                   "Proceed with macro?\\<query-replace-map>\
 175  (\\[act], \\[skip], \\[exit], \\[recenter], \\[edit]) ")))
 176         (while loop
 177           (let ((key (let ((executing-kbd-macro nil)
 178                            (defining-kbd-macro nil))
 179                        (message "%s" msg)
 180                        (read-event)))
 181                 def)
 182             (setq key (vector key))
 183             (setq def (lookup-key query-replace-map key))
 184             (cond ((eq def 'act)
 185                    (setq loop nil))
 186                   ((eq def 'skip)
 187                    (setq loop nil)
 188                    (setq executing-kbd-macro ""))
 189                   ((eq def 'exit)
 190                    (setq loop nil)
 191                    (setq executing-kbd-macro t))
 192                   ((eq def 'recenter)
 193                    (recenter nil))
 194                   ((eq def 'edit)
 195                    (let (executing-kbd-macro defining-kbd-macro)
 196                      (recursive-edit)))
 197                   ((eq def 'quit)
 198                    (setq quit-flag t))
 199                   (t
 200                    (or (eq def 'help)
 201                        (ding))
 202                    (with-output-to-temp-buffer "*Help*"
 203                      (princ
 204                       (substitute-command-keys
 205                        "Specify how to proceed with keyboard macro execution.
 206 Possibilities: \\<query-replace-map>
 207 \\[act] Finish this iteration normally and continue with the next.
 208 \\[skip]        Skip the rest of this iteration, and start the next.
 209 \\[exit]        Stop the macro entirely right now.
 210 \\[recenter]    Redisplay the screen, then ask again.
 211 \\[edit]        Enter recursive edit; ask again when you exit from that."))
 212                      (with-current-buffer standard-output
 213                        (help-mode)))))))))))
 214
 215 ;;;###autoload
 216 (defun apply-macro-to-region-lines (top bottom &optional macro)
 217   "Apply last keyboard macro to all lines in the region.
 218 For each line that begins in the region, move to the beginning of
 219 the line, and run the last keyboard macro.
 220
 221 When called from lisp, this function takes two arguments TOP and
 222 BOTTOM, describing the current region.  TOP must be before BOTTOM.
 223 The optional third argument MACRO specifies a keyboard macro to
 224 execute.
 225
 226 This is useful for quoting or unquoting included text, adding and
 227 removing comments, or producing tables where the entries are regular.
 228
 229 For example, in Usenet articles, sections of text quoted from another
 230 author are indented, or have each line start with `>'.  To quote a
 231 section of text, define a keyboard macro which inserts `>', put point
 232 and mark at opposite ends of the quoted section, and use
 233 `\\[apply-macro-to-region-lines]' to mark the entire section.
 234
 235 Suppose you wanted to build a keyword table in C where each entry
 236 looked like this:
 237
 238     { \"foo\", foo_data, foo_function },
 239     { \"bar\", bar_data, bar_function },
 240     { \"baz\", baz_data, baz_function },
 241
 242 You could enter the names in this format:
 243
 244     foo
 245     bar
 246     baz
 247
 248 and write a macro to massage a word into a table entry:
 249
 250     \\C-x (
 251        \\M-d { \"\\C-y\", \\C-y_data, \\C-y_function },
 252     \\C-x )
 253
 254 and then select the region of un-tablified names and use
 255 `\\[apply-macro-to-region-lines]' to build the table from the names."
 256   (interactive "r")
 257   (or macro
 258       (progn
 259         (if (null last-kbd-macro)
 260             (error "No keyboard macro has been defined"))
 261         (setq macro last-kbd-macro)))
 262   (save-excursion
 263     (let ((end-marker (copy-marker bottom))
 264           next-line-marker)
 265       (goto-char top)
 266       (if (not (bolp))
 267           (forward-line 1))
 268       (setq next-line-marker (point-marker))
 269       (while (< next-line-marker end-marker)
 270         (goto-char next-line-marker)
 271         (save-excursion
 272           (forward-line 1)
 273           (set-marker next-line-marker (point)))
 274         (save-excursion
 275           (let ((mark-active nil))
 276             (execute-kbd-macro macro))))
 277       (set-marker end-marker nil)
 278       (set-marker next-line-marker nil))))
 279
 280 ;;;###autoload (define-key ctl-x-map "q" 'kbd-macro-query)
 281
 282 (provide 'macros)
 283
 284 ;; arch-tag: 346ed1a5-1220-4bc8-b533-961ee704361f
 285 ;;; macros.el ends here