lisp/vc-hooks.el

   1 ;;; vc-hooks.el --- resident support for version-control
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author:     FSF (see vc.el for full credits)
   7 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; $Id$
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This is the always-loaded portion of VC.  It takes care of
  31 ;; VC-related activities that are done when you visit a file, so that
  32 ;; vc.el itself is loaded only when you use a VC command.  See the
  33 ;; commentary of vc.el.
  34
  35 ;;; Code:
  36
  37 (eval-when-compile
  38   (require 'cl))
  39
  40 ;; Customization Variables (the rest is in vc.el)
  41
  42 (defvar vc-ignore-vc-files nil)
  43 (make-obsolete-variable 'vc-ignore-vc-files
  44                         "set `vc-handled-backends' to nil to disable VC.")
  45
  46 (defvar vc-master-templates ())
  47 (make-obsolete-variable 'vc-master-templates
  48  "to define master templates for a given BACKEND, use
  49 vc-BACKEND-master-templates.  To enable or disable VC for a given
  50 BACKEND, use `vc-handled-backends'.")
  51
  52 (defvar vc-header-alist ())
  53 (make-obsolete-variable 'vc-header-alist 'vc-BACKEND-header)
  54
  55 (defcustom vc-ignore-dir-regexp
  56   ;; Stop SMB, automounter, AFS, and DFS host lookups.
  57   "\\`\\(?:[\\/][\\/]\\|/\\(?:net\\|afs\\|\\.\\\.\\.\\)/\\)\\'"
  58   "Regexp matching directory names that are not under VC's control.
  59 The default regexp prevents fruitless and time-consuming attempts
  60 to determine the VC status in directories in which filenames are
  61 interpreted as hostnames."
  62   :type 'regexp
  63   :group 'vc)
  64
  65 (defcustom vc-handled-backends '(RCS CVS SVN SCCS Bzr Git Hg Arch MCVS)
  66   ;; Bzr, Git, Hg, Arch and MCVS come last because they are per-tree
  67   ;; rather than per-dir.
  68   "*List of version control backends for which VC will be used.
  69 Entries in this list will be tried in order to determine whether a
  70 file is under that sort of version control.
  71 Removing an entry from the list prevents VC from being activated
  72 when visiting a file managed by that backend.
  73 An empty list disables VC altogether."
  74   :type '(repeat symbol)
  75   :version "22.2"
  76   :group 'vc)
  77
  78 (defcustom vc-path
  79   (if (file-directory-p "/usr/sccs")
  80       '("/usr/sccs")
  81     nil)
  82   "*List of extra directories to search for version control commands."
  83   :type '(repeat directory)
  84   :group 'vc)
  85
  86 (defcustom vc-make-backup-files nil
  87   "*If non-nil, backups of registered files are made as with other files.
  88 If nil (the default), files covered by version control don't get backups."
  89   :type 'boolean
  90   :group 'vc
  91   :group 'backup)
  92
  93 (defcustom vc-follow-symlinks 'ask
  94   "*What to do if visiting a symbolic link to a file under version control.
  95 Editing such a file through the link bypasses the version control system,
  96 which is dangerous and probably not what you want.
  97
  98 If this variable is t, VC follows the link and visits the real file,
  99 telling you about it in the echo area.  If it is `ask', VC asks for
 100 confirmation whether it should follow the link.  If nil, the link is
 101 visited and a warning displayed."
 102   :type '(choice (const :tag "Ask for confirmation" ask)
 103                  (const :tag "Visit link and warn" nil)
 104                  (const :tag "Follow link" t))
 105   :group 'vc)
 106
 107 (defcustom vc-display-status t
 108   "*If non-nil, display revision number and lock status in modeline.
 109 Otherwise, not displayed."
 110   :type 'boolean
 111   :group 'vc)
 112
 113
 114 (defcustom vc-consult-headers t
 115   "*If non-nil, identify work files by searching for version headers."
 116   :type 'boolean
 117   :group 'vc)
 118
 119 (defcustom vc-keep-workfiles t
 120   "*If non-nil, don't delete working files after registering changes.
 121 If the back-end is CVS, workfiles are always kept, regardless of the
 122 value of this flag."
 123   :type 'boolean
 124   :group 'vc)
 125
 126 (defcustom vc-mistrust-permissions nil
 127   "*If non-nil, don't assume permissions/ownership track version-control status.
 128 If nil, do rely on the permissions.
 129 See also variable `vc-consult-headers'."
 130   :type 'boolean
 131   :group 'vc)
 132
 133 (defun vc-mistrust-permissions (file)
 134   "Internal access function to variable `vc-mistrust-permissions' for FILE."
 135   (or (eq vc-mistrust-permissions 't)
 136       (and vc-mistrust-permissions
 137            (funcall vc-mistrust-permissions
 138                     (vc-backend-subdirectory-name file)))))
 139
 140 (defcustom vc-stay-local t
 141   "*Non-nil means use local operations when possible for remote repositories.
 142 This avoids slow queries over the network and instead uses heuristics
 143 and past information to determine the current status of a file.
 144
 145 The value can also be a regular expression or list of regular
 146 expressions to match against the host name of a repository; then VC
 147 only stays local for hosts that match it.  Alternatively, the value
 148 can be a list of regular expressions where the first element is the
 149 symbol `except'; then VC always stays local except for hosts matched
 150 by these regular expressions."
 151   :type '(choice (const :tag "Always stay local" t)
 152           (const :tag "Don't stay local" nil)
 153           (list :format "\nExamine hostname and %v" :tag "Examine hostname ..."
 154                 (set :format "%v" :inline t (const :format "%t" :tag "don't" except))
 155                 (regexp :format " stay local,\n%t: %v" :tag "if it matches")
 156                 (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 157   :version "22.1"
 158   :group 'vc)
 159
 160 (defun vc-stay-local-p (file)
 161   "Return non-nil if VC should stay local when handling FILE.
 162 This uses the `repository-hostname' backend operation."
 163   (let* ((backend (vc-backend file))
 164          (sym (vc-make-backend-sym backend 'stay-local))
 165          (stay-local (if (boundp sym) (symbol-value sym) t)))
 166     (if (eq stay-local t) (setq stay-local vc-stay-local))
 167     (if (symbolp stay-local) stay-local
 168       (let ((dirname (if (file-directory-p file)
 169                          (directory-file-name file)
 170                        (file-name-directory file))))
 171         (eq 'yes
 172             (or (vc-file-getprop dirname 'vc-stay-local-p)
 173                 (vc-file-setprop
 174                  dirname 'vc-stay-local-p
 175                  (let ((hostname (vc-call-backend
 176                                   backend 'repository-hostname dirname)))
 177                    (if (not hostname)
 178                        'no
 179                      (let ((default t))
 180                        (if (eq (car-safe stay-local) 'except)
 181                            (setq default nil stay-local (cdr stay-local)))
 182                        (when (consp stay-local)
 183                          (setq stay-local
 184                                (mapconcat 'identity stay-local "\\|")))
 185                        (if (if (string-match stay-local hostname)
 186                                default (not default))
 187                            'yes 'no)))))))))))
 188
 189 ;;; This is handled specially now.
 190 ;; Tell Emacs about this new kind of minor mode
 191 ;; (add-to-list 'minor-mode-alist '(vc-mode vc-mode))
 192
 193 (make-variable-buffer-local 'vc-mode)
 194 (put 'vc-mode 'permanent-local t)
 195
 196 (defun vc-mode (&optional arg)
 197   ;; Dummy function for C-h m
 198   "Version Control minor mode.
 199 This minor mode is automatically activated whenever you visit a file under
 200 control of one of the revision control systems in `vc-handled-backends'.
 201 VC commands are globally reachable under the prefix `\\[vc-prefix-map]':
 202 \\{vc-prefix-map}")
 203
 204 (defmacro vc-error-occurred (&rest body)
 205   `(condition-case nil (progn ,@body nil) (error t)))
 206
 207 ;; We need a notion of per-file properties because the version
 208 ;; control state of a file is expensive to derive --- we compute
 209 ;; them when the file is initially found, keep them up to date
 210 ;; during any subsequent VC operations, and forget them when
 211 ;; the buffer is killed.
 212
 213 (defvar vc-file-prop-obarray (make-vector 17 0)
 214   "Obarray for per-file properties.")
 215
 216 (defvar vc-touched-properties nil)
 217
 218 (defun vc-file-setprop (file property value)
 219   "Set per-file VC PROPERTY for FILE to VALUE."
 220   (if (and vc-touched-properties
 221            (not (memq property vc-touched-properties)))
 222       (setq vc-touched-properties (append (list property)
 223                                           vc-touched-properties)))
 224   (put (intern file vc-file-prop-obarray) property value))
 225
 226 (defun vc-file-getprop (file property)
 227   "Get per-file VC PROPERTY for FILE."
 228   (get (intern file vc-file-prop-obarray) property))
 229
 230 (defun vc-file-clearprops (file)
 231   "Clear all VC properties of FILE."
 232   (setplist (intern file vc-file-prop-obarray) nil))
 233
 234 \f
 235 ;; We keep properties on each symbol naming a backend as follows:
 236 ;;  * `vc-functions': an alist mapping vc-FUNCTION to vc-BACKEND-FUNCTION.
 237
 238 (defun vc-make-backend-sym (backend sym)
 239   "Return BACKEND-specific version of VC symbol SYM."
 240   (intern (concat "vc-" (downcase (symbol-name backend))
 241                   "-" (symbol-name sym))))
 242
 243 (defun vc-find-backend-function (backend fun)
 244   "Return BACKEND-specific implementation of FUN.
 245 If there is no such implementation, return the default implementation;
 246 if that doesn't exist either, return nil."
 247   (let ((f (vc-make-backend-sym backend fun)))
 248     (if (fboundp f) f
 249       ;; Load vc-BACKEND.el if needed.
 250       (require (intern (concat "vc-" (downcase (symbol-name backend)))))
 251       (if (fboundp f) f
 252         (let ((def (vc-make-backend-sym 'default fun)))
 253           (if (fboundp def) (cons def backend) nil))))))
 254
 255 (defun vc-call-backend (backend function-name &rest args)
 256   "Call for BACKEND the implementation of FUNCTION-NAME with the given ARGS.
 257 Calls
 258
 259     (apply 'vc-BACKEND-FUN ARGS)
 260
 261 if vc-BACKEND-FUN exists (after trying to find it in vc-BACKEND.el)
 262 and else calls
 263
 264     (apply 'vc-default-FUN BACKEND ARGS)
 265
 266 It is usually called via the `vc-call' macro."
 267   (let ((f (assoc function-name (get backend 'vc-functions))))
 268     (if f (setq f (cdr f))
 269       (setq f (vc-find-backend-function backend function-name))
 270       (push (cons function-name f) (get backend 'vc-functions)))
 271     (cond
 272      ((null f)
 273       (error "Sorry, %s is not implemented for %s" function-name backend))
 274      ((consp f) (apply (car f) (cdr f) args))
 275      (t         (apply f args)))))
 276
 277 (defmacro vc-call (fun file &rest args)
 278   ;; BEWARE!! `file' is evaluated twice!!
 279   `(vc-call-backend (vc-backend ,file) ',fun ,file ,@args))
 280 \f
 281 (defsubst vc-parse-buffer (pattern i)
 282   "Find PATTERN in the current buffer and return its Ith submatch."
 283   (goto-char (point-min))
 284   (if (re-search-forward pattern nil t)
 285       (match-string i)))
 286
 287 (defun vc-insert-file (file &optional limit blocksize)
 288   "Insert the contents of FILE into the current buffer.
 289
 290 Optional argument LIMIT is a regexp.  If present, the file is inserted
 291 in chunks of size BLOCKSIZE (default 8 kByte), until the first
 292 occurrence of LIMIT is found.  Anything from the start of that occurrence
 293 to the end of the buffer is then deleted.  The function returns
 294 non-nil if FILE exists and its contents were successfully inserted."
 295   (erase-buffer)
 296   (when (file-exists-p file)
 297     (if (not limit)
 298         (insert-file-contents file)
 299       (if (not blocksize) (setq blocksize 8192))
 300       (let ((filepos 0))
 301         (while
 302             (and (< 0 (cadr (insert-file-contents
 303                              file nil filepos (incf filepos blocksize))))
 304                  (progn (beginning-of-line)
 305                         (let ((pos (re-search-forward limit nil 'move)))
 306                           (if pos (delete-region (match-beginning 0)
 307                                                  (point-max)))
 308                           (not pos)))))))
 309     (set-buffer-modified-p nil)
 310     t))
 311
 312 (defun vc-find-root (file witness)
 313   "Find the root of a checked out project.
 314 The function walks up the directory tree from FILE looking for WITNESS.
 315 If WITNESS if not found, return nil, otherwise return the root."
 316   ;; Represent /home/luser/foo as ~/foo so that we don't try to look for
 317   ;; witnesses in /home or in /.
 318   (while (not (file-directory-p file))
 319     (setq file (file-name-directory (directory-file-name file))))
 320   (setq file (abbreviate-file-name file))
 321   (let ((root nil)
 322         (user (nth 2 (file-attributes file))))
 323     (while (not (or root
 324                     (null file)
 325                     ;; As a heuristic, we stop looking up the hierarchy of
 326                     ;; directories as soon as we find a directory belonging
 327                     ;; to another user.  This should save us from looking in
 328                     ;; things like /net and /afs.  This assumes that all the
 329                     ;; files inside a project belong to the same user.
 330                     (not (equal user (nth 2 (file-attributes file))))
 331                     (string-match vc-ignore-dir-regexp file)))
 332       (if (file-exists-p (expand-file-name witness file))
 333           (setq root file)
 334         (if (equal file
 335                    (setq file (file-name-directory (directory-file-name file))))
 336             (setq file nil))))
 337     root))
 338
 339 ;; Access functions to file properties
 340 ;; (Properties should be _set_ using vc-file-setprop, but
 341 ;; _retrieved_ only through these functions, which decide
 342 ;; if the property is already known or not. A property should
 343 ;; only be retrieved by vc-file-getprop if there is no
 344 ;; access function.)
 345
 346 ;; properties indicating the backend being used for FILE
 347
 348 (defun vc-registered (file)
 349   "Return non-nil if FILE is registered in a version control system.
 350
 351 This function performs the check each time it is called.  To rely
 352 on the result of a previous call, use `vc-backend' instead.  If the
 353 file was previously registered under a certain backend, then that
 354 backend is tried first."
 355   (let (handler)
 356     (cond
 357      ((string-match vc-ignore-dir-regexp (file-name-directory file)) nil)
 358      ((and (boundp 'file-name-handler-alist)
 359           (setq handler (find-file-name-handler file 'vc-registered)))
 360       ;; handler should set vc-backend and return t if registered
 361       (funcall handler 'vc-registered file))
 362      (t
 363       ;; There is no file name handler.
 364       ;; Try vc-BACKEND-registered for each handled BACKEND.
 365       (catch 'found
 366         (let ((backend (vc-file-getprop file 'vc-backend)))
 367           (mapcar
 368            (lambda (b)
 369              (and (vc-call-backend b 'registered file)
 370                   (vc-file-setprop file 'vc-backend b)
 371                   (throw 'found t)))
 372            (if (or (not backend) (eq backend 'none))
 373                vc-handled-backends
 374              (cons backend vc-handled-backends))))
 375         ;; File is not registered.
 376         (vc-file-setprop file 'vc-backend 'none)
 377         nil)))))
 378
 379 (defun vc-backend (file)
 380   "Return the version control type of FILE, nil if it is not registered."
 381   ;; `file' can be nil in several places (typically due to the use of
 382   ;; code like (vc-backend buffer-file-name)).
 383   (when (stringp file)
 384     (let ((property (vc-file-getprop file 'vc-backend)))
 385       ;; Note that internally, Emacs remembers unregistered
 386       ;; files by setting the property to `none'.
 387       (cond ((eq property 'none) nil)
 388             (property)
 389             ;; vc-registered sets the vc-backend property
 390             (t (if (vc-registered file)
 391                    (vc-file-getprop file 'vc-backend)
 392                  nil))))))
 393
 394 (defun vc-backend-subdirectory-name (file)
 395   "Return where the master and lock FILEs for the current directory are kept."
 396   (symbol-name (vc-backend file)))
 397
 398 (defun vc-name (file)
 399   "Return the master name of FILE.
 400 If the file is not registered, or the master name is not known, return nil."
 401   ;; TODO: This should ultimately become obsolete, at least up here
 402   ;; in vc-hooks.
 403   (or (vc-file-getprop file 'vc-name)
 404       ;; force computation of the property by calling
 405       ;; vc-BACKEND-registered explicitly
 406       (if (and (vc-backend file)
 407                (vc-call-backend (vc-backend file) 'registered file))
 408           (vc-file-getprop file 'vc-name))))
 409
 410 (defun vc-checkout-model (file)
 411   "Indicate how FILE is checked out.
 412
 413 If FILE is not registered, this function always returns nil.
 414 For registered files, the possible values are:
 415
 416   'implicit   FILE is always writeable, and checked out `implicitly'
 417               when the user saves the first changes to the file.
 418
 419   'locking    FILE is read-only if up-to-date; user must type
 420               \\[vc-next-action] before editing.  Strict locking
 421               is assumed.
 422
 423   'announce   FILE is read-only if up-to-date; user must type
 424               \\[vc-next-action] before editing.  But other users
 425               may be editing at the same time."
 426   (or (vc-file-getprop file 'vc-checkout-model)
 427       (if (vc-backend file)
 428           (vc-file-setprop file 'vc-checkout-model
 429                            (vc-call checkout-model file)))))
 430
 431 (defun vc-user-login-name (file)
 432   "Return the name under which the user accesses the given FILE."
 433   (or (and (eq (string-match tramp-file-name-regexp file) 0)
 434            ;; tramp case: execute "whoami" via tramp
 435            (let ((default-directory (file-name-directory file)))
 436              (with-temp-buffer
 437                (if (not (zerop (process-file "whoami" nil t)))
 438                    ;; fall through if "whoami" didn't work
 439                    nil
 440                  ;; remove trailing newline
 441                  (delete-region (1- (point-max)) (point-max))
 442                  (buffer-string)))))
 443       ;; normal case
 444       (user-login-name)
 445       ;; if user-login-name is nil, return the UID as a string
 446       (number-to-string (user-uid))))
 447
 448 (defun vc-state (file)
 449   "Return the version control state of FILE.
 450
 451 If FILE is not registered, this function always returns nil.
 452 For registered files, the value returned is one of:
 453
 454   'up-to-date        The working file is unmodified with respect to the
 455                      latest version on the current branch, and not locked.
 456
 457   'edited            The working file has been edited by the user.  If
 458                      locking is used for the file, this state means that
 459                      the current version is locked by the calling user.
 460
 461   USER               The current version of the working file is locked by
 462                      some other USER (a string).
 463
 464   'needs-patch       The file has not been edited by the user, but there is
 465                      a more recent version on the current branch stored
 466                      in the master file.
 467
 468   'needs-merge       The file has been edited by the user, and there is also
 469                      a more recent version on the current branch stored in
 470                      the master file.  This state can only occur if locking
 471                      is not used for the file.
 472
 473   'unlocked-changes  The current version of the working file is not locked,
 474                      but the working file has been changed with respect
 475                      to that version.  This state can only occur for files
 476                      with locking; it represents an erroneous condition that
 477                      should be resolved by the user (vc-next-action will
 478                      prompt the user to do it)."
 479   ;; FIXME: New (sub)states needed (?):
 480   ;; - `added' (i.e. `edited' but with no base version yet,
 481   ;;            typically represented by vc-workfile-version = "0")
 482   ;; - `conflict' (i.e. `edited' with conflict markers)
 483   ;; - `removed'
 484   ;; - `copied' and `moved' (might be handled by `removed' and `added')
 485   (or (vc-file-getprop file 'vc-state)
 486       (if (vc-backend file)
 487           (vc-file-setprop file 'vc-state
 488                            (vc-call state-heuristic file)))))
 489
 490 (defun vc-recompute-state (file)
 491   "Recompute the version control state of FILE, and return it.
 492 This calls the possibly expensive function vc-BACKEND-state,
 493 rather than the heuristic."
 494   (vc-file-setprop file 'vc-state (vc-call state file)))
 495
 496 (defsubst vc-up-to-date-p (file)
 497   "Convenience function that checks whether `vc-state' of FILE is `up-to-date'."
 498   (eq (vc-state file) 'up-to-date))
 499
 500 (defun vc-default-state-heuristic (backend file)
 501   "Default implementation of vc-state-heuristic.
 502 It simply calls the real state computation function `vc-BACKEND-state'
 503 and does not employ any heuristic at all."
 504    (vc-call-backend backend 'state file))
 505
 506 (defun vc-workfile-unchanged-p (file)
 507   "Return non-nil if FILE has not changed since the last checkout."
 508   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 509         (lastmod (nth 5 (file-attributes file))))
 510     (if (and checkout-time
 511              ;; Tramp and Ange-FTP return this when they don't know the time.
 512              (not (equal lastmod '(0 0))))
 513         (equal checkout-time lastmod)
 514       (let ((unchanged (vc-call workfile-unchanged-p file)))
 515         (vc-file-setprop file 'vc-checkout-time (if unchanged lastmod 0))
 516         unchanged))))
 517
 518 (defun vc-default-workfile-unchanged-p (backend file)
 519   "Check if FILE is unchanged by diffing against the master version.
 520 Return non-nil if FILE is unchanged."
 521   (zerop (condition-case err
 522              ;; If the implementation supports it, let the output
 523              ;; go to *vc*, not *vc-diff*, since this is an internal call.
 524              (vc-call diff file nil nil "*vc*")
 525            (wrong-number-of-arguments
 526             ;; If this error came from the above call to vc-BACKEND-diff,
 527             ;; try again without the optional buffer argument (for
 528             ;; backward compatibility).  Otherwise, resignal.
 529             (if (or (not (eq (cadr err)
 530                              (indirect-function
 531                               (vc-find-backend-function (vc-backend file)
 532                                                         'diff))))
 533                     (not (eq (caddr err) 4)))
 534                 (signal (car err) (cdr err))
 535               (vc-call diff file))))))
 536
 537 (defun vc-workfile-version (file)
 538   "Return the version level of the current workfile FILE.
 539 If FILE is not registered, this function always returns nil."
 540   (or (vc-file-getprop file 'vc-workfile-version)
 541       (if (vc-backend file)
 542           (vc-file-setprop file 'vc-workfile-version
 543                            (vc-call workfile-version file)))))
 544
 545 (defun vc-default-registered (backend file)
 546   "Check if FILE is registered in BACKEND using vc-BACKEND-master-templates."
 547   (let ((sym (vc-make-backend-sym backend 'master-templates)))
 548     (unless (get backend 'vc-templates-grabbed)
 549       (put backend 'vc-templates-grabbed t)
 550       (set sym (append (delq nil
 551                              (mapcar
 552                               (lambda (template)
 553                                 (and (consp template)
 554                                      (eq (cdr template) backend)
 555                                      (car template)))
 556                               (with-no-warnings
 557                                vc-master-templates)))
 558                        (symbol-value sym))))
 559     (let ((result (vc-check-master-templates file (symbol-value sym))))
 560       (if (stringp result)
 561           (vc-file-setprop file 'vc-name result)
 562         nil))))                         ; Not registered
 563
 564 (defun vc-possible-master (s dirname basename)
 565   (cond
 566    ((stringp s) (format s dirname basename))
 567    ((functionp s)
 568     ;; The template is a function to invoke.  If the
 569     ;; function returns non-nil, that means it has found a
 570     ;; master.  For backward compatibility, we also handle
 571     ;; the case that the function throws a 'found atom
 572     ;; and a pair (cons MASTER-FILE BACKEND).
 573     (let ((result (catch 'found (funcall s dirname basename))))
 574       (if (consp result) (car result) result)))))
 575
 576 (defun vc-check-master-templates (file templates)
 577   "Return non-nil if there is a master corresponding to FILE.
 578
 579 TEMPLATES is a list of strings or functions.  If an element is a
 580 string, it must be a control string as required by `format', with two
 581 string placeholders, such as \"%sRCS/%s,v\".  The directory part of
 582 FILE is substituted for the first placeholder, the basename of FILE
 583 for the second.  If a file with the resulting name exists, it is taken
 584 as the master of FILE, and returned.
 585
 586 If an element of TEMPLATES is a function, it is called with the
 587 directory part and the basename of FILE as arguments.  It should
 588 return non-nil if it finds a master; that value is then returned by
 589 this function."
 590   (let ((dirname (or (file-name-directory file) ""))
 591         (basename (file-name-nondirectory file)))
 592     (catch 'found
 593       (mapcar
 594        (lambda (s)
 595          (let ((trial (vc-possible-master s dirname basename)))
 596            (if (and trial (file-exists-p trial)
 597                     ;; Make sure the file we found with name
 598                     ;; TRIAL is not the source file itself.
 599                     ;; That can happen with RCS-style names if
 600                     ;; the file name is truncated (e.g. to 14
 601                     ;; chars).  See if either directory or
 602                     ;; attributes differ.
 603                     (or (not (string= dirname
 604                                       (file-name-directory trial)))
 605                         (not (equal (file-attributes file)
 606                                     (file-attributes trial)))))
 607                (throw 'found trial))))
 608        templates))))
 609
 610 (defun vc-toggle-read-only (&optional verbose)
 611   "Change read-only status of current buffer, perhaps via version control.
 612
 613 If the buffer is visiting a file registered with version control,
 614 then check the file in or out.  Otherwise, just change the read-only flag
 615 of the buffer.
 616 With prefix argument, ask for version number to check in or check out.
 617 Check-out of a specified version number does not lock the file;
 618 to do that, use this command a second time with no argument.
 619
 620 If you bind this function to \\[toggle-read-only], then Emacs checks files
 621 in or out whenever you toggle the read-only flag."
 622   (interactive "P")
 623   (if (or (and (boundp 'vc-dired-mode) vc-dired-mode)
 624           ;; use boundp because vc.el might not be loaded
 625           (vc-backend buffer-file-name))
 626       (vc-next-action verbose)
 627     (toggle-read-only)))
 628
 629 (defun vc-default-make-version-backups-p (backend file)
 630   "Return non-nil if unmodified versions should be backed up locally.
 631 The default is to switch off this feature."
 632   nil)
 633
 634 (defun vc-version-backup-file-name (file &optional rev manual regexp)
 635   "Return a backup file name for REV or the current version of FILE.
 636 If MANUAL is non-nil it means that a name for backups created by
 637 the user should be returned; if REGEXP is non-nil that means to return
 638 a regexp for matching all such backup files, regardless of the version."
 639   (if regexp
 640       (concat (regexp-quote (file-name-nondirectory file))
 641               "\\.~.+" (unless manual "\\.") "~")
 642     (expand-file-name (concat (file-name-nondirectory file)
 643                               ".~" (subst-char-in-string
 644                                     ?/ ?_ (or rev (vc-workfile-version file)))
 645                               (unless manual ".") "~")
 646                       (file-name-directory file))))
 647
 648 (defun vc-delete-automatic-version-backups (file)
 649   "Delete all existing automatic version backups for FILE."
 650   (condition-case nil
 651       (mapcar
 652        'delete-file
 653        (directory-files (or (file-name-directory file) default-directory) t
 654                         (vc-version-backup-file-name file nil nil t)))
 655     ;; Don't fail when the directory doesn't exist.
 656     (file-error nil)))
 657
 658 (defun vc-make-version-backup (file)
 659   "Make a backup copy of FILE, which is assumed in sync with the repository.
 660 Before doing that, check if there are any old backups and get rid of them."
 661   (unless (and (fboundp 'msdos-long-file-names)
 662                (not (with-no-warnings (msdos-long-file-names))))
 663     (vc-delete-automatic-version-backups file)
 664     (condition-case nil
 665         (copy-file file (vc-version-backup-file-name file)
 666                    nil 'keep-date)
 667       ;; It's ok if it doesn't work (e.g. directory not writable),
 668       ;; since this is just for efficiency.
 669       (file-error
 670        (message
 671         (concat "Warning: Cannot make version backup; "
 672                 "diff/revert therefore not local"))))))
 673
 674 (defun vc-before-save ()
 675   "Function to be called by `basic-save-buffer' (in files.el)."
 676   ;; If the file on disk is still in sync with the repository,
 677   ;; and version backups should be made, copy the file to
 678   ;; another name.  This enables local diffs and local reverting.
 679   (let ((file buffer-file-name))
 680     (and (vc-backend file)
 681          (vc-up-to-date-p file)
 682          (eq (vc-checkout-model file) 'implicit)
 683          (vc-call make-version-backups-p file)
 684          (vc-make-version-backup file))))
 685
 686 (defun vc-after-save ()
 687   "Function to be called by `basic-save-buffer' (in files.el)."
 688   ;; If the file in the current buffer is under version control,
 689   ;; up-to-date, and locking is not used for the file, set
 690   ;; the state to 'edited and redisplay the mode line.
 691   (let ((file buffer-file-name))
 692     (and (vc-backend file)
 693          (or (and (equal (vc-file-getprop file 'vc-checkout-time)
 694                          (nth 5 (file-attributes file)))
 695                   ;; File has been saved in the same second in which
 696                   ;; it was checked out.  Clear the checkout-time
 697                   ;; to avoid confusion.
 698                   (vc-file-setprop file 'vc-checkout-time nil))
 699              t)
 700          (vc-up-to-date-p file)
 701          (eq (vc-checkout-model file) 'implicit)
 702          (vc-file-setprop file 'vc-state 'edited)
 703          (vc-mode-line file)
 704          (if (featurep 'vc)
 705              ;; If VC is not loaded, then there can't be
 706              ;; any VC Dired buffer to synchronize.
 707              (vc-dired-resynch-file file)))))
 708
 709 (defun vc-mode-line (file)
 710   "Set `vc-mode' to display type of version control for FILE.
 711 The value is set in the current buffer, which should be the buffer
 712 visiting FILE."
 713   (interactive (list buffer-file-name))
 714   (let ((backend (vc-backend file)))
 715     (if (not backend)
 716         (setq vc-mode nil)
 717       (setq vc-mode (concat " " (if vc-display-status
 718                                     (vc-call mode-line-string file)
 719                                   (symbol-name backend))))
 720       ;; If the file is locked by some other user, make
 721       ;; the buffer read-only.  Like this, even root
 722       ;; cannot modify a file that someone else has locked.
 723       (and (equal file buffer-file-name)
 724            (stringp (vc-state file))
 725            (setq buffer-read-only t))
 726       ;; If the user is root, and the file is not owner-writable,
 727       ;; then pretend that we can't write it
 728       ;; even though we can (because root can write anything).
 729     ;; This way, even root cannot modify a file that isn't locked.
 730     (and (equal file buffer-file-name)
 731          (not buffer-read-only)
 732            (zerop (user-real-uid))
 733            (zerop (logand (file-modes buffer-file-name) 128))
 734            (setq buffer-read-only t)))
 735     (force-mode-line-update)
 736     backend))
 737
 738 (defun vc-default-mode-line-string (backend file)
 739   "Return string for placement in modeline by `vc-mode-line' for FILE.
 740 Format:
 741
 742   \"BACKEND-REV\"        if the file is up-to-date
 743   \"BACKEND:REV\"        if the file is edited (or locked by the calling user)
 744   \"BACKEND:LOCKER:REV\" if the file is locked by somebody else
 745
 746 This function assumes that the file is registered."
 747   (setq backend (symbol-name backend))
 748   (let ((state   (vc-state file))
 749         (rev     (vc-workfile-version file)))
 750     (cond ((or (eq state 'up-to-date)
 751                (eq state 'needs-patch))
 752            (concat backend "-" rev))
 753           ((stringp state)
 754            (concat backend ":" state ":" rev))
 755           (t
 756            ;; Not just for the 'edited state, but also a fallback
 757            ;; for all other states.  Think about different symbols
 758            ;; for 'needs-patch and 'needs-merge.
 759            (concat backend ":" rev)))))
 760
 761 (defun vc-follow-link ()
 762   "If current buffer visits a symbolic link, visit the real file.
 763 If the real file is already visited in another buffer, make that buffer
 764 current, and kill the buffer that visits the link."
 765   (let* ((truename (abbreviate-file-name (file-chase-links buffer-file-name)))
 766          (true-buffer (find-buffer-visiting truename))
 767          (this-buffer (current-buffer)))
 768     (if (eq true-buffer this-buffer)
 769         (progn
 770           (kill-buffer this-buffer)
 771           ;; In principle, we could do something like set-visited-file-name.
 772           ;; However, it can't be exactly the same as set-visited-file-name.
 773           ;; I'm not going to work out the details right now. -- rms.
 774           (set-buffer (find-file-noselect truename)))
 775       (set-buffer true-buffer)
 776       (kill-buffer this-buffer))))
 777
 778 (defun vc-default-find-file-hook (backend)
 779   nil)
 780
 781 (defun vc-find-file-hook ()
 782   "Function for `find-file-hook' activating VC mode if appropriate."
 783   ;; Recompute whether file is version controlled,
 784   ;; if user has killed the buffer and revisited.
 785   (if vc-mode
 786       (setq vc-mode nil))
 787   (when buffer-file-name
 788     (vc-file-clearprops buffer-file-name)
 789     (cond
 790      ((ignore-errors (vc-backend buffer-file-name))
 791       ;; Compute the state and put it in the modeline.
 792       (vc-mode-line buffer-file-name)
 793       (unless vc-make-backup-files
 794         ;; Use this variable, not make-backup-files,
 795         ;; because this is for things that depend on the file name.
 796         (set (make-local-variable 'backup-inhibited) t))
 797       ;; Let the backend setup any buffer-local things he needs.
 798       (vc-call-backend (vc-backend buffer-file-name) 'find-file-hook))
 799      ((let ((link-type (and (file-symlink-p buffer-file-name)
 800                             (vc-backend (file-chase-links buffer-file-name)))))
 801         (cond ((not link-type) nil)     ;Nothing to do.
 802               ((eq vc-follow-symlinks nil)
 803                (message
 804         "Warning: symbolic link to %s-controlled source file" link-type))
 805               ((or (not (eq vc-follow-symlinks 'ask))
 806                    ;; If we already visited this file by following
 807                    ;; the link, don't ask again if we try to visit
 808                    ;; it again.  GUD does that, and repeated questions
 809                    ;; are painful.
 810                    (get-file-buffer
 811                     (abbreviate-file-name
 812                      (file-chase-links buffer-file-name))))
 813
 814                (vc-follow-link)
 815                (message "Followed link to %s" buffer-file-name)
 816                (vc-find-file-hook))
 817               (t
 818                (if (yes-or-no-p (format
 819         "Symbolic link to %s-controlled source file; follow link? " link-type))
 820                    (progn (vc-follow-link)
 821                           (message "Followed link to %s" buffer-file-name)
 822                           (vc-find-file-hook))
 823                  (message
 824         "Warning: editing through the link bypasses version control")
 825                  ))))))))
 826
 827 (add-hook 'find-file-hook 'vc-find-file-hook)
 828
 829 ;; more hooks, this time for file-not-found
 830 (defun vc-file-not-found-hook ()
 831   "When file is not found, try to check it out from version control.
 832 Returns t if checkout was successful, nil otherwise.
 833 Used in `find-file-not-found-functions'."
 834   ;; When a file does not exist, ignore cached info about it
 835   ;; from a previous visit.
 836   (vc-file-clearprops buffer-file-name)
 837   (let ((backend (vc-backend buffer-file-name)))
 838     (if backend (vc-call-backend backend 'find-file-not-found-hook))))
 839
 840 (defun vc-default-find-file-not-found-hook (backend)
 841   ;; This used to do what vc-rcs-find-file-not-found-hook does, but it only
 842   ;; really makes sense for RCS.  For other backends, better not do anything.
 843   nil)
 844
 845 (add-hook 'find-file-not-found-functions 'vc-file-not-found-hook)
 846
 847 (defun vc-kill-buffer-hook ()
 848   "Discard VC info about a file when we kill its buffer."
 849   (if buffer-file-name
 850       (vc-file-clearprops buffer-file-name)))
 851
 852 (add-hook 'kill-buffer-hook 'vc-kill-buffer-hook)
 853
 854 ;; Now arrange for (autoloaded) bindings of the main package.
 855 ;; Bindings for this have to go in the global map, as we'll often
 856 ;; want to call them from random buffers.
 857
 858 ;; Autoloading works fine, but it prevents shortcuts from appearing
 859 ;; in the menu because they don't exist yet when the menu is built.
 860 ;; (autoload 'vc-prefix-map "vc" nil nil 'keymap)
 861 (defvar vc-prefix-map
 862   (let ((map (make-sparse-keymap)))
 863     (define-key map "a" 'vc-update-change-log)
 864     (define-key map "b" 'vc-switch-backend)
 865     (define-key map "c" 'vc-cancel-version)
 866     (define-key map "d" 'vc-directory)
 867     (define-key map "g" 'vc-annotate)
 868     (define-key map "h" 'vc-insert-headers)
 869     (define-key map "i" 'vc-register)
 870     (define-key map "l" 'vc-print-log)
 871     (define-key map "m" 'vc-merge)
 872     (define-key map "r" 'vc-retrieve-snapshot)
 873     (define-key map "s" 'vc-create-snapshot)
 874     (define-key map "u" 'vc-revert-buffer)
 875     (define-key map "v" 'vc-next-action)
 876     (define-key map "=" 'vc-diff)
 877     (define-key map "~" 'vc-version-other-window)
 878     map))
 879 (fset 'vc-prefix-map vc-prefix-map)
 880 (define-key global-map "\C-xv" 'vc-prefix-map)
 881
 882 (if (not (boundp 'vc-menu-map))
 883     ;; Don't do the menu bindings if menu-bar.el wasn't loaded to defvar
 884     ;; vc-menu-map.
 885     ()
 886   ;;(define-key vc-menu-map [show-files]
 887   ;;  '("Show Files under VC" . (vc-directory t)))
 888   (define-key vc-menu-map [vc-retrieve-snapshot]
 889     '("Retrieve Snapshot" . vc-retrieve-snapshot))
 890   (define-key vc-menu-map [vc-create-snapshot]
 891     '("Create Snapshot" . vc-create-snapshot))
 892   (define-key vc-menu-map [vc-directory] '("VC Directory Listing" . vc-directory))
 893   (define-key vc-menu-map [separator1] '("----"))
 894   (define-key vc-menu-map [vc-annotate] '("Annotate" . vc-annotate))
 895   (define-key vc-menu-map [vc-rename-file] '("Rename File" . vc-rename-file))
 896   (define-key vc-menu-map [vc-version-other-window]
 897     '("Show Other Version" . vc-version-other-window))
 898   (define-key vc-menu-map [vc-diff] '("Compare with Base Version" . vc-diff))
 899   (define-key vc-menu-map [vc-update-change-log]
 900     '("Update ChangeLog" . vc-update-change-log))
 901   (define-key vc-menu-map [vc-print-log] '("Show History" . vc-print-log))
 902   (define-key vc-menu-map [separator2] '("----"))
 903   (define-key vc-menu-map [vc-insert-header]
 904     '("Insert Header" . vc-insert-headers))
 905   (define-key vc-menu-map [undo] '("Undo Last Check-In" . vc-cancel-version))
 906   (define-key vc-menu-map [vc-revert-buffer]
 907     '("Revert to Base Version" . vc-revert-buffer))
 908   (define-key vc-menu-map [vc-update]
 909     '("Update to Latest Version" . vc-update))
 910   (define-key vc-menu-map [vc-next-action] '("Check In/Out" . vc-next-action))
 911   (define-key vc-menu-map [vc-register] '("Register" . vc-register)))
 912
 913 ;; These are not correct and it's not currently clear how doing it
 914 ;; better (with more complicated expressions) might slow things down
 915 ;; on older systems.
 916
 917 ;;(put 'vc-rename-file 'menu-enable 'vc-mode)
 918 ;;(put 'vc-annotate 'menu-enable '(eq (vc-buffer-backend) 'CVS))
 919 ;;(put 'vc-version-other-window 'menu-enable 'vc-mode)
 920 ;;(put 'vc-diff 'menu-enable 'vc-mode)
 921 ;;(put 'vc-update-change-log 'menu-enable
 922 ;;     '(member (vc-buffer-backend) '(RCS CVS)))
 923 ;;(put 'vc-print-log 'menu-enable 'vc-mode)
 924 ;;(put 'vc-cancel-version 'menu-enable 'vc-mode)
 925 ;;(put 'vc-revert-buffer 'menu-enable 'vc-mode)
 926 ;;(put 'vc-insert-headers 'menu-enable 'vc-mode)
 927 ;;(put 'vc-next-action 'menu-enable 'vc-mode)
 928 ;;(put 'vc-register 'menu-enable '(and buffer-file-name (not vc-mode)))
 929
 930 (provide 'vc-hooks)
 931
 932 ;; arch-tag: 2e5a6fa7-1d30-48e2-8bd0-e3d335f04f32
 933 ;;; vc-hooks.el ends here