lisp/lpr.el

   1 ;;; lpr.el --- print Emacs buffer on line printer.
   2
   3 ;; Copyright (C) 1985, 1988, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: unix
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 ;;;###autoload
  27 (defvar lpr-switches nil
  28   "*List of strings to pass as extra switch args to lpr when it is invoked.")
  29
  30 ;;;###autoload
  31 (defvar lpr-command
  32   (if (memq system-type '(usg-unix-v dgux-unix hpux silicon-graphics-unix))
  33       "lp" "lpr")
  34   "*Shell command for printing a file")
  35
  36 (defvar print-region-function nil
  37   "Function to call to print the region on a printer.
  38 See definition of `print-region-1' for calling conventions.")
  39
  40 ;;;###autoload
  41 (defun lpr-buffer ()
  42   "Print buffer contents as with Unix command `lpr'.
  43 `lpr-switches' is a list of extra switches (strings) to pass to lpr."
  44   (interactive)
  45   (print-region-1 (point-min) (point-max) lpr-switches nil))
  46
  47 ;;;###autoload
  48 (defun print-buffer ()
  49   "Print buffer contents as with Unix command `lpr -p'.
  50 `lpr-switches' is a list of extra switches (strings) to pass to lpr."
  51   (interactive)
  52   (print-region-1 (point-min) (point-max) lpr-switches t))
  53
  54 ;;;###autoload
  55 (defun lpr-region (start end)
  56   "Print region contents as with Unix command `lpr'.
  57 `lpr-switches' is a list of extra switches (strings) to pass to lpr."
  58   (interactive "r")
  59   (print-region-1 start end lpr-switches nil))
  60
  61 ;;;###autoload
  62 (defun print-region (start end)
  63   "Print region contents as with Unix command `lpr -p'.
  64 `lpr-switches' is a list of extra switches (strings) to pass to lpr."
  65   (interactive "r")
  66   (print-region-1 start end lpr-switches t))
  67
  68 (defun print-region-1 (start end switches page-headers)
  69   (let ((name (concat (buffer-name) " Emacs buffer"))
  70         (width tab-width))
  71     (save-excursion
  72       (message "Spooling...")
  73       (if (/= tab-width 8)
  74           (progn
  75             (print-region-new-buffer start end)
  76             (setq tab-width width)
  77             (untabify (point-min) (point-max))))
  78       (if page-headers
  79           (if (eq system-type 'usg-unix-v)
  80               (progn
  81                 (print-region-new-buffer start end)
  82                 (call-process-region start end "pr" t t nil))
  83             ;; On BSD, use an option to get page headers.
  84             (setq switches (cons "-p" switches))))
  85       (apply (or print-region-function 'call-process-region)
  86              (nconc (list start end lpr-command
  87                           nil nil nil)
  88                     (nconc (and (eq system-type 'berkeley-unix)
  89                                 (list "-J" name "-T" name))
  90                            switches)))
  91       (message "Spooling...done"))))
  92
  93 ;; This function copies the text between start and end
  94 ;; into a new buffer, makes that buffer current,
  95 ;; and sets start and end to the buffer bounds.
  96 ;; start and end are used free.
  97 (defun print-region-new-buffer (start end)
  98   (or (string= (buffer-name) " *spool temp*")
  99       (let ((oldbuf (current-buffer)))
 100         (set-buffer (get-buffer-create " *spool temp*"))
 101         (widen) (erase-buffer)
 102         (insert-buffer-substring oldbuf start end)
 103         (setq start (point-min) end (point-max)))))
 104
 105 ;;; lpr.el ends here