(match): New face.
[bpt/emacs.git] / lisp / replace.el
1 ;;; replace.el --- replace commands for Emacs
2
3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996, 1997, 2000, 2001, 2002,
4 ;; 2003, 2004 Free Software Foundation, Inc.
5
6 ;; Maintainer: FSF
7
8 ;; This file is part of GNU Emacs.
9
10 ;; GNU Emacs is free software; you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation; either version 2, or (at your option)
13 ;; any later version.
14
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 ;; GNU General Public License for more details.
19
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs; see the file COPYING. If not, write to the
22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 ;; Boston, MA 02111-1307, USA.
24
25 ;;; Commentary:
26
27 ;; This package supplies the string and regular-expression replace functions
28 ;; documented in the Emacs user's manual.
29
30 ;;; Code:
31
32 (defcustom case-replace t
33 "*Non-nil means `query-replace' should preserve case in replacements."
34 :type 'boolean
35 :group 'matching)
36
37 (defvar query-replace-history nil)
38
39 (defvar query-replace-interactive nil
40 "Non-nil means `query-replace' uses the last search string.
41 That becomes the \"string to replace\".")
42
43 (defcustom query-replace-from-history-variable 'query-replace-history
44 "History list to use for the FROM argument of `query-replace' commands.
45 The value of this variable should be a symbol; that symbol
46 is used as a variable to hold a history list for the strings
47 or patterns to be replaced."
48 :group 'matching
49 :type 'symbol
50 :version "20.3")
51
52 (defcustom query-replace-to-history-variable 'query-replace-history
53 "History list to use for the TO argument of `query-replace' commands.
54 The value of this variable should be a symbol; that symbol
55 is used as a variable to hold a history list for replacement
56 strings or patterns."
57 :group 'matching
58 :type 'symbol
59 :version "20.3")
60
61 (defcustom query-replace-skip-read-only nil
62 "*Non-nil means `query-replace' and friends ignore read-only matches."
63 :type 'boolean
64 :group 'matching
65 :version "21.4")
66
67 (defun query-replace-descr (string)
68 (mapconcat 'isearch-text-char-description string ""))
69
70 (defun query-replace-read-from (string regexp-flag)
71 "Query and return the `from' argument of a query-replace operation.
72 The return value can also be a pair (FROM . TO) indicating that the user
73 wants to replace FROM with TO."
74 (if query-replace-interactive
75 (car (if regexp-flag regexp-search-ring search-ring))
76 (let* ((lastfrom (car (symbol-value query-replace-from-history-variable)))
77 (lastto (car (symbol-value query-replace-to-history-variable)))
78 (from
79 ;; The save-excursion here is in case the user marks and copies
80 ;; a region in order to specify the minibuffer input.
81 ;; That should not clobber the region for the query-replace itself.
82 (save-excursion
83 (when (equal lastfrom lastto)
84 ;; Typically, this is because the two histlists are shared.
85 (setq lastfrom (cadr (symbol-value
86 query-replace-from-history-variable))))
87 (read-from-minibuffer
88 (if (and lastto lastfrom)
89 (format "%s (default %s -> %s): " string
90 (query-replace-descr lastfrom)
91 (query-replace-descr lastto))
92 (format "%s: " string))
93 nil nil nil
94 query-replace-from-history-variable
95 nil t t))))
96 (if (and (zerop (length from)) lastto lastfrom)
97 (cons lastfrom
98 (query-replace-compile-replacement lastto regexp-flag))
99 ;; Warn if user types \n or \t, but don't reject the input.
100 (and regexp-flag
101 (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\[nt]\\)" from)
102 (let ((match (match-string 3 from)))
103 (cond
104 ((string= match "\\n")
105 (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
106 ((string= match "\\t")
107 (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
108 (sit-for 2)))
109 from))))
110
111 (defun query-replace-compile-replacement (to regexp-flag)
112 "Maybe convert a regexp replacement TO to Lisp.
113 Returns a list suitable for `perform-replace' if necessary,
114 the original string if not."
115 (if (and regexp-flag
116 (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to))
117 (let (pos list char)
118 (while
119 (progn
120 (setq pos (match-end 0))
121 (push (substring to 0 (- pos 2)) list)
122 (setq char (aref to (1- pos))
123 to (substring to pos))
124 (cond ((eq char ?\#)
125 (push '(number-to-string replace-count) list))
126 ((eq char ?\,)
127 (setq pos (read-from-string to))
128 (push `(replace-quote ,(car pos)) list)
129 (let ((end
130 ;; Swallow a space after a symbol
131 ;; if there is a space.
132 (if (and (or (symbolp (car pos))
133 ;; Swallow a space after 'foo
134 ;; but not after (quote foo).
135 (and (eq (car-safe (car pos)) 'quote)
136 (not (= ?\( (aref to 0)))))
137 (eq (string-match " " to (cdr pos))
138 (cdr pos)))
139 (1+ (cdr pos))
140 (cdr pos))))
141 (setq to (substring to end)))))
142 (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\\\[,#]" to)))
143 (setq to (nreverse (delete "" (cons to list))))
144 (replace-match-string-symbols to)
145 (cons 'replace-eval-replacement
146 (if (cdr to)
147 (cons 'concat to)
148 (car to))))
149 to))
150
151
152 (defun query-replace-read-to (from string regexp-flag)
153 "Query and return the `to' argument of a query-replace operation."
154 (query-replace-compile-replacement
155 (save-excursion
156 (read-from-minibuffer
157 (format "%s %s with: " string (query-replace-descr from))
158 nil nil nil
159 query-replace-to-history-variable from t t))
160 regexp-flag))
161
162 (defun query-replace-read-args (string regexp-flag &optional noerror)
163 (unless noerror
164 (barf-if-buffer-read-only))
165 (let* ((from (query-replace-read-from string regexp-flag))
166 (to (if (consp from) (prog1 (cdr from) (setq from (car from)))
167 (query-replace-read-to from string regexp-flag))))
168 (list from to current-prefix-arg)))
169
170 (defun query-replace (from-string to-string &optional delimited start end)
171 "Replace some occurrences of FROM-STRING with TO-STRING.
172 As each match is found, the user must type a character saying
173 what to do with it. For directions, type \\[help-command] at that time.
174
175 In Transient Mark mode, if the mark is active, operate on the contents
176 of the region. Otherwise, operate from point to the end of the buffer.
177
178 If `query-replace-interactive' is non-nil, the last incremental search
179 string is used as FROM-STRING--you don't have to specify it with the
180 minibuffer.
181
182 Matching is independent of case if `case-fold-search' is non-nil and
183 FROM-STRING has no uppercase letters. Replacement transfers the case
184 pattern of the old text to the new text, if `case-replace' and
185 `case-fold-search' are non-nil and FROM-STRING has no uppercase
186 letters. \(Transferring the case pattern means that if the old text
187 matched is all caps, or capitalized, then its replacement is upcased
188 or capitalized.)
189
190 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
191 only matches surrounded by word boundaries.
192 Fourth and fifth arg START and END specify the region to operate on.
193
194 To customize possible responses, change the \"bindings\" in `query-replace-map'."
195 (interactive (let ((common
196 (query-replace-read-args "Query replace" nil)))
197 (list (nth 0 common) (nth 1 common) (nth 2 common)
198 ;; These are done separately here
199 ;; so that command-history will record these expressions
200 ;; rather than the values they had this time.
201 (if (and transient-mark-mode mark-active)
202 (region-beginning))
203 (if (and transient-mark-mode mark-active)
204 (region-end)))))
205 (perform-replace from-string to-string t nil delimited nil nil start end))
206
207 (define-key esc-map "%" 'query-replace)
208
209 (defun query-replace-regexp (regexp to-string &optional delimited start end)
210 "Replace some things after point matching REGEXP with TO-STRING.
211 As each match is found, the user must type a character saying
212 what to do with it. For directions, type \\[help-command] at that time.
213
214 In Transient Mark mode, if the mark is active, operate on the contents
215 of the region. Otherwise, operate from point to the end of the buffer.
216
217 If `query-replace-interactive' is non-nil, the last incremental search
218 regexp is used as REGEXP--you don't have to specify it with the
219 minibuffer.
220
221 Matching is independent of case if `case-fold-search' is non-nil and
222 REGEXP has no uppercase letters. Replacement transfers the case
223 pattern of the old text to the new text, if `case-replace' and
224 `case-fold-search' are non-nil and REGEXP has no uppercase letters.
225 \(Transferring the case pattern means that if the old text matched is
226 all caps, or capitalized, then its replacement is upcased or
227 capitalized.)
228
229 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
230 only matches surrounded by word boundaries.
231 Fourth and fifth arg START and END specify the region to operate on.
232
233 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
234 and `\\=\\N' (where N is a digit) stands for
235 whatever what matched the Nth `\\(...\\)' in REGEXP.
236 `\\?' lets you edit the replacement text in the minibuffer
237 at the given position for each replacement.
238
239 In interactive calls, the replacement text can contain `\\,'
240 followed by a Lisp expression. Each
241 replacement evaluates that expression to compute the replacement
242 string. Inside of that expression, `\\&' is a string denoting the
243 whole match as a string, `\\N' for a partial match, `\\#&' and `\\#N'
244 for the whole or a partial match converted to a number with
245 `string-to-number', and `\\#' itself for the number of replacements
246 done so far (starting with zero).
247
248 If the replacement expression is a symbol, write a space after it
249 to terminate it. One space there, if any, will be discarded.
250
251 When using those Lisp features interactively in the replacement
252 text, TO-STRING is actually made a list instead of a string.
253 Use \\[repeat-complex-command] after this command for details."
254 (interactive
255 (let ((common
256 (query-replace-read-args "Query replace regexp" t)))
257 (list (nth 0 common) (nth 1 common) (nth 2 common)
258 ;; These are done separately here
259 ;; so that command-history will record these expressions
260 ;; rather than the values they had this time.
261 (if (and transient-mark-mode mark-active)
262 (region-beginning))
263 (if (and transient-mark-mode mark-active)
264 (region-end)))))
265 (perform-replace regexp to-string t t delimited nil nil start end))
266
267 (define-key esc-map [?\C-%] 'query-replace-regexp)
268
269 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
270 "Replace some things after point matching REGEXP with the result of TO-EXPR.
271 As each match is found, the user must type a character saying
272 what to do with it. For directions, type \\[help-command] at that time.
273
274 TO-EXPR is a Lisp expression evaluated to compute each replacement. It may
275 reference `replace-count' to get the number of replacements already made.
276 If the result of TO-EXPR is not a string, it is converted to one using
277 `prin1-to-string' with the NOESCAPE argument (which see).
278
279 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
280 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
281 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
282 Use `\\#&' or `\\#N' if you want a number instead of a string.
283 In interactive use, `\\#' in itself stands for `replace-count'.
284
285 In Transient Mark mode, if the mark is active, operate on the contents
286 of the region. Otherwise, operate from point to the end of the buffer.
287
288 If `query-replace-interactive' is non-nil, the last incremental search
289 regexp is used as REGEXP--you don't have to specify it with the
290 minibuffer.
291
292 Preserves case in each replacement if `case-replace' and `case-fold-search'
293 are non-nil and REGEXP has no uppercase letters.
294
295 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
296 only matches that are surrounded by word boundaries.
297 Fourth and fifth arg START and END specify the region to operate on."
298 (interactive
299 (progn
300 (barf-if-buffer-read-only)
301 (let* ((from
302 ;; Let-bind the history var to disable the "foo -> bar" default.
303 ;; Maybe we shouldn't disable this default, but for now I'll
304 ;; leave it off. --Stef
305 (let ((query-replace-to-history-variable nil))
306 (query-replace-read-from "Query replace regexp" t)))
307 (to (list (read-from-minibuffer
308 (format "Query replace regexp %s with eval: "
309 (query-replace-descr from))
310 nil nil t query-replace-to-history-variable from t))))
311 ;; We make TO a list because replace-match-string-symbols requires one,
312 ;; and the user might enter a single token.
313 (replace-match-string-symbols to)
314 (list from (car to) current-prefix-arg
315 (if (and transient-mark-mode mark-active)
316 (region-beginning))
317 (if (and transient-mark-mode mark-active)
318 (region-end))))))
319 (perform-replace regexp (cons 'replace-eval-replacement to-expr)
320 t 'literal delimited nil nil start end))
321
322 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
323 "Replace some matches for REGEXP with various strings, in rotation.
324 The second argument TO-STRINGS contains the replacement strings,
325 separated by spaces. Third arg DELIMITED (prefix arg if interactive),
326 if non-nil, means replace only matches surrounded by word boundaries.
327 This command works like `query-replace-regexp' except that each
328 successive replacement uses the next successive replacement string,
329 wrapping around from the last such string to the first.
330
331 In Transient Mark mode, if the mark is active, operate on the contents
332 of the region. Otherwise, operate from point to the end of the buffer.
333
334 Non-interactively, TO-STRINGS may be a list of replacement strings.
335
336 If `query-replace-interactive' is non-nil, the last incremental search
337 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
338
339 A prefix argument N says to use each replacement string N times
340 before rotating to the next.
341 Fourth and fifth arg START and END specify the region to operate on."
342 (interactive
343 (let* ((from (if query-replace-interactive
344 (car regexp-search-ring)
345 (read-from-minibuffer "Map query replace (regexp): "
346 nil nil nil
347 'query-replace-history nil t)))
348 (to (read-from-minibuffer
349 (format "Query replace %s with (space-separated strings): "
350 (query-replace-descr from))
351 nil nil nil
352 'query-replace-history from t)))
353 (list from to
354 (and current-prefix-arg
355 (prefix-numeric-value current-prefix-arg))
356 (if (and transient-mark-mode mark-active)
357 (region-beginning))
358 (if (and transient-mark-mode mark-active)
359 (region-end)))))
360 (let (replacements)
361 (if (listp to-strings)
362 (setq replacements to-strings)
363 (while (/= (length to-strings) 0)
364 (if (string-match " " to-strings)
365 (setq replacements
366 (append replacements
367 (list (substring to-strings 0
368 (string-match " " to-strings))))
369 to-strings (substring to-strings
370 (1+ (string-match " " to-strings))))
371 (setq replacements (append replacements (list to-strings))
372 to-strings ""))))
373 (perform-replace regexp replacements t t nil n nil start end)))
374
375 (defun replace-string (from-string to-string &optional delimited start end)
376 "Replace occurrences of FROM-STRING with TO-STRING.
377 Preserve case in each match if `case-replace' and `case-fold-search'
378 are non-nil and FROM-STRING has no uppercase letters.
379 \(Preserving case means that if the string matched is all caps, or capitalized,
380 then its replacement is upcased or capitalized.)
381
382 In Transient Mark mode, if the mark is active, operate on the contents
383 of the region. Otherwise, operate from point to the end of the buffer.
384
385 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
386 only matches surrounded by word boundaries.
387 Fourth and fifth arg START and END specify the region to operate on.
388
389 If `query-replace-interactive' is non-nil, the last incremental search
390 string is used as FROM-STRING--you don't have to specify it with the
391 minibuffer.
392
393 This function is usually the wrong thing to use in a Lisp program.
394 What you probably want is a loop like this:
395 (while (search-forward FROM-STRING nil t)
396 (replace-match TO-STRING nil t))
397 which will run faster and will not set the mark or print anything.
398 \(You may need a more complex loop if FROM-STRING can match the null string
399 and TO-STRING is also null.)"
400 (interactive
401 (let ((common
402 (query-replace-read-args "Replace string" nil)))
403 (list (nth 0 common) (nth 1 common) (nth 2 common)
404 (if (and transient-mark-mode mark-active)
405 (region-beginning))
406 (if (and transient-mark-mode mark-active)
407 (region-end)))))
408 (perform-replace from-string to-string nil nil delimited nil nil start end))
409
410 (defun replace-regexp (regexp to-string &optional delimited start end)
411 "Replace things after point matching REGEXP with TO-STRING.
412 Preserve case in each match if `case-replace' and `case-fold-search'
413 are non-nil and REGEXP has no uppercase letters.
414
415 In Transient Mark mode, if the mark is active, operate on the contents
416 of the region. Otherwise, operate from point to the end of the buffer.
417
418 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
419 only matches surrounded by word boundaries.
420 Fourth and fifth arg START and END specify the region to operate on.
421
422 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
423 and `\\=\\N' (where N is a digit) stands for
424 whatever what matched the Nth `\\(...\\)' in REGEXP.
425 `\\?' lets you edit the replacement text in the minibuffer
426 at the given position for each replacement.
427
428 In interactive calls, the replacement text may contain `\\,'
429 followed by a Lisp expression used as part of the replacement
430 text. Inside of that expression, `\\&' is a string denoting the
431 whole match, `\\N' a partial matches, `\\#&' and `\\#N' the
432 respective numeric values from `string-to-number', and `\\#'
433 itself for `replace-count', the number of replacements occured so
434 far.
435
436 If your Lisp expression is an identifier and the next letter in
437 the replacement string would be interpreted as part of it, you
438 can wrap it with an expression like `\\,(or \\#)'. Incidentally,
439 for this particular case you may also enter `\\#' in the
440 replacement text directly.
441
442 When using those Lisp features interactively in the replacement
443 text, TO-STRING is actually made a list instead of a string.
444 Use \\[repeat-complex-command] after this command for details.
445
446 If `query-replace-interactive' is non-nil, the last incremental search
447 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
448
449 This function is usually the wrong thing to use in a Lisp program.
450 What you probably want is a loop like this:
451 (while (re-search-forward REGEXP nil t)
452 (replace-match TO-STRING nil nil))
453 which will run faster and will not set the mark or print anything."
454 (interactive
455 (let ((common
456 (query-replace-read-args "Replace regexp" t)))
457 (list (nth 0 common) (nth 1 common) (nth 2 common)
458 (if (and transient-mark-mode mark-active)
459 (region-beginning))
460 (if (and transient-mark-mode mark-active)
461 (region-end)))))
462 (perform-replace regexp to-string nil t delimited nil nil start end))
463
464 \f
465 (defvar regexp-history nil
466 "History list for some commands that read regular expressions.")
467
468
469 (defalias 'delete-non-matching-lines 'keep-lines)
470 (defalias 'delete-matching-lines 'flush-lines)
471 (defalias 'count-matches 'how-many)
472
473
474 (defun keep-lines-read-args (prompt)
475 "Read arguments for `keep-lines' and friends.
476 Prompt for a regexp with PROMPT.
477 Value is a list, (REGEXP)."
478 (list (read-from-minibuffer prompt nil nil nil
479 'regexp-history nil t)))
480
481 (defun keep-lines (regexp &optional rstart rend)
482 "Delete all lines except those containing matches for REGEXP.
483 A match split across lines preserves all the lines it lies in.
484 Applies to all lines after point.
485
486 If REGEXP contains upper case characters (excluding those preceded by `\\'),
487 the matching is case-sensitive.
488
489 Second and third arg RSTART and REND specify the region to operate on.
490
491 Interactively, in Transient Mark mode when the mark is active, operate
492 on the contents of the region. Otherwise, operate from point to the
493 end of the buffer."
494
495 (interactive
496 (progn
497 (barf-if-buffer-read-only)
498 (keep-lines-read-args "Keep lines (containing match for regexp): ")))
499 (if rstart
500 (progn
501 (goto-char (min rstart rend))
502 (setq rend (copy-marker (max rstart rend))))
503 (if (and transient-mark-mode mark-active)
504 (setq rstart (region-beginning)
505 rend (copy-marker (region-end)))
506 (setq rstart (point)
507 rend (point-max-marker)))
508 (goto-char rstart))
509 (save-excursion
510 (or (bolp) (forward-line 1))
511 (let ((start (point))
512 (case-fold-search (and case-fold-search
513 (isearch-no-upper-case-p regexp t))))
514 (while (< (point) rend)
515 ;; Start is first char not preserved by previous match.
516 (if (not (re-search-forward regexp rend 'move))
517 (delete-region start rend)
518 (let ((end (save-excursion (goto-char (match-beginning 0))
519 (beginning-of-line)
520 (point))))
521 ;; Now end is first char preserved by the new match.
522 (if (< start end)
523 (delete-region start end))))
524
525 (setq start (save-excursion (forward-line 1) (point)))
526 ;; If the match was empty, avoid matching again at same place.
527 (and (< (point) rend)
528 (= (match-beginning 0) (match-end 0))
529 (forward-char 1))))))
530
531
532 (defun flush-lines (regexp &optional rstart rend)
533 "Delete lines containing matches for REGEXP.
534 If a match is split across lines, all the lines it lies in are deleted.
535 Applies to lines after point.
536
537 If REGEXP contains upper case characters (excluding those preceded by `\\'),
538 the matching is case-sensitive.
539
540 Second and third arg RSTART and REND specify the region to operate on.
541
542 Interactively, in Transient Mark mode when the mark is active, operate
543 on the contents of the region. Otherwise, operate from point to the
544 end of the buffer."
545
546 (interactive
547 (progn
548 (barf-if-buffer-read-only)
549 (keep-lines-read-args "Flush lines (containing match for regexp): ")))
550 (if rstart
551 (progn
552 (goto-char (min rstart rend))
553 (setq rend (copy-marker (max rstart rend))))
554 (if (and transient-mark-mode mark-active)
555 (setq rstart (region-beginning)
556 rend (copy-marker (region-end)))
557 (setq rstart (point)
558 rend (point-max-marker)))
559 (goto-char rstart))
560 (let ((case-fold-search (and case-fold-search
561 (isearch-no-upper-case-p regexp t))))
562 (save-excursion
563 (while (and (< (point) rend)
564 (re-search-forward regexp rend t))
565 (delete-region (save-excursion (goto-char (match-beginning 0))
566 (beginning-of-line)
567 (point))
568 (progn (forward-line 1) (point)))))))
569
570
571 (defun how-many (regexp &optional rstart rend)
572 "Print number of matches for REGEXP following point.
573
574 If REGEXP contains upper case characters (excluding those preceded by `\\'),
575 the matching is case-sensitive.
576
577 Second and third arg RSTART and REND specify the region to operate on.
578
579 Interactively, in Transient Mark mode when the mark is active, operate
580 on the contents of the region. Otherwise, operate from point to the
581 end of the buffer."
582
583 (interactive
584 (keep-lines-read-args "How many matches for (regexp): "))
585 (save-excursion
586 (if rstart
587 (goto-char (min rstart rend))
588 (if (and transient-mark-mode mark-active)
589 (setq rstart (region-beginning)
590 rend (copy-marker (region-end)))
591 (setq rstart (point)
592 rend (point-max-marker)))
593 (goto-char rstart))
594 (let ((count 0)
595 opoint
596 (case-fold-search (and case-fold-search
597 (isearch-no-upper-case-p regexp t))))
598 (while (and (< (point) rend)
599 (progn (setq opoint (point))
600 (re-search-forward regexp rend t)))
601 (if (= opoint (point))
602 (forward-char 1)
603 (setq count (1+ count))))
604 (message "%d occurrences" count))))
605
606 \f
607 (defvar occur-mode-map
608 (let ((map (make-sparse-keymap)))
609 (define-key map [mouse-2] 'occur-mode-mouse-goto)
610 (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
611 (define-key map "\C-m" 'occur-mode-goto-occurrence)
612 (define-key map "o" 'occur-mode-goto-occurrence-other-window)
613 (define-key map "\C-o" 'occur-mode-display-occurrence)
614 (define-key map "\M-n" 'occur-next)
615 (define-key map "\M-p" 'occur-prev)
616 (define-key map "r" 'occur-rename-buffer)
617 (define-key map "c" 'clone-buffer)
618 (define-key map "g" 'revert-buffer)
619 (define-key map "q" 'quit-window)
620 (define-key map "z" 'kill-this-buffer)
621 (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
622 map)
623 "Keymap for `occur-mode'.")
624
625 (defvar occur-revert-arguments nil
626 "Arguments to pass to `occur-1' to revert an Occur mode buffer.
627 See `occur-revert-function'.")
628
629 (defcustom occur-mode-hook '(turn-on-font-lock)
630 "Hook run when entering Occur mode."
631 :type 'hook
632 :group 'matching)
633
634 (defcustom occur-hook nil
635 "Hook run when `occur' is called."
636 :type 'hook
637 :group 'matching)
638
639 (put 'occur-mode 'mode-class 'special)
640 (defun occur-mode ()
641 "Major mode for output from \\[occur].
642 \\<occur-mode-map>Move point to one of the items in this buffer, then use
643 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
644 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
645
646 \\{occur-mode-map}"
647 (interactive)
648 (kill-all-local-variables)
649 (use-local-map occur-mode-map)
650 (setq major-mode 'occur-mode)
651 (setq mode-name "Occur")
652 (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
653 (make-local-variable 'occur-revert-arguments)
654 (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
655 (setq next-error-function 'occur-next-error)
656 (run-hooks 'occur-mode-hook))
657
658 (defun occur-revert-function (ignore1 ignore2)
659 "Handle `revert-buffer' for Occur mode buffers."
660 (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
661
662 (defun occur-mode-mouse-goto (event)
663 "In Occur mode, go to the occurrence whose line you click on."
664 (interactive "e")
665 (let (pos)
666 (save-excursion
667 (set-buffer (window-buffer (posn-window (event-end event))))
668 (save-excursion
669 (goto-char (posn-point (event-end event)))
670 (setq pos (occur-mode-find-occurrence))))
671 (pop-to-buffer (marker-buffer pos))
672 (goto-char pos)))
673
674 (defun occur-mode-find-occurrence ()
675 (let ((pos (get-text-property (point) 'occur-target)))
676 (unless pos
677 (error "No occurrence on this line"))
678 (unless (buffer-live-p (marker-buffer pos))
679 (error "Buffer for this occurrence was killed"))
680 pos))
681
682 (defun occur-mode-goto-occurrence ()
683 "Go to the occurrence the current line describes."
684 (interactive)
685 (let ((pos (occur-mode-find-occurrence)))
686 (pop-to-buffer (marker-buffer pos))
687 (goto-char pos)))
688
689 (defun occur-mode-goto-occurrence-other-window ()
690 "Go to the occurrence the current line describes, in another window."
691 (interactive)
692 (let ((pos (occur-mode-find-occurrence)))
693 (switch-to-buffer-other-window (marker-buffer pos))
694 (goto-char pos)))
695
696 (defun occur-mode-display-occurrence ()
697 "Display in another window the occurrence the current line describes."
698 (interactive)
699 (let ((pos (occur-mode-find-occurrence))
700 window
701 ;; Bind these to ensure `display-buffer' puts it in another window.
702 same-window-buffer-names
703 same-window-regexps)
704 (setq window (display-buffer (marker-buffer pos)))
705 ;; This is the way to set point in the proper window.
706 (save-selected-window
707 (select-window window)
708 (goto-char pos))))
709
710 (defun occur-find-match (n search message)
711 (if (not n) (setq n 1))
712 (let ((r))
713 (while (> n 0)
714 (setq r (funcall search (point) 'occur-match))
715 (and r
716 (get-text-property r 'occur-match)
717 (setq r (funcall search r 'occur-match)))
718 (if r
719 (goto-char r)
720 (error message))
721 (setq n (1- n)))))
722
723 (defun occur-next (&optional n)
724 "Move to the Nth (default 1) next match in an Occur mode buffer."
725 (interactive "p")
726 (occur-find-match n #'next-single-property-change "No more matches"))
727
728 (defun occur-prev (&optional n)
729 "Move to the Nth (default 1) previous match in an Occur mode buffer."
730 (interactive "p")
731 (occur-find-match n #'previous-single-property-change "No earlier matches"))
732
733 (defun occur-next-error (&optional argp reset)
734 "Move to the Nth (default 1) next match in an Occur mode buffer.
735 Compatibility function for \\[next-error] invocations."
736 (interactive "p")
737 ;; we need to run occur-find-match from within the Occur buffer
738 (with-current-buffer
739 (if (next-error-buffer-p (current-buffer))
740 (current-buffer)
741 (next-error-find-buffer nil nil (lambda() (eq major-mode 'occur-mode))))
742
743 (when reset
744 (goto-char (point-min)))
745 (occur-find-match
746 (abs (prefix-numeric-value argp))
747 (if (> 0 (prefix-numeric-value argp))
748 #'previous-single-property-change
749 #'next-single-property-change)
750 "No more matches")
751 ;; In case the *Occur* buffer is visible in a nonselected window.
752 (set-window-point (get-buffer-window (current-buffer)) (point))
753 (occur-mode-goto-occurrence)))
754 \f
755 (defface match
756 '((((class color) (min-colors 88) (background light))
757 :background "Tan")
758 (((class color) (min-colors 88) (background dark))
759 :background "RoyalBlue4")
760 (((class color) (min-colors 8))
761 :background "blue" :foreground "white")
762 (((type tty) (class mono))
763 :inverse-video t)
764 (t :background "gray"))
765 "Face used to highlight matches permanently."
766 :group 'matching
767 :version "21.4")
768
769 (defcustom list-matching-lines-default-context-lines 0
770 "*Default number of context lines included around `list-matching-lines' matches.
771 A negative number means to include that many lines before the match.
772 A positive number means to include that many lines both before and after."
773 :type 'integer
774 :group 'matching)
775
776 (defalias 'list-matching-lines 'occur)
777
778 (defcustom list-matching-lines-face 'match
779 "*Face used by \\[list-matching-lines] to show the text that matches.
780 If the value is nil, don't highlight the matching portions specially."
781 :type 'face
782 :group 'matching)
783
784 (defcustom list-matching-lines-buffer-name-face 'underline
785 "*Face used by \\[list-matching-lines] to show the names of buffers.
786 If the value is nil, don't highlight the buffer names specially."
787 :type 'face
788 :group 'matching)
789
790 (defun occur-accumulate-lines (count &optional keep-props)
791 (save-excursion
792 (let ((forwardp (> count 0))
793 (result nil))
794 (while (not (or (zerop count)
795 (if forwardp
796 (eobp)
797 (bobp))))
798 (setq count (+ count (if forwardp -1 1)))
799 (push
800 (funcall (if keep-props
801 #'buffer-substring
802 #'buffer-substring-no-properties)
803 (line-beginning-position)
804 (line-end-position))
805 result)
806 (forward-line (if forwardp 1 -1)))
807 (nreverse result))))
808
809 (defun occur-read-primary-args ()
810 (list (let* ((default (car regexp-history))
811 (input
812 (read-from-minibuffer
813 (if default
814 (format "List lines matching regexp (default `%s'): "
815 (query-replace-descr default))
816 "List lines matching regexp: ")
817 nil
818 nil
819 nil
820 'regexp-history
821 default)))
822 (if (equal input "")
823 default
824 input))
825 (when current-prefix-arg
826 (prefix-numeric-value current-prefix-arg))))
827
828 (defun occur-rename-buffer (&optional unique-p)
829 "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
830 Here `original-buffer-name' is the buffer name were occur was originally run.
831 When given the prefix argument, the renaming will not clobber the existing
832 buffer(s) of that name, but use `generate-new-buffer-name' instead.
833 You can add this to `occur-hook' if you always want a separate *Occur*
834 buffer for each buffer where you invoke `occur'."
835 (interactive "P")
836 (with-current-buffer
837 (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
838 (rename-buffer (concat "*Occur: "
839 (mapconcat #'buffer-name
840 (car (cddr occur-revert-arguments)) "/")
841 "*")
842 unique-p)))
843
844 (defun occur (regexp &optional nlines)
845 "Show all lines in the current buffer containing a match for REGEXP.
846
847 If a match spreads across multiple lines, all those lines are shown.
848
849 Each line is displayed with NLINES lines before and after, or -NLINES
850 before if NLINES is negative.
851 NLINES defaults to `list-matching-lines-default-context-lines'.
852 Interactively it is the prefix arg.
853
854 The lines are shown in a buffer named `*Occur*'.
855 It serves as a menu to find any of the occurrences in this buffer.
856 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
857
858 If REGEXP contains upper case characters (excluding those preceded by `\\'),
859 the matching is case-sensitive."
860 (interactive (occur-read-primary-args))
861 (occur-1 regexp nlines (list (current-buffer))))
862
863 (defun multi-occur (bufs regexp &optional nlines)
864 "Show all lines in buffers BUFS containing a match for REGEXP.
865 This function acts on multiple buffers; otherwise, it is exactly like
866 `occur'."
867 (interactive
868 (cons
869 (let* ((bufs (list (read-buffer "First buffer to search: "
870 (current-buffer) t)))
871 (buf nil)
872 (ido-ignore-item-temp-list bufs))
873 (while (not (string-equal
874 (setq buf (read-buffer
875 (if (eq read-buffer-function 'ido-read-buffer)
876 "Next buffer to search (C-j to end): "
877 "Next buffer to search (RET to end): ")
878 nil t))
879 ""))
880 (add-to-list 'bufs buf)
881 (setq ido-ignore-item-temp-list bufs))
882 (nreverse (mapcar #'get-buffer bufs)))
883 (occur-read-primary-args)))
884 (occur-1 regexp nlines bufs))
885
886 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
887 "Show all lines matching REGEXP in buffers named by BUFREGEXP.
888 See also `multi-occur'."
889 (interactive
890 (cons
891 (let* ((default (car regexp-history))
892 (input
893 (read-from-minibuffer
894 "List lines in buffers whose filename matches regexp: "
895 nil
896 nil
897 nil
898 'regexp-history)))
899 (if (equal input "")
900 default
901 input))
902 (occur-read-primary-args)))
903 (when bufregexp
904 (occur-1 regexp nlines
905 (delq nil
906 (mapcar (lambda (buf)
907 (when (and (buffer-file-name buf)
908 (string-match bufregexp
909 (buffer-file-name buf)))
910 buf))
911 (buffer-list))))))
912
913 (defun occur-1 (regexp nlines bufs &optional buf-name)
914 (unless buf-name
915 (setq buf-name "*Occur*"))
916 (let ((occur-buf (get-buffer-create buf-name))
917 (made-temp-buf nil)
918 (active-bufs (delq nil (mapcar #'(lambda (buf)
919 (when (buffer-live-p buf) buf))
920 bufs))))
921 ;; Handle the case where one of the buffers we're searching is the
922 ;; *Occur* buffer itself.
923 (when (memq occur-buf bufs)
924 (setq occur-buf (with-current-buffer occur-buf
925 (clone-buffer "*Occur-temp*"))
926 made-temp-buf t))
927 (with-current-buffer occur-buf
928 (setq buffer-read-only nil)
929 (occur-mode)
930 (erase-buffer)
931 (let ((count (occur-engine
932 regexp active-bufs occur-buf
933 (or nlines list-matching-lines-default-context-lines)
934 (and case-fold-search
935 (isearch-no-upper-case-p regexp t))
936 list-matching-lines-buffer-name-face
937 nil list-matching-lines-face t)))
938 (let* ((bufcount (length active-bufs))
939 (diff (- (length bufs) bufcount)))
940 (message "Searched %d buffer%s%s; %s match%s for `%s'"
941 bufcount (if (= bufcount 1) "" "s")
942 (if (zerop diff) "" (format " (%d killed)" diff))
943 (if (zerop count) "no" (format "%d" count))
944 (if (= count 1) "" "es")
945 regexp))
946 ;; If we had to make a temporary buffer, make it the *Occur*
947 ;; buffer now.
948 (when made-temp-buf
949 (with-current-buffer (get-buffer buf-name)
950 (kill-buffer (current-buffer)))
951 (rename-buffer buf-name))
952 (setq occur-revert-arguments (list regexp nlines bufs)
953 buffer-read-only t)
954 (if (> count 0)
955 (progn
956 (display-buffer occur-buf)
957 (setq next-error-last-buffer occur-buf))
958 (kill-buffer occur-buf)))
959 (run-hooks 'occur-hook))))
960
961 (defun occur-engine-add-prefix (lines)
962 (mapcar
963 #'(lambda (line)
964 (concat " :" line "\n"))
965 lines))
966
967 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
968 title-face prefix-face match-face keep-props)
969 (with-current-buffer out-buf
970 (setq buffer-read-only nil)
971 (let ((globalcount 0)
972 (coding nil))
973 ;; Map over all the buffers
974 (dolist (buf buffers)
975 (when (buffer-live-p buf)
976 (let ((matches 0) ;; count of matched lines
977 (lines 1) ;; line count
978 (matchbeg 0)
979 (origpt nil)
980 (begpt nil)
981 (endpt nil)
982 (marker nil)
983 (curstring "")
984 (headerpt (with-current-buffer out-buf (point))))
985 (save-excursion
986 (set-buffer buf)
987 (or coding
988 ;; Set CODING only if the current buffer locally
989 ;; binds buffer-file-coding-system.
990 (not (local-variable-p 'buffer-file-coding-system))
991 (setq coding buffer-file-coding-system))
992 (save-excursion
993 (goto-char (point-min)) ;; begin searching in the buffer
994 (while (not (eobp))
995 (setq origpt (point))
996 (when (setq endpt (re-search-forward regexp nil t))
997 (setq matches (1+ matches)) ;; increment match count
998 (setq matchbeg (match-beginning 0))
999 (setq begpt (save-excursion
1000 (goto-char matchbeg)
1001 (line-beginning-position)))
1002 (setq lines (+ lines (1- (count-lines origpt endpt))))
1003 (setq marker (make-marker))
1004 (set-marker marker matchbeg)
1005 (setq curstring (buffer-substring begpt
1006 (line-end-position)))
1007 ;; Depropertize the string, and maybe
1008 ;; highlight the matches
1009 (let ((len (length curstring))
1010 (start 0))
1011 (unless keep-props
1012 (set-text-properties 0 len nil curstring))
1013 (while (and (< start len)
1014 (string-match regexp curstring start))
1015 (add-text-properties (match-beginning 0)
1016 (match-end 0)
1017 (append
1018 `(occur-match t)
1019 (when match-face
1020 ;; Use `face' rather than
1021 ;; `font-lock-face' here
1022 ;; so as to override faces
1023 ;; copied from the buffer.
1024 `(face ,match-face)))
1025 curstring)
1026 (setq start (match-end 0))))
1027 ;; Generate the string to insert for this match
1028 (let* ((out-line
1029 (concat
1030 ;; Using 7 digits aligns tabs properly.
1031 (apply #'propertize (format "%7d:" lines)
1032 (append
1033 (when prefix-face
1034 `(font-lock-face prefix-face))
1035 '(occur-prefix t)))
1036 curstring
1037 "\n"))
1038 (data
1039 (if (= nlines 0)
1040 ;; The simple display style
1041 out-line
1042 ;; The complex multi-line display
1043 ;; style. Generate a list of lines,
1044 ;; concatenate them all together.
1045 (apply #'concat
1046 (nconc
1047 (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ (abs nlines))) keep-props))))
1048 (list out-line)
1049 (if (> nlines 0)
1050 (occur-engine-add-prefix
1051 (cdr (occur-accumulate-lines (1+ nlines) keep-props)))))))))
1052 ;; Actually insert the match display data
1053 (with-current-buffer out-buf
1054 (let ((beg (point))
1055 (end (progn (insert data) (point))))
1056 (unless (= nlines 0)
1057 (insert "-------\n"))
1058 (add-text-properties
1059 beg end
1060 `(occur-target ,marker help-echo "mouse-2: go to this occurrence"))
1061 ;; We don't put `mouse-face' on the newline,
1062 ;; because that loses.
1063 (add-text-properties beg (1- end) '(mouse-face highlight)))))
1064 (goto-char endpt))
1065 (if endpt
1066 (progn
1067 (setq lines (1+ lines))
1068 ;; On to the next match...
1069 (forward-line 1))
1070 (goto-char (point-max))))))
1071 (when (not (zerop matches)) ;; is the count zero?
1072 (setq globalcount (+ globalcount matches))
1073 (with-current-buffer out-buf
1074 (goto-char headerpt)
1075 (let ((beg (point))
1076 end)
1077 (insert (format "%d match%s for \"%s\" in buffer: %s\n"
1078 matches (if (= matches 1) "" "es")
1079 regexp (buffer-name buf)))
1080 (setq end (point))
1081 (add-text-properties beg end
1082 (append
1083 (when title-face
1084 `(font-lock-face ,title-face))
1085 `(occur-title ,buf))))
1086 (goto-char (point-min)))))))
1087 (if coding
1088 ;; CODING is buffer-file-coding-system of the first buffer
1089 ;; that locally binds it. Let's use it also for the output
1090 ;; buffer.
1091 (set-buffer-file-coding-system coding))
1092 ;; Return the number of matches
1093 globalcount)))
1094
1095 \f
1096 ;; It would be nice to use \\[...], but there is no reasonable way
1097 ;; to make that display both SPC and Y.
1098 (defconst query-replace-help
1099 "Type Space or `y' to replace one match, Delete or `n' to skip to next,
1100 RET or `q' to exit, Period to replace one match and exit,
1101 Comma to replace but not move point immediately,
1102 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
1103 C-w to delete match and recursive edit,
1104 C-l to clear the screen, redisplay, and offer same replacement again,
1105 ! to replace all remaining matches with no more questions,
1106 ^ to move point back to previous match,
1107 E to edit the replacement string"
1108 "Help message while in `query-replace'.")
1109
1110 (defvar query-replace-map (make-sparse-keymap)
1111 "Keymap that defines the responses to questions in `query-replace'.
1112 The \"bindings\" in this map are not commands; they are answers.
1113 The valid answers include `act', `skip', `act-and-show',
1114 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
1115 `automatic', `backup', `exit-prefix', and `help'.")
1116
1117 (define-key query-replace-map " " 'act)
1118 (define-key query-replace-map "\d" 'skip)
1119 (define-key query-replace-map [delete] 'skip)
1120 (define-key query-replace-map [backspace] 'skip)
1121 (define-key query-replace-map "y" 'act)
1122 (define-key query-replace-map "n" 'skip)
1123 (define-key query-replace-map "Y" 'act)
1124 (define-key query-replace-map "N" 'skip)
1125 (define-key query-replace-map "e" 'edit-replacement)
1126 (define-key query-replace-map "E" 'edit-replacement)
1127 (define-key query-replace-map "," 'act-and-show)
1128 (define-key query-replace-map "q" 'exit)
1129 (define-key query-replace-map "\r" 'exit)
1130 (define-key query-replace-map [return] 'exit)
1131 (define-key query-replace-map "." 'act-and-exit)
1132 (define-key query-replace-map "\C-r" 'edit)
1133 (define-key query-replace-map "\C-w" 'delete-and-edit)
1134 (define-key query-replace-map "\C-l" 'recenter)
1135 (define-key query-replace-map "!" 'automatic)
1136 (define-key query-replace-map "^" 'backup)
1137 (define-key query-replace-map "\C-h" 'help)
1138 (define-key query-replace-map [f1] 'help)
1139 (define-key query-replace-map [help] 'help)
1140 (define-key query-replace-map "?" 'help)
1141 (define-key query-replace-map "\C-g" 'quit)
1142 (define-key query-replace-map "\C-]" 'quit)
1143 (define-key query-replace-map "\e" 'exit-prefix)
1144 (define-key query-replace-map [escape] 'exit-prefix)
1145
1146 (defun replace-match-string-symbols (n)
1147 "Process a list (and any sub-lists), expanding certain symbols.
1148 Symbol Expands To
1149 N (match-string N) (where N is a string of digits)
1150 #N (string-to-number (match-string N))
1151 & (match-string 0)
1152 #& (string-to-number (match-string 0))
1153 # replace-count
1154
1155 Note that these symbols must be preceeded by a backslash in order to
1156 type them."
1157 (while n
1158 (cond
1159 ((consp (car n))
1160 (replace-match-string-symbols (car n))) ;Process sub-list
1161 ((symbolp (car n))
1162 (let ((name (symbol-name (car n))))
1163 (cond
1164 ((string-match "^[0-9]+$" name)
1165 (setcar n (list 'match-string (string-to-number name))))
1166 ((string-match "^#[0-9]+$" name)
1167 (setcar n (list 'string-to-number
1168 (list 'match-string
1169 (string-to-number (substring name 1))))))
1170 ((string= "&" name)
1171 (setcar n '(match-string 0)))
1172 ((string= "#&" name)
1173 (setcar n '(string-to-number (match-string 0))))
1174 ((string= "#" name)
1175 (setcar n 'replace-count))))))
1176 (setq n (cdr n))))
1177
1178 (defun replace-eval-replacement (expression replace-count)
1179 (let ((replacement (eval expression)))
1180 (if (stringp replacement)
1181 replacement
1182 (prin1-to-string replacement t))))
1183
1184 (defun replace-quote (replacement)
1185 "Quote a replacement string.
1186 This just doubles all backslashes in REPLACEMENT and
1187 returns the resulting string. If REPLACEMENT is not
1188 a string, it is first passed through `prin1-to-string'
1189 with the `noescape' argument set.
1190
1191 `match-data' is preserved across the call."
1192 (save-match-data
1193 (replace-regexp-in-string "\\\\" "\\\\"
1194 (if (stringp replacement)
1195 replacement
1196 (prin1-to-string replacement t))
1197 t t)))
1198
1199 (defun replace-loop-through-replacements (data replace-count)
1200 ;; DATA is a vector contaning the following values:
1201 ;; 0 next-rotate-count
1202 ;; 1 repeat-count
1203 ;; 2 next-replacement
1204 ;; 3 replacements
1205 (if (= (aref data 0) replace-count)
1206 (progn
1207 (aset data 0 (+ replace-count (aref data 1)))
1208 (let ((next (cdr (aref data 2))))
1209 (aset data 2 (if (consp next) next (aref data 3))))))
1210 (car (aref data 2)))
1211
1212 (defun replace-match-data (integers reuse &optional new)
1213 "Like `match-data', but markers in REUSE get invalidated.
1214 If NEW is non-NIL, it is set and returned instead of fresh data,
1215 but coerced to the correct value of INTEGERS."
1216 (or (and new
1217 (progn
1218 (set-match-data new)
1219 (and (eq new reuse)
1220 (eq (null integers) (markerp (car reuse)))
1221 new)))
1222 (match-data integers
1223 (prog1 reuse
1224 (while reuse
1225 (if (markerp (car reuse))
1226 (set-marker (car reuse) nil))
1227 (setq reuse (cdr reuse)))))))
1228
1229 (defun replace-match-maybe-edit (newtext fixedcase literal noedit match-data)
1230 "Make a replacement with `replace-match', editing `\\?'.
1231 NEWTEXT, FIXEDCASE, LITERAL are just passed on. If NOEDIT is true, no
1232 check for `\\?' is made to save time. MATCH-DATA is used for the
1233 replacement. In case editing is done, it is changed to use markers.
1234
1235 The return value is non-NIL if there has been no `\\?' or NOEDIT was
1236 passed in. If LITERAL is set, no checking is done, anyway."
1237 (unless (or literal noedit)
1238 (setq noedit t)
1239 (while (string-match "\\(\\`\\|[^\\]\\)\\(\\\\\\\\\\)*\\(\\\\\\?\\)"
1240 newtext)
1241 (setq newtext
1242 (read-input "Edit replacement string: "
1243 (prog1
1244 (cons
1245 (replace-match "" t t newtext 3)
1246 (1+ (match-beginning 3)))
1247 (setq match-data
1248 (replace-match-data
1249 nil match-data match-data))))
1250 noedit nil)))
1251 (set-match-data match-data)
1252 (replace-match newtext fixedcase literal)
1253 noedit)
1254
1255 (defun perform-replace (from-string replacements
1256 query-flag regexp-flag delimited-flag
1257 &optional repeat-count map start end)
1258 "Subroutine of `query-replace'. Its complexity handles interactive queries.
1259 Don't use this in your own program unless you want to query and set the mark
1260 just as `query-replace' does. Instead, write a simple loop like this:
1261
1262 (while (re-search-forward \"foo[ \\t]+bar\" nil t)
1263 (replace-match \"foobar\" nil nil))
1264
1265 which will run faster and probably do exactly what you want. Please
1266 see the documentation of `replace-match' to find out how to simulate
1267 `case-replace'.
1268
1269 This function returns nil if and only if there were no matches to
1270 make, or the user didn't cancel the call."
1271 (or map (setq map query-replace-map))
1272 (and query-flag minibuffer-auto-raise
1273 (raise-frame (window-frame (minibuffer-window))))
1274 (let ((nocasify (not (and case-fold-search case-replace
1275 (string-equal from-string
1276 (downcase from-string)))))
1277 (case-fold-search (and case-fold-search
1278 (string-equal from-string
1279 (downcase from-string))))
1280 (literal (or (not regexp-flag) (eq regexp-flag 'literal)))
1281 (search-function (if regexp-flag 're-search-forward 'search-forward))
1282 (search-string from-string)
1283 (real-match-data nil) ; the match data for the current match
1284 (next-replacement nil)
1285 (noedit nil)
1286 (keep-going t)
1287 (stack nil)
1288 (replace-count 0)
1289 (nonempty-match nil)
1290
1291 ;; If non-nil, it is marker saying where in the buffer to stop.
1292 (limit nil)
1293
1294 ;; Data for the next match. If a cons, it has the same format as
1295 ;; (match-data); otherwise it is t if a match is possible at point.
1296 (match-again t)
1297
1298 (isearch-string isearch-string)
1299 (isearch-regexp isearch-regexp)
1300 (isearch-case-fold-search isearch-case-fold-search)
1301 (message
1302 (if query-flag
1303 (substitute-command-keys
1304 "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1305
1306 ;; If region is active, in Transient Mark mode, operate on region.
1307 (when start
1308 (setq limit (copy-marker (max start end)))
1309 (goto-char (min start end))
1310 (deactivate-mark))
1311
1312 ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1313 ;; containing a function and its first argument. The function is
1314 ;; called to generate each replacement like this:
1315 ;; (funcall (car replacements) (cdr replacements) replace-count)
1316 ;; It must return a string.
1317 (cond
1318 ((stringp replacements)
1319 (setq next-replacement replacements
1320 replacements nil))
1321 ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1322 (or repeat-count (setq repeat-count 1))
1323 (setq replacements (cons 'replace-loop-through-replacements
1324 (vector repeat-count repeat-count
1325 replacements replacements)))))
1326
1327 (if delimited-flag
1328 (setq search-function 're-search-forward
1329 search-string (concat "\\b"
1330 (if regexp-flag from-string
1331 (regexp-quote from-string))
1332 "\\b")))
1333 (when query-replace-lazy-highlight
1334 (setq isearch-string search-string
1335 isearch-regexp (or delimited-flag regexp-flag)
1336 isearch-case-fold-search case-fold-search
1337 isearch-lazy-highlight-last-string nil))
1338
1339 (push-mark)
1340 (undo-boundary)
1341 (unwind-protect
1342 ;; Loop finding occurrences that perhaps should be replaced.
1343 (while (and keep-going
1344 (not (or (eobp) (and limit (>= (point) limit))))
1345 ;; Use the next match if it is already known;
1346 ;; otherwise, search for a match after moving forward
1347 ;; one char if progress is required.
1348 (setq real-match-data
1349 (if (consp match-again)
1350 (progn (goto-char (nth 1 match-again))
1351 (replace-match-data t
1352 real-match-data
1353 match-again))
1354 (and (or match-again
1355 ;; MATCH-AGAIN non-nil means we
1356 ;; accept an adjacent match. If
1357 ;; we don't, move one char to the
1358 ;; right. This takes us a
1359 ;; character too far at the end,
1360 ;; but this is undone after the
1361 ;; while-loop.
1362 (progn
1363 (forward-char 1)
1364 (not (or (eobp)
1365 (and limit (>= (point) limit))))))
1366 (funcall search-function search-string limit t)
1367 ;; For speed, use only integers and
1368 ;; reuse the list used last time.
1369 (replace-match-data t real-match-data)))))
1370 ;; Optionally ignore matches that have a read-only property.
1371 (unless (and query-replace-skip-read-only
1372 (text-property-not-all
1373 (match-beginning 0) (match-end 0)
1374 'read-only nil))
1375
1376 ;; Record whether the match is nonempty, to avoid an infinite loop
1377 ;; repeatedly matching the same empty string.
1378 (setq nonempty-match
1379 (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1380
1381 ;; If the match is empty, record that the next one can't be
1382 ;; adjacent.
1383
1384 ;; Otherwise, if matching a regular expression, do the next
1385 ;; match now, since the replacement for this match may
1386 ;; affect whether the next match is adjacent to this one.
1387 ;; If that match is empty, don't use it.
1388 (setq match-again
1389 (and nonempty-match
1390 (or (not regexp-flag)
1391 (and (looking-at search-string)
1392 (let ((match (match-data)))
1393 (and (/= (nth 0 match) (nth 1 match))
1394 match))))))
1395
1396 ;; Calculate the replacement string, if necessary.
1397 (when replacements
1398 (set-match-data real-match-data)
1399 (setq next-replacement
1400 (funcall (car replacements) (cdr replacements)
1401 replace-count)
1402 noedit nil))
1403 (if (not query-flag)
1404 (let ((inhibit-read-only
1405 query-replace-skip-read-only))
1406 (unless (or literal noedit)
1407 (replace-highlight (nth 0 real-match-data)
1408 (nth 1 real-match-data)))
1409 (setq noedit
1410 (replace-match-maybe-edit
1411 next-replacement nocasify literal
1412 noedit real-match-data)
1413 replace-count (1+ replace-count)))
1414 (undo-boundary)
1415 (let (done replaced key def)
1416 ;; Loop reading commands until one of them sets done,
1417 ;; which means it has finished handling this
1418 ;; occurrence. Any command that sets `done' should
1419 ;; leave behind proper match data for the stack.
1420 ;; Commands not setting `done' need to adjust
1421 ;; `real-match-data'.
1422 (while (not done)
1423 (set-match-data real-match-data)
1424 (replace-highlight (match-beginning 0) (match-end 0))
1425 ;; Bind message-log-max so we don't fill up the message log
1426 ;; with a bunch of identical messages.
1427 (let ((message-log-max nil))
1428 (message message
1429 (query-replace-descr from-string)
1430 (query-replace-descr next-replacement)))
1431 (setq key (read-event))
1432 ;; Necessary in case something happens during read-event
1433 ;; that clobbers the match data.
1434 (set-match-data real-match-data)
1435 (setq key (vector key))
1436 (setq def (lookup-key map key))
1437 ;; Restore the match data while we process the command.
1438 (cond ((eq def 'help)
1439 (with-output-to-temp-buffer "*Help*"
1440 (princ
1441 (concat "Query replacing "
1442 (if regexp-flag "regexp " "")
1443 from-string " with "
1444 next-replacement ".\n\n"
1445 (substitute-command-keys
1446 query-replace-help)))
1447 (with-current-buffer standard-output
1448 (help-mode))))
1449 ((eq def 'exit)
1450 (setq keep-going nil)
1451 (setq done t))
1452 ((eq def 'backup)
1453 (if stack
1454 (let ((elt (pop stack)))
1455 (goto-char (nth 0 elt))
1456 (setq replaced (nth 1 elt)
1457 real-match-data
1458 (replace-match-data
1459 t real-match-data
1460 (nth 2 elt))))
1461 (message "No previous match")
1462 (ding 'no-terminate)
1463 (sit-for 1)))
1464 ((eq def 'act)
1465 (or replaced
1466 (setq noedit
1467 (replace-match-maybe-edit
1468 next-replacement nocasify literal
1469 noedit real-match-data)
1470 replace-count (1+ replace-count)))
1471 (setq done t replaced t))
1472 ((eq def 'act-and-exit)
1473 (or replaced
1474 (setq noedit
1475 (replace-match-maybe-edit
1476 next-replacement nocasify literal
1477 noedit real-match-data)
1478 replace-count (1+ replace-count)))
1479 (setq keep-going nil)
1480 (setq done t replaced t))
1481 ((eq def 'act-and-show)
1482 (if (not replaced)
1483 (setq noedit
1484 (replace-match-maybe-edit
1485 next-replacement nocasify literal
1486 noedit real-match-data)
1487 replace-count (1+ replace-count)
1488 real-match-data (replace-match-data
1489 t real-match-data)
1490 replaced t)))
1491 ((eq def 'automatic)
1492 (or replaced
1493 (setq noedit
1494 (replace-match-maybe-edit
1495 next-replacement nocasify literal
1496 noedit real-match-data)
1497 replace-count (1+ replace-count)))
1498 (setq done t query-flag nil replaced t))
1499 ((eq def 'skip)
1500 (setq done t))
1501 ((eq def 'recenter)
1502 (recenter nil))
1503 ((eq def 'edit)
1504 (let ((opos (point-marker)))
1505 (setq real-match-data (replace-match-data
1506 nil real-match-data
1507 real-match-data))
1508 (goto-char (match-beginning 0))
1509 (save-excursion
1510 (save-window-excursion
1511 (recursive-edit)))
1512 (goto-char opos)
1513 (set-marker opos nil))
1514 ;; Before we make the replacement,
1515 ;; decide whether the search string
1516 ;; can match again just after this match.
1517 (if (and regexp-flag nonempty-match)
1518 (setq match-again (and (looking-at search-string)
1519 (match-data)))))
1520 ;; Edit replacement.
1521 ((eq def 'edit-replacement)
1522 (setq real-match-data (replace-match-data
1523 nil real-match-data
1524 real-match-data)
1525 next-replacement
1526 (read-input "Edit replacement string: "
1527 next-replacement)
1528 noedit nil)
1529 (if replaced
1530 (set-match-data real-match-data)
1531 (setq noedit
1532 (replace-match-maybe-edit
1533 next-replacement nocasify literal noedit
1534 real-match-data)
1535 replaced t))
1536 (setq done t))
1537
1538 ((eq def 'delete-and-edit)
1539 (replace-match "" t t)
1540 (setq real-match-data (replace-match-data
1541 nil real-match-data))
1542 (replace-dehighlight)
1543 (save-excursion (recursive-edit))
1544 (setq replaced t))
1545 ;; Note: we do not need to treat `exit-prefix'
1546 ;; specially here, since we reread
1547 ;; any unrecognized character.
1548 (t
1549 (setq this-command 'mode-exited)
1550 (setq keep-going nil)
1551 (setq unread-command-events
1552 (append (listify-key-sequence key)
1553 unread-command-events))
1554 (setq done t)))
1555 (when query-replace-lazy-highlight
1556 ;; Restore isearch data for lazy highlighting
1557 ;; in case of isearching during recursive edit
1558 (setq isearch-string search-string
1559 isearch-regexp (or delimited-flag regexp-flag)
1560 isearch-case-fold-search case-fold-search)
1561 ;; Force lazy rehighlighting only after replacements
1562 (if (not (memq def '(skip backup)))
1563 (setq isearch-lazy-highlight-last-string nil))))
1564 ;; Record previous position for ^ when we move on.
1565 ;; Change markers to numbers in the match data
1566 ;; since lots of markers slow down editing.
1567 (push (list (point) replaced
1568 ;;; If the replacement has already happened, all we need is the
1569 ;;; current match start and end. We could get this with a trivial
1570 ;;; match like
1571 ;;; (save-excursion (goto-char (match-beginning 0))
1572 ;;; (search-forward (match-string 0))
1573 ;;; (match-data t))
1574 ;;; if we really wanted to avoid manually constructing match data.
1575 ;;; Adding current-buffer is necessary so that match-data calls can
1576 ;;; return markers which are appropriate for editing.
1577 (if replaced
1578 (list
1579 (match-beginning 0)
1580 (match-end 0)
1581 (current-buffer))
1582 (match-data t)))
1583 stack)))))
1584
1585 ;; The code preventing adjacent regexp matches in the condition
1586 ;; of the while-loop above will haven taken us one character
1587 ;; beyond the last replacement. Undo that.
1588 (when (and regexp-flag (not match-again) (> replace-count 0))
1589 (backward-char 1))
1590
1591 (replace-dehighlight))
1592 (or unread-command-events
1593 (message "Replaced %d occurrence%s"
1594 replace-count
1595 (if (= replace-count 1) "" "s")))
1596 (and keep-going stack)))
1597
1598 (defcustom query-replace-highlight t
1599 "*Non-nil means to highlight matches during query replacement."
1600 :type 'boolean
1601 :group 'matching)
1602
1603 (defcustom query-replace-lazy-highlight t
1604 "*Controls the lazy-highlighting during query replacements.
1605 When non-nil, all text in the buffer matching the current match
1606 is highlighted lazily using isearch lazy highlighting (see
1607 `isearch-lazy-highlight-initial-delay' and
1608 `isearch-lazy-highlight-interval')."
1609 :type 'boolean
1610 :group 'matching
1611 :version "21.4")
1612
1613 (defface query-replace
1614 '((t (:inherit isearch)))
1615 "Face for highlighting query replacement matches."
1616 :group 'matching
1617 :version "21.4")
1618
1619 (defvar replace-overlay nil)
1620
1621 (defun replace-highlight (beg end)
1622 (if query-replace-highlight
1623 (if replace-overlay
1624 (move-overlay replace-overlay beg end (current-buffer))
1625 (setq replace-overlay (make-overlay beg end))
1626 (overlay-put replace-overlay 'priority 1) ;higher than lazy overlays
1627 (overlay-put replace-overlay 'face 'query-replace)))
1628 (if query-replace-lazy-highlight
1629 (isearch-lazy-highlight-new-loop)))
1630
1631 (defun replace-dehighlight ()
1632 (when replace-overlay
1633 (delete-overlay replace-overlay))
1634 (when query-replace-lazy-highlight
1635 (isearch-lazy-highlight-cleanup isearch-lazy-highlight-cleanup)
1636 (setq isearch-lazy-highlight-last-string nil)))
1637
1638 ;; arch-tag: 16b4cd61-fd40-497b-b86f-b667c4cf88e4
1639 ;;; replace.el ends here