lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 1996 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file parses the command line and gets Emacs running.  Options on
  28 ;; the command line are handled in precedence order.  The order is the
  29 ;; one in the list below; first described means first handled.  Options
  30 ;; within each category (delimited by a bar) are handled in the order
  31 ;; encountered on the command line.
  32
  33 ;; -------------------------
  34 ;; -version                  Print Emacs version to stderr, then exit
  35 ;; --version                 successfully right away.
  36 ;;                           This option is handled by emacs.c
  37 ;; -------------------------
  38 ;; -help                     Print a short usage description and exit
  39 ;; --help                    successfully right away.
  40 ;;                           This option is handled by emacs.c
  41 ;; -------------------------
  42 ;; -nl                       Do not use shared memory (for systems that
  43 ;; -no-shared-memory         support this) for the dumped Emacs data.
  44 ;;                           This option is handled by emacs.c
  45 ;;
  46 ;; -map                      For VMS.
  47 ;; --map-data                This option is handled by emacs.c
  48 ;; -------------------------
  49 ;; -t FILE                   Use FILE as the name of the terminal.
  50 ;; --terminal FILE           Using this implies "-nw" also.
  51 ;;                           This option is handled by emacs.c
  52 ;; -------------------------
  53 ;; -d DISPNAME               Use DISPNAME as the name of the X-windows
  54 ;; -display DISPNAME         display for the initial frame.
  55 ;; --display DISPNAME        This option is handled by emacs.c
  56 ;; -------------------------
  57 ;; -nw                       Do not use a windows system (but use the
  58 ;; --no-windows              terminal instead.)
  59 ;;                           This option is handled by emacs.c
  60 ;; -------------------------
  61 ;; -batch                    Execute noninteractively (messages go to stdout,
  62 ;; --batch                   variable noninteractive set to t)
  63 ;;                           This option is handled by emacs.c
  64 ;; -------------------------
  65 ;; -q                        Do not load user's init file and do not load
  66 ;; -no-init-file             "default.el".  Regardless of this switch,
  67 ;; --no-init-file            "site-start" is still loaded.
  68 ;; -------------------------
  69 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  70 ;; --no-site-file            way to prevent loading that file.)
  71 ;; -------------------------
  72 ;; -u USER                   Load USER's init file instead of the init
  73 ;; -user USER                file belonging to the user starting Emacs.
  74 ;; --user USER
  75 ;; -------------------------
  76 ;; -debug-init               Don't catch errors in init files; let the
  77 ;; --debug-init              debugger run.
  78 ;; -------------------------
  79 ;; -i ICONTYPE               Set type of icon using when Emacs is
  80 ;; -itype ICONTYPE           iconified under X-windows.
  81 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  82 ;;
  83 ;; -iconic                   Start Emacs iconified under X-windows.
  84 ;; --iconic                  This option is passed on to term/x-win.el
  85 ;; -------------------------
  86 ;; Various X-windows options for colors/fonts/geometry/title etc.
  87 ;; These options are passed on to term/x-win.el which see.  Certain
  88 ;; of these are also found in term/pc-win.el
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;;
  92 ;; -L DIRNAME                Add DIRNAME to load-path
  93 ;; -directory DIRNAME
  94 ;; --directory DIRNAME
  95 ;;
  96 ;; -l FILE                   Load and execute the Emacs lisp code
  97 ;; -load FILE                in FILE.
  98 ;; --load FILE
  99 ;;
 100 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 101 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 102 ;; --funcall FUNC            and should not be used.  (It's a typo
 103 ;; -e FUNC                   promoted to a feature.)
 104 ;;
 105 ;; -eval FORM                Execute Emacs lisp form FORM.
 106 ;; --eval FORM
 107 ;;
 108 ;; -insert FILE              Insert the contents of FILE into buffer.
 109 ;; --insert FILE
 110 ;; -------------------------
 111 ;; -kill                     Kill (exit) Emacs right away.
 112 ;; --kill
 113 ;; -------------------------
 114
 115 ;;; Code:
 116
 117 (setq top-level '(normal-top-level))
 118
 119 (defvar command-line-processed nil
 120   "Non-nil once command line has been processed")
 121
 122 (defgroup initialization nil
 123   "Emacs start-up procedure"
 124   :group 'internal)
 125
 126 (defcustom inhibit-startup-message nil
 127   "*Non-nil inhibits the initial startup message.
 128 This is for use in your personal init file, once you are familiar
 129 with the contents of the startup message."
 130   :type 'boolean
 131   :group 'initialization)
 132
 133 (defcustom inhibit-startup-echo-area-message nil
 134   "*Non-nil inhibits the initial startup echo area message.
 135 Setting this variable takes effect
 136 only if you do it with the customization buffer
 137 or it your `.emacs' file contains a line of this form:
 138  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 139 If your `.emacs' file is byte-compiled, use the following form instead:
 140  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 141 Thus, someone else using a copy of your `.emacs' file will see
 142 the startup message unless he personally acts to inhibit it."
 143   :type '(choice (const :tag "Don't inhibit")
 144                  (string :tag "Enter your user name, to inhibit"))
 145   :group 'initialization)
 146
 147 (defcustom inhibit-default-init nil
 148   "*Non-nil inhibits loading the `default' library."
 149   :type 'boolean
 150   :group 'initialization)
 151
 152 (defvar command-switch-alist nil
 153   "Alist of command-line switches.
 154 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 155 HANDLER-FUNCTION receives switch name as sole arg;
 156 remaining command-line args are in the variable `command-line-args-left'.")
 157
 158 (defvar command-line-args-left nil
 159   "List of command-line args not yet processed.")
 160
 161 (defvar command-line-functions nil    ;; lrs 7/31/89
 162   "List of functions to process unrecognized command-line arguments.
 163 Each function should access the dynamically bound variables
 164 `argi' (the current argument) and `command-line-args-left' (the remaining
 165 arguments).  The function should return non-nil only if it recognizes and
 166 processes `argi'.  If it does so, it may consume successive arguments by
 167 altering `command-line-args-left' to remove them.")
 168
 169 (defvar command-line-default-directory nil
 170   "Default directory to use for command line arguments.
 171 This is normally copied from `default-directory' when Emacs starts.")
 172
 173 ;;; This is here, rather than in x-win.el, so that we can ignore these
 174 ;;; options when we are not using X.
 175 (defvar command-line-x-option-alist
 176   '(("-bw" 1 x-handle-numeric-switch border-width)
 177     ("-d" 1 x-handle-display)
 178     ("-display" 1 x-handle-display)
 179     ("-name" 1 x-handle-name-switch)
 180     ("-title" 1 x-handle-switch title)
 181     ("-T" 1 x-handle-switch title)
 182     ("-r" 0 x-handle-switch reverse t)
 183     ("-rv" 0 x-handle-switch reverse t)
 184     ("-reverse" 0 x-handle-switch reverse t)
 185     ("-reverse-video" 0 x-handle-switch reverse t)
 186     ("-fn" 1 x-handle-switch font)
 187     ("-font" 1 x-handle-switch font)
 188     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 189     ("-g" 1 x-handle-geometry)
 190     ("-geometry" 1 x-handle-geometry)
 191     ("-fg" 1 x-handle-switch foreground-color)
 192     ("-foreground" 1 x-handle-switch foreground-color)
 193     ("-bg" 1 x-handle-switch background-color)
 194     ("-background" 1 x-handle-switch background-color)
 195     ("-ms" 1 x-handle-switch mouse-color)
 196     ("-itype" 0 x-handle-switch icon-type t)
 197     ("-i" 0 x-handle-switch icon-type t)
 198     ("-iconic" 0 x-handle-iconic)
 199     ("-xrm" 1 x-handle-xrm-switch)
 200     ("-cr" 1 x-handle-switch cursor-color)
 201     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 202     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 203     ("-bd" 1 x-handle-switch)
 204     ("--border-width" 1 x-handle-numeric-switch border-width)
 205     ("--display" 1 x-handle-display)
 206     ("--name" 1 x-handle-name-switch)
 207     ("--title" 1 x-handle-switch title)
 208     ("--reverse-video" 0 x-handle-switch reverse t)
 209     ("--font" 1 x-handle-switch font)
 210     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 211     ("--geometry" 1 x-handle-geometry)
 212     ("--foreground-color" 1 x-handle-switch foreground-color)
 213     ("--background-color" 1 x-handle-switch background-color)
 214     ("--mouse-color" 1 x-handle-switch mouse-color)
 215     ("--icon-type" 0 x-handle-switch icon-type t)
 216     ("--iconic" 0 x-handle-iconic)
 217     ("--xrm" 1 x-handle-xrm-switch)
 218     ("--cursor-color" 1 x-handle-switch cursor-color)
 219     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 220     ("--border-color" 1 x-handle-switch border-width))
 221   "Alist of X Windows options.
 222 Each element has the form
 223   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 224 where NAME is the option name string, NUMARGS is the number of arguments
 225 that the option accepts, HANDLER is a function to call to handle the option.
 226 FRAME-PARAM (optional) is the frame parameter this option specifies,
 227 and VALUE is the value which is given to that frame parameter
 228 \(most options use the argument for this, so VALUE is not present).")
 229
 230 (defvar before-init-hook nil
 231   "Normal hook run after handling urgent options but before loading init files.")
 232
 233 (defvar after-init-hook nil
 234   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 235 There is no `condition-case' around the running of these functions;
 236 therefore, if you set `debug-on-error' non-nil in `.emacs',
 237 an error in one of these functions will invoke the debugger.")
 238
 239 (defvar emacs-startup-hook nil
 240   "Normal hook run after loading init files and handling the command line.")
 241
 242 (defvar term-setup-hook nil
 243   "Normal hook run after loading terminal-specific Lisp code.
 244 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 245 so as to override the definitions made by the terminal-specific file.
 246 Emacs never sets this variable itself.")
 247
 248 (defvar keyboard-type nil
 249   "The brand of keyboard you are using.
 250 This variable is used to define
 251 the proper function and keypad keys for use under X.  It is used in a
 252 fashion analogous to the environment value TERM.")
 253
 254 (defvar window-setup-hook nil
 255   "Normal hook run to initialize window system display.
 256 Emacs runs this hook after processing the command line arguments and loading
 257 the user's init file.")
 258
 259 (defcustom initial-major-mode 'lisp-interaction-mode
 260   "Major mode command symbol to use for the initial *scratch* buffer."
 261   :type 'command
 262   :group 'initialization)
 263
 264 (defcustom init-file-user nil
 265   "Identity of user whose `.emacs' file is or was read.
 266 The value is nil if `-q' or `--no-init-file' was specified,
 267 meaning do not load any init file.
 268
 269 Otherwise, the value may be the null string, meaning use the init file
 270 for the user that originally logged in, or it may be a
 271 string containing a user's name meaning use that person's init file.
 272
 273 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 274 evaluates to the name of the directory where the `.emacs' file was
 275 looked for.
 276
 277 Setting `init-file-user' does not prevent Emacs from loading
 278 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 279   :type '(choice (const :tag "none" nil) string)
 280   :group 'initialization)
 281
 282 (defcustom site-run-file "site-start"
 283   "File containing site-wide run-time initializations.
 284 This file is loaded at run-time before `~/.emacs'.  It contains inits
 285 that need to be in place for the entire site, but which, due to their
 286 higher incidence of change, don't make sense to load into emacs'
 287 dumped image.  Thus, the run-time load order is: 1. file described in
 288 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 289
 290 Don't use the `site-start.el' file for things some users may not like.
 291 Put them in `default.el' instead, so that users can more easily
 292 override them.  Users can prevent loading `default.el' with the `-q'
 293 option or by setting `inhibit-default-init' in their own init files,
 294 but inhibiting `site-start.el' requires `--no-site-file', which
 295 is less convenient."
 296   :type 'string
 297   :group 'initialization)
 298
 299 (defconst iso-8859-n-locale-regexp "8859[-_]?\\([1-49]\\)"
 300   "Regexp that specifies when to enable an ISO 8859-N character set.
 301 We do that if this regexp matches the locale name
 302 specified by the LC_ALL, LC_CTYPE and LANG environment variables.
 303 The paren group in the regexp should match the specific character
 304 set number, N.")
 305
 306 (defcustom mail-host-address nil
 307   "*Name of this machine, for purposes of naming users."
 308   :type '(choice (const nil) string)
 309   :group 'mail)
 310
 311 (defcustom user-mail-address nil
 312   "*Full mailing address of this user.
 313 This is initialized based on `mail-host-address',
 314 after your init file is read, in case it sets `mail-host-address'."
 315   :type 'string
 316   :group 'mail)
 317
 318 (defcustom auto-save-list-file-prefix
 319   (if (eq system-type 'ms-dos)
 320       "~/_s"  ; MS-DOS cannot have initial dot, and allows only 8.3 names
 321     "~/.saves-")
 322   "Prefix for generating `auto-save-list-file-name'.
 323 This is used after reading your `.emacs' file to initialize
 324 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 325 if you have not already set `auto-save-list-file-name' yourself.
 326 Set this to nil if you want to prevent `auto-save-list-file-name'
 327 from being initialized."
 328   :type 'string
 329   :group 'auto-save)
 330
 331 (defvar init-file-debug nil)
 332
 333 (defvar init-file-had-error nil)
 334
 335 ;; This function is called from the subdirs.el file.
 336 (defun normal-top-level-add-to-load-path (dirs)
 337   (let ((tail (member (directory-file-name default-directory) load-path)))
 338     (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail)))))
 339
 340 (defun normal-top-level ()
 341   (if command-line-processed
 342       (message "Back to top level.")
 343     (setq command-line-processed t)
 344     ;; Give *Messages* the same default-directory as *scratch*,
 345     ;; just to keep things predictable.
 346     (let ((dir default-directory))
 347       (save-excursion
 348         (set-buffer (get-buffer "*Messages*"))
 349         (setq default-directory dir)))
 350     ;; Look in each dir in load-path for a subdirs.el file.
 351     ;; If we find one, load it, which will add the appropriate subdirs
 352     ;; of that dir into load-path,
 353     (let ((tail load-path)
 354           new)
 355       (while tail
 356         (setq new (cons (car tail) new))
 357         (let ((default-directory (car tail)))
 358           (load (expand-file-name "subdirs.el" (car tail)) t t t))
 359         (setq tail (cdr tail))))
 360     (if (not (eq system-type 'vax-vms))
 361         (progn
 362           ;; If the PWD environment variable isn't accurate, delete it.
 363           (let ((pwd (getenv "PWD")))
 364             (and (stringp pwd)
 365                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 366                  ;; describes the directory linked to, not FOO itself.
 367                  (or (equal (file-attributes
 368                              (concat (file-name-as-directory pwd) "."))
 369                             (file-attributes
 370                              (concat (file-name-as-directory default-directory)
 371                                      ".")))
 372                      (setq process-environment
 373                            (delete (concat "PWD=" pwd)
 374                                    process-environment)))))))
 375     (setq default-directory (abbreviate-file-name default-directory))
 376     (let ((menubar-bindings-done nil))
 377       (unwind-protect
 378           (command-line)
 379         ;; Do this again, in case .emacs defined more abbreviations.
 380         (setq default-directory (abbreviate-file-name default-directory))
 381         ;; Specify the file for recording all the auto save files of this session.
 382         ;; This is used by recover-session.
 383         (or auto-save-list-file-name
 384             (and auto-save-list-file-prefix
 385                  (setq auto-save-list-file-name
 386                        ;; Under MS-DOS our PID is almost always reused between
 387                        ;; Emacs invocations.  We need something more unique.
 388                        (if (eq system-type 'ms-dos)
 389                            (concat
 390                             (make-temp-name
 391                              (expand-file-name auto-save-list-file-prefix))
 392                             "~")
 393
 394                          (expand-file-name (format "%s%d-%s~"
 395                                                    auto-save-list-file-prefix
 396                                                    (emacs-pid)
 397                                                    (system-name)))))))
 398         (run-hooks 'emacs-startup-hook)
 399         (and term-setup-hook
 400              (run-hooks 'term-setup-hook))
 401         ;; Modify the initial frame based on what .emacs puts into
 402         ;; ...-frame-alist.
 403         (if (fboundp 'frame-notice-user-settings)
 404             (frame-notice-user-settings))
 405         ;; Now we know the user's default font, so add it to the menu.
 406         (if (fboundp 'font-menu-add-default)
 407             (font-menu-add-default))
 408         (and window-setup-hook
 409              (run-hooks 'window-setup-hook))
 410         (or menubar-bindings-done
 411             (if (memq window-system '(x w32))
 412                 (precompute-menubar-bindings)))))))
 413
 414 ;; Precompute the keyboard equivalents in the menu bar items.
 415 (defun precompute-menubar-bindings ()
 416   (let ((submap (lookup-key global-map [menu-bar])))
 417     (while submap
 418       (and (consp (car submap))
 419            (symbolp (car (car submap)))
 420            (stringp (car-safe (cdr (car submap))))
 421            (keymapp (cdr (cdr (car submap))))
 422            (progn
 423              (x-popup-menu nil (cdr (cdr (car submap))))
 424              (if purify-flag
 425                  (garbage-collect))))
 426       (setq submap (cdr submap))))
 427   (setq define-key-rebound-commands t))
 428
 429 (defun command-line ()
 430   (setq command-line-default-directory default-directory)
 431
 432   ;; See if we should import version-control from the environment variable.
 433   (let ((vc (getenv "VERSION_CONTROL")))
 434     (cond ((eq vc nil))                 ;don't do anything if not set
 435           ((or (string= vc "t")
 436                (string= vc "numbered"))
 437            (setq version-control t))
 438           ((or (string= vc "nil")
 439                (string= vc "existing"))
 440            (setq version-control nil))
 441           ((or (string= vc "never")
 442                (string= vc "simple"))
 443            (setq version-control 'never))))
 444
 445   (let ((ctype
 446          ;; Use the first of these three envvars that has a nonempty value.
 447          (or (let ((string (getenv "LC_ALL")))
 448                (and (not (equal string "")) string))
 449              (let ((string (getenv "LC_CTYPE")))
 450                (and (not (equal string "")) string))
 451              (let ((string (getenv "LANG")))
 452                (and (not (equal string "")) string)))))
 453     (when (and ctype
 454                (string-match iso-8859-n-locale-regexp ctype))
 455       (let (charset (which (match-string 1 ctype)))
 456         (if (equal "5" which)
 457             (setq which "9"))
 458         (setq charset (concat "latin-" which))
 459         ;; Set up for this character set in multibyte mode.
 460         (if (string-match "latin-[12345]" charset)
 461             (set-language-environment charset)))
 462       ;; These two lines are ok for any Latin-N character set,
 463       ;; as long as the terminal displays it.
 464       (require 'disp-table)
 465       (standard-display-european t)))
 466
 467   ;;! This has been commented out; I currently find the behavior when
 468   ;;! split-window-keep-point is nil disturbing, but if I can get used
 469   ;;! to it, then it would be better to eliminate the option.
 470   ;;! ;; Choose a good default value for split-window-keep-point.
 471   ;;! (setq split-window-keep-point (> baud-rate 2400))
 472
 473   ;; Read window system's init file if using a window system.
 474   (condition-case error
 475       (if (and window-system (not noninteractive))
 476           (load (concat term-file-prefix
 477                         (symbol-name window-system)
 478                         "-win")
 479                 ;; Every window system should have a startup file;
 480                 ;; barf if we can't find it.
 481                 nil t))
 482     ;; If we can't read it, print the error message and exit.
 483     (error
 484      (princ
 485       (if (eq (car error) 'error)
 486           (apply 'concat (cdr error))
 487         (if (memq 'file-error (get (car error) 'error-conditions))
 488             (format "%s: %s"
 489                      (nth 1 error)
 490                      (mapconcat '(lambda (obj) (prin1-to-string obj t))
 491                                 (cdr (cdr error)) ", "))
 492           (format "%s: %s"
 493                    (get (car error) 'error-message)
 494                    (mapconcat '(lambda (obj) (prin1-to-string obj t))
 495                               (cdr error) ", "))))
 496       'external-debugging-output)
 497      (setq window-system nil)
 498      (kill-emacs)))
 499
 500   (let ((done nil)
 501         (args (cdr command-line-args)))
 502
 503     ;; Figure out which user's init file to load,
 504     ;; either from the environment or from the options.
 505     (setq init-file-user (if noninteractive nil (user-login-name)))
 506     ;; If user has not done su, use current $HOME to find .emacs.
 507     (and init-file-user (string= init-file-user (user-real-login-name))
 508          (setq init-file-user ""))
 509
 510     ;; Process the command-line args, and delete the arguments
 511     ;; processed.  This is consistent with the way main in emacs.c
 512     ;; does things.
 513     (while (and (not done) args)
 514       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 515                         ("--debug-init") ("--iconic") ("--icon-type")))
 516             (argi (car args))
 517             (argval nil))
 518         ;; Handle --OPTION=VALUE format.
 519         (if (and (string-match "\\`--" argi)
 520                  (string-match "=" argi))
 521             (setq argval (substring argi (match-end 0))
 522                   argi (substring argi 0 (match-beginning 0))))
 523         (or (equal argi "--")
 524             (let ((completion (try-completion argi longopts)))
 525               (if (eq completion t)
 526                   (setq argi (substring argi 1))
 527                 (if (stringp completion)
 528                     (let ((elt (assoc completion longopts)))
 529                       (or elt
 530                           (error "Option `%s' is ambiguous" argi))
 531                       (setq argi (substring (car elt) 1)))
 532                   (setq argval nil)))))
 533         (cond
 534          ((or (string-equal argi "-q")
 535               (string-equal argi "-no-init-file"))
 536           (setq init-file-user nil
 537                 args (cdr args)))
 538          ((or (string-equal argi "-u")
 539               (string-equal argi "-user"))
 540           (or argval
 541               (setq args (cdr args)
 542                     argval (car args)))
 543           (setq init-file-user argval
 544                 argval nil
 545                 args (cdr args)))
 546          ((string-equal argi "-no-site-file")
 547           (setq site-run-file nil
 548                 args (cdr args)))
 549          ((string-equal argi "-debug-init")
 550           (setq init-file-debug t
 551                 args (cdr args)))
 552          ((string-equal argi "-iconic")
 553           (setq initial-frame-alist
 554                 (cons '(visibility . icon) initial-frame-alist))
 555           (setq args (cdr args)))
 556          ((or (string-equal argi "-icon-type")
 557               (string-equal argi "-i")
 558               (string-equal argi "-itype"))
 559           (setq default-frame-alist
 560                 (cons '(icon-type . t) default-frame-alist))
 561           (setq args (cdr args)))
 562          (t (setq done t)))
 563         ;; Was argval set but not used?
 564         (and argval
 565              (error "Option `%s' doesn't allow an argument" argi))))
 566
 567     ;; Re-attach the program name to the front of the arg list.
 568     (and command-line-args (setcdr command-line-args args)))
 569
 570   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 571   (if (fboundp 'frame-initialize)
 572       (frame-initialize))
 573   ;; If frame was created with a menu bar, set menu-bar-mode on.
 574   (if (or (not (memq window-system '(x w32)))
 575           (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0))
 576       (menu-bar-mode t))
 577
 578   (run-hooks 'before-init-hook)
 579
 580   ;; Run the site-start library if it exists.  The point of this file is
 581   ;; that it is run before .emacs.  There is no point in doing this after
 582   ;; .emacs; that is useless.
 583   (if site-run-file
 584       (load site-run-file t t))
 585
 586   ;; Register avairable input methods by loading LEIM list file.
 587   (load "leim-list.el" 'noerror 'nomessage 'nosuffix)
 588
 589   ;; Sites should not disable this.  Only individuals should disable
 590   ;; the startup message.
 591   (setq inhibit-startup-message nil)
 592
 593   ;; Load that user's init file, or the default one, or none.
 594   (let (debug-on-error-from-init-file
 595         debug-on-error-should-be-set
 596         (debug-on-error-initial
 597          (if (eq init-file-debug t) 'startup init-file-debug)))
 598     (let ((debug-on-error debug-on-error-initial)
 599           ;; This function actually reads the init files.
 600           (inner
 601            (function
 602             (lambda ()
 603               (if init-file-user
 604                   (progn
 605                     (setq user-init-file
 606                           (cond
 607                            ((eq system-type 'ms-dos)
 608                             (concat "~" init-file-user "/_emacs"))
 609                            ((eq system-type 'windows-nt)
 610                             (if (file-exists-p "~/.emacs")
 611                                 "~/.emacs"
 612                               "~/_emacs"))
 613                            ((eq system-type 'vax-vms)
 614                             "sys$login:.emacs")
 615                            (t
 616                             (concat "~" init-file-user "/.emacs"))))
 617                     (load user-init-file t t t)
 618                     (or inhibit-default-init
 619                         (let ((inhibit-startup-message nil))
 620                           ;; Users are supposed to be told their rights.
 621                           ;; (Plus how to get help and how to undo.)
 622                           ;; Don't you dare turn this off for anyone
 623                           ;; except yourself.
 624                           (load "default" t t)))))))))
 625       (if init-file-debug
 626           ;; Do this without a condition-case if the user wants to debug.
 627           (funcall inner)
 628         (condition-case error
 629             (progn
 630               (funcall inner)
 631               (setq init-file-had-error nil))
 632           (error (message "Error in init file: %s%s%s"
 633                           (get (car error) 'error-message)
 634                           (if (cdr error) ": " "")
 635                           (mapconcat 'prin1-to-string (cdr error) ", "))
 636                  (setq init-file-had-error t))))
 637       ;; If we can tell that the init file altered debug-on-error,
 638       ;; arrange to preserve the value that it set up.
 639       (or (eq debug-on-error debug-on-error-initial)
 640           (setq debug-on-error-should-be-set t
 641                 debug-on-error-from-init-file debug-on-error)))
 642     (if debug-on-error-should-be-set
 643         (setq debug-on-error debug-on-error-from-init-file)))
 644
 645   ;; Do this here in case the init file sets mail-host-address.
 646   (or user-mail-address
 647       (setq user-mail-address (concat (user-login-name) "@"
 648                                       (or mail-host-address
 649                                           (system-name)))))
 650
 651   (run-hooks 'after-init-hook)
 652
 653   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 654   (if (get-buffer "*scratch*")
 655       (save-excursion
 656         (set-buffer "*scratch*")
 657         (if (eq major-mode 'fundamental-mode)
 658             (funcall initial-major-mode))))
 659   ;; Load library for our terminal type.
 660   ;; User init file can set term-file-prefix to nil to prevent this.
 661   (and term-file-prefix (not noninteractive) (not window-system)
 662        (let ((term (getenv "TERM"))
 663              hyphend)
 664          (while (and term
 665                      (not (load (concat term-file-prefix term) t t)))
 666            ;; Strip off last hyphen and what follows, then try again
 667            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 668                (setq term (substring term 0 hyphend))
 669              (setq term nil)))))
 670
 671   ;; Process the remaining args.
 672   (command-line-1 (cdr command-line-args))
 673
 674   ;; If -batch, terminate after processing the command options.
 675   (if noninteractive (kill-emacs t)))
 676
 677 (defun command-line-1 (command-line-args-left)
 678   (or noninteractive (input-pending-p) init-file-had-error
 679       (and inhibit-startup-echo-area-message
 680            (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
 681                     (equal inhibit-startup-echo-area-message
 682                            (if (string= init-file-user "")
 683                                (user-login-name)
 684                              init-file-user)))
 685                ;; Wasn't set with custom; see if .emacs has a setq.
 686                (let ((buffer (get-buffer-create " *temp*")))
 687                  (prog1
 688                      (condition-case nil
 689                          (save-excursion
 690                            (set-buffer buffer)
 691                            (insert-file-contents user-init-file)
 692                            (re-search-forward
 693                             (concat
 694                              "([ \t\n]*setq[ \t\n]+"
 695                              "inhibit-startup-echo-area-message[ \t\n]+"
 696                              (regexp-quote
 697                               (prin1-to-string
 698                                (if (string= init-file-user "")
 699                                    (user-login-name)
 700                                  init-file-user)))
 701                              "[ \t\n]*)")
 702                             nil t))
 703                        (error nil))
 704                    (kill-buffer buffer)))))
 705       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 706                    "For information about the GNU Project and its goals, type C-h C-p."
 707                  (substitute-command-keys
 708                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 709   (if (null command-line-args-left)
 710       (cond ((and (not inhibit-startup-message) (not noninteractive)
 711                   ;; Don't clobber a non-scratch buffer if init file
 712                   ;; has selected it.
 713                   (string= (buffer-name) "*scratch*")
 714                   (not (input-pending-p)))
 715              ;; If there are no switches to process, we might as well
 716              ;; run this hook now, and there may be some need to do it
 717              ;; before doing any output.
 718              (and term-setup-hook
 719                   (run-hooks 'term-setup-hook))
 720              ;; Don't let the hook be run twice.
 721              (setq term-setup-hook nil)
 722
 723              ;; It's important to notice the user settings before we
 724              ;; display the startup message; otherwise, the settings
 725              ;; won't take effect until the user gives the first
 726              ;; keystroke, and that's distracting.
 727              (if (fboundp 'frame-notice-user-settings)
 728                  (frame-notice-user-settings))
 729
 730              (and window-setup-hook
 731                   (run-hooks 'window-setup-hook))
 732              (setq window-setup-hook nil)
 733              ;; Do this now to avoid an annoying delay if the user
 734              ;; clicks the menu bar during the sit-for.
 735              (if (memq window-system '(x w32))
 736                  (precompute-menubar-bindings))
 737              (setq menubar-bindings-done t)
 738              (when (= (buffer-size) 0)
 739                (let ((buffer-undo-list t))
 740                  (unwind-protect
 741                      (progn
 742                        (goto-char (point-max))
 743                        ;; The convention for this piece of code is that
 744                        ;; each piece of output starts with one or two newlines
 745                        ;; and does not end with any newlines.
 746                        (insert "Welcome to GNU Emacs")
 747                        (if (eq system-type 'gnu/linux)
 748                            (insert ", one component of a Linux-based GNU system."))
 749                        (insert "\n")
 750                        ;; If keys have their default meanings,
 751                        ;; use precomputed string to save lots of time.
 752                        (if (and (eq (key-binding "\C-h") 'help-command)
 753                                 (eq (key-binding "\C-xu") 'advertised-undo)
 754                                 (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 755                                 (eq (key-binding "\C-ht") 'help-with-tutorial)
 756                                 (eq (key-binding "\C-hi") 'info)
 757                                 (eq (key-binding "\C-h\C-n") 'view-emacs-news))
 758                            (insert "
 759 Get help           C-h  (Hold down CTRL and press h)
 760 Undo changes       C-x u       Exit Emacs               C-x C-c
 761 Get a tutorial     C-h t       Use Info to read docs    C-h i")
 762                          (insert (substitute-command-keys
 763                                   (format "\n
 764 Get help           %s
 765 Undo changes       \\[advertised-undo]
 766 Exit Emacs         \\[save-buffers-kill-emacs]
 767 Get a tutorial     \\[help-with-tutorial]
 768 Use Info to read docs   \\[info]"
 769                                           (let ((where (where-is-internal
 770                                                         'help-command nil t)))
 771                                             (if where
 772                                                 (key-description where)
 773                                               "M-x help"))))))
 774                        ;; Say how to use the menu bar
 775                        ;; if that is not with the mouse.
 776                        (if (not (assq 'display (frame-parameters)))
 777                            (if (and (eq (key-binding "\M-`") 'tmm-menubar)
 778                                     (eq (key-binding [f10]) 'tmm-menubar))
 779                                (insert "
 780 Activate menubar   F10  or  ESC `  or   M-`")
 781                              (insert (substitute-command-keys "
 782 Activate menubar     \\[tmm-menubar]"))))
 783
 784                        ;; Windows and MSDOS (currently) do not count as
 785                        ;; window systems, but do have mouse support.
 786                        (if window-system
 787                            (insert "
 788 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
 789                        ;; Many users seem to have problems with these.
 790                        (insert "
 791 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
 792 If you have no Meta key, you may instead type ESC followed by the character.)")
 793                        (and auto-save-list-file-prefix
 794                             (directory-files
 795                              (file-name-directory auto-save-list-file-prefix)
 796                              nil
 797                              (concat "\\`"
 798                                      (regexp-quote (file-name-nondirectory
 799                                                     auto-save-list-file-prefix)))
 800                              t)
 801                             (insert "\n\nIf an Emacs session crashed recently, "
 802                                     "type M-x recover-session RET\nto recover"
 803                                     " the files you were editing."))
 804
 805                        (insert "\n\n" (emacs-version)
 806                                "
 807 Copyright (C) 1996 Free Software Foundation, Inc.")
 808                        (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
 809                                 (eq (key-binding "\C-h\C-d") 'describe-distribution)
 810                                 (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
 811                            (insert
 812                             "\n
 813 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 814 You may give out copies of Emacs; type C-h C-c to see the conditions.
 815 Type C-h C-d for information on getting the latest version.")
 816                          (insert (substitute-command-keys
 817                                   "\n
 818 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 819 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 820 Type \\[describe-distribution] for information on getting the latest version.")))
 821                        (goto-char (point-min))
 822
 823                        (set-buffer-modified-p nil)
 824                        (sit-for 120))
 825                    (with-current-buffer (get-buffer "*scratch*")
 826                      (erase-buffer)
 827                      (insert "\
 828 If you want to create a file, don't type the text in this buffer.
 829 This buffer is for notes you don't want to save, and for Lisp evaluation.
 830 If you want to create a file, first visit that file with C-x C-f,
 831 then enter the text in that file's own buffer.
 832
 833 ")
 834                      (set-buffer-modified-p nil)))))))
 835     ;; Delay 2 seconds after the init file error message
 836     ;; was displayed, so user can read it.
 837     (if init-file-had-error
 838         (sit-for 2))
 839     (let ((dir command-line-default-directory)
 840           (file-count 0)
 841           first-file-buffer
 842           tem
 843           just-files  ;; t if this follows the magic -- option.
 844           ;; This includes our standard options' long versions
 845           ;; and long versions of what's on command-switch-alist.
 846           (longopts
 847            (append '(("--funcall") ("--load") ("--insert") ("--kill")
 848                      ("--directory") ("--eval") ("--find-file") ("--visit"))
 849                    (mapcar '(lambda (elt)
 850                               (list (concat "-" (car elt))))
 851                            command-switch-alist)))
 852           (line 0))
 853
 854       ;; Add the long X options to longopts.
 855       (setq tem command-line-x-option-alist)
 856       (while tem
 857         (if (string-match "^--" (car (car tem)))
 858             (setq longopts (cons (list (car (car tem))) longopts)))
 859         (setq tem (cdr tem)))
 860
 861       ;; Loop, processing options.
 862       (while (and command-line-args-left)
 863         (let* ((argi (car command-line-args-left))
 864                (orig-argi argi)
 865                argval completion
 866                ;; List of directories specified in -L/--directory,
 867                ;; in reverse of the order specified.
 868                extra-load-path
 869                (initial-load-path load-path))
 870           (setq command-line-args-left (cdr command-line-args-left))
 871
 872           ;; Do preliminary decoding of the option.
 873           (if just-files
 874               ;; After --, don't look for options; treat all args as files.
 875               (setq argi "")
 876             ;; Convert long options to ordinary options
 877             ;; and separate out an attached option argument into argval.
 878             (if (string-match "^--[^=]*=" argi)
 879                 (setq argval (substring argi (match-end 0))
 880                       argi (substring argi 0 (1- (match-end 0)))))
 881             (if (equal argi "--")
 882                 (setq completion nil)
 883               (setq completion (try-completion argi longopts)))
 884             (if (eq completion t)
 885                 (setq argi (substring argi 1))
 886               (if (stringp completion)
 887                   (let ((elt (assoc completion longopts)))
 888                     (or elt
 889                         (error "Option `%s' is ambiguous" argi))
 890                     (setq argi (substring (car elt) 1)))
 891                 (setq argval nil argi orig-argi))))
 892
 893           ;; Execute the option.
 894           (cond ((setq tem (assoc argi command-switch-alist))
 895                  (if argval
 896                      (let ((command-line-args-left
 897                             (cons argval command-line-args-left)))
 898                        (funcall (cdr tem) argi))
 899                    (funcall (cdr tem) argi)))
 900                 ((or (string-equal argi "-f")  ;what the manual claims
 901                      (string-equal argi "-funcall")
 902                      (string-equal argi "-e")) ; what the source used to say
 903                  (if argval
 904                      (setq tem (intern argval))
 905                    (setq tem (intern (car command-line-args-left)))
 906                    (setq command-line-args-left (cdr command-line-args-left)))
 907                  (if (arrayp (symbol-function tem))
 908                      (command-execute tem)
 909                    (funcall tem)))
 910                 ((string-equal argi "-eval")
 911                  (if argval
 912                      (setq tem argval)
 913                    (setq tem (car command-line-args-left))
 914                    (setq command-line-args-left (cdr command-line-args-left)))
 915                  (eval (read tem)))
 916                 ;; Set the default directory as specified in -L.
 917                 ((or (string-equal argi "-L")
 918                      (string-equal argi "-directory"))
 919                  (if argval
 920                      (setq tem argval)
 921                    (setq tem (car command-line-args-left)
 922                          command-line-args-left (cdr command-line-args-left)))
 923                  (setq tem (command-line-normalize-file-name tem))
 924                  (setq extra-load-path
 925                        (cons (expand-file-name tem) extra-load-path))
 926                  (setq load-path (append (nreverse extra-load-path)
 927                                          initial-load-path)))
 928                 ((or (string-equal argi "-l")
 929                      (string-equal argi "-load"))
 930                  (if argval
 931                      (setq tem argval)
 932                    (setq tem (car command-line-args-left)
 933                          command-line-args-left (cdr command-line-args-left)))
 934                  (let ((file (command-line-normalize-file-name tem)))
 935                    ;; Take file from default dir if it exists there;
 936                    ;; otherwise let `load' search for it.
 937                    (if (file-exists-p (expand-file-name file))
 938                        (setq file (expand-file-name file)))
 939                    (load file nil t)))
 940                 ((string-equal argi "-insert")
 941                  (if argval
 942                      (setq tem argval)
 943                    (setq tem (car command-line-args-left)
 944                          command-line-args-left (cdr command-line-args-left)))
 945                  (or (stringp tem)
 946                      (error "File name omitted from `-insert' option"))
 947                  (insert-file-contents (command-line-normalize-file-name tem)))
 948                 ((string-equal argi "-kill")
 949                  (kill-emacs t))
 950                 ((string-match "^\\+[0-9]+\\'" argi)
 951                  (setq line (string-to-int argi)))
 952                 ((setq tem (assoc argi command-line-x-option-alist))
 953                  ;; Ignore X-windows options and their args if not using X.
 954                  (setq command-line-args-left
 955                        (nthcdr (nth 1 tem) command-line-args-left)))
 956                 ((or (string-equal argi "-find-file")
 957                      (string-equal argi "-visit"))
 958                  ;; An explicit option to specify visiting a file.
 959                  (setq file-count (1+ file-count))
 960                  (let ((file
 961                         (expand-file-name
 962                          (command-line-normalize-file-name orig-argi)
 963                          dir)))
 964                    (if (= file-count 1)
 965                        (setq first-file-buffer (find-file file))
 966                      (find-file-other-window file)))
 967                  (or (zerop line)
 968                      (goto-line line))
 969                  (setq line 0))
 970                 ((equal argi "--")
 971                  (setq just-files t))
 972                 (t
 973                  ;; We have almost exhausted our options. See if the
 974                  ;; user has made any other command-line options available
 975                  (let ((hooks command-line-functions);; lrs 7/31/89
 976                        (did-hook nil))
 977                    (while (and hooks
 978                                (not (setq did-hook (funcall (car hooks)))))
 979                      (setq hooks (cdr hooks)))
 980                    (if (not did-hook)
 981                        ;; Ok, presume that the argument is a file name
 982                        (progn
 983                          (if (string-match "\\`-" argi)
 984                              (error "Unknown option `%s'" argi))
 985                          (setq file-count (1+ file-count))
 986                          (let ((file
 987                                 (expand-file-name
 988                                  (command-line-normalize-file-name orig-argi)
 989                                  dir)))
 990                            (if (= file-count 1)
 991                                (setq first-file-buffer (find-file file))
 992                              (find-file-other-window file)))
 993                          (or (zerop line)
 994                              (goto-line line))
 995                          (setq line 0))))))))
 996       ;; If 3 or more files visited, and not all visible,
 997       ;; show user what they all are.
 998       (and (> file-count 2)
 999            (not noninteractive)
1000            (or (get-buffer-window first-file-buffer)
1001                (progn (other-window 1)
1002                       (buffer-menu)))))))
1003
1004 (defun command-line-normalize-file-name (file)
1005   "Collapse multiple slashes to one, to handle non-Emacs file names."
1006   (save-match-data
1007     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1008     ;; That is significant on some systems.
1009     ;; However, /// at the beginning is supposed to mean just /, not //.
1010     (if (string-match "^///+" file)
1011         (setq file (replace-match "/" t t file)))
1012     (while (string-match "//+" file 1)
1013       (setq file (replace-match "/" t t file)))
1014     file))
1015
1016 ;;; startup.el ends here