lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;;; Customizable settings
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40
  41 (defcustom tooltip-delay 0.7
  42   "Seconds to wait before displaying a tooltip the first time."
  43   :tag "Delay"
  44   :type 'number
  45   :group 'tooltip)
  46
  47 (defcustom tooltip-short-delay 0.1
  48   "Seconds to wait between subsequent tooltips on different items."
  49   :tag "Short delay"
  50   :type 'number
  51   :group 'tooltip)
  52
  53 (defcustom tooltip-recent-seconds 1
  54   "Display tooltips if changing tip items within this many seconds.
  55 Do so after `tooltip-short-delay'."
  56   :tag "Recent seconds"
  57   :type 'number
  58   :group 'tooltip)
  59
  60 (defcustom tooltip-hide-delay 10
  61   "Hide tooltips automatically after this many seconds."
  62   :tag "Hide delay"
  63   :type 'number
  64   :group 'tooltip)
  65
  66 (defcustom tooltip-x-offset nil
  67   "X offset, in pixels, for the display of tooltips.
  68 The offset is relative to the position of the mouse.  It must
  69 be chosen so that the tooltip window doesn't contain the mouse
  70 when it pops up.  If the value is nil, the default offset is 5
  71 pixels.
  72
  73 If `tooltip-frame-parameters' includes the `left' parameter,
  74 the value of `tooltip-x-offset' is ignored."
  75   :tag "X offset"
  76   :type '(choice (const :tag "Default" nil)
  77                  (integer :tag "Offset" :value 1))
  78   :group 'tooltip)
  79
  80 (defcustom tooltip-y-offset nil
  81   "Y offset, in pixels, for the display of tooltips.
  82 The offset is relative to the position of the mouse.  It must
  83 be chosen so that the tooltip window doesn't contain the mouse
  84 when it pops up.  If the value is nil, the default offset is -10
  85 pixels.
  86
  87 If `tooltip-frame-parameters' includes the `top' parameter,
  88 the value of `tooltip-y-offset' is ignored."
  89   :tag "Y offset"
  90   :type '(choice (const :tag "Default" nil)
  91                  (integer :tag "Offset" :value 1))
  92   :group 'tooltip)
  93
  94 (defcustom tooltip-frame-parameters
  95   '((name . "tooltip")
  96     (internal-border-width . 5)
  97     (border-width . 1))
  98   "Frame parameters used for tooltips.
  99
 100 If `left' or `top' parameters are included, they specify the absolute
 101 position to pop up the tooltip."
 102   :type 'sexp
 103   :tag "Frame Parameters"
 104   :group 'tooltip)
 105
 106 (defface tooltip
 107   '((((class color))
 108      :background "lightyellow"
 109      :foreground "black"
 110      :inherit variable-pitch)
 111     (t
 112      :inherit variable-pitch))
 113   "Face for tooltips."
 114   :group 'tooltip)
 115
 116 (defcustom tooltip-use-echo-area nil
 117   "Use the echo area instead of tooltip frames for help and GUD tooltips."
 118   :type 'boolean
 119   :tag "Use echo area"
 120   :group 'tooltip)
 121
 122 \f
 123 ;;; Variables that are not customizable.
 124
 125 (defvar tooltip-hook nil
 126   "Functions to call to display tooltips.
 127 Each function is called with one argument EVENT which is a copy of
 128 the last mouse movement event that occurred.")
 129
 130 (defvar tooltip-timeout-id nil
 131   "The id of the timeout started when Emacs becomes idle.")
 132
 133 (defvar tooltip-last-mouse-motion-event nil
 134   "A copy of the last mouse motion event seen.")
 135
 136 (defvar tooltip-hide-time nil
 137   "Time when the last tooltip was hidden.")
 138
 139 ;;; Event accessors
 140
 141 (defun tooltip-event-buffer (event)
 142   "Return the buffer over which event EVENT occurred.
 143 This might return nil if the event did not occur over a buffer."
 144   (let ((window (posn-window (event-end event))))
 145     (and window (window-buffer window))))
 146
 147 ;;; Switching tooltips on/off
 148
 149 ;; We don't set track-mouse globally because this is a big redisplay
 150 ;; problem in buffers having a pre-command-hook or such installed,
 151 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 152 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 153 ;; would be accompanied by a full redisplay.
 154
 155 ;;;###autoload
 156 (define-minor-mode tooltip-mode
 157   "Toggle Tooltip display.
 158 With ARG, turn tooltip mode on if and only if ARG is positive."
 159   :global t
 160   ;; If you change the :init-value below, you also need to change the
 161   ;; corresponding code in startup.el.
 162   :init-value (not (or noninteractive
 163                        (and (boundp 'emacs-quick-startup) emacs-quick-startup)
 164                        (not (and (fboundp 'display-graphic-p)
 165                                  (display-graphic-p)))
 166                        (not (fboundp 'x-show-tip))))
 167   :group 'tooltip
 168   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
 169     (error "Sorry, tooltips are not yet available on this system"))
 170   (if tooltip-mode
 171       (progn
 172         (add-hook 'pre-command-hook 'tooltip-hide)
 173         (add-hook 'tooltip-hook 'tooltip-help-tips))
 174     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
 175       (remove-hook 'pre-command-hook 'tooltip-hide))
 176     (remove-hook 'tooltip-hook 'tooltip-help-tips))
 177   (setq show-help-function
 178         (if tooltip-mode 'tooltip-show-help nil)))
 179
 180 \f
 181 ;;; Timeout for tooltip display
 182
 183 (defun tooltip-delay ()
 184   "Return the delay in seconds for the next tooltip."
 185   (let ((delay tooltip-delay)
 186         (now (float-time)))
 187     (when (and tooltip-hide-time
 188                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 189       (setq delay tooltip-short-delay))
 190     delay))
 191
 192 (defun tooltip-cancel-delayed-tip ()
 193   "Disable the tooltip timeout."
 194   (when tooltip-timeout-id
 195     (disable-timeout tooltip-timeout-id)
 196     (setq tooltip-timeout-id nil)))
 197
 198 (defun tooltip-start-delayed-tip ()
 199   "Add a one-shot timeout to call function `tooltip-timeout'."
 200   (setq tooltip-timeout-id
 201         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 202
 203 (defun tooltip-timeout (object)
 204   "Function called when timer with id `tooltip-timeout-id' fires."
 205   (run-hook-with-args-until-success 'tooltip-hook
 206                                     tooltip-last-mouse-motion-event))
 207
 208 \f
 209 ;;; Displaying tips
 210
 211 (defun tooltip-set-param (alist key value)
 212   "Change the value of KEY in alist ALIST to VALUE.
 213 If there's no association for KEY in ALIST, add one, otherwise
 214 change the existing association.  Value is the resulting alist."
 215   (let ((param (assq key alist)))
 216     (if (consp param)
 217         (setcdr param value)
 218       (push (cons key value) alist))
 219     alist))
 220
 221 (defun tooltip-show (text &optional use-echo-area)
 222   "Show a tooltip window displaying TEXT.
 223
 224 Text larger than `x-max-tooltip-size' is clipped.
 225
 226 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 227 parameters, they determine the x and y position where the tooltip
 228 is displayed.  Otherwise, the tooltip pops at offsets specified by
 229 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 230 position.
 231
 232 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 233 in echo area."
 234   (if use-echo-area
 235       (message "%s" text)
 236     (condition-case error
 237         (let ((params (copy-sequence tooltip-frame-parameters))
 238               (fg (face-attribute 'tooltip :foreground))
 239               (bg (face-attribute 'tooltip :background)))
 240           (when (stringp fg)
 241             (setq params (tooltip-set-param params 'foreground-color fg))
 242             (setq params (tooltip-set-param params 'border-color fg)))
 243           (when (stringp bg)
 244             (setq params (tooltip-set-param params 'background-color bg)))
 245           (x-show-tip (propertize text 'face 'tooltip)
 246                       (selected-frame)
 247                       params
 248                       tooltip-hide-delay
 249                       tooltip-x-offset
 250                       tooltip-y-offset))
 251       (error
 252        (message "Error while displaying tooltip: %s" error)
 253        (sit-for 1)
 254        (message "%s" text)))))
 255
 256 (defun tooltip-hide (&optional ignored-arg)
 257   "Hide a tooltip, if one is displayed.
 258 Value is non-nil if tooltip was open."
 259   (tooltip-cancel-delayed-tip)
 260   (when (x-hide-tip)
 261     (setq tooltip-hide-time (float-time))))
 262
 263 \f
 264 ;;; Debugger-related functions
 265
 266 (defun tooltip-identifier-from-point (point)
 267   "Extract the identifier at POINT, if any.
 268 Value is nil if no identifier exists at point.  Identifier extraction
 269 is based on the current syntax table."
 270   (save-excursion
 271     (goto-char point)
 272     (let ((start (progn (skip-syntax-backward "w_") (point))))
 273       (unless (looking-at "[0-9]")
 274         (skip-syntax-forward "w_")
 275         (when (> (point) start)
 276           (buffer-substring start (point)))))))
 277
 278 (defmacro tooltip-region-active-p ()
 279   "Value is non-nil if the region is currently active."
 280   (if (string-match "^GNU" (emacs-version))
 281       `(and transient-mark-mode mark-active)
 282     `(region-active-p)))
 283
 284 (defun tooltip-expr-to-print (event)
 285   "Return an expression that should be printed for EVENT.
 286 If a region is active and the mouse is inside the region, print
 287 the region.  Otherwise, figure out the identifier around the point
 288 where the mouse is."
 289   (save-excursion
 290     (set-buffer (tooltip-event-buffer event))
 291     (let ((point (posn-point (event-end event))))
 292       (if (tooltip-region-active-p)
 293           (when (and (<= (region-beginning) point) (<= point (region-end)))
 294             (buffer-substring (region-beginning) (region-end)))
 295         (tooltip-identifier-from-point point)))))
 296
 297 (defun tooltip-process-prompt-regexp (process)
 298   "Return regexp matching the prompt of PROCESS at the end of a string.
 299 The prompt is taken from the value of `comint-prompt-regexp' in
 300 the buffer of PROCESS."
 301   (let ((prompt-regexp (save-excursion
 302                          (set-buffer (process-buffer process))
 303                          comint-prompt-regexp)))
 304     ;; Most start with `^' but the one for `sdb' cannot be easily
 305     ;; stripped.  Code the prompt for `sdb' fixed here.
 306     (if (= (aref prompt-regexp 0) ?^)
 307         (setq prompt-regexp (substring prompt-regexp 1))
 308       (setq prompt-regexp "\\*"))
 309     (concat "\n*" prompt-regexp "$")))
 310
 311 (defun tooltip-strip-prompt (process output)
 312   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 313   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 314     (save-match-data
 315       (when (string-match prompt-regexp output)
 316         (setq output (substring output 0 (match-beginning 0)))))
 317     output))
 318
 319 \f
 320 ;;; Tooltip help.
 321
 322 (defvar tooltip-help-message nil
 323   "The last help message received via `tooltip-show-help'.")
 324
 325 (defun tooltip-show-help (msg)
 326   "Function installed as `show-help-function'.
 327 MSG is either a help string to display, or nil to cancel the display."
 328   (let ((previous-help tooltip-help-message))
 329     (setq tooltip-help-message msg)
 330     (cond ((null msg)
 331            ;; Cancel display.  This also cancels a delayed tip, if
 332            ;; there is one.
 333            (tooltip-hide))
 334           ((equal previous-help msg)
 335            ;; Same help as before (but possibly the mouse has moved).
 336            ;; Keep what we have.
 337            )
 338           (t
 339            ;; A different help.  Remove a previous tooltip, and
 340            ;; display a new one, with some delay.
 341            (tooltip-hide)
 342            (tooltip-start-delayed-tip)))))
 343
 344 (defun tooltip-help-tips (event)
 345   "Hook function to display a help tooltip.
 346 This is installed on the hook `tooltip-hook', which is run when
 347 the timer with id `tooltip-timeout-id' fires.
 348 Value is non-nil if this function handled the tip."
 349   (when (stringp tooltip-help-message)
 350     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 351     t))
 352
 353 (provide 'tooltip)
 354
 355 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 356 ;;; tooltip.el ends here