lisp/custom.el

   1 ;;; custom.el --- tools for declaring and initializing options
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; This file only contains the code needed to declare and initialize
  30 ;; user options.  The code to customize options is autoloaded from
  31 ;; `cus-edit.el' and is documented in the Emacs Lisp Reference manual.
  32
  33 ;; The code implementing face declarations is in `cus-face.el'.
  34
  35 ;;; Code:
  36
  37 (require 'widget)
  38
  39 (defvar custom-define-hook nil
  40   ;; Customize information for this option is in `cus-edit.el'.
  41   "Hook called after defining each customize option.")
  42
  43 (defvar custom-dont-initialize nil
  44   "Non-nil means `defcustom' should not initialize the variable.
  45 That is used for the sake of `custom-make-dependencies'.
  46 Users should not set it.")
  47
  48 (defvar custom-current-group-alist nil
  49   "Alist of (FILE . GROUP) indicating the current group to use for FILE.")
  50
  51 ;;; The `defcustom' Macro.
  52
  53 (defun custom-initialize-default (symbol value)
  54   "Initialize SYMBOL with VALUE.
  55 This will do nothing if symbol already has a default binding.
  56 Otherwise, if symbol has a `saved-value' property, it will evaluate
  57 the car of that and use it as the default binding for symbol.
  58 Otherwise, VALUE will be evaluated and used as the default binding for
  59 symbol."
  60   (unless (default-boundp symbol)
  61     ;; Use the saved value if it exists, otherwise the standard setting.
  62     (set-default symbol (if (get symbol 'saved-value)
  63                             (eval (car (get symbol 'saved-value)))
  64                           (eval value)))))
  65
  66 (defun custom-initialize-set (symbol value)
  67   "Initialize SYMBOL based on VALUE.
  68 If the symbol doesn't have a default binding already,
  69 then set it using its `:set' function (or `set-default' if it has none).
  70 The value is either the value in the symbol's `saved-value' property,
  71 if any, or VALUE."
  72   (unless (default-boundp symbol)
  73     (funcall (or (get symbol 'custom-set) 'set-default)
  74              symbol
  75              (if (get symbol 'saved-value)
  76                  (eval (car (get symbol 'saved-value)))
  77                (eval value)))))
  78
  79 (defun custom-initialize-safe-set (symbol value)
  80   "Like `custom-initialize-set', but catches errors.
  81 If an error occurs during initialization, SYMBOL is set to nil
  82 and no error is thrown.  This is meant for use in pre-loaded files
  83 where some variables or functions used to compute VALUE may not yet
  84 be defined.  You can then re-evaluate VALUE in startup.el, for instance
  85 using `custom-reevaluate-setting'."
  86   (condition-case nil
  87       (custom-initialize-set symbol value)
  88     (error (set-default symbol nil))))
  89
  90 (defun custom-initialize-safe-default (symbol value)
  91   "Like `custom-initialize-default', but catches errors.
  92 If an error occurs during initialization, SYMBOL is set to nil
  93 and no error is thrown.  This is meant for use in pre-loaded files
  94 where some variables or functions used to compute VALUE may not yet
  95 be defined.  You can then re-evaluate VALUE in startup.el, for instance
  96 using `custom-reevaluate-setting'."
  97   (condition-case nil
  98       (custom-initialize-default symbol value)
  99     (error (set-default symbol nil))))
 100
 101 (defun custom-initialize-reset (symbol value)
 102   "Initialize SYMBOL based on VALUE.
 103 Set the symbol, using its `:set' function (or `set-default' if it has none).
 104 The value is either the symbol's current value
 105  \(as obtained using the `:get' function), if any,
 106 or the value in the symbol's `saved-value' property if any,
 107 or (last of all) VALUE."
 108     (funcall (or (get symbol 'custom-set) 'set-default)
 109              symbol
 110              (cond ((default-boundp symbol)
 111                     (funcall (or (get symbol 'custom-get) 'default-value)
 112                              symbol))
 113                    ((get symbol 'saved-value)
 114                     (eval (car (get symbol 'saved-value))))
 115                    (t
 116                     (eval value)))))
 117
 118 (defun custom-initialize-changed (symbol value)
 119   "Initialize SYMBOL with VALUE.
 120 Like `custom-initialize-reset', but only use the `:set' function if
 121 not using the standard setting.
 122 For the standard setting, use `set-default'."
 123   (cond ((default-boundp symbol)
 124          (funcall (or (get symbol 'custom-set) 'set-default)
 125                   symbol
 126                   (funcall (or (get symbol 'custom-get) 'default-value)
 127                            symbol)))
 128         ((get symbol 'saved-value)
 129          (funcall (or (get symbol 'custom-set) 'set-default)
 130                   symbol
 131                   (eval (car (get symbol 'saved-value)))))
 132         (t
 133          (set-default symbol (eval value)))))
 134
 135 (defun custom-declare-variable (symbol default doc &rest args)
 136   "Like `defcustom', but SYMBOL and DEFAULT are evaluated as normal arguments.
 137 DEFAULT should be an expression to evaluate to compute the default value,
 138 not the default value itself.
 139
 140 DEFAULT is stored as SYMBOL's standard value, in SYMBOL's property
 141 `standard-value'.  At the same time, SYMBOL's property `force-value' is
 142 set to nil, as the value is no longer rogue."
 143   (put symbol 'standard-value (list default))
 144   ;; Maybe this option was rogue in an earlier version.  It no longer is.
 145   (when (get symbol 'force-value)
 146     (put symbol 'force-value nil))
 147   (when doc
 148     (put symbol 'variable-documentation doc))
 149   (let ((initialize 'custom-initialize-reset)
 150         (requests nil))
 151     (unless (memq :group args)
 152       (custom-add-to-group (custom-current-group) symbol 'custom-variable))
 153     (while args
 154       (let ((arg (car args)))
 155         (setq args (cdr args))
 156         (unless (symbolp arg)
 157           (error "Junk in args %S" args))
 158         (let ((keyword arg)
 159               (value (car args)))
 160           (unless args
 161             (error "Keyword %s is missing an argument" keyword))
 162           (setq args (cdr args))
 163           (cond ((eq keyword :initialize)
 164                  (setq initialize value))
 165                 ((eq keyword :set)
 166                  (put symbol 'custom-set value))
 167                 ((eq keyword :get)
 168                  (put symbol 'custom-get value))
 169                 ((eq keyword :require)
 170                  (push value requests))
 171                 ((eq keyword :type)
 172                  (put symbol 'custom-type (purecopy value)))
 173                 ((eq keyword :options)
 174                  (if (get symbol 'custom-options)
 175                      ;; Slow safe code to avoid duplicates.
 176                      (mapc (lambda (option)
 177                              (custom-add-option symbol option))
 178                            value)
 179                    ;; Fast code for the common case.
 180                    (put symbol 'custom-options (copy-sequence value))))
 181                 (t
 182                  (custom-handle-keyword symbol keyword value
 183                                         'custom-variable))))))
 184     (put symbol 'custom-requests requests)
 185     ;; Do the actual initialization.
 186     (unless custom-dont-initialize
 187       (funcall initialize symbol default)))
 188   (push symbol current-load-list)
 189   (run-hooks 'custom-define-hook)
 190   symbol)
 191
 192 (defmacro defcustom (symbol value doc &rest args)
 193   "Declare SYMBOL as a customizable variable that defaults to VALUE.
 194 DOC is the variable documentation.
 195
 196 Neither SYMBOL nor VALUE need to be quoted.
 197 If SYMBOL is not already bound, initialize it to VALUE.
 198 The remaining arguments should have the form
 199
 200    [KEYWORD VALUE]...
 201
 202 The following keywords are meaningful:
 203
 204 :type   VALUE should be a widget type for editing the symbol's value.
 205 :options VALUE should be a list of valid members of the widget type.
 206 :group  VALUE should be a customization group.
 207         Add SYMBOL to that group.
 208 :link LINK-DATA
 209         Include an external link after the documentation string for this
 210         item.  This is a sentence containing an active field which
 211         references some other documentation.
 212
 213         There are several alternatives you can use for LINK-DATA:
 214
 215         (custom-manual INFO-NODE)
 216              Link to an Info node; INFO-NODE is a string which specifies
 217              the node name, as in \"(emacs)Top\".
 218
 219         (info-link INFO-NODE)
 220              Like `custom-manual' except that the link appears in the
 221              customization buffer with the Info node name.
 222
 223         (url-link URL)
 224              Link to a web page; URL is a string which specifies the URL.
 225
 226         (emacs-commentary-link LIBRARY)
 227              Link to the commentary section of LIBRARY.
 228
 229         (emacs-library-link LIBRARY)
 230              Link to an Emacs Lisp LIBRARY file.
 231
 232         (file-link FILE)
 233              Link to FILE.
 234
 235         (function-link FUNCTION)
 236              Link to the documentation of FUNCTION.
 237
 238         (variable-link VARIABLE)
 239              Link to the documentation of VARIABLE.
 240
 241         (custom-group-link GROUP)
 242              Link to another customization GROUP.
 243
 244         You can specify the text to use in the customization buffer by
 245         adding `:tag NAME' after the first element of the LINK-DATA; for
 246         example, (info-link :tag \"foo\" \"(emacs)Top\") makes a link to the
 247         Emacs manual which appears in the buffer as `foo'.
 248
 249         An item can have more than one external link; however, most items
 250         have none at all.
 251 :initialize
 252         VALUE should be a function used to initialize the
 253         variable.  It takes two arguments, the symbol and value
 254         given in the `defcustom' call.  The default is
 255         `custom-initialize-reset'.
 256 :set    VALUE should be a function to set the value of the symbol.
 257         It takes two arguments, the symbol to set and the value to
 258         give it.  The default choice of function is `custom-set-default'.
 259 :get    VALUE should be a function to extract the value of symbol.
 260         The function takes one argument, a symbol, and should return
 261         the current value for that symbol.  The default choice of function
 262         is `custom-default-value'.
 263 :require
 264         VALUE should be a feature symbol.  If you save a value
 265         for this option, then when your `.emacs' file loads the value,
 266         it does (require VALUE) first.
 267 :version
 268         VALUE should be a string specifying that the variable was
 269         first introduced, or its default value was changed, in Emacs
 270         version VERSION.
 271 :tag LABEL
 272         Use LABEL, a string, instead of the item's name, to label the item
 273         in customization menus and buffers.
 274 :load FILE
 275         Load file FILE (a string) before displaying this customization
 276         item.  Loading is done with `load', and only if the file is
 277         not already loaded.
 278 :set-after VARIABLES
 279         Specifies that SYMBOL should be set after the list of variables
 280         VARIABLES when both have been customized.
 281
 282 If SYMBOL has a local binding, then this form affects the local
 283 binding.  This is normally not what you want.  Thus, if you need
 284 to load a file defining variables with this form, or with
 285 `defvar' or `defconst', you should always load that file
 286 _outside_ any bindings for these variables.  \(`defvar' and
 287 `defconst' behave similarly in this respect.)
 288
 289 Read the section about customization in the Emacs Lisp manual for more
 290 information."
 291   (declare (doc-string 3))
 292   ;; It is better not to use backquote in this file,
 293   ;; because that makes a bootstrapping problem
 294   ;; if you need to recompile all the Lisp files using interpreted code.
 295   (nconc (list 'custom-declare-variable
 296                (list 'quote symbol)
 297                (list 'quote value)
 298                doc)
 299          args))
 300
 301 ;;; The `defface' Macro.
 302
 303 (defmacro defface (face spec doc &rest args)
 304   "Declare FACE as a customizable face that defaults to SPEC.
 305 FACE does not need to be quoted.
 306
 307 Third argument DOC is the face documentation.
 308
 309 If FACE has been set with `custom-set-faces', set the face attributes
 310 as specified by that function, otherwise set the face attributes
 311 according to SPEC.
 312
 313 The remaining arguments should have the form
 314
 315    [KEYWORD VALUE]...
 316
 317 The following KEYWORDs are defined:
 318
 319 :group  VALUE should be a customization group.
 320         Add FACE to that group.
 321
 322 SPEC should be an alist of the form ((DISPLAY ATTS)...).
 323
 324 In the first element, DISPLAY can be :default.  The ATTS in that
 325 element then act as defaults for all the following elements.
 326
 327 Aside from that, DISPLAY specifies conditions to match some or
 328 all frames.  For each frame, the first element of SPEC where the
 329 DISPLAY conditions are satisfied is the one that applies to that
 330 frame.  The ATTRs in this element take effect, and the following
 331 elements are ignored, on that frame.
 332
 333 In the last element, DISPLAY can be t.  That element applies to a
 334 frame if none of the previous elements (except the :default if
 335 any) did.
 336
 337 ATTS is a list of face attributes followed by their values:
 338   (ATTR VALUE ATTR VALUE...)
 339
 340 The possible attributes are `:family', `:width', `:height', `:weight',
 341 `:slant', `:underline', `:overline', `:strike-through', `:box',
 342 `:foreground', `:background', `:stipple', `:inverse-video', and `:inherit'.
 343
 344 DISPLAY can be `:default' (only in the first element), the symbol
 345 t (only in the last element) to match all frames, or an alist of
 346 conditions of the form \(REQ ITEM...).  For such an alist to
 347 match a frame, each of the conditions must be satisfied, meaning
 348 that the REQ property of the frame must match one of the
 349 corresponding ITEMs.  These are the defined REQ values:
 350
 351 `type' (the value of `window-system')
 352   Under X, in addition to the values `window-system' can take,
 353   `motif', `lucid', `gtk' and `x-toolkit' are allowed, and match when
 354   the Motif toolkit, Lucid toolkit, GTK toolkit or any X toolkit is in use.
 355
 356 `class' (the frame's color support)
 357   Should be one of `color', `grayscale', or `mono'.
 358
 359 `background' (what color is used for the background text)
 360   Should be one of `light' or `dark'.
 361
 362 `min-colors' (the minimum number of colors the frame should support)
 363   Should be an integer, it is compared with the result of
 364   `display-color-cells'.
 365
 366 `supports' (only match frames that support the specified face attributes)
 367   Should be a list of face attributes.  See the documentation for
 368   the function `display-supports-face-attributes-p' for more
 369   information on exactly how testing is done.
 370
 371 Read the section about customization in the Emacs Lisp manual for more
 372 information."
 373   (declare (doc-string 3))
 374   ;; It is better not to use backquote in this file,
 375   ;; because that makes a bootstrapping problem
 376   ;; if you need to recompile all the Lisp files using interpreted code.
 377   (nconc (list 'custom-declare-face (list 'quote face) spec doc) args))
 378
 379 ;;; The `defgroup' Macro.
 380
 381 (defun custom-current-group ()
 382   (cdr (assoc load-file-name custom-current-group-alist)))
 383
 384 (defun custom-declare-group (symbol members doc &rest args)
 385   "Like `defgroup', but SYMBOL is evaluated as a normal argument."
 386   (while members
 387     (apply 'custom-add-to-group symbol (car members))
 388     (setq members (cdr members)))
 389   (when doc
 390     ;; This text doesn't get into DOC.
 391     (put symbol 'group-documentation (purecopy doc)))
 392   (while args
 393     (let ((arg (car args)))
 394       (setq args (cdr args))
 395       (unless (symbolp arg)
 396         (error "Junk in args %S" args))
 397       (let ((keyword arg)
 398             (value (car args)))
 399         (unless args
 400           (error "Keyword %s is missing an argument" keyword))
 401         (setq args (cdr args))
 402         (cond ((eq keyword :prefix)
 403                (put symbol 'custom-prefix value))
 404               (t
 405                (custom-handle-keyword symbol keyword value
 406                                       'custom-group))))))
 407   ;; Record the group on the `current' list.
 408   (let ((elt (assoc load-file-name custom-current-group-alist)))
 409     (if elt (setcdr elt symbol)
 410       (push (cons load-file-name symbol) custom-current-group-alist)))
 411   (run-hooks 'custom-define-hook)
 412   symbol)
 413
 414 (defmacro defgroup (symbol members doc &rest args)
 415   "Declare SYMBOL as a customization group containing MEMBERS.
 416 SYMBOL does not need to be quoted.
 417
 418 Third arg DOC is the group documentation.
 419
 420 MEMBERS should be an alist of the form ((NAME WIDGET)...) where
 421 NAME is a symbol and WIDGET is a widget for editing that symbol.
 422 Useful widgets are `custom-variable' for editing variables,
 423 `custom-face' for edit faces, and `custom-group' for editing groups.
 424
 425 The remaining arguments should have the form
 426
 427    [KEYWORD VALUE]...
 428
 429 The following KEYWORDs are defined:
 430
 431 :group   VALUE should be a customization group.
 432          Add SYMBOL to that group.
 433
 434 :version VALUE should be a string specifying that the group was introduced
 435          in Emacs version VERSION.
 436
 437 Read the section about customization in the Emacs Lisp manual for more
 438 information."
 439   (declare (doc-string 3))
 440   ;; It is better not to use backquote in this file,
 441   ;; because that makes a bootstrapping problem
 442   ;; if you need to recompile all the Lisp files using interpreted code.
 443   (nconc (list 'custom-declare-group (list 'quote symbol) members doc) args))
 444
 445 (defun custom-add-to-group (group option widget)
 446   "To existing GROUP add a new OPTION of type WIDGET.
 447 If there already is an entry for OPTION and WIDGET, nothing is done."
 448   (let ((members (get group 'custom-group))
 449         (entry (list option widget)))
 450     (unless (member entry members)
 451       (put group 'custom-group (nconc members (list entry))))))
 452
 453 (defun custom-group-of-mode (mode)
 454   "Return the custom group corresponding to the major or minor MODE.
 455 If no such group is found, return nil."
 456   (or (get mode 'custom-mode-group)
 457       (if (or (get mode 'custom-group)
 458               (and (string-match "-mode\\'" (symbol-name mode))
 459                    (get (setq mode (intern (substring (symbol-name mode)
 460                                                       0 (match-beginning 0))))
 461                         'custom-group)))
 462           mode)))
 463
 464 ;;; Properties.
 465
 466 (defun custom-handle-all-keywords (symbol args type)
 467   "For customization option SYMBOL, handle keyword arguments ARGS.
 468 Third argument TYPE is the custom option type."
 469   (unless (memq :group args)
 470     (custom-add-to-group (custom-current-group) symbol type))
 471   (while args
 472     (let ((arg (car args)))
 473       (setq args (cdr args))
 474       (unless (symbolp arg)
 475         (error "Junk in args %S" args))
 476       (let ((keyword arg)
 477             (value (car args)))
 478         (unless args
 479           (error "Keyword %s is missing an argument" keyword))
 480         (setq args (cdr args))
 481         (custom-handle-keyword symbol keyword value type)))))
 482
 483 (defun custom-handle-keyword (symbol keyword value type)
 484   "For customization option SYMBOL, handle KEYWORD with VALUE.
 485 Fourth argument TYPE is the custom option type."
 486   (if purify-flag
 487       (setq value (purecopy value)))
 488   (cond ((eq keyword :group)
 489          (custom-add-to-group value symbol type))
 490         ((eq keyword :version)
 491          (custom-add-version symbol value))
 492         ((eq keyword :link)
 493          (custom-add-link symbol value))
 494         ((eq keyword :load)
 495          (custom-add-load symbol value))
 496         ((eq keyword :tag)
 497          (put symbol 'custom-tag value))
 498         ((eq keyword :set-after)
 499          (custom-add-dependencies symbol value))
 500         (t
 501          (error "Unknown keyword %s" keyword))))
 502
 503 (defun custom-add-dependencies (symbol value)
 504   "To the custom option SYMBOL, add dependencies specified by VALUE.
 505 VALUE should be a list of symbols.  For each symbol in that list,
 506 this specifies that SYMBOL should be set after the specified symbol, if
 507 both appear in constructs like `custom-set-variables'."
 508   (unless (listp value)
 509     (error "Invalid custom dependency `%s'" value))
 510   (let* ((deps (get symbol 'custom-dependencies))
 511          (new-deps deps))
 512     (while value
 513       (let ((dep (car value)))
 514         (unless (symbolp dep)
 515           (error "Invalid custom dependency `%s'" dep))
 516         (unless (memq dep new-deps)
 517           (setq new-deps (cons dep new-deps)))
 518         (setq value (cdr value))))
 519     (unless (eq deps new-deps)
 520       (put symbol 'custom-dependencies new-deps))))
 521
 522 (defun custom-add-option (symbol option)
 523   "To the variable SYMBOL add OPTION.
 524
 525 If SYMBOL's custom type is a hook, OPTION should be a hook member.
 526 If SYMBOL's custom type is an alist, OPTION specifies a symbol
 527 to offer to the user as a possible key in the alist.
 528 For other custom types, this has no effect."
 529   (let ((options (get symbol 'custom-options)))
 530     (unless (member option options)
 531       (put symbol 'custom-options (cons option options)))))
 532
 533 (defun custom-add-link (symbol widget)
 534   "To the custom option SYMBOL add the link WIDGET."
 535   (let ((links (get symbol 'custom-links)))
 536     (unless (member widget links)
 537       (put symbol 'custom-links (cons (purecopy widget) links)))))
 538
 539 (defun custom-add-version (symbol version)
 540   "To the custom option SYMBOL add the version VERSION."
 541   (put symbol 'custom-version (purecopy version)))
 542
 543 (defun custom-add-load (symbol load)
 544   "To the custom option SYMBOL add the dependency LOAD.
 545 LOAD should be either a library file name, or a feature name."
 546   (let ((loads (get symbol 'custom-loads)))
 547     (unless (member load loads)
 548       (put symbol 'custom-loads (cons (purecopy load) loads)))))
 549
 550 (defun custom-autoload (symbol load)
 551   "Mark SYMBOL as autoloaded custom variable and add dependency LOAD."
 552   (put symbol 'custom-autoload t)
 553   (custom-add-load symbol load))
 554
 555 ;; This test is also in the C code of `user-variable-p'.
 556 (defun custom-variable-p (variable)
 557   "Return non-nil if VARIABLE is a custom variable.
 558 This recursively follows aliases."
 559   (setq variable (indirect-variable variable))
 560   (or (get variable 'standard-value)
 561       (get variable 'custom-autoload)))
 562
 563 ;;; Loading files needed to customize a symbol.
 564 ;;; This is in custom.el because menu-bar.el needs it for toggle cmds.
 565
 566 (defvar custom-load-recursion nil
 567   "Hack to avoid recursive dependencies.")
 568
 569 (defun custom-load-symbol (symbol)
 570   "Load all dependencies for SYMBOL."
 571   (unless custom-load-recursion
 572     (let ((custom-load-recursion t))
 573       ;; Load these files if not already done,
 574       ;; to make sure we know all the dependencies of SYMBOL.
 575       (condition-case nil
 576           (require 'cus-load)
 577         (error nil))
 578       (condition-case nil
 579           (require 'cus-start)
 580         (error nil))
 581       (dolist (load (get symbol 'custom-loads))
 582         (cond ((symbolp load) (condition-case nil (require load) (error nil)))
 583               ;; This is subsumed by the test below, but it's much faster.
 584               ((assoc load load-history))
 585               ;; This was just (assoc (locate-library load) load-history)
 586               ;; but has been optimized not to load locate-library
 587               ;; if not necessary.
 588               ((let ((regexp (concat "\\(\\`\\|/\\)" (regexp-quote load)
 589                                      "\\(\\'\\|\\.\\)"))
 590                      (found nil))
 591                  (dolist (loaded load-history)
 592                    (and (stringp (car loaded))
 593                         (string-match regexp (car loaded))
 594                         (setq found t)))
 595                  found))
 596               ;; Without this, we would load cus-edit recursively.
 597               ;; We are still loading it when we call this,
 598               ;; and it is not in load-history yet.
 599               ((equal load "cus-edit"))
 600               (t (condition-case nil (load load) (error nil))))))))
 601 \f
 602 (defvar custom-local-buffer nil
 603   "Non-nil, in a Customization buffer, means customize a specific buffer.
 604 If this variable is non-nil, it should be a buffer,
 605 and it means customize the local bindings of that buffer.
 606 This variable is a permanent local, and it normally has a local binding
 607 in every Customization buffer.")
 608 (put 'custom-local-buffer 'permanent-local t)
 609
 610 (defun custom-set-default (variable value)
 611   "Default :set function for a customizable variable.
 612 Normally, this sets the default value of VARIABLE to VALUE,
 613 but if `custom-local-buffer' is non-nil,
 614 this sets the local binding in that buffer instead."
 615   (if custom-local-buffer
 616       (with-current-buffer custom-local-buffer
 617         (set variable value))
 618     (set-default variable value)))
 619
 620 (defun custom-set-minor-mode (variable value)
 621   ":set function for minor mode variables.
 622 Normally, this sets the default value of VARIABLE to nil if VALUE
 623 is nil and to t otherwise,
 624 but if `custom-local-buffer' is non-nil,
 625 this sets the local binding in that buffer instead."
 626   (if custom-local-buffer
 627       (with-current-buffer custom-local-buffer
 628         (funcall variable (if value 1 0)))
 629     (funcall variable (if value 1 0))))
 630
 631 (defun custom-quote (sexp)
 632   "Quote SEXP iff it is not self quoting."
 633   (if (or (memq sexp '(t nil))
 634           (keywordp sexp)
 635           (and (listp sexp)
 636                (memq (car sexp) '(lambda)))
 637           (stringp sexp)
 638           (numberp sexp)
 639           (vectorp sexp)
 640 ;;;       (and (fboundp 'characterp)
 641 ;;;            (characterp sexp))
 642           )
 643       sexp
 644     (list 'quote sexp)))
 645
 646 (defun customize-mark-to-save (symbol)
 647   "Mark SYMBOL for later saving.
 648
 649 If the default value of SYMBOL is different from the standard value,
 650 set the `saved-value' property to a list whose car evaluates to the
 651 default value.  Otherwise, set it to nil.
 652
 653 To actually save the value, call `custom-save-all'.
 654
 655 Return non-nil iff the `saved-value' property actually changed."
 656   (let* ((get (or (get symbol 'custom-get) 'default-value))
 657          (value (funcall get symbol))
 658          (saved (get symbol 'saved-value))
 659          (standard (get symbol 'standard-value))
 660          (comment (get symbol 'customized-variable-comment)))
 661     ;; Save default value iff different from standard value.
 662     (if (or (null standard)
 663             (not (equal value (condition-case nil
 664                                   (eval (car standard))
 665                                 (error nil)))))
 666         (put symbol 'saved-value (list (custom-quote value)))
 667       (put symbol 'saved-value nil))
 668     ;; Clear customized information (set, but not saved).
 669     (put symbol 'customized-value nil)
 670     ;; Save any comment that might have been set.
 671     (when comment
 672       (put symbol 'saved-variable-comment comment))
 673     (not (equal saved (get symbol 'saved-value)))))
 674
 675 (defun customize-mark-as-set (symbol)
 676   "Mark current value of SYMBOL as being set from customize.
 677
 678 If the default value of SYMBOL is different from the saved value if any,
 679 or else if it is different from the standard value, set the
 680 `customized-value' property to a list whose car evaluates to the
 681 default value.  Otherwise, set it to nil.
 682
 683 Return non-nil iff the `customized-value' property actually changed."
 684   (let* ((get (or (get symbol 'custom-get) 'default-value))
 685          (value (funcall get symbol))
 686          (customized (get symbol 'customized-value))
 687          (old (or (get symbol 'saved-value) (get symbol 'standard-value))))
 688     ;; Mark default value as set iff different from old value.
 689     (if (or (null old)
 690             (not (equal value (condition-case nil
 691                                   (eval (car old))
 692                                 (error nil)))))
 693         (put symbol 'customized-value (list (custom-quote value)))
 694       (put symbol 'customized-value nil))
 695     ;; Changed?
 696     (not (equal customized (get symbol 'customized-value)))))
 697
 698 (defun custom-reevaluate-setting (symbol)
 699   "Reset the value of SYMBOL by re-evaluating its saved or standard value.
 700 Use the :set function to do so.  This is useful for customizable options
 701 that are defined before their standard value can really be computed.
 702 E.g. dumped variables whose default depends on run-time information."
 703   (funcall (or (get symbol 'custom-set) 'set-default)
 704            symbol
 705            (eval (car (or (get symbol 'saved-value) (get symbol 'standard-value))))))
 706
 707 \f
 708 ;;; Custom Themes
 709
 710 ;; Custom themes are collections of settings that can be enabled or
 711 ;; disabled as a unit.
 712
 713 ;; Each Custom theme is defined by a symbol, called the theme name.
 714 ;; The `theme-settings' property of the theme name records the
 715 ;; variable and face settings of the theme.  This property is a list
 716 ;; of elements, each of the form
 717 ;;
 718 ;;     (PROP SYMBOL THEME VALUE)
 719 ;;
 720 ;;  - PROP is either `theme-value' or `theme-face'
 721 ;;  - SYMBOL is the face or variable name
 722 ;;  - THEME is the theme name (redundant, but simplifies the code)
 723 ;;  - VALUE is an expression that gives the theme's setting for SYMBOL.
 724 ;;
 725 ;; The theme name also has a `theme-feature' property, whose value is
 726 ;; specified when the theme is defined (see `custom-declare-theme').
 727 ;; Usually, this is just a symbol named THEME-theme.  This lets
 728 ;; external libraries call (require 'foo-theme).
 729
 730 ;; In addition, each symbol (either a variable or a face) affected by
 731 ;; an *enabled* theme has a `theme-value' or `theme-face' property,
 732 ;; which is a list of elements each of the form
 733 ;;
 734 ;;     (THEME VALUE)
 735 ;;
 736 ;; which have the same meanings as in `theme-settings'.
 737 ;;
 738 ;; The `theme-value' and `theme-face' lists are ordered by decreasing
 739 ;; theme precedence.  Thus, the first element is always the one that
 740 ;; is in effect.
 741
 742 ;; Each theme is stored in a theme file, with filename THEME-theme.el.
 743 ;; Loading a theme basically involves calling (load "THEME-theme")
 744 ;; This is done by the function `load-theme'.  Loading a theme
 745 ;; automatically enables it.
 746 ;;
 747 ;; When a theme is enabled, the `theme-value' and `theme-face'
 748 ;; properties for the affected symbols are set.  When a theme is
 749 ;; disabled, its settings are removed from the `theme-value' and
 750 ;; `theme-face' properties, but the theme's own `theme-settings'
 751 ;; property remains unchanged.
 752
 753 (defvar custom-known-themes '(user changed)
 754    "Themes that have been defined with `deftheme'.
 755 The default value is the list (user changed).  The theme `changed'
 756 contains the settings before custom themes are applied.  The
 757 theme `user' contains all the settings the user customized and saved.
 758 Additional themes declared with the `deftheme' macro will be added to
 759 the front of this list.")
 760
 761 (defsubst custom-theme-p (theme)
 762   "Non-nil when THEME has been defined."
 763   (memq theme custom-known-themes))
 764
 765 (defsubst custom-check-theme (theme)
 766   "Check whether THEME is valid, and signal an error if it is not."
 767   (unless (custom-theme-p theme)
 768     (error "Unknown theme `%s'" theme)))
 769
 770 (defun custom-push-theme (prop symbol theme mode &optional value)
 771   "Record VALUE for face or variable SYMBOL in custom theme THEME.
 772 PROP is `theme-face' for a face, `theme-value' for a variable.
 773
 774 MODE can be either the symbol `set' or the symbol `reset'.  If it is the
 775 symbol `set', then VALUE is the value to use.  If it is the symbol
 776 `reset', then SYMBOL will be removed from THEME (VALUE is ignored).
 777
 778 See `custom-known-themes' for a list of known themes."
 779   (unless (memq prop '(theme-value theme-face))
 780     (error "Unknown theme property"))
 781   (let* ((old (get symbol prop))
 782          (setting (assq theme old))  ; '(theme value)
 783          (theme-settings             ; '(prop symbol theme value)
 784           (get theme 'theme-settings)))
 785     (if (eq mode 'reset)
 786         ;; Remove a setting.
 787         (when setting
 788           (let (res)
 789             (dolist (theme-setting theme-settings)
 790               (if (and (eq (car  theme-setting) prop)
 791                        (eq (cadr theme-setting) symbol))
 792                   (setq res theme-setting)))
 793             (put theme 'theme-settings (delq res theme-settings)))
 794           (put symbol prop (delq setting old)))
 795       (if setting
 796           ;; Alter an existing setting.
 797           (let (res)
 798             (dolist (theme-setting theme-settings)
 799               (if (and (eq (car  theme-setting) prop)
 800                        (eq (cadr theme-setting) symbol))
 801                   (setq res theme-setting)))
 802             (put theme 'theme-settings
 803                  (cons (list prop symbol theme value)
 804                        (delq res theme-settings)))
 805             (setcar (cdr setting) value))
 806         ;; Add a new setting.
 807         ;; If the user changed the value outside of Customize, we
 808         ;; first save the current value to a fake theme, `changed'.
 809         ;; This ensures that the user-set value comes back if the
 810         ;; theme is later disabled.
 811         (if (null old)
 812             (if (and (eq prop 'theme-value)
 813                      (boundp symbol)
 814                      (or (null (get symbol 'standard-value))
 815                          (not (equal (eval (car (get symbol 'standard-value)))
 816                                      (symbol-value symbol)))))
 817                 (setq old (list (list 'changed (symbol-value symbol))))
 818               (if (facep symbol)
 819                   (setq old (list (list 'changed (list
 820                     (append '(t) (custom-face-attributes-get symbol nil)))))))))
 821         (put symbol prop (cons (list theme value) old))
 822         (put theme 'theme-settings
 823              (cons (list prop symbol theme value)
 824                    theme-settings))))))
 825
 826 \f
 827 (defun custom-set-variables (&rest args)
 828   "Install user customizations of variable values specified in ARGS.
 829 These settings are registered as theme `user'.
 830 The arguments should each be a list of the form:
 831
 832   (SYMBOL EXP [NOW [REQUEST [COMMENT]]])
 833
 834 This stores EXP (without evaluating it) as the saved value for SYMBOL.
 835 If NOW is present and non-nil, then also evaluate EXP and set
 836 the default value for the SYMBOL to the value of EXP.
 837
 838 REQUEST is a list of features we must require in order to
 839 handle SYMBOL properly.
 840 COMMENT is a comment string about SYMBOL."
 841   (apply 'custom-theme-set-variables 'user args))
 842
 843 (defun custom-theme-set-variables (theme &rest args)
 844   "Initialize variables for theme THEME according to settings in ARGS.
 845 Each of the arguments in ARGS should be a list of this form:
 846
 847   (SYMBOL EXP [NOW [REQUEST [COMMENT]]])
 848
 849 This stores EXP (without evaluating it) as the saved value for SYMBOL.
 850 If NOW is present and non-nil, then also evaluate EXP and set
 851 the default value for the SYMBOL to the value of EXP.
 852
 853 REQUEST is a list of features we must require in order to
 854 handle SYMBOL properly.
 855 COMMENT is a comment string about SYMBOL.
 856
 857 EXP itself is saved unevaluated as SYMBOL property `saved-value' and
 858 in SYMBOL's list property `theme-value' \(using `custom-push-theme')."
 859   (custom-check-theme theme)
 860   (setq args
 861         (sort args
 862               (lambda (a1 a2)
 863                 (let* ((sym1 (car a1))
 864                        (sym2 (car a2))
 865                        (1-then-2 (memq sym1 (get sym2 'custom-dependencies)))
 866                        (2-then-1 (memq sym2 (get sym1 'custom-dependencies))))
 867                   (cond ((and 1-then-2 2-then-1)
 868                          (error "Circular custom dependency between `%s' and `%s'"
 869                                 sym1 sym2))
 870                         (2-then-1 nil)
 871                         ;; Put minor modes and symbols with :require last.
 872                         ;; Putting minor modes last ensures that the mode
 873                         ;; function will see other customized values rather
 874                         ;; than default values.
 875                         (t (or (nth 3 a2)
 876                                (eq (get sym2 'custom-set)
 877                                    'custom-set-minor-mode))))))))
 878   (while args
 879     (let ((entry (car args)))
 880       (if (listp entry)
 881           (let* ((symbol (indirect-variable (nth 0 entry)))
 882                  (value (nth 1 entry))
 883                  (now (nth 2 entry))
 884                  (requests (nth 3 entry))
 885                  (comment (nth 4 entry))
 886                  set)
 887             (when requests
 888               (put symbol 'custom-requests requests)
 889               (mapc 'require requests))
 890             (setq set (or (get symbol 'custom-set) 'custom-set-default))
 891             (put symbol 'saved-value (list value))
 892             (put symbol 'saved-variable-comment comment)
 893             (custom-push-theme 'theme-value symbol theme 'set value)
 894             ;; Allow for errors in the case where the setter has
 895             ;; changed between versions, say, but let the user know.
 896             (condition-case data
 897                 (cond (now
 898                        ;; Rogue variable, set it now.
 899                        (put symbol 'force-value t)
 900                        (funcall set symbol (eval value)))
 901                       ((default-boundp symbol)
 902                        ;; Something already set this, overwrite it.
 903                        (funcall set symbol (eval value))))
 904               (error
 905                (message "Error setting %s: %s" symbol data)))
 906             (setq args (cdr args))
 907             (and (or now (default-boundp symbol))
 908                  (put symbol 'variable-comment comment)))
 909         ;; Old format, a plist of SYMBOL VALUE pairs.
 910         (message "Warning: old format `custom-set-variables'")
 911         (ding)
 912         (sit-for 2)
 913         (let ((symbol (indirect-variable (nth 0 args)))
 914               (value (nth 1 args)))
 915           (put symbol 'saved-value (list value))
 916           (custom-push-theme 'theme-value symbol theme 'set value))
 917         (setq args (cdr (cdr args)))))))
 918
 919 \f
 920 ;;; Defining themes.
 921
 922 ;; A theme file should be named `THEME-theme.el' (where THEME is the theme
 923 ;; name), and found in either `custom-theme-directory' or the load path.
 924 ;; It has the following format:
 925 ;;
 926 ;;   (deftheme THEME
 927 ;;     DOCSTRING)
 928 ;;
 929 ;;   (custom-theme-set-variables
 930 ;;    'THEME
 931 ;;    [THEME-VARIABLES])
 932 ;;
 933 ;;   (custom-theme-set-faces
 934 ;;    'THEME
 935 ;;    [THEME-FACES])
 936 ;;
 937 ;;   (provide-theme 'THEME)
 938
 939
 940 ;; The IGNORED arguments to deftheme come from the XEmacs theme code, where
 941 ;; they were used to supply keyword-value pairs like `:immediate',
 942 ;; `:variable-reset-string', etc.  We don't use any of these, so ignore them.
 943
 944 (defmacro deftheme (theme &optional doc &rest ignored)
 945   "Declare THEME to be a Custom theme.
 946 The optional argument DOC is a doc string describing the theme.
 947
 948 Any theme `foo' should be defined in a file called `foo-theme.el';
 949 see `custom-make-theme-feature' for more information."
 950   (let ((feature (custom-make-theme-feature theme)))
 951     ;; It is better not to use backquote in this file,
 952     ;; because that makes a bootstrapping problem
 953     ;; if you need to recompile all the Lisp files using interpreted code.
 954     (list 'custom-declare-theme (list 'quote theme) (list 'quote feature) doc)))
 955
 956 (defun custom-declare-theme (theme feature &optional doc &rest ignored)
 957   "Like `deftheme', but THEME is evaluated as a normal argument.
 958 FEATURE is the feature this theme provides.  Normally, this is a symbol
 959 created from THEME by `custom-make-theme-feature'."
 960   (if (memq theme '(user changed))
 961       (error "Custom theme cannot be named %S" theme))
 962   (add-to-list 'custom-known-themes theme)
 963   (put theme 'theme-feature feature)
 964   (when doc (put theme 'theme-documentation doc)))
 965
 966 (defun custom-make-theme-feature (theme)
 967   "Given a symbol THEME, create a new symbol by appending \"-theme\".
 968 Store this symbol in the `theme-feature' property of THEME.
 969 Calling `provide-theme' to provide THEME actually puts `THEME-theme'
 970 into `features'.
 971
 972 This allows for a file-name convention for autoloading themes:
 973 Every theme X has a property `provide-theme' whose value is \"X-theme\".
 974 \(load-theme X) then attempts to load the file `X-theme.el'."
 975   (intern (concat (symbol-name theme) "-theme")))
 976 \f
 977 ;;; Loading themes.
 978
 979 (defcustom custom-theme-directory
 980   (if (eq system-type 'ms-dos)
 981          ;; MS-DOS cannot have initial dot.
 982          "~/_emacs.d/"
 983       "~/.emacs.d/")
 984   "Directory in which Custom theme files should be written.
 985 `load-theme' searches this directory in addition to load-path.
 986 The command `customize-create-theme' writes the files it produces
 987 into this directory."
 988   :type 'string
 989   :group 'customize
 990   :version "22.1")
 991
 992 (defun provide-theme (theme)
 993   "Indicate that this file provides THEME.
 994 This calls `provide' to provide the feature name stored in THEME's
 995 property `theme-feature' (which is usually a symbol created by
 996 `custom-make-theme-feature')."
 997   (if (memq theme '(user changed))
 998       (error "Custom theme cannot be named %S" theme))
 999   (custom-check-theme theme)
1000   (provide (get theme 'theme-feature))
1001   ;; Loading a theme also enables it.
1002   (push theme custom-enabled-themes)
1003   ;; `user' must always be the highest-precedence enabled theme.
1004   ;; Make that remain true.  (This has the effect of making user settings
1005   ;; override the ones just loaded, too.)
1006   (let ((custom-enabling-themes t))
1007     (enable-theme 'user)))
1008
1009 (defun load-theme (theme)
1010   "Load a theme's settings from its file.
1011 This also enables the theme; use `disable-theme' to disable it."
1012   ;; Note we do no check for validity of the theme here.
1013   ;; This allows to pull in themes by a file-name convention
1014   (interactive "SCustom theme name: ")
1015   ;; If reloading, clear out the old theme settings.
1016   (when (custom-theme-p theme)
1017     (disable-theme theme)
1018     (put theme 'theme-settings nil)
1019     (put theme 'theme-feature nil)
1020     (put theme 'theme-documentation nil))
1021   (let ((load-path (if (file-directory-p custom-theme-directory)
1022                        (cons custom-theme-directory load-path)
1023                      load-path)))
1024     (load (symbol-name (custom-make-theme-feature theme)))))
1025 \f
1026 ;;; Enabling and disabling loaded themes.
1027
1028 (defvar custom-enabling-themes nil)
1029
1030 (defun enable-theme (theme)
1031   "Reenable all variable and face settings defined by THEME.
1032 The newly enabled theme gets the highest precedence (after `user').
1033 If it is already enabled, just give it highest precedence (after `user').
1034
1035 If THEME does not specify any theme settings, this tries to load
1036 the theme from its theme file, by calling `load-theme'."
1037   (interactive "SEnable Custom theme: ")
1038   (if (not (custom-theme-p theme))
1039       (load-theme theme)
1040     ;; This could use a bit of optimization -- cyd
1041     (let ((settings (get theme 'theme-settings)))
1042       (dolist (s settings)
1043         (let* ((prop (car s))
1044                (symbol (cadr s))
1045                (spec-list (get symbol prop)))
1046           (put symbol prop (cons (cddr s) (assq-delete-all theme spec-list)))
1047           (if (eq prop 'theme-value)
1048               (custom-theme-recalc-variable symbol)
1049             (custom-theme-recalc-face symbol)))))
1050     (unless (eq theme 'user)
1051       (setq custom-enabled-themes
1052             (cons theme (delq theme custom-enabled-themes)))
1053       (unless custom-enabling-themes
1054         (enable-theme 'user)))))
1055
1056 (defcustom custom-enabled-themes nil
1057   "List of enabled Custom Themes, highest precedence first.
1058
1059 This does not include the `user' theme, which is set by Customize,
1060 and always takes precedence over other Custom Themes."
1061   :group 'customize
1062   :type  '(repeat symbol)
1063   :set (lambda (symbol themes)
1064          ;; Avoid an infinite loop when custom-enabled-themes is
1065          ;; defined in a theme (e.g. `user').  Enabling the theme sets
1066          ;; custom-enabled-themes, which enables the theme...
1067          (unless custom-enabling-themes
1068            (let ((custom-enabling-themes t) failures)
1069              (setq themes (delq 'user (delete-dups themes)))
1070              (if (boundp symbol)
1071                  (dolist (theme (symbol-value symbol))
1072                    (if (not (memq theme themes))
1073                        (disable-theme theme))))
1074              (dolist (theme (reverse themes))
1075                (condition-case nil
1076                    (enable-theme theme)
1077                  (error (progn (push theme failures)
1078                                (setq themes (delq theme themes))))))
1079              (enable-theme 'user)
1080              (custom-set-default symbol themes)
1081              (if failures
1082                  (message "Failed to enable themes: %s"
1083                           (mapconcat 'symbol-name failures " ")))))))
1084
1085 (defsubst custom-theme-enabled-p (theme)
1086   "Return non-nil if THEME is enabled."
1087   (memq theme custom-enabled-themes))
1088
1089 (defun disable-theme (theme)
1090   "Disable all variable and face settings defined by THEME.
1091 See `custom-enabled-themes' for a list of enabled themes."
1092   (interactive (list (intern
1093                       (completing-read
1094                        "Disable Custom theme: "
1095                        (mapcar 'symbol-name custom-enabled-themes)
1096                        nil t))))
1097   (when (custom-theme-enabled-p theme)
1098     (let ((settings (get theme 'theme-settings)))
1099       (dolist (s settings)
1100         (let* ((prop (car s))
1101                (symbol (cadr s))
1102                (spec-list (get symbol prop)))
1103           (put symbol prop (assq-delete-all theme spec-list))
1104           (if (eq prop 'theme-value)
1105               (custom-theme-recalc-variable symbol)
1106             (custom-theme-recalc-face symbol)))))
1107     (setq custom-enabled-themes
1108           (delq theme custom-enabled-themes))))
1109
1110 (defun custom-variable-theme-value (variable)
1111   "Return (list VALUE) indicating the custom theme value of VARIABLE.
1112 That is to say, it specifies what the value should be according to
1113 currently enabled custom themes.
1114
1115 This function returns nil if no custom theme specifies a value for VARIABLE."
1116   (let* ((theme-value (get variable 'theme-value)))
1117     (if theme-value
1118         (cdr (car theme-value)))))
1119
1120 (defun custom-theme-recalc-variable (variable)
1121   "Set VARIABLE according to currently enabled custom themes."
1122   (let ((valspec (custom-variable-theme-value variable)))
1123     (if valspec
1124         (put variable 'saved-value valspec)
1125       (setq valspec (get variable 'standard-value)))
1126     (if (and valspec
1127              (or (get variable 'force-value)
1128                  (default-boundp variable)))
1129         (funcall (or (get variable 'custom-set) 'set-default) variable
1130                  (eval (car valspec))))))
1131
1132 (defun custom-theme-recalc-face (face)
1133   "Set FACE according to currently enabled custom themes."
1134   (if (facep face)
1135       (let ((theme-faces (reverse (get face 'theme-face))))
1136         (dolist (spec theme-faces)
1137           (face-spec-set face (cadr spec))))))
1138 \f
1139 ;;; XEmacs compability functions
1140
1141 ;; In XEmacs, when you reset a Custom Theme, you have to specify the
1142 ;; theme to reset it to.  We just apply the next available theme, so
1143 ;; just ignore the IGNORED arguments.
1144
1145 (defun custom-theme-reset-variables (theme &rest args)
1146   "Reset some variable settings in THEME to their values in other themes.
1147 Each of the arguments ARGS has this form:
1148
1149     (VARIABLE IGNORED)
1150
1151 This means reset VARIABLE.  (The argument IGNORED is ignored)."
1152   (custom-check-theme theme)
1153   (dolist (arg args)
1154     (custom-push-theme 'theme-value (car arg) theme 'reset)))
1155
1156 (defun custom-reset-variables (&rest args)
1157   "Reset the specs of some variables to their values in other themes.
1158 This creates settings in the `user' theme.
1159
1160 Each of the arguments ARGS has this form:
1161
1162     (VARIABLE IGNORED)
1163
1164 This means reset VARIABLE.  (The argument IGNORED is ignored)."
1165     (apply 'custom-theme-reset-variables 'user args))
1166
1167 ;;; The End.
1168
1169 ;; Process the defcustoms for variables loaded before this file.
1170 (while custom-declare-variable-list
1171   (apply 'custom-declare-variable (car custom-declare-variable-list))
1172   (setq custom-declare-variable-list (cdr custom-declare-variable-list)))
1173
1174 (provide 'custom)
1175
1176 ;; arch-tag: 041b6116-aabe-4f9a-902d-74092bc3dab2
1177 ;;; custom.el ends here