lisp/emacs-lisp/lisp.el

   1 ;;; lisp.el --- Lisp editing commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 2000 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Lisp editing commands to go with Lisp major mode.  More-or-less
  28 ;; applicable in other modes too.
  29
  30 ;;; Code:
  31
  32 ;; Note that this variable is used by non-lisp modes too.
  33 (defcustom defun-prompt-regexp nil
  34   "*If non-nil, a regexp to ignore before the character that starts a defun.
  35 This is only necessary if the opening paren or brace is not in column 0.
  36 See function `beginning-of-defun'.
  37
  38 Setting this variable automatically makes it local to the current buffer."
  39   :type '(choice (const nil)
  40                  regexp)
  41   :group 'lisp)
  42 (make-variable-buffer-local 'defun-prompt-regexp)
  43
  44 (defcustom parens-require-spaces t
  45   "Non-nil means `insert-parentheses' should insert whitespace as needed."
  46   :type 'boolean
  47   :group 'lisp)
  48
  49 (defvar forward-sexp-function nil
  50   "If non-nil, `forward-sexp' delegates to this function.
  51 Should take the same arguments and behave similarly to `forward-sexp'.")
  52
  53 (defun forward-sexp (&optional arg)
  54   "Move forward across one balanced expression (sexp).
  55 With ARG, do it that many times.  Negative arg -N means
  56 move backward across N balanced expressions."
  57   (interactive "p")
  58   (or arg (setq arg 1))
  59   (if forward-sexp-function
  60       (funcall forward-sexp-function arg)
  61     (goto-char (or (scan-sexps (point) arg) (buffer-end arg)))
  62     (if (< arg 0) (backward-prefix-chars))))
  63
  64 (defun backward-sexp (&optional arg)
  65   "Move backward across one balanced expression (sexp).
  66 With ARG, do it that many times.  Negative arg -N means
  67 move forward across N balanced expressions."
  68   (interactive "p")
  69   (or arg (setq arg 1))
  70   (forward-sexp (- arg)))
  71
  72 (defun mark-sexp (&optional arg)
  73   "Set mark ARG sexps from point.
  74 The place mark goes is the same place \\[forward-sexp] would
  75 move to with the same argument.
  76 If this command is repeated, it marks the next ARG sexps after the ones
  77 already marked."
  78   (interactive "p")
  79   (cond ((and (eq last-command this-command) (mark t))
  80          (set-mark
  81           (save-excursion
  82            (goto-char (mark))
  83            (forward-sexp (or arg 1))
  84            (point))))
  85         (t
  86          (push-mark
  87           (save-excursion
  88             (forward-sexp (or arg 1))
  89             (point))
  90           nil t))))
  91
  92 (defun forward-list (&optional arg)
  93   "Move forward across one balanced group of parentheses.
  94 With ARG, do it that many times.
  95 Negative arg -N means move backward across N groups of parentheses."
  96   (interactive "p")
  97   (or arg (setq arg 1))
  98   (goto-char (or (scan-lists (point) arg 0) (buffer-end arg))))
  99
 100 (defun backward-list (&optional arg)
 101   "Move backward across one balanced group of parentheses.
 102 With ARG, do it that many times.
 103 Negative arg -N means move forward across N groups of parentheses."
 104   (interactive "p")
 105   (or arg (setq arg 1))
 106   (forward-list (- arg)))
 107
 108 (defun down-list (&optional arg)
 109   "Move forward down one level of parentheses.
 110 With ARG, do this that many times.
 111 A negative argument means move backward but still go down a level."
 112   (interactive "p")
 113   (or arg (setq arg 1))
 114   (let ((inc (if (> arg 0) 1 -1)))
 115     (while (/= arg 0)
 116       (goto-char (or (scan-lists (point) inc -1) (buffer-end arg)))
 117       (setq arg (- arg inc)))))
 118
 119 (defun backward-up-list (&optional arg)
 120   "Move backward out of one level of parentheses.
 121 With ARG, do this that many times.
 122 A negative argument means move forward but still to a less deep spot."
 123   (interactive "p")
 124   (up-list (- (or arg 1))))
 125
 126 (defun up-list (&optional arg)
 127   "Move forward out of one level of parentheses.
 128 With ARG, do this that many times.
 129 A negative argument means move backward but still to a less deep spot."
 130   (interactive "p")
 131   (or arg (setq arg 1))
 132   (let ((inc (if (> arg 0) 1 -1)))
 133     (while (/= arg 0)
 134       (goto-char (or (scan-lists (point) inc 1) (buffer-end arg)))
 135       (setq arg (- arg inc)))))
 136
 137 (defun kill-sexp (&optional arg)
 138   "Kill the sexp (balanced expression) following the cursor.
 139 With ARG, kill that many sexps after the cursor.
 140 Negative arg -N means kill N sexps before the cursor."
 141   (interactive "p")
 142   (let ((opoint (point)))
 143     (forward-sexp (or arg 1))
 144     (kill-region opoint (point))))
 145
 146 (defun backward-kill-sexp (&optional arg)
 147   "Kill the sexp (balanced expression) preceding the cursor.
 148 With ARG, kill that many sexps before the cursor.
 149 Negative arg -N means kill N sexps after the cursor."
 150   (interactive "p")
 151   (kill-sexp (- (or arg 1))))
 152 \f
 153 (defvar beginning-of-defun-function nil
 154   "If non-nil, function for `beginning-of-defun-raw' to call.
 155 This is used to find the beginning of the defun instead of using the
 156 normal recipe (see `beginning-of-defun').  Major modes can define this
 157 if defining `defun-prompt-regexp' is not sufficient to handle the mode's
 158 needs.
 159
 160 The function (of no args) should go to the line on which the current
 161 defun starts, and return non-nil, or should return nil if it can't
 162 find the beginning.")
 163
 164 (defun beginning-of-defun (&optional arg)
 165   "Move backward to the beginning of a defun.
 166 With ARG, do it that many times.  Negative arg -N
 167 means move forward to Nth following beginning of defun.
 168 Returns t unless search stops due to beginning or end of buffer.
 169
 170 Normally a defun starts when there is a char with open-parenthesis
 171 syntax at the beginning of a line.  If `defun-prompt-regexp' is
 172 non-nil, then a string which matches that regexp may precede the
 173 open-parenthesis, and point ends up at the beginning of the line.
 174
 175 If variable `beginning-of-defun-function' is non-nil, its value
 176 is called as a function to find the defun's beginning."
 177   (interactive "p")
 178   (and (beginning-of-defun-raw arg)
 179        (progn (beginning-of-line) t)))
 180
 181 (defun beginning-of-defun-raw (&optional arg)
 182   "Move point to the character that starts a defun.
 183 This is identical to function `beginning-of-defun', except that point
 184 does not move to the beginning of the line when `defun-prompt-regexp'
 185 is non-nil.
 186
 187 If variable `beginning-of-defun-function' is non-nil, its value
 188 is called as a function to find the defun's beginning."
 189   (interactive "p")
 190   (if beginning-of-defun-function
 191       (funcall beginning-of-defun-function)
 192     (and arg (< arg 0) (not (eobp)) (forward-char 1))
 193     (and (re-search-backward (if defun-prompt-regexp
 194                                  (concat (if open-paren-in-column-0-is-defun-start
 195                                              "^\\s(\\|" "")
 196                                          "\\(?:" defun-prompt-regexp "\\)\\s(")
 197                                "^\\s(")
 198                              nil 'move (or arg 1))
 199          (progn (goto-char (1- (match-end 0)))) t)))
 200
 201 (defvar end-of-defun-function nil
 202   "If non-nil, function for function `end-of-defun' to call.
 203 This is used to find the end of the defun instead of using the normal
 204 recipe (see `end-of-defun').  Major modes can define this if the
 205 normal method is not appropriate.")
 206
 207 (defun buffer-end (arg)
 208   (if (> arg 0) (point-max) (point-min)))
 209
 210 (defun end-of-defun (&optional arg)
 211   "Move forward to next end of defun.  With argument, do it that many times.
 212 Negative argument -N means move back to Nth preceding end of defun.
 213
 214 An end of a defun occurs right after the close-parenthesis that
 215 matches the open-parenthesis that starts a defun; see function
 216 `beginning-of-defun'.
 217
 218 If variable `end-of-defun-function' is non-nil, its value
 219 is called as a function to find the defun's end."
 220   (interactive "p")
 221   (if end-of-defun-function
 222       (funcall end-of-defun-function)
 223     (if (or (null arg) (= arg 0)) (setq arg 1))
 224     (let ((first t))
 225       (while (and (> arg 0) (< (point) (point-max)))
 226         (let ((pos (point)) npos)
 227           (while (progn
 228                    (if (and first
 229                             (progn
 230                               (end-of-line 1)
 231                               (beginning-of-defun-raw 1)))
 232                        nil
 233                      (or (bobp) (forward-char -1))
 234                      (beginning-of-defun-raw -1))
 235                    (setq first nil)
 236                    (forward-list 1)
 237                    (skip-chars-forward " \t")
 238                    (if (looking-at "\\s<\\|\n")
 239                        (forward-line 1))
 240                    (<= (point) pos))))
 241         (setq arg (1- arg)))
 242       (while (< arg 0)
 243         (let ((pos (point)))
 244           (beginning-of-defun-raw 1)
 245           (forward-sexp 1)
 246           (forward-line 1)
 247           (if (>= (point) pos)
 248               (if (beginning-of-defun-raw 2)
 249                   (progn
 250                     (forward-list 1)
 251                     (skip-chars-forward " \t")
 252                     (if (looking-at "\\s<\\|\n")
 253                         (forward-line 1)))
 254                 (goto-char (point-min)))))
 255         (setq arg (1+ arg))))))
 256
 257 (defun mark-defun ()
 258   "Put mark at end of this defun, point at beginning.
 259 The defun marked is the one that contains point or follows point.
 260 If this command is repeated, marks more defuns after the ones
 261 already marked."
 262   (interactive)
 263   (cond ((and (eq last-command this-command) (mark t))
 264          (set-mark
 265           (save-excursion
 266             (goto-char (mark))
 267             (end-of-defun)
 268             (point))))
 269         (t
 270          (push-mark (point))
 271          (end-of-defun)
 272          (push-mark (point) nil t)
 273          (beginning-of-defun)
 274          (re-search-backward "^\n" (- (point) 1) t))))
 275
 276 (defun narrow-to-defun (&optional arg)
 277   "Make text outside current defun invisible.
 278 The defun visible is the one that contains point or follows point.
 279 Optional ARG is ignored."
 280   (interactive)
 281   (save-excursion
 282     (widen)
 283     (end-of-defun)
 284     (let ((end (point)))
 285       (beginning-of-defun)
 286       (narrow-to-region (point) end))))
 287
 288 (defun insert-parentheses (arg)
 289   "Enclose following ARG sexps in parentheses.  Leave point after open-paren.
 290 A negative ARG encloses the preceding ARG sexps instead.
 291 No argument is equivalent to zero: just insert `()' and leave point between.
 292 If `parens-require-spaces' is non-nil, this command also inserts a space
 293 before and after, depending on the surrounding characters."
 294   (interactive "P")
 295   (if arg (setq arg (prefix-numeric-value arg))
 296     (setq arg 0))
 297   (cond ((> arg 0) (skip-chars-forward " \t"))
 298         ((< arg 0) (forward-sexp arg) (setq arg (- arg))))
 299   (and parens-require-spaces
 300        (not (bobp))
 301        (memq (char-syntax (preceding-char)) '(?w ?_ ?\) ))
 302        (insert " "))
 303   (insert ?\()
 304   (save-excursion
 305     (or (eq arg 0) (forward-sexp arg))
 306     (insert ?\))
 307     (and parens-require-spaces
 308          (not (eobp))
 309          (memq (char-syntax (following-char)) '(?w ?_ ?\( ))
 310          (insert " "))))
 311
 312 (defun move-past-close-and-reindent ()
 313   "Move past next `)', delete indentation before it, then indent after it."
 314   (interactive)
 315   (up-list 1)
 316   (forward-char -1)
 317   (while (save-excursion                ; this is my contribution
 318            (let ((before-paren (point)))
 319              (back-to-indentation)
 320              (and (= (point) before-paren)
 321                   (progn
 322                     ;; Move to end of previous line.
 323                     (beginning-of-line)
 324                     (forward-char -1)
 325                     ;; Verify it doesn't end within a string or comment.
 326                     (let ((end (point))
 327                           state)
 328                       (beginning-of-line)
 329                       ;; Get state at start of line.
 330                       (setq state  (list 0 nil nil
 331                                          (null (calculate-lisp-indent))
 332                                          nil nil nil nil
 333                                          nil))
 334                       ;; Parse state across the line to get state at end.
 335                       (setq state (parse-partial-sexp (point) end nil nil
 336                                                       state))
 337                       ;; Check not in string or comment.
 338                       (and (not (elt state 3)) (not (elt state 4))))))))
 339     (delete-indentation))
 340   (forward-char 1)
 341   (newline-and-indent))
 342
 343 (defun check-parens ()                  ; lame name?
 344   "Check for unbalanced parentheses in the current buffer.
 345 More accurately, check the narrowed part of the buffer for unbalanced
 346 expressions (\"sexps\") in general.  This is done according to the
 347 current syntax table and will find unbalanced brackets or quotes as
 348 appropriate.  (See Info node `(emacs)Lists and Sexps'.)  If imbalance
 349 is found, an error is signalled and point is left at the first
 350 unbalanced character."
 351   (interactive)
 352   (condition-case data
 353       ;; Buffer can't have more than (point-max) sexps.
 354       (scan-sexps (point-min) (point-max))
 355     (scan-error (goto-char (nth 2 data))
 356                 ;; Could print (nth 1 data), which is either
 357                 ;; "Containing expression ends prematurely" or
 358                 ;; "Unbalanced parentheses", but those may not be so
 359                 ;; accurate/helpful, e.g. quotes may actually be
 360                 ;; mismatched.
 361                 (error "Unmatched bracket or quote"))
 362     (error (cond ((eq 'scan-error (car data))
 363                   (goto-char (nth 2 data))
 364                   (error "Unmatched bracket or quote"))
 365                  (t (signal (car data) (cdr data)))))))
 366 \f
 367 (defun lisp-complete-symbol (&optional predicate)
 368   "Perform completion on Lisp symbol preceding point.
 369 Compare that symbol against the known Lisp symbols.
 370 If no characters can be completed, display a list of possible completions.
 371 Repeating the command at that point scrolls the list.
 372
 373 When called from a program, optional arg PREDICATE is a predicate
 374 determining which symbols are considered, e.g. `commandp'.
 375 If PREDICATE is nil, the context determines which symbols are
 376 considered.  If the symbol starts just after an open-parenthesis, only
 377 symbols with function definitions are considered.  Otherwise, all
 378 symbols with function definitions, values or properties are
 379 considered."
 380   (interactive)
 381
 382   (let ((window (get-buffer-window "*Completions*")))
 383     (if (and (eq last-command this-command)
 384              window (window-live-p window) (window-buffer window)
 385              (buffer-name (window-buffer window)))
 386         ;; If this command was repeated, and
 387         ;; there's a fresh completion window with a live buffer,
 388         ;; and this command is repeated, scroll that window.
 389         (with-current-buffer (window-buffer window)
 390           (if (pos-visible-in-window-p (point-max) window)
 391               (set-window-start window (point-min))
 392             (save-selected-window
 393               (select-window window)
 394               (scroll-up))))
 395
 396       ;; Do completion.
 397       (let* ((end (point))
 398              (beg (with-syntax-table emacs-lisp-mode-syntax-table
 399                     (save-excursion
 400                       (backward-sexp 1)
 401                       (while (= (char-syntax (following-char)) ?\')
 402                         (forward-char 1))
 403                       (point))))
 404              (pattern (buffer-substring-no-properties beg end))
 405              (predicate
 406               (or predicate
 407                   (save-excursion
 408                     (goto-char beg)
 409                     (if (not (eq (char-before) ?\())
 410                         (lambda (sym)   ;why not just nil ?   -sm
 411                           (or (boundp sym) (fboundp sym)
 412                               (symbol-plist sym)))
 413                       ;; Looks like a funcall position.  Let's double check.
 414                       (if (condition-case nil
 415                               (progn (up-list -2) (forward-char 1)
 416                                      (eq (char-after) ?\())
 417                             (error nil))
 418                           ;; If the first element of the parent list is an open
 419                           ;; parenthesis we are probably not in a funcall position.
 420                           ;; Maybe a `let' varlist or something.
 421                           nil
 422                         ;; Else, we assume that a function name is expected.
 423                         'fboundp)))))
 424              (completion (try-completion pattern obarray predicate)))
 425         (cond ((eq completion t))
 426               ((null completion)
 427                (message "Can't find completion for \"%s\"" pattern)
 428                (ding))
 429               ((not (string= pattern completion))
 430                (delete-region beg end)
 431                (insert completion))
 432               (t
 433                (message "Making completion list...")
 434                (let ((list (all-completions pattern obarray predicate)))
 435                  (setq list (sort list 'string<))
 436                  (or (eq predicate 'fboundp)
 437                      (let (new)
 438                        (while list
 439                          (setq new (cons (if (fboundp (intern (car list)))
 440                                              (list (car list) " <f>")
 441                                            (car list))
 442                                          new))
 443                          (setq list (cdr list)))
 444                        (setq list (nreverse new))))
 445                  (with-output-to-temp-buffer "*Completions*"
 446                    (display-completion-list list)))
 447                (message "Making completion list...%s" "done")))))))
 448
 449 ;;; arch-tag: aa7fa8a4-2e6f-4e9b-9cd9-fef06340e67e
 450 ;;; lisp.el ends here