lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter
   2
   3 ;; Copyright (C) 1989, 1994, 1998, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do M-x `describe-mode'.
  33 ;;
  34 ;; NOTE: Remember to change `hexl-program' or `hexl-options' if needed.
  35 ;;
  36 ;; Currently hexl only supports big endian hex output with 16 bit
  37 ;; grouping.
  38 ;;
  39 ;; -iso in `hexl-options' will allow iso characters to display in the
  40 ;; ASCII region of the screen (if your emacs supports this) instead of
  41 ;; changing them to dots.
  42
  43 ;;; Code:
  44
  45 ;;
  46 ;; vars here
  47 ;;
  48
  49 (defgroup hexl nil
  50   "Edit a file in a hex dump format using the hexl filter."
  51   :group 'data)
  52
  53
  54 (defcustom hexl-program "hexl"
  55   "The program that will hexlify and dehexlify its stdin.
  56 `hexl-program' will always be concatenated with `hexl-options'
  57 and \"-de\" when dehexlifying a buffer."
  58   :type 'string
  59   :group 'hexl)
  60
  61 (defcustom hexl-iso ""
  62   "If your emacs can handle ISO characters, this should be set to
  63 \"-iso\" otherwise it should be \"\"."
  64   :type 'string
  65   :group 'hexl)
  66
  67 (defcustom hexl-options (format "-hex %s" hexl-iso)
  68   "Options to `hexl-program' that suit your needs."
  69   :type 'string
  70   :group 'hexl)
  71
  72 (defcustom hexlify-command
  73   (format "%s %s"
  74           (shell-quote-argument
  75            (expand-file-name hexl-program exec-directory))
  76           hexl-options)
  77   "The command to use to hexlify a buffer."
  78   :type 'string
  79   :group 'hexl)
  80
  81 (defcustom dehexlify-command
  82   (format "%s -de %s"
  83           (shell-quote-argument
  84            (expand-file-name hexl-program exec-directory))
  85           hexl-options)
  86   "The command to use to unhexlify a buffer."
  87   :type 'string
  88   :group 'hexl)
  89
  90 (defcustom hexl-follow-ascii t
  91   "If non-nil then highlight the ASCII character corresponding to point."
  92   :type 'boolean
  93   :group 'hexl
  94   :version "20.3")
  95
  96 (defvar hexl-max-address 0
  97   "Maximum offset into hexl buffer.")
  98
  99 (defvar hexl-mode-map nil)
 100
 101 (defvar hexl-mode-old-local-map)
 102 (defvar hexl-mode-old-mode-name)
 103 (defvar hexl-mode-old-major-mode)
 104 (defvar hexl-mode-old-write-contents-hooks)
 105 (defvar hexl-mode-old-require-final-newline)
 106 (defvar hexl-mode-old-syntax-table)
 107
 108 (defvar hexl-ascii-overlay nil
 109   "Overlay used to highlight ASCII element corresponding to current point.")
 110 (make-variable-buffer-local 'hexl-ascii-overlay)
 111
 112 ;; routines
 113
 114 (put 'hexl-mode 'mode-class 'special)
 115
 116 ;;;###autoload
 117 (defun hexl-mode (&optional arg)
 118   "\\<hexl-mode-map>A mode for editing binary files in hex dump format.
 119 This is not an ordinary major mode; it alters some aspects
 120 if the current mode's behavior, but not all; also, you can exit
 121 Hexl mode and return to the previous mode using `hexl-mode-exit'.
 122
 123 This function automatically converts a buffer into the hexl format
 124 using the function `hexlify-buffer'.
 125
 126 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 127 representing the offset into the file that the characters on this line
 128 are at and 16 characters from the file (displayed as hexadecimal
 129 values grouped every 16 bits) and as their ASCII values.
 130
 131 If any of the characters (displayed as ASCII characters) are
 132 unprintable (control or meta characters) they will be replaced as
 133 periods.
 134
 135 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 136 in hexl format.
 137
 138 A sample format:
 139
 140   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 141   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 142   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 143   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 144   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 145   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 146   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 147   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 148   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 149   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 150   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 151   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 152   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 153   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 154   000000c0: 7265 6769 6f6e 2e0a                      region..
 155
 156 Movement is as simple as movement in a normal emacs text buffer.  Most
 157 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 158 to move the cursor left, right, down, and up).
 159
 160 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 161 also supported.
 162
 163 There are several ways to change text in hexl mode:
 164
 165 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 166 bound to self-insert so you can simply type the character and it will
 167 insert itself (actually overstrike) into the buffer.
 168
 169 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 170 it isn't bound to self-insert.  An octal number can be supplied in place
 171 of another key to insert the octal number's ASCII representation.
 172
 173 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 174 into the buffer at the current point.
 175
 176 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 177 into the buffer at the current point.
 178
 179 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 180 into the buffer at the current point.
 181
 182 \\[hexl-mode-exit] will exit hexl-mode.
 183
 184 Note: saving the file with any of the usual Emacs commands
 185 will actually convert it back to binary format while saving.
 186
 187 You can use \\[hexl-find-file] to visit a file in Hexl mode.
 188
 189 \\[describe-bindings] for advanced commands."
 190   (interactive "p")
 191   (unless (eq major-mode 'hexl-mode)
 192     (let ((modified (buffer-modified-p))
 193           (inhibit-read-only t)
 194           (original-point (1- (point)))
 195           max-address)
 196       (and (eobp) (not (bobp))
 197            (setq original-point (1- original-point)))
 198       (if (not (or (eq arg 1) (not arg)))
 199           ;; if no argument then we guess at hexl-max-address
 200           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 201         (setq max-address (1- (buffer-size)))
 202         ;; If the buffer's EOL type is -dos, we need to account for
 203         ;; extra CR characters added when hexlify-buffer writes the
 204         ;; buffer to a file.
 205         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 206           (setq max-address (+ (count-lines (point-min) (point-max))
 207                                max-address))
 208           ;; But if there's no newline at the last line, we are off by
 209           ;; one; adjust.
 210           (or (eq (char-before (point-max)) ?\n)
 211               (setq max-address (1- max-address)))
 212           (setq original-point (+ (count-lines (point-min) (point))
 213                                   original-point))
 214           (or (bolp) (setq original-point (1- original-point))))
 215         (hexlify-buffer)
 216         (set-buffer-modified-p modified))
 217       (make-local-variable 'hexl-max-address)
 218       (setq hexl-max-address max-address)
 219       (hexl-goto-address original-point))
 220
 221     ;; We do not turn off the old major mode; instead we just
 222     ;; override most of it.  That way, we can restore it perfectly.
 223     (make-local-variable 'hexl-mode-old-local-map)
 224     (setq hexl-mode-old-local-map (current-local-map))
 225     (use-local-map hexl-mode-map)
 226
 227     (make-local-variable 'hexl-mode-old-mode-name)
 228     (setq hexl-mode-old-mode-name mode-name)
 229     (setq mode-name "Hexl")
 230
 231     (make-local-variable 'hexl-mode-old-major-mode)
 232     (setq hexl-mode-old-major-mode major-mode)
 233     (setq major-mode 'hexl-mode)
 234
 235     (make-local-variable 'hexl-mode-old-syntax-table)
 236     (setq hexl-mode-old-syntax-table (syntax-table))
 237     (set-syntax-table (standard-syntax-table))
 238
 239     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 240     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 241     (make-local-variable 'write-contents-hooks)
 242     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 243
 244     (make-local-variable 'hexl-mode-old-require-final-newline)
 245     (setq hexl-mode-old-require-final-newline require-final-newline)
 246     (make-local-variable 'require-final-newline)
 247     (setq require-final-newline nil)
 248
 249     ;; Add hooks to rehexlify or dehexlify on various events.
 250     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 251
 252     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 253
 254     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 255   (run-hooks 'hexl-mode-hook))
 256
 257 (defun hexl-after-revert-hook ()
 258   (setq hexl-max-address (1- (buffer-size)))
 259   (hexlify-buffer)
 260   (set-buffer-modified-p nil))
 261
 262 (defvar hexl-in-save-buffer nil)
 263
 264 (defun hexl-save-buffer ()
 265   "Save a hexl format buffer as binary in visited file if modified."
 266   (interactive)
 267   (if hexl-in-save-buffer nil
 268     (set-buffer-modified-p (if (buffer-modified-p)
 269                                (save-excursion
 270                                  (let ((buf (generate-new-buffer " hexl"))
 271                                        (name (buffer-name))
 272                                        (file-name (buffer-file-name))
 273                                        (start (point-min))
 274                                        (end (point-max))
 275                                        modified)
 276                                    (set-buffer buf)
 277                                    (insert-buffer-substring name start end)
 278                                    (set-buffer name)
 279                                    (dehexlify-buffer)
 280                                    ;; Prevent infinite recursion.
 281                                    (let ((hexl-in-save-buffer t))
 282                                      (save-buffer))
 283                                    (setq modified (buffer-modified-p))
 284                                    (delete-region (point-min) (point-max))
 285                                    (insert-buffer-substring buf start end)
 286                                    (kill-buffer buf)
 287                                    modified))
 288                              (message "(No changes need to be saved)")
 289                              nil))
 290     ;; Return t to indicate we have saved t
 291     t))
 292
 293 ;;;###autoload
 294 (defun hexl-find-file (filename)
 295   "Edit file FILENAME in hexl-mode.
 296 Switch to a buffer visiting file FILENAME, creating one in none exists."
 297   (interactive "fFilename: ")
 298   (find-file-literally filename)
 299   (if (not (eq major-mode 'hexl-mode))
 300       (hexl-mode)))
 301
 302 (defun hexl-mode-exit (&optional arg)
 303   "Exit Hexl mode, returning to previous mode.
 304 With arg, don't unhexlify buffer."
 305   (interactive "p")
 306   (if (or (eq arg 1) (not arg))
 307       (let ((modified (buffer-modified-p))
 308             (inhibit-read-only t)
 309             (original-point (1+ (hexl-current-address))))
 310         (dehexlify-buffer)
 311         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 312         (set-buffer-modified-p modified)
 313         (goto-char original-point)
 314         ;; Maybe adjust point for the removed CR characters.
 315         (when (eq (coding-system-eol-type buffer-file-coding-system) 1)
 316           (setq original-point (- original-point
 317                                   (count-lines (point-min) (point))))
 318           (or (bobp) (setq original-point (1+ original-point))))
 319         (goto-char original-point)))
 320
 321   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 322   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 323   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 324   (setq hexl-ascii-overlay nil)
 325
 326   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 327   (setq require-final-newline hexl-mode-old-require-final-newline)
 328   (setq mode-name hexl-mode-old-mode-name)
 329   (use-local-map hexl-mode-old-local-map)
 330   (set-syntax-table hexl-mode-old-syntax-table)
 331   (setq major-mode hexl-mode-old-major-mode)
 332   (force-mode-line-update))
 333
 334 (defun hexl-maybe-dehexlify-buffer ()
 335   "Convert a hexl format buffer to binary.
 336 Ask the user for confirmation."
 337   (if (y-or-n-p "Convert contents back to binary format? ")
 338       (let ((modified (buffer-modified-p))
 339             (inhibit-read-only t)
 340             (original-point (1+ (hexl-current-address))))
 341         (dehexlify-buffer)
 342         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 343         (set-buffer-modified-p modified)
 344         (goto-char original-point))))
 345
 346 (defun hexl-current-address (&optional validate)
 347   "Return current hexl-address."
 348   (interactive)
 349   (let ((current-column (- (% (point) 68) 11))
 350         (hexl-address 0))
 351     (if (< current-column 0)
 352         (if validate
 353             (error "Point is not on a character in the file")
 354           (setq current-column 0)))
 355     (setq hexl-address
 356           (+ (* (/ (point) 68) 16)
 357              (if (>= current-column 41)
 358                  (- current-column 41)
 359                (/ (- current-column  (/ current-column 5)) 2))))
 360     (when (interactive-p)
 361       (message "Current address is %d" hexl-address))
 362     hexl-address))
 363
 364 (defun hexl-address-to-marker (address)
 365   "Return buffer position for ADDRESS."
 366   (interactive "nAddress: ")
 367   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 368
 369 (defun hexl-goto-address (address)
 370   "Goto hexl-mode (decimal) address ADDRESS.
 371 Signal error if ADDRESS out of range."
 372   (interactive "nAddress: ")
 373   (if (or (< address 0) (> address hexl-max-address))
 374           (error "Out of hexl region"))
 375   (goto-char (hexl-address-to-marker address)))
 376
 377 (defun hexl-goto-hex-address (hex-address)
 378   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 379 Signal error if HEX-ADDRESS is out of range."
 380   (interactive "sHex Address: ")
 381   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 382
 383 (defun hexl-hex-string-to-integer (hex-string)
 384   "Return decimal integer for HEX-STRING."
 385   (interactive "sHex number: ")
 386   (let ((hex-num 0))
 387     (while (not (equal hex-string ""))
 388       (setq hex-num (+ (* hex-num 16)
 389                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 390       (setq hex-string (substring hex-string 1)))
 391     hex-num))
 392
 393 (defun hexl-octal-string-to-integer (octal-string)
 394   "Return decimal integer for OCTAL-STRING."
 395   (interactive "sOctal number: ")
 396   (let ((oct-num 0))
 397     (while (not (equal octal-string ""))
 398       (setq oct-num (+ (* oct-num 8)
 399                        (hexl-oct-char-to-integer
 400                         (string-to-char octal-string))))
 401       (setq octal-string (substring octal-string 1)))
 402     oct-num))
 403
 404 ;; move point functions
 405
 406 (defun hexl-backward-char (arg)
 407   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 408   (interactive "p")
 409   (hexl-goto-address (- (hexl-current-address) arg)))
 410
 411 (defun hexl-forward-char (arg)
 412   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 413   (interactive "p")
 414   (hexl-goto-address (+ (hexl-current-address) arg)))
 415
 416 (defun hexl-backward-short (arg)
 417   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 418   (interactive "p")
 419   (hexl-goto-address (let ((address (hexl-current-address)))
 420                        (if (< arg 0)
 421                            (progn
 422                              (setq arg (- arg))
 423                              (while (> arg 0)
 424                                (if (not (equal address (logior address 3)))
 425                                    (if (> address hexl-max-address)
 426                                        (progn
 427                                          (message "End of buffer.")
 428                                          (setq address hexl-max-address))
 429                                      (setq address (logior address 3)))
 430                                  (if (> address hexl-max-address)
 431                                      (progn
 432                                        (message "End of buffer.")
 433                                        (setq address hexl-max-address))
 434                                    (setq address (+ address 4))))
 435                                (setq arg (1- arg)))
 436                              (if (> address hexl-max-address)
 437                                  (progn
 438                                    (message "End of buffer.")
 439                                    (setq address hexl-max-address))
 440                                (setq address (logior address 3))))
 441                          (while (> arg 0)
 442                            (if (not (equal address (logand address -4)))
 443                                (setq address (logand address -4))
 444                              (if (not (equal address 0))
 445                                  (setq address (- address 4))
 446                                (message "Beginning of buffer.")))
 447                            (setq arg (1- arg))))
 448                        address)))
 449
 450 (defun hexl-forward-short (arg)
 451   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 452   (interactive "p")
 453   (hexl-backward-short (- arg)))
 454
 455 (defun hexl-backward-word (arg)
 456   "Move to left ARG words (right if ARG negative) in hexl-mode."
 457   (interactive "p")
 458   (hexl-goto-address (let ((address (hexl-current-address)))
 459                        (if (< arg 0)
 460                            (progn
 461                              (setq arg (- arg))
 462                              (while (> arg 0)
 463                                (if (not (equal address (logior address 7)))
 464                                    (if (> address hexl-max-address)
 465                                        (progn
 466                                          (message "End of buffer.")
 467                                          (setq address hexl-max-address))
 468                                      (setq address (logior address 7)))
 469                                  (if (> address hexl-max-address)
 470                                      (progn
 471                                        (message "End of buffer.")
 472                                        (setq address hexl-max-address))
 473                                    (setq address (+ address 8))))
 474                                (setq arg (1- arg)))
 475                              (if (> address hexl-max-address)
 476                                  (progn
 477                                    (message "End of buffer.")
 478                                    (setq address hexl-max-address))
 479                                (setq address (logior address 7))))
 480                          (while (> arg 0)
 481                            (if (not (equal address (logand address -8)))
 482                                (setq address (logand address -8))
 483                              (if (not (equal address 0))
 484                                  (setq address (- address 8))
 485                                (message "Beginning of buffer.")))
 486                            (setq arg (1- arg))))
 487                        address)))
 488
 489 (defun hexl-forward-word (arg)
 490   "Move right ARG words (left if ARG negative) in hexl-mode."
 491   (interactive "p")
 492   (hexl-backward-word (- arg)))
 493
 494 (defun hexl-previous-line (arg)
 495   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 496 If there is byte at the target address move to the last byte in that line."
 497   (interactive "p")
 498   (hexl-next-line (- arg)))
 499
 500 (defun hexl-next-line (arg)
 501   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 502 If there is no byte at the target address move to the last byte in that line."
 503   (interactive "p")
 504   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 505                        (if (and (< arg 0) (< address 0))
 506                                 (progn (message "Out of hexl region.")
 507                                        (setq address
 508                                              (% (hexl-current-address) 16)))
 509                          (if (and (> address hexl-max-address)
 510                                   (< (% hexl-max-address 16) (% address 16)))
 511                              (setq address hexl-max-address)
 512                            (if (> address hexl-max-address)
 513                                (progn (message "Out of hexl region.")
 514                                       (setq
 515                                        address
 516                                        (+ (logand hexl-max-address -16)
 517                                           (% (hexl-current-address) 16)))))))
 518                        address)))
 519
 520 (defun hexl-beginning-of-buffer (arg)
 521   "Move to the beginning of the hexl buffer.
 522 Leaves `hexl-mark' at previous position.
 523 With prefix arg N, puts point N bytes of the way from the true beginning."
 524   (interactive "p")
 525   (push-mark (point))
 526   (hexl-goto-address (+ 0 (1- arg))))
 527
 528 (defun hexl-end-of-buffer (arg)
 529   "Go to `hexl-max-address' minus ARG."
 530   (interactive "p")
 531   (push-mark (point))
 532   (hexl-goto-address (- hexl-max-address (1- arg))))
 533
 534 (defun hexl-beginning-of-line ()
 535   "Goto beginning of line in hexl mode."
 536   (interactive)
 537   (goto-char (+ (* (/ (point) 68) 68) 11)))
 538
 539 (defun hexl-end-of-line ()
 540   "Goto end of line in hexl mode."
 541   (interactive)
 542   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 543                        (if (> address hexl-max-address)
 544                            (setq address hexl-max-address))
 545                        address)))
 546
 547 (defun hexl-scroll-down (arg)
 548   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 549   (interactive "P")
 550   (if (null arg)
 551       (setq arg (1- (window-height)))
 552     (setq arg (prefix-numeric-value arg)))
 553   (hexl-scroll-up (- arg)))
 554
 555 (defun hexl-scroll-up (arg)
 556   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG.
 557 If there's no byte at the target address, move to the first or last line."
 558   (interactive "P")
 559   (if (null arg)
 560       (setq arg (1- (window-height)))
 561     (setq arg (prefix-numeric-value arg)))
 562   (let* ((movement (* arg 16))
 563          (address (hexl-current-address))
 564          (dest (+ address movement)))
 565     (cond
 566      ;; If possible, try to stay at the same offset from the beginning
 567      ;; of the 16-byte group, even if we move to the first or last
 568      ;; group.
 569      ((and (> dest hexl-max-address)
 570            (>= (% hexl-max-address 16) (% address 16)))
 571       (setq dest (+ (logand hexl-max-address -16) (% address 16))))
 572      ((> dest hexl-max-address)
 573       (setq dest hexl-max-address))
 574      ((< dest 0)
 575       (setq dest (% address 16))))
 576     (if (/= dest (+ address movement))
 577         (message "Out of hexl region."))
 578     (hexl-goto-address dest)
 579     (recenter 0)))
 580
 581 (defun hexl-beginning-of-1k-page ()
 582   "Go to beginning of 1k boundary."
 583   (interactive)
 584   (hexl-goto-address (logand (hexl-current-address) -1024)))
 585
 586 (defun hexl-end-of-1k-page ()
 587   "Go to end of 1k boundary."
 588   (interactive)
 589   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 590                        (if (> address hexl-max-address)
 591                            (setq address hexl-max-address))
 592                        address)))
 593
 594 (defun hexl-beginning-of-512b-page ()
 595   "Go to beginning of 512 byte boundary."
 596   (interactive)
 597   (hexl-goto-address (logand (hexl-current-address) -512)))
 598
 599 (defun hexl-end-of-512b-page ()
 600   "Go to end of 512 byte boundary."
 601   (interactive)
 602   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 603                        (if (> address hexl-max-address)
 604                            (setq address hexl-max-address))
 605                        address)))
 606
 607 (defun hexl-quoted-insert (arg)
 608   "Read next input character and insert it.
 609 Useful for inserting control characters and non-ASCII characters given their
 610 numerical code.
 611 You may also type octal digits, to insert a character with that code."
 612   (interactive "p")
 613   (hexl-insert-multibyte-char (read-quoted-char) arg))
 614
 615 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 616
 617 ;;;###autoload
 618 (defun hexlify-buffer ()
 619   "Convert a binary buffer to hexl format.
 620 This discards the buffer's undo information."
 621   (interactive)
 622   (and buffer-undo-list
 623        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 624            (error "Aborted")))
 625   (setq buffer-undo-list nil)
 626   ;; Don't decode text in the ASCII part of `hexl' program output.
 627   (let ((coding-system-for-read 'raw-text)
 628         (coding-system-for-write buffer-file-coding-system)
 629         (buffer-undo-list t))
 630     (shell-command-on-region (point-min) (point-max) hexlify-command t)
 631     (if (> (point) (hexl-address-to-marker hexl-max-address))
 632         (hexl-goto-address hexl-max-address))))
 633
 634 (defun dehexlify-buffer ()
 635   "Convert a hexl format buffer to binary.
 636 This discards the buffer's undo information."
 637   (interactive)
 638   (and buffer-undo-list
 639        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 640            (error "Aborted")))
 641   (setq buffer-undo-list nil)
 642   (let ((coding-system-for-write 'raw-text)
 643         (coding-system-for-read buffer-file-coding-system)
 644         (buffer-undo-list t))
 645     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 646
 647 (defun hexl-char-after-point ()
 648   "Return char for ASCII hex digits at point."
 649   (hexl-htoi (char-after (point))
 650              (char-after (1+ (point)))))
 651
 652 (defun hexl-htoi (lh rh)
 653   "Hex (char) LH (char) RH to integer."
 654     (+ (* (hexl-hex-char-to-integer lh) 16)
 655        (hexl-hex-char-to-integer rh)))
 656
 657 (defun hexl-hex-char-to-integer (character)
 658   "Take a char and return its value as if it was a hex digit."
 659   (if (and (>= character ?0) (<= character ?9))
 660       (- character ?0)
 661     (let ((ch (logior character 32)))
 662       (if (and (>= ch ?a) (<= ch ?f))
 663           (- ch (- ?a 10))
 664         (error "Invalid hex digit `%c'" ch)))))
 665
 666 (defun hexl-oct-char-to-integer (character)
 667   "Take a char and return its value as if it was a octal digit."
 668   (if (and (>= character ?0) (<= character ?7))
 669       (- character ?0)
 670     (error "Invalid octal digit `%c'" character)))
 671
 672 (defun hexl-printable-character (ch)
 673   "Return a displayable string for character CH."
 674   (format "%c" (if hexl-iso
 675                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 676                        46
 677                      ch)
 678                  (if (or (< ch 32) (>= ch 127))
 679                      46
 680                    ch))))
 681
 682 (defun hexl-insert-multibyte-char (ch num)
 683   "Insert a possibly multibyte character CH NUM times.
 684
 685 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 686 and their encoded form is inserted byte by byte."
 687   (let ((charset (char-charset ch))
 688         (coding (if (or (null buffer-file-coding-system)
 689                         ;; coding-system-type equals t means undecided.
 690                         (eq (coding-system-type buffer-file-coding-system) t))
 691                     default-buffer-file-coding-system
 692                   buffer-file-coding-system)))
 693     (cond ((and (> ch 0) (< ch 256))
 694            (hexl-insert-char ch num))
 695           ((eq charset 'unknown)
 696            (error
 697             "0x%x -- invalid character code; use \\[hexl-insert-hex-string]"
 698             ch))
 699           (t
 700            (let ((encoded (encode-coding-char ch coding))
 701                  (internal (string-as-unibyte (char-to-string ch)))
 702                  internal-hex)
 703              ;; If encode-coding-char returns nil, it means our character
 704              ;; cannot be safely encoded with buffer-file-coding-system.
 705              ;; In that case, we offer to insert the internal representation
 706              ;; of that character, byte by byte.
 707              (when (null encoded)
 708                (setq internal-hex
 709                      (mapconcat (function (lambda (c) (format "%x" c)))
 710                                 internal " "))
 711                (if (yes-or-no-p
 712                     (format
 713                      "Insert char 0x%x's internal representation \"%s\"? "
 714                      ch internal-hex))
 715                    (setq encoded internal)
 716                  (error
 717                   "Can't encode `0x%x' with this buffer's coding system; try \\[hexl-insert-hex-string]"
 718                   ch)))
 719              (while (> num 0)
 720                (mapc
 721                 (function (lambda (c) (hexl-insert-char c 1))) encoded)
 722                (setq num (1- num))))))))
 723
 724 (defun hexl-self-insert-command (arg)
 725   "Insert this character.
 726 Interactively, with a numeric argument, insert this character that many times.
 727
 728 Non-ASCII characters are first encoded with `buffer-file-coding-system',
 729 and their encoded form is inserted byte by byte."
 730   (interactive "p")
 731   (hexl-insert-multibyte-char last-command-char arg))
 732
 733 (defun hexl-insert-char (ch num)
 734   "Insert the character CH NUM times in a hexl buffer.
 735
 736 CH must be a unibyte character whose value is between 0 and 255."
 737   (if (or (< ch 0) (> ch 255))
 738       (error "Invalid character 0x%x -- must be in the range [0..255]"))
 739   (let ((address (hexl-current-address t)))
 740     (while (> num 0)
 741       (let ((hex-position
 742              (+ (* (/ address 16) 68)
 743                 11
 744                 (* 2 (% address 16))
 745                 (/ (% address 16) 2)))
 746             (ascii-position
 747              (+ (* (/ address 16) 68) 52 (% address 16)))
 748             at-ascii-position)
 749         (if (= (point) ascii-position)
 750             (setq at-ascii-position t))
 751         (goto-char hex-position)
 752         (delete-char 2)
 753         (insert (format "%02x" ch))
 754         (goto-char ascii-position)
 755         (delete-char 1)
 756         (insert (hexl-printable-character ch))
 757         (or (eq address hexl-max-address)
 758             (setq address (1+ address)))
 759         (hexl-goto-address address)
 760         (if at-ascii-position
 761             (progn
 762               (beginning-of-line)
 763               (forward-char 51)
 764               (forward-char (% address 16)))))
 765       (setq num (1- num)))))
 766
 767 ;; hex conversion
 768
 769 (defun hexl-insert-hex-char (arg)
 770   "Insert a character given by its hexadecimal code ARG times at point."
 771   (interactive "p")
 772   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 773     (if (< num 0)
 774         (error "Hex number out of range")
 775       (hexl-insert-multibyte-char num arg))))
 776
 777 (defun hexl-insert-hex-string (str arg)
 778   "Insert hexadecimal string STR at point ARG times.
 779 Embedded whitespace, dashes, and periods in the string are ignored."
 780   (interactive "sHex string: \np")
 781   (setq str (replace-regexp-in-string "[- \t.]" "" str))
 782   (let ((chars '()))
 783     (let ((len (length str))
 784           (idx 0))
 785       (if (eq (logand len 1) 1)
 786           (let ((num (hexl-hex-string-to-integer (substring str 0 1))))
 787             (setq chars (cons num chars))
 788             (setq idx 1)))
 789       (while (< idx len)
 790         (let* ((nidx (+ idx 2))
 791                (num (hexl-hex-string-to-integer (substring str idx nidx))))
 792           (setq chars (cons num chars))
 793           (setq idx nidx))))
 794     (setq chars (nreverse chars))
 795     (while (> arg 0)
 796       (let ((chars chars))
 797         (while chars
 798           (hexl-insert-char (car chars) 1)
 799           (setq chars (cdr chars))))
 800       (setq arg (- arg 1)))))
 801
 802 (defun hexl-insert-decimal-char (arg)
 803   "Insert a character given by its decimal code ARG times at point."
 804   (interactive "p")
 805   (let ((num (string-to-int (read-string "Decimal Number: "))))
 806     (if (< num 0)
 807         (error "Decimal number out of range")
 808       (hexl-insert-multibyte-char num arg))))
 809
 810 (defun hexl-insert-octal-char (arg)
 811   "Insert a character given by its octal code ARG times at point."
 812   (interactive "p")
 813   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 814     (if (< num 0)
 815         (error "Decimal number out of range")
 816       (hexl-insert-multibyte-char num arg))))
 817
 818 (defun hexl-follow-ascii (&optional arg)
 819   "Toggle following ASCII in Hexl buffers.
 820 With prefix ARG, turn on following if and only if ARG is positive.
 821 When following is enabled, the ASCII character corresponding to the
 822 element under the point is highlighted.
 823 Customize the variable `hexl-follow-ascii' to disable this feature."
 824   (interactive "P")
 825   (let ((on-p (if arg
 826                   (> (prefix-numeric-value arg) 0)
 827                (not hexl-ascii-overlay))))
 828
 829     (if on-p
 830       ;; turn it on
 831       (if (not hexl-ascii-overlay)
 832           (progn
 833             (setq hexl-ascii-overlay (make-overlay 1 1)
 834                   hexl-follow-ascii t)
 835             (overlay-put hexl-ascii-overlay 'face 'highlight)
 836             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 837       ;; turn it off
 838       (if hexl-ascii-overlay
 839           (progn
 840             (delete-overlay hexl-ascii-overlay)
 841             (setq hexl-ascii-overlay nil
 842                   hexl-follow-ascii nil)
 843             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 844             )))))
 845
 846 (defun hexl-follow-ascii-find ()
 847   "Find and highlight the ASCII element corresponding to current point."
 848   (let ((pos (+ 51
 849                 (- (point) (current-column))
 850                 (mod (hexl-current-address) 16))))
 851     (move-overlay hexl-ascii-overlay pos (1+ pos))
 852     ))
 853
 854 ;; startup stuff.
 855
 856 (if hexl-mode-map
 857     nil
 858   (setq hexl-mode-map (make-keymap))
 859   ;; Make all self-inserting keys go through hexl-self-insert-command,
 860   ;; because we need to convert them to unibyte characters before
 861   ;; inserting them into the buffer.
 862   (substitute-key-definition 'self-insert-command 'hexl-self-insert-command
 863                              hexl-mode-map (current-global-map))
 864
 865   (define-key hexl-mode-map [left] 'hexl-backward-char)
 866   (define-key hexl-mode-map [right] 'hexl-forward-char)
 867   (define-key hexl-mode-map [up] 'hexl-previous-line)
 868   (define-key hexl-mode-map [down] 'hexl-next-line)
 869   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 870   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 871   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 872   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 873   (define-key hexl-mode-map [home] 'hexl-beginning-of-line)
 874   (define-key hexl-mode-map [end] 'hexl-end-of-line)
 875   (define-key hexl-mode-map [C-home] 'hexl-beginning-of-buffer)
 876   (define-key hexl-mode-map [C-end] 'hexl-end-of-buffer)
 877   (define-key hexl-mode-map [deletechar] 'undefined)
 878   (define-key hexl-mode-map [deleteline] 'undefined)
 879   (define-key hexl-mode-map [insertline] 'undefined)
 880   (define-key hexl-mode-map [S-delete] 'undefined)
 881   (define-key hexl-mode-map "\177" 'undefined)
 882
 883   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 884   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 885   (define-key hexl-mode-map "\C-d" 'undefined)
 886   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 887   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 888
 889   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 890       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 891
 892   (define-key hexl-mode-map "\C-k" 'undefined)
 893   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 894   (define-key hexl-mode-map "\C-o" 'undefined)
 895   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 896   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 897   (define-key hexl-mode-map "\C-t" 'undefined)
 898   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 899   (define-key hexl-mode-map "\C-w" 'undefined)
 900   (define-key hexl-mode-map "\C-y" 'undefined)
 901
 902   (fset 'hexl-ESC-prefix (copy-keymap 'ESC-prefix))
 903   (define-key hexl-mode-map "\e" 'hexl-ESC-prefix)
 904   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 905   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 906   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 907   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 908   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 909   (define-key hexl-mode-map "\e\C-i" 'undefined)
 910   (define-key hexl-mode-map "\e\C-j" 'undefined)
 911   (define-key hexl-mode-map "\e\C-k" 'undefined)
 912   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 913   (define-key hexl-mode-map "\e\C-q" 'undefined)
 914   (define-key hexl-mode-map "\e\C-t" 'undefined)
 915   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 916   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 917   (define-key hexl-mode-map "\ec" 'undefined)
 918   (define-key hexl-mode-map "\ed" 'undefined)
 919   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 920   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 921   (define-key hexl-mode-map "\ei" 'undefined)
 922   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 923   (define-key hexl-mode-map "\ek" 'undefined)
 924   (define-key hexl-mode-map "\el" 'undefined)
 925   (define-key hexl-mode-map "\eq" 'undefined)
 926   (define-key hexl-mode-map "\es" 'undefined)
 927   (define-key hexl-mode-map "\et" 'undefined)
 928   (define-key hexl-mode-map "\eu" 'undefined)
 929   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 930   (define-key hexl-mode-map "\ey" 'undefined)
 931   (define-key hexl-mode-map "\ez" 'undefined)
 932   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 933   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 934
 935   (fset 'hexl-C-c-prefix (copy-keymap mode-specific-map))
 936   (define-key hexl-mode-map "\C-c" 'hexl-C-c-prefix)
 937   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 938
 939   (fset 'hexl-C-x-prefix (copy-keymap 'Control-X-prefix))
 940   (define-key hexl-mode-map "\C-x" 'hexl-C-x-prefix)
 941   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 942   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 943   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 944   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 945   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 946
 947 (provide 'hexl)
 948
 949 ;;; hexl.el ends here