lisp/mh-e/mh-speed.el

   1 ;;; mh-speed.el --- Speedbar interface for MH-E.
   2
   3 ;; Copyright (C) 2002, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Satyaki Das <satyaki@theforce.stanford.edu>
   6 ;; Maintainer: Bill Wohler <wohler@newt.com>
   7 ;; Keywords: mail
   8 ;; See: mh-e.el
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;   Future versions should only use flists.
  29
  30 ;; Speedbar support for MH-E package.
  31
  32 ;;; Change Log:
  33
  34 ;;; Code:
  35
  36 ;; Requires
  37 (require 'cl)
  38 (require 'mh-e)
  39 (require 'speedbar)
  40
  41 ;; Global variables
  42 (defvar mh-speed-refresh-flag nil)
  43 (defvar mh-speed-last-selected-folder nil)
  44 (defvar mh-speed-folder-map (make-hash-table :test #'equal))
  45 (defvar mh-speed-flists-cache (make-hash-table :test #'equal))
  46 (defvar mh-speed-flists-process nil)
  47 (defvar mh-speed-flists-timer nil)
  48 (defvar mh-speed-partial-line "")
  49
  50 ;; Add our stealth update function
  51 (unless (member 'mh-speed-stealth-update
  52                 (cdr (assoc "files" speedbar-stealthy-function-list)))
  53   ;; Is changing constant lists in elisp safe?
  54   (setq speedbar-stealthy-function-list
  55         (copy-tree speedbar-stealthy-function-list))
  56   (push 'mh-speed-stealth-update
  57         (cdr (assoc "files" speedbar-stealthy-function-list))))
  58
  59 ;; Functions called by speedbar to initialize display...
  60 ;;;###mh-autoload
  61 (defun mh-folder-speedbar-buttons (buffer)
  62   "Interface function to create MH-E speedbar buffer.
  63 BUFFER is the MH-E buffer for which the speedbar buffer is to be created."
  64   (unless (get-text-property (point-min) 'mh-level)
  65     (erase-buffer)
  66     (clrhash mh-speed-folder-map)
  67     (speedbar-make-tag-line 'bracket ?+ 'mh-speed-toggle nil " " 'ignore nil
  68                             'mh-speedbar-folder-face 0)
  69     (forward-line -1)
  70     (setf (gethash nil mh-speed-folder-map)
  71           (set-marker (or (gethash nil mh-speed-folder-map) (make-marker))
  72                       (1+ (line-beginning-position))))
  73     (add-text-properties
  74      (line-beginning-position) (1+ (line-beginning-position))
  75      `(mh-folder nil mh-expanded nil mh-children-p t mh-level 0))
  76     (mh-speed-stealth-update t)
  77     (when mh-speed-run-flists-flag
  78       (mh-speed-flists nil))))
  79
  80 ;;;###mh-autoload
  81 (defalias 'mh-show-speedbar-buttons 'mh-folder-speedbar-buttons)
  82 ;;;###mh-autoload
  83 (defalias 'mh-letter-speedbar-buttons 'mh-folder-speedbar-buttons)
  84
  85 ;; Keymaps for speedbar...
  86 (defvar mh-folder-speedbar-key-map (speedbar-make-specialized-keymap)
  87   "Specialized speedbar keymap for MH-E buffers.")
  88 (gnus-define-keys mh-folder-speedbar-key-map
  89   "+"           mh-speed-expand-folder
  90   "-"           mh-speed-contract-folder
  91   "\r"          mh-speed-view
  92   "f"           mh-speed-flists
  93   "i"           mh-speed-invalidate-map)
  94
  95 (defvar mh-show-speedbar-key-map mh-folder-speedbar-key-map)
  96 (defvar mh-letter-speedbar-key-map mh-folder-speedbar-key-map)
  97
  98 ;; Menus for speedbar...
  99 (defvar mh-folder-speedbar-menu-items
 100   '(["Visit Folder" mh-speed-view
 101      (save-excursion
 102        (set-buffer speedbar-buffer)
 103        (get-text-property (line-beginning-position) 'mh-folder))]
 104     ["Expand nested folders" mh-speed-expand-folder
 105      (and (get-text-property (line-beginning-position) 'mh-children-p)
 106           (not (get-text-property (line-beginning-position) 'mh-expanded)))]
 107     ["Contract nested folders" mh-speed-contract-folder
 108      (and (get-text-property (line-beginning-position) 'mh-children-p)
 109           (get-text-property (line-beginning-position) 'mh-expanded))]
 110     ["Run Flists" mh-speed-flists t]
 111     ["Invalidate cached folders" mh-speed-invalidate-map t])
 112   "Extra menu items for speedbar.")
 113
 114 (defvar mh-show-speedbar-menu-items mh-folder-speedbar-menu-items)
 115 (defvar mh-letter-speedbar-menu-items mh-folder-speedbar-menu-items)
 116
 117 (defmacro mh-speed-select-attached-frame ()
 118   "Compatibility macro to handle speedbar versions 0.11a and 0.14beta4."
 119   (cond ((fboundp 'dframe-select-attached-frame)
 120          '(dframe-select-attached-frame speedbar-frame))
 121         ((boundp 'speedbar-attached-frame)
 122          '(select-frame speedbar-attached-frame))
 123         (t (error "Installed speedbar version not supported by MH-E"))))
 124
 125 (defun mh-speed-update-current-folder (force)
 126   "Update speedbar highlighting of the current folder.
 127 The function tries to be smart so that work done is minimized. The currently
 128 highlighted folder is cached and no highlighting happens unless it changes.
 129 Also highlighting is suspended while the speedbar frame is selected.
 130 Otherwise you get the disconcerting behavior of folders popping open on their
 131 own when you are trying to navigate around in the speedbar buffer.
 132
 133 The update is always carried out if FORCE is non-nil."
 134   (let* ((lastf (selected-frame))
 135          (newcf (save-excursion
 136                   (mh-speed-select-attached-frame)
 137                   (prog1 (mh-speed-extract-folder-name (buffer-name))
 138                     (select-frame lastf))))
 139          (lastb (current-buffer))
 140          (case-fold-search t))
 141     (when (or force
 142               (and mh-speed-refresh-flag (not (eq lastf speedbar-frame)))
 143               (and (stringp newcf)
 144                    (equal (substring newcf 0 1) "+")
 145                    (not (equal newcf mh-speed-last-selected-folder))))
 146       (setq mh-speed-refresh-flag nil)
 147       (select-frame speedbar-frame)
 148       (set-buffer speedbar-buffer)
 149
 150       ;; Remove highlight from previous match...
 151       (mh-speed-highlight mh-speed-last-selected-folder
 152                           'mh-speedbar-folder-face)
 153
 154       ;; If we found a match highlight it...
 155       (when (mh-speed-goto-folder newcf)
 156         (mh-speed-highlight newcf 'mh-speedbar-selected-folder-face))
 157
 158       (setq mh-speed-last-selected-folder newcf)
 159       (speedbar-position-cursor-on-line)
 160       (set-window-point (frame-first-window speedbar-frame) (point))
 161       (set-buffer lastb)
 162       (select-frame lastf))
 163     (when (eq lastf speedbar-frame)
 164       (setq mh-speed-refresh-flag t))))
 165
 166 (defun mh-speed-normal-face (face)
 167   "Return normal face for given FACE."
 168   (cond ((eq face 'mh-speedbar-folder-with-unseen-messages-face)
 169          'mh-speedbar-folder-face)
 170         ((eq face 'mh-speedbar-selected-folder-with-unseen-messages-face)
 171          'mh-speedbar-selected-folder-face)
 172         (t face)))
 173
 174 (defun mh-speed-bold-face (face)
 175   "Return bold face for given FACE."
 176   (cond ((eq face 'mh-speedbar-folder-face)
 177          'mh-speedbar-folder-with-unseen-messages-face)
 178         ((eq face 'mh-speedbar-selected-folder-face)
 179          'mh-speedbar-selected-folder-with-unseen-messages-face)
 180         (t face)))
 181
 182 (defun mh-speed-highlight (folder face)
 183   "Set FOLDER to FACE."
 184   (save-excursion
 185     (speedbar-with-writable
 186       (goto-char (gethash folder mh-speed-folder-map (point)))
 187       (beginning-of-line)
 188       (if (re-search-forward "([1-9][0-9]*/[0-9]+)" (line-end-position) t)
 189           (setq face (mh-speed-bold-face face))
 190         (setq face (mh-speed-normal-face face)))
 191       (beginning-of-line)
 192       (when (re-search-forward "\\[.\\] " (line-end-position) t)
 193         (put-text-property (point) (line-end-position) 'face face)))))
 194
 195 (defun mh-speed-stealth-update (&optional force)
 196   "Do stealth update.
 197 With non-nil FORCE, the update is always carried out."
 198   (cond ((save-excursion (set-buffer speedbar-buffer)
 199                          (get-text-property (point-min) 'mh-level))
 200          ;; Execute this hook and *don't* run anything else
 201          (mh-speed-update-current-folder force)
 202          nil)
 203         ;; Otherwise on to your regular programming
 204         (t t)))
 205
 206 (defun mh-speed-goto-folder (folder)
 207   "Move point to line containing FOLDER.
 208 The function will expand out parent folders of FOLDER if needed."
 209   (let ((prefix folder)
 210         (suffix-list ())
 211         (last-slash t))
 212     (while (and (not (gethash prefix mh-speed-folder-map)) last-slash)
 213       (setq last-slash (mh-search-from-end ?/ prefix))
 214       (when (integerp last-slash)
 215         (push (substring prefix (1+ last-slash)) suffix-list)
 216         (setq prefix (substring prefix 0 last-slash))))
 217     (let ((prefix-position (gethash prefix mh-speed-folder-map)))
 218       (if prefix-position
 219           (goto-char prefix-position)
 220         (goto-char (point-min))
 221         (mh-speed-toggle)
 222         (unless (get-text-property (point) 'mh-expanded)
 223           (mh-speed-toggle))
 224         (goto-char (gethash prefix mh-speed-folder-map))))
 225     (while suffix-list
 226       ;; We always need atleast one toggle. We need two if the directory list
 227       ;; is stale since a folder was added.
 228       (when (equal prefix (get-text-property (line-beginning-position)
 229                                              'mh-folder))
 230         (mh-speed-toggle)
 231         (unless (get-text-property (point) 'mh-expanded)
 232           (mh-speed-toggle)))
 233       (setq prefix (format "%s/%s" prefix (pop suffix-list)))
 234       (goto-char (gethash prefix mh-speed-folder-map (point))))
 235     (beginning-of-line)
 236     (equal folder (get-text-property (point) 'mh-folder))))
 237
 238 (defun mh-speed-extract-folder-name (buffer)
 239   "Given an MH-E BUFFER find the folder that should be highlighted.
 240 Do the right thing for the different kinds of buffers that MH-E uses."
 241   (save-excursion
 242     (set-buffer buffer)
 243     (cond ((eq major-mode 'mh-folder-mode)
 244            mh-current-folder)
 245           ((eq major-mode 'mh-show-mode)
 246            (set-buffer mh-show-folder-buffer)
 247            mh-current-folder)
 248           ((eq major-mode 'mh-letter-mode)
 249            (when (string-match mh-user-path buffer-file-name)
 250              (let* ((rel-path (substring buffer-file-name (match-end 0)))
 251                     (directory-end (mh-search-from-end ?/ rel-path)))
 252                (when directory-end
 253                  (format "+%s" (substring rel-path 0 directory-end)))))))))
 254
 255 (defun mh-speed-add-buttons (folder level)
 256   "Add speedbar button for FOLDER which is at indented by LEVEL amount."
 257   (let ((folder-list (mh-sub-folders folder)))
 258     (mapc
 259      (lambda (f)
 260        (let* ((folder-name (format "%s%s%s" (or folder "+")
 261                                    (if folder "/" "") (car f)))
 262               (counts (gethash folder-name mh-speed-flists-cache)))
 263          (speedbar-with-writable
 264            (speedbar-make-tag-line
 265             'bracket (if (cdr f) ?+ ? )
 266             'mh-speed-toggle nil
 267             (format "%s%s"
 268                     (car f)
 269                     (if counts
 270                         (format " (%s/%s)" (car counts) (cdr counts))
 271                       ""))
 272             'mh-speed-view nil
 273             (if (and counts (> (car counts) 0))
 274                 'mh-speedbar-folder-with-unseen-messages-face
 275               'mh-speedbar-folder-face)
 276             level)
 277            (save-excursion
 278              (forward-line -1)
 279              (setf (gethash folder-name mh-speed-folder-map)
 280                    (set-marker (or (gethash folder-name mh-speed-folder-map)
 281                                    (make-marker))
 282                                (1+ (line-beginning-position))))
 283              (add-text-properties
 284               (line-beginning-position) (1+ (line-beginning-position))
 285               `(mh-folder ,folder-name
 286                           mh-expanded nil
 287                           mh-children-p ,(not (not (cdr f)))
 288                           ,@(if counts `(mh-count
 289                                          (,(car counts) . ,(cdr counts))) ())
 290                           mh-level ,level))))))
 291      folder-list)))
 292
 293 ;;;###mh-autoload
 294 (defun mh-speed-toggle (&rest args)
 295   "Toggle the display of child folders.
 296 The otional ARGS are ignored and there for compatibilty with speedbar."
 297   (interactive)
 298   (declare (ignore args))
 299   (beginning-of-line)
 300   (let ((parent (get-text-property (point) 'mh-folder))
 301         (kids-p (get-text-property (point) 'mh-children-p))
 302         (expanded (get-text-property (point) 'mh-expanded))
 303         (level (get-text-property (point) 'mh-level))
 304         (point (point))
 305         start-region)
 306     (speedbar-with-writable
 307       (cond ((not kids-p) nil)
 308             (expanded
 309              (forward-line)
 310              (setq start-region (point))
 311              (while (and (get-text-property (point) 'mh-level)
 312                          (> (get-text-property (point) 'mh-level) level))
 313                (let ((folder (get-text-property (point) 'mh-folder)))
 314                  (when (gethash folder mh-speed-folder-map)
 315                    (set-marker (gethash folder mh-speed-folder-map) nil)
 316                    (remhash folder mh-speed-folder-map)))
 317                (forward-line))
 318              (delete-region start-region (point))
 319              (forward-line -1)
 320              (speedbar-change-expand-button-char ?+)
 321              (add-text-properties
 322               (line-beginning-position) (1+ (line-beginning-position))
 323               '(mh-expanded nil)))
 324             (t
 325              (forward-line)
 326              (mh-speed-add-buttons parent (1+ level))
 327              (goto-char point)
 328              (speedbar-change-expand-button-char ?-)
 329              (add-text-properties
 330               (line-beginning-position) (1+ (line-beginning-position))
 331               `(mh-expanded t)))))))
 332
 333 (defalias 'mh-speed-expand-folder 'mh-speed-toggle)
 334 (defalias 'mh-speed-contract-folder 'mh-speed-toggle)
 335
 336 ;;;###mh-autoload
 337 (defun mh-speed-view (&rest args)
 338   "View folder on current line.
 339 Optional ARGS are ignored."
 340   (interactive)
 341   (declare (ignore args))
 342   (let* ((folder (get-text-property (line-beginning-position) 'mh-folder))
 343          (range (and (stringp folder) (mh-read-msg-range folder))))
 344     (when (stringp folder)
 345       (speedbar-with-attached-buffer
 346        (mh-visit-folder folder range)
 347        (delete-other-windows)))))
 348
 349 (defvar mh-speed-current-folder nil)
 350 (defvar mh-speed-flists-folder nil)
 351
 352 ;;;###mh-autoload
 353 (defun mh-speed-flists (force &optional folder)
 354   "Execute flists -recurse and update message counts.
 355 If FORCE is non-nil the timer is reset. If FOLDER is non-nil then flists is run
 356 only for that one folder."
 357   (interactive (list t))
 358   (when force
 359     (when mh-speed-flists-timer
 360       (cancel-timer mh-speed-flists-timer)
 361       (setq mh-speed-flists-timer nil))
 362     (when (and (processp mh-speed-flists-process)
 363                (not (eq (process-status mh-speed-flists-process) 'exit)))
 364       (set-process-filter mh-speed-flists-process t)
 365       (kill-process mh-speed-flists-process)
 366       (setq mh-speed-partial-line "")
 367       (setq mh-speed-flists-process nil)))
 368   (setq mh-speed-flists-folder folder)
 369   (unless mh-speed-flists-timer
 370     (setq mh-speed-flists-timer
 371           (run-at-time
 372            nil (and mh-speed-run-flists-flag mh-speed-flists-interval)
 373            (lambda ()
 374              (unless (and (processp mh-speed-flists-process)
 375                           (not (eq (process-status mh-speed-flists-process)
 376                                    'exit)))
 377                (setq mh-speed-current-folder
 378                      (concat
 379                       (with-temp-buffer
 380                         (call-process (expand-file-name "folder" mh-progs)
 381                                       nil '(t nil) nil "-fast")
 382                         (buffer-substring (point-min) (1- (point-max))))
 383                       "+"))
 384                (setq mh-speed-flists-process
 385                      (start-process "*flists*" nil
 386                                     (expand-file-name "flists" mh-progs)
 387                                     (or mh-speed-flists-folder "-recurse")
 388                                     (if mh-speed-flists-folder "-noall" "-all")
 389                                     "-sequence" (symbol-name mh-unseen-seq)))
 390                ;; Run flists on all folders the next time around...
 391                (setq mh-speed-flists-folder nil)
 392                (set-process-filter mh-speed-flists-process
 393                                    'mh-speed-parse-flists-output)))))))
 394
 395 ;; Copied from mh-make-folder-list-filter...
 396 (defun mh-speed-parse-flists-output (process output)
 397   "Parse the incremental results from flists.
 398 PROCESS is the flists process and OUTPUT is the results that must be handled
 399 next."
 400   (let ((prevailing-match-data (match-data))
 401         (position 0)
 402         line-end line folder unseen total)
 403     (unwind-protect
 404         (while (setq line-end (string-match "\n" output position))
 405           (setq line (format "%s%s"
 406                              mh-speed-partial-line
 407                              (substring output position line-end))
 408                 mh-speed-partial-line "")
 409           (multiple-value-setq (folder unseen total)
 410             (mh-parse-flist-output-line line mh-speed-current-folder))
 411           (when (and folder unseen total
 412                      (let ((old-pair (gethash folder mh-speed-flists-cache)))
 413                        (or (not (equal (car old-pair) unseen))
 414                            (not (equal (cdr old-pair) total)))))
 415             (setf (gethash folder mh-speed-flists-cache) (cons unseen total))
 416             (save-excursion
 417               (when (buffer-live-p (get-buffer speedbar-buffer))
 418                 (set-buffer speedbar-buffer)
 419                 (speedbar-with-writable
 420                   (when (get-text-property (point-min) 'mh-level)
 421                     (let ((pos (gethash folder mh-speed-folder-map))
 422                           face)
 423                       (when pos
 424                         (goto-char pos)
 425                         (goto-char (line-beginning-position))
 426                         (cond
 427                          ((null (get-text-property (point) 'mh-count))
 428                           (goto-char (line-end-position))
 429                           (setq face (get-text-property (1- (point)) 'face))
 430                           (insert (format " (%s/%s)" unseen total))
 431                           (mh-speed-highlight 'unknown face)
 432                           (goto-char (line-beginning-position))
 433                           (add-text-properties (point) (1+ (point))
 434                                                `(mh-count (,unseen . ,total))))
 435                          ((not (equal (get-text-property (point) 'mh-count)
 436                                       (cons unseen total)))
 437                           (goto-char (line-end-position))
 438                           (setq face (get-text-property (1- (point)) 'face))
 439                           (re-search-backward " " (line-beginning-position) t)
 440                           (delete-region (point) (line-end-position))
 441                           (insert (format " (%s/%s)" unseen total))
 442                           (mh-speed-highlight 'unknown face)
 443                           (goto-char (line-beginning-position))
 444                           (add-text-properties
 445                            (point) (1+ (point))
 446                            `(mh-count (,unseen . ,total))))))))))))
 447           (setq position (1+ line-end)))
 448       (set-match-data prevailing-match-data))
 449     (setq mh-speed-partial-line (substring output position))))
 450
 451 ;;;###mh-autoload
 452 (defun mh-speed-invalidate-map (folder)
 453   "Remove FOLDER from various optimization caches."
 454   (interactive (list ""))
 455   (save-excursion
 456     (set-buffer speedbar-buffer)
 457     (let* ((speedbar-update-flag nil)
 458            (last-slash (mh-search-from-end ?/ folder))
 459            (parent (if last-slash (substring folder 0 last-slash) nil))
 460            (parent-position (gethash parent mh-speed-folder-map))
 461            (parent-change nil))
 462       (when parent-position
 463         (let ((parent-kids (mh-sub-folders parent)))
 464           (cond ((null parent-kids)
 465                  (setq parent-change ?+))
 466                 ((and (null (cdr parent-kids))
 467                       (equal (if last-slash
 468                                  (substring folder (1+ last-slash))
 469                                (substring folder 1))
 470                              (caar parent-kids)))
 471                  (setq parent-change ? ))))
 472         (goto-char parent-position)
 473         (when (equal (get-text-property (line-beginning-position) 'mh-folder)
 474                      parent)
 475           (when (get-text-property (line-beginning-position) 'mh-expanded)
 476             (mh-speed-toggle))
 477           (when parent-change
 478             (speedbar-with-writable
 479               (mh-speedbar-change-expand-button-char parent-change)
 480               (add-text-properties
 481                (line-beginning-position) (1+ (line-beginning-position))
 482                `(mh-children-p ,(equal parent-change ?+)))))
 483           (mh-speed-highlight mh-speed-last-selected-folder
 484                               'mh-speedbar-folder-face)
 485           (setq mh-speed-last-selected-folder nil)
 486           (setq mh-speed-refresh-flag t)))
 487       (when (equal folder "")
 488         (clrhash mh-sub-folders-cache)))))
 489
 490 ;;;###mh-autoload
 491 (defun mh-speed-add-folder (folder)
 492   "Add FOLDER since it is being created.
 493 The function invalidates the latest ancestor that is present."
 494   (save-excursion
 495     (set-buffer speedbar-buffer)
 496     (let ((speedbar-update-flag nil)
 497           (last-slash (mh-search-from-end ?/ folder))
 498           (ancestor folder)
 499           (ancestor-pos nil))
 500       (block while-loop
 501         (while last-slash
 502           (setq ancestor (substring ancestor 0 last-slash))
 503           (setq ancestor-pos (gethash ancestor mh-speed-folder-map))
 504           (when ancestor-pos
 505             (return-from while-loop))
 506           (setq last-slash (mh-search-from-end ?/ ancestor))))
 507       (unless ancestor-pos (setq ancestor nil))
 508       (goto-char (or ancestor-pos (gethash nil mh-speed-folder-map)))
 509       (speedbar-with-writable
 510         (mh-speedbar-change-expand-button-char ?+)
 511         (add-text-properties
 512          (line-beginning-position) (1+ (line-beginning-position))
 513          `(mh-children-p t)))
 514       (when (get-text-property (line-beginning-position) 'mh-expanded)
 515         (mh-speed-toggle))
 516       (setq mh-speed-refresh-flag t))))
 517
 518 ;; Make it slightly more general to allow for [ ] buttons to be changed to
 519 ;; [+].
 520 (defun mh-speedbar-change-expand-button-char (char)
 521   "Change the expansion button character to CHAR for the current line."
 522   (save-excursion
 523     (beginning-of-line)
 524     (if (re-search-forward "\\[.\\]" (line-end-position) t)
 525         (speedbar-with-writable
 526           (backward-char 2)
 527           (delete-char 1)
 528           (insert-char char 1 t)
 529           (put-text-property (point) (1- (point)) 'invisible nil)
 530           ;; make sure we fix the image on the text here.
 531           (mh-funcall-if-exists
 532            speedbar-insert-image-button-maybe (- (point) 2) 3)))))
 533
 534 (provide 'mh-speed)
 535
 536 ;;; Local Variables:
 537 ;;; indent-tabs-mode: nil
 538 ;;; sentence-end-double-space: nil
 539 ;;; End:
 540
 541 ;;; arch-tag: d38ddcd4-3c00-4e37-99bf-8b89dda7b32c
 542 ;;; mh-speed.el ends here