lisp/textmodes/spell.el

   1 ;;; spell.el --- spelling correction interface for Emacs.
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp, unix
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode provides an Emacs interface to the UNIX spell(1) program.
  27 ;; Entry points are `spell-buffer', `spell-word', `spell-region' and
  28 ;; `spell-string'.  These facilities are documented in the Emacs user's
  29 ;; manual.
  30
  31 ;;; Code:
  32
  33 (defvar spell-command "spell"
  34   "*Command to run the spell program.")
  35
  36 (defvar spell-filter nil
  37   "*Filter function to process text before passing it to spell program.
  38 This function might remove text-processor commands.
  39 nil means don't alter the text before checking it.")
  40
  41 ;;;###autoload
  42 (put 'spell-filter 'risky-local-variable t)
  43
  44 ;;;###autoload
  45 (defun spell-buffer ()
  46   "Check spelling of every word in the buffer.
  47 For each incorrect word, you are asked for the correct spelling
  48 and then put into a query-replace to fix some or all occurrences.
  49 If you do not want to change a word, just give the same word
  50 as its \"correct\" spelling; then the query replace is skipped."
  51   (interactive)
  52   (spell-region (point-min) (point-max) "buffer"))
  53
  54 ;;;###autoload
  55 (defun spell-word ()
  56   "Check spelling of word at or before point.
  57 If it is not correct, ask user for the correct spelling
  58 and `query-replace' the entire buffer to substitute it."
  59   (interactive)
  60   (let (beg end spell-filter)
  61     (save-excursion
  62      (if (not (looking-at "\\<"))
  63          (forward-word -1))
  64      (setq beg (point))
  65      (forward-word 1)
  66      (setq end (point)))
  67     (spell-region beg end (buffer-substring beg end))))
  68
  69 ;;;###autoload
  70 (defun spell-region (start end &optional description)
  71   "Like `spell-buffer' but applies only to region.
  72 Used in a program, applies from START to END.
  73 DESCRIPTION is an optional string naming the unit being checked:
  74 for example, \"word\"."
  75   (interactive "r")
  76   (let ((filter spell-filter)
  77         (buf (get-buffer-create " *temp*")))
  78     (save-excursion
  79      (set-buffer buf)
  80      (widen)
  81      (erase-buffer))
  82     (message "Checking spelling of %s..." (or description "region"))
  83     (if (and (null filter) (= ?\n (char-after (1- end))))
  84         (if (string= "spell" spell-command)
  85             (call-process-region start end "spell" nil buf)
  86           (call-process-region start end shell-file-name
  87                                nil buf nil "-c" spell-command))
  88       (let ((oldbuf (current-buffer)))
  89         (save-excursion
  90          (set-buffer buf)
  91          (insert-buffer-substring oldbuf start end)
  92          (or (bolp) (insert ?\n))
  93          (if filter (funcall filter))
  94          (if (string= "spell" spell-command)
  95              (call-process-region (point-min) (point-max) "spell" t buf)
  96            (call-process-region (point-min) (point-max) shell-file-name
  97                                 t buf nil "-c" spell-command)))))
  98     (message "Checking spelling of %s...%s"
  99              (or description "region")
 100              (if (save-excursion
 101                   (set-buffer buf)
 102                   (> (buffer-size) 0))
 103                  "not correct"
 104                "correct"))
 105     (let (word newword
 106           (case-fold-search t)
 107           (case-replace t))
 108       (while (save-excursion
 109               (set-buffer buf)
 110               (> (buffer-size) 0))
 111         (save-excursion
 112          (set-buffer buf)
 113          (goto-char (point-min))
 114          (setq word (downcase
 115                      (buffer-substring (point)
 116                                        (progn (end-of-line) (point)))))
 117          (forward-char 1)
 118          (delete-region (point-min) (point))
 119          (setq newword
 120                (read-input (concat "`" word
 121                                    "' not recognized; edit a replacement: ")
 122                            word))
 123          (flush-lines (concat "^" (regexp-quote word) "$")))
 124         (if (not (equal word newword))
 125             (progn
 126              (goto-char (point-min))
 127              (query-replace-regexp (concat "\\b" (regexp-quote word) "\\b")
 128                                    newword)))))))
 129
 130
 131 ;;;###autoload
 132 (defun spell-string (string)
 133   "Check spelling of string supplied as argument."
 134   (interactive "sSpell string: ")
 135   (let ((buf (get-buffer-create " *temp*")))
 136     (save-excursion
 137      (set-buffer buf)
 138      (widen)
 139      (erase-buffer)
 140      (insert string "\n")
 141      (if (string= "spell" spell-command)
 142          (call-process-region (point-min) (point-max) "spell"
 143                               t t)
 144        (call-process-region (point-min) (point-max) shell-file-name
 145                             t t nil "-c" spell-command))
 146      (if (= 0 (buffer-size))
 147          (message "%s is correct" string)
 148        (goto-char (point-min))
 149        (while (search-forward "\n" nil t)
 150          (replace-match " "))
 151        (message "%sincorrect" (buffer-substring 1 (point-max)))))))
 152
 153 ;;; spell.el ends here