lisp/find-file.el

   1 ;;; find-file.el --- find a file corresponding to this one given a pattern
   2
   3 ;; Author: Henry Guillaume <henri@tibco.com, henry@c032.aone.net.au>
   4 ;; Maintainer: FSF
   5 ;; Keywords: c, matching, tools
   6
   7 ;; Copyright (C) 1994, 1995 Free Software Foundation, Inc.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; PURPOSE:
  29 ;; This package features a function called ff-find-other-file, which performs
  30 ;; the following function:
  31 ;;
  32 ;;     When in a .c file, find the first corresponding .h file in a set
  33 ;;     of directories and display it, and vice-versa from the .h file.
  34 ;;
  35 ;; Many people maintain their include file in a directory separate to their
  36 ;; src directory, and very often you may be editing a file and have a need to
  37 ;; visit the "other file". This package searches through a set of directories
  38 ;; to find that file.
  39 ;;
  40 ;; THE "OTHER FILE", or "corresponding file", generally has the same basename,
  41 ;; and just has a different extension as described by the ff-other-file-alist
  42 ;; variable:
  43 ;;
  44 ;;   '(("\\.cc$"  (".hh" ".h"))
  45 ;;     ("\\.hh$"  (".cc" ".C" ".CC" ".cxx" ".cpp")))
  46 ;;
  47 ;; If the current file has a .cc extension, ff-find-other-file will attempt
  48 ;; to look for a .hh file, and then a .h file in some directory as described
  49 ;; below. The mechanism here is to replace the matched part of the original
  50 ;; filename with each of the corresponding extensions in turn.
  51 ;;
  52 ;; Alternatively, there are situations where the filename of the other file
  53 ;; cannot be determined easily with regexps. For example, a .c file may
  54 ;; have two corresponding .h files, for its public and private parts, or
  55 ;; the filename for the .c file contains part of the pathname of the .h
  56 ;; file, as between src/fooZap.cc and include/FOO/zap.hh. In that case, the
  57 ;; format above can be changed to include a function to be called when the
  58 ;; current file matches the regexp:
  59 ;;
  60 ;;   '(("\\.cc$"  cc-function)
  61 ;;     ("\\.hh$"  hh-function))
  62 ;;
  63 ;; These functions must return a list consisting of the possible names of the
  64 ;; corresponding file, with or without path. There is no real need for more
  65 ;; than one function, and one could imagine the following value for cc-other-
  66 ;; file-alist:
  67 ;;
  68 ;;    (setq cc-other-file-alist
  69 ;;        '(("\\.cc$"  ff-cc-hh-converter)
  70 ;;          ("\\.hh$"  ff-cc-hh-converter)
  71 ;;          ("\\.c$"   (".h"))
  72 ;;          ("\\.h$"   (".c" ".cc" ".C" ".CC" ".cxx" ".cpp"))))
  73 ;;
  74 ;; ff-cc-hh-converter is included at the end of this file as a reference.
  75 ;;
  76 ;; SEARCHING is carried out in a set of directories specified by the
  77 ;; ff-search-directories variable:
  78 ;;
  79 ;;     ("." "../../src" "../include/*" "/usr/local/*/src/*" "$PROJECT/src")
  80 ;;
  81 ;; This means that the corresponding file will be searched for first in
  82 ;; the current directory, then in ../../src, then in one of the directories
  83 ;; under ../include, and so on. The star is _not_ a general wildcard
  84 ;; character: it just indicates that the subdirectories of this directory
  85 ;; must each be searched in turn. Environment variables will be expanded in
  86 ;; the ff-search-directories variable.
  87 ;;
  88 ;; If the point is on a #include line, the file to be #included is searched
  89 ;; for in the same manner. This can be disabled with the ff-ignore-include
  90 ;; variable, or by calling ff-get-other-file instead of ff-find-other-file.
  91 ;;
  92 ;; If the file was not found, ff-find-other-file will prompt you for where
  93 ;; to create the new "corresponding file" (defaults to the current directory),
  94 ;; unless the variable ff-always-try-to-create is set to nil.
  95 ;;
  96 ;; GIVEN AN ARGUMENT (with the ^U prefix), ff-find-other-file will get the
  97 ;; other file in another (the other?) window (see find-file-other-window and
  98 ;; switch-to-buffer-other-window). This can be set on a more permanent basis
  99 ;; by setting ff-always-in-other-window to t in which case the ^U prefix will
 100 ;; do the opposite of what was described above.
 101 ;;
 102 ;; THERE ARE FIVE AVAILABLE HOOKS, called in this order if non-nil:
 103 ;;
 104 ;; - ff-pre-find-hooks     - called before the search for the other file starts
 105 ;; - ff-not-found-hooks    - called when the other file could not be found
 106 ;; - ff-pre-load-hooks     - called just before the other file is 'loaded'
 107 ;; - ff-file-created-hooks - called when the other file is created
 108 ;; - ff-post-load-hooks    - called just after the other file is 'loaded'
 109 ;;
 110 ;; The *load-hooks allow you to place point where you want it in the other
 111 ;; file.
 112
 113 ;; CREDITS:
 114 ;; Many thanks go to TUSC Computer Systems Pty Ltd for providing an environ-
 115 ;; ment that made the development of this package possible.
 116 ;;
 117 ;; Many thanks also go to all those who provided valuable feedback throughout
 118 ;; the development of this package:
 119 ;;     Rolf Ebert in particular, Fritz Knabe, Heddy Boubaker, Sebastian Kremer,
 120 ;;     Vasco Lopes Paulo, Mark A. Plaksin, Robert Lang, Trevor West, Kevin
 121 ;;     Pereira, Benedict Lofstedt & Justin Vallon.
 122
 123 ;;; Code:
 124 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 125 ;; User definable variables:
 126
 127 (defgroup ff nil
 128   "Find a file corresponding to this one given a pattern."
 129   :prefix "ff-"
 130   :link '(emacs-commentary-link "find-file")
 131   :group 'find-file)
 132
 133 (defcustom ff-pre-find-hooks nil
 134   "*List of functions to be called before the search for the file starts."
 135   :type 'hook
 136   :group 'ff)
 137
 138 (defcustom ff-pre-load-hooks nil
 139   "*List of functions to be called before the other file is loaded."
 140   :type 'hook
 141   :group 'ff)
 142
 143 (defcustom ff-post-load-hooks nil
 144   "*List of functions to be called after the other file is loaded."
 145   :type 'hook
 146   :group 'ff)
 147
 148 (defcustom ff-not-found-hooks nil
 149   "*List of functions to be called if the other file could not be found."
 150   :type 'hook
 151   :group 'ff)
 152
 153 (defcustom ff-file-created-hooks nil
 154   "*List of functions to be called if the other file needs to be created."
 155   :type 'hook
 156   :group 'ff)
 157
 158 (defcustom ff-case-fold-search nil
 159   "*Non-nil means ignore cases in matches (see `case-fold-search').
 160 If you have extensions in different cases, you will want this to be nil."
 161   :type 'boolean
 162   :group 'ff)
 163
 164 (defcustom ff-always-in-other-window nil
 165   "*If non-nil, find the corresponding file in another window by default.
 166 To override this, give an argument to `ff-find-other-file'."
 167   :type 'boolean
 168   :group 'ff)
 169
 170 (defcustom ff-ignore-include nil
 171   "*If non-nil, ignore `#include' lines."
 172   :type 'boolean
 173   :group 'ff)
 174
 175 (defcustom ff-always-try-to-create t
 176   "*If non-nil, always attempt to create the other file if it was not found."
 177   :type 'boolean
 178   :group 'ff)
 179
 180 (defcustom ff-quiet-mode nil
 181   "*If non-nil, trace which directories are being searched."
 182   :type 'boolean
 183   :group 'ff)
 184
 185 (defvar ff-special-constructs
 186   '(
 187     ;; C/C++ include, for NeXTSTEP too
 188     ("^\#\\s *\\(include\\|import\\)\\s +[<\"]\\(.*\\)[>\"]" .
 189      (lambda ()
 190        (setq fname (buffer-substring (match-beginning 2) (match-end 2)))))
 191
 192     ;; Ada import
 193     ("^with[ \t]+\\([a-zA-Z0-9_\\.]+\\)" .
 194      (lambda ()
 195        (setq fname (buffer-substring (match-beginning 1) (match-end 1)))
 196        (require 'ada-mode)
 197        (setq fname (concat (ada-make-filename-from-adaname fname)
 198                            ada-spec-suffix))))
 199     )
 200   "*A list of regular expressions for `ff-find-file'.
 201 Specifies how to recognise special constructs such as include files
 202 etc. and an associated method for extracting the filename from that
 203 construct.")
 204
 205 (defcustom ff-other-file-alist 'cc-other-file-alist
 206   "*Alist of extensions to find given the current file's extension.
 207
 208 This list should contain the most used extensions before the others,
 209 since the search algorithm searches sequentially through each
 210 directory specified in `ff-search-directories'.  If a file is not found,
 211 a new one is created with the first matching extension (`.cc' yields `.hh').
 212 This alist should be set by the major mode."
 213   :type '(choice (repeat (list regexp (choice (repeat string) function)))
 214                  symbol)
 215   :group 'ff)
 216
 217 (defcustom ff-search-directories 'cc-search-directories
 218   "*List of directories to search for a specific file.
 219
 220 Set by default to `cc-search-directories', expanded at run-time.
 221
 222 This list is searched through with each extension specified in
 223 `ff-other-file-alist' that matches this file's extension.  So the
 224 longer the list, the longer it'll take to realise that a file
 225 may not exist.
 226
 227 A typical format is
 228
 229     '(\".\" \"/usr/include\" \"$PROJECT/*/include\")
 230
 231 Environment variables can be inserted between slashes (`/').
 232 They will be replaced by their definition. If a variable does
 233 not exist, it is replaced (silently) with an empty string.
 234
 235 The stars are *not* wildcards: they are searched for together with
 236 the preceding slash.  The star represents all the subdirectories except
 237 `..', and each of these subdirectories will be searched in turn."
 238   :type '(choice (repeat directory) symbol)
 239   :group 'ff)
 240
 241 (defcustom cc-search-directories
 242   '("." "/usr/include" "/usr/local/include/*")
 243   "*See the description of the `ff-search-directories' variable."
 244   :type '(repeat directory)
 245   :group 'ff)
 246
 247 (defcustom cc-other-file-alist
 248   '(
 249     ("\\.cc$"  (".hh" ".h"))
 250     ("\\.hh$"  (".cc" ".C"))
 251
 252     ("\\.c$"   (".h"))
 253     ("\\.h$"   (".c" ".cc" ".C" ".CC" ".cxx" ".cpp"))
 254
 255     ("\\.C$"   (".H"  ".hh" ".h"))
 256     ("\\.H$"   (".C"  ".CC"))
 257
 258     ("\\.CC$"  (".HH" ".H"  ".hh" ".h"))
 259     ("\\.HH$"  (".CC"))
 260
 261     ("\\.cxx$" (".hh" ".h"))
 262     ("\\.cpp$" (".hh" ".h"))
 263     )
 264   "*Alist of extensions to find given the current file's extension.
 265
 266 This list should contain the most used extensions before the others,
 267 since the search algorithm searches sequentially through each directory
 268 specified in `ff-search-directories'.  If a file is not found, a new one
 269 is created with the first matching extension (`.cc' yields `.hh')."
 270   :type '(repeat (list regexp (choice (repeat string) function)))
 271   :group 'ff)
 272
 273 (defcustom modula2-other-file-alist
 274   '(
 275     ("\\.mi$" (".md")) ;; Modula-2 module definition
 276     ("\\.md$" (".mi")) ;; and implementation.
 277     )
 278   "*See the description for the `ff-search-directories' variable."
 279   :type '(repeat (list regexp (choice (repeat string) function)))
 280   :group 'ff)
 281
 282
 283 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 284 ;; No user definable variables beyond this point!
 285 ;; ==============================================
 286
 287 (make-variable-buffer-local 'ff-pre-find-hooks)
 288 (make-variable-buffer-local 'ff-pre-load-hooks)
 289 (make-variable-buffer-local 'ff-post-load-hooks)
 290 (make-variable-buffer-local 'ff-not-found-hooks)
 291 (make-variable-buffer-local 'ff-file-created-hooks)
 292 (make-variable-buffer-local 'ff-case-fold-search)
 293 (make-variable-buffer-local 'ff-always-in-other-window)
 294 (make-variable-buffer-local 'ff-ignore-include)
 295 (make-variable-buffer-local 'ff-quiet-mode)
 296 (make-variable-buffer-local 'ff-other-file-alist)
 297 (make-variable-buffer-local 'ff-search-directories)
 298
 299 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 300 ;; User entry points
 301
 302 ;;;###autoload
 303 (defun ff-get-other-file (&optional in-other-window)
 304   "Find the header or source file corresponding to this file.
 305 See also the documentation for `ff-find-other-file'.
 306
 307 If optional IN-OTHER-WINDOW is non-nil, find the file in another window."
 308   (interactive "P")
 309   (let ((ignore ff-ignore-include))
 310     (setq ff-ignore-include t)
 311     (ff-find-the-other-file in-other-window)
 312     (setq ff-ignore-include ignore)))
 313
 314 ;;;###autoload
 315 (defun ff-find-other-file (&optional in-other-window ignore-include)
 316   "Find the header or source file corresponding to this file.
 317 Being on a `#include' line pulls in that file.
 318
 319 If optional IN-OTHER-WINDOW is non-nil, find the file in the other window.
 320 If optional IGNORE-INCLUDE is non-nil, ignore being on `#include' lines.
 321
 322 Variables of interest include:
 323
 324  - `ff-case-fold-search'
 325    Non-nil means ignore cases in matches (see `case-fold-search').
 326    If you have extensions in different cases, you will want this to be nil.
 327
 328  - `ff-always-in-other-window'
 329    If non-nil, always open the other file in another window, unless an
 330    argument is given to `ff-find-other-file'.
 331
 332  - `ff-ignore-include'
 333    If non-nil, ignores #include lines.
 334
 335  - `ff-always-try-to-create'
 336    If non-nil, always attempt to create the other file if it was not found.
 337
 338  - `ff-quiet-mode'
 339    If non-nil, traces which directories are being searched.
 340
 341  - `ff-special-constructs'
 342    A list of regular expressions specifying how to recognise special
 343    constructs such as include files etc, and an associated method for
 344    extracting the filename from that construct.
 345
 346  - `ff-other-file-alist'
 347    Alist of extensions to find given the current file's extension.
 348
 349  - `ff-search-directories'
 350    List of directories searched through with each extension specified in
 351    `ff-other-file-alist' that matches this file's extension.
 352
 353  - `ff-pre-find-hooks'
 354    List of functions to be called before the search for the file starts.
 355
 356  - `ff-pre-load-hooks'
 357    List of functions to be called before the other file is loaded.
 358
 359  - `ff-post-load-hooks'
 360    List of functions to be called after the other file is loaded.
 361
 362  - `ff-not-found-hooks'
 363    List of functions to be called if the other file could not be found.
 364
 365  - `ff-file-created-hooks'
 366    List of functions to be called if the other file has been created."
 367   (interactive "P")
 368   (let ((ignore ff-ignore-include))
 369     (setq ff-ignore-include ignore-include)
 370     (ff-find-the-other-file in-other-window)
 371     (setq ff-ignore-include ignore)))
 372
 373 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 374 ;; Support functions
 375
 376 (defun ff-find-the-other-file (&optional in-other-window)
 377   "Find the header or source file corresponding to the current file.
 378 Being on a `#include' line pulls in that file, but see the help on
 379 the `ff-ignore-include' variable.
 380
 381 If optional IN-OTHER-WINDOW is non-nil, find the file in another window."
 382
 383   (let (match           ;; matching regexp for this file
 384         suffixes        ;; set of replacing regexps for the matching regexp
 385         action          ;; function to generate the names of the other files
 386         fname           ;; basename of this file
 387         pos             ;; where we start matching filenames
 388         stub            ;; name of the file without extension
 389         alist           ;; working copy of the list of file extensions
 390         pathname        ;; the pathname of the file or the #include line
 391         default-name    ;; file we should create if none found
 392         format          ;; what we have to match
 393         found           ;; name of the file or buffer found - nil if none
 394         dirs            ;; local value of ff-search-directories
 395         no-match)       ;; whether we know about this kind of file
 396
 397     (if ff-pre-find-hooks
 398         (run-hooks 'ff-pre-find-hooks))
 399
 400     (message "Working...")
 401
 402     (setq dirs
 403           (if (symbolp ff-search-directories)
 404               (ff-list-replace-env-vars (symbol-value ff-search-directories))
 405             (ff-list-replace-env-vars ff-search-directories)))
 406
 407     (save-excursion
 408       (beginning-of-line 1)
 409       (setq fname (ff-treat-as-special)))
 410
 411     (cond
 412      ((and (not ff-ignore-include) fname)
 413       (setq default-name fname)
 414       (setq found (ff-get-file dirs fname nil in-other-window)))
 415
 416      ;; let's just get the corresponding file
 417      (t
 418       (setq alist (if (symbolp ff-other-file-alist)
 419                       (symbol-value ff-other-file-alist)
 420                     ff-other-file-alist)
 421             pathname (if (buffer-file-name)
 422                          (buffer-file-name)
 423                        "/none.none"))
 424
 425       (setq fname (file-name-nondirectory pathname)
 426             no-match nil
 427             match (car alist))
 428
 429       ;; find the table entry corresponding to this file
 430       (setq pos (ff-string-match (car match) fname))
 431       (while (and match (if (and pos (>= pos 0)) nil (not pos)))
 432         (setq alist (cdr alist))
 433         (setq match (car alist))
 434         (setq pos (ff-string-match (car match) fname)))
 435
 436       ;; no point going on if we haven't found anything
 437       (if (not match)
 438           (setq no-match t)
 439
 440         ;; otherwise, suffixes contains what we need
 441         (setq suffixes (car (cdr match))
 442               action (car (cdr match))
 443               found nil)
 444
 445         ;; if we have a function to generate new names,
 446         ;; invoke it with the name of the current file
 447         (if (and (atom action) (fboundp action))
 448             (progn
 449               (setq suffixes (funcall action (buffer-file-name))
 450                     match (cons (car match) (list suffixes))
 451                     stub nil
 452                     default-name (car suffixes)))
 453
 454           ;; otherwise build our filename stub
 455           (cond
 456
 457            ;; get around the problem that 0 and nil both mean false!
 458            ((= pos 0)
 459             (setq format "")
 460             (setq stub "")
 461             )
 462
 463            (t
 464             (setq format (concat "\\(.+\\)" (car match)))
 465             (string-match format fname)
 466             (setq stub (substring fname (match-beginning 1) (match-end 1)))
 467             ))
 468
 469           ;; if we find nothing, we should try to get a file like this one
 470           (setq default-name
 471                 (concat stub (car (car (cdr match))))))
 472
 473         ;; do the real work - find the file
 474         (setq found
 475               (ff-get-file dirs
 476                            stub
 477                            suffixes
 478                            in-other-window)))))
 479
 480     (cond
 481      (no-match                     ;; could not even determine the other file
 482       (message ""))
 483
 484      (t
 485       (cond
 486
 487        ((not found)                ;; could not find the other file
 488
 489         (if ff-not-found-hooks     ;; run the hooks
 490             (run-hooks 'ff-not-found-hooks))
 491
 492         (cond
 493          (ff-always-try-to-create  ;; try to create the file
 494           (let (name pathname)
 495
 496             (setq name
 497                   (expand-file-name
 498                    (read-file-name
 499                     (format "Find or create %s in: " default-name)
 500                     default-directory default-name nil)))
 501
 502             (setq pathname
 503                   (if (file-directory-p name)
 504                       (concat (file-name-as-directory name) default-name)
 505                     (setq found name)))
 506
 507             (ff-find-file pathname in-other-window t)))
 508
 509          (t                        ;; don't create the file, just whinge
 510           (message "No file found for %s" fname))))
 511
 512        (t                          ;; matching file found
 513         nil))))
 514
 515     found))                        ;; return buffer-name or filename
 516
 517 (defun ff-get-file (search-dirs filename &optional suffix-list other-window)
 518   "Find a file in the SEARCH-DIRS with the given FILENAME (or filename stub).
 519 If (optional) SUFFIX-LIST is nil, search for fname, otherwise search
 520 for fname with each of the given suffixes.  Get the file or the buffer
 521 corresponding to the name of the first file found, or nil."
 522   (let ((filename (ff-get-file-name search-dirs filename suffix-list)))
 523
 524     (cond
 525      ((not filename)
 526       nil)
 527
 528      ((bufferp (get-file-buffer filename))
 529       (ff-switch-to-buffer (get-file-buffer filename) other-window)
 530       filename)
 531
 532      ((file-exists-p filename)
 533       (ff-find-file filename other-window nil)
 534       filename)
 535
 536      (t
 537       nil))))
 538
 539 (defun ff-get-file-name (search-dirs fname-stub &optional suffix-list)
 540   "Find a file in SEARCH-DIRS with the given name (or stub) FNAME-STUB.
 541 If (optional) SUFFIX-LIST is nil, search for FNAME-STUB, otherwise
 542 search for FNAME-STUB with each of the given suffixes.  Return the
 543 name of the first file found."
 544   (let* (dirs         ;; working copy of dirs to search
 545          dir          ;; the current dir considered
 546          file         ;; filename being looked for
 547          rest         ;; pathname after first /*
 548          this-suffix  ;; the suffix we are currently considering
 549          suffixes     ;; working copy of suffix-list
 550          filename     ;; built filename
 551          blist        ;; list of live buffers
 552          buf          ;; current buffer in blist
 553          found)       ;; whether we have found anything
 554
 555     (setq suffixes suffix-list)
 556
 557     ;; suffixes is nil => fname-stub is the file we are looking for
 558     ;; otherwise fname-stub is a stub, and we append a suffix
 559     (if suffixes
 560         (setq this-suffix (car suffixes))
 561       (setq this-suffix "")
 562       (setq suffixes (list "")))
 563
 564     ;; find whether the file is in a buffer first
 565     (while (and suffixes (not found))
 566       (setq filename (concat fname-stub this-suffix))
 567
 568       (if (not ff-quiet-mode)
 569           (message "Finding buffer %s..." filename))
 570
 571       (if (bufferp (get-file-buffer filename))
 572           (setq found (buffer-file-name (get-file-buffer filename))))
 573
 574       (setq blist (buffer-list))
 575       (setq buf (buffer-name (car blist)))
 576       (while (and blist (not found))
 577
 578         (if (string-match (concat filename "<[0-9]+>") buf)
 579             (setq found (buffer-file-name (car blist))))
 580
 581         (setq blist (cdr blist))
 582         (setq buf (buffer-name (car blist))))
 583
 584       (setq suffixes (cdr suffixes))
 585       (setq this-suffix (car suffixes)))
 586
 587     ;; now look for the real file
 588     (setq dirs search-dirs)
 589     (setq dir  (car dirs))
 590     (while (and (not found) dirs)
 591
 592       (setq suffixes suffix-list)
 593
 594       ;; if dir does not contain '/*', look for the file
 595       (if (and dir (not (string-match "\\([^*]*\\)/\\\*\\(/.*\\)*" dir)))
 596           (progn
 597
 598             ;; suffixes is nil => fname-stub is the file we are looking for
 599             ;; otherwise fname-stub is a stub, and we append a suffix
 600             (if suffixes
 601                 (setq this-suffix (car suffixes))
 602               (setq this-suffix "")
 603               (setq suffixes (list "")))
 604
 605             (while (and suffixes (not found))
 606
 607               (setq filename (concat fname-stub this-suffix))
 608               (setq file (concat dir "/" filename))
 609
 610               (if (not ff-quiet-mode)
 611                   (message "Finding %s..." file))
 612
 613               (if (file-exists-p file)
 614                   (setq found file))
 615
 616               (setq suffixes (cdr suffixes))
 617               (setq this-suffix (car suffixes))))
 618
 619         ;; otherwise dir matches the '/*', so search each dir separately
 620         (progn
 621           (if (match-beginning 2)
 622               (setq rest (substring dir (match-beginning 2) (match-end 2)))
 623             (setq rest "")
 624             )
 625           (setq dir  (substring dir (match-beginning 1) (match-end 1)))
 626
 627           (let ((dirlist (ff-all-dirs-under dir '("..")))
 628                 this-dir compl-dirs)
 629
 630             (setq this-dir (car dirlist))
 631             (while dirlist
 632               (setq compl-dirs
 633                     (append
 634                      compl-dirs
 635                      (list (concat this-dir rest))
 636                      ))
 637               (setq dirlist  (cdr dirlist))
 638               (setq this-dir (car dirlist)))
 639
 640             (if compl-dirs
 641                 (setq found (ff-get-file-name compl-dirs
 642                                               fname-stub
 643                                               suffix-list))))))
 644       (setq dirs (cdr dirs))
 645       (setq dir (car dirs)))
 646
 647     (if found
 648         (message "%s found" found))
 649
 650     found))
 651
 652 (defun ff-string-match (regexp string &optional start)
 653   "Like `string-match', but set `case-fold-search' temporarily.
 654 The value used comes from `ff-case-fold-search'."
 655   (let ((case-fold-search ff-case-fold-search))
 656     (if regexp
 657         (string-match regexp string start))))
 658
 659 (defun ff-list-replace-env-vars (search-list)
 660   "Replace environment variables (of the form $VARIABLE) in SEARCH-LIST."
 661   (let (list
 662         (var (car search-list)))
 663     (while search-list
 664       (if (string-match "\\(.*\\)\\$[({]*\\([a-zA-Z0-9_]+\\)[)}]*\\(.*\\)" var)
 665           (setq var
 666                 (concat
 667                  (substring var (match-beginning 1) (match-end 1))
 668                  (getenv (substring var (match-beginning 2) (match-end 2)))
 669                  (substring var (match-beginning 3) (match-end 3)))))
 670       (setq search-list (cdr search-list))
 671       (setq list (cons var list))
 672       (setq var (car search-list)))
 673     (setq search-list (reverse list))))
 674
 675 (defun ff-treat-as-special ()
 676   "Return the file to look for if the construct was special, else nil.
 677 The construct is defined in the variable `ff-special-constructs'."
 678   (let* (fname
 679          (list ff-special-constructs)
 680          (elem (car list))
 681          (regexp (car elem))
 682          (match (cdr elem)))
 683     (while (and list (not fname))
 684       (if (and (looking-at regexp) match)
 685           (setq fname (funcall match)))
 686       (setq list (cdr list))
 687       (setq elem (car list))
 688       (setq regexp (car elem))
 689       (setq match (cdr elem)))
 690     fname))
 691
 692 (defun ff-basename (string)
 693   "Return the basename of pathname STRING."
 694   (setq string (concat "/" string))
 695   (string-match ".*/\\([^/]+\\)$" string)
 696   (setq string (substring string (match-beginning 1) (match-end 1))))
 697
 698 (defun ff-all-dirs-under (here &optional exclude)
 699   "Get all the directory files under directory HERE.
 700 Exclude all files in the optional EXCLUDE list."
 701   (if (file-directory-p here)
 702       (condition-case nil
 703           (progn
 704             (let ((files (directory-files here t))
 705                   (dirlist (list))
 706                   file)
 707               (while files
 708                 (setq file (car files))
 709                 (if (and
 710                      (file-directory-p file)
 711                      (not (member (ff-basename file) exclude)))
 712                     (setq dirlist (cons file dirlist)))
 713                 (setq files (cdr files)))
 714               (setq dirlist (reverse dirlist))))
 715         (error nil))
 716     nil))
 717
 718 (defun ff-switch-file (f1 f2 file &optional in-other-window new-file)
 719   "Call F1 or F2 on FILE, according to IN-OTHER-WINDOW.
 720 In addition, this runs various hooks.
 721
 722 Either F1 or F2 receives FILE as the sole argument.
 723 The decision of which one to call is based on IN-OTHER-WINDOW
 724 and on the global variable `ff-always-in-other-window'.
 725
 726 F1 and F2 are typically `find-file' / `find-file-other-window'
 727 or `switch-to-buffer' / `switch-to-buffer-other-window' function pairs.
 728
 729 If optional NEW-FILE is t, then a special hook (`ff-file-created-hooks') is
 730 called before `ff-post-load-hooks'."
 731   (if ff-pre-load-hooks
 732       (run-hooks 'ff-pre-load-hooks))
 733   (if (or
 734        (and in-other-window (not ff-always-in-other-window))
 735        (and (not in-other-window) ff-always-in-other-window))
 736       (funcall f2 file)
 737     (funcall f1 file))
 738   (if new-file
 739       (if ff-file-created-hooks
 740           (run-hooks 'ff-file-created-hooks)))
 741   (if ff-post-load-hooks
 742       (run-hooks 'ff-post-load-hooks)))
 743
 744 (defun ff-find-file (file &optional in-other-window new-file)
 745   "Like `find-file', but may show the file in another window."
 746   (ff-switch-file 'find-file
 747                   'find-file-other-window
 748                   file in-other-window new-file))
 749
 750 (defun ff-switch-to-buffer (buffer-or-name &optional in-other-window)
 751   "Like `switch-to-buffer', but may show the buffer in another window."
 752
 753   (ff-switch-file 'switch-to-buffer
 754                   'switch-to-buffer-other-window
 755                   buffer-or-name in-other-window nil))
 756
 757 ;;;###autoload
 758 (defun ff-mouse-find-other-file (event)
 759   "Visit the file you click on."
 760   (interactive "e")
 761   (save-excursion
 762     (mouse-set-point event)
 763     (ff-find-other-file nil)))
 764
 765 ;;;###autoload
 766 (defun ff-mouse-find-other-file-other-window (event)
 767   "Visit the file you click on in another window."
 768   (interactive "e")
 769   (save-excursion
 770     (mouse-set-point event)
 771     (ff-find-other-file t)))
 772
 773 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 774 ;; This section offers an example of user defined function to select files
 775
 776 (defun ff-upcase-p (string &optional start end)
 777   "Return t if STRING is all uppercase.
 778 Given START and/or END, checks between these characters."
 779   (let (match str)
 780     (if (not start)
 781         (setq start 0))
 782     (if (not end)
 783         (setq end (length string)))
 784     (if (= start end)
 785         (setq end (1+ end)))
 786     (setq str (substring string start end))
 787     (if (and
 788          (ff-string-match "[A-Z]+" str)
 789          (setq match (match-data))
 790          (= (car match) 0)
 791          (= (car (cdr match)) (length str)))
 792         t
 793       nil)))
 794
 795 (defun ff-cc-hh-converter (arg)
 796   "Discriminate file extensions.
 797 Build up a new file list based possibly on part of the directory name
 798 and the name of the file passed in."
 799   (ff-string-match "\\(.*\\)/\\([^/]+\\)/\\([^.]+\\).\\([^/]+\\)$" arg)
 800   (let ((path (if (match-beginning 1)
 801                   (substring arg (match-beginning 1) (match-end 1)) nil))
 802         (dire (if (match-beginning 2)
 803                   (substring arg (match-beginning 2) (match-end 2)) nil))
 804         (file (if (match-beginning 3)
 805                   (substring arg (match-beginning 3) (match-end 3)) nil))
 806         (extn (if (match-beginning 4)
 807                   (substring arg (match-beginning 4) (match-end 4)) nil))
 808         return-list)
 809     (cond
 810      ;; fooZapJunk.cc => ZapJunk.{hh,h} or fooZapJunk.{hh,h}
 811      ((and (string= extn "cc")
 812            (ff-string-match "^\\([a-z]+\\)\\([A-Z].+\\)$" file))
 813       (let ((stub  (substring file (match-beginning 2) (match-end 2))))
 814         (setq dire (upcase (substring file (match-beginning 1) (match-end 1))))
 815         (setq return-list (list (concat stub ".hh")
 816                                 (concat stub ".h")
 817                                 (concat file ".hh")
 818                                 (concat file ".h")))
 819         ))
 820      ;; FOO/ZapJunk.hh => fooZapJunk.{cc,C} or ZapJunk.{cc,C}
 821      ((and (string= extn "hh") (ff-upcase-p dire) file)
 822       (let ((stub (concat (downcase dire) file)))
 823         (setq return-list (list (concat stub ".cc")
 824                                 (concat stub ".C")
 825                                 (concat file ".cc")
 826                                 (concat file ".C")))
 827         ))
 828      ;; zap.cc => zap.hh or zap.h
 829      ((string= extn "cc")
 830       (let ((stub file))
 831         (setq return-list (list (concat stub ".hh")
 832                                 (concat stub ".h")))
 833         ))
 834      ;; zap.hh => zap.cc or zap.C
 835      ((string= extn "hh")
 836       (let ((stub file))
 837         (setq return-list (list (concat stub ".cc")
 838                                 (concat stub ".C")))
 839         ))
 840      (t
 841       nil))
 842
 843     return-list))
 844
 845 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 846 ;; This section offers an example of user defined function to place point.
 847 ;; The regexps are Ada specific.
 848
 849 (defvar ff-function-name nil "Name of the function we are in.")
 850
 851 (eval-when-compile (require 'ada-mode))
 852
 853 ;; bind with (setq ff-pre-load-hooks 'ff-which-function-are-we-in)
 854 ;;
 855 (defun ff-which-function-are-we-in ()
 856   "Return the name of the function whose definition/declaration point is in.
 857 Also remember that name in `ff-function-name'."
 858
 859   (setq ff-function-name nil)
 860
 861   (save-excursion
 862     (if (re-search-backward ada-procedure-start-regexp nil t)
 863         (setq ff-function-name (buffer-substring (match-beginning 0)
 864                                                  (match-end 0)))
 865       ; we didn't find a procedure start, perhaps there is a package
 866       (if (re-search-backward ada-package-start-regexp nil t)
 867           (setq ff-function-name (buffer-substring (match-beginning 0)
 868                                                    (match-end 0)))
 869         ))))
 870
 871 ;; bind with (setq ff-post-load-hooks 'ff-set-point-accordingly)
 872 ;;
 873 (defun ff-set-point-accordingly ()
 874   "Find the function specified in `ff-function-name'.
 875 That name was previously determined by `ff-which-function-are-we-in'."
 876   (if ff-function-name
 877       (progn
 878         (goto-char (point-min))
 879         (search-forward ff-function-name nil t))))
 880
 881 (provide 'find-file)
 882
 883 ;;; find-file.el ends here