lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
  69 is a string describing the argument list of DEF, such as
  70 \"(apply FUNCTION &rest ARGUMENTS)\".
  71 DEF is the function whose usage we're looking for in DOCSTRING."
  72   ;; Functions can get the calling sequence at the end of the doc string.
  73   ;; In cases where `function' has been fset to a subr we can't search for
  74   ;; function's name in the doc string so we use `fn' as the anonymous
  75   ;; function name instead.
  76   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  77     (cons (format "(%s%s"
  78                   ;; Replace `fn' with the actual function name.
  79                   (if (consp def) "anonymous" def)
  80                   (match-string 1 docstring))
  81           (unless (zerop (match-beginning 0))
  82             (substring docstring 0 (match-beginning 0))))))
  83
  84 ;; FIXME: Move to subr.el?
  85 (defun help-add-fundoc-usage (docstring arglist)
  86   "Add the usage info to DOCSTRING.
  87 If DOCSTRING already has a usage info, then just return it unchanged.
  88 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  89 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  90   (unless (stringp docstring) (setq docstring ""))
  91   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
  92           (eq arglist t))
  93       docstring
  94     (concat docstring
  95             (if (string-match "\n?\n\\'" docstring)
  96                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  97               "\n\n")
  98             (if (and (stringp arglist)
  99                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
 100                 (concat "(fn" (match-string 1 arglist) ")")
 101               (format "%S" (help-make-usage 'fn arglist))))))
 102
 103 ;; FIXME: Move to subr.el?
 104 (defun help-function-arglist (def &optional preserve-names)
 105   "Return a formal argument list for the function DEF.
 106 IF PRESERVE-NAMES is non-nil, return a formal arglist that uses
 107 the same names as used in the original source code, when possible."
 108   ;; Handle symbols aliased to other symbols.
 109   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 110   ;; If definition is a macro, find the function inside it.
 111   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 112   (cond
 113    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
 114    ((eq (car-safe def) 'lambda) (nth 1 def))
 115    ((eq (car-safe def) 'closure) (nth 2 def))
 116    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
 117         (subrp def))
 118     (or (when preserve-names
 119           (let* ((doc (condition-case nil (documentation def) (error nil)))
 120                  (docargs (if doc (car (help-split-fundoc doc nil))))
 121                  (arglist (if docargs
 122                               (cdar (read-from-string (downcase docargs)))))
 123                  (valid t))
 124             ;; Check validity.
 125             (dolist (arg arglist)
 126               (unless (and (symbolp arg)
 127                            (let ((name (symbol-name arg)))
 128                              (if (eq (aref name 0) ?&)
 129                                  (memq arg '(&rest &optional))
 130                                (not (string-match "\\." name)))))
 131                 (setq valid nil)))
 132             (when valid arglist)))
 133         (let* ((args-desc (if (not (subrp def))
 134                               (aref def 0)
 135                             (let ((a (subr-arity def)))
 136                               (logior (car a)
 137                                       (if (numberp (cdr a))
 138                                           (lsh (cdr a) 8)
 139                                         (lsh 1 7))))))
 140                (max (lsh args-desc -8))
 141                (min (logand args-desc 127))
 142                (rest (logand args-desc 128))
 143                (arglist ()))
 144           (dotimes (i min)
 145             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
 146           (when (> max min)
 147             (push '&optional arglist)
 148             (dotimes (i (- max min))
 149               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
 150                     arglist)))
 151           (unless (zerop rest) (push '&rest arglist) (push 'rest arglist))
 152           (nreverse arglist))))
 153    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 154     "[Arg list not available until function definition is loaded.]")
 155    (t t)))
 156
 157 ;; FIXME: Move to subr.el?
 158 (defun help-make-usage (function arglist)
 159   (cons (if (symbolp function) function 'anonymous)
 160         (mapcar (lambda (arg)
 161                   (if (not (symbolp arg)) arg
 162                     (let ((name (symbol-name arg)))
 163                       (cond
 164                        ((string-match "\\`&" name) arg)
 165                        ((string-match "\\`_" name)
 166                         (intern (upcase (substring name 1))))
 167                        (t (intern (upcase name)))))))
 168                 arglist)))
 169
 170 ;; Could be this, if we make symbol-file do the work below.
 171 ;; (defun help-C-file-name (subr-or-var kind)
 172 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 173 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 174 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 175 ;;               (subr-name subr-or-var))
 176 ;;             (if (eq kind 'var) 'defvar 'defun)))
 177 ;;;###autoload
 178 (defun help-C-file-name (subr-or-var kind)
 179   "Return the name of the C file where SUBR-OR-VAR is defined.
 180 KIND should be `var' for a variable or `subr' for a subroutine."
 181   (let ((docbuf (get-buffer-create " *DOC*"))
 182         (name (if (eq 'var kind)
 183                   (concat "V" (symbol-name subr-or-var))
 184                 (concat "F" (subr-name subr-or-var)))))
 185     (with-current-buffer docbuf
 186       (goto-char (point-min))
 187       (if (eobp)
 188           (insert-file-contents-literally
 189            (expand-file-name internal-doc-file-name doc-directory)))
 190       (let ((file (catch 'loop
 191                     (while t
 192                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 193                         (re-search-backward "\1fS\\(.*\\)")
 194                         (let ((file (match-string 1)))
 195                           (if (member file build-files)
 196                               (throw 'loop file)
 197                             (goto-char pnt))))))))
 198         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 199             (setq file (replace-match ".m" t t file 1))
 200           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 201               (setq file (replace-match ".c" t t file))))
 202         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 203             (concat "src/" file)
 204           file)))))
 205
 206 (defcustom help-downcase-arguments nil
 207   "If non-nil, argument names in *Help* buffers are downcased."
 208   :type 'boolean
 209   :group 'help
 210   :version "23.2")
 211
 212 (defun help-highlight-arg (arg)
 213   "Highlight ARG as an argument name for a *Help* buffer.
 214 Return ARG in face `help-argument-name'; ARG is also downcased
 215 if the variable `help-downcase-arguments' is non-nil."
 216   (propertize (if help-downcase-arguments (downcase arg) arg)
 217               'face 'help-argument-name))
 218
 219 (defun help-do-arg-highlight (doc args)
 220   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 221     (modify-syntax-entry ?\- "w")
 222     (dolist (arg args)
 223       (setq doc (replace-regexp-in-string
 224                  ;; This is heuristic, but covers all common cases
 225                  ;; except ARG1-ARG2
 226                  (concat "\\<"                   ; beginning of word
 227                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 228                          "\\("
 229                          (regexp-quote arg)
 230                          "\\)"
 231                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 232                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 233                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 234                          "\\>")                  ; end of word
 235                  (help-highlight-arg arg)
 236                  doc t t 1)))
 237     doc))
 238
 239 (defun help-highlight-arguments (usage doc &rest args)
 240   (when (and usage (string-match "^(" usage))
 241     (with-temp-buffer
 242       (insert usage)
 243       (goto-char (point-min))
 244       (let ((case-fold-search nil)
 245             (next (not (or args (looking-at "\\["))))
 246             (opt nil))
 247         ;; Make a list of all arguments
 248         (skip-chars-forward "^ ")
 249         (while next
 250           (or opt (not (looking-at " &")) (setq opt t))
 251           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 252               (setq next nil)
 253             (setq args (cons (match-string 2) args))
 254             (when (and opt (string= (match-string 1) "("))
 255               ;; A pesky CL-style optional argument with default value,
 256               ;; so let's skip over it
 257               (search-backward "(")
 258               (goto-char (scan-sexps (point) 1)))))
 259         ;; Highlight arguments in the USAGE string
 260         (setq usage (help-do-arg-highlight (buffer-string) args))
 261         ;; Highlight arguments in the DOC string
 262         (setq doc (and doc (help-do-arg-highlight doc args))))))
 263   ;; Return value is like the one from help-split-fundoc, but highlighted
 264   (cons usage doc))
 265
 266 ;; The following function was compiled from the former functions
 267 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 268 ;; some excerpts from `describe-function-1' and `describe-variable'.
 269 ;; The only additional twists provided are (1) locate the defining file
 270 ;; for autoloaded functions, and (2) give preference to files in the
 271 ;; "install directory" (directories found via `load-path') rather than
 272 ;; to files in the "compile directory" (directories found by searching
 273 ;; the loaddefs.el file).  We autoload it because it's also used by
 274 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 275
 276 ;;;###autoload
 277 (defun find-lisp-object-file-name (object type)
 278   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 279 OBJECT should be a symbol associated with a function, variable, or face;
 280   alternatively, it can be a function definition.
 281 If TYPE is `defvar', search for a variable definition.
 282 If TYPE is `defface', search for a face definition.
 283 If TYPE is the value returned by `symbol-function' for a function symbol,
 284  search for a function definition.
 285
 286 The return value is the absolute name of a readable file where OBJECT is
 287 defined.  If several such files exist, preference is given to a file
 288 found via `load-path'.  The return value can also be `C-source', which
 289 means that OBJECT is a function or variable defined in C.  If no
 290 suitable file is found, return nil."
 291   (let* ((autoloaded (eq (car-safe type) 'autoload))
 292          (file-name (or (and autoloaded (nth 1 type))
 293                         (symbol-file
 294                          object (if (memq type (list 'defvar 'defface))
 295                                     type
 296                                   'defun)))))
 297     (cond
 298      (autoloaded
 299       ;; An autoloaded function: Locate the file since `symbol-function'
 300       ;; has only returned a bare string here.
 301       (setq file-name
 302             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 303      ((and (stringp file-name)
 304            (string-match "[.]*loaddefs.el\\'" file-name))
 305       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 306       ;; and try to extract the defining file.  The following form is
 307       ;; from `describe-function-1' and `describe-variable'.
 308       (let ((location
 309              (condition-case nil
 310                  (find-function-search-for-symbol object nil file-name)
 311                (error nil))))
 312         (when (cdr location)
 313           (with-current-buffer (car location)
 314             (goto-char (cdr location))
 315             (when (re-search-backward
 316                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 317               (setq file-name
 318                     (locate-file
 319                      (file-name-sans-extension
 320                       (match-string-no-properties 1))
 321                      load-path '(".el" ".elc") 'readable))))))))
 322
 323     (cond
 324      ((and (not file-name) (subrp type))
 325       ;; A built-in function.  The form is from `describe-function-1'.
 326       (if (get-buffer " *DOC*")
 327           (help-C-file-name type 'subr)
 328         'C-source))
 329      ((and (not file-name) (symbolp object)
 330            (integerp (get object 'variable-documentation)))
 331       ;; A variable defined in C.  The form is from `describe-variable'.
 332       (if (get-buffer " *DOC*")
 333           (help-C-file-name object 'var)
 334         'C-source))
 335      ((not (stringp file-name))
 336       ;; If we don't have a file-name string by now, we lost.
 337       nil)
 338      ;; Now, `file-name' should have become an absolute file name.
 339      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 340      ((let (fn)
 341         (and (string-equal file-name
 342                            (expand-file-name ".emacs.elc" "~"))
 343              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 344              fn)))
 345      ;; When the Elisp source file can be found in the install
 346      ;; directory, return the name of that file.
 347      ((let ((lib-name
 348              (if (string-match "[.]elc\\'" file-name)
 349                  (substring-no-properties file-name 0 -1)
 350                file-name)))
 351         (or (and (file-readable-p lib-name) lib-name)
 352             ;; The library might be compressed.
 353             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 354      ((let* ((lib-name (file-name-nondirectory file-name))
 355              ;; The next form is from `describe-simplify-lib-file-name'.
 356              (file-name
 357               ;; Try converting the absolute file name to a library
 358               ;; name, convert that back to a file name and see if we
 359               ;; get the original one.  If so, they are equivalent.
 360               (if (equal file-name (locate-file lib-name load-path '("")))
 361                   (if (string-match "[.]elc\\'" lib-name)
 362                       (substring-no-properties lib-name 0 -1)
 363                     lib-name)
 364                 file-name))
 365              ;; The next three forms are from `find-source-lisp-file'.
 366              (elc-file (locate-file
 367                         (concat file-name
 368                                 (if (string-match "\\.el\\'" file-name)
 369                                     "c"
 370                                   ".elc"))
 371                         load-path nil 'readable))
 372              (str (when elc-file
 373                     (with-temp-buffer
 374                       (insert-file-contents-literally elc-file nil 0 256)
 375                       (buffer-string))))
 376              (src-file (and str
 377                             (string-match ";;; from file \\(.*\\.el\\)" str)
 378                             (match-string 1 str))))
 379         (and src-file (file-readable-p src-file) src-file))))))
 380
 381 (declare-function ad-get-advice-info "advice" (function))
 382
 383 ;;;###autoload
 384 (defun describe-function-1 (function)
 385   (let* ((advised (and (symbolp function) (featurep 'advice)
 386                        (ad-get-advice-info function)))
 387          ;; If the function is advised, use the symbol that has the
 388          ;; real definition, if that symbol is already set up.
 389          (real-function
 390           (or (and advised
 391                    (let ((origname (cdr (assq 'origname advised))))
 392                      (and (fboundp origname) origname)))
 393               function))
 394          ;; Get the real definition.
 395          (def (if (symbolp real-function)
 396                   (symbol-function real-function)
 397                 function))
 398          file-name string
 399          (beg (if (commandp def) "an interactive " "a "))
 400          (pt1 (with-current-buffer (help-buffer) (point)))
 401          errtype)
 402     (setq string
 403           (cond ((or (stringp def) (vectorp def))
 404                  "a keyboard macro")
 405                 ((subrp def)
 406                  (if (eq 'unevalled (cdr (subr-arity def)))
 407                      (concat beg "special form")
 408                    (concat beg "built-in function")))
 409                 ((byte-code-function-p def)
 410                  (concat beg "compiled Lisp function"))
 411                 ((symbolp def)
 412                  (while (and (fboundp def)
 413                              (symbolp (symbol-function def)))
 414                    (setq def (symbol-function def)))
 415                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 416                  (or (fboundp def) (setq errtype 'alias))
 417                  (format "an alias for `%s'" def))
 418                 ((eq (car-safe def) 'lambda)
 419                  (concat beg "Lisp function"))
 420                 ((eq (car-safe def) 'macro)
 421                  "a Lisp macro")
 422                 ((eq (car-safe def) 'closure)
 423                  (concat beg "Lisp closure"))
 424                 ((eq (car-safe def) 'autoload)
 425                  (format "%s autoloaded %s"
 426                          (if (commandp def) "an interactive" "an")
 427                          (if (eq (nth 4 def) 'keymap) "keymap"
 428                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 429                 ((keymapp def)
 430                  (let ((is-full nil)
 431                        (elts (cdr-safe def)))
 432                    (while elts
 433                      (if (char-table-p (car-safe elts))
 434                          (setq is-full t
 435                                elts nil))
 436                      (setq elts (cdr-safe elts)))
 437                    (if is-full
 438                        "a full keymap"
 439                      "a sparse keymap")))
 440                 (t "")))
 441     (princ string)
 442     (if (eq errtype 'alias)
 443         (princ ",\nwhich is not defined.  Please make a bug report.")
 444       (with-current-buffer standard-output
 445         (save-excursion
 446           (save-match-data
 447             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 448               (help-xref-button 1 'help-function def)))))
 449
 450       (setq file-name (find-lisp-object-file-name function def))
 451       (when file-name
 452         (princ " in `")
 453         ;; We used to add .el to the file name,
 454         ;; but that's completely wrong when the user used load-file.
 455         (princ (if (eq file-name 'C-source)
 456                    "C source code"
 457                  (file-name-nondirectory file-name)))
 458         (princ "'")
 459         ;; Make a hyperlink to the library.
 460         (with-current-buffer standard-output
 461           (save-excursion
 462             (re-search-backward "`\\([^`']+\\)'" nil t)
 463             (help-xref-button 1 'help-function-def function file-name))))
 464       (princ ".")
 465       (with-current-buffer (help-buffer)
 466         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 467                                   (point)))
 468       (terpri)(terpri)
 469       (when (commandp function)
 470         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 471               (remapped (command-remapping function)))
 472           (unless (memq remapped '(ignore undefined))
 473             (let ((keys (where-is-internal
 474                          (or remapped function) overriding-local-map nil nil))
 475                   non-modified-keys)
 476               (if (and (eq function 'self-insert-command)
 477                        (vectorp (car-safe keys))
 478                        (consp (aref (car keys) 0)))
 479                   (princ "It is bound to many ordinary text characters.\n")
 480                 ;; Which non-control non-meta keys run this command?
 481                 (dolist (key keys)
 482                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 483                       (push key non-modified-keys)))
 484                 (when remapped
 485                   (princ "It is remapped to `")
 486                   (princ (symbol-name remapped))
 487                   (princ "'"))
 488
 489                 (when keys
 490                   (princ (if remapped ", which is bound to " "It is bound to "))
 491                   ;; If lots of ordinary text characters run this command,
 492                   ;; don't mention them one by one.
 493                   (if (< (length non-modified-keys) 10)
 494                       (princ (mapconcat 'key-description keys ", "))
 495                     (dolist (key non-modified-keys)
 496                       (setq keys (delq key keys)))
 497                     (if keys
 498                         (progn
 499                           (princ (mapconcat 'key-description keys ", "))
 500                           (princ ", and many ordinary text characters"))
 501                       (princ "many ordinary text characters"))))
 502                 (when (or remapped keys non-modified-keys)
 503                   (princ ".")
 504                   (terpri)))))
 505
 506           (with-current-buffer (help-buffer)
 507             (fill-region-as-paragraph pt2 (point))
 508             (unless (looking-back "\n\n")
 509               (terpri)))))
 510       ;; Note that list* etc do not get this property until
 511       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 512       (when (and (symbolp function)
 513                  (eq (get function 'byte-compile)
 514                      'cl-byte-compile-compiler-macro))
 515         (princ "This function has a compiler macro")
 516         (let ((lib (get function 'compiler-macro-file)))
 517           (when (stringp lib)
 518             (princ (format " in `%s'" lib))
 519             (with-current-buffer standard-output
 520               (save-excursion
 521                 (re-search-backward "`\\([^`']+\\)'" nil t)
 522                 (help-xref-button 1 'help-function-cmacro function lib)))))
 523         (princ ".\n\n"))
 524       (let* ((advertised (gethash def advertised-signature-table t))
 525              (arglist (if (listp advertised)
 526                           advertised (help-function-arglist def)))
 527              (doc (condition-case err (documentation function)
 528                     (error (format "No Doc! %S" err))))
 529              (usage (help-split-fundoc doc function)))
 530         (with-current-buffer standard-output
 531           ;; If definition is a keymap, skip arglist note.
 532           (unless (keymapp function)
 533             (if usage (setq doc (cdr usage)))
 534             (let* ((use (cond
 535                          ((and usage (not (listp advertised))) (car usage))
 536                          ((listp arglist)
 537                           (format "%S" (help-make-usage function arglist)))
 538                          ((stringp arglist) arglist)
 539                          ;; Maybe the arglist is in the docstring of a symbol
 540                          ;; this one is aliased to.
 541                          ((let ((fun real-function))
 542                             (while (and (symbolp fun)
 543                                         (setq fun (symbol-function fun))
 544                                         (not (setq usage (help-split-fundoc
 545                                                           (documentation fun)
 546                                                           function)))))
 547                             usage)
 548                           (car usage))
 549                          ((or (stringp def)
 550                               (vectorp def))
 551                           (format "\nMacro: %s" (format-kbd-macro def)))
 552                          (t "[Missing arglist.  Please make a bug report.]")))
 553                    (high (help-highlight-arguments use doc)))
 554               (let ((fill-begin (point)))
 555                 (insert (car high) "\n")
 556                 (fill-region fill-begin (point)))
 557               (setq doc (cdr high))))
 558
 559           ;; If this is a derived mode, link to the parent.
 560           (let ((parent-mode (and (symbolp real-function)
 561                                   (get real-function
 562                                        'derived-mode-parent))))
 563             (when parent-mode
 564               (with-current-buffer standard-output
 565                 (insert "\nParent mode: `")
 566                 (let ((beg (point)))
 567                   (insert (format "%s" parent-mode))
 568                   (make-text-button beg (point)
 569                                     'type 'help-function
 570                                     'help-args (list parent-mode))))
 571               (princ "'.\n")))
 572
 573           (let* ((obsolete (and
 574                             ;; function might be a lambda construct.
 575                             (symbolp function)
 576                             (get function 'byte-obsolete-info)))
 577                  (use (car obsolete)))
 578             (when obsolete
 579               (princ "\nThis function is obsolete")
 580               (when (nth 2 obsolete)
 581                 (insert (format " since %s" (nth 2 obsolete))))
 582               (insert (cond ((stringp use) (concat ";\n" use))
 583                             (use (format ";\nuse `%s' instead." use))
 584                             (t "."))
 585                       "\n"))
 586             (insert "\n"
 587                     (or doc "Not documented."))))))))
 588
 589 \f
 590 ;; Variables
 591
 592 ;;;###autoload
 593 (defun variable-at-point (&optional any-symbol)
 594   "Return the bound variable symbol found at or before point.
 595 Return 0 if there is no such symbol.
 596 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 597   (with-syntax-table emacs-lisp-mode-syntax-table
 598     (or (condition-case ()
 599             (save-excursion
 600               (skip-chars-forward "'")
 601               (or (not (zerop (skip-syntax-backward "_w")))
 602                   (eq (char-syntax (following-char)) ?w)
 603                   (eq (char-syntax (following-char)) ?_)
 604                   (forward-sexp -1))
 605               (skip-chars-forward "'")
 606               (let ((obj (read (current-buffer))))
 607                 (and (symbolp obj) (boundp obj) obj)))
 608           (error nil))
 609         (let* ((str (find-tag-default))
 610                (sym (if str (intern-soft str))))
 611           (if (and sym (or any-symbol (boundp sym)))
 612               sym
 613             (save-match-data
 614               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 615                 (setq sym (intern-soft (match-string 1 str)))
 616                 (and (or any-symbol (boundp sym)) sym)))))
 617         0)))
 618
 619 (defun describe-variable-custom-version-info (variable)
 620   (let ((custom-version (get variable 'custom-version))
 621         (cpv (get variable 'custom-package-version))
 622         (output nil))
 623     (if custom-version
 624         (setq output
 625               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 626                       custom-version))
 627       (when cpv
 628         (let* ((package (car-safe cpv))
 629                (version (if (listp (cdr-safe cpv))
 630                             (car (cdr-safe cpv))
 631                           (cdr-safe cpv)))
 632                (pkg-versions (assq package customize-package-emacs-version-alist))
 633                (emacsv (cdr (assoc version pkg-versions))))
 634           (if (and package version)
 635               (setq output
 636                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 637                                     (if emacsv
 638                                         (format " that is part of Emacs %s" emacsv))
 639                                     ".\n")
 640                             version package))))))
 641     output))
 642
 643 ;;;###autoload
 644 (defun describe-variable (variable &optional buffer frame)
 645   "Display the full documentation of VARIABLE (a symbol).
 646 Returns the documentation as a string, also.
 647 If VARIABLE has a buffer-local value in BUFFER or FRAME
 648 \(default to the current buffer and current frame),
 649 it is displayed along with the global value."
 650   (interactive
 651    (let ((v (variable-at-point))
 652          (enable-recursive-minibuffers t)
 653          val)
 654      (setq val (completing-read (if (symbolp v)
 655                                     (format
 656                                      "Describe variable (default %s): " v)
 657                                   "Describe variable: ")
 658                                 obarray
 659                                 (lambda (vv)
 660                                   (or (get vv 'variable-documentation)
 661                                       (and (boundp vv) (not (keywordp vv)))))
 662                                 t nil nil
 663                                 (if (symbolp v) (symbol-name v))))
 664      (list (if (equal val "")
 665                v (intern val)))))
 666   (let (file-name)
 667     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 668     (unless (frame-live-p frame) (setq frame (selected-frame)))
 669     (if (not (symbolp variable))
 670         (message "You did not specify a variable")
 671       (save-excursion
 672         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 673               val val-start-pos locus)
 674           ;; Extract the value before setting up the output buffer,
 675           ;; in case `buffer' *is* the output buffer.
 676           (unless valvoid
 677             (with-selected-frame frame
 678               (with-current-buffer buffer
 679                 (setq val (symbol-value variable)
 680                       locus (variable-binding-locus variable)))))
 681           (help-setup-xref (list #'describe-variable variable buffer)
 682                            (called-interactively-p 'interactive))
 683           (with-help-window (help-buffer)
 684             (with-current-buffer buffer
 685               (prin1 variable)
 686               (setq file-name (find-lisp-object-file-name variable 'defvar))
 687
 688               (if file-name
 689                   (progn
 690                     (princ " is a variable defined in `")
 691                     (princ (if (eq file-name 'C-source)
 692                                "C source code"
 693                              (file-name-nondirectory file-name)))
 694                     (princ "'.\n")
 695                     (with-current-buffer standard-output
 696                       (save-excursion
 697                         (re-search-backward "`\\([^`']+\\)'" nil t)
 698                         (help-xref-button 1 'help-variable-def
 699                                           variable file-name)))
 700                     (if valvoid
 701                         (princ "It is void as a variable.")
 702                       (princ "Its ")))
 703                 (if valvoid
 704                     (princ " is void as a variable.")
 705                   (princ "'s "))))
 706             (unless valvoid
 707               (with-current-buffer standard-output
 708                 (setq val-start-pos (point))
 709                 (princ "value is ")
 710                 (let ((from (point)))
 711                   (terpri)
 712                   (pp val)
 713                   (if (< (point) (+ 68 (line-beginning-position 0)))
 714                       (delete-region from (1+ from))
 715                     (delete-region (1- from) from))
 716                   (let* ((sv (get variable 'standard-value))
 717                          (origval (and (consp sv)
 718                                        (condition-case nil
 719                                            (eval (car sv))
 720                                          (error :help-eval-error)))))
 721                     (when (and (consp sv)
 722                                (not (equal origval val))
 723                                (not (equal origval :help-eval-error)))
 724                       (princ "\nOriginal value was \n")
 725                       (setq from (point))
 726                       (pp origval)
 727                       (if (< (point) (+ from 20))
 728                           (delete-region (1- from) from)))))))
 729             (terpri)
 730             (when locus
 731               (cond
 732                ((bufferp locus)
 733                 (princ (format "%socal in buffer %s; "
 734                                (if (get variable 'permanent-local)
 735                                    "Permanently l" "L")
 736                                (buffer-name))))
 737                ((framep locus)
 738                 (princ (format "It is a frame-local variable; ")))
 739                ((terminal-live-p locus)
 740                 (princ (format "It is a terminal-local variable; ")))
 741                (t
 742                 (princ (format "It is local to %S" locus))))
 743               (if (not (default-boundp variable))
 744                   (princ "globally void")
 745                 (let ((val (default-value variable)))
 746                   (with-current-buffer standard-output
 747                     (princ "global value is ")
 748                     (terpri)
 749                     ;; Fixme: pp can take an age if you happen to
 750                     ;; ask for a very large expression.  We should
 751                     ;; probably print it raw once and check it's a
 752                     ;; sensible size before prettyprinting.  -- fx
 753                     (let ((from (point)))
 754                       (pp val)
 755                       ;; See previous comment for this function.
 756                       ;; (help-xref-on-pp from (point))
 757                       (if (< (point) (+ from 20))
 758                           (delete-region (1- from) from))))))
 759               (terpri))
 760
 761             ;; If the value is large, move it to the end.
 762             (with-current-buffer standard-output
 763               (when (> (count-lines (point-min) (point-max)) 10)
 764                 ;; Note that setting the syntax table like below
 765                 ;; makes forward-sexp move over a `'s' at the end
 766                 ;; of a symbol.
 767                 (set-syntax-table emacs-lisp-mode-syntax-table)
 768                 (goto-char val-start-pos)
 769                 ;; The line below previously read as
 770                 ;; (delete-region (point) (progn (end-of-line) (point)))
 771                 ;; which suppressed display of the buffer local value for
 772                 ;; large values.
 773                 (when (looking-at "value is") (replace-match ""))
 774                 (save-excursion
 775                   (insert "\n\nValue:")
 776                   (set (make-local-variable 'help-button-cache)
 777                        (point-marker)))
 778                 (insert "value is shown ")
 779                 (insert-button "below"
 780                                'action help-button-cache
 781                                'follow-link t
 782                                'help-echo "mouse-2, RET: show value")
 783                 (insert ".\n")))
 784             (terpri)
 785
 786             (let* ((alias (condition-case nil
 787                               (indirect-variable variable)
 788                             (error variable)))
 789                    (obsolete (get variable 'byte-obsolete-variable))
 790                    (use (car obsolete))
 791                    (safe-var (get variable 'safe-local-variable))
 792                    (doc (or (documentation-property variable 'variable-documentation)
 793                             (documentation-property alias 'variable-documentation)))
 794                    (extra-line nil))
 795               ;; Add a note for variables that have been make-var-buffer-local.
 796               (when (and (local-variable-if-set-p variable)
 797                          (or (not (local-variable-p variable))
 798                              (with-temp-buffer
 799                                (local-variable-if-set-p variable))))
 800                 (setq extra-line t)
 801                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 802
 803               ;; Mention if it's an alias
 804               (unless (eq alias variable)
 805                 (setq extra-line t)
 806                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 807
 808               (when obsolete
 809                 (setq extra-line t)
 810                 (princ "  This variable is obsolete")
 811                 (if (nth 2 obsolete)
 812                     (princ (format " since %s" (nth 2 obsolete))))
 813                 (princ (cond ((stringp use) (concat ";\n  " use))
 814                              (use (format ";\n  use `%s' instead." (car obsolete)))
 815                              (t ".")))
 816                 (terpri))
 817
 818               (when (member (cons variable val) file-local-variables-alist)
 819                 (setq extra-line t)
 820                 (if (member (cons variable val) dir-local-variables-alist)
 821                     (let ((file (and (buffer-file-name)
 822                                       (not (file-remote-p (buffer-file-name)))
 823                                       (dir-locals-find-file
 824                                        (buffer-file-name))))
 825                           (type "file"))
 826                       (princ "  This variable is a directory local variable")
 827                       (when file
 828                         (if (consp file) ; result from cache
 829                             ;; If the cache element has an mtime, we
 830                             ;; assume it came from a file.
 831                             (if (nth 2 file)
 832                                 (setq file (expand-file-name
 833                                             dir-locals-file (car file)))
 834                               ;; Otherwise, assume it was set directly.
 835                               (setq type "directory")))
 836                         (princ (format "\n  from the %s \"%s\"" type file)))
 837                       (princ ".\n"))
 838                   (princ "  This variable is a file local variable.\n")))
 839
 840               (when (memq variable ignored-local-variables)
 841                 (setq extra-line t)
 842                 (princ "  This variable is ignored when used as a file local \
 843 variable.\n"))
 844
 845               ;; Can be both risky and safe, eg auto-fill-function.
 846               (when (risky-local-variable-p variable)
 847                 (setq extra-line t)
 848                 (princ "  This variable is potentially risky when used as a \
 849 file local variable.\n")
 850                 (when (assq variable safe-local-variable-values)
 851                   (princ "  However, you have added it to \
 852 `safe-local-variable-values'.\n")))
 853
 854               (when safe-var
 855                 (setq extra-line t)
 856                 (princ "  This variable is safe as a file local variable ")
 857                 (princ "if its value\n  satisfies the predicate ")
 858                 (princ (if (byte-code-function-p safe-var)
 859                            "which is byte-compiled expression.\n"
 860                          (format "`%s'.\n" safe-var))))
 861
 862               (if extra-line (terpri))
 863               (princ "Documentation:\n")
 864               (with-current-buffer standard-output
 865                 (insert (or doc "Not documented as a variable."))))
 866
 867             ;; Make a link to customize if this variable can be customized.
 868             (when (custom-variable-p variable)
 869               (let ((customize-label "customize"))
 870                 (terpri)
 871                 (terpri)
 872                 (princ (concat "You can " customize-label " this variable."))
 873                 (with-current-buffer standard-output
 874                   (save-excursion
 875                     (re-search-backward
 876                      (concat "\\(" customize-label "\\)") nil t)
 877                     (help-xref-button 1 'help-customize-variable variable))))
 878               ;; Note variable's version or package version
 879               (let ((output (describe-variable-custom-version-info variable)))
 880                 (when output
 881                   (terpri)
 882                   (terpri)
 883                   (princ output))))
 884
 885             (with-current-buffer standard-output
 886               ;; Return the text we displayed.
 887               (buffer-string))))))))
 888
 889
 890 ;;;###autoload
 891 (defun describe-syntax (&optional buffer)
 892   "Describe the syntax specifications in the syntax table of BUFFER.
 893 The descriptions are inserted in a help buffer, which is then displayed.
 894 BUFFER defaults to the current buffer."
 895   (interactive)
 896   (setq buffer (or buffer (current-buffer)))
 897   (help-setup-xref (list #'describe-syntax buffer)
 898                    (called-interactively-p 'interactive))
 899   (with-help-window (help-buffer)
 900     (let ((table (with-current-buffer buffer (syntax-table))))
 901       (with-current-buffer standard-output
 902         (describe-vector table 'internal-describe-syntax-value)
 903         (while (setq table (char-table-parent table))
 904           (insert "\nThe parent syntax table is:")
 905           (describe-vector table 'internal-describe-syntax-value))))))
 906
 907 (defun help-describe-category-set (value)
 908   (insert (cond
 909            ((null value) "default")
 910            ((char-table-p value) "deeper char-table ...")
 911            (t (condition-case nil
 912                   (category-set-mnemonics value)
 913                 (error "invalid"))))))
 914
 915 ;;;###autoload
 916 (defun describe-categories (&optional buffer)
 917   "Describe the category specifications in the current category table.
 918 The descriptions are inserted in a buffer, which is then displayed.
 919 If BUFFER is non-nil, then describe BUFFER's category table instead.
 920 BUFFER should be a buffer or a buffer name."
 921   (interactive)
 922   (setq buffer (or buffer (current-buffer)))
 923   (help-setup-xref (list #'describe-categories buffer)
 924                    (called-interactively-p 'interactive))
 925   (with-help-window (help-buffer)
 926     (let* ((table (with-current-buffer buffer (category-table)))
 927            (docs (char-table-extra-slot table 0)))
 928       (if (or (not (vectorp docs)) (/= (length docs) 95))
 929           (error "Invalid first extra slot in this category table\n"))
 930       (with-current-buffer standard-output
 931         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 932         (let ((pos (point)) (items 0) lines n)
 933           (dotimes (i 95)
 934             (if (aref docs i) (setq items (1+ items))))
 935           (setq lines (1+ (/ (1- items) 4)))
 936           (setq n 0)
 937           (dotimes (i 95)
 938             (let ((elt (aref docs i)))
 939               (when elt
 940                 (string-match ".*" elt)
 941                 (setq elt (match-string 0 elt))
 942                 (if (>= (length elt) 17)
 943                     (setq elt (concat (substring elt 0 14) "...")))
 944                 (if (< (point) (point-max))
 945                     (move-to-column (* 20 (/ n lines)) t))
 946                 (insert (+ i ?\s) ?: elt)
 947                 (if (< (point) (point-max))
 948                     (forward-line 1)
 949                   (insert "\n"))
 950                 (setq n (1+ n))
 951                 (if (= (% n lines) 0)
 952                     (goto-char pos))))))
 953         (goto-char (point-max))
 954         (insert "\n"
 955                 "character(s)\tcategory mnemonics\n"
 956                 "------------\t------------------")
 957         (describe-vector table 'help-describe-category-set)
 958         (insert "Legend of category mnemonics:\n")
 959         (dotimes (i 95)
 960           (let ((elt (aref docs i)))
 961             (when elt
 962               (if (string-match "\n" elt)
 963                   (setq elt (substring elt (match-end 0))))
 964               (insert (+ i ?\s) ": " elt "\n"))))
 965         (while (setq table (char-table-parent table))
 966           (insert "\nThe parent category table is:")
 967           (describe-vector table 'help-describe-category-set))))))
 968
 969 \f
 970 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
 971
 972 ;; Replaces lib-src/digest-doc.c.
 973 ;;;###autoload
 974 (defun doc-file-to-man (file)
 975   "Produce an nroff buffer containing the doc-strings from the DOC file."
 976   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 977                                      internal-doc-file-name t)))
 978   (or (file-readable-p file)
 979       (error "Cannot read file `%s'" file))
 980   (pop-to-buffer (generate-new-buffer "*man-doc*"))
 981   (setq buffer-undo-list t)
 982   (insert ".TH \"Command Summary for GNU Emacs\"\n"
 983           ".AU Richard M. Stallman\n")
 984   (insert-file-contents file)
 985   (let (notfirst)
 986     (while (search-forward "\1f" nil 'move)
 987       (if (looking-at "S")
 988           (delete-region (1- (point)) (line-end-position))
 989         (delete-char -1)
 990         (if notfirst
 991             (insert "\n.DE\n")
 992           (setq notfirst t))
 993         (insert "\n.SH ")
 994         (insert (if (looking-at "F") "Function " "Variable "))
 995         (delete-char 1)
 996         (forward-line 1)
 997         (insert ".DS L\n"))))
 998   (insert "\n.DE\n")
 999   (setq buffer-undo-list nil)
1000   (nroff-mode))
1001
1002 ;; Replaces lib-src/sorted-doc.c.
1003 ;;;###autoload
1004 (defun doc-file-to-info (file)
1005   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
1006   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1007                                      internal-doc-file-name t)))
1008   (or (file-readable-p file)
1009       (error "Cannot read file `%s'" file))
1010   (let ((i 0) type name doc alist)
1011     (with-temp-buffer
1012       (insert-file-contents file)
1013       ;; The characters "@{}" need special treatment.
1014       (while (re-search-forward "[@{}]" nil t)
1015         (backward-char)
1016         (insert "@")
1017         (forward-char 1))
1018       (goto-char (point-min))
1019       (while (search-forward "\1f" nil t)
1020         (unless (looking-at "S")
1021           (setq type (char-after)
1022                 name (buffer-substring (1+ (point)) (line-end-position))
1023                 doc (buffer-substring (line-beginning-position 2)
1024                                       (if (search-forward  "\1f" nil 'move)
1025                                           (1- (point))
1026                                         (point)))
1027                 alist (cons (list name type doc) alist))
1028           (backward-char 1))))
1029     (pop-to-buffer (generate-new-buffer "*info-doc*"))
1030     (setq buffer-undo-list t)
1031     ;; Write the output header.
1032     (insert "\\input texinfo  @c -*-texinfo-*-\n"
1033             "@setfilename emacsdoc.info\n"
1034             "@settitle Command Summary for GNU Emacs\n"
1035             "@finalout\n"
1036             "\n@node Top\n"
1037             "@unnumbered Command Summary for GNU Emacs\n\n"
1038             "@table @asis\n\n"
1039             "@iftex\n"
1040             "@global@let@ITEM@item\n"
1041             "@def@item{@filbreak@vskip5pt@ITEM}\n"
1042             "@font@tensy cmsy10 scaled @magstephalf\n"
1043             "@font@teni cmmi10 scaled @magstephalf\n"
1044             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
1045             "@def|{{@tensy@char106}}\n"
1046             "@def@{{{@tensy@char102}}\n"
1047             "@def@}{{@tensy@char103}}\n"
1048             "@def<{{@teni@char62}}\n"
1049             "@def>{{@teni@char60}}\n"
1050             "@chardef@@64\n"
1051             "@catcode43=12\n"
1052             "@tableindent-0.2in\n"
1053             "@end iftex\n")
1054     ;; Sort the array by name; within each name, by type (functions first).
1055     (setq alist (sort alist (lambda (e1 e2)
1056                               (if (string-equal (car e1) (car e2))
1057                                   (<= (cadr e1) (cadr e2))
1058                                 (string-lessp (car e1) (car e2))))))
1059     ;; Print each function.
1060     (dolist (e alist)
1061       (insert "\n@item "
1062               (if (char-equal (cadr e) ?\F) "Function" "Variable")
1063               " @code{" (car e) "}\n@display\n"
1064               (nth 2 e)
1065               "\n@end display\n")
1066       ;; Try to avoid a save size overflow in the TeX output routine.
1067       (if (zerop (setq i (% (1+ i) 100)))
1068           (insert "\n@end table\n@table @asis\n")))
1069     (insert "@end table\n"
1070             "@bye\n")
1071     (setq buffer-undo-list nil)
1072     (texinfo-mode)))
1073
1074 (provide 'help-fns)
1075
1076 ;;; help-fns.el ends here