lisp/abbrev.el

   1 ;;; abbrev.el --- abbrev mode commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This facility is documented in the Emacs Manual.
  28
  29 ;;; Code:
  30
  31 (defcustom only-global-abbrevs nil
  32   "*t means user plans to use global abbrevs only.
  33 This makes the commands that normally define mode-specific abbrevs
  34 define global abbrevs instead."
  35   :type 'boolean
  36   :group 'abbrev-mode
  37   :group 'convenience)
  38
  39 (defun abbrev-mode (&optional arg)
  40   "Toggle abbrev mode.
  41 With argument ARG, turn abbrev mode on iff ARG is positive.
  42 In abbrev mode, inserting an abbreviation causes it to expand
  43 and be replaced by its expansion."
  44   (interactive "P")
  45   (setq abbrev-mode
  46         (if (null arg) (not abbrev-mode)
  47           (> (prefix-numeric-value arg) 0)))
  48   (force-mode-line-update))
  49
  50 (defcustom abbrev-mode nil
  51   "Toggle abbrev mode.
  52 Non-nil means automatically expand abbrevs as they are inserted.
  53
  54 This variable automatically becomes buffer-local when set in any fashion.
  55 Changing it with \\[customize] sets the default value.
  56 Use the command `abbrev-mode' to enable or disable Abbrev mode in the current
  57 buffer."
  58   :type 'boolean
  59   :group 'abbrev-mode)
  60
  61 \f
  62 (defvar edit-abbrevs-map nil
  63   "Keymap used in edit-abbrevs.")
  64 (if edit-abbrevs-map
  65     nil
  66   (setq edit-abbrevs-map (make-sparse-keymap))
  67   (define-key edit-abbrevs-map "\C-x\C-s" 'edit-abbrevs-redefine)
  68   (define-key edit-abbrevs-map "\C-c\C-c" 'edit-abbrevs-redefine))
  69
  70 (defun kill-all-abbrevs ()
  71   "Undefine all defined abbrevs."
  72   (interactive)
  73   (let ((tables abbrev-table-name-list))
  74     (while tables
  75       (clear-abbrev-table (symbol-value (car tables)))
  76       (setq tables (cdr tables)))))
  77
  78 (defun insert-abbrevs ()
  79   "Insert after point a description of all defined abbrevs.
  80 Mark is set after the inserted text."
  81   (interactive)
  82   (push-mark
  83    (save-excursion
  84     (let ((tables abbrev-table-name-list))
  85       (while tables
  86         (insert-abbrev-table-description (car tables) t)
  87         (setq tables (cdr tables))))
  88     (point))))
  89
  90 (defun list-abbrevs (&optional local)
  91   "Display a list of defined abbrevs.
  92 If LOCAL is non-nil, interactively when invoked with a
  93 prefix arg, display only local, i.e. mode-specific, abbrevs.
  94 Otherwise display all abbrevs."
  95   (interactive "P")
  96   (display-buffer (prepare-abbrev-list-buffer local)))
  97
  98 (defun abbrev-table-name (table)
  99   "Value is the name of abbrev table TABLE."
 100   (let ((tables abbrev-table-name-list)
 101         found)
 102     (while (and (not found) tables)
 103       (when (eq (symbol-value (car tables)) table)
 104         (setq found (car tables)))
 105       (setq tables (cdr tables)))
 106     found))
 107
 108 (defun prepare-abbrev-list-buffer (&optional local)
 109   (save-excursion
 110     (let ((table local-abbrev-table))
 111       (set-buffer (get-buffer-create "*Abbrevs*"))
 112       (erase-buffer)
 113       (if local
 114           (insert-abbrev-table-description (abbrev-table-name table) t)
 115         (dolist (table abbrev-table-name-list)
 116           (insert-abbrev-table-description table t)))
 117       (goto-char (point-min))
 118       (set-buffer-modified-p nil)
 119       (edit-abbrevs-mode)
 120       (current-buffer))))
 121
 122 (defun edit-abbrevs-mode ()
 123   "Major mode for editing the list of abbrev definitions.
 124 \\{edit-abbrevs-map}"
 125   (interactive)
 126   (setq major-mode 'edit-abbrevs-mode)
 127   (setq mode-name "Edit-Abbrevs")
 128   (use-local-map edit-abbrevs-map))
 129
 130 (defun edit-abbrevs ()
 131   "Alter abbrev definitions by editing a list of them.
 132 Selects a buffer containing a list of abbrev definitions.
 133 You can edit them and type \\<edit-abbrevs-map>\\[edit-abbrevs-redefine] to redefine abbrevs
 134 according to your editing.
 135 Buffer contains a header line for each abbrev table,
 136  which is the abbrev table name in parentheses.
 137 This is followed by one line per abbrev in that table:
 138 NAME   USECOUNT   EXPANSION   HOOK
 139 where NAME and EXPANSION are strings with quotes,
 140 USECOUNT is an integer, and HOOK is any valid function
 141 or may be omitted (it is usually omitted)."
 142   (interactive)
 143   (switch-to-buffer (prepare-abbrev-list-buffer)))
 144
 145 (defun edit-abbrevs-redefine ()
 146   "Redefine abbrevs according to current buffer contents."
 147   (interactive)
 148   (define-abbrevs t)
 149   (set-buffer-modified-p nil))
 150
 151 (defun define-abbrevs (&optional arg)
 152   "Define abbrevs according to current visible buffer contents.
 153 See documentation of `edit-abbrevs' for info on the format of the
 154 text you must have in the buffer.
 155 With argument, eliminate all abbrev definitions except
 156 the ones defined from the buffer now."
 157   (interactive "P")
 158   (if arg (kill-all-abbrevs))
 159   (save-excursion
 160    (goto-char (point-min))
 161    (while (and (not (eobp)) (re-search-forward "^(" nil t))
 162      (let* ((buf (current-buffer))
 163             (table (read buf))
 164             abbrevs name hook exp count)
 165        (forward-line 1)
 166        (while (progn (forward-line 1)
 167                      (not (eolp)))
 168          (setq name (read buf) count (read buf) exp (read buf))
 169          (skip-chars-backward " \t\n\f")
 170          (setq hook (if (not (eolp)) (read buf)))
 171          (skip-chars-backward " \t\n\f")
 172          (setq abbrevs (cons (list name exp hook count) abbrevs)))
 173        (define-abbrev-table table abbrevs)))))
 174
 175 (defun read-abbrev-file (&optional file quietly)
 176   "Read abbrev definitions from file written with `write-abbrev-file'.
 177 Optional argument FILE is the name of the file to read;
 178 it defaults to the value of `abbrev-file-name'.
 179 Optional second argument QUIETLY non-nil means don't print anything."
 180   (interactive "fRead abbrev file: ")
 181   (load (if (and file (> (length file) 0)) file abbrev-file-name)
 182         nil quietly)
 183   (setq save-abbrevs t abbrevs-changed nil))
 184
 185 (defun quietly-read-abbrev-file (&optional file)
 186   "Read abbrev definitions from file written with write-abbrev-file.
 187 Optional argument FILE is the name of the file to read;
 188 it defaults to the value of `abbrev-file-name'.
 189 Does not print anything."
 190   ;(interactive "fRead abbrev file: ")
 191   (read-abbrev-file file t))
 192
 193 (defun write-abbrev-file (file)
 194   "Write all abbrev definitions to a file of Lisp code.
 195 The file written can be loaded in another session to define the same abbrevs.
 196 The argument FILE is the file name to write."
 197   (interactive
 198    (list
 199     (read-file-name "Write abbrev file: "
 200                     (file-name-directory (expand-file-name abbrev-file-name))
 201                     abbrev-file-name)))
 202   (or (and file (> (length file) 0))
 203       (setq file abbrev-file-name))
 204   (save-excursion
 205    (set-buffer (get-buffer-create " write-abbrev-file"))
 206    (erase-buffer)
 207    (let ((tables abbrev-table-name-list))
 208      (while tables
 209        (insert-abbrev-table-description (car tables) nil)
 210        (setq tables (cdr tables))))
 211    (write-region 1 (point-max) file)
 212    (erase-buffer)))
 213 \f
 214 (defun add-mode-abbrev (arg)
 215   "Define mode-specific abbrev for last word(s) before point.
 216 Argument is how many words before point form the expansion;
 217 or zero means the region is the expansion.
 218 A negative argument means to undefine the specified abbrev.
 219 Reads the abbreviation in the minibuffer.
 220
 221 Don't use this function in a Lisp program; use `define-abbrev' instead."
 222   (interactive "p")
 223   (add-abbrev
 224    (if only-global-abbrevs
 225        global-abbrev-table
 226      (or local-abbrev-table
 227          (error "No per-mode abbrev table")))
 228    "Mode" arg))
 229
 230 (defun add-global-abbrev (arg)
 231   "Define global (all modes) abbrev for last word(s) before point.
 232 The prefix argument specifies the number of words before point that form the
 233 expansion; or zero means the region is the expansion.
 234 A negative argument means to undefine the specified abbrev.
 235 This command uses the minibuffer to read the abbreviation.
 236
 237 Don't use this function in a Lisp program; use `define-abbrev' instead."
 238   (interactive "p")
 239   (add-abbrev global-abbrev-table "Global" arg))
 240
 241 (defun add-abbrev (table type arg)
 242   (let ((exp (and (>= arg 0)
 243                   (buffer-substring-no-properties
 244                    (point)
 245                    (if (= arg 0) (mark)
 246                      (save-excursion (forward-word (- arg)) (point))))))
 247         name)
 248     (setq name
 249           (read-string (format (if exp "%s abbrev for \"%s\": "
 250                                  "Undefine %s abbrev: ")
 251                                type exp)))
 252     (set-text-properties 0 (length name) nil name)
 253     (if (or (null exp)
 254             (not (abbrev-expansion name table))
 255             (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 256                               name (abbrev-expansion name table))))
 257         (define-abbrev table (downcase name) exp))))
 258
 259 (defun inverse-add-mode-abbrev (arg)
 260   "Define last word before point as a mode-specific abbrev.
 261 With prefix argument N, defines the Nth word before point.
 262 This command uses the minibuffer to read the expansion.
 263 Expands the abbreviation after defining it."
 264   (interactive "p")
 265   (inverse-add-abbrev
 266    (if only-global-abbrevs
 267        global-abbrev-table
 268      (or local-abbrev-table
 269          (error "No per-mode abbrev table")))
 270    "Mode" arg))
 271
 272 (defun inverse-add-global-abbrev (arg)
 273   "Define last word before point as a global (mode-independent) abbrev.
 274 With prefix argument N, defines the Nth word before point.
 275 This command uses the minibuffer to read the expansion.
 276 Expands the abbreviation after defining it."
 277   (interactive "p")
 278   (inverse-add-abbrev global-abbrev-table "Global" arg))
 279
 280 (defun inverse-add-abbrev (table type arg)
 281   (let (name exp start end)
 282     (save-excursion
 283       (forward-word (1+ (- arg)))
 284       (setq end (point))
 285       (backward-word 1)
 286       (setq start (point)
 287             name (buffer-substring-no-properties start end)))
 288
 289     (setq exp (read-string (format "%s expansion for \"%s\": " type name)
 290                            nil nil nil t))
 291     (when (or (not (abbrev-expansion name table))
 292               (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 293                                 name (abbrev-expansion name table))))
 294       (define-abbrev table (downcase name) exp)
 295       (save-excursion
 296         (goto-char end)
 297         (expand-abbrev)))))
 298
 299 (defun abbrev-prefix-mark (&optional arg)
 300   "Mark current point as the beginning of an abbrev.
 301 Abbrev to be expanded starts here rather than at beginning of word.
 302 This way, you can expand an abbrev with a prefix: insert the prefix,
 303 use this command, then insert the abbrev."
 304   (interactive "P")
 305   (or arg (expand-abbrev))
 306   (setq abbrev-start-location (point-marker)
 307         abbrev-start-location-buffer (current-buffer))
 308   (insert "-"))
 309
 310 (defun expand-region-abbrevs (start end &optional noquery)
 311   "For abbrev occurrence in the region, offer to expand it.
 312 The user is asked to type y or n for each occurrence.
 313 A prefix argument means don't query; expand all abbrevs.
 314 If called from a Lisp program, arguments are START END &optional NOQUERY."
 315   (interactive "r\nP")
 316   (save-excursion
 317     (goto-char start)
 318     (let ((lim (- (point-max) end))
 319           pnt string)
 320       (while (and (not (eobp))
 321                   (progn (forward-word 1)
 322                          (<= (setq pnt (point)) (- (point-max) lim))))
 323         (if (abbrev-expansion
 324              (setq string
 325                    (buffer-substring-no-properties
 326                     (save-excursion (forward-word -1) (point))
 327                     pnt)))
 328             (if (or noquery (y-or-n-p (format "Expand `%s'? " string)))
 329                 (expand-abbrev)))))))
 330
 331 ;;; abbrev.el ends here