lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8 ;; Keywords: extensions
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 ;; PUBLIC: define a new major mode which inherits from an existing one.
  95
  96 ;;;###autoload
  97 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
  98   "Create a new mode as a variant of an existing mode.
  99
 100 The arguments to this command are as follow:
 101
 102 CHILD:     the name of the command for the derived mode.
 103 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 104            or nil if there is no parent.
 105 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 106 DOCSTRING: an optional documentation string--if you do not supply one,
 107            the function will attempt to invent something useful.
 108 BODY:      forms to execute just before running the
 109            hooks for the new mode.
 110
 111 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 112
 113   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 114
 115 You could then make new key bindings for `LaTeX-thesis-mode-map'
 116 without changing regular LaTeX mode.  In this example, BODY is empty,
 117 and DOCSTRING is generated by default.
 118
 119 On a more complicated level, the following command uses `sgml-mode' as
 120 the parent, and then sets the variable `case-fold-search' to nil:
 121
 122   (define-derived-mode article-mode sgml-mode \"Article\"
 123     \"Major mode for editing technical articles.\"
 124     (setq case-fold-search nil))
 125
 126 Note that if the documentation string had been left out, it would have
 127 been generated automatically, with a reference to the keymap."
 128
 129   (when (and docstring (not (stringp docstring)))
 130     ;; Some trickiness, since what appears to be the docstring may really be
 131     ;; the first element of the body.
 132     (push docstring body)
 133     (setq docstring nil))
 134
 135   (when (eq parent 'fundamental-mode) (setq parent nil))
 136
 137   (let ((map (derived-mode-map-name child))
 138         (syntax (derived-mode-syntax-table-name child))
 139         (abbrev (derived-mode-abbrev-table-name child))
 140         (hook (derived-mode-hook-name child))
 141         (docstring (derived-mode-make-docstring parent child docstring)))
 142
 143     `(progn
 144        (defvar ,map (make-sparse-keymap))
 145        (defvar ,syntax (make-syntax-table))
 146        (defvar ,abbrev)
 147        (define-abbrev-table ',abbrev nil)
 148        (put ',child 'derived-mode-parent ',parent)
 149
 150        (defun ,child ()
 151          ,docstring
 152          (interactive)
 153                                         ; Run the parent.
 154          ;; (combine-run-hooks
 155
 156           (,(or parent 'kill-all-local-variables))
 157                                         ; Identify the child mode.
 158           (setq major-mode (quote ,child))
 159           (setq mode-name ,name)
 160                                         ; Identify special modes.
 161           ,(when parent
 162              `(progn
 163                 (if (get (quote ,parent) 'special)
 164                     (put (quote ,child) 'special t))
 165                                         ; Set up maps and tables.
 166                 (unless (keymap-parent ,map)
 167                   (set-keymap-parent ,map (current-local-map)))
 168                 (let ((parent (char-table-parent ,syntax)))
 169                   (unless (and parent (not (eq parent (standard-syntax-table))))
 170                     (set-char-table-parent ,syntax (syntax-table))))
 171                 (when local-abbrev-table
 172                   (mapatoms
 173                    (lambda (symbol)
 174                      (or (intern-soft (symbol-name symbol) ,abbrev)
 175                          (define-abbrev ,abbrev (symbol-name symbol)
 176                            (symbol-value symbol) (symbol-function symbol))))
 177                    local-abbrev-table))))
 178
 179           (use-local-map ,map)
 180           (set-syntax-table ,syntax)
 181           (setq local-abbrev-table ,abbrev)
 182                                         ; Splice in the body (if any).
 183           ,@body
 184           ;; )
 185                                         ; Run the hooks, if any.
 186          (run-hooks ',hook)))))
 187
 188 ;; PUBLIC: find if the current mode derives from another.
 189
 190 (defun derived-mode-p (&rest modes)
 191   "Non-nil if the current major mode is derived from one of MODES.
 192 Uses the `derived-mode-parent' property of the symbol to trace backwards."
 193   (let ((parent major-mode))
 194     (while (and (not (memq parent modes))
 195                 (setq parent (get parent 'derived-mode-parent))))
 196     parent))
 197
 198 ;; PUBLIC: find the ultimate class of a derived mode.
 199
 200 (defun derived-mode-class (mode)
 201   "Find the class of a major MODE.
 202 A mode's class is the first ancestor which is NOT a derived mode.
 203 Use the `derived-mode-parent' property of the symbol to trace backwards.
 204 Since major-modes might derive from each other and from `fundamental-mode',
 205 this function is not very useful.  Use `derived-mode-p' instead."
 206   (while (get mode 'derived-mode-parent)
 207     (setq mode (get mode 'derived-mode-parent)))
 208   mode)
 209
 210 \f
 211 ;;; PRIVATE
 212
 213 (defsubst derived-mode-hook-name (mode)
 214   "Construct the mode hook name based on mode name MODE."
 215   (intern (concat (symbol-name mode) "-hook")))
 216
 217 (defsubst derived-mode-map-name (mode)
 218   "Construct a map name based on a MODE name."
 219   (intern (concat (symbol-name mode) "-map")))
 220
 221 (defsubst derived-mode-syntax-table-name (mode)
 222   "Construct a syntax-table name based on a MODE name."
 223   (intern (concat (symbol-name mode) "-syntax-table")))
 224
 225 (defsubst derived-mode-abbrev-table-name (mode)
 226   "Construct an abbrev-table name based on a MODE name."
 227   (intern (concat (symbol-name mode) "-abbrev-table")))
 228
 229 (defun derived-mode-make-docstring (parent child &optional docstring)
 230   "Construct a docstring for a new mode if none is provided."
 231
 232   (let ((map (derived-mode-map-name child))
 233         (syntax (derived-mode-syntax-table-name child))
 234         (abbrev (derived-mode-abbrev-table-name child))
 235         (hook (derived-mode-hook-name child)))
 236
 237     (unless (stringp docstring)
 238       ;; Use a default docstring.
 239       (setq docstring
 240             (if (null parent)
 241                 (format "Major-mode.
 242 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 243               (format "Major mode derived from `%s' by `define-derived-mode'.
 244 It inherits all of the parent's attributes, but has its own keymap,
 245 abbrev table and syntax table:
 246
 247   `%s', `%s' and `%s'
 248
 249 which more-or-less shadow %s's corresponding tables."
 250                       parent map abbrev syntax parent))))
 251
 252     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 253       ;; Make sure the docstring mentions the mode's hook
 254       (setq docstring
 255             (concat docstring
 256                     (if (null parent)
 257                         "\n\nThis mode "
 258                       (concat
 259                        "\n\nIn addition to any hooks its parent mode "
 260                        (if (string-match (regexp-quote (format "`%s'" parent))
 261                                          docstring) nil
 262                          (format "`%s' " parent))
 263                        "might have run,\nthis mode "))
 264                     (format "runs the hook `%s'" hook)
 265                     ", as the final step\nduring initialization.")))
 266
 267     (unless (string-match "\\\\[{[]" docstring)
 268       ;; And don't forget to put the mode's keymap
 269       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 270
 271     docstring))
 272
 273 \f
 274 ;;; OBSOLETE
 275 ;; The functions below are only provided for backward compatibility with
 276 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 277
 278 (defsubst derived-mode-setup-function-name (mode)
 279   "Construct a setup-function name based on a MODE name."
 280   (intern (concat (symbol-name mode) "-setup")))
 281
 282 \f
 283 ;; Utility functions for defining a derived mode.
 284
 285 ;;;###autoload
 286 (defun derived-mode-init-mode-variables (mode)
 287   "Initialise variables for a new MODE.
 288 Right now, if they don't already exist, set up a blank keymap, an
 289 empty syntax table, and an empty abbrev table -- these will be merged
 290 the first time the mode is used."
 291
 292   (if (boundp (derived-mode-map-name mode))
 293       t
 294     (eval `(defvar ,(derived-mode-map-name mode)
 295                (make-sparse-keymap)
 296                ,(format "Keymap for %s." mode)))
 297     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 298
 299   (if (boundp (derived-mode-syntax-table-name mode))
 300       t
 301     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 302              ;; Make a syntax table which doesn't specify anything
 303              ;; for any char.  Valid data will be merged in by
 304              ;; derived-mode-merge-syntax-tables.
 305              (make-char-table 'syntax-table nil)
 306              ,(format "Syntax table for %s." mode)))
 307     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 308
 309   (if (boundp (derived-mode-abbrev-table-name mode))
 310       t
 311     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 312              (progn
 313                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 314                (make-abbrev-table))
 315              ,(format "Abbrev table for %s." mode)))))
 316 \f
 317 ;; Utility functions for running a derived mode.
 318
 319 (defun derived-mode-set-keymap (mode)
 320   "Set the keymap of the new MODE, maybe merging with the parent."
 321   (let* ((map-name (derived-mode-map-name mode))
 322          (new-map (eval map-name))
 323          (old-map (current-local-map)))
 324     (and old-map
 325          (get map-name 'derived-mode-unmerged)
 326          (derived-mode-merge-keymaps old-map new-map))
 327     (put map-name 'derived-mode-unmerged nil)
 328     (use-local-map new-map)))
 329
 330 (defun derived-mode-set-syntax-table (mode)
 331   "Set the syntax table of the new MODE, maybe merging with the parent."
 332   (let* ((table-name (derived-mode-syntax-table-name mode))
 333          (old-table (syntax-table))
 334          (new-table (eval table-name)))
 335     (if (get table-name 'derived-mode-unmerged)
 336         (derived-mode-merge-syntax-tables old-table new-table))
 337     (put table-name 'derived-mode-unmerged nil)
 338     (set-syntax-table new-table)))
 339
 340 (defun derived-mode-set-abbrev-table (mode)
 341   "Set the abbrev table for MODE if it exists.
 342 Always merge its parent into it, since the merge is non-destructive."
 343   (let* ((table-name (derived-mode-abbrev-table-name mode))
 344          (old-table local-abbrev-table)
 345          (new-table (eval table-name)))
 346     (derived-mode-merge-abbrev-tables old-table new-table)
 347     (setq local-abbrev-table new-table)))
 348
 349 ;;;(defun derived-mode-run-setup-function (mode)
 350 ;;;  "Run the setup function if it exists."
 351
 352 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 353 ;;;    (if (fboundp fname)
 354 ;;;     (funcall fname))))
 355
 356 (defun derived-mode-run-hooks (mode)
 357   "Run the mode hook for MODE."
 358   (let ((hooks-name (derived-mode-hook-name mode)))
 359     (if (boundp hooks-name)
 360         (run-hooks hooks-name))))
 361
 362 ;; Functions to merge maps and tables.
 363
 364 (defun derived-mode-merge-keymaps (old new)
 365   "Merge an OLD keymap into a NEW one.
 366 The old keymap is set to be the last cdr of the new one, so that there will
 367 be automatic inheritance."
 368   ;; ?? Can this just use `set-keymap-parent'?
 369   (let ((tail new))
 370     ;; Scan the NEW map for prefix keys.
 371     (while (consp tail)
 372       (and (consp (car tail))
 373            (let* ((key (vector (car (car tail))))
 374                   (subnew (lookup-key new key))
 375                   (subold (lookup-key old key)))
 376              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 377              (and (keymapp subnew) (keymapp subold)
 378                   (derived-mode-merge-keymaps subold subnew))))
 379       (and (vectorp (car tail))
 380            ;; Search a vector of ASCII char bindings for prefix keys.
 381            (let ((i (1- (length (car tail)))))
 382              (while (>= i 0)
 383                (let* ((key (vector i))
 384                       (subnew (lookup-key new key))
 385                       (subold (lookup-key old key)))
 386                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 387                  (and (keymapp subnew) (keymapp subold)
 388                       (derived-mode-merge-keymaps subold subnew)))
 389                (setq i (1- i)))))
 390       (setq tail (cdr tail))))
 391   (setcdr (nthcdr (1- (length new)) new) old))
 392
 393 (defun derived-mode-merge-syntax-tables (old new)
 394   "Merge an OLD syntax table into a NEW one.
 395 Where the new table already has an entry, nothing is copied from the old one."
 396   (set-char-table-parent new old))
 397
 398 ;; Merge an old abbrev table into a new one.
 399 ;; This function requires internal knowledge of how abbrev tables work,
 400 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 401 ;; as the value of the symbol, and the hook as the function definition.
 402 (defun derived-mode-merge-abbrev-tables (old new)
 403   (if old
 404       (mapatoms
 405        (lambda (symbol)
 406          (or (intern-soft (symbol-name symbol) new)
 407              (define-abbrev new (symbol-name symbol)
 408                (symbol-value symbol) (symbol-function symbol))))
 409        old)))
 410
 411 (provide 'derived)
 412
 413 ;;; derived.el ends here