lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; This package supplies the string and regular-expression replace functions
  25 ;; documented in the Emacs user's manual.
  26
  27 ;;; Code:
  28
  29 (defcustom case-replace t
  30   "*Non-nil means query-replace should preserve case in replacements."
  31   :type 'boolean
  32   :group 'matching)
  33
  34 (defvar query-replace-history nil)
  35
  36 (defvar query-replace-interactive nil
  37   "Non-nil means `query-replace' uses the last search string.
  38 That becomes the \"string to replace\".")
  39
  40 (defun query-replace-read-args (string regexp-flag)
  41   (let (from to)
  42     (if query-replace-interactive
  43         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  44       (setq from (read-from-minibuffer (format "%s: " string)
  45                                        nil nil nil
  46                                        'query-replace-history)))
  47     (setq to (read-from-minibuffer (format "%s %s with: " string from)
  48                                    nil nil nil
  49                                    'query-replace-history))
  50     (list from to current-prefix-arg)))
  51
  52 (defun query-replace (from-string to-string &optional arg)
  53   "Replace some occurrences of FROM-STRING with TO-STRING.
  54 As each match is found, the user must type a character saying
  55 what to do with it.  For directions, type \\[help-command] at that time.
  56
  57 If `query-replace-interactive' is non-nil, the last incremental search
  58 string is used as FROM-STRING--you don't have to specify it with the
  59 minibuffer.
  60
  61 Preserves case in each replacement if `case-replace' and `case-fold-search'
  62 are non-nil and FROM-STRING has no uppercase letters.
  63 \(Preserving case means that if the string matched is all caps, or capitalized,
  64 then its replacement is upcased or capitalized.)
  65
  66 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  67 only matches surrounded by word boundaries.
  68
  69 To customize possible responses, change the \"bindings\" in `query-replace-map'."
  70   (interactive (query-replace-read-args "Query replace" nil))
  71   (perform-replace from-string to-string t nil arg))
  72 (define-key esc-map "%" 'query-replace)
  73
  74 (defun query-replace-regexp (regexp to-string &optional arg)
  75   "Replace some things after point matching REGEXP with TO-STRING.
  76 As each match is found, the user must type a character saying
  77 what to do with it.  For directions, type \\[help-command] at that time.
  78
  79 If `query-replace-interactive' is non-nil, the last incremental search
  80 regexp is used as REGEXP--you don't have to specify it with the
  81 minibuffer.
  82
  83 Preserves case in each replacement if `case-replace' and `case-fold-search'
  84 are non-nil and REGEXP has no uppercase letters.
  85 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  86 only matches surrounded by word boundaries.
  87 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
  88 and `\\=\\N' (where N is a digit) stands for
  89  whatever what matched the Nth `\\(...\\)' in REGEXP."
  90   (interactive (query-replace-read-args "Query replace regexp" t))
  91   (perform-replace regexp to-string t t arg))
  92
  93 (defun map-query-replace-regexp (regexp to-strings &optional arg)
  94   "Replace some matches for REGEXP with various strings, in rotation.
  95 The second argument TO-STRINGS contains the replacement strings, separated
  96 by spaces.  This command works like `query-replace-regexp' except
  97 that each successive replacement uses the next successive replacement string,
  98 wrapping around from the last such string to the first.
  99
 100 Non-interactively, TO-STRINGS may be a list of replacement strings.
 101
 102 If `query-replace-interactive' is non-nil, the last incremental search
 103 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 104
 105 A prefix argument N says to use each replacement string N times
 106 before rotating to the next."
 107   (interactive
 108    (let (from to)
 109      (setq from (if query-replace-interactive
 110                     (car regexp-search-ring)
 111                   (read-from-minibuffer "Map query replace (regexp): "
 112                                         nil nil nil
 113                                         'query-replace-history)))
 114      (setq to (read-from-minibuffer
 115                (format "Query replace %s with (space-separated strings): "
 116                        from)
 117                nil nil nil
 118                'query-replace-history))
 119      (list from to current-prefix-arg)))
 120   (let (replacements)
 121     (if (listp to-strings)
 122         (setq replacements to-strings)
 123       (while (/= (length to-strings) 0)
 124         (if (string-match " " to-strings)
 125             (setq replacements
 126                   (append replacements
 127                           (list (substring to-strings 0
 128                                            (string-match " " to-strings))))
 129                   to-strings (substring to-strings
 130                                        (1+ (string-match " " to-strings))))
 131           (setq replacements (append replacements (list to-strings))
 132                 to-strings ""))))
 133     (perform-replace regexp replacements t t nil arg)))
 134
 135 (defun replace-string (from-string to-string &optional delimited)
 136   "Replace occurrences of FROM-STRING with TO-STRING.
 137 Preserve case in each match if `case-replace' and `case-fold-search'
 138 are non-nil and FROM-STRING has no uppercase letters.
 139 \(Preserving case means that if the string matched is all caps, or capitalized,
 140 then its replacement is upcased or capitalized.)
 141
 142 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 143 only matches surrounded by word boundaries.
 144
 145 If `query-replace-interactive' is non-nil, the last incremental search
 146 string is used as FROM-STRING--you don't have to specify it with the
 147 minibuffer.
 148
 149 This function is usually the wrong thing to use in a Lisp program.
 150 What you probably want is a loop like this:
 151   (while (search-forward FROM-STRING nil t)
 152     (replace-match TO-STRING nil t))
 153 which will run faster and will not set the mark or print anything.
 154 \(You may need a more complex loop if FROM-STRING can match the null string
 155 and TO-STRING is also null.)"
 156   (interactive (query-replace-read-args "Replace string" nil))
 157   (perform-replace from-string to-string nil nil delimited))
 158
 159 (defun replace-regexp (regexp to-string &optional delimited)
 160   "Replace things after point matching REGEXP with TO-STRING.
 161 Preserve case in each match if `case-replace' and `case-fold-search'
 162 are non-nil and REGEXP has no uppercase letters.
 163 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 164 only matches surrounded by word boundaries.
 165 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 166 and `\\=\\N' (where N is a digit) stands for
 167  whatever what matched the Nth `\\(...\\)' in REGEXP.
 168
 169 If `query-replace-interactive' is non-nil, the last incremental search
 170 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 171
 172 This function is usually the wrong thing to use in a Lisp program.
 173 What you probably want is a loop like this:
 174   (while (re-search-forward REGEXP nil t)
 175     (replace-match TO-STRING nil nil))
 176 which will run faster and will not set the mark or print anything."
 177   (interactive (query-replace-read-args "Replace regexp" t))
 178   (perform-replace regexp to-string nil t delimited))
 179 \f
 180 (defvar regexp-history nil
 181   "History list for some commands that read regular expressions.")
 182
 183 (defalias 'delete-non-matching-lines 'keep-lines)
 184 (defun keep-lines (regexp)
 185   "Delete all lines except those containing matches for REGEXP.
 186 A match split across lines preserves all the lines it lies in.
 187 Applies to all lines after point."
 188   (interactive (list (read-from-minibuffer
 189                       "Keep lines (containing match for regexp): "
 190                       nil nil nil 'regexp-history)))
 191   (save-excursion
 192     (or (bolp) (forward-line 1))
 193     (let ((start (point)))
 194       (while (not (eobp))
 195         ;; Start is first char not preserved by previous match.
 196         (if (not (re-search-forward regexp nil 'move))
 197             (delete-region start (point-max))
 198           (let ((end (save-excursion (goto-char (match-beginning 0))
 199                                      (beginning-of-line)
 200                                      (point))))
 201             ;; Now end is first char preserved by the new match.
 202             (if (< start end)
 203                 (delete-region start end))))
 204         (setq start (save-excursion (forward-line 1)
 205                                     (point)))
 206         ;; If the match was empty, avoid matching again at same place.
 207         (and (not (eobp)) (= (match-beginning 0) (match-end 0))
 208              (forward-char 1))))))
 209
 210 (defalias 'delete-matching-lines 'flush-lines)
 211 (defun flush-lines (regexp)
 212   "Delete lines containing matches for REGEXP.
 213 If a match is split across lines, all the lines it lies in are deleted.
 214 Applies to lines after point."
 215   (interactive (list (read-from-minibuffer
 216                       "Flush lines (containing match for regexp): "
 217                       nil nil nil 'regexp-history)))
 218   (save-excursion
 219     (while (and (not (eobp))
 220                 (re-search-forward regexp nil t))
 221       (delete-region (save-excursion (goto-char (match-beginning 0))
 222                                      (beginning-of-line)
 223                                      (point))
 224                      (progn (forward-line 1) (point))))))
 225
 226 (defalias 'count-matches 'how-many)
 227 (defun how-many (regexp)
 228   "Print number of matches for REGEXP following point."
 229   (interactive (list (read-from-minibuffer
 230                       "How many matches for (regexp): "
 231                       nil nil nil 'regexp-history)))
 232   (let ((count 0) opoint)
 233     (save-excursion
 234      (while (and (not (eobp))
 235                  (progn (setq opoint (point))
 236                         (re-search-forward regexp nil t)))
 237        (if (= opoint (point))
 238            (forward-char 1)
 239          (setq count (1+ count))))
 240      (message "%d occurrences" count))))
 241 \f
 242 (defvar occur-mode-map ())
 243 (if occur-mode-map
 244     ()
 245   (setq occur-mode-map (make-sparse-keymap))
 246   (define-key occur-mode-map [mouse-2] 'occur-mode-mouse-goto)
 247   (define-key occur-mode-map "\C-c\C-c" 'occur-mode-goto-occurrence)
 248   (define-key occur-mode-map "\C-m" 'occur-mode-goto-occurrence)
 249   (define-key occur-mode-map "g" 'revert-buffer))
 250
 251 (defvar occur-buffer nil)
 252 (defvar occur-nlines nil)
 253 (defvar occur-pos-list nil)
 254 (defvar occur-command-arguments nil
 255   "Arguments that were given to `occur' when it made this buffer.")
 256
 257 (put 'occur-mode 'mode-class 'special)
 258
 259 (defun occur-mode ()
 260   "Major mode for output from \\[occur].
 261 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 262 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 263 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 264
 265 \\{occur-mode-map}"
 266   (kill-all-local-variables)
 267   (use-local-map occur-mode-map)
 268   (setq major-mode 'occur-mode)
 269   (setq mode-name "Occur")
 270   (make-local-variable 'revert-buffer-function)
 271   (setq revert-buffer-function 'occur-revert-function)
 272   (make-local-variable 'occur-buffer)
 273   (make-local-variable 'occur-nlines)
 274   (make-local-variable 'occur-pos-list)
 275   (make-local-variable 'occur-command-arguments)
 276   (run-hooks 'occur-mode-hook))
 277
 278 ;; Handle revert-buffer for *Occur* buffers.
 279 (defun occur-revert-function (ignore1 ignore2)
 280   (let ((args occur-command-arguments ))
 281     (save-excursion
 282       (set-buffer occur-buffer)
 283       (apply 'occur args))))
 284
 285 (defun occur-mode-mouse-goto (event)
 286   "In Occur mode, go to the occurrence whose line you click on."
 287   (interactive "e")
 288   (let (buffer pos)
 289     (save-excursion
 290       (set-buffer (window-buffer (posn-window (event-end event))))
 291       (save-excursion
 292         (goto-char (posn-point (event-end event)))
 293         (setq pos (occur-mode-find-occurrence))
 294         (setq buffer occur-buffer)))
 295     (pop-to-buffer buffer)
 296     (goto-char (marker-position pos))))
 297
 298 (defun occur-mode-find-occurrence ()
 299   (if (or (null occur-buffer)
 300           (null (buffer-name occur-buffer)))
 301       (progn
 302         (setq occur-buffer nil
 303               occur-pos-list nil)
 304         (error "Buffer in which occurrences were found is deleted")))
 305   (let* ((line-count
 306           (count-lines (point-min)
 307                        (save-excursion
 308                          (beginning-of-line)
 309                          (point))))
 310          (occur-number (save-excursion
 311                          (beginning-of-line)
 312                          (/ (1- line-count)
 313                             (cond ((< occur-nlines 0)
 314                                    (- 2 occur-nlines))
 315                                   ((> occur-nlines 0)
 316                                    (+ 2 (* 2 occur-nlines)))
 317                                   (t 1)))))
 318          (pos (nth occur-number occur-pos-list)))
 319     (if (< line-count 1)
 320         (error "No occurrence on this line"))
 321     (or pos
 322         (error "No occurrence on this line"))
 323     pos))
 324
 325 (defun occur-mode-goto-occurrence ()
 326   "Go to the occurrence the current line describes."
 327   (interactive)
 328   (let ((pos (occur-mode-find-occurrence)))
 329     (pop-to-buffer occur-buffer)
 330     (goto-char (marker-position pos))))
 331 \f
 332 (defcustom list-matching-lines-default-context-lines 0
 333   "*Default number of context lines to include around a `list-matching-lines'
 334 match.  A negative number means to include that many lines before the match.
 335 A positive number means to include that many lines both before and after."
 336   :type 'integer
 337   :group 'matching)
 338
 339 (defalias 'list-matching-lines 'occur)
 340
 341 (defvar list-matching-lines-face 'bold
 342   "*Face used by M-x list-matching-lines to show the text that matches.
 343 If the value is nil, don't highlight the matching portions specially.")
 344
 345 (defun occur (regexp &optional nlines)
 346   "Show all lines in the current buffer containing a match for REGEXP.
 347
 348 If a match spreads across multiple lines, all those lines are shown.
 349
 350 Each line is displayed with NLINES lines before and after, or -NLINES
 351 before if NLINES is negative.
 352 NLINES defaults to `list-matching-lines-default-context-lines'.
 353 Interactively it is the prefix arg.
 354
 355 The lines are shown in a buffer named `*Occur*'.
 356 It serves as a menu to find any of the occurrences in this buffer.
 357 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 358
 359 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 360 the matching is case-sensitive."
 361   (interactive
 362    (list (let* ((default (car regexp-history))
 363                 (input
 364                  (read-from-minibuffer
 365                   (if default
 366                       (format "List lines matching regexp (default `%s'): "
 367                               default)
 368                     "List lines matching regexp: ")
 369                   nil nil nil 'regexp-history)))
 370            (if (string-equal input "")
 371                default
 372              (set-text-properties 0 (length input) nil input)
 373              input))
 374          current-prefix-arg))
 375   (let ((nlines (if nlines
 376                     (prefix-numeric-value nlines)
 377                   list-matching-lines-default-context-lines))
 378         (first t)
 379         (buffer (current-buffer))
 380         (dir default-directory)
 381         (linenum 1)
 382         (prevpos (point-min))
 383         (case-fold-search  (and case-fold-search
 384                                 (isearch-no-upper-case-p regexp t)))
 385         (final-context-start (make-marker)))
 386 ;;;     (save-excursion
 387 ;;;       (beginning-of-line)
 388 ;;;       (setq linenum (1+ (count-lines (point-min) (point))))
 389 ;;;       (setq prevpos (point)))
 390     (save-excursion
 391       (goto-char (point-min))
 392       ;; Check first whether there are any matches at all.
 393       (if (not (re-search-forward regexp nil t))
 394           (message "No matches for `%s'" regexp)
 395         ;; Back up, so the search loop below will find the first match.
 396         (goto-char (match-beginning 0))
 397         (with-output-to-temp-buffer "*Occur*"
 398           (save-excursion
 399             (set-buffer standard-output)
 400             (setq default-directory dir)
 401             ;; We will insert the number of lines, and "lines", later.
 402             (insert " matching ")
 403             (let ((print-escape-newlines t))
 404               (prin1 regexp))
 405             (insert " in buffer " (buffer-name buffer) ?. ?\n)
 406             (occur-mode)
 407             (setq occur-buffer buffer)
 408             (setq occur-nlines nlines)
 409             (setq occur-pos-list ())
 410             (setq occur-command-arguments
 411                   (list regexp nlines)))
 412           (if (eq buffer standard-output)
 413               (goto-char (point-max)))
 414           (save-excursion
 415             ;; Find next match, but give up if prev match was at end of buffer.
 416             (while (and (not (= prevpos (point-max)))
 417                         (re-search-forward regexp nil t))
 418               (goto-char (match-beginning 0))
 419               (beginning-of-line)
 420               (save-match-data
 421                 (setq linenum (+ linenum (count-lines prevpos (point)))))
 422               (setq prevpos (point))
 423               (goto-char (match-end 0))
 424               (let* ((start (save-excursion
 425                               (goto-char (match-beginning 0))
 426                               (forward-line (if (< nlines 0) nlines (- nlines)))
 427                               (point)))
 428                      (end (save-excursion
 429                             (goto-char (match-end 0))
 430                             (if (> nlines 0)
 431                                 (forward-line (1+ nlines))
 432                                 (forward-line 1))
 433                             (point)))
 434                      ;; Record where the actual match
 435                      (match-offset
 436                       (save-excursion
 437                         (goto-char (match-beginning 0))
 438                         (beginning-of-line)
 439                         ;; +6 to skip over line number
 440                         (+ 6 (- (match-beginning 0) (point)))))
 441                      (match-len (- (match-end 0) (match-beginning 0)))
 442                      (tag (format "%5d" linenum))
 443                      (empty (make-string (length tag) ?\ ))
 444                      tem)
 445                 (save-excursion
 446                   (setq tem (make-marker))
 447                   (set-marker tem (point))
 448                   (set-buffer standard-output)
 449                   (setq occur-pos-list (cons tem occur-pos-list))
 450                   (or first (zerop nlines)
 451                       (insert "--------\n"))
 452                   (setq first nil)
 453                   (insert-buffer-substring buffer start end)
 454                   (set-marker final-context-start
 455                               (- (point) (- end (match-end 0))))
 456                   (goto-char (- (point) (- end start)))
 457                   (setq tem nlines)
 458                   (while (> tem 0)
 459                     (insert empty ?:)
 460                     (forward-line 1)
 461                     (setq tem (1- tem)))
 462                   (let ((this-linenum linenum)
 463                         line-start)
 464                     (while (< (point) final-context-start)
 465                       (if (null tag)
 466                           (setq tag (format "%5d" this-linenum)))
 467                       (insert tag ?:)
 468                       (setq line-start
 469                             (save-excursion
 470                               (beginning-of-line)
 471                               (point)))
 472                       (put-text-property line-start
 473                                          (save-excursion
 474                                            (end-of-line)
 475                                            (point))
 476                                          'mouse-face 'highlight)
 477                       (if list-matching-lines-face
 478                           (put-text-property
 479                            (+ line-start match-offset)
 480                            (+ line-start match-offset match-len)
 481                            'face list-matching-lines-face))
 482                       (forward-line 1)
 483                       (setq tag nil)
 484                       (setq this-linenum (1+ this-linenum)))
 485                     (while (<= (point) final-context-start)
 486                       (insert empty ?:)
 487                       (forward-line 1)
 488                       (setq this-linenum (1+ this-linenum))))
 489                   (while (< tem nlines)
 490                     (insert empty ?:)
 491                     (forward-line 1)
 492                     (setq tem (1+ tem)))
 493                   (goto-char (point-max)))
 494                 (forward-line 1)))
 495             (set-buffer standard-output)
 496             ;; Put positions in increasing order to go with buffer.
 497             (setq occur-pos-list (nreverse occur-pos-list))
 498             (goto-char (point-min))
 499             (let ((message-string
 500                    (if (= (length occur-pos-list) 1)
 501                        "1 line"
 502                      (format "%d lines" (length occur-pos-list)))))
 503               (insert message-string)
 504               (if (interactive-p)
 505                   (message "%s matched" message-string)))))))))
 506 \f
 507 ;; It would be nice to use \\[...], but there is no reasonable way
 508 ;; to make that display both SPC and Y.
 509 (defconst query-replace-help
 510   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 511 RET or `q' to exit, Period to replace one match and exit,
 512 Comma to replace but not move point immediately,
 513 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 514 C-w to delete match and recursive edit,
 515 C-l to clear the screen, redisplay, and offer same replacement again,
 516 ! to replace all remaining matches with no more questions,
 517 ^ to move point back to previous match."
 518   "Help message while in query-replace")
 519
 520 (defvar query-replace-map (make-sparse-keymap)
 521   "Keymap that defines the responses to questions in `query-replace'.
 522 The \"bindings\" in this map are not commands; they are answers.
 523 The valid answers include `act', `skip', `act-and-show',
 524 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 525 `automatic', `backup', `exit-prefix', and `help'.")
 526
 527 (define-key query-replace-map " " 'act)
 528 (define-key query-replace-map "\d" 'skip)
 529 (define-key query-replace-map [delete] 'skip)
 530 (define-key query-replace-map [backspace] 'skip)
 531 (define-key query-replace-map "y" 'act)
 532 (define-key query-replace-map "n" 'skip)
 533 (define-key query-replace-map "Y" 'act)
 534 (define-key query-replace-map "N" 'skip)
 535 (define-key query-replace-map "," 'act-and-show)
 536 (define-key query-replace-map "q" 'exit)
 537 (define-key query-replace-map "\r" 'exit)
 538 (define-key query-replace-map [return] 'exit)
 539 (define-key query-replace-map "." 'act-and-exit)
 540 (define-key query-replace-map "\C-r" 'edit)
 541 (define-key query-replace-map "\C-w" 'delete-and-edit)
 542 (define-key query-replace-map "\C-l" 'recenter)
 543 (define-key query-replace-map "!" 'automatic)
 544 (define-key query-replace-map "^" 'backup)
 545 (define-key query-replace-map "\C-h" 'help)
 546 (define-key query-replace-map [f1] 'help)
 547 (define-key query-replace-map [help] 'help)
 548 (define-key query-replace-map "?" 'help)
 549 (define-key query-replace-map "\C-g" 'quit)
 550 (define-key query-replace-map "\C-]" 'quit)
 551 (define-key query-replace-map "\e" 'exit-prefix)
 552 (define-key query-replace-map [escape] 'exit-prefix)
 553
 554 (defun perform-replace (from-string replacements
 555                         query-flag regexp-flag delimited-flag
 556                         &optional repeat-count map)
 557   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
 558 Don't use this in your own program unless you want to query and set the mark
 559 just as `query-replace' does.  Instead, write a simple loop like this:
 560   (while (re-search-forward \"foo[ \t]+bar\" nil t)
 561     (replace-match \"foobar\" nil nil))
 562 which will run faster and probably do exactly what you want."
 563   (or map (setq map query-replace-map))
 564   (and query-flag minibuffer-auto-raise
 565        (raise-frame (window-frame (minibuffer-window))))
 566   (let ((nocasify (not (and case-fold-search case-replace
 567                             (string-equal from-string
 568                                           (downcase from-string)))))
 569         (literal (not regexp-flag))
 570         (search-function (if regexp-flag 're-search-forward 'search-forward))
 571         (search-string from-string)
 572         (real-match-data nil)           ; the match data for the current match
 573         (next-replacement nil)
 574         (replacement-index 0)
 575         (keep-going t)
 576         (stack nil)
 577         (next-rotate-count 0)
 578         (replace-count 0)
 579         (lastrepl nil)                  ;Position after last match considered.
 580         (match-again t)
 581         (message
 582          (if query-flag
 583              (substitute-command-keys
 584               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
 585     (if (stringp replacements)
 586         (setq next-replacement replacements)
 587       (or repeat-count (setq repeat-count 1)))
 588     (if delimited-flag
 589         (setq search-function 're-search-forward
 590               search-string (concat "\\b"
 591                                     (if regexp-flag from-string
 592                                       (regexp-quote from-string))
 593                                     "\\b")))
 594     (push-mark)
 595     (undo-boundary)
 596     (unwind-protect
 597         ;; Loop finding occurrences that perhaps should be replaced.
 598         (while (and keep-going
 599                     (not (eobp))
 600                     (funcall search-function search-string nil t)
 601                     ;; If the search string matches immediately after
 602                     ;; the previous match, but it did not match there
 603                     ;; before the replacement was done, ignore the match.
 604                     (if (or (eq lastrepl (point))
 605                             (and regexp-flag
 606                                  (eq lastrepl (match-beginning 0))
 607                                  (not match-again)))
 608                         (if (eobp)
 609                             nil
 610                           ;; Don't replace the null string
 611                           ;; right after end of previous replacement.
 612                           (forward-char 1)
 613                           (funcall search-function search-string nil t))
 614                       t))
 615
 616           ;; Save the data associated with the real match.
 617           ;; For speed, use only integers and reuse the list used last time.
 618           (setq real-match-data (match-data t real-match-data))
 619
 620           ;; Before we make the replacement, decide whether the search string
 621           ;; can match again just after this match.
 622           (if regexp-flag
 623               (setq match-again (looking-at search-string)))
 624           ;; If time for a change, advance to next replacement string.
 625           (if (and (listp replacements)
 626                    (= next-rotate-count replace-count))
 627               (progn
 628                 (setq next-rotate-count
 629                       (+ next-rotate-count repeat-count))
 630                 (setq next-replacement (nth replacement-index replacements))
 631                 (setq replacement-index (% (1+ replacement-index) (length replacements)))))
 632           (if (not query-flag)
 633               (progn
 634                 (store-match-data real-match-data)
 635                 (replace-match next-replacement nocasify literal)
 636                 (setq replace-count (1+ replace-count)))
 637             (undo-boundary)
 638             (let (done replaced key def)
 639               ;; Loop reading commands until one of them sets done,
 640               ;; which means it has finished handling this occurrence.
 641               (while (not done)
 642                 (store-match-data real-match-data)
 643                 (replace-highlight (match-beginning 0) (match-end 0))
 644                 ;; Bind message-log-max so we don't fill up the message log
 645                 ;; with a bunch of identical messages.
 646                 (let ((message-log-max nil))
 647                   (message message from-string next-replacement))
 648                 (setq key (read-event))
 649                 (setq key (vector key))
 650                 (setq def (lookup-key map key))
 651                 ;; Restore the match data while we process the command.
 652                 (cond ((eq def 'help)
 653                        (with-output-to-temp-buffer "*Help*"
 654                          (princ
 655                           (concat "Query replacing "
 656                                   (if regexp-flag "regexp " "")
 657                                   from-string " with "
 658                                   next-replacement ".\n\n"
 659                                   (substitute-command-keys
 660                                    query-replace-help)))
 661                          (save-excursion
 662                            (set-buffer standard-output)
 663                            (help-mode))))
 664                       ((eq def 'exit)
 665                        (setq keep-going nil)
 666                        (setq done t))
 667                       ((eq def 'backup)
 668                        (if stack
 669                            (let ((elt (car stack)))
 670                              (goto-char (car elt))
 671                              (setq replaced (eq t (cdr elt)))
 672                              (or replaced
 673                                  (store-match-data (cdr elt)))
 674                              (setq stack (cdr stack)))
 675                          (message "No previous match")
 676                          (ding 'no-terminate)
 677                          (sit-for 1)))
 678                       ((eq def 'act)
 679                        (or replaced
 680                            (progn
 681                              (replace-match next-replacement nocasify literal)
 682                              (setq replace-count (1+ replace-count))))
 683                        (setq done t replaced t))
 684                       ((eq def 'act-and-exit)
 685                        (or replaced
 686                            (progn
 687                              (replace-match next-replacement nocasify literal)
 688                              (setq replace-count (1+ replace-count))))
 689                        (setq keep-going nil)
 690                        (setq done t replaced t))
 691                       ((eq def 'act-and-show)
 692                        (if (not replaced)
 693                            (progn
 694                              (replace-match next-replacement nocasify literal)
 695                              (setq replace-count (1+ replace-count))
 696                              (setq replaced t))))
 697                       ((eq def 'automatic)
 698                        (or replaced
 699                            (progn
 700                              (replace-match next-replacement nocasify literal)
 701                              (setq replace-count (1+ replace-count))))
 702                        (setq done t query-flag nil replaced t))
 703                       ((eq def 'skip)
 704                        (setq done t))
 705                       ((eq def 'recenter)
 706                        (recenter nil))
 707                       ((eq def 'edit)
 708                        (store-match-data
 709                         (prog1 (match-data)
 710                           (save-excursion (recursive-edit))))
 711                        ;; Before we make the replacement,
 712                        ;; decide whether the search string
 713                        ;; can match again just after this match.
 714                        (if regexp-flag
 715                            (setq match-again (looking-at search-string))))
 716                       ((eq def 'delete-and-edit)
 717                        (delete-region (match-beginning 0) (match-end 0))
 718                        (store-match-data
 719                         (prog1 (match-data)
 720                           (save-excursion (recursive-edit))))
 721                        (setq replaced t))
 722                       ;; Note: we do not need to treat `exit-prefix'
 723                       ;; specially here, since we reread
 724                       ;; any unrecognized character.
 725                       (t
 726                        (setq this-command 'mode-exited)
 727                        (setq keep-going nil)
 728                        (setq unread-command-events
 729                              (append (listify-key-sequence key)
 730                                      unread-command-events))
 731                        (setq done t))))
 732               ;; Record previous position for ^ when we move on.
 733               ;; Change markers to numbers in the match data
 734               ;; since lots of markers slow down editing.
 735               (setq stack
 736                     (cons (cons (point)
 737                                 (or replaced (match-data t)))
 738                           stack))))
 739           (setq lastrepl (point)))
 740       (replace-dehighlight))
 741     (or unread-command-events
 742         (message "Replaced %d occurrence%s"
 743                  replace-count
 744                  (if (= replace-count 1) "" "s")))
 745     (and keep-going stack)))
 746
 747 (defcustom query-replace-highlight nil
 748   "*Non-nil means to highlight words during query replacement."
 749   :type 'boolean
 750   :group 'matching)
 751
 752 (defvar replace-overlay nil)
 753
 754 (defun replace-dehighlight ()
 755   (and replace-overlay
 756        (progn
 757          (delete-overlay replace-overlay)
 758          (setq replace-overlay nil))))
 759
 760 (defun replace-highlight (start end)
 761   (and query-replace-highlight
 762        (progn
 763          (or replace-overlay
 764              (progn
 765                (setq replace-overlay (make-overlay start end))
 766                (overlay-put replace-overlay 'face
 767                             (if (internal-find-face 'query-replace)
 768                                 'query-replace 'region))))
 769          (move-overlay replace-overlay start end (current-buffer)))))
 770
 771 ;;; replace.el ends here