lisp/progmodes/octave-mod.el

   1 ;;; octave-mod.el --- editing Octave source files under Emacs
   2
   3 ;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>
   7 ;; Author: John Eaton <jwe@octave.org>
   8 ;; Maintainer: Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>
   9 ;; Keywords: languages
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides Emacs support for Octave.
  29 ;; It defines Octave mode, a major mode for editing
  30 ;; Octave code.
  31
  32 ;; The file octave-inf.el contains code for interacting with an inferior
  33 ;; Octave process using comint.
  34
  35 ;; See the documentation of `octave-mode' and
  36 ;; `run-octave' for further information on usage and customization.
  37
  38 ;;; Code:
  39 (require 'custom)
  40
  41 (defgroup octave nil
  42   "Major mode for editing Octave source files."
  43   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  44   :group 'languages)
  45
  46 (defvar inferior-octave-output-list nil)
  47 (defvar inferior-octave-output-string nil)
  48 (defvar inferior-octave-receive-in-progress nil)
  49
  50 (declare-function inferior-octave-send-list-and-digest "octave-inf" (list))
  51
  52 (defconst octave-maintainer-address
  53   "Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>, bug-gnu-emacs@gnu.org"
  54   "Current maintainer of the Emacs Octave package.")
  55
  56 (define-abbrev-table 'octave-abbrev-table
  57   (mapcar (lambda (e) (append e '(nil 0 t)))
  58           '(("`a" "all_va_args")
  59             ("`b" "break")
  60             ("`cs" "case")
  61             ("`ca" "catch")
  62             ("`c" "continue")
  63             ("`el" "else")
  64             ("`eli" "elseif")
  65             ("`et" "end_try_catch")
  66             ("`eu" "end_unwind_protect")
  67             ("`ef" "endfor")
  68             ("`efu" "endfunction")
  69             ("`ei" "endif")
  70             ("`es" "endswitch")
  71             ("`ew" "endwhile")
  72             ("`f" "for")
  73             ("`fu" "function")
  74             ("`gl" "global")
  75             ("`gp" "gplot")
  76             ("`gs" "gsplot")
  77             ("`if" "if ()")
  78             ("`o" "otherwise")
  79             ("`rp" "replot")
  80             ("`r" "return")
  81             ("`s" "switch")
  82             ("`t" "try")
  83             ("`u" "until ()")
  84             ("`up" "unwind_protect")
  85             ("`upc" "unwind_protect_cleanup")
  86             ("`w" "while ()")))
  87   "Abbrev table for Octave's reserved words.
  88 Used in `octave-mode' and inferior-octave-mode buffers.
  89 All Octave abbrevs start with a grave accent (`)."
  90   :regexp "\\(?:[^`]\\|^\\)\\(\\(?:\\<\\|`\\)\\w+\\)\\W*")
  91
  92 (defvar octave-comment-char ?#
  93   "Character to start an Octave comment.")
  94 (defvar octave-comment-start
  95   (string octave-comment-char ?\s)
  96   "String to insert to start a new Octave in-line comment.")
  97 (defvar octave-comment-start-skip "\\s<+\\s-*"
  98   "Regexp to match the start of an Octave comment up to its body.")
  99
 100 (defvar octave-begin-keywords
 101   '("do" "for" "function" "if" "switch" "try" "unwind_protect" "while"))
 102 (defvar octave-else-keywords
 103   '("case" "catch" "else" "elseif" "otherwise" "unwind_protect_cleanup"))
 104 (defvar octave-end-keywords
 105   '("endfor" "endfunction" "endif" "endswitch" "end_try_catch"
 106     "end_unwind_protect" "endwhile" "until" "end"))
 107
 108 (defvar octave-reserved-words
 109   (append octave-begin-keywords
 110           octave-else-keywords
 111           octave-end-keywords
 112           '("break" "continue" "end" "global" "persistent" "return"))
 113   "Reserved words in Octave.")
 114
 115 (defvar octave-text-functions
 116   '("casesen" "cd" "chdir" "clear" "diary" "dir" "document" "echo"
 117     "edit_history" "format" "help" "history" "hold"
 118     "load" "ls" "more" "run_history" "save" "type"
 119     "which" "who" "whos")
 120   "Text functions in Octave.")
 121
 122 (defvar octave-variables
 123   '("DEFAULT_EXEC_PATH" "DEFAULT_LOADPATH"
 124     "EDITOR" "EXEC_PATH" "F_DUPFD" "F_GETFD" "F_GETFL" "F_SETFD"
 125     "F_SETFL" "I" "IMAGE_PATH" "Inf" "J"
 126     "NaN" "OCTAVE_VERSION" "O_APPEND" "O_CREAT" "O_EXCL"
 127     "O_NONBLOCK" "O_RDONLY" "O_RDWR" "O_TRUNC" "O_WRONLY" "PAGER" "PS1"
 128     "PS2" "PS4" "PWD" "SEEK_CUR" "SEEK_END" "SEEK_SET" "__F_DUPFD__"
 129     "__F_GETFD__" "__F_GETFL__" "__F_SETFD__" "__F_SETFL__" "__I__"
 130     "__Inf__" "__J__" "__NaN__" "__OCTAVE_VERSION__" "__O_APPEND__"
 131     "__O_CREAT__" "__O_EXCL__" "__O_NONBLOCK__" "__O_RDONLY__"
 132     "__O_RDWR__" "__O_TRUNC__" "__O_WRONLY__" "__PWD__" "__SEEK_CUR__"
 133     "__SEEK_END__" "__SEEK_SET__" "__argv__" "__e__" "__eps__"
 134     "__i__" "__inf__" "__j__" "__nan__" "__pi__"
 135     "__program_invocation_name__" "__program_name__" "__realmax__"
 136     "__realmin__" "__stderr__" "__stdin__" "__stdout__" "ans" "argv"
 137     "beep_on_error" "completion_append_char"
 138     "crash_dumps_octave_core" "default_save_format"
 139     "e" "echo_executing_commands" "eps"
 140     "error_text" "gnuplot_binary" "history_file"
 141     "history_size" "ignore_function_time_stamp"
 142     "inf" "nan" "nargin" "output_max_field_width" "output_precision"
 143     "page_output_immediately" "page_screen_output" "pi"
 144     "print_answer_id_name" "print_empty_dimensions"
 145     "program_invocation_name" "program_name"
 146     "realmax" "realmin" "return_last_computed_value" "save_precision"
 147     "saving_history" "sighup_dumps_octave_core" "sigterm_dumps_octave_core"
 148     "silent_functions" "split_long_rows" "stderr" "stdin" "stdout"
 149     "string_fill_char" "struct_levels_to_print"
 150     "suppress_verbose_help_message")
 151   "Builtin variables in Octave.")
 152
 153 (defvar octave-function-header-regexp
 154   (concat "^\\s-*\\<\\(function\\)\\>"
 155           "\\([^=;\n]*=[ \t]*\\|[ \t]*\\)\\(\\w+\\)\\>")
 156   "Regexp to match an Octave function header.
 157 The string `function' and its name are given by the first and third
 158 parenthetical grouping.")
 159
 160 (defvar octave-font-lock-keywords
 161   (list
 162    ;; Fontify all builtin keywords.
 163    (cons (concat "\\<\\("
 164                  (regexp-opt (append octave-reserved-words
 165                                      octave-text-functions))
 166                  "\\)\\>")
 167          'font-lock-keyword-face)
 168    ;; Fontify all builtin operators.
 169    (cons "\\(&\\||\\|<=\\|>=\\|==\\|<\\|>\\|!=\\|!\\)"
 170          (if (boundp 'font-lock-builtin-face)
 171              'font-lock-builtin-face
 172            'font-lock-preprocessor-face))
 173    ;; Fontify all builtin variables.
 174    (cons (concat "\\<" (regexp-opt octave-variables) "\\>")
 175          'font-lock-variable-name-face)
 176    ;; Fontify all function declarations.
 177    (list octave-function-header-regexp
 178          '(1 font-lock-keyword-face)
 179          '(3 font-lock-function-name-face nil t)))
 180   "Additional Octave expressions to highlight.")
 181
 182 (defvar octave-font-lock-syntactic-keywords
 183   ;; Try to distinguish the string-quotes from the transpose-quotes.
 184   '(("[[({,; ]\\('\\)" (1 "\"'"))
 185     (octave-font-lock-close-quotes)))
 186
 187 (defun octave-font-lock-close-quotes (limit)
 188   "Fix the syntax-table of the closing quotes of single-quote strings."
 189   ;; Freely inspired from perl-font-lock-special-syntactic-constructs.
 190   (let ((state (syntax-ppss)))
 191     (while (< (point) limit)
 192       (cond
 193        ((eq (nth 3 state) ?\')
 194         ;; A '..' string.
 195         (save-excursion
 196           (when (and (or (looking-at "\\('\\)")
 197                          (re-search-forward "[^\\]\\(?:\\\\\\\\\\)*\\('\\)"
 198                                             nil t))
 199                      (not (eobp)))
 200             (put-text-property (match-beginning 1) (match-end 1)
 201                                'syntax-table (string-to-syntax "\"'"))))))
 202
 203       (setq state (parse-partial-sexp (point) limit nil nil state
 204                                       'syntax-table)))))
 205
 206 (defcustom inferior-octave-buffer "*Inferior Octave*"
 207   "Name of buffer for running an inferior Octave process."
 208   :type 'string
 209   :group 'octave-inferior)
 210
 211 (defvar inferior-octave-process nil)
 212 \f
 213 (defvar octave-mode-map
 214   (let ((map (make-sparse-keymap)))
 215     (define-key map "`" 'octave-abbrev-start)
 216     (define-key map ";" 'octave-electric-semi)
 217     (define-key map " " 'octave-electric-space)
 218     (define-key map "\n" 'octave-reindent-then-newline-and-indent)
 219     (define-key map "\e\n" 'octave-indent-new-comment-line)
 220     (define-key map "\M-\C-q" 'octave-indent-defun)
 221     (define-key map "\C-c\C-b" 'octave-submit-bug-report)
 222     (define-key map "\C-c\C-p" 'octave-previous-code-line)
 223     (define-key map "\C-c\C-n" 'octave-next-code-line)
 224     (define-key map "\C-c\C-a" 'octave-beginning-of-line)
 225     (define-key map "\C-c\C-e" 'octave-end-of-line)
 226     (define-key map [remap down-list] 'smie-down-list)
 227     (define-key map "\C-c\M-\C-h" 'octave-mark-block)
 228     (define-key map "\C-c]" 'smie-close-block)
 229     (define-key map "\C-c/" 'smie-close-block)
 230     (define-key map "\C-c\C-f" 'octave-insert-defun)
 231     (define-key map "\C-c\C-h" 'octave-help)
 232     (define-key map "\C-c\C-il" 'octave-send-line)
 233     (define-key map "\C-c\C-ib" 'octave-send-block)
 234     (define-key map "\C-c\C-if" 'octave-send-defun)
 235     (define-key map "\C-c\C-ir" 'octave-send-region)
 236     (define-key map "\C-c\C-is" 'octave-show-process-buffer)
 237     (define-key map "\C-c\C-ih" 'octave-hide-process-buffer)
 238     (define-key map "\C-c\C-ik" 'octave-kill-process)
 239     (define-key map "\C-c\C-i\C-l" 'octave-send-line)
 240     (define-key map "\C-c\C-i\C-b" 'octave-send-block)
 241     (define-key map "\C-c\C-i\C-f" 'octave-send-defun)
 242     (define-key map "\C-c\C-i\C-r" 'octave-send-region)
 243     (define-key map "\C-c\C-i\C-s" 'octave-show-process-buffer)
 244     (define-key map "\C-c\C-i\C-h" 'octave-hide-process-buffer)
 245     (define-key map "\C-c\C-i\C-k" 'octave-kill-process)
 246     map)
 247   "Keymap used in Octave mode.")
 248
 249
 250
 251 (easy-menu-define octave-mode-menu octave-mode-map
 252   "Menu for Octave mode."
 253   '("Octave"
 254     ("Lines"
 255       ["Previous Code Line"     octave-previous-code-line t]
 256       ["Next Code Line"         octave-next-code-line t]
 257       ["Begin of Continuation"  octave-beginning-of-line t]
 258       ["End of Continuation"    octave-end-of-line t]
 259       ["Split Line at Point"    octave-indent-new-comment-line t])
 260     ("Blocks"
 261       ["Mark Block"             octave-mark-block t]
 262       ["Close Block"            smie-close-block t])
 263     ("Functions"
 264       ["Indent Function"        octave-indent-defun t]
 265       ["Insert Function"        octave-insert-defun t])
 266     "-"
 267     ("Debug"
 268       ["Send Current Line"      octave-send-line t]
 269       ["Send Current Block"     octave-send-block t]
 270       ["Send Current Function"  octave-send-defun t]
 271       ["Send Region"            octave-send-region t]
 272       ["Show Process Buffer"    octave-show-process-buffer t]
 273       ["Hide Process Buffer"    octave-hide-process-buffer t]
 274       ["Kill Process"           octave-kill-process t])
 275     "-"
 276     ["Indent Line"              indent-according-to-mode t]
 277     ["Complete Symbol"          completion-at-point t]
 278     "-"
 279     ["Toggle Abbrev Mode"       abbrev-mode
 280      :style toggle :selected abbrev-mode]
 281     ["Toggle Auto-Fill Mode"    auto-fill-mode
 282      :style toggle :selected auto-fill-function]
 283     "-"
 284     ["Submit Bug Report"        octave-submit-bug-report t]
 285     "-"
 286     ["Describe Octave Mode"     describe-mode t]
 287     ["Lookup Octave Index"      info-lookup-symbol t]))
 288
 289 (defvar octave-mode-syntax-table
 290   (let ((table (make-syntax-table)))
 291     (modify-syntax-entry ?\r " "  table)
 292     (modify-syntax-entry ?+ "."   table)
 293     (modify-syntax-entry ?- "."   table)
 294     (modify-syntax-entry ?= "."   table)
 295     (modify-syntax-entry ?* "."   table)
 296     (modify-syntax-entry ?/ "."   table)
 297     (modify-syntax-entry ?> "."   table)
 298     (modify-syntax-entry ?< "."   table)
 299     (modify-syntax-entry ?& "."   table)
 300     (modify-syntax-entry ?| "."   table)
 301     (modify-syntax-entry ?! "."   table)
 302     (modify-syntax-entry ?\\ "\\" table)
 303     (modify-syntax-entry ?\' "."  table)
 304     ;; Was "w" for abbrevs, but now that it's not necessary any more,
 305     (modify-syntax-entry ?\` "."  table)
 306     (modify-syntax-entry ?\" "\"" table)
 307     (modify-syntax-entry ?. "w"   table)
 308     (modify-syntax-entry ?_ "w"   table)
 309     ;; The "b" flag only applies to the second letter of the comstart
 310     ;; and the first letter of the comend, i.e. the "4b" below is ineffective.
 311     ;; If we try to put `b' on the single-line comments, we get a similar
 312     ;; problem where the % and # chars appear as first chars of the 2-char
 313     ;; comend, so the multi-line ender is also turned into style-b.
 314     ;; So we need the new "c" comment style.
 315     (modify-syntax-entry ?\% "< 13"  table)
 316     (modify-syntax-entry ?\# "< 13"  table)
 317     (modify-syntax-entry ?\{ "(} 2c"  table)
 318     (modify-syntax-entry ?\} "){ 4c"  table)
 319     (modify-syntax-entry ?\n ">"  table)
 320     table)
 321   "Syntax table in use in `octave-mode' buffers.")
 322
 323 (defcustom octave-auto-indent nil
 324   "Non-nil means indent line after a semicolon or space in Octave mode."
 325   :type 'boolean
 326   :group 'octave)
 327
 328 (defcustom octave-auto-newline nil
 329   "Non-nil means automatically newline after a semicolon in Octave mode."
 330   :type 'boolean
 331   :group 'octave)
 332
 333 (defcustom octave-blink-matching-block t
 334   "Control the blinking of matching Octave block keywords.
 335 Non-nil means show matching begin of block when inserting a space,
 336 newline or semicolon after an else or end keyword."
 337   :type 'boolean
 338   :group 'octave)
 339
 340 (defcustom octave-block-offset 2
 341   "Extra indentation applied to statements in Octave block structures."
 342   :type 'integer
 343   :group 'octave)
 344
 345 (defvar octave-block-else-regexp
 346   (concat "\\<\\("
 347           (mapconcat 'identity octave-else-keywords "\\|")
 348           "\\)\\>"))
 349 (defvar octave-block-end-regexp
 350   (concat "\\<\\("
 351           (mapconcat 'identity octave-end-keywords "\\|")
 352           "\\)\\>"))
 353 (defvar octave-block-else-or-end-regexp
 354   (concat octave-block-else-regexp "\\|" octave-block-end-regexp))
 355 (defvar octave-block-match-alist
 356   '(("do" . ("until"))
 357     ("for" . ("end" "endfor"))
 358     ("function" . ("end" "endfunction"))
 359     ("if" . ("else" "elseif" "end" "endif"))
 360     ("switch" . ("case" "otherwise" "end" "endswitch"))
 361     ("try" . ("catch" "end" "end_try_catch"))
 362     ("unwind_protect" . ("unwind_protect_cleanup" "end" "end_unwind_protect"))
 363     ("while" . ("end" "endwhile")))
 364   "Alist with Octave's matching block keywords.
 365 Has Octave's begin keywords as keys and a list of the matching else or
 366 end keywords as associated values.")
 367
 368 (defvar octave-block-comment-start
 369   (concat (make-string 2 octave-comment-char) " ")
 370   "String to insert to start a new Octave comment on an empty line.")
 371
 372 (defcustom octave-continuation-offset 4
 373   "Extra indentation applied to Octave continuation lines."
 374   :type 'integer
 375   :group 'octave)
 376 (eval-and-compile
 377   (defconst octave-continuation-marker-regexp "\\\\\\|\\.\\.\\."))
 378 (defvar octave-continuation-regexp
 379   (concat "[^#%\n]*\\(" octave-continuation-marker-regexp
 380           "\\)\\s-*\\(\\s<.*\\)?$"))
 381 (defcustom octave-continuation-string "\\"
 382   "Character string used for Octave continuation lines.  Normally \\."
 383   :type 'string
 384   :group 'octave)
 385
 386 (defvar octave-completion-alist nil
 387   "Alist of Octave symbols for completion in Octave mode.
 388 Each element looks like (VAR . VAR), where the car and cdr are the same
 389 symbol (an Octave command or variable name).
 390 Currently, only builtin variables can be completed.")
 391
 392 (defvar octave-mode-imenu-generic-expression
 393   (list
 394    ;; Functions
 395    (list nil octave-function-header-regexp 3))
 396   "Imenu expression for Octave mode.  See `imenu-generic-expression'.")
 397
 398 (defcustom octave-mode-hook nil
 399   "Hook to be run when Octave mode is started."
 400   :type 'hook
 401   :group 'octave)
 402
 403 (defcustom octave-send-show-buffer t
 404   "Non-nil means display `inferior-octave-buffer' after sending to it."
 405   :type 'boolean
 406   :group 'octave)
 407 (defcustom octave-send-line-auto-forward t
 408   "Control auto-forward after sending to the inferior Octave process.
 409 Non-nil means always go to the next Octave code line after sending."
 410   :type 'boolean
 411   :group 'octave)
 412 (defcustom octave-send-echo-input t
 413   "Non-nil means echo input sent to the inferior Octave process."
 414   :type 'boolean
 415   :group 'octave)
 416
 417 \f
 418 ;;; SMIE indentation
 419
 420 (require 'smie)
 421
 422 (defconst octave-operator-table
 423   '((assoc ";" "\n") (assoc ",") ; The doc claims they have equal precedence!?
 424     (right "=" "+=" "-=" "*=" "/=")
 425     (assoc "&&") (assoc "||") ; The doc claims they have equal precedence!?
 426     (assoc "&") (assoc "|")   ; The doc claims they have equal precedence!?
 427     (nonassoc "<" "<=" "==" ">=" ">" "!=" "~=")
 428     (nonassoc ":")                      ;No idea what this is.
 429     (assoc "+" "-")
 430     (assoc "*" "/" "\\" ".\\" ".*" "./")
 431     (nonassoc "'" ".'")
 432     (nonassoc "++" "--" "!" "~")        ;And unary "+" and "-".
 433     (right "^" "**" ".^" ".**")
 434     ;; It's not really an operator, but for indentation purposes it
 435     ;; could be convenient to treat it as one.
 436     (assoc "...")))
 437
 438 (defconst octave-smie-op-levels
 439   (smie-prec2-levels
 440    (smie-merge-prec2s
 441     (smie-bnf-precedence-table
 442      '((atom)
 443        ;; We can't distinguish the first element in a sequence with
 444        ;; precedence grammars, so we can't distinguish the condition
 445        ;; if the `if' from the subsequent body, for example.
 446        ;; This has to be done later in the indentation rules.
 447        (exp (exp "\n" exp)
 448             ;; We need to mention at least one of the operators in this part
 449             ;; of the grammar: if the BNF and the operator table have
 450             ;; no overlap, SMIE can't know how they relate.
 451             (exp ";" exp)
 452             ("try" exp "catch" exp "end_try_catch")
 453             ("try" exp "catch" exp "end")
 454             ("unwind_protect" exp
 455              "unwind_protect_cleanup" exp "end_unwind_protect")
 456             ("unwind_protect" exp "unwind_protect_cleanup" exp "end")
 457             ("for" exp "endfor")
 458             ("for" exp "end")
 459             ("do" exp "until" atom)
 460             ("while" exp "endwhile")
 461             ("while" exp "end")
 462             ("if" exp "endif")
 463             ("if" exp "else" exp "endif")
 464             ("if" exp "elseif" exp "else" exp "endif")
 465             ("if" exp "elseif" exp "elseif" exp "else" exp "endif")
 466             ("if" exp "elseif" exp "elseif" exp "else" exp "end")
 467             ("switch" exp "case" exp "endswitch")
 468             ("switch" exp "case" exp "otherwise" exp "endswitch")
 469             ("switch" exp "case" exp "case" exp "otherwise" exp "endswitch")
 470             ("switch" exp "case" exp "case" exp "otherwise" exp "end")
 471             ("function" exp "endfunction")
 472             ("function" exp "end"))
 473        ;; (fundesc (atom "=" atom))
 474        )
 475      '((assoc "\n" ";")))
 476
 477     (smie-precs-precedence-table
 478      (append octave-operator-table
 479              '((nonassoc " -dummy- "))) ;Bogus anchor at the end.
 480      ))))
 481
 482 ;; Tokenizing needs to be refined so that ";;" is treated as two
 483 ;; tokens and also so as to recognize the \n separator (and
 484 ;; corresponding continuation lines).
 485
 486 (defconst octave-operator-regexp
 487   (regexp-opt (apply 'append (mapcar 'cdr octave-operator-table))))
 488
 489 (defun octave-smie-backward-token ()
 490   (let ((pos (point)))
 491     (forward-comment (- (point)))
 492     (cond
 493      ((and (not (eq (char-before) ?\;)) ;Coalesce ";" and "\n".
 494            (> pos (line-end-position))
 495            (if (looking-back octave-continuation-marker-regexp (- (point) 3))
 496                (progn
 497                  (goto-char (match-beginning 0))
 498                  (forward-comment (- (point)))
 499                  nil)
 500              t)
 501            ;; Ignore it if it's within parentheses.
 502            (let ((ppss (syntax-ppss)))
 503              (not (and (nth 1 ppss)
 504                        (eq ?\( (char-after (nth 1 ppss)))))))
 505       (skip-chars-forward " \t")
 506       ;; Why bother distinguishing \n and ;?
 507       ";") ;;"\n"
 508      ((and (looking-back octave-operator-regexp (- (point) 3) 'greedy)
 509            ;; Don't mistake a string quote for a transpose.
 510            (not (looking-back "\\s\"" (1- (point)))))
 511       (goto-char (match-beginning 0))
 512       (match-string-no-properties 0))
 513      (t
 514       (smie-default-backward-token)))))
 515
 516 (defun octave-smie-forward-token ()
 517   (skip-chars-forward " \t")
 518   (when (looking-at (eval-when-compile
 519                       (concat "\\(" octave-continuation-marker-regexp
 520                               "\\)[ \t]*\\($\\|[%#]\\)")))
 521     (goto-char (match-end 1))
 522     (forward-comment 1))
 523   (cond
 524    ((and (looking-at "$\\|[%#]")
 525          ;; Ignore it if it's within parentheses.
 526          (prog1 (let ((ppss (syntax-ppss)))
 527                   (not (and (nth 1 ppss)
 528                             (eq ?\( (char-after (nth 1 ppss))))))
 529            (forward-comment (point-max))))
 530     ;; Why bother distinguishing \n and ;?
 531     ";") ;;"\n"
 532    ((looking-at ";[ \t]*\\($\\|[%#]\\)")
 533     ;; Combine the ; with the subsequent \n.
 534     (goto-char (match-beginning 1))
 535     (forward-comment 1)
 536     ";")
 537    ((and (looking-at octave-operator-regexp)
 538          ;; Don't mistake a string quote for a transpose.
 539          (not (looking-at "\\s\"")))
 540     (goto-char (match-end 0))
 541     (match-string-no-properties 0))
 542    (t
 543     (smie-default-forward-token))))
 544
 545 (defconst octave-smie-indent-rules
 546   '((";"
 547      (:parent ("function" "if" "while" "else" "elseif" "for" "otherwise"
 548                "case" "try" "catch" "unwind_protect" "unwind_protect_cleanup")
 549       ;; FIXME: don't hardcode 2.
 550       (+ parent octave-block-offset))
 551      ;; (:parent "switch" 4) ;For (invalid) code between switch and case.
 552      0)
 553     ((:before . "case") octave-block-offset)))
 554
 555 ;;;###autoload
 556 (define-derived-mode octave-mode prog-mode "Octave"
 557   "Major mode for editing Octave code.
 558
 559 This mode makes it easier to write Octave code by helping with
 560 indentation, doing some of the typing for you (with Abbrev mode) and by
 561 showing keywords, comments, strings, etc. in different faces (with
 562 Font Lock mode on terminals that support it).
 563
 564 Octave itself is a high-level language, primarily intended for numerical
 565 computations.  It provides a convenient command line interface for
 566 solving linear and nonlinear problems numerically.  Function definitions
 567 can also be stored in files, and it can be used in a batch mode (which
 568 is why you need this mode!).
 569
 570 The latest released version of Octave is always available via anonymous
 571 ftp from ftp.octave.org in the directory `/pub/octave'.  Complete
 572 source and binaries for several popular systems are available.
 573
 574 Type \\[list-abbrevs] to display the built-in abbrevs for Octave keywords.
 575
 576 Keybindings
 577 ===========
 578
 579 \\{octave-mode-map}
 580
 581 Variables you can use to customize Octave mode
 582 ==============================================
 583
 584 `octave-auto-indent'
 585   Non-nil means indent current line after a semicolon or space.
 586   Default is nil.
 587
 588 `octave-auto-newline'
 589   Non-nil means auto-insert a newline and indent after a semicolon.
 590   Default is nil.
 591
 592 `octave-blink-matching-block'
 593   Non-nil means show matching begin of block when inserting a space,
 594   newline or semicolon after an else or end keyword.  Default is t.
 595
 596 `octave-block-offset'
 597   Extra indentation applied to statements in block structures.
 598   Default is 2.
 599
 600 `octave-continuation-offset'
 601   Extra indentation applied to Octave continuation lines.
 602   Default is 4.
 603
 604 `octave-continuation-string'
 605   String used for Octave continuation lines.
 606   Default is a backslash.
 607
 608 `octave-send-echo-input'
 609   Non-nil means always display `inferior-octave-buffer' after sending a
 610   command to the inferior Octave process.
 611
 612 `octave-send-line-auto-forward'
 613   Non-nil means always go to the next unsent line of Octave code after
 614   sending a line to the inferior Octave process.
 615
 616 `octave-send-echo-input'
 617   Non-nil means echo input sent to the inferior Octave process.
 618
 619 Turning on Octave mode runs the hook `octave-mode-hook'.
 620
 621 To begin using this mode for all `.m' files that you edit, add the
 622 following lines to your `.emacs' file:
 623
 624   (add-to-list 'auto-mode-alist '(\"\\\\.m\\\\'\" . octave-mode))
 625
 626 To automatically turn on the abbrev and auto-fill features,
 627 add the following lines to your `.emacs' file as well:
 628
 629   (add-hook 'octave-mode-hook
 630             (lambda ()
 631               (abbrev-mode 1)
 632               (auto-fill-mode 1)))
 633
 634 To submit a problem report, enter \\[octave-submit-bug-report] from \
 635 an Octave mode buffer.
 636 This automatically sets up a mail buffer with version information
 637 already added.  You just need to add a description of the problem,
 638 including a reproducible test case and send the message."
 639   (setq local-abbrev-table octave-abbrev-table)
 640
 641   (smie-setup octave-smie-op-levels octave-smie-indent-rules)
 642   (set (make-local-variable 'smie-indent-basic) 'octave-block-offset)
 643   (set (make-local-variable 'smie-backward-token-function)
 644        'octave-smie-backward-token)
 645   (set (make-local-variable 'smie-forward-token-function)
 646        'octave-smie-forward-token)
 647   (set (make-local-variable 'forward-sexp-function)
 648        'smie-forward-sexp-command)
 649   (set (make-local-variable 'smie-closer-alist)
 650        (mapcar (lambda (elem) (cons (car elem) (car (last elem))))
 651                octave-block-match-alist))
 652
 653   (set (make-local-variable 'comment-start) octave-comment-start)
 654   (set (make-local-variable 'comment-end) "")
 655   ;; Don't set it here: it's not really a property of the language,
 656   ;; just a personal preference of the author.
 657   ;; (set (make-local-variable 'comment-column) 32)
 658   (set (make-local-variable 'comment-start-skip) "\\s<+\\s-*")
 659   (set (make-local-variable 'comment-add) 1)
 660
 661   (set (make-local-variable 'parse-sexp-ignore-comments) t)
 662   (set (make-local-variable 'paragraph-start)
 663        (concat "\\s-*$\\|" page-delimiter))
 664   (set (make-local-variable 'paragraph-separate) paragraph-start)
 665   (set (make-local-variable 'paragraph-ignore-fill-prefix) t)
 666   (set (make-local-variable 'fill-paragraph-function) 'octave-fill-paragraph)
 667   ;; FIXME: Why disable it?
 668   ;; (set (make-local-variable 'adaptive-fill-regexp) nil)
 669   ;; Again, this is not a property of the language, don't set it here.
 670   ;; (set (make-local-variable 'fill-column) 72)
 671   (set (make-local-variable 'normal-auto-fill-function) 'octave-auto-fill)
 672
 673   (set (make-local-variable 'font-lock-defaults)
 674        '(octave-font-lock-keywords nil nil nil nil
 675          (font-lock-syntactic-keywords . octave-font-lock-syntactic-keywords)
 676          (parse-sexp-lookup-properties . t)))
 677
 678   (set (make-local-variable 'imenu-generic-expression)
 679        octave-mode-imenu-generic-expression)
 680   (set (make-local-variable 'imenu-case-fold-search) nil)
 681
 682   (add-hook 'completion-at-point-functions
 683             'octave-completion-at-point-function nil t)
 684   (set (make-local-variable 'beginning-of-defun-function)
 685        'octave-beginning-of-defun)
 686
 687   (easy-menu-add octave-mode-menu)
 688   (octave-initialize-completions)
 689   (run-mode-hooks 'octave-mode-hook))
 690
 691 (defvar info-lookup-mode)
 692
 693 (defun octave-help ()
 694   "Get help on Octave symbols from the Octave info files.
 695 Look up symbol in the function, operator and variable indices of the info files."
 696   (let ((info-lookup-mode 'octave-mode))
 697     (call-interactively 'info-lookup-symbol)))
 698 \f
 699 ;;; Miscellaneous useful functions
 700
 701 (defsubst octave-in-comment-p ()
 702   "Return t if point is inside an Octave comment."
 703   (save-excursion
 704     ;; FIXME: use syntax-ppss?
 705     (nth 4 (parse-partial-sexp (line-beginning-position) (point)))))
 706
 707 (defsubst octave-in-string-p ()
 708   "Return t if point is inside an Octave string."
 709   (save-excursion
 710     ;; FIXME: use syntax-ppss?
 711     (nth 3 (parse-partial-sexp (line-beginning-position) (point)))))
 712
 713 (defsubst octave-not-in-string-or-comment-p ()
 714   "Return t if point is not inside an Octave string or comment."
 715   ;; FIXME: Use syntax-ppss?
 716   (let ((pps (parse-partial-sexp (line-beginning-position) (point))))
 717     (not (or (nth 3 pps) (nth 4 pps)))))
 718
 719
 720 (defun octave-looking-at-kw (regexp)
 721   "Like `looking-at', but sets `case-fold-search' nil."
 722   (let ((case-fold-search nil))
 723     (looking-at regexp)))
 724
 725 (defun octave-maybe-insert-continuation-string ()
 726   (if (or (octave-in-comment-p)
 727           (save-excursion
 728             (beginning-of-line)
 729             (looking-at octave-continuation-regexp)))
 730       nil
 731     (delete-horizontal-space)
 732     (insert (concat " " octave-continuation-string))))
 733
 734 \f
 735 ;;; Indentation
 736
 737 (defun octave-indent-new-comment-line ()
 738   "Break Octave line at point, continuing comment if within one.
 739 If within code, insert `octave-continuation-string' before breaking the
 740 line.  If within a string, signal an error.
 741 The new line is properly indented."
 742   (interactive)
 743   (delete-horizontal-space)
 744   (cond
 745    ((octave-in-comment-p)
 746     (indent-new-comment-line))
 747    ((octave-in-string-p)
 748     (error "Cannot split a code line inside a string"))
 749    (t
 750     (insert (concat " " octave-continuation-string))
 751     (octave-reindent-then-newline-and-indent))))
 752
 753 (defun octave-indent-defun ()
 754   "Properly indent the Octave function which contains point."
 755   (interactive)
 756   (save-excursion
 757     (mark-defun)
 758     (message "Indenting function...")
 759     (indent-region (point) (mark) nil))
 760   (message "Indenting function...done."))
 761
 762 \f
 763 ;;; Motion
 764 (defun octave-next-code-line (&optional arg)
 765   "Move ARG lines of Octave code forward (backward if ARG is negative).
 766 Skips past all empty and comment lines.  Default for ARG is 1.
 767
 768 On success, return 0.  Otherwise, go as far as possible and return -1."
 769   (interactive "p")
 770   (or arg (setq arg 1))
 771   (beginning-of-line)
 772   (let ((n 0)
 773         (inc (if (> arg 0) 1 -1)))
 774     (while (and (/= arg 0) (= n 0))
 775       (setq n (forward-line inc))
 776       (while (and (= n 0)
 777                   (looking-at "\\s-*\\($\\|\\s<\\)"))
 778         (setq n (forward-line inc)))
 779       (setq arg (- arg inc)))
 780     n))
 781
 782 (defun octave-previous-code-line (&optional arg)
 783   "Move ARG lines of Octave code backward (forward if ARG is negative).
 784 Skips past all empty and comment lines.  Default for ARG is 1.
 785
 786 On success, return 0.  Otherwise, go as far as possible and return -1."
 787   (interactive "p")
 788   (or arg (setq arg 1))
 789   (octave-next-code-line (- arg)))
 790
 791 (defun octave-beginning-of-line ()
 792   "Move point to beginning of current Octave line.
 793 If on an empty or comment line, go to the beginning of that line.
 794 Otherwise, move backward to the beginning of the first Octave code line
 795 which is not inside a continuation statement, i.e., which does not
 796 follow a code line ending in `...' or `\\', or is inside an open
 797 parenthesis list."
 798   (interactive)
 799   (beginning-of-line)
 800   (if (not (looking-at "\\s-*\\($\\|\\s<\\)"))
 801       (while (or (condition-case nil
 802                      (progn
 803                        (up-list -1)
 804                        (beginning-of-line)
 805                        t)
 806                    (error nil))
 807                  (and (or (looking-at "\\s-*\\($\\|\\s<\\)")
 808                           (save-excursion
 809                             (if (zerop (octave-previous-code-line))
 810                                 (looking-at octave-continuation-regexp))))
 811                       (zerop (forward-line -1)))))))
 812
 813 (defun octave-end-of-line ()
 814   "Move point to end of current Octave line.
 815 If on an empty or comment line, go to the end of that line.
 816 Otherwise, move forward to the end of the first Octave code line which
 817 does not end in `...' or `\\' or is inside an open parenthesis list."
 818   (interactive)
 819   (end-of-line)
 820   (if (save-excursion
 821         (beginning-of-line)
 822         (looking-at "\\s-*\\($\\|\\s<\\)"))
 823       ()
 824     (while (or (condition-case nil
 825                    (progn
 826                      (up-list 1)
 827                      (end-of-line)
 828                      t)
 829                  (error nil))
 830                (and (save-excursion
 831                       (beginning-of-line)
 832                       (or (looking-at "\\s-*\\($\\|\\s<\\)")
 833                           (looking-at octave-continuation-regexp)))
 834                     (zerop (forward-line 1)))))
 835     (end-of-line)))
 836
 837 (defun octave-mark-block ()
 838   "Put point at the beginning of this Octave block, mark at the end.
 839 The block marked is the one that contains point or follows point."
 840   (interactive)
 841   (unless (or (looking-at "\\s(")
 842               (save-excursion
 843                 (let* ((token (funcall smie-forward-token-function))
 844                        (level (assoc token smie-op-levels)))
 845                   (and level (null (cadr level))))))
 846     (backward-up-list 1))
 847   (mark-sexp))
 848
 849 (defun octave-blink-matching-block-open ()
 850   "Blink the matching Octave begin block keyword.
 851 If point is right after an Octave else or end type block keyword, move
 852 cursor momentarily to the corresponding begin keyword.
 853 Signal an error if the keywords are incompatible."
 854   (interactive)
 855   (let (bb-keyword bb-arg eb-keyword pos eol)
 856     (if (and (octave-not-in-string-or-comment-p)
 857              (looking-at "\\>")
 858              (save-excursion
 859                (skip-syntax-backward "w")
 860                (octave-looking-at-kw octave-block-else-or-end-regexp)))
 861         (save-excursion
 862           (cond
 863            ((match-end 1)
 864             (setq eb-keyword
 865                   (buffer-substring-no-properties
 866                    (match-beginning 1) (match-end 1)))
 867             (backward-up-list 1))
 868            ((match-end 2)
 869             (setq eb-keyword
 870                   (buffer-substring-no-properties
 871                    (match-beginning 2) (match-end 2)))
 872             (backward-sexp 1)))
 873           (setq pos (match-end 0)
 874                 bb-keyword
 875                 (buffer-substring-no-properties
 876                  (match-beginning 0) pos)
 877                 pos (+ pos 1)
 878                 eol (line-end-position)
 879                 bb-arg
 880                 (save-excursion
 881                   (save-restriction
 882                     (goto-char pos)
 883                     (while (and (skip-syntax-forward "^<" eol)
 884                                 (octave-in-string-p)
 885                                 (not (forward-char 1))))
 886                     (skip-syntax-backward " ")
 887                     (buffer-substring-no-properties pos (point)))))
 888           (if (member eb-keyword
 889                       (cdr (assoc bb-keyword octave-block-match-alist)))
 890               (progn
 891                 (message "Matches `%s %s'" bb-keyword bb-arg)
 892                 (if (pos-visible-in-window-p)
 893                     (sit-for blink-matching-delay)))
 894             (error "Block keywords `%s' and `%s' do not match"
 895                    bb-keyword eb-keyword))))))
 896
 897 (defun octave-beginning-of-defun (&optional arg)
 898   "Move backward to the beginning of an Octave function.
 899 With positive ARG, do it that many times.  Negative argument -N means
 900 move forward to Nth following beginning of a function.
 901 Returns t unless search stops at the beginning or end of the buffer."
 902   (let* ((arg (or arg 1))
 903          (inc (if (> arg 0) 1 -1))
 904          (found nil)
 905          (case-fold-search nil))
 906     (and (not (eobp))
 907          (not (and (> arg 0) (looking-at "\\<function\\>")))
 908          (skip-syntax-forward "w"))
 909     (while (and (/= arg 0)
 910                 (setq found
 911                       (re-search-backward "\\<function\\>" inc)))
 912       (if (octave-not-in-string-or-comment-p)
 913           (setq arg (- arg inc))))
 914     (if found
 915         (progn
 916           (and (< inc 0) (goto-char (match-beginning 0)))
 917           t))))
 918
 919 \f
 920 ;;; Filling
 921 (defun octave-auto-fill ()
 922   "Perform auto-fill in Octave mode.
 923 Returns nil if no feasible place to break the line could be found, and t
 924 otherwise."
 925   (let (fc give-up)
 926     (if (or (null (setq fc (current-fill-column)))
 927             (save-excursion
 928               (beginning-of-line)
 929               (and auto-fill-inhibit-regexp
 930                    (octave-looking-at-kw auto-fill-inhibit-regexp))))
 931         nil                             ; Can't do anything
 932       (if (and (not (octave-in-comment-p))
 933                (> (current-column) fc))
 934           (setq fc (- fc (+ (length octave-continuation-string) 1))))
 935       (while (and (not give-up) (> (current-column) fc))
 936         (let* ((opoint (point))
 937                (fpoint
 938                 (save-excursion
 939                   (move-to-column (+ fc 1))
 940                   (skip-chars-backward "^ \t\n")
 941                   ;; If we're at the beginning of the line, break after
 942                   ;; the first word
 943                   (if (bolp)
 944                       (re-search-forward "[ \t]" opoint t))
 945                   ;; If we're in a comment line, don't break after the
 946                   ;; comment chars
 947                   (if (save-excursion
 948                         (skip-syntax-backward " <")
 949                         (bolp))
 950                       (re-search-forward "[ \t]" (line-end-position)
 951                                          'move))
 952                   ;; If we're not in a comment line and just ahead the
 953                   ;; continuation string, don't break here.
 954                   (if (and (not (octave-in-comment-p))
 955                            (looking-at
 956                             (concat "\\s-*"
 957                                     (regexp-quote
 958                                      octave-continuation-string)
 959                                     "\\s-*$")))
 960                       (end-of-line))
 961                   (skip-chars-backward " \t")
 962                   (point))))
 963           (if (save-excursion
 964                 (goto-char fpoint)
 965                 (not (or (bolp) (eolp))))
 966               (let ((prev-column (current-column)))
 967                 (if (save-excursion
 968                       (skip-chars-backward " \t")
 969                       (= (point) fpoint))
 970                     (progn
 971                       (octave-maybe-insert-continuation-string)
 972                       (indent-new-comment-line t))
 973                   (save-excursion
 974                     (goto-char fpoint)
 975                     (octave-maybe-insert-continuation-string)
 976                     (indent-new-comment-line t)))
 977                 (if (>= (current-column) prev-column)
 978                     (setq give-up t)))
 979             (setq give-up t))))
 980       (not give-up))))
 981
 982 (defun octave-fill-paragraph (&optional arg)
 983   "Fill paragraph of Octave code, handling Octave comments."
 984   ;; FIXME: difference with generic fill-paragraph:
 985   ;; - code lines are only split, never joined.
 986   ;; - \n that end comments are never removed.
 987   ;; - insert continuation marker when splitting code lines.
 988   (interactive "P")
 989   (save-excursion
 990     (let ((end (progn (forward-paragraph) (copy-marker (point) t)))
 991           (beg (progn
 992                  (forward-paragraph -1)
 993                  (skip-chars-forward " \t\n")
 994                  (beginning-of-line)
 995                  (point)))
 996           (cfc (current-fill-column))
 997           comment-prefix)
 998       (goto-char beg)
 999       (while (< (point) end)
1000         (condition-case nil
1001             (indent-according-to-mode)
1002           (error nil))
1003         (move-to-column cfc)
1004         ;; First check whether we need to combine non-empty comment lines
1005         (if (and (< (current-column) cfc)
1006                  (octave-in-comment-p)
1007                  (not (save-excursion
1008                         (beginning-of-line)
1009                         (looking-at "^\\s-*\\s<+\\s-*$"))))
1010             ;; This is a nonempty comment line which does not extend
1011             ;; past the fill column.  If it is followed by a nonempty
1012             ;; comment line with the same comment prefix, try to
1013             ;; combine them, and repeat this until either we reach the
1014             ;; fill-column or there is nothing more to combine.
1015             (progn
1016               ;; Get the comment prefix
1017               (save-excursion
1018                 (beginning-of-line)
1019                 (while (and (re-search-forward "\\s<+")
1020                             (not (octave-in-comment-p))))
1021                 (setq comment-prefix (match-string 0)))
1022               ;; And keep combining ...
1023               (while (and (< (current-column) cfc)
1024                           (save-excursion
1025                             (forward-line 1)
1026                             (and (looking-at
1027                                   (concat "^\\s-*"
1028                                           comment-prefix
1029                                           "\\S<"))
1030                                  (not (looking-at
1031                                        (concat "^\\s-*"
1032                                                comment-prefix
1033                                                "\\s-*$"))))))
1034                 (delete-char 1)
1035                 (re-search-forward comment-prefix)
1036                 (delete-region (match-beginning 0) (match-end 0))
1037                 (fixup-whitespace)
1038                 (move-to-column cfc))))
1039         ;; We might also try to combine continued code lines>  Perhaps
1040         ;; some other time ...
1041         (skip-chars-forward "^ \t\n")
1042         (delete-horizontal-space)
1043         (if (or (< (current-column) cfc)
1044                 (and (= (current-column) cfc) (eolp)))
1045             (forward-line 1)
1046           (if (not (eolp)) (insert " "))
1047           (or (octave-auto-fill)
1048               (forward-line 1))))
1049       t)))
1050
1051 \f
1052 ;;; Completions
1053 (defun octave-initialize-completions ()
1054   "Create an alist for Octave completions."
1055   (if octave-completion-alist
1056       ()
1057     (setq octave-completion-alist
1058           (append octave-reserved-words
1059                   octave-text-functions
1060                   octave-variables))))
1061
1062 (defun octave-completion-at-point-function ()
1063   "Find the text to complete and the corresponding table."
1064   (let* ((beg (save-excursion (backward-sexp 1) (point)))
1065          (end (point)))
1066     (if (< beg (point))
1067         ;; Extend region past point, if applicable.
1068         (save-excursion (goto-char beg) (forward-sexp 1)
1069                         (setq end (max end (point)))))
1070     (list beg end octave-completion-alist)))
1071
1072 (defun octave-complete-symbol ()
1073   "Perform completion on Octave symbol preceding point.
1074 Compare that symbol against Octave's reserved words and builtin
1075 variables."
1076   (interactive)
1077   (apply 'completion-in-region (octave-completion-at-point-function)))
1078 \f
1079 ;;; Electric characters && friends
1080 (defun octave-reindent-then-newline-and-indent ()
1081   "Reindent current Octave line, insert newline, and indent the new line.
1082 If Abbrev mode is on, expand abbrevs first."
1083   ;; FIXME: None of this is Octave-specific.
1084   (interactive)
1085   (if abbrev-mode (expand-abbrev))
1086   (if octave-blink-matching-block
1087       (octave-blink-matching-block-open))
1088   (reindent-then-newline-and-indent))
1089
1090 (defun octave-electric-semi ()
1091   "Insert a semicolon in Octave mode.
1092 Maybe expand abbrevs and blink matching block open keywords.
1093 Reindent the line if `octave-auto-indent' is non-nil.
1094 Insert a newline if `octave-auto-newline' is non-nil."
1095   (interactive)
1096   (if (not (octave-not-in-string-or-comment-p))
1097       (insert ";")
1098     (if abbrev-mode (expand-abbrev))
1099     (if octave-blink-matching-block
1100         (octave-blink-matching-block-open))
1101     (if octave-auto-indent
1102         (indent-according-to-mode))
1103     (insert ";")
1104     (if octave-auto-newline
1105         (newline-and-indent))))
1106
1107 (defun octave-electric-space ()
1108   "Insert a space in Octave mode.
1109 Maybe expand abbrevs and blink matching block open keywords.
1110 Reindent the line if `octave-auto-indent' is non-nil."
1111   (interactive)
1112   (setq last-command-event ? )
1113   (if (and octave-auto-indent
1114            (not (octave-not-in-string-or-comment-p)))
1115       (progn
1116         (indent-according-to-mode)
1117         (self-insert-command 1))
1118     (if abbrev-mode (expand-abbrev))
1119     (if octave-blink-matching-block
1120         (octave-blink-matching-block-open))
1121     (if (and octave-auto-indent
1122              (save-excursion
1123                (skip-syntax-backward " ")
1124                (not (bolp))))
1125         (indent-according-to-mode))
1126     (self-insert-command 1)))
1127
1128 (defun octave-abbrev-start ()
1129   "Start entering an Octave abbreviation.
1130 If Abbrev mode is turned on, typing ` (grave accent) followed by ? or
1131 \\[help-command] lists all Octave abbrevs.  Any other key combination is
1132 executed normally.
1133 Note that all Octave mode abbrevs start with a grave accent."
1134   (interactive)
1135   (if (not abbrev-mode)
1136       (self-insert-command 1)
1137     (let (c)
1138       (insert last-command-event)
1139       (if (if (featurep 'xemacs)
1140               (or (eq (event-to-character (setq c (next-event))) ??)
1141                   (eq (event-to-character c) help-char))
1142             (or (eq (setq c (read-event)) ??)
1143                 (eq c help-char)))
1144           (let ((abbrev-table-name-list '(octave-abbrev-table)))
1145             (list-abbrevs))
1146         (setq unread-command-events (list c))))))
1147
1148 (define-skeleton octave-insert-defun
1149   "Insert an Octave function skeleton.
1150 Prompt for the function's name, arguments and return values (to be
1151 entered without parens)."
1152   (let* ((defname (substring (buffer-name) 0 -2))
1153          (name (read-string (format "Function name (default %s): " defname)
1154                             nil nil defname))
1155          (args (read-string "Arguments: "))
1156          (vals (read-string "Return values: ")))
1157     (format "%s%s (%s)"
1158             (cond
1159              ((string-equal vals "") vals)
1160              ((string-match "[ ,]" vals) (concat "[" vals "] = "))
1161              (t (concat vals " = ")))
1162             name
1163             args))
1164   \n "function " > str \n \n
1165   octave-block-comment-start "usage: " str \n
1166   octave-block-comment-start \n octave-block-comment-start
1167   \n _ \n
1168   "endfunction" > \n)
1169 \f
1170 ;;; Communication with the inferior Octave process
1171 (defun octave-kill-process ()
1172   "Kill inferior Octave process and its buffer."
1173   (interactive)
1174   (if inferior-octave-process
1175       (progn
1176         (process-send-string inferior-octave-process "quit;\n")
1177         (accept-process-output inferior-octave-process)))
1178   (if inferior-octave-buffer
1179       (kill-buffer inferior-octave-buffer)))
1180
1181 (defun octave-show-process-buffer ()
1182   "Make sure that `inferior-octave-buffer' is displayed."
1183   (interactive)
1184   (if (get-buffer inferior-octave-buffer)
1185       (display-buffer inferior-octave-buffer)
1186     (message "No buffer named %s" inferior-octave-buffer)))
1187
1188 (defun octave-hide-process-buffer ()
1189   "Delete all windows that display `inferior-octave-buffer'."
1190   (interactive)
1191   (if (get-buffer inferior-octave-buffer)
1192       (delete-windows-on inferior-octave-buffer)
1193     (message "No buffer named %s" inferior-octave-buffer)))
1194
1195 (defun octave-send-region (beg end)
1196   "Send current region to the inferior Octave process."
1197   (interactive "r")
1198   (inferior-octave t)
1199   (let ((proc inferior-octave-process)
1200         (string (buffer-substring-no-properties beg end))
1201         line)
1202     (with-current-buffer inferior-octave-buffer
1203       (setq inferior-octave-output-list nil)
1204       (while (not (string-equal string ""))
1205         (if (string-match "\n" string)
1206             (setq line (substring string 0 (match-beginning 0))
1207                   string (substring string (match-end 0)))
1208           (setq line string string ""))
1209         (setq inferior-octave-receive-in-progress t)
1210         (inferior-octave-send-list-and-digest (list (concat line "\n")))
1211         (while inferior-octave-receive-in-progress
1212           (accept-process-output proc))
1213         (insert-before-markers
1214          (mapconcat 'identity
1215                     (append
1216                      (if octave-send-echo-input (list line) (list ""))
1217                      (mapcar 'inferior-octave-strip-ctrl-g
1218                              inferior-octave-output-list)
1219                      (list inferior-octave-output-string))
1220                     "\n")))))
1221   (if octave-send-show-buffer
1222       (display-buffer inferior-octave-buffer)))
1223
1224 (defun octave-send-block ()
1225   "Send current Octave block to the inferior Octave process."
1226   (interactive)
1227   (save-excursion
1228     (octave-mark-block)
1229     (octave-send-region (point) (mark))))
1230
1231 (defun octave-send-defun ()
1232   "Send current Octave function to the inferior Octave process."
1233   (interactive)
1234   (save-excursion
1235     (mark-defun)
1236     (octave-send-region (point) (mark))))
1237
1238 (defun octave-send-line (&optional arg)
1239   "Send current Octave code line to the inferior Octave process.
1240 With positive prefix ARG, send that many lines.
1241 If `octave-send-line-auto-forward' is non-nil, go to the next unsent
1242 code line."
1243   (interactive "P")
1244   (or arg (setq arg 1))
1245   (if (> arg 0)
1246       (let (beg end)
1247         (beginning-of-line)
1248         (setq beg (point))
1249         (octave-next-code-line (- arg 1))
1250         (end-of-line)
1251         (setq end (point))
1252         (if octave-send-line-auto-forward
1253             (octave-next-code-line 1))
1254         (octave-send-region beg end))))
1255
1256 (defun octave-eval-print-last-sexp ()
1257   "Evaluate Octave sexp before point and print value into current buffer."
1258   (interactive)
1259   (inferior-octave t)
1260   (let ((standard-output (current-buffer))
1261         (print-escape-newlines nil)
1262         (opoint (point)))
1263     (terpri)
1264     (prin1
1265      (save-excursion
1266        (forward-sexp -1)
1267        (inferior-octave-send-list-and-digest
1268         (list (concat (buffer-substring-no-properties (point) opoint)
1269                       "\n")))
1270        (mapconcat 'identity inferior-octave-output-list "\n")))
1271     (terpri)))
1272 \f
1273 ;;; Bug reporting
1274 (defun octave-submit-bug-report ()
1275   "Submit a bug report on the Emacs Octave package via mail."
1276   (interactive)
1277   (require 'reporter)
1278   (and
1279    (y-or-n-p "Do you want to submit a bug report? ")
1280    (reporter-submit-bug-report
1281     octave-maintainer-address
1282     (concat "Emacs version " emacs-version)
1283     (list
1284      'octave-auto-indent
1285      'octave-auto-newline
1286      'octave-blink-matching-block
1287      'octave-block-offset
1288      'octave-comment-char
1289      'octave-continuation-offset
1290      'octave-continuation-string
1291      'octave-send-echo-input
1292      'octave-send-line-auto-forward
1293      'octave-send-show-buffer))))
1294
1295 ;; provide ourself
1296
1297 (provide 'octave-mod)
1298
1299 ;; arch-tag: 05f1ce09-be87-4c00-803e-4919ffa26c23
1300 ;;; octave-mod.el ends here