lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   4 ;; Keywords: multimedia
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27
  28 (defgroup image ()
  29   "Image support."
  30   :group 'multimedia)
  31
  32
  33 (defconst image-type-regexps
  34   '(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  35     ("\\`P[1-6]" . pbm)
  36     ("\\`GIF8" . gif)
  37     ("\\`\211PNG\r\n" . png)
  38     ("\\`[\t\n\r ]*#define" . xbm)
  39     ("\\`\\(MM\0\\*\\|II\\*\0\\)" . tiff)
  40     ("\\`[\t\n\r ]*%!PS" . postscript)
  41     ("\\`\xff\xd8" . (image-jpeg-p . jpeg)))
  42   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  43 When the first bytes of an image file match REGEXP, it is assumed to
  44 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  45 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  46 with one argument, a string containing the image data.  If PREDICATE returns
  47 a non-nil value, TYPE is the image's type ")
  48
  49
  50 (defun image-jpeg-p (data)
  51   "Value is non-nil if DATA, a string, consists of JFIF image data."
  52   (when (string-match "\\`\xff\xd8" data)
  53     (catch 'jfif
  54       (let ((len (length data)) (i 2))
  55         (while (< i len)
  56           (when (/= (aref data i) #xff)
  57             (throw 'jfif nil))
  58           (setq i (1+ i))
  59           (when (>= (+ i 2) len)
  60             (throw 'jfif nil))
  61           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
  62                            (aref data (+ i 2))))
  63                 (code (aref data i)))
  64             (when (and (>= code #xe0) (<= code #xef))
  65               ;; APP0 LEN1 LEN2 "JFIF\0"
  66               (throw 'jfif
  67                      (string-match "JFIF" (substring data i (+ i nbytes)))))
  68             (setq i (+ i 1 nbytes))))))))
  69
  70
  71 ;;;###autoload
  72 (defun image-type-from-data (data)
  73   "Determine the image type from image data DATA.
  74 Value is a symbol specifying the image type or nil if type cannot
  75 be determined."
  76   (let ((types image-type-regexps)
  77         type)
  78     (while (and types (null type))
  79       (let ((regexp (car (car types)))
  80             (image-type (cdr (car types))))
  81         (when (or (and (symbolp image-type)
  82                        (string-match regexp data))
  83                   (and (consp image-type)
  84                        (funcall (car image-type) data)
  85                        (setq image-type (cdr image-type))))
  86           (setq type image-type))
  87         (setq types (cdr types))))
  88     type))
  89
  90
  91 ;;;###autoload
  92 (defun image-type-from-file-header (file)
  93   "Determine the type of image file FILE from its first few bytes.
  94 Value is a symbol specifying the image type, or nil if type cannot
  95 be determined."
  96   (unless (file-name-directory file)
  97     (setq file (expand-file-name file data-directory)))
  98   (setq file (expand-file-name file))
  99   (let ((header (with-temp-buffer
 100                   (insert-file-contents-literally file nil 0 256)
 101                   (buffer-string))))
 102     (image-type-from-data header)))
 103
 104
 105 ;;;###autoload
 106 (defun image-type-available-p (type)
 107   "Value is non-nil if image type TYPE is available.
 108 Image types are symbols like `xbm' or `jpeg'."
 109   (and (boundp 'image-types) (not (null (memq type image-types)))))
 110
 111
 112 ;;;###autoload
 113 (defun create-image (file-or-data &optional type data-p &rest props)
 114   "Create an image.
 115 FILE-OR-DATA is an image file name or image data.
 116 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 117 or nil, try to determine the image type from its first few bytes
 118 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 119 use its file extension as image type.
 120 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 121 Optional PROPS are additional image attributes to assign to the image,
 122 like, e.g. `:mask MASK'.
 123 Value is the image created, or nil if images of type TYPE are not supported."
 124   (when (and (not data-p) (not (stringp file-or-data)))
 125     (error "Invalid image file name `%s'" file-or-data))
 126   (cond ((null data-p)
 127          ;; FILE-OR-DATA is a file name.
 128          (unless (or type
 129                      (setq type (image-type-from-file-header file-or-data)))
 130            (let ((extension (file-name-extension file-or-data)))
 131              (unless extension
 132                (error "Cannot determine image type"))
 133              (setq type (intern extension)))))
 134         (t
 135          ;; FILE-OR-DATA contains image data.
 136          (unless type
 137            (setq type (image-type-from-data file-or-data)))))
 138   (unless type
 139     (error "Cannot determine image type"))
 140   (unless (symbolp type)
 141     (error "Invalid image type `%s'" type))
 142   (when (image-type-available-p type)
 143     (append (list 'image :type type (if data-p :data :file) file-or-data)
 144             props)))
 145
 146
 147 ;;;###autoload
 148 (defun put-image (image pos &optional string area)
 149   "Put image IMAGE in front of POS in the current buffer.
 150 IMAGE must be an image created with `create-image' or `defimage'.
 151 IMAGE is displayed by putting an overlay into the current buffer with a
 152 `before-string' STRING that has a `display' property whose value is the
 153 image.  STRING is defaulted if you omit it.
 154 POS may be an integer or marker.
 155 AREA is where to display the image.  AREA nil or omitted means
 156 display it in the text area, a value of `left-margin' means
 157 display it in the left marginal area, a value of `right-margin'
 158 means display it in the right marginal area."
 159   (unless string (setq string "x"))
 160   (let ((buffer (current-buffer)))
 161     (unless (eq (car-safe image) 'image)
 162       (error "Not an image: %s" image))
 163     (unless (or (null area) (memq area '(left-margin right-margin)))
 164       (error "Invalid area %s" area))
 165     (setq string (copy-sequence string))
 166     (let ((overlay (make-overlay pos pos buffer))
 167           (prop (if (null area) image (list (list 'margin area) image))))
 168       (put-text-property 0 (length string) 'display prop string)
 169       (overlay-put overlay 'put-image t)
 170       (overlay-put overlay 'before-string string))))
 171
 172
 173 ;;;###autoload
 174 (defun insert-image (image &optional string area)
 175   "Insert IMAGE into current buffer at point.
 176 IMAGE is displayed by inserting STRING into the current buffer
 177 with a `display' property whose value is the image.  STRING is
 178 defaulted if you omit it.
 179 AREA is where to display the image.  AREA nil or omitted means
 180 display it in the text area, a value of `left-margin' means
 181 display it in the left marginal area, a value of `right-margin'
 182 means display it in the right marginal area."
 183   ;; Use a space as least likely to cause trouble when it's a hidden
 184   ;; character in the buffer.
 185   (unless string (setq string " "))
 186   (unless (eq (car-safe image) 'image)
 187     (error "Not an image: %s" image))
 188   (unless (or (null area) (memq area '(left-margin right-margin)))
 189     (error "Invalid area %s" area))
 190   (if area
 191       (setq image (list (list 'margin area) image))
 192     ;; Cons up a new spec equal but not eq to `image' so that
 193     ;; inserting it twice in a row (adjacently) displays two copies of
 194     ;; the image.  Don't try to avoid this by looking at the display
 195     ;; properties on either side so that we DTRT more often with
 196     ;; cut-and-paste.  (Yanking killed image text next to another copy
 197     ;; of it loses anyway.)
 198     (setq image (cons 'image (cdr image))))
 199   (let ((start (point)))
 200     (insert string)
 201     (add-text-properties start (point)
 202                          (list 'display image
 203                                ;; `image' has the right properties to
 204                                ;; mark an intangible field.
 205                                'intangible image
 206                                'rear-nonsticky (list 'display)))))
 207
 208
 209 ;;;###autoload
 210 (defun remove-images (start end &optional buffer)
 211   "Remove images between START and END in BUFFER.
 212 Remove only images that were put in BUFFER with calls to `put-image'.
 213 BUFFER nil or omitted means use the current buffer."
 214   (unless buffer
 215     (setq buffer (current-buffer)))
 216   (let ((overlays (overlays-in start end)))
 217     (while overlays
 218       (let ((overlay (car overlays)))
 219         (when (overlay-get overlay 'put-image)
 220           (delete-overlay overlay)))
 221       (setq overlays (cdr overlays)))))
 222
 223
 224 ;;;###autoload
 225 (defun find-image (specs)
 226   "Find an image, choosing one of a list of image specifications.
 227
 228 SPECS is a list of image specifications.
 229
 230 Each image specification in SPECS is a property list.  The contents of
 231 a specification are image type dependent.  All specifications must at
 232 least contain the properties `:type TYPE' and either `:file FILE' or
 233 `:data DATA', where TYPE is a symbol specifying the image type,
 234 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 235 string containing the actual image data.  The specification whose TYPE
 236 is supported, and FILE exists, is used to construct the image
 237 specification to be returned.  Return nil if no specification is
 238 satisfied.
 239
 240 The image is looked for first on `load-path' and then in `data-directory'."
 241   (let (image)
 242     (while (and specs (null image))
 243       (let* ((spec (car specs))
 244              (type (plist-get spec :type))
 245              (data (plist-get spec :data))
 246              (file (plist-get spec :file))
 247              found)
 248         (when (image-type-available-p type)
 249           (cond ((stringp file)
 250                  (let ((path load-path))
 251                    (while (and (not found) path)
 252                      (let ((try-file (expand-file-name file (car path))))
 253                        (when (file-readable-p try-file)
 254                          (setq found try-file)))
 255                      (setq path (cdr path)))
 256                    (unless found
 257                      (let ((try-file (expand-file-name file data-directory)))
 258                        (if (file-readable-p try-file)
 259                            (setq found try-file))))
 260                    (if found
 261                        (setq image
 262                              (cons 'image (plist-put (copy-sequence spec)
 263                                                      :file found))))))
 264                 ((not (null data))
 265                  (setq image (cons 'image spec)))))
 266         (setq specs (cdr specs))))
 267     image))
 268
 269
 270 ;;;###autoload
 271 (defmacro defimage (symbol specs &optional doc)
 272   "Define SYMBOL as an image.
 273
 274 SPECS is a list of image specifications.  DOC is an optional
 275 documentation string.
 276
 277 Each image specification in SPECS is a property list.  The contents of
 278 a specification are image type dependent.  All specifications must at
 279 least contain the properties `:type TYPE' and either `:file FILE' or
 280 `:data DATA', where TYPE is a symbol specifying the image type,
 281 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 282 string containing the actual image data.  The first image
 283 specification whose TYPE is supported, and FILE exists, is used to
 284 define SYMBOL.
 285
 286 Example:
 287
 288    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 289                          (:type xbm :file \"~/test1.xbm\")))"
 290   `(defvar ,symbol (find-image ',specs) ,doc))
 291
 292
 293 (provide 'image)
 294
 295 ;;; image.el ends here