lisp/scroll-bar.el

   1 ;;; scroll-bar.el --- window system-independent scroll bar support.
   2
   3 ;; Copyright (C) 1993, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Window-system-independent bindings of mouse clicks on the scroll bar.
  28 ;; Presently emulates the scroll-bar behavior of xterm.
  29
  30 ;;; Code:
  31
  32 (require 'mouse)
  33
  34 \f
  35 ;;;; Utilities.
  36
  37 (defun scroll-bar-event-ratio (event)
  38   "Given a scroll bar event EVENT, return the scroll bar position as a ratio.
  39 The value is a cons cell (PORTION . WHOLE) containing two integers
  40 whose ratio gives the event's vertical position in the scroll bar, with 0
  41 referring to the top and 1 to the bottom."
  42   (nth 2 event))
  43
  44 (defun scroll-bar-scale (num-denom whole)
  45   "Given a pair (NUM . DENOM) and WHOLE, return (/ (* NUM WHOLE) DENOM).
  46 This is handy for scaling a position on a scroll bar into real units,
  47 like buffer positions.  If SCROLL-BAR-POS is the (PORTION . WHOLE) pair
  48 from a scroll bar event, then (scroll-bar-scale SCROLL-BAR-POS
  49 \(buffer-size)) is the position in the current buffer corresponding to
  50 that scroll bar position."
  51   ;; We multiply before we divide to maintain precision.
  52   ;; We use floating point because the product of a large buffer size
  53   ;; with a large scroll bar portion can easily overflow a lisp int.
  54   (truncate (/ (* (float (car num-denom)) whole) (cdr num-denom))))
  55
  56 \f
  57 ;;;; Helpful functions for enabling and disabling scroll bars.
  58
  59 (defun scroll-bar-mode (flag)
  60   "Toggle display of vertical scroll bars on each frame.
  61 This command applies to all frames that exist and frames to be
  62 created in the future.
  63 With a numeric argument, if the argument is negative,
  64 turn off scroll bars; otherwise, turn on scroll bars."
  65   (interactive "P")
  66   (if flag (setq flag (prefix-numeric-value flag)))
  67
  68   ;; Obtain the current setting by looking at default-frame-alist.
  69   (let ((scroll-bar-mode
  70          (let ((assq (assq 'vertical-scroll-bars default-frame-alist)))
  71            (if assq (cdr assq) t))))
  72
  73     ;; Tweedle it according to the argument.
  74     (setq scroll-bar-mode (if (null flag) (not scroll-bar-mode)
  75                             (or (not (numberp flag)) (>= flag 0))))
  76
  77     ;; Apply it to default-frame-alist.
  78     (mapcar
  79      (function
  80       (lambda (param-name)
  81         (let ((parameter (assq param-name default-frame-alist)))
  82           (if (consp parameter)
  83               (setcdr parameter scroll-bar-mode)
  84             (setq default-frame-alist
  85                   (cons (cons param-name scroll-bar-mode)
  86                         default-frame-alist))))))
  87      '(vertical-scroll-bars horizontal-scroll-bars))
  88
  89     ;; Apply it to existing frames.
  90     (let ((frames (frame-list)))
  91       (while frames
  92         (modify-frame-parameters
  93          (car frames)
  94          (list (cons 'vertical-scroll-bars scroll-bar-mode)
  95                (cons 'horizontal-scroll-bars scroll-bar-mode)))
  96         (setq frames (cdr frames))))))
  97 \f
  98 ;;;; Buffer navigation using the scroll bar.
  99
 100 ;;; This was used for up-events on button 2, but no longer.
 101 (defun scroll-bar-set-window-start (event)
 102   "Set the window start according to where the scroll bar is dragged.
 103 EVENT should be a scroll bar click or drag event."
 104   (interactive "e")
 105   (let* ((end-position (event-end event))
 106          (window (nth 0 end-position))
 107          (portion-whole (nth 2 end-position)))
 108     (save-excursion
 109       (set-buffer (window-buffer window))
 110       (save-excursion
 111         (goto-char (+ (point-min)
 112                       (scroll-bar-scale portion-whole
 113                                         (- (point-max) (point-min)))))
 114         (beginning-of-line)
 115         (set-window-start window (point))))))
 116
 117 (defun scroll-bar-drag-position (portion-whole)
 118   "Calculate new window start for drag event."
 119   (save-excursion
 120     (goto-char (+ (point-min)
 121                   (scroll-bar-scale portion-whole
 122                                     (- (point-max) (point-min)))))
 123     (beginning-of-line)
 124     (point)))
 125
 126 (defun scroll-bar-maybe-set-window-start (event)
 127   "Set the window start according to where the scroll bar is dragged.
 128 Only change window start if the new start is substantially different.
 129 EVENT should be a scroll bar click or drag event."
 130   (interactive "e")
 131   (let* ((end-position (event-end event))
 132          (window (nth 0 end-position))
 133          (portion-whole (nth 2 end-position))
 134          (next-portion-whole (cons (1+ (car portion-whole))
 135                                    (cdr portion-whole)))
 136          portion-start
 137          next-portion-start
 138          (current-start (window-start window)))
 139     (save-excursion
 140       (set-buffer (window-buffer window))
 141       (setq portion-start (scroll-bar-drag-position portion-whole))
 142       (setq next-portion-start (max
 143                                 (scroll-bar-drag-position next-portion-whole)
 144                                 (1+ portion-start)))
 145       (if (or (> current-start next-portion-start)
 146               (< current-start portion-start))
 147           (set-window-start window portion-start)))))
 148
 149 ;; Scroll the window to the proper position for EVENT.
 150 (defun scroll-bar-drag-1 (event)
 151   (let* ((start-position (event-start event))
 152          (window (nth 0 start-position))
 153          (portion-whole (nth 2 start-position)))
 154     (save-excursion
 155       (set-buffer (window-buffer window))
 156       ;; Calculate position relative to the accessible part of the buffer.
 157       (goto-char (+ (point-min)
 158                     (scroll-bar-scale portion-whole
 159                                       (- (point-max) (point-min)))))
 160       (beginning-of-line)
 161       (set-window-start window (point)))))
 162
 163 (defun scroll-bar-drag (event)
 164   "Scroll the window by dragging the scroll bar slider.
 165 If you click outside the slider, the window scrolls to bring the slider there."
 166   (interactive "e")
 167   (let* (done
 168          (echo-keystrokes 0))
 169     (or point-before-scroll
 170         (setq point-before-scroll (point)))
 171     ;; Our scrolling can move point; don't let that clear point-before-scroll.
 172     (let (point-before-scroll)
 173       (scroll-bar-drag-1 event)
 174       (track-mouse
 175         (while (not done)
 176           (setq event (read-event))
 177           (if (eq (car-safe event) 'mouse-movement)
 178               (setq event (read-event)))
 179           (cond ((eq (car-safe event) 'scroll-bar-movement)
 180                  (scroll-bar-drag-1 event))
 181                 (t
 182                  ;; Exit when we get the drag event; ignore that event.
 183                  (setq done t)))))
 184       (sit-for 0))))
 185
 186 (defun scroll-bar-scroll-down (event)
 187   "Scroll the window's top line down to the location of the scroll bar click.
 188 EVENT should be a scroll bar click."
 189   (interactive "e")
 190   (let ((old-selected-window (selected-window)))
 191     (unwind-protect
 192         (progn
 193           (let* ((end-position (event-end event))
 194                  (window (nth 0 end-position))
 195                  (portion-whole (nth 2 end-position)))
 196             (let (point-before-scroll)
 197               (select-window window))
 198             (or point-before-scroll
 199                 (setq point-before-scroll (point)))
 200             (let (point-before-scroll)
 201               (scroll-down
 202                (scroll-bar-scale portion-whole (1- (window-height)))))))
 203       (select-window old-selected-window))))
 204
 205 (defun scroll-bar-scroll-up (event)
 206   "Scroll the line next to the scroll bar click to the top of the window.
 207 EVENT should be a scroll bar click."
 208   (interactive "e")
 209   (let ((old-selected-window (selected-window)))
 210     (unwind-protect
 211         (progn
 212           (let* ((end-position (event-end event))
 213                  (window (nth 0 end-position))
 214                  (portion-whole (nth 2 end-position)))
 215             (let (point-before-scroll)
 216               (select-window window))
 217             (or point-before-scroll
 218                 (setq point-before-scroll (point)))
 219             (let (point-before-scroll)
 220               (scroll-up
 221                (scroll-bar-scale portion-whole (1- (window-height)))))))
 222       (select-window old-selected-window))))
 223
 224 \f
 225 ;;;; Bindings.
 226
 227 ;;; For now, we'll set things up to work like xterm.
 228 (global-set-key [vertical-scroll-bar mouse-1] 'scroll-bar-scroll-up)
 229 (global-set-key [vertical-scroll-bar drag-mouse-1] 'scroll-bar-scroll-up)
 230
 231 (global-set-key [vertical-scroll-bar down-mouse-2] 'scroll-bar-drag)
 232
 233 (global-set-key [vertical-scroll-bar mouse-3] 'scroll-bar-scroll-down)
 234 (global-set-key [vertical-scroll-bar drag-mouse-3] 'scroll-bar-scroll-down)
 235
 236 \f
 237 (provide 'scroll-bar)
 238
 239 ;;; scroll-bar.el ends here