configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 24.4.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl We get MINGW64 with MSYS2
  29 if test "x$MSYSTEM" = "xMINGW32" -o "x$MSYSTEM" = "xMINGW64"
  30 then
  31   . $srcdir/nt/mingw-cfg.site
  32
  33   case $srcdir in
  34     /* | ?:*)
  35       # srcdir is an absolute path.  In this case, force the format
  36       # "/c/foo/bar", to simplify later conversions to native Windows
  37       # format ("c:/foo/bar")
  38       srcdir=`cd "${srcdir}" && pwd -W`
  39       srcdir="/${srcdir:0:1}${srcdir:2}"
  40       ;;
  41   esac
  42 fi
  43
  44 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  45 dnl and then quoted again for a C string.  Separate options with spaces.
  46 dnl Add some environment variables, if they were passed via the environment
  47 dnl rather than on the command-line.
  48 emacs_config_options=
  49 optsep=
  50 dnl This is the documented way to record the args passed to configure,
  51 dnl rather than $ac_configure_args.
  52 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  53   case $opt in
  54     -n | --no-create | --no-recursion)
  55       continue ;;
  56     CFLAGS | CPPFLAGS | LDFLAGS)
  57       eval 'test "${'$opt'+set}" = set' || continue
  58       case " $*" in
  59         *" $opt="*) continue ;;
  60       esac
  61       eval opt=$opt=\$$opt ;;
  62   esac
  63
  64   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  65   case $opt in
  66     *[["$emacs_shell_specials"]]*)
  67       case $opt in
  68         *\'*)
  69           emacs_quote_apostrophes="s/'/'\\\\''/g"
  70           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  71       esac
  72       opt="'$opt'"
  73       case $opt in
  74         *[['"\\']]*)
  75           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  76           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  77       esac ;;
  78   esac
  79   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  80   optsep=' '
  81 done
  82
  83 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  84 AC_CONFIG_SRCDIR(src/lisp.h)
  85 AC_CONFIG_AUX_DIR(build-aux)
  86 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  87 dnl With older versions this is a no-op.
  88 AC_CONFIG_MACRO_DIR(m4)
  89
  90 xcsdkdir=
  91 AC_CHECK_PROGS(XCRUN, [xcrun])
  92 if test -n "$XCRUN"; then
  93   if test -z "$MAKE"; then
  94     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  95     dnl SET_MAKE and with the usual MAKE variable that 'make' itself uses.
  96     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  97     if test -z "$MAKE_PROG"; then
  98       MAKE="$XCRUN MAKE"
  99       export MAKE
 100       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
 101     fi
 102   fi
 103 fi
 104
 105 dnl Fairly arbitrary, older versions might work too.
 106 AM_INIT_AUTOMAKE(1.11)
 107
 108 dnl Support for --program-prefix, --program-suffix and
 109 dnl --program-transform-name options
 110 AC_ARG_PROGRAM
 111
 112 dnl It is important that variables on the RHS not be expanded here,
 113 dnl hence the single quotes.  This is per the GNU coding standards, see
 114 dnl (autoconf) Installation Directory Variables
 115 dnl See also epaths.h below.
 116 lispdir='${datadir}/emacs/${version}/lisp'
 117 standardlisppath='${lispdir}'
 118 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 119 '${datadir}/emacs/site-lisp'
 120 lisppath='${locallisppath}:${standardlisppath}'
 121 etcdir='${datadir}/emacs/${version}/etc'
 122 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 123 etcdocdir='${datadir}/emacs/${version}/etc'
 124 gamedir='${localstatedir}/games/emacs'
 125
 126 dnl Special option to disable the most of other options.
 127 AC_ARG_WITH(all,
 128 [AS_HELP_STRING([--without-all],
 129                 [omit almost all features and build
 130                 small executable with minimal dependencies])],
 131   [with_features=$withval],
 132   [with_features=yes])
 133
 134 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 135 dnl Create a new --with option that defaults to being disabled.
 136 dnl NAME is the base name of the option.  The shell variable with_NAME
 137 dnl   will be set to either the user's value (if the option is
 138 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 139 dnl   option is not specified).  Note that the shell variable name is
 140 dnl   constructed as autoconf does, by replacing non-alphanumeric
 141 dnl   characters with "_".
 142 dnl HELP-STRING is the help text for the option.
 143 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 144   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 145     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 146 ])dnl
 147
 148 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 149 dnl Create a new --with option that defaults to $with_features.
 150 dnl NAME is the base name of the option.  The shell variable with_NAME
 151 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 152 dnl   'yes' (if the option is not specified).  Note that the shell
 153 dnl   variable name is constructed as autoconf does, by replacing
 154 dnl   non-alphanumeric characters with "_".
 155 dnl HELP-STRING is the help text for the option.
 156 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 157   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 158    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 159 ])dnl
 160
 161 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 162 if test "$with_pop" = yes; then
 163    AC_DEFINE(MAIL_USE_POP)
 164 fi
 165 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 166
 167 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 168 if test "$with_kerberos" != no; then
 169    AC_DEFINE(KERBEROS)
 170 fi
 171 AH_TEMPLATE(KERBEROS,
 172             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 173
 174 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 175 if test "${with_kerberos5}" != no; then
 176   if test "${with_kerberos}" = no; then
 177     with_kerberos=yes
 178     AC_DEFINE(KERBEROS)
 179   fi
 180   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 181 fi
 182
 183 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 184 dnl FIXME hesiod support may not be present, so it seems like an error
 185 dnl to define, or at least use, this unconditionally.
 186 if test "$with_hesiod" != no; then
 187   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 188 fi
 189
 190 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 191 if test "$with_mmdf" != no; then
 192    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 193 fi
 194
 195 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 196 if test "$with_mail_unlink" != no; then
 197    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 198 fi
 199
 200 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 201     [string giving default POP mail host])],
 202     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 203
 204 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 205   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 206 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 207   [ case "${withval}" in
 208       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 209       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 210 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 211       ;;
 212     esac
 213     with_sound=$val
 214   ],
 215   [with_sound=$with_features])
 216
 217 dnl FIXME currently it is not the last.
 218 dnl This should be the last --with option, because --with-x is
 219 dnl added later on when we find the file name of X, and it's best to
 220 dnl keep them together visually.
 221 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 222  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 223 [         case "${withval}" in
 224             y | ye | yes )      val=gtk ;;
 225             n | no )            val=no  ;;
 226             l | lu | luc | luci | lucid )       val=lucid ;;
 227             a | at | ath | athe | athen | athena )      val=athena ;;
 228             m | mo | mot | moti | motif )       val=motif ;;
 229             g | gt | gtk  )     val=gtk ;;
 230             gtk2  )     val=gtk2 ;;
 231             gtk3  )     val=gtk3 ;;
 232             * )
 233 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 234 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 235 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 236 `athena' and `lucid' are synonyms.])
 237             ;;
 238           esac
 239           with_x_toolkit=$val
 240 ])
 241
 242 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 243 if test "$with_wide_int" = yes; then
 244   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 245 fi
 246
 247 dnl _ON results in a '--without' option in the --help output, so
 248 dnl the help text should refer to "don't compile", etc.
 249 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 250 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 251 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 252 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 253 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 254 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 255 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 256 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 257
 258 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 259 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 260 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 261
 262 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 263 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 264 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 265 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 266 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 267
 268 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 269 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 270 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 271 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 272 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 273 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 274 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 275
 276 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 277  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 278  [ case "${withval}" in
 279     y | ye | yes )      val=yes ;;
 280     n | no )            val=no  ;;
 281     g | gf | gfi | gfil | gfile )       val=gfile ;;
 282     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 283     w | w3 | w32 )      val=w32 ;;
 284     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 285 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 286 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 287 otherwise for the first of `gfile' or `inotify' that is usable.])
 288     ;;
 289    esac
 290    with_file_notification=$val
 291  ],
 292  [with_file_notification=$with_features])
 293
 294 ## For the times when you want to build Emacs but don't have
 295 ## a suitable makeinfo, and can live without the manuals.
 296 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 297 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 298
 299 ## This might be a 'configure' arg, e.g., autogen.sh might set it.
 300 AC_SUBST([ACLOCAL_PATH])
 301
 302 ## Makefile.in needs the cache file name.
 303 AC_SUBST(cache_file)
 304
 305 ## This is an option because I do not know if all info/man support
 306 ## compressed files, nor how to test if they do so.
 307 OPTION_DEFAULT_ON([compress-install],
 308   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 309 make GZIP_PROG= install])
 310
 311 AC_ARG_WITH(gameuser,dnl
 312 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 313 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 314   && gameuser="${with_gameuser}"
 315 test "X$gameuser" = X && gameuser=games
 316
 317 AC_ARG_WITH([gnustep-conf],dnl
 318 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 319    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 320 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 321   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 322 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 323      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 324
 325 AC_ARG_ENABLE(ns-self-contained,
 326 [AS_HELP_STRING([--disable-ns-self-contained],
 327                 [disable self contained build under NeXTstep])],
 328    EN_NS_SELF_CONTAINED=$enableval,
 329    EN_NS_SELF_CONTAINED=yes)
 330
 331 AC_ARG_ENABLE(locallisppath,
 332 [AS_HELP_STRING([--enable-locallisppath=PATH],
 333                 [directories Emacs should search for lisp files specific
 334                  to this site])],
 335 if test "${enableval}" = "no"; then
 336   locallisppath=
 337 elif test "${enableval}" != "yes"; then
 338   locallisppath=${enableval}
 339 fi)
 340
 341 AC_ARG_ENABLE(checking,
 342 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 343                 [enable expensive run-time checks.  With LIST,
 344                  enable only specific categories of checks.
 345                  Categories are: all,yes,no.
 346                  Flags are: stringbytes, stringoverrun, stringfreelist,
 347                  xmallocoverrun, conslist, glyphs])],
 348 [ac_checking_flags="${enableval}"],[])
 349 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 350 for check in $ac_checking_flags
 351 do
 352         case $check in
 353         # these set all the flags to specific states
 354         yes)            ac_enable_checking=1 ;;
 355         no)             ac_enable_checking= ;
 356                         ac_gc_check_stringbytes= ;
 357                         ac_gc_check_string_overrun= ;
 358                         ac_gc_check_string_free_list= ;
 359                         ac_xmalloc_overrun= ;
 360                         ac_gc_check_cons_list= ;
 361                         ac_glyphs_debug= ;;
 362         all)            ac_enable_checking=1 ;
 363                         ac_gc_check_stringbytes=1 ;
 364                         ac_gc_check_string_overrun=1 ;
 365                         ac_gc_check_string_free_list=1 ;
 366                         ac_xmalloc_overrun=1 ;
 367                         ac_gc_check_cons_list=1 ;
 368                         ac_glyphs_debug=1 ;;
 369         # these enable particular checks
 370         stringbytes)    ac_gc_check_stringbytes=1 ;;
 371         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 372         stringfreelist) ac_gc_check_string_free_list=1 ;;
 373         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 374         conslist)       ac_gc_check_cons_list=1 ;;
 375         glyphs)         ac_glyphs_debug=1 ;;
 376         *)      AC_MSG_ERROR(unknown check category $check) ;;
 377         esac
 378 done
 379 IFS="$ac_save_IFS"
 380
 381 if test x$ac_enable_checking != x ; then
 382   AC_DEFINE(ENABLE_CHECKING, 1,
 383 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 384 fi
 385 if test x$ac_gc_check_stringbytes != x ; then
 386   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 387 [Define this temporarily to hunt a bug.  If defined, the size of
 388    strings is redundantly recorded in sdata structures so that it can
 389    be compared to the sizes recorded in Lisp strings.])
 390 fi
 391 if test x$ac_gc_check_string_overrun != x ; then
 392   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 393 [Define this to check for short string overrun.])
 394 fi
 395 if test x$ac_gc_check_string_free_list != x ; then
 396   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 397 [Define this to check the string free list.])
 398 fi
 399 if test x$ac_xmalloc_overrun != x ; then
 400   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 401 [Define this to check for malloc buffer overrun.])
 402 fi
 403 if test x$ac_gc_check_cons_list != x ; then
 404   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 405 [Define this to check for errors in cons list.])
 406 fi
 407 if test x$ac_glyphs_debug != x ; then
 408   AC_DEFINE(GLYPH_DEBUG, 1,
 409 [Define this to enable glyphs debugging code.])
 410 fi
 411
 412 AC_ARG_ENABLE(check-lisp-object-type,
 413 [AS_HELP_STRING([--enable-check-lisp-object-type],
 414                 [enable compile time checks for the Lisp_Object data type.
 415                 This is useful for development for catching certain types of bugs.])],
 416 if test "${enableval}" != "no"; then
 417    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 418    [Define this to enable compile time checks for the Lisp_Object data type.])
 419 fi)
 420
 421
 422 dnl The name of this option is unfortunate.  It predates, and has no
 423 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 424 dnl Actually, it stops it working.
 425 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 426 AC_ARG_ENABLE(profiling,
 427 [AS_HELP_STRING([--enable-profiling],
 428                 [build emacs with low-level, gprof profiling support.
 429                 Mainly useful for debugging Emacs itself.  May not work on
 430                 all platforms.  Stops profiler.el working.])],
 431 [ac_enable_profiling="${enableval}"],[])
 432 if test x$ac_enable_profiling != x ; then
 433    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 434 else
 435    PROFILING_CFLAGS=
 436 fi
 437 AC_SUBST(PROFILING_CFLAGS)
 438
 439 AC_ARG_ENABLE(autodepend,
 440 [AS_HELP_STRING([--enable-autodepend],
 441                 [automatically generate dependencies to .h-files.
 442                  Requires gcc, enabled if found.])],
 443 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 444
 445 AC_ARG_ENABLE(gtk-deprecation-warnings,
 446 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 447                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 448 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 449
 450 ### Canonicalize the configuration name.
 451
 452 AC_CANONICAL_HOST
 453 canonical=$host
 454 configuration=${host_alias-${build_alias-$host}}
 455
 456 dnl This used to use changequote, but, apart from `changequote is evil'
 457 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 458 dnl the great gob of text.  Thus it's not processed for possible expansion.
 459 dnl Just make sure the brackets remain balanced.
 460 dnl
 461 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 462 dnl indicated by comments.
 463 dnl quotation begins
 464 [
 465
 466 ### If you add support for a new configuration, add code to this
 467 ### switch statement to recognize your configuration name and select
 468 ### the appropriate opsys.
 469
 470 ### As far as handling version numbers on operating systems is
 471 ### concerned, make sure things will fail in a fixable way.  If
 472 ### /etc/MACHINES doesn't say anything about version numbers, be
 473 ### prepared to handle anything reasonably.  If version numbers
 474 ### matter, be sure /etc/MACHINES says something about it.
 475
 476 opsys='' unported=no
 477 case "${canonical}" in
 478
 479   ## GNU/Linux and similar ports
 480   *-*-linux* )
 481     opsys=gnu-linux
 482   ;;
 483
 484   ## FreeBSD ports
 485   *-*-freebsd* )
 486     opsys=freebsd
 487   ;;
 488
 489   ## DragonFly ports
 490   *-*-dragonfly* )
 491     opsys=dragonfly
 492   ;;
 493
 494   ## FreeBSD kernel + glibc based userland
 495   *-*-kfreebsd*gnu* )
 496     opsys=gnu-kfreebsd
 497   ;;
 498
 499   ## NetBSD ports
 500   *-*-netbsd* )
 501     opsys=netbsd
 502   ;;
 503
 504   ## OpenBSD ports
 505   *-*-openbsd* | *-*-mirbsd* )
 506     opsys=openbsd
 507   ;;
 508
 509   ## Apple Darwin / Mac OS X
 510   *-apple-darwin* )
 511     case "${canonical}" in
 512       i[3456]86-* )  ;;
 513       powerpc-* )    ;;
 514       x86_64-* )     ;;
 515       * )            unported=yes ;;
 516     esac
 517     opsys=darwin
 518     ## Use fink packages if available.
 519     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 520 ##    if test -d /sw/include && test -d /sw/lib; then
 521 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 522 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 523 ##    fi
 524   ;;
 525
 526   ## Cygwin ports
 527   *-*-cygwin )
 528     opsys=cygwin
 529   ;;
 530
 531   ## HP 9000 series 700 and 800, running HP/UX
 532   hppa*-hp-hpux10.2* )
 533     opsys=hpux10-20
 534   ;;
 535   hppa*-hp-hpux1[1-9]* )
 536     opsys=hpux11
 537     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 538   ;;
 539
 540   ## IBM machines
 541   rs6000-ibm-aix4.[23]* )
 542     opsys=aix4-2
 543   ;;
 544   powerpc-ibm-aix4.[23]*  )
 545     opsys=aix4-2
 546   ;;
 547   rs6000-ibm-aix[56]* )
 548     opsys=aix4-2
 549   ;;
 550   powerpc-ibm-aix[56]*  )
 551     opsys=aix4-2
 552   ;;
 553
 554   ## Silicon Graphics machines
 555   ## Iris 4D
 556   mips-sgi-irix6.5 )
 557     opsys=irix6-5
 558     # Without defining _LANGUAGE_C, things get masked out in the headers
 559     # so that, for instance, grepping for `free' in stdlib.h fails and
 560     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 561     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 562   ;;
 563
 564   ## Suns
 565   *-sun-solaris* \
 566     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 567     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 568     case "${canonical}" in
 569       i[3456]86-*-* )   ;;
 570       amd64-*-*|x86_64-*-*) ;;
 571       sparc* )          ;;
 572       * )               unported=yes ;;
 573     esac
 574     case "${canonical}" in
 575       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 576                 opsys=sol2-10
 577                 emacs_check_sunpro_c=yes
 578                 ;;
 579       *-sunos5.6* | *-solaris2.6* )
 580                 opsys=sol2-6
 581                 RANLIB="ar -ts"
 582                 ;;
 583       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 584                 opsys=sol2-6
 585                 emacs_check_sunpro_c=yes
 586                 ;;
 587     esac
 588     ## Watch out for a compiler that we know will not work.
 589     case "${canonical}" in
 590      *-solaris* | *-sunos5* )
 591                 if [ "x$CC" = x/usr/ucb/cc ]; then
 592                   ## /usr/ucb/cc doesn't work;
 593                   ## we should find some other compiler that does work.
 594                   unset CC
 595                 fi
 596                 ;;
 597       *) ;;
 598     esac
 599   ;;
 600
 601   ## Intel 386 machines where we don't care about the manufacturer.
 602   i[3456]86-*-* )
 603     case "${canonical}" in
 604       *-darwin* )               opsys=darwin ;;
 605       *-mingw32 )
 606                 opsys=mingw32
 607                 # MinGW overrides and adds some system headers in nt/inc.
 608                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 609                 ;;
 610       *-sysv4.2uw* )            opsys=unixware ;;
 611       *-sysv5uw* )              opsys=unixware ;;
 612       *-sysv5OpenUNIX* )        opsys=unixware ;;
 613       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 614     esac
 615   ;;
 616
 617   # MinGW64
 618   x86_64-*-* )
 619     case "${canonical}" in
 620       *-mingw32 )
 621                 opsys=mingw32
 622                 # MinGW overrides and adds some system headers in nt/inc.
 623                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 624                 ;;
 625       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 626     esac
 627   ;;
 628
 629   * )
 630     unported=yes
 631   ;;
 632 esac
 633
 634 ### If the code above didn't choose an operating system, just choose
 635 ### an operating system based on the configuration name.  You really
 636 ### only want to use this when you have no idea what the right
 637 ### operating system is; if you know what operating systems a machine
 638 ### runs, it's cleaner to make it explicit in the case statement
 639 ### above.
 640 if test x"${opsys}" = x; then
 641   case "${canonical}" in
 642     *-gnu* )                            opsys=gnu ;;
 643     * )
 644       unported=yes
 645     ;;
 646   esac
 647 fi
 648
 649 ]
 650 dnl quotation ends
 651
 652 if test $unported = yes; then
 653   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 654 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 655 Check `etc/MACHINES' for recognized configuration names.])
 656 fi
 657
 658
 659 AC_MSG_CHECKING([whether we are using GNU Make])
 660 testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
 661 if test "x$testval" != x; then
 662   AC_MSG_RESULT([yes])
 663 else
 664   AC_MSG_RESULT([no])
 665   AC_MSG_ERROR([Building Emacs requires GNU make.
 666 If you have it installed under another name, configure with 'MAKE=...'.
 667 For example, run './configure MAKE=gmake'.])
 668 fi
 669
 670
 671 #### Choose a compiler.
 672
 673 dnl Sets GCC=yes if using gcc.
 674 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 675 if test -n "$XCRUN"; then
 676   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 677   test -n "$AR" && export AR
 678 fi
 679
 680 AM_PROG_CC_C_O
 681
 682 if test x$GCC = xyes; then
 683   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 684 else
 685   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 686 fi
 687
 688 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 689 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 690 dnl that clash with MinGW.
 691 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 692
 693 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 694 AC_DEFUN([gl_CRYPTO_CHECK])
 695 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 696 # as we don't use them.
 697 AC_DEFUN([gl_FCNTL_O_FLAGS])
 698 # Avoid gnulib's threadlib module, as we do threads our own way.
 699 AC_DEFUN([gl_THREADLIB])
 700
 701 # Initialize gnulib right after choosing the compiler.
 702 dnl Amongst other things, this sets AR and ARFLAGS.
 703 gl_EARLY
 704
 705 if test "$ac_test_CFLAGS" != set; then
 706   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 707   # if -g3 works and the user does not specify CFLAGS.
 708   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 709   case $CFLAGS in
 710     '-g')
 711       emacs_g3_CFLAGS='-g3';;
 712     '-g -O2')
 713       emacs_g3_CFLAGS='-g3 -O2';;
 714     *)
 715       emacs_g3_CFLAGS='';;
 716   esac
 717   if test -n "$emacs_g3_CFLAGS"; then
 718     emacs_save_CFLAGS=$CFLAGS
 719     CFLAGS=$emacs_g3_CFLAGS
 720     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 721       [emacs_cv_prog_cc_g3],
 722       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 723          [emacs_cv_prog_cc_g3=yes],
 724          [emacs_cv_prog_cc_g3=no])])
 725     if test $emacs_cv_prog_cc_g3 != yes; then
 726       CFLAGS=$emacs_save_CFLAGS
 727     fi
 728     if test $opsys = mingw32; then
 729       CFLAGS="$CFLAGS -gdwarf-2"
 730     fi
 731   fi
 732
 733   case $CFLAGS in
 734     *-O*) ;;
 735     *)
 736       # No optimization flag was inferred for this non-GCC compiler.
 737       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 738       emacs_save_CFLAGS=$CFLAGS
 739       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 740       CFLAGS=${CFLAGS}-O
 741       AC_CACHE_CHECK([whether $CC accepts -O],
 742         [emacs_cv_prog_cc_o],
 743         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 744            [emacs_cv_prog_cc_o=yes],
 745            [emacs_cv_prog_cc_o=no])])
 746       if test $emacs_cv_prog_cc_o != yes; then
 747         CFLAGS=$emacs_save_CFLAGS
 748       fi ;;
 749   esac
 750 fi
 751
 752 AC_ARG_ENABLE([gcc-warnings],
 753   [AS_HELP_STRING([--enable-gcc-warnings],
 754                   [turn on lots of GCC warnings/errors. This is intended for
 755                    developers, and may generate false alarms when used
 756                    with older or non-GNU development tools.])],
 757   [case $enableval in
 758      yes|no) ;;
 759      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 760    esac
 761    gl_gcc_warnings=$enableval],
 762   [gl_gcc_warnings=no]
 763 )
 764
 765 AC_ARG_ENABLE(link-time-optimization,
 766 [AS_HELP_STRING([--enable-link-time-optimization],
 767                 [build emacs with link-time optimization.
 768                  This is supported only for GCC since 4.5.0.])],
 769 if test "${enableval}" != "no"; then
 770    AC_MSG_CHECKING([whether link-time optimization is supported])
 771    ac_lto_supported=no
 772    if test x$GCC = xyes; then
 773       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 774       if test x$CPUS != x; then
 775          LTO="-flto=$CPUS"
 776       else
 777          LTO="-flto"
 778       fi
 779       old_CFLAGS=$CFLAGS
 780       CFLAGS="$CFLAGS $LTO"
 781       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 782         [ac_lto_supported=yes], [ac_lto_supported=no])
 783       CFLAGS="$old_CFLAGS"
 784    fi
 785    AC_MSG_RESULT([$ac_lto_supported])
 786    if test "$ac_lto_supported" = "yes"; then
 787       CFLAGS="$CFLAGS $LTO"
 788    fi
 789 fi)
 790
 791 # clang is unduly picky about some things.
 792 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 793   [AC_COMPILE_IFELSE(
 794      [AC_LANG_PROGRAM([[
 795           #ifndef __clang__
 796             error "not clang";
 797           #endif
 798         ]])],
 799      [emacs_cv_clang=yes],
 800      [emacs_cv_clang=no])])
 801
 802 # When compiling with GCC, prefer -isystem to -I when including system
 803 # include files, to avoid generating useless diagnostics for the files.
 804 if test "$gl_gcc_warnings" != yes; then
 805   isystem='-I'
 806   if test "$emacs_cv_clang" = yes
 807   then
 808      # Turn off some warnings if supported.
 809      gl_WARN_ADD([-Wno-switch])
 810      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 811      gl_WARN_ADD([-Wno-pointer-sign])
 812   fi
 813 else
 814   isystem='-isystem '
 815
 816   # This, $nw, is the list of warnings we disable.
 817   nw=
 818
 819   case $with_x_toolkit in
 820     lucid | athena | motif)
 821        # Old toolkits mishandle 'const'.
 822        nw="$nw -Wwrite-strings"
 823        ;;
 824     *)
 825        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 826        ;;
 827   esac
 828   AC_SUBST([WERROR_CFLAGS])
 829
 830   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 831   nw="$nw -Woverlength-strings"     # Not a problem these days
 832   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 833   nw="$nw -Wformat-nonliteral"      # we do this a lot
 834   nw="$nw -Wvla"                    # warnings in gettext.h
 835   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 836   nw="$nw -Wswitch-default"         # Too many warnings for now
 837   nw="$nw -Winline"                 # OK to ignore 'inline'
 838   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 839   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 840                                     # signed overflow has undefined behavior
 841   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 842   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 843   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 844
 845   # Emacs doesn't care about shadowing; see
 846   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 847   nw="$nw -Wshadow"
 848
 849   # Emacs's use of alloca inhibits protecting the stack.
 850   nw="$nw -Wstack-protector"
 851
 852   # The following line should be removable at some point.
 853   nw="$nw -Wsuggest-attribute=pure"
 854
 855   # This part is merely for shortening the command line,
 856   # since -Wno-FOO needs to be added below regardless.
 857   nw="$nw -Wmissing-field-initializers"
 858   nw="$nw -Wswitch"
 859   nw="$nw -Wtype-limits"
 860   nw="$nw -Wunused-parameter"
 861
 862   if test $emacs_cv_clang = yes; then
 863     nw="$nw -Wcast-align"
 864   fi
 865
 866   gl_MANYWARN_ALL_GCC([ws])
 867   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 868   for w in $ws; do
 869     gl_WARN_ADD([$w])
 870   done
 871   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 872   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 873   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 874   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 875   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 876   gl_WARN_ADD([-Wno-format-nonliteral])
 877
 878   # In spite of excluding -Wlogical-op above, it is enabled, as of
 879   # gcc 4.5.0 20090517.
 880   gl_WARN_ADD([-Wno-logical-op])
 881
 882   # More things that clang is unduly picky about.
 883   if test $emacs_cv_clang = yes; then
 884     gl_WARN_ADD([-Wno-format-extra-args])
 885     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 886     gl_WARN_ADD([-Wno-unused-command-line-argument])
 887     gl_WARN_ADD([-Wno-unused-value])
 888   fi
 889
 890   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 891   AH_VERBATIM([FORTIFY_SOURCE],
 892   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 893       without upsetting glibc 2.15+. */
 894    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 895    # define _FORTIFY_SOURCE 2
 896    #endif
 897   ])
 898   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 899
 900   # We use a slightly smaller set of warning options for lib/.
 901   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 902   nw=
 903   nw="$nw -Wunused-macros"
 904
 905   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 906   AC_SUBST([GNULIB_WARN_CFLAGS])
 907 fi
 908
 909 edit_cflags="
 910   s,///*,/,g
 911   s/^/ /
 912   s/ -I/ $isystem/g
 913   s/^ //
 914 "
 915
 916
 917
 918 dnl Some other nice autoconf tests.
 919 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 920 dnl AC_PROG_INSTALL
 921 dnl AC_PROG_MKDIR_P
 922 dnl if test "x$RANLIB" = x; then
 923 dnl   AC_PROG_RANLIB
 924 dnl fi
 925
 926
 927 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 928 dnl can be made to directories.  This is not relevant for our usage, and
 929 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 930 dnl hosted on AFS, both examples where simple links work, but links to
 931 dnl directories fail.  We use a cut-down version instead.
 932 dnl AC_PROG_LN_S
 933
 934 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 935 rm -f conf$$ conf$$.file
 936
 937 LN_S_FILEONLY='cp -p'
 938
 939 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
 940 dnl random program in the current directory.
 941 if (echo >conf$$.file) 2>/dev/null; then
 942   if ln -s conf$$.file conf$$ 2>/dev/null; then
 943     if test "$opsys" = "mingw32"; then
 944       LN_S_FILEONLY='/bin/ln -s'
 945     else
 946       LN_S_FILEONLY='ln -s'
 947     fi
 948   elif ln conf$$.file conf$$ 2>/dev/null; then
 949     if test "$opsys" = "mingw32"; then
 950       LN_S_FILEONLY=/bin/ln
 951     else
 952       LN_S_FILEONLY=ln
 953     fi
 954   fi
 955 fi
 956
 957 rm -f conf$$ conf$$.file
 958
 959 if test "$LN_S_FILEONLY" = "ln -s"; then
 960    AC_MSG_RESULT([yes])
 961 else
 962    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 963 fi
 964
 965 AC_SUBST(LN_S_FILEONLY)
 966
 967
 968 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 969 dnl doesn't support links to directories, as in "ln file dir".  But that
 970 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 971 dnl executables at "make install" time.
 972 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 973 dnl for more details.
 974 if test "$opsys" = "mingw32"; then
 975   LN_S="/bin/ln"
 976 fi
 977
 978 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 979   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 980 dnl Don't use GZIP, which is used by gzip for additional parameters.
 981 AC_PATH_PROG(GZIP_PROG, gzip)
 982
 983 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
 984    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
 985
 986 if test $opsys = gnu-linux; then
 987   AC_PATH_PROG(PAXCTL, paxctl,,
 988     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 989   if test "X$PAXCTL" != X; then
 990     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 991     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 992       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 993       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 994   fi
 995
 996   if test "${SETFATTR+set}" != set; then
 997     AC_CACHE_CHECK([for setfattr],
 998       [emacs_cv_prog_setfattr],
 999       [touch conftest.tmp
1000        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1001          emacs_cv_prog_setfattr=yes
1002        else
1003          emacs_cv_prog_setfattr=no
1004        fi])
1005     if test "$emacs_cv_prog_setfattr" = yes; then
1006       SETFATTR=setfattr
1007     else
1008       SETFATTR=
1009     fi
1010     rm -f conftest.tmp
1011     AC_SUBST([SETFATTR])
1012   fi
1013 fi
1014
1015 ## Need makeinfo >= 4.7 (?) to build the manuals.
1016 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1017 dnl By this stage, configure has already checked for egrep and set EGREP,
1018 dnl or exited with an error if no egrep was found.
1019 if test "$MAKEINFO" != "no"; then
1020   case `
1021     $MAKEINFO --version 2> /dev/null |
1022     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1023   ` in
1024     '') MAKEINFO=no;;
1025   esac
1026 fi
1027
1028 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1029 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1030 ## therefore in the category of "special tools" not normally required, which
1031 ## configure does not have to check for (eg autoconf itself).
1032 ## In a repository checkout on the other hand, the manuals are not included.
1033 ## So makeinfo is a requirement to build from the repository, and configure
1034 ## should test for it as it does for any other build requirement.
1035 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1036 ## with pre-built manuals, from a repository checkout.
1037 HAVE_MAKEINFO=yes
1038
1039 if test "$MAKEINFO" = "no"; then
1040   MAKEINFO=makeinfo
1041   if test "x${with_makeinfo}" = "xno"; then
1042     HAVE_MAKEINFO=no
1043   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1044     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1045 source tree does not seem to have pre-built manuals in the `info' directory.
1046 Either install a suitable version of makeinfo, or re-run configure
1047 with the `--without-makeinfo' option to build without the manuals.] )
1048   fi
1049 fi
1050 AC_SUBST(HAVE_MAKEINFO)
1051
1052 dnl Just so that there is only a single place we need to edit.
1053 INFO_EXT=.info
1054 INFO_OPTS=--no-split
1055 AC_SUBST(INFO_EXT)
1056 AC_SUBST(INFO_OPTS)
1057
1058 if test $opsys = mingw32; then
1059    DOCMISC_W32=efaq-w32
1060 else
1061    DOCMISC_W32=
1062 fi
1063 AC_SUBST(DOCMISC_W32)
1064
1065 dnl Add our options to ac_link now, after it is set up.
1066
1067 if test x$GCC = xyes; then
1068   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1069     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1070 else
1071   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1072     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1073 fi
1074
1075 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1076 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1077 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1078 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1079 dnl if not built to support GNU ld.
1080
1081 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1082 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1083 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1084 dnl   Eg "make LDFLAGS=... all" could run into problems,
1085 dnl   http://bugs.debian.org/684788
1086 dnl * unnecessary, since temacs is the only thing that actually needs it.
1087 dnl   Indeed this is where it was originally, prior to:
1088 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1089 late_LDFLAGS="$LDFLAGS"
1090 if test x$GCC = xyes; then
1091   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1092 else
1093   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1094 fi
1095
1096 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1097
1098 AC_MSG_CHECKING([for -znocombreloc])
1099 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1100   [AC_MSG_RESULT(yes)],
1101   LDFLAGS_NOCOMBRELOC=
1102   [AC_MSG_RESULT(no)])
1103
1104 LDFLAGS="$late_LDFLAGS"
1105
1106 AC_CACHE_CHECK([whether addresses are sanitized],
1107   [emacs_cv_sanitize_address],
1108   [AC_COMPILE_IFELSE(
1109      [AC_LANG_PROGRAM(
1110         [[#ifndef __has_feature
1111           #define __has_feature(f) 0
1112           #endif
1113           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1114           #else
1115            error "Addresses are not sanitized.";
1116           #endif
1117         ]])],
1118      [emacs_cv_sanitize_address=yes],
1119      [emacs_cv_sanitize_address=no])])
1120
1121 dnl The function dump-emacs will not be defined and temacs will do
1122 dnl (load "loadup") automatically unless told otherwise.
1123 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1124 case "$opsys" in
1125   your-opsys-here) CANNOT_DUMP=yes ;;
1126 esac
1127
1128 if test "$CANNOT_DUMP" = "yes"; then
1129   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1130 elif test "$emacs_cv_sanitize_address" = yes; then
1131   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1132 fi
1133
1134 AC_SUBST(CANNOT_DUMP)
1135
1136
1137 UNEXEC_OBJ=unexelf.o
1138 case "$opsys" in
1139   # MSDOS uses unexcoff.o
1140   aix4-2)
1141    UNEXEC_OBJ=unexaix.o
1142    ;;
1143   cygwin)
1144    UNEXEC_OBJ=unexcw.o
1145    ;;
1146   darwin)
1147    UNEXEC_OBJ=unexmacosx.o
1148    ;;
1149   hpux10-20 | hpux11)
1150    UNEXEC_OBJ=unexhp9k800.o
1151    ;;
1152   mingw32)
1153    UNEXEC_OBJ=unexw32.o
1154    ;;
1155   sol2-10)
1156    # Use the Solaris dldump() function, called from unexsol.c, to dump
1157    # emacs, instead of the generic ELF dump code found in unexelf.c.
1158    # The resulting binary has a complete symbol table, and is better
1159    # for debugging and other observability tools (debuggers, pstack, etc).
1160    #
1161    # If you encounter a problem using dldump(), please consider sending
1162    # a message to the OpenSolaris tools-linking mailing list:
1163    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1164    #
1165    # It is likely that dldump() works with older Solaris too, but this has
1166    # not been tested, so for now this change is for Solaris 10 or newer.
1167    UNEXEC_OBJ=unexsol.o
1168    ;;
1169 esac
1170
1171 LD_SWITCH_SYSTEM=
1172 case "$opsys" in
1173   freebsd|dragonfly)
1174    ## Let `ld' find image libs and similar things in /usr/local/lib.
1175    ## The system compiler, GCC, has apparently been modified to not
1176    ## look there, contrary to what a stock GCC would do.
1177 ### It's not our place to do this.  See bug#10313#17.
1178 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1179       :
1180    ;;
1181
1182   gnu-linux)
1183    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1184    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1185    ;;
1186
1187   netbsd)
1188 ### It's not our place to do this.  See bug#10313#17.
1189 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1190       :
1191    ;;
1192
1193   openbsd)
1194    ## Han Boetes <han@boetes.org> says this is necessary,
1195    ## otherwise Emacs dumps core on elf systems.
1196    LD_SWITCH_SYSTEM="-Z"
1197    ;;
1198 esac
1199 AC_SUBST(LD_SWITCH_SYSTEM)
1200
1201 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1202
1203 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1204 ## which has not been defined yet.  When this was handled with cpp,
1205 ## it was expanded to null when configure sourced the s/*.h file.
1206 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1207 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1208 ## (or somesuch), but because it is supposed to go at the _front_
1209 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1210 ## Compare with the gnu-linux case below, which added to the end
1211 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1212 ## LD_SWITCH_SYSTEM_TEMACS.
1213 case "$opsys" in
1214   netbsd|openbsd)
1215    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1216 esac
1217
1218
1219 C_SWITCH_MACHINE=
1220 case $canonical in
1221  alpha*)
1222   AC_CHECK_DECL([__ELF__])
1223   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1224     ## With ELF, make sure that all common symbols get allocated to in the
1225     ## data section.  Otherwise, the dump of temacs may miss variables in
1226     ## the shared library that have been initialized.  For example, with
1227     ## GNU libc, __malloc_initialized would normally be resolved to the
1228     ## shared library's .bss section, which is fatal.
1229     if test "x$GCC" = "xyes"; then
1230       C_SWITCH_MACHINE="-fno-common"
1231     else
1232       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1233     fi
1234   else
1235       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1236       dnl albeit under the mistaken assumption that said file
1237       dnl was no longer used.
1238       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1239   fi
1240   ;;
1241 esac
1242 AC_SUBST(C_SWITCH_MACHINE)
1243
1244 AC_SUBST(UNEXEC_OBJ)
1245
1246 C_SWITCH_SYSTEM=
1247 ## Some programs in src produce warnings saying certain subprograms
1248 ## are too complex and need a MAXMEM value greater than 2000 for
1249 ## additional optimization.  --nils@exp-math.uni-essen.de
1250 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1251   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1252 if test "$opsys" = "mingw32"; then
1253   case "$canonical" in
1254     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1255     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1256   esac
1257 fi
1258 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1259 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1260 AC_SUBST(C_SWITCH_SYSTEM)
1261
1262
1263 LIBS_SYSTEM=
1264 case "$opsys" in
1265   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1266   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1267
1268   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1269
1270   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1271
1272   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1273
1274   ## Motif needs -lgen.
1275   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1276 esac
1277
1278 AC_SUBST(LIBS_SYSTEM)
1279
1280 ### Make sure subsequent tests use flags consistent with the build flags.
1281
1282 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1283   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1284 else
1285   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1286 fi
1287
1288 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1289 AC_DEFUN([AC_TYPE_SIZE_T])
1290 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1291 AC_DEFUN([AC_TYPE_UID_T])
1292
1293 # sqrt and other floating-point functions such as fmod and frexp
1294 # are found in -lm on many systems.
1295 OLD_LIBS=$LIBS
1296 AC_SEARCH_LIBS([sqrt], [m])
1297 if test "X$LIBS" = "X$OLD_LIBS"; then
1298   LIB_MATH=
1299 else
1300   LIB_MATH=$ac_cv_search_sqrt
1301 fi
1302 LIBS=$OLD_LIBS
1303
1304 dnl Current possibilities handled by sed (aix4-2 -> aix,
1305 dnl gnu-linux -> gnu/linux, etc.):
1306 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1307 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1308 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1309
1310 case $opsys in
1311   cygwin )
1312     LIB_MATH=
1313     ;;
1314   darwin )
1315     ## Adding -lm confuses the dynamic linker, so omit it.
1316     LIB_MATH=
1317     ;;
1318   freebsd | dragonfly )
1319     SYSTEM_TYPE=berkeley-unix
1320     ;;
1321   gnu-linux | gnu-kfreebsd )
1322     ;;
1323   hpux10-20 | hpux11 )
1324     ;;
1325   mingw32 )
1326     LIB_MATH=
1327     SYSTEM_TYPE=windows-nt
1328     ;;
1329   dnl NB this may be adjusted below.
1330   netbsd | openbsd )
1331     SYSTEM_TYPE=berkeley-unix
1332     ;;
1333
1334   sol2* | unixware )
1335     SYSTEM_TYPE=usg-unix-v
1336     ;;
1337
1338 esac
1339
1340 AC_SUBST(LIB_MATH)
1341 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1342   [The type of system you are compiling for; sets `system-type'.])
1343
1344 m4_pattern_forbid([^PKG_])
1345
1346 AC_ARG_VAR(PKG_CONFIG_PATH, [Colon-separated list of directories
1347 searched by pkg-config])
1348
1349 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1350 pre_PKG_CONFIG_LIBS=$LIBS
1351
1352 PKG_PROG_PKG_CONFIG(0.9.0)
1353
1354 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1355 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1356 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1357 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1358 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1359 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1360 dnl actions.
1361 AC_DEFUN([EMACS_CHECK_MODULES],
1362   [PKG_CHECK_MODULES([$1], [$2],
1363      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1364       m4_default([$3], [HAVE_$1=yes])],
1365      [m4_default([$4], [HAVE_$1=no])])])
1366
1367 HAVE_SOUND=no
1368 if test "${with_sound}" != "no"; then
1369   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1370   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1371     have_sound_header=yes, [], [
1372     #ifdef __MINGW32__
1373     #define WIN32_LEAN_AND_MEAN
1374     #include <windows.h>
1375     #endif
1376     ])
1377   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1378     AC_MSG_ERROR([OSS sound support requested but not found.])
1379
1380   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1381     # Emulation library used on NetBSD.
1382     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1383     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1384       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1385     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1386     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1387   fi
1388   AC_SUBST(LIBSOUND)
1389
1390   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1391     ALSA_REQUIRED=1.0.0
1392     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1393     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1394     if test $HAVE_ALSA = yes; then
1395       SAVE_CFLAGS="$CFLAGS"
1396       SAVE_LIBS="$LIBS"
1397       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1398       LIBS="$ALSA_LIBS $LIBS"
1399       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1400                       emacs_alsa_normal=yes,
1401                     emacs_alsa_normal=no)
1402       if test "$emacs_alsa_normal" != yes; then
1403         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1404                        [[snd_lib_error_set_handler (0);]])],
1405                        emacs_alsa_subdir=yes,
1406                      emacs_alsa_subdir=no)
1407         if test "$emacs_alsa_subdir" != yes; then
1408           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1409         fi
1410         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1411       fi
1412
1413       CFLAGS="$SAVE_CFLAGS"
1414       LIBS="$SAVE_LIBS"
1415       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1416       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1417       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1418     elif test "${with_sound}" = "alsa"; then
1419       AC_MSG_ERROR([ALSA sound support requested but not found.])
1420     fi
1421   fi                            dnl with_sound = alsa|yes
1422
1423   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1424   dnl compiles only on the specified platforms.  For others, it
1425   dnl probably doesn't make sense to try.
1426   dnl FIXME So surely we should bypass this whole section if not using
1427   dnl one of these platforms?
1428   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1429      case "$opsys" in
1430        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1431        dnl Adjust the --with-sound help text if you change this.
1432        gnu-linux|freebsd|netbsd|mingw32)
1433          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1434          HAVE_SOUND=yes
1435          ;;
1436      esac
1437   fi
1438
1439   AC_SUBST(CFLAGS_SOUND)
1440 fi
1441
1442 dnl checks for header files
1443 AC_CHECK_HEADERS_ONCE(
1444   sys/systeminfo.h
1445   coff.h pty.h
1446   sys/resource.h
1447   sys/utsname.h pwd.h utmp.h util.h)
1448
1449 AC_MSG_CHECKING(if personality LINUX32 can be set)
1450 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1451                emacs_cv_personality_linux32=yes,
1452                emacs_cv_personality_linux32=no)
1453 AC_MSG_RESULT($emacs_cv_personality_linux32)
1454
1455 if test $emacs_cv_personality_linux32 = yes; then
1456   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1457             [Define to 1 if personality LINUX32 can be set.])
1458 fi
1459
1460 dnl On Solaris 8 there's a compilation warning for term.h because
1461 dnl it doesn't define `bool'.
1462 AC_CHECK_HEADERS(term.h, , , -)
1463 AC_HEADER_TIME
1464 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1465                                       ]])
1466 if test $ac_cv_have_decl_sys_siglist != yes; then
1467   # For Tru64, at least:
1468   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1469                                           ]])
1470 fi
1471 AC_HEADER_SYS_WAIT
1472
1473 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1474 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1475 #if HAVE_SYS_SOCKET_H
1476 #include <sys/socket.h>
1477 #endif])
1478 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1479 #if HAVE_SYS_SOCKET_H
1480 #include <sys/socket.h>
1481 #endif])
1482 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1483 #if HAVE_SYS_SOCKET_H
1484 #include <sys/socket.h>
1485 #endif])
1486
1487 dnl checks for structure members
1488 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1489                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1490                   struct ifreq.ifr_addr,
1491                   struct ifreq.ifr_addr.sa_len], , ,
1492                  [AC_INCLUDES_DEFAULT
1493 #if HAVE_SYS_SOCKET_H
1494 #include <sys/socket.h>
1495 #endif
1496 #if HAVE_NET_IF_H
1497 #include <net/if.h>
1498 #endif])
1499
1500 dnl Check for endianness.
1501 dnl AC_C_BIGENDIAN is done by gnulib.
1502
1503 dnl check for Make feature
1504 dnl AC_PROG_MAKE_SET is done by Automake.
1505
1506 DEPFLAGS=
1507 MKDEPDIR=":"
1508 deps_frag=deps.mk
1509 dnl check if we have GCC and autodepend is on.
1510 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1511    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1512    SAVE_CFLAGS="$CFLAGS"
1513    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1514    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1515    CFLAGS="$SAVE_CFLAGS"
1516    test -f deps.d || ac_enable_autodepend=no
1517    rm -rf deps.d
1518    AC_MSG_RESULT([$ac_enable_autodepend])
1519    if test $ac_enable_autodepend = yes; then
1520       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1521       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1522       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1523       deps_frag=autodeps.mk
1524    fi
1525 fi
1526 deps_frag=$srcdir/src/$deps_frag
1527 AC_SUBST(MKDEPDIR)
1528 AC_SUBST(DEPFLAGS)
1529 AC_SUBST_FILE(deps_frag)
1530
1531
1532 lisp_frag=$srcdir/src/lisp.mk
1533 AC_SUBST_FILE(lisp_frag)
1534
1535
1536 dnl checks for operating system services
1537 AC_SYS_LONG_FILE_NAMES
1538
1539 #### Choose a window system.
1540
1541 ## We leave window_system equal to none if
1542 ## we end up building without one.  Any new window system should
1543 ## set window_system to an appropriate value and add objects to
1544 ## window-system-specific substs.
1545
1546 window_system=none
1547 AC_PATH_X
1548 if test "$no_x" != yes; then
1549   window_system=x11
1550 fi
1551
1552 LD_SWITCH_X_SITE_RPATH=
1553 if test "${x_libraries}" != NONE; then
1554   if test -n "${x_libraries}"; then
1555     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1556     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1557   fi
1558   x_default_search_path=""
1559   x_search_path=${x_libraries}
1560   if test -z "${x_search_path}"; then
1561     x_search_path=/usr/lib
1562   fi
1563   for x_library in `echo ${x_search_path}: | \
1564                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1565     x_search_path="\
1566 ${x_library}/X11/%L/%T/%N%C%S:\
1567 ${x_library}/X11/%l/%T/%N%C%S:\
1568 ${x_library}/X11/%T/%N%C%S:\
1569 ${x_library}/X11/%L/%T/%N%S:\
1570 ${x_library}/X11/%l/%T/%N%S:\
1571 ${x_library}/X11/%T/%N%S"
1572     if test x"${x_default_search_path}" = x; then
1573       x_default_search_path=${x_search_path}
1574     else
1575       x_default_search_path="${x_search_path}:${x_default_search_path}"
1576     fi
1577   done
1578 fi
1579 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1580
1581 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1582   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1583 fi
1584
1585 if test x"${x_includes}" = x; then
1586   bitmapdir=/usr/include/X11/bitmaps
1587 else
1588   # accumulate include directories that have X11 bitmap subdirectories
1589   bmd_acc="dummyval"
1590   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1591     if test -d "${bmd}/X11/bitmaps"; then
1592       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1593     fi
1594     if test -d "${bmd}/bitmaps"; then
1595       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1596     fi
1597   done
1598   if test ${bmd_acc} != "dummyval"; then
1599     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1600   fi
1601 fi
1602
1603 HAVE_NS=no
1604 NS_IMPL_COCOA=no
1605 NS_IMPL_GNUSTEP=no
1606 tmp_CPPFLAGS="$CPPFLAGS"
1607 tmp_CFLAGS="$CFLAGS"
1608 CPPFLAGS="$CPPFLAGS -x objective-c"
1609 CFLAGS="$CFLAGS -x objective-c"
1610 GNU_OBJC_CFLAGS=
1611 LIBS_GNUSTEP=
1612 if test "${with_ns}" != no; then
1613   if test "${opsys}" = darwin; then
1614      NS_IMPL_COCOA=yes
1615      ns_appdir=`pwd`/nextstep/Emacs.app
1616      ns_appbindir=${ns_appdir}/Contents/MacOS
1617      ns_appresdir=${ns_appdir}/Contents/Resources
1618      ns_appsrc=Cocoa/Emacs.base
1619   elif test -f $GNUSTEP_CONFIG_FILE; then
1620      NS_IMPL_GNUSTEP=yes
1621      ns_appdir=`pwd`/nextstep/Emacs.app
1622      ns_appbindir=${ns_appdir}
1623      ns_appresdir=${ns_appdir}/Resources
1624      ns_appsrc=GNUstep/Emacs.base
1625      dnl FIXME sourcing this several times in subshells seems inefficient.
1626      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1627      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1628      dnl I seemed to need these as well with GNUstep-startup 0.25.
1629      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1630      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1631      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1632        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1633      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1634        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1635      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1636      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1637      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1638      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1639      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1640      dnl If they had chosen to either define it or not, we could have
1641      dnl just used AC_CHECK_DECL here.
1642      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1643        emacs_cv_objc_exceptions,
1644 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1645 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1646 1;
1647 #else
1648 fail;
1649 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1650      if test $emacs_cv_objc_exceptions = yes; then
1651        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1652        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1653          [Define if GNUstep uses ObjC exceptions.])
1654        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1655      fi
1656   fi
1657
1658   dnl This is only used while we test the NS headers, it gets reset below.
1659   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1660
1661   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1662                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1663   files are missing or cannot be compiled.])])
1664
1665   macfont_file=""
1666   if test "${NS_IMPL_COCOA}" = "yes"; then
1667     AC_MSG_CHECKING([for OSX 10.4 or newer])
1668     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1669                                      [
1670 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1671 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1672  ; /* OK */
1673 #else
1674  error "OSX 10.4 or newer required";
1675 #endif
1676 #endif
1677                     ])],
1678                     ns_osx_have_104=yes,
1679                     ns_osx_have_104=no)
1680     AC_MSG_RESULT([$ns_osx_have_104])
1681
1682     if test $ns_osx_have_104 = no; then
1683        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1684     fi
1685     AC_MSG_CHECKING([for OSX 10.5 or newer])
1686     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1687                                      [
1688 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1689 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1690  ; /* OK */
1691 #else
1692  error "OSX 10.5 not found";
1693 #endif
1694 #endif
1695                     ])],
1696                     ns_osx_have_105=yes,
1697                     ns_osx_have_105=no)
1698     AC_MSG_RESULT([$ns_osx_have_105])
1699     if test $ns_osx_have_105 = yes; then
1700       macfont_file="macfont.o"
1701     fi
1702   fi
1703   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1704                                      [NSInteger i;])],
1705                     ns_have_nsinteger=yes,
1706                     ns_have_nsinteger=no)
1707   if test $ns_have_nsinteger = yes; then
1708     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1709   fi
1710 fi
1711
1712 AC_SUBST(LIBS_GNUSTEP)
1713
1714 INSTALL_ARCH_INDEP_EXTRA=install-etc
1715 ns_self_contained=no
1716 NS_OBJ=
1717 NS_OBJC_OBJ=
1718 if test "${HAVE_NS}" = yes; then
1719   if test "$with_toolkit_scroll_bars" = "no"; then
1720     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1721   fi
1722
1723   window_system=nextstep
1724   # set up packaging dirs
1725   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1726      ns_self_contained=yes
1727      prefix=${ns_appresdir}
1728      exec_prefix=${ns_appbindir}
1729      dnl This one isn't really used, only archlibdir is.
1730      libexecdir="\${ns_appbindir}/libexec"
1731      archlibdir="\${ns_appbindir}/libexec"
1732      etcdocdir="\${ns_appresdir}/etc"
1733      etcdir="\${ns_appresdir}/etc"
1734      dnl FIXME maybe set datarootdir instead.
1735      dnl That would also get applications, icons, man.
1736      infodir="\${ns_appresdir}/info"
1737      mandir="\${ns_appresdir}/man"
1738      lispdir="\${ns_appresdir}/lisp"
1739      INSTALL_ARCH_INDEP_EXTRA=
1740   fi
1741
1742   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1743 fi
1744 CFLAGS="$tmp_CFLAGS"
1745 CPPFLAGS="$tmp_CPPFLAGS"
1746 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1747 AC_SUBST(ns_self_contained)
1748 AC_SUBST(NS_OBJ)
1749 AC_SUBST(NS_OBJC_OBJ)
1750
1751 HAVE_W32=no
1752 W32_OBJ=
1753 W32_LIBS=
1754 EMACSRES=
1755 CLIENTRES=
1756 CLIENTW=
1757 W32_RES_LINK=
1758 EMACS_MANIFEST=
1759 UPDATE_MANIFEST=
1760 if test "${with_w32}" != no; then
1761   case "${opsys}" in
1762     cygwin)
1763       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1764              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1765                    cannot be found.])])
1766     ;;
1767     mingw32)
1768     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1769     ;;
1770     *)
1771       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1772     ;;
1773   esac
1774 fi
1775
1776 if test "${opsys}" = "mingw32"; then
1777   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1778   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1779      #include <windows.h>
1780      #include <usp10.h>]],
1781    [[PIMAGE_NT_HEADERS pHeader;
1782      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1783    [emacs_cv_w32api=yes
1784     HAVE_W32=yes],
1785    emacs_cv_w32api=no)
1786   AC_MSG_RESULT($emacs_cv_w32api)
1787   if test "${emacs_cv_w32api}" = "no"; then
1788     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1789   fi
1790 fi
1791
1792 FIRSTFILE_OBJ=
1793 NTDIR=
1794 LIBS_ECLIENT=
1795 LIB_WSOCK32=
1796 NTLIB=
1797 CM_OBJ="cm.o"
1798 XARGS_LIMIT=
1799 if test "${HAVE_W32}" = "yes"; then
1800   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1801   AC_CHECK_TOOL(WINDRES, [windres],
1802                 [AC_MSG_ERROR([No resource compiler found.])])
1803   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1804   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1805   EMACSRES="emacs.res"
1806   case "$canonical" in
1807     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1808     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1809   esac
1810   if test "${opsys}" = "cygwin"; then
1811     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1812     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1813     # Tell the linker that emacs.res is an object (which we compile from
1814     # the rc file), not a linker script.
1815     W32_RES_LINK="-Wl,emacs.res"
1816   else
1817     UPDATE_MANIFEST=update-game-score.exe.manifest
1818     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1819     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1820     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1821     W32_RES_LINK="\$(EMACSRES)"
1822     CLIENTRES="emacsclient.res"
1823     CLIENTW="emacsclientw\$(EXEEXT)"
1824     FIRSTFILE_OBJ=firstfile.o
1825     NTDIR=nt
1826     CM_OBJ=
1827     LIBS_ECLIENT="-lcomctl32"
1828     LIB_WSOCK32="-lwsock32"
1829     NTLIB="ntlib.$ac_objext"
1830     XARGS_LIMIT="-s 10000"
1831   fi
1832 fi
1833 AC_SUBST(W32_OBJ)
1834 AC_SUBST(W32_LIBS)
1835 AC_SUBST(EMACSRES)
1836 AC_SUBST(EMACS_MANIFEST)
1837 AC_SUBST(UPDATE_MANIFEST)
1838 AC_SUBST(CLIENTRES)
1839 AC_SUBST(CLIENTW)
1840 AC_SUBST(W32_RES_LINK)
1841 AC_SUBST(FIRSTFILE_OBJ)
1842 AC_SUBST(NTDIR)
1843 AC_SUBST(CM_OBJ)
1844 AC_SUBST(LIBS_ECLIENT)
1845 AC_SUBST(LIB_WSOCK32)
1846 AC_SUBST(NTLIB)
1847 AC_SUBST(XARGS_LIMIT)
1848
1849 if test "${HAVE_W32}" = "yes"; then
1850   window_system=w32
1851   with_xft=no
1852 fi
1853
1854 ## $window_system is now set to the window system we will
1855 ## ultimately use.
1856
1857 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1858    # Too many warnings for now.
1859    nw=
1860    nw="$nw -Wsuggest-attribute=const"
1861    nw="$nw -Wsuggest-attribute=noreturn"
1862    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1863
1864    gl_WARN_ADD([-Wno-unused-variable])
1865    gl_WARN_ADD([-Wno-unused-but-set-variable])
1866    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1867 fi
1868
1869 term_header=
1870 HAVE_X_WINDOWS=no
1871 HAVE_X11=no
1872 USE_X_TOOLKIT=none
1873
1874 case "${window_system}" in
1875   x11 )
1876     HAVE_X_WINDOWS=yes
1877     HAVE_X11=yes
1878     term_header=xterm.h
1879     case "${with_x_toolkit}" in
1880       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1881       motif ) USE_X_TOOLKIT=MOTIF ;;
1882       gtk ) with_gtk=yes
1883             term_header=gtkutil.h
1884 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1885 dnl USE_X_TOOLKIT is set.
1886             USE_X_TOOLKIT=none ;;
1887       gtk2 ) with_gtk2=yes
1888              term_header=gtkutil.h
1889              USE_X_TOOLKIT=none ;;
1890       gtk3 ) with_gtk3=yes
1891              term_header=gtkutil.h
1892              USE_X_TOOLKIT=none ;;
1893       no ) USE_X_TOOLKIT=none ;;
1894 dnl If user did not say whether to use a toolkit, make this decision later:
1895 dnl use the toolkit if we have gtk, or X11R5 or newer.
1896       * ) USE_X_TOOLKIT=maybe ;;
1897     esac
1898   ;;
1899   nextstep )
1900     term_header=nsterm.h
1901   ;;
1902   w32 )
1903     term_header=w32term.h
1904   ;;
1905 esac
1906
1907 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1908    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1909    if test "$HAVE_XSERVER" = true ||
1910       test -n "$DISPLAY" ||
1911       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1912         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1913 were found.  You should install the relevant development files for X
1914 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1915 sure you have development files for image handling, i.e.
1916 tiff, gif, jpeg, png and xpm.
1917 If you are sure you want Emacs compiled without X window support, pass
1918   --without-x
1919 to configure.])
1920    fi
1921 fi
1922
1923 # Does the opsystem file prohibit the use of the GNU malloc?
1924 # Assume not, until told otherwise.
1925 GNU_MALLOC=yes
1926
1927 AC_CACHE_CHECK(
1928   [whether malloc is Doug Lea style],
1929   [emacs_cv_var_doug_lea_malloc],
1930   [emacs_cv_var_doug_lea_malloc=no
1931    dnl Hooks do not work with address sanitization.
1932    if test "$emacs_cv_sanitize_address" != yes; then
1933      AC_LINK_IFELSE(
1934        [AC_LANG_PROGRAM(
1935           [[#include <malloc.h>
1936             static void hook (void) {}]],
1937           [[malloc_set_state (malloc_get_state ());
1938             __after_morecore_hook = hook;
1939             __malloc_initialize_hook = hook;]])],
1940        [emacs_cv_var_doug_lea_malloc=yes])])
1941    fi
1942 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1943
1944 system_malloc=$emacs_cv_sanitize_address
1945 case "$opsys" in
1946   ## darwin ld insists on the use of malloc routines in the System framework.
1947   darwin|sol2-10) system_malloc=yes ;;
1948 esac
1949
1950 GMALLOC_OBJ=
1951 if test "${system_malloc}" = "yes"; then
1952   AC_DEFINE([SYSTEM_MALLOC], 1,
1953     [Define to 1 to use the system memory allocator, even if it is not
1954      Doug Lea style.])
1955   GNU_MALLOC=no
1956   GNU_MALLOC_reason="
1957     (The GNU allocators don't work with this system configuration.)"
1958   VMLIMIT_OBJ=
1959 else
1960   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1961   VMLIMIT_OBJ=vm-limit.o
1962
1963   AC_CHECK_HEADERS([sys/vlimit.h])
1964   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1965     [AC_LINK_IFELSE(
1966        [AC_LANG_PROGRAM(
1967          [[extern char data_start[]; char ch;]],
1968          [[return data_start < &ch;]])],
1969        [emacs_cv_data_start=yes],
1970        [emacs_cv_data_start=no])])
1971   if test $emacs_cv_data_start = yes; then
1972     AC_DEFINE([HAVE_DATA_START], 1,
1973       [Define to 1 if data_start is the address of the start
1974        of the main data segment.])
1975   fi
1976 fi
1977 AC_SUBST(GMALLOC_OBJ)
1978 AC_SUBST(VMLIMIT_OBJ)
1979
1980 if test "$doug_lea_malloc" = "yes" ; then
1981   if test "$GNU_MALLOC" = yes ; then
1982     GNU_MALLOC_reason="
1983       (Using Doug Lea's new malloc from the GNU C Library.)"
1984   fi
1985   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1986     [Define to 1 if the system memory allocator is Doug Lea style,
1987      with malloc hooks and malloc_set_state.])
1988
1989   ## Use mmap directly for allocating larger buffers.
1990   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1991   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1992   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1993   case "$opsys" in
1994     gnu*) REL_ALLOC=no ;;
1995   esac
1996 fi
1997
1998 if test x"${REL_ALLOC}" = x; then
1999   REL_ALLOC=${GNU_MALLOC}
2000 fi
2001
2002 use_mmap_for_buffers=no
2003 case "$opsys" in
2004   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2005 esac
2006
2007 AC_FUNC_MMAP
2008 if test $use_mmap_for_buffers = yes; then
2009   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2010   REL_ALLOC=no
2011 fi
2012
2013 LIBS="$LIBS_SYSTEM $LIBS"
2014
2015 dnl FIXME replace main with a function we actually want from this library.
2016 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2017
2018 dnl Check for the POSIX thread library.
2019 LIB_PTHREAD=
2020 AC_CHECK_HEADERS_ONCE(pthread.h)
2021 if test "$ac_cv_header_pthread_h"; then
2022   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2023   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2024   dnl testing for pthread_kill if Emacs uses gmalloc.c.
2025   if test "$GMALLOC_OBJ" = gmalloc.o; then
2026     emacs_pthread_function=pthread_atfork
2027   else
2028     emacs_pthread_function=pthread_kill
2029   fi
2030   OLD_LIBS=$LIBS
2031   AC_SEARCH_LIBS([$emacs_pthread_function], [pthread],
2032     [AC_DEFINE([HAVE_PTHREAD], [1],
2033        [Define to 1 if you have pthread (-lpthread).])])
2034   if test "X$LIBS" != "X$OLD_LIBS"; then
2035     eval LIB_PTHREAD=\$ac_cv_search_$emacs_pthread_function
2036   fi
2037   LIBS=$OLD_LIBS
2038 fi
2039 AC_SUBST([LIB_PTHREAD])
2040
2041 dnl Check for need for bigtoc support on IBM AIX
2042
2043 case ${host_os} in
2044 aix*)
2045   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2046     case $GCC in
2047     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2048     *) gdb_cv_bigtoc=-bbigtoc ;;
2049     esac
2050
2051     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2052     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2053   ])
2054   ;;
2055 esac
2056
2057 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2058 # is for the tests that follow.  We set them back later on.
2059
2060 REAL_CFLAGS="$CFLAGS"
2061 REAL_CPPFLAGS="$CPPFLAGS"
2062 REAL_LIBS="$LIBS"
2063
2064 if test "${HAVE_X11}" = "yes"; then
2065   DEFS="$C_SWITCH_X_SITE $DEFS"
2066   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2067   LIBS="-lX11 $LIBS"
2068   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2069   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2070
2071   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2072   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2073   # but it's more convenient here to set LD_RUN_PATH since this
2074   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2075   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2076     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2077     export LD_RUN_PATH
2078   fi
2079
2080   if test "${opsys}" = "gnu-linux"; then
2081     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2082     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2083      [[XOpenDisplay ("foo");]])],
2084      [xgnu_linux_first_failure=no],
2085      [xgnu_linux_first_failure=yes])
2086     if test "${xgnu_linux_first_failure}" = "yes"; then
2087       OLD_CPPFLAGS="$CPPFLAGS"
2088       OLD_LIBS="$LIBS"
2089       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2090       LIBS="$LIBS -b i486-linuxaout"
2091       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2092        [[XOpenDisplay ("foo");]])],
2093        [xgnu_linux_second_failure=no],
2094        [xgnu_linux_second_failure=yes])
2095       if test "${xgnu_linux_second_failure}" = "yes"; then
2096         # If we get the same failure with -b, there is no use adding -b.
2097         # So leave it out.  This plays safe.
2098         AC_MSG_RESULT(no)
2099       else
2100         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2101         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2102         AC_MSG_RESULT(yes)
2103       fi
2104       CPPFLAGS=$OLD_CPPFLAGS
2105       LIBS=$OLD_LIBS
2106     else
2107       AC_MSG_RESULT(no)
2108     fi
2109   fi
2110
2111   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2112   # header files included from there.
2113   AC_MSG_CHECKING(for Xkb)
2114   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2115 #include <X11/XKBlib.h>]],
2116         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2117         emacs_xkb=yes, emacs_xkb=no)
2118   AC_MSG_RESULT($emacs_xkb)
2119   if test $emacs_xkb = yes; then
2120     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2121   fi
2122
2123   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2124 XScreenNumberOfScreen)
2125 fi
2126
2127 if test "${window_system}" = "x11"; then
2128   AC_MSG_CHECKING(X11 version 6)
2129   AC_CACHE_VAL(emacs_cv_x11_version_6,
2130   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2131 [[#if XlibSpecificationRelease < 6
2132 fail;
2133 #endif
2134 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2135   if test $emacs_cv_x11_version_6 = yes; then
2136     AC_MSG_RESULT(6 or newer)
2137     AC_DEFINE(HAVE_X11R6, 1,
2138               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2139     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2140     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2141     ## XIM support.
2142     case "$opsys" in
2143       sol2-*) : ;;
2144       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2145            [Define if you have usable X11R6-style XIM support.])
2146          ;;
2147     esac
2148   else
2149     AC_MSG_RESULT(before 6)
2150   fi
2151 fi
2152
2153
2154 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2155 HAVE_RSVG=no
2156 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2157   if test "${with_rsvg}" != "no"; then
2158     RSVG_REQUIRED=2.11.0
2159     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2160
2161     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2162     AC_SUBST(RSVG_CFLAGS)
2163     AC_SUBST(RSVG_LIBS)
2164
2165     if test $HAVE_RSVG = yes; then
2166       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2167       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2168       # Windows loads librsvg dynamically
2169       if test "${opsys}" = "mingw32"; then
2170         RSVG_LIBS=
2171       fi
2172     fi
2173   fi
2174 fi
2175
2176 HAVE_IMAGEMAGICK=no
2177 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2178   if test "${with_imagemagick}" != "no"; then
2179     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2180     ## 6.8.2 makes Emacs crash; see Bug#13867.
2181     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2182     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2183     AC_SUBST(IMAGEMAGICK_CFLAGS)
2184     AC_SUBST(IMAGEMAGICK_LIBS)
2185
2186     if test $HAVE_IMAGEMAGICK = yes; then
2187       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2188       OLD_CFLAGS=$CFLAGS
2189       OLD_LIBS=$LIBS
2190       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2191       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2192       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2193       CFLAGS=$OLD_CFLAGS
2194       LIBS=$OLD_LIBS
2195     fi
2196   fi
2197 fi
2198
2199
2200 HAVE_GTK=no
2201 GTK_OBJ=
2202 gtk_term_header=$term_header
2203 check_gtk2=no
2204 gtk3_pkg_errors=
2205 if test "${opsys}" != "mingw32"; then
2206   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2207     GLIB_REQUIRED=2.28
2208     GTK_REQUIRED=3.0
2209     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2210
2211     dnl Checks for libraries.
2212     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2213       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2214     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2215        AC_MSG_ERROR($GTK_PKG_ERRORS)
2216     fi
2217     if test "$pkg_check_gtk" = "yes"; then
2218        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2219        GTK_OBJ=emacsgtkfixed.o
2220        gtk_term_header=gtkutil.h
2221        USE_GTK_TOOLKIT="GTK3"
2222        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2223          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2224            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2225          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2226            [Define to 1 to disable Glib deprecation warnings.])
2227        fi
2228     else
2229        check_gtk2=yes
2230        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2231     fi
2232   fi
2233
2234   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2235     GLIB_REQUIRED=2.10
2236     GTK_REQUIRED=2.10
2237     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2238
2239     dnl Checks for libraries.
2240     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2241       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2242     if test "$pkg_check_gtk" = "no" &&
2243        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2244     then
2245       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2246     fi
2247     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2248   fi
2249 fi
2250
2251 OLD_CFLAGS=$CFLAGS
2252 OLD_LIBS=$LIBS
2253
2254 if test x"$pkg_check_gtk" = xyes; then
2255
2256   AC_SUBST(GTK_LIBS)
2257   CFLAGS="$CFLAGS $GTK_CFLAGS"
2258   LIBS="$GTK_LIBS $LIBS"
2259   dnl Try to compile a simple GTK program.
2260   AC_MSG_CHECKING([whether GTK compiles])
2261   GTK_COMPILES=no
2262   AC_LINK_IFELSE(
2263     [AC_LANG_PROGRAM(
2264        [[/* Check the Gtk and Glib APIs.  */
2265          #include <gtk/gtk.h>
2266          #include <glib-object.h>
2267          static void
2268          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2269          {}
2270        ]],
2271        [[
2272          GtkSettings *gs = 0;
2273          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2274             strict C prohibits this.  Use gtk_main_iteration to test that the
2275             libraries are there.  */
2276          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2277                                     0, 0, 0, G_CALLBACK (callback), 0))
2278            gtk_main_iteration ();
2279        ]])],
2280     [GTK_COMPILES=yes])
2281   AC_MSG_RESULT([$GTK_COMPILES])
2282   if test "${GTK_COMPILES}" != "yes"; then
2283     GTK_OBJ=
2284     if test "$USE_X_TOOLKIT" != "maybe"; then
2285       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2286     fi
2287   else
2288     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2289     HAVE_GTK=yes
2290     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2291     GTK_OBJ="gtkutil.o $GTK_OBJ"
2292     term_header=$gtk_term_header
2293     USE_X_TOOLKIT=none
2294     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2295       :
2296     else
2297       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2298        closing open displays.  This is no problem if you just use
2299        one display, but if you use more than one and close one of them
2300        Emacs may crash.]])
2301       sleep 3
2302     fi
2303   fi
2304
2305 fi
2306 AC_SUBST(GTK_OBJ)
2307
2308
2309 if test "${HAVE_GTK}" = "yes"; then
2310
2311   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2312   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2313   if test "$with_toolkit_scroll_bars" != no; then
2314     with_toolkit_scroll_bars=yes
2315   fi
2316
2317   dnl  Check if we have the old file selection dialog declared and
2318   dnl  in the link library.  In 2.x it may be in the library,
2319   dnl  but not declared if deprecated featured has been selected out.
2320   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2321   HAVE_GTK_FILE_SELECTION=no
2322   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2323                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2324 #include <gtk/gtk.h>])
2325   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2326     AC_CHECK_FUNCS(gtk_file_selection_new)
2327   fi
2328
2329   dnl Same as above for gtk_handle_box.
2330   HAVE_GTK_HANDLE_BOX=no
2331   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2332                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2333 #include <gtk/gtk.h>])
2334   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2335     AC_CHECK_FUNCS(gtk_handle_box_new)
2336   fi
2337
2338   dnl Same as above for gtk_tearoff_menu_item.
2339   HAVE_GTK_TEAROFF_MENU_ITEM=no
2340   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2341                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2342 #include <gtk/gtk.h>])
2343   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2344     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2345   fi
2346
2347   dnl Check for functions introduced in 2.14 and later.
2348   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2349                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2350                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2351                  gtk_orientable_set_orientation \
2352                  gtk_window_set_has_resize_grip)
2353
2354  term_header=gtkutil.h
2355 fi
2356
2357 CFLAGS=$OLD_CFLAGS
2358 LIBS=$OLD_LIBS
2359
2360 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2361 dnl other platforms.
2362 HAVE_DBUS=no
2363 DBUS_OBJ=
2364 if test "${with_dbus}" = "yes"; then
2365    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2366    if test "$HAVE_DBUS" = yes; then
2367      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2368      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2369      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2370      dnl D-Bus 1.5.12.
2371      OLD_LIBS=$LIBS
2372      LIBS="$LIBS $DBUS_LIBS"
2373      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2374                     dbus_type_is_valid \
2375                     dbus_validate_bus_name \
2376                     dbus_validate_path \
2377                     dbus_validate_interface \
2378                     dbus_validate_member)
2379      LIBS=$OLD_LIBS
2380      DBUS_OBJ=dbusbind.o
2381    fi
2382 fi
2383 AC_SUBST(DBUS_CFLAGS)
2384 AC_SUBST(DBUS_LIBS)
2385 AC_SUBST(DBUS_OBJ)
2386
2387 dnl GSettings has been tested under GNU/Linux only.
2388 HAVE_GSETTINGS=no
2389 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2390    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2391    if test "$HAVE_GSETTINGS" = "yes"; then
2392       old_CFLAGS=$CFLAGS
2393       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2394       old_LIBS=$LIBS
2395       LIBS="$LIBS $GSETTINGS_LIBS"
2396       AC_MSG_CHECKING([whether GSettings is in gio])
2397       AC_LINK_IFELSE(
2398          [AC_LANG_PROGRAM(
2399              [[/* Check that gsettings really is present.  */
2400              #include <glib-object.h>
2401              #include <gio/gio.h>
2402              ]],
2403              [[
2404                GSettings *settings;
2405                GVariant *val = g_settings_get_value (settings, "");
2406              ]])],
2407          [], HAVE_GSETTINGS=no)
2408       AC_MSG_RESULT([$HAVE_GSETTINGS])
2409
2410       if test "$HAVE_GSETTINGS" = "yes"; then
2411         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2412         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2413         SETTINGS_LIBS="$GSETTINGS_LIBS"
2414       fi
2415       CFLAGS=$old_CFLAGS
2416       LIBS=$old_LIBS
2417    fi
2418 fi
2419
2420 dnl GConf has been tested under GNU/Linux only.
2421 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2422 HAVE_GCONF=no
2423 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2424    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2425    if test "$HAVE_GCONF" = yes; then
2426       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2427       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2428       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2429       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2430    fi
2431 fi
2432
2433 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2434     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2435     if test "$HAVE_GOBJECT" = "yes"; then
2436        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2437        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2438     fi
2439     SAVE_CFLAGS="$CFLAGS"
2440     SAVE_LIBS="$LIBS"
2441     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2442     LIBS="$SETTINGS_LIBS $LIBS"
2443     CFLAGS="$SAVE_CFLAGS"
2444     LIBS="$SAVE_LIBS"
2445 fi
2446 AC_SUBST(SETTINGS_CFLAGS)
2447 AC_SUBST(SETTINGS_LIBS)
2448
2449
2450 dnl SELinux is available for GNU/Linux only.
2451 HAVE_LIBSELINUX=no
2452 LIBSELINUX_LIBS=
2453 if test "${with_selinux}" = "yes"; then
2454    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2455    if test "$HAVE_LIBSELINUX" = yes; then
2456       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2457       LIBSELINUX_LIBS=-lselinux
2458    fi
2459 fi
2460 AC_SUBST(LIBSELINUX_LIBS)
2461
2462 HAVE_GNUTLS=no
2463 HAVE_GNUTLS3=no
2464 if test "${with_gnutls}" = "yes" ; then
2465   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0],
2466     [HAVE_GNUTLS3=yes], [HAVE_GNUTLS3=no])
2467   if test "${HAVE_GNUTLS3}" = "yes"; then
2468     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2469     HAVE_GNUTLS="yes"
2470   else
2471     EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2472       [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2473   fi
2474   if test "${HAVE_GNUTLS}" = "yes"; then
2475     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2476   fi
2477
2478   # Windows loads GnuTLS dynamically
2479   if test "${opsys}" = "mingw32"; then
2480     LIBGNUTLS_LIBS=
2481   fi
2482 fi
2483
2484 AC_SUBST(LIBGNUTLS_LIBS)
2485 AC_SUBST(LIBGNUTLS_CFLAGS)
2486
2487 NOTIFY_OBJ=
2488 NOTIFY_SUMMARY=no
2489
2490 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2491 dnl a particular library.  This doesn't make much sense?
2492 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2493   with_file_notification=no
2494 fi
2495
2496 dnl MS Windows native file monitor is available for mingw32 only.
2497 case $with_file_notification,$opsys in
2498   w32,* | yes,mingw32)
2499     AC_CHECK_HEADER(windows.h)
2500     if test "$ac_cv_header_windows_h" = yes ; then
2501        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2502        NOTIFY_OBJ=w32notify.o
2503        NOTIFY_SUMMARY="yes (w32)"
2504     fi ;;
2505 esac
2506
2507 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2508 dnl has been added in glib 2.24.  It has been tested under
2509 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2510 dnl only sense when glib has been compiled with inotify support.  How
2511 dnl to check?
2512 case $with_file_notification,$NOTIFY_OBJ in
2513   gfile, | yes,)
2514     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2515     if test "$HAVE_GFILENOTIFY" = "yes"; then
2516        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2517        NOTIFY_OBJ=gfilenotify.o
2518        NOTIFY_SUMMARY="yes -lgio (gfile)"
2519     fi ;;
2520 esac
2521
2522 dnl inotify is only available on GNU/Linux.
2523 case $with_file_notification,$NOTIFY_OBJ in
2524   inotify, | yes,)
2525     AC_CHECK_HEADER(sys/inotify.h)
2526     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2527         AC_CHECK_FUNC(inotify_init1)
2528         if test "$ac_cv_func_inotify_init1" = yes; then
2529           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2530           NOTIFY_OBJ=inotify.o
2531           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2532        fi
2533     fi ;;
2534 esac
2535
2536 case $with_file_notification,$NOTIFY_OBJ in
2537   yes,* | no,* | *,?*) ;;
2538   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2539 esac
2540
2541 if test -n "$NOTIFY_OBJ"; then
2542    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2543 fi
2544 AC_SUBST(NOTIFY_OBJ)
2545 AC_SUBST(GFILENOTIFY_CFLAGS)
2546 AC_SUBST(GFILENOTIFY_LIBS)
2547
2548 dnl Do not put whitespace before the #include statements below.
2549 dnl Older compilers (eg sunos4 cc) choke on it.
2550 HAVE_XAW3D=no
2551 LUCID_LIBW=
2552 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2553   if test "$with_xaw3d" != no; then
2554     AC_CACHE_VAL(emacs_cv_xaw3d,
2555     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2556 #include <X11/Intrinsic.h>
2557 #include <X11/Xaw3d/Simple.h>]],
2558       [[]])],
2559       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2560                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2561       emacs_cv_xaw3d=no)])
2562   else
2563     emacs_cv_xaw3d=no
2564   fi
2565   if test $emacs_cv_xaw3d = yes; then
2566     AC_MSG_CHECKING(for xaw3d)
2567     AC_MSG_RESULT([yes; using Lucid toolkit])
2568     USE_X_TOOLKIT=LUCID
2569     HAVE_XAW3D=yes
2570     LUCID_LIBW=-lXaw3d
2571     AC_DEFINE(HAVE_XAW3D, 1,
2572               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2573   else
2574     AC_MSG_CHECKING(for xaw3d)
2575     AC_MSG_RESULT(no)
2576     AC_MSG_CHECKING(for libXaw)
2577     AC_CACHE_VAL(emacs_cv_xaw,
2578     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2579 #include <X11/Intrinsic.h>
2580 #include <X11/Xaw/Simple.h>]],
2581       [[]])],
2582       emacs_cv_xaw=yes,
2583       emacs_cv_xaw=no)])
2584     if test $emacs_cv_xaw = yes; then
2585       AC_MSG_RESULT([yes; using Lucid toolkit])
2586       USE_X_TOOLKIT=LUCID
2587       LUCID_LIBW=-lXaw
2588     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2589       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2590     else
2591       AC_MSG_ERROR([No X toolkit could be found.
2592 If you are sure you want Emacs compiled without an X toolkit, pass
2593   --with-x-toolkit=no
2594 to configure.  Otherwise, install the development libraries for the toolkit
2595 that you want to use (e.g. Gtk+) and re-run configure.])
2596     fi
2597   fi
2598 fi
2599
2600 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2601
2602 LIBXTR6=
2603 LIBXMU=
2604 if test "${USE_X_TOOLKIT}" != "none"; then
2605   AC_MSG_CHECKING(X11 toolkit version)
2606   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2607   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2608 [[#if XtSpecificationRelease < 6
2609 fail;
2610 #endif
2611 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2612   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2613   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2614     AC_MSG_RESULT(6 or newer)
2615     AC_DEFINE(HAVE_X11XTR6, 1,
2616               [Define to 1 if you have the X11R6 or newer version of Xt.])
2617     LIBXTR6="-lSM -lICE"
2618     case "$opsys" in
2619       ## Use libw.a along with X11R6 Xt.
2620       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2621     esac
2622   else
2623     AC_MSG_RESULT(before 6)
2624   fi
2625
2626 dnl If using toolkit, check whether libXmu.a exists.
2627 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2628   OLDLIBS="$LIBS"
2629   if test x$HAVE_X11XTR6 = xyes; then
2630     OTHERLIBS='-lXt -lSM -lICE'
2631   else
2632     OTHERLIBS='-lXt'
2633   fi
2634   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2635   if test "X$LIBS" != "X$OLDLIBS"; then
2636     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2637   fi
2638   LIBS=$OLDLIBS
2639   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2640 fi
2641 AC_SUBST(LIBXTR6)
2642 AC_SUBST(LIBXMU)
2643
2644 LIBXP=
2645 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2646   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2647   if test -d /usr/include/openmotif; then
2648     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2649     emacs_cv_openmotif=yes
2650     case "$canonical" in
2651       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2652       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2653       ;;
2654       *)
2655       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2656     esac
2657   else
2658     emacs_cv_openmotif=no
2659   fi
2660   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2661   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2662     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2663 int x = 5;
2664 #else
2665 Motif version prior to 2.1.
2666 #endif]])],
2667     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2668   if test $emacs_cv_motif_version_2_1 = yes; then
2669     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2670     if test x$emacs_cv_openmotif = xyes; then
2671       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2672     fi
2673   else
2674     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2675     # We put this in CFLAGS temporarily to precede other -I options
2676     # that might be in CFLAGS temporarily.
2677     # We put this in CPPFLAGS where it precedes the other -I options.
2678     OLD_CPPFLAGS=$CPPFLAGS
2679     OLD_CFLAGS=$CFLAGS
2680     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2681     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2682     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2683       [[int x = 5;]])],
2684       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2685     if test $emacs_cv_lesstif = yes; then
2686       # Make sure this -I option remains in CPPFLAGS after it is set
2687       # back to REAL_CPPFLAGS.
2688       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2689       # have those other -I options anyway.  Ultimately, having this
2690       # directory ultimately in CPPFLAGS will be enough.
2691       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2692       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2693     else
2694       CFLAGS=$OLD_CFLAGS
2695       CPPFLAGS=$OLD_CPPFLAGS
2696     fi
2697   fi
2698   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2699     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2700 fi
2701
2702 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2703 dnl using Motif or Xaw3d is available, and unless
2704 dnl --with-toolkit-scroll-bars=no was specified.
2705
2706 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2707             [Define to 1 if we should use toolkit scroll bars.])dnl
2708 USE_TOOLKIT_SCROLL_BARS=no
2709 if test "${with_toolkit_scroll_bars}" != "no"; then
2710   if test "${USE_X_TOOLKIT}" != "none"; then
2711     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2712       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2713       HAVE_XAW3D=no
2714       USE_TOOLKIT_SCROLL_BARS=yes
2715     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2716       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2717       USE_TOOLKIT_SCROLL_BARS=yes
2718     fi
2719   elif test "${HAVE_GTK}" = "yes"; then
2720     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2721     USE_TOOLKIT_SCROLL_BARS=yes
2722   elif test "${HAVE_NS}" = "yes"; then
2723     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2724     USE_TOOLKIT_SCROLL_BARS=yes
2725   elif test "${HAVE_W32}" = "yes"; then
2726     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2727     USE_TOOLKIT_SCROLL_BARS=yes
2728   fi
2729 fi
2730
2731 dnl See if XIM is available.
2732 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2733           #include <X11/Xlib.h>
2734           #include <X11/Xresource.h>]],
2735          [[XIMProc  callback;]])],
2736          [HAVE_XIM=yes
2737          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2738          HAVE_XIM=no)
2739
2740 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2741
2742 if test "${with_xim}" != "no"; then
2743   AC_DEFINE(USE_XIM, 1,
2744             [Define to 1 if we should use XIM, if it is available.])
2745 fi
2746
2747
2748 if test "${HAVE_XIM}" != "no"; then
2749   late_CFLAGS=$CFLAGS
2750   if test "$GCC" = yes; then
2751     CFLAGS="$CFLAGS --pedantic-errors"
2752   fi
2753   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2754 #include <X11/Xlib.h>
2755 #include <X11/Xresource.h>]],
2756 [[Display *display;
2757 XrmDatabase db;
2758 char *res_name;
2759 char *res_class;
2760 XIMProc  callback;
2761 XPointer *client_data;
2762 #ifndef __GNUC__
2763 /* If we're not using GCC, it's probably not XFree86, and this is
2764    probably right, but we can't use something like --pedantic-errors.  */
2765 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2766                                            char*, XIMProc, XPointer*);
2767 #endif
2768 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2769    client_data);]])],
2770     [emacs_cv_arg6_star=yes])
2771   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2772          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2773 either XPointer or XPointer*.])dnl
2774   if test "$emacs_cv_arg6_star" = yes; then
2775     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2776   else
2777     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2778   fi
2779   CFLAGS=$late_CFLAGS
2780 fi
2781
2782 ### Start of font-backend (under any platform) section.
2783 # (nothing here yet -- this is a placeholder)
2784 ### End of font-backend (under any platform) section.
2785
2786 ### Start of font-backend (under X11) section.
2787 if test "${HAVE_X11}" = "yes"; then
2788    EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0],
2789      [HAVE_FC=yes], [HAVE_FC=no])
2790
2791    ## Use -lXft if available, unless `--with-xft=no'.
2792    HAVE_XFT=maybe
2793     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2794       with_xft="no";
2795     fi
2796     if test "x${with_xft}" != "xno"; then
2797
2798       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2799       ## Because xftfont.c uses XRenderQueryExtension, we also
2800       ## need to link to -lXrender.
2801       HAVE_XRENDER=no
2802       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2803       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2804         OLD_CPPFLAGS="$CPPFLAGS"
2805         OLD_CFLAGS="$CFLAGS"
2806         OLD_LIBS="$LIBS"
2807         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2808         CFLAGS="$CFLAGS $XFT_CFLAGS"
2809         XFT_LIBS="-lXrender $XFT_LIBS"
2810         LIBS="$XFT_LIBS $LIBS"
2811         AC_CHECK_HEADER(X11/Xft/Xft.h,
2812           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2813           [[#include <X11/X.h>]])
2814
2815         if test "${HAVE_XFT}" = "yes"; then
2816           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2817             AC_SUBST(XFT_LIBS)
2818           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2819         fi                        # "${HAVE_XFT}" = "yes"
2820         CPPFLAGS=$OLD_CPPFLAGS
2821         CFLAGS=$OLD_CFLAGS
2822         LIBS=$OLD_LIBS
2823       fi                          # "$HAVE_XFT" != no
2824     fi                            # "x${with_xft}" != "xno"
2825
2826     ## We used to allow building with FreeType and without Xft.
2827     ## However, the ftx font backend driver is not in good shape.
2828     if test "$HAVE_XFT" != "yes"; then
2829        dnl For the "Does Emacs use" message at the end.
2830        HAVE_XFT=no
2831        HAVE_FREETYPE=no
2832     else
2833        dnl Strict linkers fail with
2834        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2835        dnl if -lfreetype is not specified.
2836        dnl The following is needed to set FREETYPE_LIBS.
2837        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
2838
2839        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2840     fi
2841
2842     HAVE_LIBOTF=no
2843     if test "${HAVE_FREETYPE}" = "yes"; then
2844       AC_DEFINE(HAVE_FREETYPE, 1,
2845                 [Define to 1 if using the freetype and fontconfig libraries.])
2846       if test "${with_libotf}" != "no"; then
2847         EMACS_CHECK_MODULES([LIBOTF], [libotf])
2848         if test "$HAVE_LIBOTF" = "yes"; then
2849           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2850           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2851                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2852                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2853           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2854             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2855                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2856           fi
2857         fi
2858       fi
2859     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2860     dnl Does the new font backend require it, or can it work without it?
2861     fi
2862
2863     HAVE_M17N_FLT=no
2864     if test "${HAVE_LIBOTF}" = yes; then
2865       if test "${with_m17n_flt}" != "no"; then
2866         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
2867         if test "$HAVE_M17N_FLT" = "yes"; then
2868           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2869         fi
2870       fi
2871     fi
2872 else
2873     HAVE_XFT=no
2874     HAVE_FREETYPE=no
2875     HAVE_LIBOTF=no
2876     HAVE_M17N_FLT=no
2877 fi
2878
2879 ### End of font-backend (under X11) section.
2880
2881 AC_SUBST(FREETYPE_CFLAGS)
2882 AC_SUBST(FREETYPE_LIBS)
2883 AC_SUBST(FONTCONFIG_CFLAGS)
2884 AC_SUBST(FONTCONFIG_LIBS)
2885 AC_SUBST(LIBOTF_CFLAGS)
2886 AC_SUBST(LIBOTF_LIBS)
2887 AC_SUBST(M17N_FLT_CFLAGS)
2888 AC_SUBST(M17N_FLT_LIBS)
2889
2890 ### Use -lXpm if available, unless `--with-xpm=no'.
2891 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2892 HAVE_XPM=no
2893 LIBXPM=
2894 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2895   if test "${with_xpm}" != "no"; then
2896     SAVE_CPPFLAGS="$CPPFLAGS"
2897     SAVE_LDFLAGS="$LDFLAGS"
2898     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2899     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2900     AC_CHECK_HEADER(X11/xpm.h,
2901       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2902     if test "${HAVE_XPM}" = "yes"; then
2903       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2904       AC_EGREP_CPP(no_return_alloc_pixels,
2905       [#include "X11/xpm.h"
2906 #ifndef XpmReturnAllocPixels
2907 no_return_alloc_pixels
2908 #endif
2909       ], HAVE_XPM=no, HAVE_XPM=yes)
2910
2911       if test "${HAVE_XPM}" = "yes"; then
2912         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2913         AC_MSG_RESULT(yes)
2914       else
2915         AC_MSG_RESULT(no)
2916         CPPFLAGS="$SAVE_CPPFLAGS"
2917         LDFLAGS="$SAVE_LDFLAGS"
2918       fi
2919     fi
2920   fi
2921
2922   if test "${HAVE_XPM}" = "yes"; then
2923     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2924     LIBXPM=-lXpm
2925   fi
2926 fi
2927
2928 if test "${HAVE_X11}" = "yes"; then
2929   if test "${with_xpm}" != "no"; then
2930     AC_CHECK_HEADER(X11/xpm.h,
2931       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2932     if test "${HAVE_XPM}" = "yes"; then
2933       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2934       AC_EGREP_CPP(no_return_alloc_pixels,
2935       [#include "X11/xpm.h"
2936 #ifndef XpmReturnAllocPixels
2937 no_return_alloc_pixels
2938 #endif
2939       ], HAVE_XPM=no, HAVE_XPM=yes)
2940
2941       if test "${HAVE_XPM}" = "yes"; then
2942         AC_MSG_RESULT(yes)
2943       else
2944         AC_MSG_RESULT(no)
2945       fi
2946     fi
2947   fi
2948
2949   if test "${HAVE_XPM}" = "yes"; then
2950     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2951     LIBXPM=-lXpm
2952   fi
2953 fi
2954
2955 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
2956 ### slightly different requirements wrt image libraries (it doesn't
2957 ### use -lXpm because it loads the xpm shared library dynamically at
2958 ### run time).
2959 if test "${opsys}" = "mingw32"; then
2960   if test "${with_xpm}" != "no"; then
2961     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
2962 #define FOR_MSW 1])
2963   fi
2964
2965   if test "${HAVE_XPM}" = "yes"; then
2966     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2967   fi
2968 fi
2969
2970 AC_SUBST(LIBXPM)
2971
2972 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2973 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
2974 HAVE_JPEG=no
2975 LIBJPEG=
2976 if test "${opsys}" = "mingw32"; then
2977   if test "${with_jpeg}" != "no"; then
2978     dnl Checking for jpeglib.h can lose because of a redefinition of
2979     dnl HAVE_STDLIB_H.
2980     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
2981   fi
2982   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2983   if test "${HAVE_JPEG}" = "yes"; then
2984     AC_DEFINE(HAVE_JPEG)
2985     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2986         [#include <jpeglib.h>
2987          version=JPEG_LIB_VERSION
2988 ],
2989         [AC_DEFINE(HAVE_JPEG)],
2990         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2991         HAVE_JPEG=no])
2992   fi
2993 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2994   if test "${with_jpeg}" != "no"; then
2995     dnl Checking for jpeglib.h can lose because of a redefinition of
2996     dnl  HAVE_STDLIB_H.
2997     AC_CHECK_HEADER(jerror.h,
2998       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2999   fi
3000
3001   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3002   if test "${HAVE_JPEG}" = "yes"; then
3003     AC_DEFINE(HAVE_JPEG)
3004     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3005         [#include <jpeglib.h>
3006          version=JPEG_LIB_VERSION
3007 ],
3008         [AC_DEFINE(HAVE_JPEG)],
3009         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3010         HAVE_JPEG=no])
3011   fi
3012   if test "${HAVE_JPEG}" = "yes"; then
3013     LIBJPEG=-ljpeg
3014   fi
3015 fi
3016 AC_SUBST(LIBJPEG)
3017
3018 HAVE_ZLIB=no
3019 LIBZ=
3020 if test "${with_zlib}" != "no"; then
3021   OLIBS=$LIBS
3022   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3023   LIBS=$OLIBS
3024   case $ac_cv_search_inflateEnd in
3025     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3026   esac
3027 fi
3028 if test "${HAVE_ZLIB}" = "yes"; then
3029   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3030   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3031   if test "${opsys}" = "mingw32"; then
3032      LIBZ=
3033   fi
3034 fi
3035 AC_SUBST(LIBZ)
3036
3037 ### Use -lpng if available, unless `--with-png=no'.
3038 HAVE_PNG=no
3039 LIBPNG=
3040 PNG_CFLAGS=
3041 if test "${with_png}" != no; then
3042   # mingw32 loads the library dynamically.
3043   if test "$opsys" = mingw32; then
3044     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3045   elif png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3046        png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD`
3047   then
3048     HAVE_PNG=yes
3049     PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3050     LIBPNG=$png_libs
3051   else
3052     # libpng-config does not work; configure by hand.
3053     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3054     # in /usr/include/libpng.
3055     AC_CHECK_HEADERS([png.h libpng/png.h],
3056       [AC_CHECK_LIB([png], [png_get_channels],
3057          [HAVE_PNG=yes
3058           LIBPNG='-lpng'
3059           if test "$ac_cv_header_png_h" != yes; then
3060             PNG_CFLAGS=-I/usr/include/libpng
3061           fi
3062           break],
3063           [], [-lz -lm])])
3064   fi
3065   # $LIBPNG requires explicit -lz in some cases.
3066   # We don't know what those cases are, exactly, so play it safe and
3067   # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3068   if test -n "$LIBPNG" && test -z "$LIBZ"; then
3069     LIBPNG="$LIBPNG -lz"
3070   fi
3071 fi
3072 if test $HAVE_PNG = yes; then
3073   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3074
3075   SAVE_CFLAGS=$CFLAGS
3076   CFLAGS="$CFLAGS $PNG_CFLAGS"
3077   AC_CHECK_DECL([png_longjmp],
3078     [],
3079     [AC_DEFINE([PNG_DEPSTRUCT], [],
3080        [Define to empty to suppress deprecation warnings when building
3081         with --enable-gcc-warnings and with libpng versions before 1.5,
3082         which lack png_longjmp.])],
3083     [[#include <png.h>
3084     ]])
3085   CFLAGS=$SAVE_CFLAGS
3086 fi
3087 AC_SUBST(LIBPNG)
3088 AC_SUBST(PNG_CFLAGS)
3089
3090 ### Use -ltiff if available, unless `--with-tiff=no'.
3091 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3092 HAVE_TIFF=no
3093 LIBTIFF=
3094 if test "${opsys}" = "mingw32"; then
3095   if test "${with_tiff}" != "no"; then
3096     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3097   fi
3098   if test "${HAVE_TIFF}" = "yes"; then
3099     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3100   fi
3101 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3102   if test "${with_tiff}" != "no"; then
3103     AC_CHECK_HEADER(tiffio.h,
3104       [tifflibs="-lz -lm"
3105       # At least one tiff package requires the jpeg library.
3106       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3107       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3108   fi
3109
3110   if test "${HAVE_TIFF}" = "yes"; then
3111     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3112     dnl FIXME -lz -lm, as per libpng?
3113     LIBTIFF=-ltiff
3114   fi
3115 fi
3116 AC_SUBST(LIBTIFF)
3117
3118 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3119 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3120 HAVE_GIF=no
3121 LIBGIF=
3122 if test "${opsys}" = "mingw32"; then
3123   if test "${with_gif}" != "no"; then
3124     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3125   fi
3126   if test "${HAVE_GIF}" = "yes"; then
3127     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3128   fi
3129 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3130         || test "${HAVE_W32}" = "yes"; then
3131   AC_CHECK_HEADER(gif_lib.h,
3132 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3133 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3134     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3135         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3136
3137   if test "$HAVE_GIF" = yes; then
3138     LIBGIF=-lgif
3139   elif test "$HAVE_GIF" = maybe; then
3140 # If gif_lib.h but no libgif, try libungif.
3141     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3142     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3143   fi
3144
3145   if test "${HAVE_GIF}" = "yes"; then
3146     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3147   fi
3148 fi
3149 AC_SUBST(LIBGIF)
3150
3151 dnl Check for required libraries.
3152 if test "${HAVE_X11}" = "yes"; then
3153   MISSING=""
3154   WITH_NO=""
3155   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3156     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3157   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3158     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3159   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3160     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3161   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3162     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3163   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3164     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3165
3166   if test "X${MISSING}" != X; then
3167     AC_MSG_ERROR([The following required libraries were not found:
3168     $MISSING
3169 Maybe some development libraries/packages are missing?
3170 If you don't want to link with them give
3171     $WITH_NO
3172 as options to configure])
3173   fi
3174 fi
3175
3176 ### Use -lgpm if available, unless `--with-gpm=no'.
3177 HAVE_GPM=no
3178 LIBGPM=
3179 if test "${with_gpm}" != "no"; then
3180   AC_CHECK_HEADER(gpm.h,
3181     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3182
3183   if test "${HAVE_GPM}" = "yes"; then
3184     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3185     LIBGPM=-lgpm
3186   fi
3187 fi
3188 AC_SUBST(LIBGPM)
3189
3190 dnl Check for malloc/malloc.h on darwin
3191 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3192
3193 GNUSTEP_CFLAGS=
3194 ### Use NeXTstep API to implement GUI.
3195 if test "${HAVE_NS}" = "yes"; then
3196   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3197   if test "${NS_IMPL_COCOA}" = "yes"; then
3198     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3199   fi
3200   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3201     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3202     # See also .m.o rule in Makefile.in */
3203     # FIXME: are all these flags really needed?  Document here why.  */
3204     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3205     ## Extra CFLAGS applied to src/*.m files.
3206     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3207   fi
3208   OTHER_FILES=ns-app
3209 fi
3210
3211 ### Use session management (-lSM -lICE) if available
3212 HAVE_X_SM=no
3213 LIBXSM=
3214 if test "${HAVE_X11}" = "yes"; then
3215   AC_CHECK_HEADER(X11/SM/SMlib.h,
3216     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3217
3218   if test "${HAVE_X_SM}" = "yes"; then
3219     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3220     LIBXSM="-lSM -lICE"
3221   fi
3222 fi
3223 AC_SUBST(LIBXSM)
3224
3225 ### Use XRandr (-lXrandr) if available
3226 HAVE_XRANDR=no
3227 if test "${HAVE_X11}" = "yes"; then
3228   XRANDR_REQUIRED=1.2.2
3229   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3230   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3231   if test $HAVE_XRANDR = no; then
3232     # Test old way in case pkg-config doesn't have it (older machines).
3233     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3234       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3235     if test $HAVE_XRANDR = yes; then
3236       XRANDR_LIBS=-lXrandr
3237     fi
3238   fi
3239   if test $HAVE_XRANDR = yes; then
3240     SAVE_CFLAGS="$CFLAGS"
3241     SAVE_LIBS="$LIBS"
3242     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3243     LIBS="$XRANDR_LIBS $LIBS"
3244     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3245     CFLAGS="$SAVE_CFLAGS"
3246     LIBS="$SAVE_LIBS"
3247
3248     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3249   fi
3250 fi
3251 AC_SUBST(XRANDR_CFLAGS)
3252 AC_SUBST(XRANDR_LIBS)
3253
3254 ### Use Xinerama (-lXinerama) if available
3255 HAVE_XINERAMA=no
3256 if test "${HAVE_X11}" = "yes"; then
3257   XINERAMA_REQUIRED=1.0.2
3258   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3259   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3260   if test $HAVE_XINERAMA = no; then
3261     # Test old way in case pkg-config doesn't have it (older machines).
3262     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3263       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3264     if test $HAVE_XINERAMA = yes; then
3265       XINERAMA_LIBS=-lXinerama
3266     fi
3267   fi
3268   if test $HAVE_XINERAMA = yes; then
3269     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3270   fi
3271 fi
3272 AC_SUBST(XINERAMA_CFLAGS)
3273 AC_SUBST(XINERAMA_LIBS)
3274
3275
3276 ### Use libxml (-lxml2) if available
3277 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3278 HAVE_LIBXML2=no
3279 if test "${with_xml2}" != "no"; then
3280   ### I'm not sure what the version number should be, so I just guessed.
3281   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3282   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3283   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3284     SAVE_CPPFLAGS="$CPPFLAGS"
3285     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3286     AC_CHECK_HEADER(libxml/HTMLparser.h,
3287       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3288                      [#include <libxml/HTMLparser.h>])])
3289     CPPFLAGS="$SAVE_CPPFLAGS"
3290     if test "${HAVE_LIBXML2}" = "yes"; then
3291       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3292       LIBXML2_LIBS="-lxml2"
3293     fi
3294   fi
3295   if test "${HAVE_LIBXML2}" = "yes"; then
3296     if test "${opsys}" != "mingw32"; then
3297       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no
3298         [$LIBXML2_LIBS])
3299     else
3300       LIBXML2_LIBS=""
3301     fi
3302     if test "${HAVE_LIBXML2}" = "yes"; then
3303       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3304     else
3305       LIBXML2_LIBS=""
3306       LIBXML2_CFLAGS=""
3307     fi
3308   fi
3309 fi
3310 AC_SUBST(LIBXML2_LIBS)
3311 AC_SUBST(LIBXML2_CFLAGS)
3312
3313 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3314 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3315 if test "${opsys}" = "mingw32"; then
3316   emacs_cv_netdb_declares_h_errno=yes
3317 fi
3318 AC_CACHE_CHECK(whether netdb declares h_errno,
3319                emacs_cv_netdb_declares_h_errno,
3320 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3321   [[return h_errno;]])],
3322   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3323 if test $emacs_cv_netdb_declares_h_errno = yes; then
3324   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3325 fi
3326
3327 # Check for mail-locking functions in a "mail" library.  Probably this should
3328 # have the same check as for liblockfile below.
3329 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3330 if test $have_mail = yes; then
3331   LIBS_MAIL=-lmail
3332   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3333
3334   OLD_LIBS=$LIBS
3335   LIBS="$LIBS_MAIL $LIBS"
3336   AC_CHECK_FUNCS(touchlock)
3337   LIBS=$OLD_LIBS
3338 else
3339   LIBS_MAIL=
3340 fi
3341 dnl Debian, at least:
3342 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3343 if test $have_lockfile = yes; then
3344    LIBS_MAIL=-llockfile
3345    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3346 else
3347 # If we have the shared liblockfile, assume we must use it for mail
3348 # locking (e.g. Debian).  If we couldn't link against liblockfile
3349 # (no liblockfile.a installed), ensure that we don't need to.
3350   dnl This works for files generally, not just executables.
3351   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3352   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3353                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3354   if test $ac_cv_prog_liblockfile = yes; then
3355     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3356 This probably means that movemail could lose mail.
3357 There may be a `development' package to install containing liblockfile.])
3358   fi
3359 fi
3360 AC_CHECK_HEADERS_ONCE(maillock.h)
3361 AC_SUBST(LIBS_MAIL)
3362
3363 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3364 ## interlock access to the mail spool.  The alternative is a lock file named
3365 ## /usr/spool/mail/$USER.lock.
3366 mail_lock=no
3367 case "$opsys" in
3368   aix4-2) mail_lock="lockf" ;;
3369
3370   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3371
3372   ## On GNU/Linux systems, both methods are used by various mail programs.
3373   ## I assume most people are using newer mailers that have heard of flock.
3374   ## Change this if you need to.
3375   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3376   ## configure gets the right answers, and that means *NOT* using flock.
3377   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3378   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3379   ## Debian maintainer hasn't provided a clean fix for Emacs.
3380   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3381   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3382   ## correct logic.  -- fx
3383   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3384   ## liblockfile is a Free Software replacement for libmail, used on
3385   ## Debian systems and elsewhere. -rfr.
3386   gnu-*)
3387     mail_lock="flock"
3388     if test $have_mail = yes || test $have_lockfile = yes; then
3389       test $ac_cv_header_maillock_h = yes && mail_lock=no
3390     fi
3391     ;;
3392
3393   mingw32)
3394     mail_lock="none-needed" ;;
3395 esac
3396
3397 BLESSMAIL_TARGET=
3398 case "$mail_lock" in
3399   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3400
3401   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3402
3403   none-needed) ;;
3404
3405   *) BLESSMAIL_TARGET="need-blessmail" ;;
3406 esac
3407 AC_SUBST(BLESSMAIL_TARGET)
3408
3409 OLD_LIBS=$LIBS
3410 LIBS="$LIB_MATH $LIBS"
3411 AC_CHECK_FUNCS(accept4 gethostname \
3412 getrusage get_current_dir_name \
3413 lrand48 random rint \
3414 select getpagesize setlocale \
3415 getrlimit setrlimit shutdown getaddrinfo \
3416 strsignal setitimer \
3417 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3418 gai_strerror getline getdelim sync \
3419 getpwent endpwent getgrent endgrent \
3420 cfmakeraw cfsetspeed copysign __executable_start log2)
3421 LIBS=$OLD_LIBS
3422
3423 dnl No need to check for aligned_alloc and posix_memalign if using
3424 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3425 dnl Darwin as they are incompatible with unexmacosx.c.
3426 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3427   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3428 fi
3429
3430 dnl Cannot use AC_CHECK_FUNCS
3431 AC_CACHE_CHECK([for __builtin_unwind_init],
3432                emacs_cv_func___builtin_unwind_init,
3433 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3434                 emacs_cv_func___builtin_unwind_init=yes,
3435                 emacs_cv_func___builtin_unwind_init=no)])
3436 if test $emacs_cv_func___builtin_unwind_init = yes; then
3437   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3438             [Define to 1 if you have the `__builtin_unwind_init' function.])
3439 fi
3440
3441 AC_CHECK_HEADERS_ONCE(sys/un.h)
3442
3443 AC_FUNC_FSEEKO
3444
3445 # UNIX98 PTYs.
3446 AC_CHECK_FUNCS(grantpt)
3447
3448 # PTY-related GNU extensions.
3449 AC_CHECK_FUNCS(getpt posix_openpt)
3450
3451 # Check this now, so that we will NOT find the above functions in ncurses.
3452 # That is because we have not set up to link ncurses in lib-src.
3453 # It's better to believe a function is not available
3454 # than to expect to find it in ncurses.
3455 # Also we need tputs and friends to be able to build at all.
3456 AC_MSG_CHECKING([for library containing tputs])
3457 # Run a test program that contains a call to tputs, a call that is
3458 # never executed.  This tests whether a pre-'main' dynamic linker
3459 # works with the library.  It's too much trouble to actually call
3460 # tputs in the test program, due to portability hassles.  When
3461 # cross-compiling, assume the test program will run if it links.
3462 AC_DEFUN([tputs_link_source], [
3463   AC_LANG_SOURCE(
3464      [[extern void tputs (const char *, int, int (*)(int));
3465        int main (int argc, char **argv)
3466        {
3467           if (argc == 10000)
3468             tputs (argv[0], 0, 0);
3469           return 0;
3470        }]])
3471 ])
3472 if test "${opsys}" = "mingw32"; then
3473   msg='none required'
3474 else
3475   # Maybe curses should be tried earlier?
3476   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3477   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3478     OLIBS=$LIBS
3479     if test -z "$tputs_library"; then
3480       LIBS_TERMCAP=
3481       msg='none required'
3482     else
3483       LIBS_TERMCAP=-l$tputs_library
3484       msg=$LIBS_TERMCAP
3485       LIBS="$LIBS_TERMCAP $LIBS"
3486     fi
3487     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3488       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3489     LIBS=$OLIBS
3490     if test "X$msg" != Xno; then
3491       break
3492     fi
3493   done
3494 fi
3495 AC_MSG_RESULT([$msg])
3496 if test "X$msg" = Xno; then
3497   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3498 The following libraries were tried (in order):
3499   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3500 Please try installing whichever of these libraries is most appropriate
3501 for your system, together with its header files.
3502 For example, a libncurses-dev(el) or similar package.])
3503 fi
3504
3505 ## Use termcap instead of terminfo?
3506 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3507 TERMINFO=yes
3508 ## FIXME?  In the cases below where we unconditionally set
3509 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3510 ## if that was found above to have tputs.
3511 ## Should we use the gnu* logic everywhere?
3512 case "$opsys" in
3513   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3514   ##  The ncurses library has been moved out of the System framework in
3515   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3516   ##  option to use it.
3517   darwin) LIBS_TERMCAP="-lncurses" ;;
3518
3519   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3520
3521   freebsd)
3522     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3523     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3524     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3525 [[#if __FreeBSD_version < 400000
3526 fail;
3527 #endif
3528 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3529
3530     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3531
3532     if test $emacs_cv_freebsd_terminfo = yes; then
3533       LIBS_TERMCAP="-lncurses"
3534     else
3535       TERMINFO=no
3536       LIBS_TERMCAP="-ltermcap"
3537     fi
3538     ;;
3539
3540   mingw32)
3541     TERMINFO=no
3542     LIBS_TERMCAP=
3543     ;;
3544
3545   netbsd)
3546     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3547       TERMINFO=no
3548       LIBS_TERMCAP="-ltermcap"
3549     fi
3550     ;;
3551
3552   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3553
3554   ## hpux: Make sure we get select from libc rather than from libcurses
3555   ##  because libcurses on HPUX 10.10 has a broken version of select.
3556   ##  We used to use -lc -lcurses, but this may be cleaner.
3557   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3558   # set that way, now it uses the default).  Isn't this a contradiction?
3559   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3560
3561 esac
3562
3563 TERMCAP_OBJ=tparam.o
3564 if test $TERMINFO = yes; then
3565   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3566   TERMCAP_OBJ=terminfo.o
3567 fi
3568 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3569   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3570 fi
3571 AC_SUBST(LIBS_TERMCAP)
3572 AC_SUBST(TERMCAP_OBJ)
3573
3574
3575 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3576 # On Darwin, res_init appears not to be useful: see bug#562 and
3577 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3578 resolv=no
3579
3580 if test $opsys != darwin; then
3581
3582   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3583 #include <arpa/nameser.h>
3584 #include <resolv.h>]],
3585     [[return res_init();]])],
3586     have_res_init=yes, have_res_init=no)
3587   if test "$have_res_init" = no; then
3588     OLIBS="$LIBS"
3589     LIBS="$LIBS -lresolv"
3590     AC_MSG_CHECKING(for res_init with -lresolv)
3591     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3592 #include <arpa/nameser.h>
3593 #include <resolv.h>]],
3594       [[return res_init();]])],
3595       have_res_init=yes, have_res_init=no)
3596     AC_MSG_RESULT($have_res_init)
3597     if test "$have_res_init" = yes ; then
3598       resolv=yes
3599     fi
3600     LIBS="$OLIBS"
3601   fi
3602
3603   if test "$have_res_init" = yes; then
3604     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3605   fi
3606 fi                              dnl !darwin
3607
3608 # Do we need the Hesiod library to provide the support routines?
3609 dnl FIXME?  Should we be skipping this on Darwin too?
3610 LIBHESIOD=
3611 if test "$with_hesiod" != no ; then
3612   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3613   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3614      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3615                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3616   if test "$resolv" = yes ; then
3617     RESOLVLIB=-lresolv
3618   else
3619     RESOLVLIB=
3620   fi
3621   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3622         hesiod=yes, :, $RESOLVLIB)])
3623
3624   if test x"$hesiod" = xyes; then
3625     LIBHESIOD=-lhesiod
3626   fi
3627 fi
3628 AC_SUBST(LIBHESIOD)
3629
3630 # Do we need libresolv (due to res_init or Hesiod)?
3631 if test "$resolv" = yes && test $opsys != darwin; then
3632   LIBRESOLV=-lresolv
3633 else
3634   LIBRESOLV=
3635 fi
3636 AC_SUBST(LIBRESOLV)
3637
3638 # These tell us which Kerberos-related libraries to use.
3639 COM_ERRLIB=
3640 CRYPTOLIB=
3641 KRB5LIB=
3642 DESLIB=
3643 KRB4LIB=
3644
3645 if test "${with_kerberos}" != no; then
3646   OLD_LIBS=$LIBS
3647   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3648   if test $have_com_err = yes; then
3649     COM_ERRLIB=-lcom_err
3650     LIBS="$COM_ERRLIB $LIBS"
3651   fi
3652   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3653   if test $have_crypto = yes; then
3654     CRYPTOLIB=-lcrypto
3655     LIBS="$CRYPTOLIB $LIBS"
3656   fi
3657   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3658   if test $have_k5crypto = yes; then
3659     CRYPTOLIB=-lk5crypto
3660     LIBS="$CRYPTOLIB $LIBS"
3661   fi
3662   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3663   if test $have_krb5=yes; then
3664     KRB5LIB=-lkrb5
3665     LIBS="$KRB5LIB $LIBS"
3666   fi
3667   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3668   if test "${with_kerberos5}" = no; then
3669     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3670     if test $have_des425 = yes; then
3671       DESLIB=-ldes425
3672       LIBS="$DESLIB $LIBS"
3673     else
3674       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3675       if test $have_des = yes; then
3676         DESLIB=-ldes
3677         LIBS="$DESLIB $LIBS"
3678       fi
3679     fi
3680     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3681     if test $have_krb4 = yes; then
3682       KRB4LIB=-lkrb4
3683       LIBS="$KRB4LIB $LIBS"
3684     else
3685       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3686       if test $have_krb = yes; then
3687         KRB4LIB=-lkrb
3688         LIBS="$KRB4LIB $LIBS"
3689       fi
3690     fi
3691   fi
3692
3693   if test "${with_kerberos5}" != no; then
3694     AC_CHECK_HEADERS(krb5.h,
3695       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3696                         [#include <krb5.h>])])
3697   else
3698     AC_CHECK_HEADERS(krb.h,,
3699                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3700                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3701   fi
3702   AC_CHECK_HEADERS(com_err.h)
3703   LIBS=$OLD_LIBS
3704 fi
3705
3706 AC_SUBST(COM_ERRLIB)
3707 AC_SUBST(CRYPTOLIB)
3708 AC_SUBST(KRB5LIB)
3709 AC_SUBST(DESLIB)
3710 AC_SUBST(KRB4LIB)
3711
3712 AC_CHECK_HEADERS(valgrind/valgrind.h)
3713
3714 AC_CHECK_FUNCS_ONCE(tzset)
3715 AC_MSG_CHECKING(whether localtime caches TZ)
3716 AC_CACHE_VAL(emacs_cv_localtime_cache,
3717 [if test x$ac_cv_func_tzset = xyes; then
3718 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3719 char TZ_GMT0[] = "TZ=GMT0";
3720 char TZ_PST8[] = "TZ=PST8";
3721 main()
3722 {
3723   time_t now = time ((time_t *) 0);
3724   int hour_GMT0, hour_unset;
3725   if (putenv (TZ_GMT0) != 0)
3726     exit (1);
3727   hour_GMT0 = localtime (&now)->tm_hour;
3728   unsetenv("TZ");
3729   hour_unset = localtime (&now)->tm_hour;
3730   if (putenv (TZ_PST8) != 0)
3731     exit (1);
3732   if (localtime (&now)->tm_hour == hour_GMT0)
3733     exit (1);
3734   unsetenv("TZ");
3735   if (localtime (&now)->tm_hour != hour_unset)
3736     exit (1);
3737   exit (0);
3738 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3739 [# If we have tzset, assume the worst when cross-compiling.
3740 emacs_cv_localtime_cache=yes])
3741 else
3742         # If we lack tzset, report that localtime does not cache TZ,
3743         # since we can't invalidate the cache if we don't have tzset.
3744         emacs_cv_localtime_cache=no
3745 fi])dnl
3746 AC_MSG_RESULT($emacs_cv_localtime_cache)
3747 if test $emacs_cv_localtime_cache = yes; then
3748   AC_DEFINE(LOCALTIME_CACHE, 1,
3749             [Define to 1 if localtime caches TZ.])
3750 fi
3751
3752 ok_so_far=yes
3753 AC_CHECK_FUNC(socket, , ok_so_far=no)
3754 if test $ok_so_far = yes; then
3755   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3756 fi
3757 if test $ok_so_far = yes; then
3758   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3759 fi
3760 if test $ok_so_far = yes; then
3761 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3762   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3763             [Define to 1 if you have inet sockets.])
3764 fi
3765
3766 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3767 dnl This can be removed once we assume Autoconf 2.70.
3768 case $canonical in
3769   *-solaris2.4 | *-solaris2.4.*)
3770     dnl Disable the Autoconf-generated vfork test.
3771     : ${ac_cv_func_vfork_works=no};;
3772 esac
3773
3774 AC_FUNC_FORK
3775
3776 AC_CHECK_FUNCS(snprintf)
3777
3778 dnl Check for glib.  This differs from other library checks in that
3779 dnl Emacs need not link to glib unless some other library is already
3780 dnl linking to glib.  Although glib provides no facilities that Emacs
3781 dnl needs for its own purposes, when glib is present Emacs needs to
3782 dnl use primitives like g_main_context_query to avoid clashing with
3783 dnl glib at a low level.
3784 dnl
3785 dnl Check this late, since it depends on $GTK_CFLAGS etc.
3786 XGSELOBJ=
3787 OLDCFLAGS="$CFLAGS"
3788 OLDLIBS="$LIBS"
3789 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
3790 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
3791 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3792 LIBS="$LIBS $GFILENOTIFY_LIBS"
3793 AC_MSG_CHECKING([whether GLib is linked in])
3794 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3795         [[#include <glib.h>
3796         ]],
3797         [[g_print ("Hello world");]])],
3798      [links_glib=yes],
3799      [links_glib=no])
3800 AC_MSG_RESULT([$links_glib])
3801 if test "${links_glib}" = "yes"; then
3802   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3803   if test "$HAVE_NS" = no;then
3804     XGSELOBJ=xgselect.o
3805   fi
3806 fi
3807 CFLAGS="$OLDCFLAGS"
3808 LIBS="$OLDLIBS"
3809 AC_SUBST(XGSELOBJ)
3810
3811 dnl Adapted from Haible's version.
3812 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3813   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3814     [[char* cs = nl_langinfo(CODESET);]])],
3815     emacs_cv_langinfo_codeset=yes,
3816     emacs_cv_langinfo_codeset=no)
3817   ])
3818 if test $emacs_cv_langinfo_codeset = yes; then
3819   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3820     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3821 fi
3822
3823 AC_TYPE_MBSTATE_T
3824
3825 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3826   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3827                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3828 if test "$emacs_cv_c_restrict_arr" = yes; then
3829   AC_DEFINE(__restrict_arr, __restrict,
3830     [Define to compiler's equivalent of C99 restrict keyword in array
3831      declarations.  Define as empty for no equivalent.])
3832 fi
3833
3834 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3835 dnl how the tty code is related to POSIX and/or other versions of termios.
3836 dnl The following looks like a useful start.
3837 dnl
3838 dnl AC_SYS_POSIX_TERMIOS
3839 dnl if test $ac_cv_sys_posix_termios = yes; then
3840 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3841 dnl                                and macros for terminal control.])
3842 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3843 dnl fi
3844
3845 dnl Turned on June 1996 supposing nobody will mind it.
3846 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3847 if test "${opsys}" != "mingw32"; then
3848    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3849      in the full name stands for the login id.])
3850 fi
3851
3852 dnl Everybody supports this, except MS.
3853 dnl Seems like the kind of thing we should be testing for, though.
3854 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3855 if test "${opsys}" != "mingw32"; then
3856   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3857 fi
3858
3859 dnl Everybody supports this, except MS-DOS.
3860 dnl Seems like the kind of thing we should be testing for, though.
3861 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3862 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3863   4.2-compatible sockets.])
3864
3865 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3866
3867 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3868   a null file, or a data sink.])
3869 if test "${opsys}" = "mingw32"; then
3870   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3871 else
3872   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3873 fi
3874
3875 if test "${opsys}" = "mingw32"; then
3876   SEPCHAR=';'
3877 else
3878   SEPCHAR=':'
3879 fi
3880 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
3881 dnl This is for MinGW, and is used in test/automated/Makefile.in.
3882 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
3883 dnl decides that a command-line argument to be passed to a MinGW program
3884 dnl is a PATH-style list of directories.  But that heuristics plays it
3885 dnl safe, and only does the replacement when it is _absolutely_ sure it
3886 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
3887 dnl which breaks in-tree builds.  So we do this manually instead.
3888 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
3889 dnl be computed as ':' in MSYS Bash.
3890 AC_SUBST(SEPCHAR)
3891
3892 dnl Everybody supports this, except MS-DOS.
3893 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3894
3895 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3896
3897
3898 AC_DEFINE(DIRECTORY_SEP, ['/'],
3899   [Character that separates directories in a file name.])
3900
3901 if test "${opsys}" = "mingw32"; then
3902   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
3903     [Returns true if character is a device separator.])
3904
3905   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3906     [Returns true if character is a directory separator.])
3907
3908   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3909     [Returns true if character is any form of separator.])
3910 else
3911   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3912     [Returns true if character is a device separator.])
3913
3914   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3915     [Returns true if character is a directory separator.])
3916
3917   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3918     [Returns true if character is any form of separator.])
3919 fi
3920
3921 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3922
3923 case $opsys in
3924   aix4-2)
3925     dnl Unfortunately without libXmu we cannot support EditRes.
3926     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
3927       AC_DEFINE(NO_EDITRES, 1)
3928     fi
3929     ;;
3930
3931   hpux*)
3932     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3933     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3934     AC_DEFINE(NO_EDITRES, 1)
3935     ;;
3936 esac
3937
3938
3939 case $opsys in
3940   irix6-5 | sol2* | unixware )
3941     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3942     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3943     dnl need the constant to dimension an array.  So wire in the appropriate
3944     dnl value here.
3945     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3946     ;;
3947 esac
3948
3949 emacs_broken_SIGIO=no
3950
3951 case $opsys in
3952   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3953   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3954   hpux* | irix6-5 | openbsd | sol2* | unixware )
3955     emacs_broken_SIGIO=yes
3956     ;;
3957
3958   aix4-2)
3959     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3960     dnl the way this system works, libc functions that return malloced
3961     dnl memory use the libc malloc implementation. Calling xfree or
3962     dnl xrealloc on the results of such functions results in a crash.
3963     dnl
3964     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3965     dnl but that does not currently work on this system.
3966     dnl
3967     dnl It is possible to completely override the malloc implementation on
3968     dnl AIX, but that involves putting the malloc functions in a shared
3969     dnl library and setting the MALLOCTYPE environment variable to point to
3970     dnl that shared library.
3971     dnl
3972     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3973     dnl to avoid a crash just use the Emacs implementation for that function.
3974     dnl
3975     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3976     dnl of this file, so that we do not check for get_current_dir_name
3977     dnl on AIX.  But that might be fragile if something else ends
3978     dnl up testing for get_current_dir_name as a dependency.
3979     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3980       get_current_dir_name should not be used.])
3981     ;;
3982
3983   freebsd)
3984     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3985     dnl writes/reads on a PTY, read(2) returns bogus data:
3986     dnl
3987     dnl write(2)  1022 bytes
3988     dnl write(2)   954 bytes, get EAGAIN
3989     dnl read(2)   1024 bytes in process_read_output
3990     dnl read(2)     11 bytes in process_read_output
3991     dnl
3992     dnl That is, read(2) returns more bytes than have ever been written
3993     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3994     dnl successfully after processing (for example with CRs added if the
3995     dnl terminal is set up that way which it is here).  The same bytes will
3996     dnl be seen again in a later read(2), without the CRs.
3997     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3998       work around an issue when reading from a PTY.])
3999     ;;
4000 esac
4001
4002 case $opsys in
4003   gnu-* | sol2-10 )
4004     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4005     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4006   ;;
4007 esac
4008
4009 case $opsys in
4010   darwin | dragonfly | freebsd | netbsd | openbsd )
4011     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4012       close a pty to make it a controlling terminal (it is already a
4013       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4014   ;;
4015 esac
4016
4017 dnl FIXME Surely we can test for this rather than hard-code it.
4018 case $opsys in
4019   netbsd | openbsd) sound_device="/dev/audio" ;;
4020   *) sound_device="/dev/dsp" ;;
4021 esac
4022
4023 dnl Used in sound.c
4024 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4025   [Name of the default sound device.])
4026
4027
4028 dnl Emacs can read input using SIGIO and buffering characters itself,
4029 dnl or using CBREAK mode and making C-g cause SIGINT.
4030 dnl The choice is controlled by the variable interrupt_input.
4031 dnl
4032 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4033 dnl
4034 dnl Emacs uses the presence of the USABLE_SIGIO macro
4035 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4036 dnl INTERRUPT_INPUT to decide whether to use it by default.
4037 dnl
4038 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4039 dnl CBREAK mode has two disadvantages
4040 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4041 dnl I hear that in system V this problem does not exist.
4042 dnl 2) Control-G causes output to be discarded.
4043 dnl I do not know whether this can be fixed in system V.
4044 dnl
4045 dnl Another method of doing input is planned but not implemented.
4046 dnl It would have Emacs fork off a separate process
4047 dnl to read the input and send it to the true Emacs process
4048 dnl through a pipe.
4049 case $opsys in
4050   darwin | gnu-linux | gnu-kfreebsd )
4051     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4052   ;;
4053 esac
4054
4055
4056 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4057 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4058 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4059 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4060 dnl taking float or double parameters.
4061 case $opsys in
4062   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4063     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4064       file defines `NeedWidePrototypes' as `NO'.])
4065   ;;
4066 esac
4067
4068
4069 dnl Used in process.c, this must be a loop, even if it only runs once.
4070 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4071 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4072 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4073 dnl trying suffixes 0-16.
4074 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4075   first PTY, if PTYs are supported.])
4076 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4077 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4078   end of a PTY, if non-standard.])
4079 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4080   end of a PTY, if non-standard.])
4081
4082 case $opsys in
4083   aix4-2 )
4084     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4085     dnl You allocate a pty by opening /dev/ptc to get the master side.
4086     dnl To get the name of the slave side, you just ttyname() the master side.
4087     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4088     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4089     ;;
4090
4091   cygwin )
4092     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4093     dnl multi-line AC_DEFINEs are hard. :(
4094     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4095     AC_DEFINE(PTY_NAME_SPRINTF, [])
4096     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4097     ;;
4098
4099   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4100   darwin )
4101     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4102     dnl Not used, because PTY_ITERATION is defined.
4103     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4104     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4105     dnl But we don't have to block SIGCHLD because it is blocked in the
4106     dnl implementation of grantpt.
4107     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4108     AC_DEFINE(PTY_NAME_SPRINTF, [])
4109     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4110     ;;
4111
4112   gnu | openbsd )
4113     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4114     ;;
4115
4116   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4117     dnl if HAVE_GRANTPT
4118     if test "x$ac_cv_func_grantpt" = xyes; then
4119       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4120       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4121       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4122       dnl to prevent sigchld_handler from intercepting the child's death.
4123       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4124       dnl if HAVE_POSIX_OPENPT
4125       if test "x$ac_cv_func_posix_openpt" = xyes; then
4126         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4127         AC_DEFINE(PTY_NAME_SPRINTF, [])
4128       dnl if HAVE_GETPT
4129       elif test "x$ac_cv_func_getpt" = xyes; then
4130         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4131         AC_DEFINE(PTY_NAME_SPRINTF, [])
4132       else
4133         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4134       fi
4135     else
4136       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4137     fi
4138     ;;
4139
4140   hpux*)
4141     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4142     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4143     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4144     ;;
4145
4146   irix6-5 )
4147     dnl It looks like this cannot be right, because it is not a loop.
4148     dnl However, process.c actually does this:
4149     dnl # ifndef __sgi
4150     dnl   continue;
4151     dnl # else
4152     dnl   return -1;
4153     dnl # endif
4154     dnl which presumably makes it OK, since irix == sgi (?).
4155     dnl FIXME it seems like this special treatment is unnecessary?
4156     dnl Why can't irix use a single-trip loop like eg cygwin?
4157     AC_DEFINE(PTY_ITERATION, [])
4158     dnl Not used, because PTY_ITERATION is defined.
4159     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4160     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4161     dnl No need to get the pty name at all.
4162     AC_DEFINE(PTY_NAME_SPRINTF, [])
4163     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4164     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4165     ;;
4166
4167   sol2* )
4168     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4169     dnl from intercepting that death.  If any child but grantpt's should die
4170     dnl within, it should be caught after sigrelse(2).
4171     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4172     ;;
4173
4174   unixware )
4175     dnl Comments are as per sol2*.
4176     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4177     ;;
4178 esac
4179
4180
4181 case $opsys in
4182   sol2* | unixware )
4183     dnl This change means that we don't loop through allocate_pty too
4184     dnl many times in the (rare) event of a failure.
4185     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4186     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4187     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4188     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4189     ;;
4190 esac
4191
4192
4193 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4194 "typing" a signal character on the pty.])
4195
4196 case $opsys in
4197   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4198   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4199   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4200     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4201     ;;
4202
4203   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4204   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4205   gnu-linux | gnu-kfreebsd )
4206
4207     AC_MSG_CHECKING([for signals via characters])
4208     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4209 #include <linux/version.h>
4210 #if LINUX_VERSION_CODE < 0x20400
4211 # error "Linux version too old"
4212 #endif
4213       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4214
4215     AC_MSG_RESULT([$emacs_signals_via_chars])
4216     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4217     ;;
4218 esac
4219
4220
4221 AH_TEMPLATE(TAB3, [Undocumented.])
4222
4223 case $opsys in
4224   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4225
4226   gnu | dragonfly | freebsd | netbsd | openbsd )
4227     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4228     AC_DEFINE(TAB3, OXTABS)
4229     ;;
4230
4231   gnu-linux | gnu-kfreebsd )
4232     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4233 #ifndef __ia64__
4234 # error "not ia64"
4235 #endif
4236       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4237         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4238         [Mark a secondary stack, like the register stack on the ia64.]), [])
4239     ;;
4240
4241   hpux*)
4242     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4243       run_time_remap; for HPUX.])
4244     ;;
4245 esac
4246
4247
4248 dnl This won't be used automatically yet.  We also need to know, at least,
4249 dnl that the stack is continuous.
4250 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4251   registers relevant for conservative garbage collection in the jmp_buf.])
4252
4253
4254 case $opsys in
4255   dnl Not all the architectures are tested, but there are Debian packages
4256   dnl for SCM and/or Guile on them, so the technique must work.  See also
4257   dnl comments in alloc.c concerning setjmp and gcc.
4258   dnl Fixme: it's probably safe to just use the GCC conditional below.
4259   gnu-linux | gnu-kfreebsd )
4260     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4261 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4262   || defined __alpha__ || defined __mips__ || defined __s390__ \
4263   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4264   || defined __ia64__ || defined __sh__
4265 /* ok */
4266 #else
4267 # error "setjmp not known to work on this arch"
4268 #endif
4269     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4270     ;;
4271 esac
4272
4273
4274 if test x$GCC = xyes; then
4275    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4276    AC_DEFINE(GC_SETJMP_WORKS, 1)
4277 else
4278   case $opsys in
4279     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4280     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4281       AC_DEFINE(GC_SETJMP_WORKS, 1)
4282       ;;
4283   esac
4284 fi                              dnl GCC?
4285
4286 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4287 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4288   [AC_LINK_IFELSE(
4289      [AC_LANG_PROGRAM(
4290        [[#include <setjmp.h>
4291          #ifdef __MINGW32__
4292          # define _longjmp longjmp
4293          #endif
4294        ]],
4295        [[jmp_buf j;
4296          if (! _setjmp (j))
4297            _longjmp (j, 1);]])],
4298      [emacs_cv_func__setjmp=yes],
4299      [emacs_cv_func__setjmp=no])])
4300 if test $emacs_cv_func__setjmp = yes; then
4301   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4302 else
4303   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4304     [AC_LINK_IFELSE(
4305        [AC_LANG_PROGRAM(
4306          [[#include <setjmp.h>
4307          ]],
4308          [[sigjmp_buf j;
4309            if (! sigsetjmp (j, 1))
4310              siglongjmp (j, 1);]])],
4311        [emacs_cv_func_sigsetjmp=yes],
4312        [emacs_cv_func_sigsetjmp=no])])
4313   if test $emacs_cv_func_sigsetjmp = yes; then
4314     AC_DEFINE([HAVE_SIGSETJMP], 1,
4315       [Define to 1 if sigsetjmp and siglongjmp work.
4316        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4317   fi
4318 fi
4319
4320 case $opsys in
4321   sol2* | unixware )
4322     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4323     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4324     dnl and this is all we need.
4325     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4326     ;;
4327 esac
4328
4329
4330 case $opsys in
4331   hpux* | sol2* )
4332     dnl Used in xfaces.c.
4333     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4334       some systems, where it requires time.h.])
4335     ;;
4336 esac
4337
4338
4339 dnl Define symbols to identify the version of Unix this is.
4340 dnl Define all the symbols that apply correctly.
4341 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4342 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4343 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4344 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4345
4346 case $opsys in
4347   aix4-2)
4348     AC_DEFINE(USG, [])
4349     dnl This symbol should be defined on AIX Version 3  ???????
4350     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4351 #ifndef _AIX
4352 # error "_AIX not defined"
4353 #endif
4354     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4355     ;;
4356
4357   cygwin)
4358     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4359     ;;
4360
4361   darwin)
4362     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4363     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4364     dnl distinguish OS X from pure Darwin.
4365     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4366     ;;
4367
4368   gnu-linux | gnu-kfreebsd )
4369     AC_DEFINE(USG, [])
4370     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4371     ;;
4372
4373   hpux*)
4374     AC_DEFINE(USG, [])
4375     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4376     ;;
4377
4378   irix6-5)
4379     AC_DEFINE(USG, [])
4380     AC_DEFINE(USG5_4, [])
4381     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4382     ;;
4383
4384   mingw32)
4385     AC_DEFINE(DOS_NT, [])
4386     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4387     if test "x$ac_enable_checking" != "x" ; then
4388       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4389     fi
4390     ;;
4391
4392   sol2*)
4393     AC_DEFINE(USG, [])
4394     AC_DEFINE(USG5_4, [])
4395     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4396     ;;
4397
4398   unixware)
4399     AC_DEFINE(USG, [])
4400     AC_DEFINE(USG5_4, [])
4401     ;;
4402 esac
4403
4404 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4405   [case $opsys in
4406      aix4-2)
4407        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4408        emacs_cv_usable_FIONREAD=no
4409        ;;
4410
4411      mingw32)
4412        emacs_cv_usable_FIONREAD=yes
4413        ;;
4414
4415      *)
4416        AC_COMPILE_IFELSE(
4417          [AC_LANG_PROGRAM([[#include <sys/types.h>
4418                             #include <sys/ioctl.h>
4419                             #ifdef USG5_4
4420                             # include <sys/filio.h>
4421                             #endif
4422                           ]],
4423                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4424          [emacs_cv_usable_FIONREAD=yes],
4425          [emacs_cv_usable_FIONREAD=no])
4426        ;;
4427    esac])
4428 if test $emacs_cv_usable_FIONREAD = yes; then
4429   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4430
4431   if test $emacs_broken_SIGIO = no; then
4432     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4433       [AC_COMPILE_IFELSE(
4434          [AC_LANG_PROGRAM([[#include <fcntl.h>
4435                             #include <signal.h>
4436                           ]],
4437                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4438          [emacs_cv_usable_SIGIO=yes],
4439          [emacs_cv_usable_SIGIO=no])],
4440       [emacs_cv_usable_SIGIO=yes],
4441       [emacs_cv_usable_SIGIO=no])
4442     if test $emacs_cv_usable_SIGIO = yes; then
4443       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4444     fi
4445   fi
4446 fi
4447
4448
4449 case $opsys in
4450   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4451   dnl and on Cygwin prior to version 1.7.24 that becomes the
4452   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4453   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4454   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4455   dnl needed starting with cygwin-1.7.24, and it is no longer
4456   dnl effective starting with glib-2.36. */
4457   cygwin)
4458     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4459       G_SLICE environment variable to "always-malloc" at startup.])
4460     ;;
4461
4462   hpux11)
4463     dnl It works to open the pty's tty in the parent (Emacs), then
4464     dnl close and reopen it in the child.
4465     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4466       works to open a pty's tty in the parent process, then close and
4467       reopen it in the child.])
4468     ;;
4469
4470   irix6-5)
4471     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4472       use VSUSP instead of VSWTCH.])
4473     ;;
4474
4475   sol2-10)
4476     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4477       on Solaris.])
4478     ;;
4479 esac
4480
4481 # Set up the CFLAGS for real compilation, so we can substitute it.
4482 CFLAGS="$REAL_CFLAGS"
4483 CPPFLAGS="$REAL_CPPFLAGS"
4484 LIBS="$REAL_LIBS"
4485
4486 ## Hack to detect a buggy GCC version.
4487 if test "x$GCC" = xyes \
4488    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4489    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4490    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4491    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4492 fi
4493
4494 version=$PACKAGE_VERSION
4495
4496 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4497 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4498   [Short copyright string for this version of Emacs.])
4499 AC_SUBST(copyright)
4500
4501 ### Specify what sort of things we'll be editing into Makefile and config.h.
4502 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4503 AC_SUBST(version)
4504 AC_SUBST(configuration)
4505 ## Unused?
4506 AC_SUBST(canonical)
4507 AC_SUBST(srcdir)
4508 AC_SUBST(prefix)
4509 AC_SUBST(exec_prefix)
4510 AC_SUBST(bindir)
4511 AC_SUBST(datadir)
4512 AC_SUBST(sharedstatedir)
4513 AC_SUBST(libexecdir)
4514 AC_SUBST(mandir)
4515 AC_SUBST(infodir)
4516 AC_SUBST(lispdir)
4517 AC_SUBST(standardlisppath)
4518 AC_SUBST(locallisppath)
4519 AC_SUBST(lisppath)
4520 AC_SUBST(x_default_search_path)
4521 AC_SUBST(etcdir)
4522 AC_SUBST(archlibdir)
4523 AC_SUBST(etcdocdir)
4524 AC_SUBST(bitmapdir)
4525 AC_SUBST(gamedir)
4526 AC_SUBST(gameuser)
4527 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4528 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4529 ## end of LIBX_BASE, but nothing ever set it.
4530 AC_SUBST(LD_SWITCH_X_SITE)
4531 AC_SUBST(C_SWITCH_X_SITE)
4532 AC_SUBST(GNUSTEP_CFLAGS)
4533 AC_SUBST(CFLAGS)
4534 ## Used in lwlib/Makefile.in.
4535 AC_SUBST(X_TOOLKIT_TYPE)
4536 AC_SUBST(ns_appdir)
4537 AC_SUBST(ns_appbindir)
4538 AC_SUBST(ns_appresdir)
4539 AC_SUBST(ns_appsrc)
4540 AC_SUBST(GNU_OBJC_CFLAGS)
4541 AC_SUBST(OTHER_FILES)
4542
4543 if test -n "${term_header}"; then
4544     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4545         [Define to the header for the built-in window system.])
4546 fi
4547
4548 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4549                    [Define to the canonical Emacs configuration name.])
4550 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4551                    [Define to the options passed to configure.])
4552 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4553   define this to include extra configuration information.])
4554
4555 case $opsys in
4556   mingw32)
4557     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4558     ;;
4559 esac
4560
4561 XMENU_OBJ=
4562 XOBJ=
4563 FONT_OBJ=
4564 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4565   AC_DEFINE(HAVE_X_WINDOWS, 1,
4566             [Define to 1 if you want to use the X window system.])
4567   XMENU_OBJ=xmenu.o
4568   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4569   FONT_OBJ=xfont.o
4570   if test "$HAVE_XFT" = "yes"; then
4571     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4572   elif test "$HAVE_FREETYPE" = "yes"; then
4573     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4574   fi
4575   AC_SUBST(FONT_OBJ)
4576 fi
4577 AC_SUBST(XMENU_OBJ)
4578 AC_SUBST(XOBJ)
4579 AC_SUBST(FONT_OBJ)
4580
4581 WIDGET_OBJ=
4582 MOTIF_LIBW=
4583 if test "${USE_X_TOOLKIT}" != "none" ; then
4584   WIDGET_OBJ=widget.o
4585   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4586   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4587     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4588   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4589     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4590     MOTIF_LIBW=-lXm
4591     case "$opsys" in
4592       gnu-linux)
4593         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4594         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4595         ;;
4596
4597       unixware)
4598         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4599         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4600         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4601         ;;
4602
4603       aix4-2)
4604         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4605         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4606         ;;
4607     esac
4608     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4609   fi
4610 fi
4611 AC_SUBST(WIDGET_OBJ)
4612
4613 TOOLKIT_LIBW=
4614 case "$USE_X_TOOLKIT" in
4615   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4616   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4617   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4618 esac
4619 AC_SUBST(TOOLKIT_LIBW)
4620
4621 if test "${opsys}" != "mingw32"; then
4622   if test "$USE_X_TOOLKIT" = "none"; then
4623     LIBXT_OTHER="\$(LIBXSM)"
4624   else
4625     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4626   fi
4627 fi
4628 AC_SUBST(LIBXT_OTHER)
4629
4630 if test "${HAVE_X11}" = "yes" ; then
4631   AC_DEFINE(HAVE_X11, 1,
4632             [Define to 1 if you want to use version 11 of X windows.])
4633   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4634 else
4635   LIBX_OTHER=
4636 fi
4637 AC_SUBST(LIBX_OTHER)
4638
4639 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4640   LIBXMENU=
4641 elif test "$USE_X_TOOLKIT" = none; then
4642   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4643 else
4644   LIBXMENU='$(lwlibdir)/liblw.a'
4645 fi
4646 AC_SUBST(LIBXMENU)
4647
4648 if test "${GNU_MALLOC}" = "yes" ; then
4649   AC_DEFINE(GNU_MALLOC, 1,
4650             [Define to 1 if you want to use the GNU memory allocator.])
4651 fi
4652
4653 RALLOC_OBJ=
4654 if test "${REL_ALLOC}" = "yes" ; then
4655   AC_DEFINE(REL_ALLOC, 1,
4656             [Define REL_ALLOC if you want to use the relocating allocator for
4657              buffer space.])
4658
4659   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4660 fi
4661 AC_SUBST(RALLOC_OBJ)
4662
4663 if test "$opsys" = "cygwin"; then
4664   CYGWIN_OBJ="sheap.o cygw32.o"
4665   ## Cygwin differs because of its unexec().
4666   PRE_ALLOC_OBJ=
4667   POST_ALLOC_OBJ=lastfile.o
4668 elif test "$opsys" = "mingw32"; then
4669   CYGWIN_OBJ=
4670   PRE_ALLOC_OBJ=
4671   POST_ALLOC_OBJ=lastfile.o
4672 else
4673   CYGWIN_OBJ=
4674   PRE_ALLOC_OBJ=lastfile.o
4675   POST_ALLOC_OBJ=
4676 fi
4677 AC_SUBST(CYGWIN_OBJ)
4678 AC_SUBST(PRE_ALLOC_OBJ)
4679 AC_SUBST(POST_ALLOC_OBJ)
4680
4681 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4682 dnl verbatim defined above.  The tricky name is apropos, as this hack
4683 dnl makes Fortify go sour!
4684 AH_VERBATIM([FORTIFY_SOUR],
4685 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4686    The workaround disables some useful run-time checking, so it
4687    should be conditional to the platforms with the performance bug.
4688    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4689 #if defined __APPLE__ && defined __GNUC__
4690 # ifndef _DONT_USE_CTYPE_INLINE_
4691 #  define _DONT_USE_CTYPE_INLINE_
4692 # endif
4693 # ifndef _FORTIFY_SOURCE
4694 #  define _FORTIFY_SOURCE 0
4695 # endif
4696 #endif
4697 ])
4698
4699 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4700 # it temporarily reverts them to their pre-pkg-config values,
4701 # because gnulib needs to work with both src (which uses the
4702 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4703 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4704 # and it therefore needs to run in an environment where LIBS does not
4705 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4706 # for some package unrelated to lib-src.
4707 SAVE_CFLAGS=$CFLAGS
4708 SAVE_LIBS=$LIBS
4709 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4710 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4711 gl_ASSERT_NO_GNULIB_POSIXCHECK
4712 gl_ASSERT_NO_GNULIB_TESTS
4713 gl_INIT
4714 CFLAGS=$SAVE_CFLAGS
4715 LIBS=$SAVE_LIBS
4716
4717 if test "${opsys}" = "mingw32"; then
4718   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4719   # Remove unneeded switches from the value of CC that goes to Makefiles
4720   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4721 fi
4722
4723 case "$opsys" in
4724   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4725
4726   darwin)
4727    ## The -headerpad option tells ld (see man page) to leave room at the
4728    ## end of the header for adding load commands.  Needed for dumping.
4729    ## 0x690 is the total size of 30 segment load commands (at 56
4730    ## each); under Cocoa 31 commands are required.
4731    if test "$HAVE_NS" = "yes"; then
4732      libs_nsgui="-framework AppKit"
4733      if test "$NS_IMPL_COCOA" = "yes"; then
4734         libs_nsgui="$libs_nsgui -framework IOKit"
4735      fi
4736      headerpad_extra=6C8
4737    else
4738      libs_nsgui=
4739      headerpad_extra=690
4740    fi
4741    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4742
4743    ## This is here because src/Makefile.in did some extra fiddling around
4744    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4745    ## LD_SWITCH_SYSTEM_TEMACS instead,
4746    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4747      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4748    ;;
4749
4750   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4751   ## find X at run-time.
4752   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4753   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4754   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4755   ## had different values in configure (in ac_link) and src/Makefile.in.
4756   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4757   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4758
4759   mingw32)
4760    ## MinGW64 does not prepend an underscore to symbols, so we must
4761    ## pass a different -entry switch to linker.  FIXME: It is better
4762    ## to make the entry points the same by changing unexw32.c.
4763    case "$canonical" in
4764      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4765      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4766    esac
4767    ;;
4768
4769   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4770
4771   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4772 esac
4773
4774 if test x$ac_enable_profiling != x ; then
4775   case $opsys in
4776     *freebsd | gnu-linux) ;;
4777     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4778   esac
4779 fi
4780
4781 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4782
4783 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4784
4785 ## MinGW-specific post-link processing of temacs.
4786 TEMACS_POST_LINK=":"
4787 ADDSECTION=
4788 EMACS_HEAPSIZE=
4789 if test "${opsys}" = "mingw32"; then
4790   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4791   ADDSECTION="../nt/addsection\$(EXEEXT)"
4792   ## Preload heap size of temacs.exe in MB.
4793   case "$canonical" in
4794     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4795     *) EMACS_HEAPSIZE=27 ;;
4796   esac
4797 fi
4798
4799 AC_SUBST(ADDSECTION)
4800 AC_SUBST(TEMACS_POST_LINK)
4801 AC_SUBST(EMACS_HEAPSIZE)
4802
4803 ## Common for all window systems
4804 if test "$window_system" != "none"; then
4805   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4806   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4807 fi
4808
4809 AC_SUBST(WINDOW_SYSTEM_OBJ)
4810
4811 AH_TOP([/* GNU Emacs site configuration template file.
4812
4813 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4814   Free Software Foundation, Inc.
4815
4816 This file is part of GNU Emacs.
4817
4818 GNU Emacs is free software: you can redistribute it and/or modify
4819 it under the terms of the GNU General Public License as published by
4820 the Free Software Foundation, either version 3 of the License, or
4821 (at your option) any later version.
4822
4823 GNU Emacs is distributed in the hope that it will be useful,
4824 but WITHOUT ANY WARRANTY; without even the implied warranty of
4825 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4826 GNU General Public License for more details.
4827
4828 You should have received a copy of the GNU General Public License
4829 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4830
4831
4832 /* No code in Emacs #includes config.h twice, but some bits of code
4833    intended to work with other packages as well (like gmalloc.c)
4834    think they can include it as many times as they like.  */
4835 #ifndef EMACS_CONFIG_H
4836 #define EMACS_CONFIG_H
4837 ])dnl
4838
4839 AH_BOTTOM([#include <conf_post.h>
4840
4841 #endif /* EMACS_CONFIG_H */
4842
4843 /*
4844 Local Variables:
4845 mode: c
4846 End:
4847 */
4848 ])dnl
4849
4850 #### Report on what we decided to do.
4851 #### Report GTK as a toolkit, even if it doesn't use Xt.
4852 #### It makes printing result more understandable as using GTK sets
4853 #### toolkit_scroll_bars to yes by default.
4854 if test "${HAVE_GTK}" = "yes"; then
4855   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4856 fi
4857
4858 if test $USE_ACL -ne 0; then
4859   ACL_SUMMARY="yes $LIB_ACL"
4860 else
4861   ACL_SUMMARY=no
4862 fi
4863
4864 echo "
4865 Configured for \`${canonical}'.
4866
4867   Where should the build process find the source code?    ${srcdir}
4868   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4869   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4870   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4871   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4872   What window system should Emacs use?                    ${window_system}
4873   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4874
4875 if test -n "${x_includes}"; then
4876 echo "  Where do we find X Windows header files?                ${x_includes}"
4877 else
4878 echo "  Where do we find X Windows header files?                Standard dirs"
4879 fi
4880 if test -n "${x_libraries}"; then
4881 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4882 else
4883 echo "  Where do we find X Windows libraries?                   Standard dirs"
4884 fi
4885
4886 optsep=
4887 emacs_config_features=
4888 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
4889   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
4890   LIBOTF XFT ZLIB; do
4891
4892     case $opt in
4893       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
4894       *) eval val=\${HAVE_$opt} ;;
4895     esac
4896     test x"$val" = xno && continue
4897     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
4898     optsep=' '
4899 done
4900 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
4901   [Summary of some of the main features enabled by configure.])
4902
4903 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4904 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4905 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4906 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4907 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4908 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
4909 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4910 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4911
4912 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
4913
4914 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4915 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4916 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4917 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4918 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4919 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
4920 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4921 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4922 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4923
4924 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4925 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4926 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4927 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4928 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
4929
4930 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4931 echo
4932
4933 if test -n "${EMACSDATA}"; then
4934    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4935 fi
4936 if test -n "${EMACSDOC}"; then
4937    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4938 fi
4939
4940 echo
4941
4942 if test "$HAVE_NS" = "yes"; then
4943    echo
4944    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4945 The installed application will go to nextstep/Emacs.app and can be
4946 run or moved from there."
4947    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4948       echo "The application will be fully self-contained."
4949     else
4950       echo "The lisp resources for the application will be installed under ${prefix}.
4951 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4952 to run if these resources are not installed."
4953    fi
4954    echo
4955 fi
4956
4957 if test "${opsys}" = "cygwin"; then
4958   case `uname -r` in
4959     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4960            echo
4961            ;;
4962   esac
4963 fi
4964
4965 # Remove any trailing slashes in these variables.
4966 [test "${prefix}" != NONE &&
4967   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4968 test "${exec_prefix}" != NONE &&
4969   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4970
4971 if test "$HAVE_NS" = "yes"; then
4972   if test "$NS_IMPL_GNUSTEP" = yes; then
4973     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4974       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4975     ns_check_file=Resources/Info-gnustep.plist
4976   else
4977     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4978       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4979     ns_check_file=Contents/Info.plist
4980   fi
4981   AC_SUBST(ns_check_file)
4982 fi
4983
4984 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4985 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4986 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4987 dnl (else you get "no `Makefile.am' found for any configure output").
4988 dnl This will work, but you get a config.status that is not quite right
4989 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4990 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4991 dnl it seems better to just live with the duplication.
4992 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
4993
4994 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4995        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4996        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4997        leim/Makefile nextstep/Makefile nt/Makefile])
4998
4999 dnl test/ is not present in release tarfiles.
5000 opt_makefile=test/automated/Makefile
5001
5002 if test -f "$srcdir/$opt_makefile.in"; then
5003   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5004   dnl Again, it's best not to use a variable.  Though you can add
5005   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5006   AC_CONFIG_FILES([test/automated/Makefile])
5007 fi
5008
5009
5010 dnl The admin/ directory used to be excluded from tarfiles.
5011 if test -d $srcdir/admin; then
5012   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5013   AC_CONFIG_FILES([admin/unidata/Makefile])
5014   AC_CONFIG_FILES([admin/grammars/Makefile])
5015 fi                              dnl -d admin
5016
5017
5018 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5019
5020 AC_SUBST(SUBDIR_MAKEFILES_IN)
5021
5022 dnl You might wonder (I did) why epaths.h is generated by running make,
5023 dnl rather than just letting configure generate it from epaths.in.
5024 dnl One reason is that the various paths are not fully expanded (see above);
5025 dnl eg gamedir=${prefix}/var/games/emacs.
5026 dnl Secondly, the GNU Coding standards require that one should be able
5027 dnl to run `make prefix=/some/where/else' and override the values set
5028 dnl by configure.  This also explains the `move-if-change' test and
5029 dnl the use of force in the `epaths-force' rule in Makefile.in.
5030 AC_CONFIG_COMMANDS([src/epaths.h], [
5031 if test "${opsys}" = "mingw32"; then
5032   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5033 else
5034   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5035 fi
5036 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5037
5038 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5039 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5040 dnl or a symlink?
5041 AC_CONFIG_COMMANDS([src/.gdbinit], [
5042 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5043   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5044 fi
5045 ])
5046
5047 AC_OUTPUT