lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2003, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@gnu.org>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  81 ;;             Level 2 header is free of DOS specific restrictions and most
  82 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  83 ;;             and extension headers.  For more details see
  84 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  85 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  86 ;;
  87 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  88 ;;             which is a series of (cheader) followed by an end-of-
  89 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  90 ;;             links to c-d.  cheaders link to lheaders which are basically
  91 ;;             cut-down versions of the cheaders.
  92 ;;
  93 ;; ZOO         An archive header followed by a series of (header,file).
  94 ;;             Each member header points to the next.  The archive is
  95 ;;             terminated by a bogus header with a zero next link.
  96 ;; -------------------------------------
  97 ;; HOOKS: `foo' means one of the supported archive types.
  98 ;;
  99 ;; archive-mode-hook
 100 ;; archive-foo-mode-hook
 101 ;; archive-extract-hooks
 102
 103 ;;; Code:
 104
 105 ;; -------------------------------------------------------------------------
 106 ;; Section: Configuration.
 107
 108 (defgroup archive nil
 109   "Simple editing of archives."
 110   :group 'data)
 111
 112 (defgroup archive-arc nil
 113   "ARC-specific options to archive."
 114   :group 'archive)
 115
 116 (defgroup archive-lzh nil
 117   "LZH-specific options to archive."
 118   :group 'archive)
 119
 120 (defgroup archive-zip nil
 121   "ZIP-specific options to archive."
 122   :group 'archive)
 123
 124 (defgroup archive-zoo nil
 125   "ZOO-specific options to archive."
 126   :group 'archive)
 127
 128 (defcustom archive-tmpdir
 129   ;; make-temp-name is safe here because we use this name
 130   ;; to create a directory.
 131   (make-temp-name
 132    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 133                      temporary-file-directory))
 134   "*Directory for temporary files made by arc-mode.el"
 135   :type 'directory
 136   :group 'archive)
 137
 138 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 139   "*Regexp recognizing archive files names that are not local.
 140 A non-local file is one whose file name is not proper outside Emacs.
 141 A local copy of the archive will be used when updating."
 142   :type 'regexp
 143   :group 'archive)
 144
 145 (defcustom archive-extract-hooks nil
 146   "*Hooks to run when an archive member has been extracted."
 147   :type 'hook
 148   :group 'archive)
 149 ;; ------------------------------
 150 ;; Arc archive configuration
 151
 152 ;; We always go via a local file since there seems to be no reliable way
 153 ;; to extract to stdout without junk getting added.
 154 (defcustom archive-arc-extract
 155   '("arc" "x")
 156   "*Program and its options to run in order to extract an arc file member.
 157 Extraction should happen to the current directory.  Archive and member
 158 name will be added."
 159   :type '(list (string :tag "Program")
 160                 (repeat :tag "Options"
 161                         :inline t
 162                         (string :format "%v")))
 163   :group 'archive-arc)
 164
 165 (defcustom archive-arc-expunge
 166   '("arc" "d")
 167   "*Program and its options to run in order to delete arc file members.
 168 Archive and member names will be added."
 169   :type '(list (string :tag "Program")
 170                 (repeat :tag "Options"
 171                         :inline t
 172                         (string :format "%v")))
 173   :group 'archive-arc)
 174
 175 (defcustom archive-arc-write-file-member
 176   '("arc" "u")
 177   "*Program and its options to run in order to update an arc file member.
 178 Archive and member name will be added."
 179   :type '(list (string :tag "Program")
 180                 (repeat :tag "Options"
 181                         :inline t
 182                         (string :format "%v")))
 183   :group 'archive-arc)
 184 ;; ------------------------------
 185 ;; Lzh archive configuration
 186
 187 (defcustom archive-lzh-extract
 188   '("lha" "pq")
 189   "*Program and its options to run in order to extract an lzh file member.
 190 Extraction should happen to standard output.  Archive and member name will
 191 be added."
 192   :type '(list (string :tag "Program")
 193                 (repeat :tag "Options"
 194                         :inline t
 195                         (string :format "%v")))
 196   :group 'archive-lzh)
 197
 198 (defcustom archive-lzh-expunge
 199   '("lha" "d")
 200   "*Program and its options to run in order to delete lzh file members.
 201 Archive and member names will be added."
 202   :type '(list (string :tag "Program")
 203                 (repeat :tag "Options"
 204                         :inline t
 205                         (string :format "%v")))
 206   :group 'archive-lzh)
 207
 208 (defcustom archive-lzh-write-file-member
 209   '("lha" "a")
 210   "*Program and its options to run in order to update an lzh file member.
 211 Archive and member name will be added."
 212   :type '(list (string :tag "Program")
 213                 (repeat :tag "Options"
 214                         :inline t
 215                         (string :format "%v")))
 216   :group 'archive-lzh)
 217 ;; ------------------------------
 218 ;; Zip archive configuration
 219
 220 (defcustom archive-zip-extract
 221   (if (locate-file "unzip" nil 'file-executable-p)
 222       '("unzip" "-qq" "-c")
 223     (if (locate-file "pkunzip" nil 'file-executable-p)
 224         '("pkunzip" "-e" "-o-")
 225       '("unzip" "-qq" "-c")))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 229 expected to extract to a file junking the directory part of the name."
 230   :type '(list (string :tag "Program")
 231                 (repeat :tag "Options"
 232                         :inline t
 233                         (string :format "%v")))
 234   :group 'archive-zip)
 235
 236 ;; For several reasons the latter behaviour is not desirable in general.
 237 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 238 ;; existent.  (3) It tends to do funny things with other systems' file
 239 ;; names.
 240
 241 (defcustom archive-zip-expunge
 242   (if (locate-file "zip" nil 'file-executable-p)
 243       '("zip" "-d" "-q")
 244     (if (locate-file "pkzip" nil 'file-executable-p)
 245          '("pkzip" "-d")
 246       '("zip" "-d" "-q")))
 247   "*Program and its options to run in order to delete zip file members.
 248 Archive and member names will be added."
 249   :type '(list (string :tag "Program")
 250                 (repeat :tag "Options"
 251                         :inline t
 252                         (string :format "%v")))
 253   :group 'archive-zip)
 254
 255 (defcustom archive-zip-update
 256   (if (locate-file "zip" nil 'file-executable-p)
 257       '("zip" "-q")
 258     (if (locate-file "pkzip" nil 'file-executable-p)
 259          '("pkzip" "-u" "-P")
 260       '("zip" "-q")))
 261   "*Program and its options to run in order to update a zip file member.
 262 Options should ensure that specified directory will be put into the zip
 263 file.  Archive and member name will be added."
 264   :type '(list (string :tag "Program")
 265                 (repeat :tag "Options"
 266                         :inline t
 267                         (string :format "%v")))
 268   :group 'archive-zip)
 269
 270 (defcustom archive-zip-update-case
 271   (if (locate-file "zip" nil 'file-executable-p)
 272       '("zip" "-q" "-k")
 273     (if (locate-file "pkzip" nil 'file-executable-p)
 274          '("pkzip" "-u" "-P")
 275       '("zip" "-q" "-k")))
 276   "*Program and its options to run in order to update a case fiddled zip member.
 277 Options should ensure that specified directory will be put into the zip file.
 278 Archive and member name will be added."
 279   :type '(list (string :tag "Program")
 280                 (repeat :tag "Options"
 281                         :inline t
 282                         (string :format "%v")))
 283   :group 'archive-zip)
 284
 285 (defcustom archive-zip-case-fiddle t
 286   "*If non-nil then zip file members may be down-cased.
 287 This case fiddling will only happen for members created by a system
 288 that uses caseless file names."
 289   :type 'boolean
 290   :group 'archive-zip)
 291 ;; ------------------------------
 292 ;; Zoo archive configuration
 293
 294 (defcustom archive-zoo-extract
 295   '("zoo" "xpq")
 296   "*Program and its options to run in order to extract a zoo file member.
 297 Extraction should happen to standard output.  Archive and member name will
 298 be added."
 299   :type '(list (string :tag "Program")
 300                 (repeat :tag "Options"
 301                         :inline t
 302                         (string :format "%v")))
 303   :group 'archive-zoo)
 304
 305 (defcustom archive-zoo-expunge
 306   '("zoo" "DqPP")
 307   "*Program and its options to run in order to delete zoo file members.
 308 Archive and member names will be added."
 309   :type '(list (string :tag "Program")
 310                 (repeat :tag "Options"
 311                         :inline t
 312                         (string :format "%v")))
 313   :group 'archive-zoo)
 314
 315 (defcustom archive-zoo-write-file-member
 316   '("zoo" "a")
 317   "*Program and its options to run in order to update a zoo file member.
 318 Archive and member name will be added."
 319   :type '(list (string :tag "Program")
 320                 (repeat :tag "Options"
 321                         :inline t
 322                         (string :format "%v")))
 323   :group 'archive-zoo)
 324 ;; -------------------------------------------------------------------------
 325 ;; Section: Variables
 326
 327 (defvar archive-subtype nil "Symbol describing archive type.")
 328 (defvar archive-file-list-start nil "Position of first contents line.")
 329 (defvar archive-file-list-end nil "Position just after last contents line.")
 330 (defvar archive-proper-file-start nil "Position of real archive's start.")
 331 (defvar archive-read-only nil "Non-nil if the archive is read-only on disk.")
 332 (defvar archive-local-name nil "Name of local copy of remote archive.")
 333 (defvar archive-mode-map
 334   (let ((map (make-keymap)))
 335     (suppress-keymap map)
 336     (define-key map " " 'archive-next-line)
 337     (define-key map "a" 'archive-alternate-display)
 338     ;;(define-key map "c" 'archive-copy)
 339     (define-key map "d" 'archive-flag-deleted)
 340     (define-key map "\C-d" 'archive-flag-deleted)
 341     (define-key map "e" 'archive-extract)
 342     (define-key map "f" 'archive-extract)
 343     (define-key map "\C-m" 'archive-extract)
 344     (define-key map "g" 'revert-buffer)
 345     (define-key map "h" 'describe-mode)
 346     (define-key map "m" 'archive-mark)
 347     (define-key map "n" 'archive-next-line)
 348     (define-key map "\C-n" 'archive-next-line)
 349     (define-key map [down] 'archive-next-line)
 350     (define-key map "o" 'archive-extract-other-window)
 351     (define-key map "p" 'archive-previous-line)
 352     (define-key map "q" 'quit-window)
 353     (define-key map "\C-p" 'archive-previous-line)
 354     (define-key map [up] 'archive-previous-line)
 355     (define-key map "r" 'archive-rename-entry)
 356     (define-key map "u" 'archive-unflag)
 357     (define-key map "\M-\C-?" 'archive-unmark-all-files)
 358     (define-key map "v" 'archive-view)
 359     (define-key map "x" 'archive-expunge)
 360     (define-key map "\177" 'archive-unflag-backwards)
 361     (define-key map "E" 'archive-extract-other-window)
 362     (define-key map "M" 'archive-chmod-entry)
 363     (define-key map "G" 'archive-chgrp-entry)
 364     (define-key map "O" 'archive-chown-entry)
 365
 366     (if (fboundp 'command-remapping)
 367         (progn
 368           (define-key map [remap advertised-undo] 'archive-undo)
 369           (define-key map [remap undo] 'archive-undo))
 370       (substitute-key-definition 'advertised-undo 'archive-undo map global-map)
 371       (substitute-key-definition 'undo 'archive-undo map global-map))
 372
 373     (define-key map
 374       (if (featurep 'xemacs) 'button2 [mouse-2]) 'archive-mouse-extract)
 375
 376     (if (featurep 'xemacs)
 377         ()                              ; out of luck
 378
 379       (define-key map [menu-bar immediate]
 380         (cons "Immediate" (make-sparse-keymap "Immediate")))
 381       (define-key map [menu-bar immediate alternate]
 382         '(menu-item "Alternate Display" archive-alternate-display
 383           :enable (boundp (archive-name "alternate-display"))
 384           :help "Toggle alternate file info display"))
 385       (define-key map [menu-bar immediate view]
 386         '(menu-item "View This File" archive-view
 387           :help "Display file at cursor in View Mode"))
 388       (define-key map [menu-bar immediate display]
 389         '(menu-item "Display in Other Window" archive-display-other-window
 390           :help "Display file at cursor in another window"))
 391       (define-key map [menu-bar immediate find-file-other-window]
 392         '(menu-item "Find in Other Window" archive-extract-other-window
 393           :help "Edit file at cursor in another window"))
 394       (define-key map [menu-bar immediate find-file]
 395         '(menu-item "Find This File" archive-extract
 396           :help "Extract file at cursor and edit it"))
 397
 398       (define-key map [menu-bar mark]
 399         (cons "Mark" (make-sparse-keymap "Mark")))
 400       (define-key map [menu-bar mark unmark-all]
 401         '(menu-item "Unmark All" archive-unmark-all-files
 402           :help "Unmark all marked files"))
 403       (define-key map [menu-bar mark deletion]
 404         '(menu-item "Flag" archive-flag-deleted
 405           :help "Flag file at cursor for deletion"))
 406       (define-key map [menu-bar mark unmark]
 407         '(menu-item "Unflag" archive-unflag
 408           :help "Unmark file at cursor"))
 409       (define-key map [menu-bar mark mark]
 410         '(menu-item "Mark" archive-mark
 411           :help "Mark file at cursor"))
 412
 413       (define-key map [menu-bar operate]
 414         (cons "Operate" (make-sparse-keymap "Operate")))
 415       (define-key map [menu-bar operate chown]
 416         '(menu-item "Change Owner..." archive-chown-entry
 417           :enable (fboundp (archive-name "chown-entry"))
 418           :help "Change owner of marked files"))
 419       (define-key map [menu-bar operate chgrp]
 420         '(menu-item "Change Group..." archive-chgrp-entry
 421           :enable (fboundp (archive-name "chgrp-entry"))
 422           :help "Change group ownership of marked files"))
 423       (define-key map [menu-bar operate chmod]
 424         '(menu-item "Change Mode..." archive-chmod-entry
 425           :enable (fboundp (archive-name "chmod-entry"))
 426           :help "Change mode (permissions) of marked files"))
 427       (define-key map [menu-bar operate rename]
 428         '(menu-item "Rename to..." archive-rename-entry
 429           :enable (fboundp (archive-name "rename-entry"))
 430           :help "Rename marked files"))
 431       ;;(define-key map [menu-bar operate copy]
 432       ;;  '(menu-item "Copy to..." archive-copy))
 433       (define-key map [menu-bar operate expunge]
 434         '(menu-item "Expunge Marked Files" archive-expunge
 435           :help "Delete all flagged files from archive"))
 436       map))
 437   "Local keymap for archive mode listings.")
 438 (defvar archive-file-name-indent nil "Column where file names start.")
 439
 440 (defvar archive-remote nil "Non-nil if the archive is outside file system.")
 441 (make-variable-buffer-local 'archive-remote)
 442 (put 'archive-remote 'permanent-local t)
 443
 444 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 445 (make-variable-buffer-local 'archive-member-coding-system)
 446
 447 (defvar archive-alternate-display nil
 448   "Non-nil when alternate information is shown.")
 449 (make-variable-buffer-local 'archive-alternate-display)
 450 (put 'archive-alternate-display 'permanent-local t)
 451
 452 (defvar archive-superior-buffer nil "In archive members, points to archive.")
 453 (put 'archive-superior-buffer 'permanent-local t)
 454
 455 (defvar archive-subfile-mode nil "Non-nil in archive member buffers.")
 456 (make-variable-buffer-local 'archive-subfile-mode)
 457 (put 'archive-subfile-mode 'permanent-local t)
 458
 459 (defvar archive-files nil
 460   "Vector of file descriptors.
 461 Each descriptor is a vector of the form
 462  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 463 (make-variable-buffer-local 'archive-files)
 464
 465 ;; -------------------------------------------------------------------------
 466 ;; Section: Support functions.
 467
 468 (defsubst archive-name (suffix)
 469   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 470
 471 (defun archive-l-e (str &optional len)
 472   "Convert little endian string/vector to integer.
 473 Alternatively, first argument may be a buffer position in the current buffer
 474 in which case a second argument, length, should be supplied."
 475   (if (stringp str)
 476       (setq len (length str))
 477     (setq str (buffer-substring str (+ str len))))
 478   (let ((result 0)
 479         (i 0))
 480     (while (< i len)
 481       (setq i (1+ i)
 482             result (+ (ash result 8) (aref str (- len i)))))
 483     result))
 484
 485 (defun archive-int-to-mode (mode)
 486   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 487   ;; FIXME: merge with tar-grind-file-mode.
 488   (string
 489     (if (zerop (logand  8192 mode))
 490         (if (zerop (logand 16384 mode)) ?- ?d)
 491       ?c) ; completeness
 492     (if (zerop (logand   256 mode)) ?- ?r)
 493     (if (zerop (logand   128 mode)) ?- ?w)
 494     (if (zerop (logand    64 mode))
 495         (if (zerop (logand  1024 mode)) ?- ?S)
 496       (if (zerop (logand  1024 mode)) ?x ?s))
 497     (if (zerop (logand    32 mode)) ?- ?r)
 498     (if (zerop (logand    16 mode)) ?- ?w)
 499     (if (zerop (logand     8 mode))
 500         (if (zerop (logand  2048 mode)) ?- ?S)
 501       (if (zerop (logand  2048 mode)) ?x ?s))
 502     (if (zerop (logand     4 mode)) ?- ?r)
 503     (if (zerop (logand     2 mode)) ?- ?w)
 504     (if (zerop (logand     1 mode)) ?- ?x)))
 505
 506 (defun archive-calc-mode (oldmode newmode &optional error)
 507   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 508 NEWMODE may be an octal number including a leading zero in which case it
 509 will become the new mode.\n
 510 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 511 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 512 If optional third argument ERROR is non-nil an error will be signaled if
 513 the mode is invalid.  If ERROR is nil then nil will be returned."
 514   (cond ((string-match "^0[0-7]*$" newmode)
 515          (let ((result 0)
 516                (len (length newmode))
 517                (i 1))
 518            (while (< i len)
 519              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 520                    i (1+ i)))
 521            (logior (logand oldmode 65024) result)))
 522         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 523          (let ((who 0)
 524                (result oldmode)
 525                (op (aref newmode (match-beginning 2)))
 526                (bits 0)
 527                (i (match-beginning 3)))
 528            (while (< i (match-end 3))
 529              (let ((rwx (aref newmode i)))
 530                (setq bits (logior bits (cond ((= rwx ?r)  292)
 531                                              ((= rwx ?w)  146)
 532                                              ((= rwx ?x)   73)
 533                                              ((= rwx ?s) 3072)
 534                                              ((= rwx ?t)  512)))
 535                      i (1+ i))))
 536            (while (< who (match-end 1))
 537              (let* ((whoc (aref newmode who))
 538                     (whomask (cond ((= whoc ?a) 4095)
 539                                    ((= whoc ?u) 1472)
 540                                    ((= whoc ?g) 2104)
 541                                    ((= whoc ?o)    7))))
 542                (if (= op ?=)
 543                    (setq result (logand result (lognot whomask))))
 544                (if (= op ?-)
 545                    (setq result (logand result (lognot (logand whomask bits))))
 546                  (setq result (logior result (logand whomask bits)))))
 547              (setq who (1+ who)))
 548            result))
 549         (t
 550          (if error
 551              (error "Invalid mode specification: %s" newmode)))))
 552
 553 (defun archive-dosdate (date)
 554   "Stringify dos packed DATE record."
 555   (let ((year (+ 1980 (logand (ash date -9) 127)))
 556         (month (logand (ash date -5) 15))
 557         (day (logand date 31)))
 558     (if (or (> month 12) (< month 1))
 559         ""
 560       (format "%2d-%s-%d"
 561               day
 562               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 563                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 564               year))))
 565
 566 (defun archive-dostime (time)
 567   "Stringify dos packed TIME record."
 568   (let ((hour (logand (ash time -11) 31))
 569         (minute (logand (ash time -5) 63))
 570         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 571     (format "%02d:%02d:%02d" hour minute second)))
 572
 573 (defun archive-unixdate (low high)
 574   "Stringify unix (LOW HIGH) date."
 575   (let ((str (current-time-string (cons high low))))
 576     (format "%s-%s-%s"
 577             (substring str 8 10)
 578             (substring str 4 7)
 579             (substring str 20 24))))
 580
 581 (defun archive-unixtime (low high)
 582   "Stringify unix (LOW HIGH) time."
 583   (let ((str (current-time-string (cons high low))))
 584     (substring str 11 19)))
 585
 586 (defun archive-get-lineno ()
 587   (if (>= (point) archive-file-list-start)
 588       (count-lines archive-file-list-start
 589                    (save-excursion (beginning-of-line) (point)))
 590     0))
 591
 592 (defun archive-get-descr (&optional noerror)
 593   "Return the descriptor vector for file at point.
 594 Does not signal an error if optional second argument NOERROR is non-nil."
 595   (let ((no (archive-get-lineno)))
 596     (if (and (>= (point) archive-file-list-start)
 597              (< no (length archive-files)))
 598         (let ((item (aref archive-files no)))
 599           (if (vectorp item)
 600               item
 601             (if (not noerror)
 602                 (error "Entry is not a regular member of the archive"))))
 603       (if (not noerror)
 604           (error "Line does not describe a member of the archive")))))
 605 ;; -------------------------------------------------------------------------
 606 ;; Section: the mode definition
 607
 608 ;;;###autoload
 609 (defun archive-mode (&optional force)
 610   "Major mode for viewing an archive file in a dired-like way.
 611 You can move around using the usual cursor motion commands.
 612 Letters no longer insert themselves.
 613 Type `e' to pull a file out of the archive and into its own buffer;
 614 or click mouse-2 on the file's line in the archive mode buffer.
 615
 616 If you edit a sub-file of this archive (as with the `e' command) and
 617 save it, the contents of that buffer will be saved back into the
 618 archive.
 619
 620 \\{archive-mode-map}"
 621   ;; This is not interactive because you shouldn't be turning this
 622   ;; mode on and off.  You can corrupt things that way.
 623   (if (zerop (buffer-size))
 624       ;; At present we cannot create archives from scratch
 625       (funcall default-major-mode)
 626     (if (and (not force) archive-files) nil
 627       (let* ((type (archive-find-type))
 628              (typename (capitalize (symbol-name type))))
 629         (kill-all-local-variables)
 630         (make-local-variable 'archive-subtype)
 631         (setq archive-subtype type)
 632
 633         ;; Buffer contains treated image of file before the file contents
 634         (make-local-variable 'revert-buffer-function)
 635         (setq revert-buffer-function 'archive-mode-revert)
 636         (auto-save-mode 0)
 637
 638         ;; Remote archives are not written by a hook.
 639         (if archive-remote nil
 640           (make-local-variable 'write-contents-hooks)
 641           (add-hook 'write-contents-hooks 'archive-write-file))
 642
 643         (make-local-variable 'require-final-newline)
 644         (setq require-final-newline nil)
 645         (make-local-variable 'local-enable-local-variables)
 646         (setq local-enable-local-variables nil)
 647
 648         ;; Prevent loss of data when saving the file.
 649         (make-local-variable 'file-precious-flag)
 650         (setq file-precious-flag t)
 651
 652         (make-local-variable 'archive-read-only)
 653         ;; Archives which are inside other archives and whose
 654         ;; names are invalid for this OS, can't be written.
 655         (setq archive-read-only
 656               (or (not (file-writable-p (buffer-file-name)))
 657                   (and archive-subfile-mode
 658                        (string-match file-name-invalid-regexp
 659                                      (aref archive-subfile-mode 0)))))
 660
 661         ;; Should we use a local copy when accessing from outside Emacs?
 662         (make-local-variable 'archive-local-name)
 663
 664         ;; An archive can contain another archive whose name is invalid
 665         ;; on local filesystem.  Treat such archives as remote.
 666         (or archive-remote
 667             (setq archive-remote
 668                   (or (string-match archive-remote-regexp (buffer-file-name))
 669                       (string-match file-name-invalid-regexp
 670                                     (buffer-file-name)))))
 671
 672         (setq major-mode 'archive-mode)
 673         (setq mode-name (concat typename "-Archive"))
 674         ;; Run archive-foo-mode-hook and archive-mode-hook
 675         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 676         (use-local-map archive-mode-map))
 677
 678       (make-local-variable 'archive-proper-file-start)
 679       (make-local-variable 'archive-file-list-start)
 680       (make-local-variable 'archive-file-list-end)
 681       (make-local-variable 'archive-file-name-indent)
 682       (archive-summarize nil)
 683       (setq buffer-read-only t))))
 684
 685 ;; Archive mode is suitable only for specially formatted data.
 686 (put 'archive-mode 'mode-class 'special)
 687 ;; -------------------------------------------------------------------------
 688 ;; Section: Key maps
 689
 690 (let ((item1 '(archive-subfile-mode " Archive")))
 691   (or (member item1 minor-mode-alist)
 692       (setq minor-mode-alist (cons item1 minor-mode-alist))))
 693 ;; -------------------------------------------------------------------------
 694 (defun archive-find-type ()
 695   (widen)
 696   (goto-char (point-min))
 697   ;; The funny [] here make it unlikely that the .elc file will be treated
 698   ;; as an archive by other software.
 699   (let (case-fold-search)
 700     (cond ((looking-at "[P]K\003\004") 'zip)
 701           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 702           ((looking-at "....................[\334]\247\304\375") 'zoo)
 703           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 704                 (string-match "\\.[aA][rR][cC]$"
 705                               (or buffer-file-name (buffer-name))))
 706            'arc)
 707           (t (error "Buffer format not recognized")))))
 708 ;; -------------------------------------------------------------------------
 709 (defun archive-summarize (&optional shut-up)
 710   "Parse the contents of the archive file in the current buffer.
 711 Place a dired-like listing on the front;
 712 then narrow to it, so that only that listing
 713 is visible (and the real data of the buffer is hidden).
 714 Optional argument SHUT-UP, if non-nil, means don't print messages
 715 when parsing the archive."
 716   (widen)
 717   (set-buffer-multibyte nil)
 718   (let (buffer-read-only)
 719     (or shut-up
 720         (message "Parsing archive file..."))
 721     (buffer-disable-undo (current-buffer))
 722     (setq archive-files (funcall (archive-name "summarize")))
 723     (or shut-up
 724         (message "Parsing archive file...done."))
 725     (setq archive-proper-file-start (point-marker))
 726     (narrow-to-region (point-min) (point))
 727     (set-buffer-modified-p nil)
 728     (buffer-enable-undo))
 729   (goto-char archive-file-list-start)
 730   (archive-next-line 0))
 731
 732 (defun archive-resummarize ()
 733   "Recreate the contents listing of an archive."
 734   (let ((modified (buffer-modified-p))
 735         (no (archive-get-lineno))
 736         buffer-read-only)
 737     (widen)
 738     (delete-region (point-min) archive-proper-file-start)
 739     (archive-summarize t)
 740     (set-buffer-modified-p modified)
 741     (goto-char archive-file-list-start)
 742     (archive-next-line no)))
 743
 744 (defun archive-summarize-files (files)
 745   "Insert a description of a list of files annotated with proper mouse face."
 746   (setq archive-file-list-start (point-marker))
 747   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 748   ;; We don't want to do an insert for each element since that takes too
 749   ;; long when the archive -- which has to be moved in memory -- is large.
 750   (insert
 751    (apply
 752     (function concat)
 753     (mapcar
 754      (function
 755       (lambda (fil)
 756         ;; Using `concat' here copies the text also, so we can add
 757         ;; properties without problems.
 758         (let ((text (concat (aref fil 0) "\n")))
 759           (if (featurep 'xemacs)
 760               ()                        ; out of luck
 761             (add-text-properties
 762              (aref fil 1) (aref fil 2)
 763              '(mouse-face highlight
 764                help-echo "mouse-2: extract this file into a buffer")
 765              text))
 766           text)))
 767      files)))
 768   (setq archive-file-list-end (point-marker)))
 769
 770 (defun archive-alternate-display ()
 771   "Toggle alternative display.
 772 To avoid very long lines some archive mode don't show all information.
 773 This function changes the set of information shown for each files."
 774   (interactive)
 775   (setq archive-alternate-display (not archive-alternate-display))
 776   (archive-resummarize))
 777 ;; -------------------------------------------------------------------------
 778 ;; Section: Local archive copy handling
 779
 780 (defun archive-unique-fname (fname dir)
 781   "Make sure a file FNAME can be created uniquely in directory DIR.
 782
 783 If FNAME can be uniquely created in DIR, it is returned unaltered.
 784 If FNAME is something our underlying filesystem can't grok, or if another
 785 file by that name already exists in DIR, a unique new name is generated
 786 using `make-temp-file', and the generated name is returned."
 787   (let ((fullname (expand-file-name fname dir))
 788         (alien (string-match file-name-invalid-regexp fname)))
 789     (if (or alien (file-exists-p fullname))
 790         (make-temp-file
 791          (expand-file-name
 792           (if (if (fboundp 'msdos-long-file-names)
 793                   (not (msdos-long-file-names)))
 794               "am"
 795             "arc-mode.")
 796           dir))
 797       fullname)))
 798
 799 (defun archive-maybe-copy (archive)
 800   (let ((coding-system-for-write 'no-conversion))
 801     (if archive-remote
 802         (let ((start (point-max))
 803               ;; Sometimes ARCHIVE is invalid while its actual name, as
 804               ;; recorded in its parent archive, is not.  For example, an
 805               ;; archive bar.zip inside another archive foo.zip gets a name
 806               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 807               ;; So use the actual name if available.
 808               (archive-name
 809                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 810                    archive)))
 811           (make-directory archive-tmpdir t)
 812           ;; If ARCHIVE includes leading directories, make sure they
 813           ;; exist under archive-tmpdir.
 814           (let ((arch-dir (file-name-directory archive)))
 815             (if arch-dir
 816                 (make-directory (concat
 817                                  (file-name-as-directory archive-tmpdir)
 818                                  arch-dir)
 819                                 t)))
 820           (setq archive-local-name
 821                 (archive-unique-fname archive-name archive-tmpdir))
 822           (save-restriction
 823             (widen)
 824             (write-region start (point-max) archive-local-name nil 'nomessage))
 825           archive-local-name)
 826       (if (buffer-modified-p) (save-buffer))
 827       archive)))
 828
 829 (defun archive-maybe-update (unchanged)
 830   (if archive-remote
 831       (let ((name archive-local-name)
 832             (modified (buffer-modified-p))
 833             (coding-system-for-read 'no-conversion)
 834             (lno (archive-get-lineno))
 835             buffer-read-only)
 836         (if unchanged nil
 837           (setq archive-files nil)
 838           (erase-buffer)
 839           (insert-file-contents name)
 840           (archive-mode t)
 841           (goto-char archive-file-list-start)
 842           (archive-next-line lno))
 843         (archive-delete-local name)
 844         (if (not unchanged)
 845             (message
 846              "Buffer `%s' must be saved for changes to take effect"
 847              (buffer-name (current-buffer))))
 848         (set-buffer-modified-p (or modified (not unchanged))))))
 849
 850 (defun archive-delete-local (name)
 851   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 852   (let ((again t)
 853         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 854     (condition-case nil
 855         (delete-file name)
 856       (error nil))
 857     (while again
 858       (setq name (directory-file-name (file-name-directory name)))
 859       (condition-case nil
 860           (delete-directory name)
 861         (error nil))
 862       (if (string= name top) (setq again nil)))))
 863 ;; -------------------------------------------------------------------------
 864 ;; Section: Member extraction
 865
 866 (defun archive-file-name-handler (op &rest args)
 867   (or (eq op 'file-exists-p)
 868       (let ((file-name-handler-alist nil))
 869         (apply op args))))
 870
 871 (defun archive-set-buffer-as-visiting-file (filename)
 872   "Set the current buffer as if it were visiting FILENAME."
 873   (save-excursion
 874     (goto-char (point-min))
 875     (let ((coding
 876            (or coding-system-for-read
 877                (and set-auto-coding-function
 878                     (save-excursion
 879                       (funcall set-auto-coding-function
 880                                filename (- (point-max) (point-min)))))
 881                ;; dos-w32.el defines find-operation-coding-system for
 882                ;; DOS/Windows systems which preserves the coding-system
 883                ;; of existing files.  We want it to act here as if the
 884                ;; extracted file existed.
 885                (let ((file-name-handler-alist
 886                       '(("" . archive-file-name-handler))))
 887                  (car (find-operation-coding-system 'insert-file-contents
 888                                                     filename t))))))
 889       (if (and (not coding-system-for-read)
 890                (not enable-multibyte-characters))
 891           (setq coding
 892                 (coding-system-change-text-conversion coding 'raw-text)))
 893       (if (and coding
 894                (not (eq coding 'no-conversion)))
 895           (decode-coding-region (point-min) (point-max) coding)
 896         (setq last-coding-system-used coding))
 897       (set-buffer-modified-p nil)
 898       (kill-local-variable 'buffer-file-coding-system)
 899       (after-insert-file-set-coding (- (point-max) (point-min))))))
 900
 901 (defun archive-mouse-extract (event)
 902   "Extract a file whose name you click on."
 903   (interactive "e")
 904   (mouse-set-point event)
 905   (switch-to-buffer
 906    (save-excursion
 907      (archive-extract)
 908      (current-buffer))))
 909
 910 (defun archive-extract (&optional other-window-p)
 911   "In archive mode, extract this entry of the archive into its own buffer."
 912   (interactive)
 913   (let* ((view-p (eq other-window-p 'view))
 914          (descr (archive-get-descr))
 915          (ename (aref descr 0))
 916          (iname (aref descr 1))
 917          (archive-buffer (current-buffer))
 918          (arcdir default-directory)
 919          (archive (buffer-file-name))
 920          (arcname (file-name-nondirectory archive))
 921          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 922          (extractor (archive-name "extract"))
 923          ;; Members with file names which aren't valid for the
 924          ;; underlying filesystem, are treated as read-only.
 925          (read-only-p (or archive-read-only
 926                           view-p
 927                           (string-match file-name-invalid-regexp ename)))
 928          (buffer (get-buffer bufname))
 929          (just-created nil))
 930       (if buffer
 931           nil
 932         (setq archive (archive-maybe-copy archive))
 933         (setq buffer (get-buffer-create bufname))
 934         (setq just-created t)
 935         (save-excursion
 936           (set-buffer buffer)
 937           (setq buffer-file-name
 938                 (expand-file-name (concat arcname ":" iname)))
 939           (setq buffer-file-truename
 940                 (abbreviate-file-name buffer-file-name))
 941           ;; Set the default-directory to the dir of the superior buffer.
 942           (setq default-directory arcdir)
 943           (make-local-variable 'archive-superior-buffer)
 944           (setq archive-superior-buffer archive-buffer)
 945           (make-local-variable 'local-write-file-hooks)
 946           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 947           (setq archive-subfile-mode descr)
 948           (if (and
 949                (null
 950                 (let (;; We may have to encode file name arguement for
 951                       ;; external programs.
 952                       (coding-system-for-write
 953                        (and enable-multibyte-characters
 954                             file-name-coding-system))
 955                       ;; We read an archive member by no-conversion at
 956                       ;; first, then decode appropriately by calling
 957                       ;; archive-set-buffer-as-visiting-file later.
 958                       (coding-system-for-read 'no-conversion))
 959                   (condition-case err
 960                       (if (fboundp extractor)
 961                           (funcall extractor archive ename)
 962                         (archive-*-extract archive ename
 963                                            (symbol-value extractor)))
 964                     (error
 965                      (ding (message "%s" (error-message-string err)))
 966                      nil))))
 967                just-created)
 968               (progn
 969                 (set-buffer-modified-p nil)
 970                 (kill-buffer buffer))
 971             (archive-set-buffer-as-visiting-file ename)
 972             (goto-char (point-min))
 973             (rename-buffer bufname)
 974             (setq buffer-read-only read-only-p)
 975             (setq buffer-undo-list nil)
 976             (set-buffer-modified-p nil)
 977             (setq buffer-saved-size (buffer-size))
 978             (normal-mode)
 979             ;; Just in case an archive occurs inside another archive.
 980             (if (eq major-mode 'archive-mode)
 981                 (progn
 982                   (setq archive-remote t)
 983                   (if read-only-p (setq archive-read-only t))
 984                   ;; We will write out the archive ourselves if it is
 985                   ;; part of another archive.
 986                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 987             (run-hooks 'archive-extract-hooks)
 988             (if archive-read-only
 989                 (message "Note: altering this archive is not implemented."))))
 990         (archive-maybe-update t))
 991       (or (not (buffer-name buffer))
 992           (progn
 993             (if view-p
 994                 (view-buffer buffer (and just-created 'kill-buffer))
 995               (if (eq other-window-p 'display)
 996                   (display-buffer buffer)
 997                 (if other-window-p
 998                     (switch-to-buffer-other-window buffer)
 999                   (switch-to-buffer buffer))))))))
1000
1001 (defun archive-*-extract (archive name command)
1002   (let* ((default-directory (file-name-as-directory archive-tmpdir))
1003          (tmpfile (expand-file-name (file-name-nondirectory name)
1004                                     default-directory))
1005          exit-status success)
1006     (make-directory (directory-file-name default-directory) t)
1007     (setq exit-status
1008           (apply 'call-process
1009                  (car command)
1010                  nil
1011                  nil
1012                  nil
1013                  (append (cdr command) (list archive name))))
1014     (cond ((and (numberp exit-status) (= exit-status 0))
1015            (if (not (file-exists-p tmpfile))
1016                (ding (message "`%s': no such file or directory" tmpfile))
1017              (insert-file-contents tmpfile)
1018              (setq success t)))
1019           ((numberp exit-status)
1020            (ding
1021             (message "`%s' exited with status %d" (car command) exit-status)))
1022           ((stringp exit-status)
1023            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1024           (t
1025            (ding (message "`%s' failed" (car command)))))
1026     (archive-delete-local tmpfile)
1027     success))
1028
1029 (defun archive-extract-by-stdout (archive name command)
1030   (apply 'call-process
1031          (car command)
1032          nil
1033          t
1034          nil
1035          (append (cdr command) (list archive name))))
1036
1037 (defun archive-extract-other-window ()
1038   "In archive mode, find this member in another window."
1039   (interactive)
1040   (archive-extract t))
1041
1042 (defun archive-display-other-window ()
1043   "In archive mode, display this member in another window."
1044   (interactive)
1045   (archive-extract 'display))
1046
1047 (defun archive-view ()
1048   "In archive mode, view the member on this line."
1049   (interactive)
1050   (archive-extract 'view))
1051
1052 (defun archive-add-new-member (arcbuf name)
1053   "Add current buffer to the archive in ARCBUF naming it NAME."
1054   (interactive
1055    (list (get-buffer
1056           (read-buffer "Buffer containing archive: "
1057                        ;; Find first archive buffer and suggest that
1058                        (let ((bufs (buffer-list)))
1059                          (while (and bufs (not (eq (save-excursion
1060                                                      (set-buffer (car bufs))
1061                                                      major-mode)
1062                                                    'archive-mode)))
1063                            (setq bufs (cdr bufs)))
1064                          (if bufs
1065                              (car bufs)
1066                            (error "There are no archive buffers")))
1067                        t))
1068          (read-string "File name in archive: "
1069                       (if buffer-file-name
1070                           (file-name-nondirectory buffer-file-name)
1071                         ""))))
1072   (save-excursion
1073     (set-buffer arcbuf)
1074     (or (eq major-mode 'archive-mode)
1075         (error "Buffer is not an archive buffer"))
1076     (if archive-read-only
1077         (error "Archive is read-only")))
1078   (if (eq arcbuf (current-buffer))
1079       (error "An archive buffer cannot be added to itself"))
1080   (if (string= name "")
1081       (error "Archive members may not be given empty names"))
1082   (let ((func (save-excursion (set-buffer arcbuf)
1083                               (archive-name "add-new-member")))
1084         (membuf (current-buffer)))
1085     (if (fboundp func)
1086         (save-excursion
1087           (set-buffer arcbuf)
1088           (funcall func buffer-file-name membuf name))
1089       (error "Adding a new member is not supported for this archive type"))))
1090 ;; -------------------------------------------------------------------------
1091 ;; Section: IO stuff
1092
1093 (defun archive-write-file-member ()
1094   (save-excursion
1095     (save-restriction
1096       (message "Updating archive...")
1097       (widen)
1098       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1099                                      (archive-name "write-file-member")))
1100             (archive (save-excursion (set-buffer archive-superior-buffer)
1101                                      (archive-maybe-copy (buffer-file-name)))))
1102         (if (fboundp writer)
1103             (funcall writer archive archive-subfile-mode)
1104           (archive-*-write-file-member archive
1105                                        archive-subfile-mode
1106                                        (symbol-value writer)))
1107         (set-buffer-modified-p nil)
1108         (message "Updating archive...done"))
1109       (set-buffer archive-superior-buffer)
1110       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1111   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1112   ;; won't reset the coding-system of this archive member.
1113   (if (local-variable-p 'archive-member-coding-system)
1114       (setq last-coding-system-used archive-member-coding-system))
1115   t)
1116
1117 (defun archive-*-write-file-member (archive descr command)
1118   (let* ((ename (aref descr 0))
1119          (tmpfile (expand-file-name ename archive-tmpdir))
1120          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1121          (default-directory (file-name-as-directory top)))
1122     (unwind-protect
1123         (progn
1124           (make-directory (file-name-directory tmpfile) t)
1125           ;; If the member is itself an archive, write it without
1126           ;; the dired-like listing we created.
1127           (if (eq major-mode 'archive-mode)
1128               (archive-write-file tmpfile)
1129             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1130           ;; basic-save-buffer needs last-coding-system-used to have
1131           ;; the value used to write the file, so save it before any
1132           ;; further processing clobbers it (we restore it in
1133           ;; archive-write-file-member, above).
1134           (setq archive-member-coding-system last-coding-system-used)
1135           (if (aref descr 3)
1136               ;; Set the file modes, but make sure we can read it.
1137               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1138           (if enable-multibyte-characters
1139               (setq ename
1140                     (encode-coding-string ename file-name-coding-system)))
1141           (let ((exitcode (apply 'call-process
1142                                  (car command)
1143                                  nil
1144                                  nil
1145                                  nil
1146                                  (append (cdr command) (list archive ename)))))
1147             (if (equal exitcode 0)
1148                 nil
1149               (error "Updating was unsuccessful (%S)" exitcode))))
1150       (archive-delete-local tmpfile))))
1151
1152 (defun archive-write-file (&optional file)
1153   (save-excursion
1154     (let ((coding-system-for-write 'no-conversion))
1155       (write-region archive-proper-file-start (point-max)
1156                     (or file buffer-file-name) nil t)
1157       (set-buffer-modified-p nil))
1158     t))
1159 ;; -------------------------------------------------------------------------
1160 ;; Section: Marking and unmarking.
1161
1162 (defun archive-flag-deleted (p &optional type)
1163   "In archive mode, mark this member to be deleted from the archive.
1164 With a prefix argument, mark that many files."
1165   (interactive "p")
1166   (or type (setq type ?D))
1167   (beginning-of-line)
1168   (let ((sign (if (>= p 0) +1 -1))
1169         (modified (buffer-modified-p))
1170         buffer-read-only)
1171     (while (not (zerop p))
1172       (if (archive-get-descr t)
1173           (progn
1174             (delete-char 1)
1175             (insert type)))
1176       (forward-line sign)
1177       (setq p (- p sign)))
1178     (set-buffer-modified-p modified))
1179   (archive-next-line 0))
1180
1181 (defun archive-unflag (p)
1182   "In archive mode, un-mark this member if it is marked to be deleted.
1183 With a prefix argument, un-mark that many files forward."
1184   (interactive "p")
1185   (archive-flag-deleted p ? ))
1186
1187 (defun archive-unflag-backwards (p)
1188   "In archive mode, un-mark this member if it is marked to be deleted.
1189 With a prefix argument, un-mark that many members backward."
1190   (interactive "p")
1191   (archive-flag-deleted (- p) ? ))
1192
1193 (defun archive-unmark-all-files ()
1194   "Remove all marks."
1195   (interactive)
1196   (let ((modified (buffer-modified-p))
1197         buffer-read-only)
1198     (save-excursion
1199       (goto-char archive-file-list-start)
1200       (while (< (point) archive-file-list-end)
1201         (or (= (following-char) ? )
1202             (progn (delete-char 1) (insert ? )))
1203         (forward-line 1)))
1204     (set-buffer-modified-p modified)))
1205
1206 (defun archive-mark (p)
1207   "In archive mode, mark this member for group operations.
1208 With a prefix argument, mark that many members.
1209 Use \\[archive-unmark-all-files] to remove all marks."
1210   (interactive "p")
1211   (archive-flag-deleted p ?*))
1212
1213 (defun archive-get-marked (mark &optional default)
1214   (let (files)
1215     (save-excursion
1216       (goto-char archive-file-list-start)
1217       (while (< (point) archive-file-list-end)
1218         (if (= (following-char) mark)
1219             (setq files (cons (archive-get-descr) files)))
1220         (forward-line 1)))
1221     (or (nreverse files)
1222         (and default
1223              (list (archive-get-descr))))))
1224 ;; -------------------------------------------------------------------------
1225 ;; Section: Operate
1226
1227 (defun archive-next-line (p)
1228   (interactive "p")
1229   (forward-line p)
1230   (or (eobp)
1231       (forward-char archive-file-name-indent)))
1232
1233 (defun archive-previous-line (p)
1234   (interactive "p")
1235   (archive-next-line (- p)))
1236
1237 (defun archive-chmod-entry (new-mode)
1238   "Change the protection bits associated with all marked or this member.
1239 The new protection bits can either be specified as an octal number or
1240 as a relative change like \"g+rw\" as for chmod(2)"
1241   (interactive "sNew mode (octal or relative): ")
1242   (if archive-read-only (error "Archive is read-only"))
1243   (let ((func (archive-name "chmod-entry")))
1244     (if (fboundp func)
1245         (progn
1246           (funcall func new-mode (archive-get-marked ?* t))
1247           (archive-resummarize))
1248       (error "Setting mode bits is not supported for this archive type"))))
1249
1250 (defun archive-chown-entry (new-uid)
1251   "Change the owner of all marked or this member."
1252   (interactive "nNew uid: ")
1253   (if archive-read-only (error "Archive is read-only"))
1254   (let ((func (archive-name "chown-entry")))
1255     (if (fboundp func)
1256         (progn
1257           (funcall func new-uid (archive-get-marked ?* t))
1258           (archive-resummarize))
1259       (error "Setting owner is not supported for this archive type"))))
1260
1261 (defun archive-chgrp-entry (new-gid)
1262   "Change the group of all marked or this member."
1263   (interactive "nNew gid: ")
1264   (if archive-read-only (error "Archive is read-only"))
1265   (let ((func (archive-name "chgrp-entry")))
1266     (if (fboundp func)
1267         (progn
1268           (funcall func new-gid (archive-get-marked ?* t))
1269           (archive-resummarize))
1270       (error "Setting group is not supported for this archive type"))))
1271
1272 (defun archive-expunge ()
1273   "Do the flagged deletions."
1274   (interactive)
1275   (let (files)
1276     (save-excursion
1277       (goto-char archive-file-list-start)
1278       (while (< (point) archive-file-list-end)
1279         (if (= (following-char) ?D)
1280             (setq files (cons (aref (archive-get-descr) 0) files)))
1281         (forward-line 1)))
1282     (setq files (nreverse files))
1283     (and files
1284          (or (not archive-read-only)
1285              (error "Archive is read-only"))
1286          (or (yes-or-no-p (format "Really delete %d member%s? "
1287                                   (length files)
1288                                   (if (null (cdr files)) "" "s")))
1289              (error "Operation aborted"))
1290          (let ((archive (archive-maybe-copy (buffer-file-name)))
1291                (expunger (archive-name "expunge")))
1292            (if (fboundp expunger)
1293                (funcall expunger archive files)
1294              (archive-*-expunge archive files (symbol-value expunger)))
1295            (archive-maybe-update nil)
1296            (if archive-remote
1297                (archive-resummarize)
1298              (revert-buffer))))))
1299
1300 (defun archive-*-expunge (archive files command)
1301   (apply 'call-process
1302          (car command)
1303          nil
1304          nil
1305          nil
1306          (append (cdr command) (cons archive files))))
1307
1308 (defun archive-rename-entry (newname)
1309   "Change the name associated with this entry in the tar file."
1310   (interactive "sNew name: ")
1311   (if archive-read-only (error "Archive is read-only"))
1312   (if (string= newname "")
1313       (error "Archive members may not be given empty names"))
1314   (let ((func (archive-name "rename-entry"))
1315         (descr (archive-get-descr)))
1316     (if (fboundp func)
1317         (progn
1318           (funcall func (buffer-file-name)
1319                    (if enable-multibyte-characters
1320                        (encode-coding-string newname file-name-coding-system)
1321                      newname)
1322                    descr)
1323           (archive-resummarize))
1324       (error "Renaming is not supported for this archive type"))))
1325
1326 ;; Revert the buffer and recompute the dired-like listing.
1327 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1328   (let ((no (archive-get-lineno)))
1329     (setq archive-files nil)
1330     (let ((revert-buffer-function nil)
1331           (coding-system-for-read 'no-conversion))
1332       (set-buffer-multibyte nil)
1333       (revert-buffer t t))
1334     (archive-mode)
1335     (goto-char archive-file-list-start)
1336     (archive-next-line no)))
1337
1338 (defun archive-undo ()
1339   "Undo in an archive buffer.
1340 This doesn't recover lost files, it just undoes changes in the buffer itself."
1341   (interactive)
1342   (let (buffer-read-only)
1343     (undo)))
1344 ;; -------------------------------------------------------------------------
1345 ;; Section: Arc Archives
1346
1347 (defun archive-arc-summarize ()
1348   (let ((p 1)
1349         (totalsize 0)
1350         (maxlen 8)
1351         files
1352         visual)
1353     (while (and (< (+ p 29) (point-max))
1354                 (= (char-after p) ?\C-z)
1355                 (> (char-after (1+ p)) 0))
1356       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1357              (fnlen   (or (string-match "\0" namefld) 13))
1358              (efnname (substring namefld 0 fnlen))
1359              (csize   (archive-l-e (+ p 15) 4))
1360              (moddate (archive-l-e (+ p 19) 2))
1361              (modtime (archive-l-e (+ p 21) 2))
1362              (ucsize  (archive-l-e (+ p 25) 4))
1363              (fiddle  (string= efnname (upcase efnname)))
1364              (ifnname (if fiddle (downcase efnname) efnname))
1365              (text    (format "  %8d  %-11s  %-8s  %s"
1366                               ucsize
1367                               (archive-dosdate moddate)
1368                               (archive-dostime modtime)
1369                               ifnname)))
1370         (setq maxlen (max maxlen fnlen)
1371               totalsize (+ totalsize ucsize)
1372               visual (cons (vector text
1373                                    (- (length text) (length ifnname))
1374                                    (length text))
1375                            visual)
1376               files (cons (vector efnname ifnname fiddle nil (1- p))
1377                           files)
1378               p (+ p 29 csize))))
1379     (goto-char (point-min))
1380     (let ((dash (concat "- --------  -----------  --------  "
1381                         (make-string maxlen ?-)
1382                         "\n")))
1383       (insert "M   Length  Date         Time      File\n"
1384               dash)
1385       (archive-summarize-files (nreverse visual))
1386       (insert dash
1387               (format "  %8d                         %d file%s"
1388                       totalsize
1389                       (length files)
1390                       (if (= 1 (length files)) "" "s"))
1391               "\n"))
1392     (apply 'vector (nreverse files))))
1393
1394 (defun archive-arc-rename-entry (archive newname descr)
1395   (if (string-match "[:\\\\/]" newname)
1396       (error "File names in arc files must not contain a directory component"))
1397   (if (> (length newname) 12)
1398       (error "File names in arc files are limited to 12 characters"))
1399   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1400                                          (length newname))))
1401         buffer-read-only)
1402     (save-restriction
1403       (save-excursion
1404         (widen)
1405         (set-buffer-multibyte nil)
1406         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1407         (delete-char 13)
1408         (insert name)))))
1409 ;; -------------------------------------------------------------------------
1410 ;; Section: Lzh Archives
1411
1412 (defun archive-lzh-summarize ()
1413   (let ((p 1)
1414         (totalsize 0)
1415         (maxlen 8)
1416         files
1417         visual)
1418     (while (progn (goto-char p)         ;beginning of a base header.
1419                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1420       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1421              (csize   (archive-l-e (+ p 7) 4)) ;size of a compressed file to follow (level 0 and 2),
1422                                         ;size of extended headers + the compressed file to follow (level 1).
1423              (ucsize  (archive-l-e (+ p 11) 4)) ;size of an uncompressed file.
1424              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1425              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1426              (hdrlvl  (char-after (+ p 20))) ;header level
1427              thsize             ;total header size (base + extensions)
1428              fnlen efnname fiddle ifnname width p2 creator
1429              neh        ;beginning of next extension header (level 1 and 2)
1430              mode modestr uid gid text dir prname
1431              gname uname modtime moddate)
1432         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1433         (when (or (= hdrlvl 0) (= hdrlvl 1))
1434           (setq fnlen   (char-after (+ p 21))) ;filename length
1435           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1436                         (if file-name-coding-system
1437                             (decode-coding-string str file-name-coding-system)
1438                           (string-as-multibyte str))))
1439           (setq p2      (+ p 22 fnlen))) ;
1440         (if (= hdrlvl 1)
1441             (progn              ;specific to level 1 header
1442               (setq creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1443               (setq neh (+ p2 3)))
1444           (if (= hdrlvl 2)
1445               (progn            ;specific to level 2 header
1446                 (setq creator (char-after (+ p 23)) )
1447                 (setq neh (+ p 24)))))
1448         (if neh         ;if level 1 or 2 we expect extension headers to follow
1449             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1450                    (etype (char-after (+ neh 2)))) ;extension type
1451               (while (not (= ehsize 0))
1452                   (cond
1453                  ((= etype 1)   ;file name
1454                   (let ((i (+ neh 3)))
1455                     (while (< i (+ neh ehsize))
1456                       (setq efnname (concat efnname (char-to-string (char-after i))))
1457                       (setq i (1+ i)))))
1458                  ((= etype 2)   ;directory name
1459                   (let ((i (+ neh 3)))
1460                     (while (< i (+ neh ehsize))
1461                                     (setq dir (concat dir
1462                                                        (if (= (char-after i)
1463                                                               255)
1464                                                            "/"
1465                                                          (char-to-string
1466                                                           (char-after i)))))
1467                                     (setq i (1+ i)))))
1468                  ((= etype 80)          ;Unix file permission
1469                   (setq mode (archive-l-e (+ neh 3) 2)))
1470                  ((= etype 81)          ;UNIX file group/user ID
1471                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1472                          (setq gid (archive-l-e (+ neh 5) 2))))
1473                  ((= etype 82)          ;UNIX file group name
1474                   (let ((i (+ neh 3)))
1475                     (while (< i (+ neh ehsize))
1476                       (setq gname (concat gname (char-to-string (char-after i))))
1477                       (setq i (1+ i)))))
1478                  ((= etype 83)          ;UNIX file user name
1479                   (let ((i (+ neh 3)))
1480                     (while (< i (+ neh ehsize))
1481                       (setq uname (concat uname (char-to-string (char-after i))))
1482                       (setq i (1+ i)))))
1483                    )
1484                 (setq neh (+ neh ehsize))
1485                 (setq ehsize (archive-l-e neh 2))
1486                 (setq etype (char-after (+ neh 2))))
1487               ;;get total header size for level 1 and 2 headers
1488               (setq thsize (- neh p))))
1489         (if (= hdrlvl 0)  ;total header size
1490             (setq thsize hsize))
1491         (setq fiddle  (if efnname (string= efnname (upcase efnname))))
1492         (setq ifnname (if fiddle (downcase efnname) efnname))
1493         (setq prname (if dir (concat dir ifnname) ifnname))
1494         (setq width (if prname (string-width prname) 0))
1495         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1496         (setq moddate (if (= hdrlvl 2)
1497                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1498                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1499         (setq modtime (if (= hdrlvl 2)
1500                           (archive-unixtime time1 time2)
1501                         (archive-dostime time1)))
1502         (setq text    (if archive-alternate-display
1503                           (format "  %8d  %5S  %5S  %s"
1504                                   ucsize
1505                                   (or uid "?")
1506                                   (or gid "?")
1507                                   ifnname)
1508                         (format "  %10s  %8d  %-11s  %-8s  %s"
1509                                 modestr
1510                                 ucsize
1511                                 moddate
1512                                 modtime
1513                                 prname)))
1514         (setq maxlen (max maxlen width)
1515               totalsize (+ totalsize ucsize)
1516               visual (cons (vector text
1517                                    (- (length text) (length prname))
1518                                    (length text))
1519                            visual)
1520               files (cons (vector prname ifnname fiddle mode (1- p))
1521                           files))
1522         (cond ((= hdrlvl 1)
1523                (setq p (+ p hsize 2 csize)))
1524               ((or (= hdrlvl 2) (= hdrlvl 0))
1525                (setq p (+ p thsize 2 csize))))
1526         ))
1527     (goto-char (point-min))
1528     (set-buffer-multibyte default-enable-multibyte-characters)
1529     (let ((dash (concat (if archive-alternate-display
1530                             "- --------  -----  -----  "
1531                           "- ----------  --------  -----------  --------  ")
1532                         (make-string maxlen ?-)
1533                         "\n"))
1534           (header (if archive-alternate-display
1535                        "M   Length    Uid    Gid  File\n"
1536                     "M   Filemode    Length  Date         Time      File\n"))
1537           (sumline (if archive-alternate-display
1538                        "  %8d                %d file%s"
1539                      "              %8d                         %d file%s")))
1540       (insert header dash)
1541       (archive-summarize-files (nreverse visual))
1542       (insert dash
1543               (format sumline
1544                       totalsize
1545                       (length files)
1546                       (if (= 1 (length files)) "" "s"))
1547               "\n"))
1548     (apply 'vector (nreverse files))))
1549
1550 (defconst archive-lzh-alternate-display t)
1551
1552 (defun archive-lzh-extract (archive name)
1553   (archive-extract-by-stdout archive name archive-lzh-extract))
1554
1555 (defun archive-lzh-resum (p count)
1556   (let ((sum 0))
1557     (while (> count 0)
1558       (setq count (1- count)
1559             sum (+ sum (char-after p))
1560             p (1+ p)))
1561     (logand sum 255)))
1562
1563 (defun archive-lzh-rename-entry (archive newname descr)
1564   (save-restriction
1565     (save-excursion
1566       (widen)
1567       (set-buffer-multibyte nil)
1568       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1569              (oldhsize (char-after p))
1570              (oldfnlen (char-after (+ p 21)))
1571              (newfnlen (length newname))
1572              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1573              buffer-read-only)
1574         (if (> newhsize 255)
1575             (error "The file name is too long"))
1576         (goto-char (+ p 21))
1577         (delete-char (1+ oldfnlen))
1578         (insert newfnlen newname)
1579         (goto-char p)
1580         (delete-char 2)
1581         (insert newhsize (archive-lzh-resum p newhsize))))))
1582
1583 (defun archive-lzh-ogm (newval files errtxt ofs)
1584   (save-restriction
1585     (save-excursion
1586       (widen)
1587       (set-buffer-multibyte nil)
1588       (while files
1589         (let* ((fil (car files))
1590                (p (+ archive-proper-file-start (aref fil 4)))
1591                (hsize   (char-after p))
1592                (fnlen   (char-after (+ p 21)))
1593                (p2      (+ p 22 fnlen))
1594                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1595                buffer-read-only)
1596           (if (= creator ?U)
1597               (progn
1598                 (or (numberp newval)
1599                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1600                 (goto-char (+ p2 ofs))
1601                 (delete-char 2)
1602                 (insert (logand newval 255) (lsh newval -8))
1603                 (goto-char (1+ p))
1604                 (delete-char 1)
1605                 (insert (archive-lzh-resum (1+ p) hsize)))
1606             (message "Member %s does not have %s field"
1607                      (aref fil 1) errtxt)))
1608         (setq files (cdr files))))))
1609
1610 (defun archive-lzh-chown-entry (newuid files)
1611   (archive-lzh-ogm newuid files "an uid" 10))
1612
1613 (defun archive-lzh-chgrp-entry (newgid files)
1614   (archive-lzh-ogm newgid files "a gid" 12))
1615
1616 (defun archive-lzh-chmod-entry (newmode files)
1617   (archive-lzh-ogm
1618    ;; This should work even though newmode will be dynamically accessed.
1619    (function (lambda (old) (archive-calc-mode old newmode t)))
1620    files "a unix-style mode" 8))
1621 ;; -------------------------------------------------------------------------
1622 ;; Section: Zip Archives
1623
1624 (defun archive-zip-summarize ()
1625   (goto-char (- (point-max) (- 22 18)))
1626   (search-backward-regexp "[P]K\005\006")
1627   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1628         (maxlen 8)
1629         (totalsize 0)
1630         files
1631         visual)
1632     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1633       (let* ((creator (char-after (+ p 5)))
1634              (method  (archive-l-e (+ p 10) 2))
1635              (modtime (archive-l-e (+ p 12) 2))
1636              (moddate (archive-l-e (+ p 14) 2))
1637              (ucsize  (archive-l-e (+ p 24) 4))
1638              (fnlen   (archive-l-e (+ p 28) 2))
1639              (exlen   (archive-l-e (+ p 30) 2))
1640              (fclen   (archive-l-e (+ p 32) 2))
1641              (lheader (archive-l-e (+ p 42) 4))
1642              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1643                         (if file-name-coding-system
1644                             (decode-coding-string str file-name-coding-system)
1645                           (string-as-multibyte str))))
1646              (isdir   (and (= ucsize 0)
1647                            (string= (file-name-nondirectory efnname) "")))
1648              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1649                              (archive-l-e (+ p 40) 2))
1650                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1651                              (logior ?\444
1652                                      (if isdir (logior 16384 ?\111) 0)
1653                                      (if (zerop
1654                                           (logand 1 (char-after (+ p 38))))
1655                                          ?\222 0)))
1656                             (t nil)))
1657              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1658              (fiddle  (and archive-zip-case-fiddle
1659                            (not (not (memq creator '(0 2 4 5 9))))
1660                            (string= (upcase efnname) efnname)))
1661              (ifnname (if fiddle (downcase efnname) efnname))
1662              (width (string-width ifnname))
1663              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1664                               modestr
1665                               ucsize
1666                               (archive-dosdate moddate)
1667                               (archive-dostime modtime)
1668                               ifnname)))
1669         (setq maxlen (max maxlen width)
1670               totalsize (+ totalsize ucsize)
1671               visual (cons (vector text
1672                                    (- (length text) (length ifnname))
1673                                    (length text))
1674                            visual)
1675               files (cons (if isdir
1676                               nil
1677                             (vector efnname ifnname fiddle mode
1678                                     (list (1- p) lheader)))
1679                           files)
1680               p (+ p 46 fnlen exlen fclen))))
1681     (goto-char (point-min))
1682     (let ((dash (concat "- ----------  --------  -----------  --------  "
1683                         (make-string maxlen ?-)
1684                         "\n")))
1685       (insert "M Filemode      Length  Date         Time      File\n"
1686               dash)
1687       (archive-summarize-files (nreverse visual))
1688       (insert dash
1689               (format "              %8d                         %d file%s"
1690                       totalsize
1691                       (length files)
1692                       (if (= 1 (length files)) "" "s"))
1693               "\n"))
1694     (apply 'vector (nreverse files))))
1695
1696 (defun archive-zip-extract (archive name)
1697   (if (equal (car archive-zip-extract) "pkzip")
1698       (archive-*-extract archive name archive-zip-extract)
1699     (archive-extract-by-stdout archive name archive-zip-extract)))
1700
1701 (defun archive-zip-write-file-member (archive descr)
1702   (archive-*-write-file-member
1703    archive
1704    descr
1705    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1706
1707 (defun archive-zip-chmod-entry (newmode files)
1708   (save-restriction
1709     (save-excursion
1710       (widen)
1711       (set-buffer-multibyte nil)
1712       (while files
1713         (let* ((fil (car files))
1714                (p (+ archive-proper-file-start (car (aref fil 4))))
1715                (creator (char-after (+ p 5)))
1716                (oldmode (aref fil 3))
1717                (newval  (archive-calc-mode oldmode newmode t))
1718                buffer-read-only)
1719           (cond ((memq creator '(2 3)) ; Unix + VMS
1720                  (goto-char (+ p 40))
1721                  (delete-char 2)
1722                  (insert (logand newval 255) (lsh newval -8)))
1723                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1724                  (goto-char (+ p 38))
1725                  (insert (logior (logand (char-after (point)) 254)
1726                                  (logand (logxor 1 (lsh newval -7)) 1)))
1727                  (delete-char 1))
1728                 (t (message "Don't know how to change mode for this member"))))
1729         (setq files (cdr files))))))
1730 ;; -------------------------------------------------------------------------
1731 ;; Section: Zoo Archives
1732
1733 (defun archive-zoo-summarize ()
1734   (let ((p (1+ (archive-l-e 25 4)))
1735         (maxlen 8)
1736         (totalsize 0)
1737         files
1738         visual)
1739     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1740                 (> (archive-l-e (+ p 6) 4) 0))
1741       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1742              (moddate (archive-l-e (+ p 14) 2))
1743              (modtime (archive-l-e (+ p 16) 2))
1744              (ucsize  (archive-l-e (+ p 20) 4))
1745              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1746              (dirtype (char-after (+ p 4)))
1747              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1748              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1749              (fnlen   (or (string-match "\0" namefld) 13))
1750              (efnname (let ((str
1751                              (concat
1752                               (if (> ldirlen 0)
1753                                   (concat (buffer-substring
1754                                            (+ p 58 lfnlen)
1755                                            (+ p 58 lfnlen ldirlen -1))
1756                                           "/")
1757                                 "")
1758                               (if (> lfnlen 0)
1759                                   (buffer-substring (+ p 58)
1760                                                     (+ p 58 lfnlen -1))
1761                                 (substring namefld 0 fnlen)))))
1762                         (if file-name-coding-system
1763                             (decode-coding-string str file-name-coding-system)
1764                           (string-as-multibyte str))))
1765              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1766              (ifnname (if fiddle (downcase efnname) efnname))
1767              (width (string-width ifnname))
1768              (text    (format "  %8d  %-11s  %-8s  %s"
1769                               ucsize
1770                               (archive-dosdate moddate)
1771                               (archive-dostime modtime)
1772                               ifnname)))
1773         (setq maxlen (max maxlen width)
1774               totalsize (+ totalsize ucsize)
1775               visual (cons (vector text
1776                                    (- (length text) (length ifnname))
1777                                    (length text))
1778                            visual)
1779               files (cons (vector efnname ifnname fiddle nil (1- p))
1780                           files)
1781               p next)))
1782     (goto-char (point-min))
1783     (let ((dash (concat "- --------  -----------  --------  "
1784                         (make-string maxlen ?-)
1785                         "\n")))
1786       (insert "M   Length  Date         Time      File\n"
1787               dash)
1788       (archive-summarize-files (nreverse visual))
1789       (insert dash
1790               (format "  %8d                         %d file%s"
1791                       totalsize
1792                       (length files)
1793                       (if (= 1 (length files)) "" "s"))
1794               "\n"))
1795     (apply 'vector (nreverse files))))
1796
1797 (defun archive-zoo-extract (archive name)
1798   (archive-extract-by-stdout archive name archive-zoo-extract))
1799 ;; -------------------------------------------------------------------------
1800 ;; This line was a mistake; it is kept now for compatibility.
1801 ;; rms  15 Oct 98
1802 (provide 'archive-mode)
1803
1804 (provide 'arc-mode)
1805
1806 ;; arch-tag: e5966a01-35ec-4f27-8095-a043a79b457b
1807 ;;; arc-mode.el ends here