lisp/vc-mcvs.el

   1 ;;; vc-mcvs.el --- VC backend for the Meta-CVS version-control system
   2
   3 ;; Copyright (C) 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author:      FSF (see vc.el for full credits)
   6 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; The home page of the Meta-CVS version control system is at
  28 ;;
  29 ;;      http://users.footprints.net/~kaz/mcvs.html
  30 ;;
  31 ;; This is derived from vc-cvs.el as follows:
  32 ;; - cp vc-cvs.el vc-mcvs.el
  33 ;; - Replace CVS/ with MCVS/CVS/
  34 ;; - Replace 'CVS with 'MCVS
  35 ;; - Replace -cvs- with -mcvs-
  36 ;; - Replace most of the rest of CVS to Meta-CVS
  37 ;;
  38 ;; Then of course started the hacking.  Only a small part of the code
  39 ;; has been touched and not much more than that was tested, so if
  40 ;; you bump into a bug, don't be surprised: just report it to me.
  41 ;;
  42 ;; What has been partly tested:
  43 ;; - C-x v v to start editing a file that was checked out with CVSREAD on.
  44 ;; - C-x v v to commit a file
  45 ;; - C-x v =
  46 ;; - C-x v l
  47 ;; - C-x v i
  48 ;; - C-x v g
  49 ;; - M-x vc-rename-file RET
  50
  51 ;;; Bugs:
  52
  53 ;; - Retrieving snapshots doesn't filter `cvs update' output and thus
  54 ;;   parses bogus filenames.  Don't know if it harms.
  55
  56 ;;; Code:
  57
  58 (eval-when-compile (require 'vc))
  59 (require 'vc-cvs)
  60
  61 ;;;
  62 ;;; Customization options
  63 ;;;
  64
  65 (defcustom vc-mcvs-global-switches nil
  66   "*Global switches to pass to any Meta-CVS command."
  67   :type '(choice (const :tag "None" nil)
  68                  (string :tag "Argument String")
  69                  (repeat :tag "Argument List"
  70                          :value ("")
  71                          string))
  72   :version "22.1"
  73   :group 'vc)
  74
  75 (defcustom vc-mcvs-register-switches nil
  76   "*Extra switches for registering a file into Meta-CVS.
  77 A string or list of strings passed to the checkin program by
  78 \\[vc-register]."
  79   :type '(choice (const :tag "None" nil)
  80                  (string :tag "Argument String")
  81                  (repeat :tag "Argument List"
  82                          :value ("")
  83                          string))
  84   :version "22.1"
  85   :group 'vc)
  86
  87 (defcustom vc-mcvs-diff-switches nil
  88   "*A string or list of strings specifying extra switches for cvs diff under VC."
  89     :type '(choice (const :tag "None" nil)
  90                  (string :tag "Argument String")
  91                  (repeat :tag "Argument List"
  92                          :value ("")
  93                          string))
  94   :version "22.1"
  95   :group 'vc)
  96
  97 (defcustom vc-mcvs-header (or (cdr (assoc 'MCVS vc-header-alist))
  98                               vc-cvs-header)
  99   "*Header keywords to be inserted by `vc-insert-headers'."
 100   :version "22.1"
 101   :type '(repeat string)
 102   :group 'vc)
 103
 104 (defcustom vc-mcvs-use-edit vc-cvs-use-edit
 105   "*Non-nil means to use `cvs edit' to \"check out\" a file.
 106 This is only meaningful if you don't use the implicit checkout model
 107 \(i.e. if you have $CVSREAD set)."
 108   :type 'boolean
 109   :version "22.1"
 110   :group 'vc)
 111
 112 ;;; Properties of the backend
 113
 114 (defun vc-mcvs-revision-granularity ()
 115      'file)
 116
 117 ;;;
 118 ;;; State-querying functions
 119 ;;;
 120
 121 ;;;###autoload (defun vc-mcvs-registered (file)
 122 ;;;###autoload   (if (vc-find-root file "MCVS/CVS")
 123 ;;;###autoload       (progn
 124 ;;;###autoload         (load "vc-mcvs")
 125 ;;;###autoload         (vc-mcvs-registered file))))
 126
 127 (defun vc-mcvs-root (file)
 128   "Return the root directory of a Meta-CVS project, if any."
 129   (or (vc-file-getprop file 'mcvs-root)
 130       (vc-file-setprop file 'mcvs-root (vc-find-root file "MCVS/CVS"))))
 131
 132 (defun vc-mcvs-read (file)
 133   (if (file-readable-p file)
 134       (with-temp-buffer
 135         (insert-file-contents file)
 136         (goto-char (point-min))
 137         (read (current-buffer)))))
 138
 139 (defun vc-mcvs-map-file (dir file)
 140   (let ((map (vc-mcvs-read (expand-file-name "MCVS/MAP" dir)))
 141         inode)
 142     (dolist (x map inode)
 143       (if (equal (nth 2 x) file) (setq inode (nth 1 x))))))
 144
 145 (defun vc-mcvs-registered (file)
 146   (let (root inode cvsfile)
 147     (when (and (setq root (vc-mcvs-root file))
 148                (setq inode (vc-mcvs-map-file
 149                             root (file-relative-name file root))))
 150       (vc-file-setprop file 'mcvs-inode inode)
 151       ;; Avoid calling `mcvs diff' in vc-workfile-unchanged-p.
 152       (vc-file-setprop file 'vc-checkout-time
 153                        (if (vc-cvs-registered
 154                             (setq cvsfile (expand-file-name inode root)))
 155                            (vc-file-getprop cvsfile 'vc-checkout-time)
 156                          ;; The file might not be registered yet because
 157                          ;; of lazy-adding.
 158                          0))
 159       t)))
 160
 161 (defun vc-mcvs-state (file)
 162   ;; This would assume the Meta-CVS sandbox is synchronized.
 163   ;; (vc-mcvs-cvs state file))
 164   "Meta-CVS-specific version of `vc-state'."
 165   (if (vc-stay-local-p file)
 166       (let ((state (vc-file-getprop file 'vc-state)))
 167         ;; If we should stay local, use the heuristic but only if
 168         ;; we don't have a more precise state already available.
 169         (if (memq state '(up-to-date edited))
 170             (vc-mcvs-state-heuristic file)
 171           state))
 172     (with-temp-buffer
 173       (setq default-directory (vc-mcvs-root file))
 174       (vc-mcvs-command t 0 file "status")
 175       (vc-cvs-parse-status t))))
 176
 177
 178 (defalias 'vc-mcvs-state-heuristic 'vc-cvs-state-heuristic)
 179
 180 (defun vc-mcvs-dir-state (dir)
 181   "Find the Meta-CVS state of all files in DIR."
 182   ;; if DIR is not under Meta-CVS control, don't do anything.
 183   (when (file-readable-p (expand-file-name "MCVS/CVS/Entries" dir))
 184     (if (vc-stay-local-p dir)
 185         (vc-mcvs-dir-state-heuristic dir)
 186       (let ((default-directory dir))
 187         ;; Don't specify DIR in this command, the default-directory is
 188         ;; enough.  Otherwise it might fail with remote repositories.
 189         (with-temp-buffer
 190           (setq default-directory (vc-mcvs-root dir))
 191           (vc-mcvs-command t 0 nil "status" "-l")
 192           (goto-char (point-min))
 193           (while (re-search-forward "^=+\n\\([^=\n].*\n\\|\n\\)+" nil t)
 194             (narrow-to-region (match-beginning 0) (match-end 0))
 195             (vc-cvs-parse-status)
 196             (goto-char (point-max))
 197             (widen)))))))
 198
 199 (defun vc-mcvs-workfile-version (file)
 200   (vc-cvs-workfile-version
 201    (expand-file-name (vc-file-getprop file 'mcvs-inode)
 202                      (vc-file-getprop file 'mcvs-root))))
 203
 204 (defalias 'vc-mcvs-checkout-model 'vc-cvs-checkout-model)
 205
 206 ;;;
 207 ;;; State-changing functions
 208 ;;;
 209
 210 (defun vc-mcvs-register (files &optional rev comment)
 211   "Register FILES into the Meta-CVS version-control system.
 212 COMMENT can be used to provide an initial description of FILE.
 213
 214 `vc-register-switches' and `vc-mcvs-register-switches' are passed to
 215 the Meta-CVS command (in that order)."
 216   ;; FIXME: multiple-file case should be made to work
 217   (if (> (length files) 1) (error "Registering filesets is not yet supported."))
 218   (let* ((file (car files))
 219          (filename (file-name-nondirectory file))
 220          (extpos (string-match "\\." filename))
 221          (ext (if extpos (substring filename (1+ extpos))))
 222          (root (vc-mcvs-root file))
 223          (types-file (expand-file-name "MCVS/TYPES" root))
 224          (map-file (expand-file-name "MCVS/MAP" root))
 225          (types (vc-mcvs-read types-file)))
 226     ;; Make sure meta files like MCVS/MAP are not read-only (happens with
 227     ;; CVSREAD) since Meta-CVS doesn't pay attention to it at all and goes
 228     ;; belly-up.
 229     (unless (file-writable-p map-file)
 230       (vc-checkout map-file t))
 231     (unless (or (file-writable-p types-file) (not (file-exists-p types-file)))
 232       (vc-checkout types-file t))
 233     ;; Make sure the `mcvs add' will not fire up the CVSEDITOR
 234     ;; to add a rule for the given file's extension.
 235     (when (and ext (not (assoc ext types)))
 236       (let ((type (completing-read "Type to use (default): "
 237                                    '("default" "name-only" "keep-old"
 238                                      "binary" "value-only")
 239                                    nil t nil nil "default")))
 240         (push (list ext (make-symbol (upcase (concat ":" type)))) types)
 241         (setq types (sort types (lambda (x y) (string< (car x) (car y)))))
 242         (with-current-buffer (find-file-noselect types-file)
 243           (erase-buffer)
 244           (pp types (current-buffer))
 245           (save-buffer)
 246           (unless (get-buffer-window (current-buffer) t)
 247             (kill-buffer (current-buffer)))))))
 248   ;; Now do the ADD.
 249   (prog1 (apply 'vc-mcvs-command nil 0 file
 250                 "add"
 251                 (and comment (string-match "[^\t\n ]" comment)
 252                      (concat "-m" comment))
 253                 (vc-switches 'MCVS 'register))
 254     ;; I'm not sure exactly why, but if we don't setup the inode and root
 255     ;; prop of the file, things break later on in vc-mode-line that
 256     ;; ends up calling vc-mcvs-workfile-version.
 257     ;; We also need to set vc-checkout-time so that vc-workfile-unchanged-p
 258     ;; doesn't try to call `mcvs diff' on the file.
 259     (vc-mcvs-registered file)))
 260
 261 (defalias 'vc-mcvs-responsible-p 'vc-mcvs-root
 262   "Return non-nil if CVS thinks it is responsible for FILE.")
 263
 264 (defalias 'vc-cvs-could-register 'vc-cvs-responsible-p
 265   "Return non-nil if FILE could be registered in Meta-CVS.
 266 This is only possible if Meta-CVS is responsible for FILE's directory.")
 267
 268 (defun vc-mcvs-checkin (files rev comment)
 269   "Meta-CVS-specific version of `vc-backend-checkin'."
 270   (unless (or (not rev) (vc-mcvs-valid-version-number-p rev))
 271     (if (not (vc-mcvs-valid-symbolic-tag-name-p rev))
 272         (error "%s is not a valid symbolic tag name" rev)
 273       ;; If the input revision is a valid symbolic tag name, we create it
 274       ;; as a branch, commit and switch to it.
 275       ;; This file-specific form of branching is deprecated.
 276       ;; We can't use `mcvs branch' and `mcvs switch' because they cannot
 277       ;; be applied just to this one file.
 278       (apply 'vc-mcvs-command nil 0 files "tag" "-b" (list rev))
 279       (apply 'vc-mcvs-command nil 0 files "update" "-r" (list rev))
 280       (mapcar (lambda (file) (vc-file-setprop file 'vc-mcvs-sticky-tag rev))
 281               files)
 282       (setq rev nil)))
 283   ;; This commit might cvs-commit several files (e.g. MAP and TYPES)
 284   ;; so using numbered revs here is dangerous and somewhat meaningless.
 285   (when rev (error "Cannot commit to a specific revision number"))
 286   (let ((status (apply 'vc-mcvs-command nil 1 files
 287                        "ci" "-m" comment
 288                        (vc-switches 'MCVS 'checkin))))
 289     (set-buffer "*vc*")
 290     (goto-char (point-min))
 291     (when (not (zerop status))
 292       ;; Check checkin problem.
 293       (cond
 294        ((re-search-forward "Up-to-date check failed" nil t)
 295         (mapcar (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 296               files)
 297         (error (substitute-command-keys
 298                 (concat "Up-to-date check failed: "
 299                         "type \\[vc-next-action] to merge in changes"))))
 300        (t
 301         (pop-to-buffer (current-buffer))
 302         (goto-char (point-min))
 303         (shrink-window-if-larger-than-buffer)
 304         (error "Check-in failed"))))
 305     ;; Single-file commit?  Then update the version by parsing the buffer.
 306     ;; Otherwise we can't necessarily tell what goes with what; clear
 307     ;; its properties so they have to be refetched.
 308     (if (= (length files) 1)
 309         (vc-file-setprop
 310          (car files) 'vc-workfile-version
 311          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 312       (mapc (lambda (file) (vc-file-clearprops file)) files))
 313     ;; Anyway, forget the checkout model of the file, because we might have
 314     ;; guessed wrong when we found the file.  After commit, we can
 315     ;; tell it from the permissions of the file (see
 316     ;; vc-mcvs-checkout-model).
 317     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 318             files)
 319
 320     ;; if this was an explicit check-in (does not include creation of
 321     ;; a branch), remove the sticky tag.
 322     (if (and rev (not (vc-mcvs-valid-symbolic-tag-name-p rev)))
 323         (vc-mcvs-command nil 0 files "update" "-A"))))
 324
 325 (defun vc-mcvs-find-version (file rev buffer)
 326   (apply 'vc-mcvs-command
 327          buffer 0 file
 328          "-Q"                           ; suppress diagnostic output
 329          "update"
 330          (and rev (not (string= rev ""))
 331               (concat "-r" rev))
 332          "-p"
 333          (vc-switches 'MCVS 'checkout)))
 334
 335 (defun vc-mcvs-checkout (file &optional editable rev)
 336   (message "Checking out %s..." file)
 337   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 338     (vc-call update file editable rev (vc-switches 'MCVS 'checkout)))
 339   (vc-mode-line file)
 340   (message "Checking out %s...done" file))
 341
 342 (defun vc-mcvs-update (file editable rev switches)
 343   (if (and (file-exists-p file) (not rev))
 344       ;; If no revision was specified, just make the file writable
 345       ;; if necessary (using `cvs-edit' if requested).
 346       (and editable (not (eq (vc-mcvs-checkout-model file) 'implicit))
 347            (if vc-mcvs-use-edit
 348                (vc-mcvs-command nil 0 file "edit")
 349              (set-file-modes file (logior (file-modes file) 128))
 350              (if (equal file buffer-file-name) (toggle-read-only -1))))
 351     ;; Check out a particular version (or recreate the file).
 352     (vc-file-setprop file 'vc-workfile-version nil)
 353     (apply 'vc-mcvs-command nil 0 file
 354            (if editable "-w")
 355            "update"
 356            ;; default for verbose checkout: clear the sticky tag so
 357            ;; that the actual update will get the head of the trunk
 358            (if (or (not rev) (string= rev ""))
 359                "-A"
 360              (concat "-r" rev))
 361            switches)))
 362
 363 (defun vc-mcvs-rename-file (old new)
 364   (vc-mcvs-command nil 0 new "move" (file-relative-name old)))
 365
 366 (defun vc-mcvs-revert (file &optional contents-done)
 367   "Revert FILE to the version it was based on."
 368   (vc-default-revert 'MCVS file contents-done)
 369   (unless (eq (vc-checkout-model file) 'implicit)
 370     (if vc-mcvs-use-edit
 371         (vc-mcvs-command nil 0 file "unedit")
 372       ;; Make the file read-only by switching off all w-bits
 373       (set-file-modes file (logand (file-modes file) 3950)))))
 374
 375 (defun vc-mcvs-merge (file first-version &optional second-version)
 376   "Merge changes into current working copy of FILE.
 377 The changes are between FIRST-VERSION and SECOND-VERSION."
 378   (vc-mcvs-command nil 0 file
 379                    "update" "-kk"
 380                    (concat "-j" first-version)
 381                    (concat "-j" second-version))
 382   (vc-file-setprop file 'vc-state 'edited)
 383   (with-current-buffer (get-buffer "*vc*")
 384     (goto-char (point-min))
 385     (if (re-search-forward "conflicts during merge" nil t)
 386         1                               ; signal error
 387       0)))                              ; signal success
 388
 389 (defun vc-mcvs-merge-news (file)
 390   "Merge in any new changes made to FILE."
 391   (message "Merging changes into %s..." file)
 392   ;; (vc-file-setprop file 'vc-workfile-version nil)
 393   (vc-file-setprop file 'vc-checkout-time 0)
 394   (vc-mcvs-command nil 0 file "update")
 395   ;; Analyze the merge result reported by Meta-CVS, and set
 396   ;; file properties accordingly.
 397   (with-current-buffer (get-buffer "*vc*")
 398     (goto-char (point-min))
 399     ;; get new workfile version
 400     (if (re-search-forward
 401          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 402         (vc-file-setprop file 'vc-workfile-version (match-string 1))
 403       (vc-file-setprop file 'vc-workfile-version nil))
 404     ;; get file status
 405     (prog1
 406         (if (eq (buffer-size) 0)
 407             0 ;; there were no news; indicate success
 408           (if (re-search-forward
 409                (concat "^\\([CMUP] \\)?"
 410                        ".*"
 411                        "\\( already contains the differences between \\)?")
 412                nil t)
 413               (cond
 414                ;; Merge successful, we are in sync with repository now
 415                ((or (match-string 2)
 416                     (string= (match-string 1) "U ")
 417                     (string= (match-string 1) "P "))
 418                 (vc-file-setprop file 'vc-state 'up-to-date)
 419                 (vc-file-setprop file 'vc-checkout-time
 420                                  (nth 5 (file-attributes file)))
 421                 0);; indicate success to the caller
 422                ;; Merge successful, but our own changes are still in the file
 423                ((string= (match-string 1) "M ")
 424                 (vc-file-setprop file 'vc-state 'edited)
 425                 0);; indicate success to the caller
 426                ;; Conflicts detected!
 427                (t
 428                 (vc-file-setprop file 'vc-state 'edited)
 429                 1);; signal the error to the caller
 430                )
 431             (pop-to-buffer "*vc*")
 432             (error "Couldn't analyze mcvs update result")))
 433       (message "Merging changes into %s...done" file))))
 434
 435 ;;;
 436 ;;; History functions
 437 ;;;
 438
 439 (defun vc-mcvs-print-log (files &optional buffer)
 440   "Get change log associated with FILES."
 441   (let ((default-directory (vc-mcvs-root (car files))))
 442     ;; Run the command from the root dir so that `mcvs filt' returns
 443     ;; valid relative names.
 444     (vc-mcvs-command
 445      buffer
 446      (if (and (vc-stay-local-p files) (fboundp 'start-process)) 'async 0)
 447      files "log")))
 448
 449 (defun vc-mcvs-diff (files &optional oldvers newvers buffer)
 450   "Get a difference report using Meta-CVS between two versions of FILES."
 451     (let* ((async (and (not vc-disable-async-diff)
 452                        (vc-stay-local-p files)
 453                        (fboundp 'start-process)))
 454            ;; Run the command from the root dir so that `mcvs filt' returns
 455            ;; valid relative names.
 456            (default-directory (vc-mcvs-root (car files)))
 457            (status
 458             (apply 'vc-mcvs-command (or buffer "*vc-diff*")
 459                    (if async 'async 1)
 460                    files "diff"
 461                    (and oldvers (concat "-r" oldvers))
 462                    (and newvers (concat "-r" newvers))
 463                    (vc-switches 'MCVS 'diff))))
 464       (if async 1 status)))            ; async diff, pessimistic assumption.
 465
 466 (defun vc-mcvs-diff-tree (dir &optional rev1 rev2)
 467   "Diff all files at and below DIR."
 468   (with-current-buffer "*vc-diff*"
 469     ;; Run the command from the root dir so that `mcvs filt' returns
 470     ;; valid relative names.
 471     (setq default-directory (vc-mcvs-root dir))
 472     ;; cvs diff: use a single call for the entire tree
 473     (let ((coding-system-for-read (or coding-system-for-read 'undecided)))
 474       (apply 'vc-mcvs-command "*vc-diff*" 1 dir "diff"
 475              (and rev1 (concat "-r" rev1))
 476              (and rev2 (concat "-r" rev2))
 477              (vc-switches 'MCVS 'diff)))))
 478
 479 (defun vc-mcvs-annotate-command (file buffer &optional version)
 480   "Execute \"mcvs annotate\" on FILE, inserting the contents in BUFFER.
 481 Optional arg VERSION is a version to annotate from."
 482   (vc-mcvs-command
 483    buffer
 484    (if (and (vc-stay-local-p file) (fboundp 'start-process)) 'async 0)
 485    file "annotate" (if version (concat "-r" version)))
 486   (with-current-buffer buffer
 487     (goto-char (point-min))
 488     (re-search-forward "^[0-9]")
 489     (delete-region (point-min) (1- (point)))))
 490
 491 (defalias 'vc-mcvs-annotate-current-time 'vc-cvs-annotate-current-time)
 492 (defalias 'vc-mcvs-annotate-time 'vc-cvs-annotate-time)
 493
 494 ;;;
 495 ;;; Snapshot system
 496 ;;;
 497
 498 (defun vc-mcvs-create-snapshot (dir name branchp)
 499   "Assign to DIR's current version a given NAME.
 500 If BRANCHP is non-nil, the name is created as a branch (and the current
 501 workspace is immediately moved to that new branch)."
 502   (if (not branchp)
 503       (vc-mcvs-command nil 0 dir "tag" "-c" name)
 504     (vc-mcvs-command nil 0 dir "branch" name)
 505     (vc-mcvs-command nil 0 dir "switch" name)))
 506
 507 (defun vc-mcvs-retrieve-snapshot (dir name update)
 508   "Retrieve a snapshot at and below DIR.
 509 NAME is the name of the snapshot; if it is empty, do a `cvs update'.
 510 If UPDATE is non-nil, then update (resynch) any affected buffers."
 511   (with-current-buffer (get-buffer-create "*vc*")
 512     (let ((default-directory dir)
 513           (sticky-tag))
 514       (erase-buffer)
 515       (if (or (not name) (string= name ""))
 516           (vc-mcvs-command t 0 nil "update")
 517         (vc-mcvs-command t 0 nil "update" "-r" name)
 518         (setq sticky-tag name))
 519       (when update
 520         (goto-char (point-min))
 521         (while (not (eobp))
 522           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 523               (let* ((file (expand-file-name (match-string 2) dir))
 524                      (state (match-string 1))
 525                      (buffer (find-buffer-visiting file)))
 526                 (when buffer
 527                   (cond
 528                    ((or (string= state "U")
 529                         (string= state "P"))
 530                     (vc-file-setprop file 'vc-state 'up-to-date)
 531                     (vc-file-setprop file 'vc-workfile-version nil)
 532                     (vc-file-setprop file 'vc-checkout-time
 533                                      (nth 5 (file-attributes file))))
 534                    ((or (string= state "M")
 535                         (string= state "C"))
 536                     (vc-file-setprop file 'vc-state 'edited)
 537                     (vc-file-setprop file 'vc-workfile-version nil)
 538                     (vc-file-setprop file 'vc-checkout-time 0)))
 539                   (vc-file-setprop file 'vc-mcvs-sticky-tag sticky-tag)
 540                   (vc-resynch-buffer file t t))))
 541           (forward-line 1))))))
 542
 543
 544 ;;;
 545 ;;; Miscellaneous
 546 ;;;
 547
 548 (defalias 'vc-mcvs-make-version-backups-p 'vc-stay-local-p
 549   "Return non-nil if version backups should be made for FILE.")
 550 (defalias 'vc-mcvs-check-headers 'vc-cvs-check-headers)
 551
 552
 553 ;;;
 554 ;;; Internal functions
 555 ;;;
 556
 557 (defun vc-mcvs-command (buffer okstatus file &rest flags)
 558   "A wrapper around `vc-do-command' for use in vc-mcvs.el.
 559 The difference to vc-do-command is that this function always invokes `mcvs',
 560 and that it passes `vc-mcvs-global-switches' to it before FLAGS."
 561   (let ((args (append '("--error-terminate")
 562                       (if (stringp vc-mcvs-global-switches)
 563                           (cons vc-mcvs-global-switches flags)
 564                         (append vc-mcvs-global-switches flags)))))
 565     (if (not (member (car flags) '("diff" "log" "status")))
 566         ;; No need to filter: do it the easy way.
 567         (apply 'vc-do-command buffer okstatus "mcvs" file args)
 568       ;; We need to filter the output.
 569       ;; The output of the filter uses filenames relative to the root,
 570       ;; so we need to change the default-directory.
 571       ;; (assert (equal default-directory (vc-mcvs-root file)))
 572       (vc-do-command
 573        buffer okstatus "sh" nil "-c"
 574        (concat "mcvs "
 575                (mapconcat
 576                 'shell-quote-argument
 577                 (append (remq nil args)
 578                         (if file (list (file-relative-name file))))
 579                 " ")
 580                " | mcvs filt")))))
 581
 582 (defun vc-mcvs-repository-hostname (dirname)
 583   (vc-cvs-repository-hostname (vc-mcvs-root dirname)))
 584
 585 (defun vc-mcvs-dir-state-heuristic (dir)
 586   "Find the Meta-CVS state of all files in DIR, using only local information."
 587   (with-temp-buffer
 588     (vc-cvs-get-entries dir)
 589     (goto-char (point-min))
 590     (while (not (eobp))
 591       ;; Meta-MCVS-removed files are not taken under VC control.
 592       (when (looking-at "/\\([^/]*\\)/[^/-]")
 593         (let ((file (expand-file-name (match-string 1) dir)))
 594           (unless (vc-file-getprop file 'vc-state)
 595             (vc-cvs-parse-entry file t))))
 596       (forward-line 1))))
 597
 598 (defalias 'vc-mcvs-valid-symbolic-tag-name-p 'vc-cvs-valid-symbolic-tag-name-p)
 599 (defalias 'vc-mcvs-valid-version-number-p 'vc-cvs-valid-version-number-p)
 600
 601 (provide 'vc-mcvs)
 602
 603 ;; arch-tag: a39c7c1c-5247-429d-88df-dd7187d2e704
 604 ;;; vc-mcvs.el ends here