configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 165
 166 ## For the times when you want to build Emacs but don't have
 167 ## a suitable makeinfo, and can live without the manuals.
 168 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 169 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 170
 171 dnl Can remove these in Emacs 24.
 172 AC_ARG_WITH([gtk],,
 173   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 174 specify a toolkit.])],,)
 175
 176 AC_ARG_WITH([gcc],,
 177   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 178 variable to specify a compiler.])],,)
 179
 180 AC_ARG_WITH([pkg-config-prog],dnl
 181 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 182                   [path to pkg-config for finding GTK and librsvg])])
 183 if test "X${with_pkg_config_prog}" != X; then
 184    if test "${with_pkg_config_prog}" != yes; then
 185       PKG_CONFIG="${with_pkg_config_prog}"
 186    fi
 187 fi
 188
 189 CRT_DIR=
 190 AC_ARG_WITH([crt-dir],dnl
 191 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 192 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 193 CRT_DIR="${with_crt_dir}"
 194
 195 AC_ARG_WITH([gnustep-conf],dnl
 196 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 197 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 198   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 199 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 200      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 201
 202 AC_ARG_ENABLE(ns-self-contained,
 203 [AS_HELP_STRING([--disable-ns-self-contained],
 204                 [disable self contained build under NeXTstep])],
 205    EN_NS_SELF_CONTAINED=$enableval,
 206    EN_NS_SELF_CONTAINED=yes)
 207
 208 AC_ARG_ENABLE(asserts,
 209 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 210       USE_XASSERTS=$enableval,
 211       USE_XASSERTS=no)
 212
 213 AC_ARG_ENABLE(maintainer-mode,
 214 [AS_HELP_STRING([--enable-maintainer-mode],
 215                 [enable make rules and dependencies not useful (and sometimes
 216                  confusing) to the casual installer])],
 217       USE_MAINTAINER_MODE=$enableval,
 218       USE_MAINTAINER_MODE=no)
 219 if test $USE_MAINTAINER_MODE = yes; then
 220   MAINT=
 221 else
 222   MAINT=#
 223 fi
 224 AC_SUBST(MAINT)
 225
 226 AC_ARG_ENABLE(locallisppath,
 227 [AS_HELP_STRING([--enable-locallisppath=PATH],
 228                 [directories Emacs should search for lisp files specific
 229                  to this site])],
 230 if test "${enableval}" = "no"; then
 231   locallisppath=
 232 elif test "${enableval}" != "yes"; then
 233   locallisppath=${enableval}
 234 fi)
 235
 236 AC_ARG_ENABLE(checking,
 237 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 238                 [enable expensive run-time checks.  With LIST,
 239                  enable only specific categories of checks.
 240                  Categories are: all,yes,no.
 241                  Flags are: stringbytes, stringoverrun, stringfreelist,
 242                  xmallocoverrun, conslist])],
 243 [ac_checking_flags="${enableval}"],[])
 244 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 245 for check in $ac_checking_flags
 246 do
 247         case $check in
 248         # these set all the flags to specific states
 249         yes)            ac_enable_checking=1 ;;
 250         no)             ac_enable_checking= ;
 251                         ac_gc_check_stringbytes= ;
 252                         ac_gc_check_string_overrun= ;
 253                         ac_gc_check_string_free_list= ;
 254                         ac_xmalloc_overrun= ;
 255                         ac_gc_check_cons_list= ;;
 256         all)            ac_enable_checking=1 ;
 257                         ac_gc_check_stringbytes=1 ;
 258                         ac_gc_check_string_overrun=1 ;
 259                         ac_gc_check_string_free_list=1 ;
 260                         ac_xmalloc_overrun=1 ;
 261                         ac_gc_check_cons_list=1 ;;
 262         # these enable particular checks
 263         stringbytes)    ac_gc_check_stringbytes=1 ;;
 264         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 265         stringfreelist) ac_gc_check_string_free_list=1 ;;
 266         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 267         conslist)       ac_gc_check_cons_list=1 ;;
 268         *)      AC_MSG_ERROR(unknown check category $check) ;;
 269         esac
 270 done
 271 IFS="$ac_save_IFS"
 272
 273 if test x$ac_enable_checking != x ; then
 274   AC_DEFINE(ENABLE_CHECKING, 1,
 275 [Enable expensive run-time checking of data types?])
 276 fi
 277 if test x$ac_gc_check_stringbytes != x ; then
 278   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 279 [Define this temporarily to hunt a bug.  If defined, the size of
 280    strings is redundantly recorded in sdata structures so that it can
 281    be compared to the sizes recorded in Lisp strings.])
 282 fi
 283 if test x$ac_gc_check_stringoverrun != x ; then
 284   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 285 [Define this to check for short string overrun.])
 286 fi
 287 if test x$ac_gc_check_string_free_list != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 289 [Define this to check the string free list.])
 290 fi
 291 if test x$ac_xmalloc_overrun != x ; then
 292   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 293 [Define this to check for malloc buffer overrun.])
 294 fi
 295 if test x$ac_gc_check_cons_list != x ; then
 296   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 297 [Define this to check for errors in cons list.])
 298 fi
 299
 300 AC_ARG_ENABLE(profiling,
 301 [AS_HELP_STRING([--enable-profiling],
 302                 [build emacs with profiling support.
 303                  This might not work on all platforms])],
 304 [ac_enable_profiling="${enableval}"],[])
 305 if test x$ac_enable_profiling != x ; then
 306    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 307    PROFILING_LDFLAGS="-pg"
 308 else
 309    PROFILING_CFLAGS=
 310    PROFILING_LDFLAGS=
 311 fi
 312
 313 AC_ARG_ENABLE(autodepend,
 314 [AS_HELP_STRING([--enable-autodepend],
 315                 [automatically generate dependencies to .h-files.
 316                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 317                  found])],
 318 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 319
 320 #### Make srcdir absolute, if it isn't already.  It's important to
 321 #### avoid running the path through pwd unnecessarily, since pwd can
 322 #### give you automounter prefixes, which can go away.  We do all this
 323 #### so Emacs can find its files when run uninstalled.
 324 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 325 unset CDPATH
 326 case "${srcdir}" in
 327   /* ) ;;
 328   . )
 329     ## We may be able to use the $PWD environment variable to make this
 330     ## absolute.  But sometimes PWD is inaccurate.
 331     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 332     ## but that tested only for a well-formed and valid PWD,
 333     ## it did not object when PWD was well-formed and valid but just wrong.
 334     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 335     then
 336       srcdir="$PWD"
 337     else
 338       srcdir="`(cd ${srcdir}; pwd)`"
 339     fi
 340   ;;
 341   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 342 esac
 343
 344 #### Check if the source directory already has a configured system in it.
 345 if test `pwd` != `(cd ${srcdir} && pwd)` \
 346    && test -f "${srcdir}/src/config.h" ; then
 347   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 348    as a build directory right now; it has been configured in its own
 349    right.  To configure in another directory as well, you MUST
 350    use GNU make.  If you do not have GNU make, then you must
 351    now do `make distclean' in ${srcdir},
 352    and then run $0 again.]])
 353 fi
 354
 355 #### Given the configuration name, set machfile and opsysfile to the
 356 #### names of the m/*.h and s/*.h files we should use.
 357
 358 ### Canonicalize the configuration name.
 359
 360 AC_CANONICAL_HOST
 361 canonical=$host
 362 configuration=${host_alias-${build_alias-$host}}
 363
 364 dnl This used to use changequote, but, apart from `changequote is evil'
 365 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 366 dnl the great gob of text.  Thus it's not processed for possible expansion.
 367 dnl Just make sure the brackets remain balanced.
 368 dnl
 369 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 370 dnl indicated by comments.
 371 dnl quotation begins
 372 [
 373
 374 ### If you add support for a new configuration, add code to this
 375 ### switch statement to recognize your configuration name and select
 376 ### the appropriate operating system and machine description files.
 377
 378 ### You would hope that you could choose an m/*.h file pretty much
 379 ### based on the machine portion of the configuration name, and an s-
 380 ### file based on the operating system portion.  However, it turns out
 381 ### that each m/*.h file is pretty manufacturer-specific - for
 382 ### example mips.h is MIPS
 383 ### So we basically have to have a special case for each
 384 ### configuration name.
 385 ###
 386 ### As far as handling version numbers on operating systems is
 387 ### concerned, make sure things will fail in a fixable way.  If
 388 ### /etc/MACHINES doesn't say anything about version numbers, be
 389 ### prepared to handle anything reasonably.  If version numbers
 390 ### matter, be sure /etc/MACHINES says something about it.
 391 ###
 392 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 393 ### "System V Release 4"; he writes, "The old convention encouraged
 394 ### confusion between `system' and `release' levels'."
 395
 396 machine='' opsys='' unported=no
 397 case "${canonical}" in
 398
 399   ## FreeBSD ports
 400   *-*-freebsd* )
 401     opsys=freebsd
 402     case "${canonical}" in
 403       alpha*-*-freebsd*)        machine=alpha ;;
 404       arm*-*-freebsd*)          machine=arm ;;
 405       ia64-*-freebsd*)          machine=ia64 ;;
 406       sparc-*-freebsd*)         machine=sparc ;;
 407       sparc64-*-freebsd*)       machine=sparc ;;
 408       powerpc-*-freebsd*)       machine=macppc ;;
 409       i[3456]86-*-freebsd*)     machine=intel386 ;;
 410       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 411     esac
 412   ;;
 413
 414   ## FreeBSD kernel + glibc based userland
 415   *-*-kfreebsd*gnu* )
 416     opsys=gnu-kfreebsd
 417     case "${canonical}" in
 418       alpha*-*-kfreebsd*)       machine=alpha ;;
 419       ia64-*-kfreebsd*)         machine=ia64 ;;
 420       sparc-*-kfreebsd*)        machine=sparc ;;
 421       sparc64-*-kfreebsd*)      machine=sparc ;;
 422       powerpc-*-kfreebsd*)      machine=macppc ;;
 423       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 424       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 425     esac
 426   ;;
 427
 428   ## NetBSD ports
 429   *-*-netbsd* )
 430     opsys=netbsd
 431     case "${canonical}" in
 432       alpha*-*-netbsd*) machine=alpha ;;
 433       i[3456]86-*-netbsd*) machine=intel386 ;;
 434       mips-*-netbsd*)   machine=mips ;;
 435       mipsel-*-netbsd*) machine=mips ;;
 436       mipseb-*-netbsd*) machine=mips ;;
 437       powerpc-*-netbsd*) machine=macppc ;;
 438       sparc*-*-netbsd*) machine=sparc ;;
 439       vax-*-netbsd*)    machine=vax ;;
 440       arm-*-netbsd*)    machine=arm ;;
 441       x86_64-*-netbsd*) machine=amdx86-64 ;;
 442       hppa-*-netbsd*)   machine=hp800 ;;
 443       m68k-*-netbsd*)   machine=m68k ;;
 444     esac
 445   ;;
 446
 447   ## OpenBSD ports
 448   *-*-openbsd* )
 449     opsys=openbsd
 450     case "${canonical}" in
 451       alpha*-*-openbsd*)        machine=alpha ;;
 452       arm-*-openbsd*)          machine=arm ;;
 453       i386-*-openbsd*)         machine=intel386 ;;
 454       powerpc-*-openbsd*)      machine=macppc ;;
 455       sparc*-*-openbsd*)       machine=sparc ;;
 456       vax-*-openbsd*)          machine=vax ;;
 457       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 458       hppa-*-openbsd*)         machine=hp800 ;;
 459     esac
 460   ;;
 461
 462   alpha*-*-linux-gnu* )
 463     machine=alpha opsys=gnu-linux
 464   ;;
 465
 466   arm*-*-linux-gnu* )
 467     machine=arm opsys=gnu-linux
 468   ;;
 469
 470   ## Apple Darwin / Mac OS X
 471   *-apple-darwin* )
 472     case "${canonical}" in
 473       i[3456]86-* )  machine=intel386 ;;
 474       powerpc-* )    machine=macppc ;;
 475       x86_64-* )     machine=amdx86-64 ;;
 476       * )            unported=yes ;;
 477     esac
 478     opsys=darwin
 479     # Define CPP as follows to make autoconf work correctly.
 480     CPP="${CC-cc} -E -no-cpp-precomp"
 481     # Use fink packages if available.
 482     if test -d /sw/include && test -d /sw/lib; then
 483       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 484       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 485       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 486     fi
 487   ;;
 488
 489   ## HP 9000 series 700 and 800, running HP/UX
 490   hppa*-hp-hpux10.2* )
 491     machine=hp800 opsys=hpux10-20
 492   ;;
 493   hppa*-hp-hpux1[1-9]* )
 494     machine=hp800 opsys=hpux11
 495     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 496   ;;
 497
 498   hppa*-*-linux-gnu* )
 499     machine=hp800 opsys=gnu-linux
 500   ;;
 501
 502   ## IBM machines
 503   s390-*-linux-gnu* )
 504     machine=ibms390 opsys=gnu-linux
 505   ;;
 506   s390x-*-linux-gnu* )
 507     machine=ibms390x opsys=gnu-linux
 508   ;;
 509   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 510     machine=ibmrs6000 opsys=aix4-2
 511   ;;
 512   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521
 522   ## Macintosh PowerPC
 523   powerpc*-*-linux-gnu* )
 524     machine=macppc opsys=gnu-linux
 525   ;;
 526
 527   ## Silicon Graphics machines
 528   ## Iris 4D
 529   mips-sgi-irix6.5 )
 530     machine=iris4d opsys=irix6-5
 531     # Without defining _LANGUAGE_C, things get masked out in the headers
 532     # so that, for instance, grepping for `free' in stdlib.h fails and
 533     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 534     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 535     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 536   ;;
 537
 538   ## Suns
 539   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 540     machine=sparc opsys=gnu-linux
 541   ;;
 542
 543   *-sun-solaris* \
 544     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 545     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## IA-64
 583   ia64*-*-linux* )
 584     machine=ia64 opsys=gnu-linux
 585   ;;
 586
 587   ## Intel 386 machines where we don't care about the manufacturer
 588   i[3456]86-*-* )
 589     machine=intel386
 590     case "${canonical}" in
 591       *-cygwin )                opsys=cygwin ;;
 592       *-darwin* )               opsys=darwin
 593                                 CPP="${CC-cc} -E -no-cpp-precomp"
 594                                 ;;
 595       *-linux-gnu* )            opsys=gnu-linux ;;
 596       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 600     esac
 601   ;;
 602
 603   ## m68k Linux-based GNU system
 604   m68k-*-linux-gnu* )
 605     machine=m68k opsys=gnu-linux
 606   ;;
 607
 608   ## Mips Linux-based GNU system
 609   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 610     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 611     machine=mips opsys=gnu-linux
 612   ;;
 613
 614   ## AMD x86-64 Linux-based GNU system
 615   x86_64-*-linux-gnu* )
 616     machine=amdx86-64 opsys=gnu-linux
 617   ;;
 618
 619   ## Tensilica Xtensa Linux-based GNU system
 620   xtensa*-*-linux-gnu* )
 621     machine=xtensa opsys=gnu-linux
 622     ;;
 623
 624   ## SuperH Linux-based GNU system
 625   sh[34]*-*-linux-gnu* )
 626     machine=sh3 opsys=gnu-linux
 627   ;;
 628
 629   * )
 630     unported=yes
 631   ;;
 632 esac
 633
 634 ### If the code above didn't choose an operating system, just choose
 635 ### an operating system based on the configuration name.  You really
 636 ### only want to use this when you have no idea what the right
 637 ### operating system is; if you know what operating systems a machine
 638 ### runs, it's cleaner to make it explicit in the case statement
 639 ### above.
 640 if test x"${opsys}" = x; then
 641   case "${canonical}" in
 642     *-gnu* )                            opsys=gnu ;;
 643     * )
 644       unported=yes
 645     ;;
 646   esac
 647 fi
 648
 649 ]
 650 dnl quotation ends
 651
 652 if test $unported = yes; then
 653   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 654 Check `etc/MACHINES' for recognized configuration names.])
 655 fi
 656
 657 machfile="m/${machine}.h"
 658 opsysfile="s/${opsys}.h"
 659
 660
 661 #### Choose a compiler.
 662 test -n "$CC" && cc_specified=yes
 663
 664 # Save the value of CFLAGS that the user specified.
 665 SPECIFIED_CFLAGS="$CFLAGS"
 666
 667 dnl Sets GCC=yes if using gcc.
 668 AC_PROG_CC
 669
 670 # On Suns, sometimes $CPP names a directory.
 671 if test -n "$CPP" && test -d "$CPP"; then
 672   CPP=
 673 fi
 674
 675 ## If not using gcc, and on Solaris, and no CPP specified, see if
 676 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 677 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 678  test x"$CPP" = x; then
 679   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 680   AC_CACHE_VAL(emacs_cv_sunpro_c,
 681   [AC_TRY_LINK([],
 682 [#ifndef __SUNPRO_C
 683 fail;
 684 #endif
 685 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 686   AC_MSG_RESULT($emacs_cv_sunpro_c)
 687
 688   if test x"$emacs_cv_sunpro_c" = xyes; then
 689     NON_GNU_CPP="$CC -E -Xs"
 690   fi
 691 fi
 692
 693 #### Some systems specify a CPP to use unless we are using GCC.
 694 #### Now that we know whether we are using GCC, we can decide whether
 695 #### to use that one.
 696 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 697 then
 698   CPP="$NON_GNU_CPP"
 699 fi
 700
 701 #### Some systems specify a CC to use unless we are using GCC.
 702 #### Now that we know whether we are using GCC, we can decide whether
 703 #### to use that one.
 704 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 705   test x$cc_specified != xyes
 706 then
 707   CC="$NON_GNU_CC"
 708 fi
 709
 710 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 711 then
 712   CC="$CC $GCC_TEST_OPTIONS"
 713 fi
 714
 715 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 716 then
 717   CC="$CC $NON_GCC_TEST_OPTIONS"
 718 fi
 719
 720 dnl checks for Unix variants
 721 AC_USE_SYSTEM_EXTENSIONS
 722
 723 ### Use -Wno-pointer-sign if the compiler supports it
 724 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 725 SAVE_CFLAGS="$CFLAGS"
 726 CFLAGS="$CFLAGS -Wno-pointer-sign"
 727 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 728 if test $has_option = yes; then
 729    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 730 fi
 731 AC_MSG_RESULT($has_option)
 732 CFLAGS="$SAVE_CFLAGS"
 733 unset has_option
 734 unset SAVE_CFLAGS
 735
 736 ### Use -Wdeclaration-after-statement if the compiler supports it
 737 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 738 SAVE_CFLAGS="$CFLAGS"
 739 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 740 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 741 if test $has_option = yes; then
 742    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 743 fi
 744 AC_MSG_RESULT($has_option)
 745 CFLAGS="$SAVE_CFLAGS"
 746 unset has_option
 747 unset SAVE_CFLAGS
 748
 749 #### Some other nice autoconf tests.
 750
 751 dnl checks for programs
 752 AC_PROG_CPP
 753 AC_PROG_INSTALL
 754 if test "x$RANLIB" = x; then
 755   AC_PROG_RANLIB
 756 fi
 757
 758 ## Although we're running on an amd64 kernel, we're actually compiling for
 759 ## the x86 architecture.  The user should probably have provided an
 760 ## explicit --build to `configure', but if everything else than the kernel
 761 ## is running in i386 mode, we can help them out.
 762 if test "$machine" = "amdx86-64"; then
 763   AC_CHECK_DECL([i386])
 764   if test "$ac_cv_have_decl_i386" = "yes"; then
 765     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 766     machine=intel386
 767     machfile="m/${machine}.h"
 768   fi
 769 fi
 770
 771 AC_PATH_PROG(INSTALL_INFO, install-info)
 772 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 773 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777
 778 ## Need makeinfo >= 4.6 (?) to build the manuals.
 779 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 780 dnl By this stage, configure has already checked for egrep and set EGREP,
 781 dnl or exited with an error if no egrep was found.
 782 if test "$MAKEINFO" != "no" && \
 783   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 784    MAKEINFO=no
 785 fi
 786
 787 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 788 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 789 ## therefore in the category of "special tools" not normally required, which
 790 ## configure does not have to check for (eg autoconf itself).
 791 ## In a Bazaar checkout on the other hand, the manuals are not included.
 792 ## So makeinfo is a requirement to build from Bazaar, and configure
 793 ## should test for it as it does for any other build requirement.
 794 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 795 ## with pre-built manuals, from a Bazaar checkout.
 796 if test "$MAKEINFO" = "no"; then
 797   if test "x${with_makeinfo}" = "xno"; then
 798     MAKEINFO=off
 799   elif test ! -e $srcdir/info/emacs; then
 800     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 801 source tree does not seem to have pre-built manuals in the `info' directory.
 802 Either install a suitable version of makeinfo, or re-run configure
 803 with the `--without-makeinfo' option to build without the manuals.] )
 804   fi
 805 fi
 806
 807 dnl Add our options to ac_link now, after it is set up.
 808
 809 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 810 then
 811   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 812 fi
 813
 814 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 815 then
 816   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 817 fi
 818
 819 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 820 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 821 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 822 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 823 dnl if not built to support GNU ld.
 824
 825 late_LDFLAGS=$LDFLAGS
 826 if test "$GCC" = yes; then
 827   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 828 else
 829   LDFLAGS="$LDFLAGS -znocombreloc"
 830 fi
 831
 832 AC_MSG_CHECKING([for -znocombreloc])
 833 AC_LINK_IFELSE([main(){return 0;}],
 834   [AC_MSG_RESULT(yes)],
 835   LDFLAGS=$late_LDFLAGS
 836   [AC_MSG_RESULT(no)])
 837
 838 #### Extract some information from the operating system and machine files.
 839
 840 AC_CHECKING([the machine- and system-dependent files to find out
 841  - which libraries the lib-src programs will want, and
 842  - whether the GNU malloc routines are usable])
 843
 844 ### First figure out CFLAGS (which we use for running the compiler here)
 845 ### and REAL_CFLAGS (which we use for real compilation).
 846 ### The two are the same except on a few systems, where they are made
 847 ### different to work around various lossages.  For example,
 848 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 849 ### as implying static linking.
 850
 851 ### If the CFLAGS env var is specified, we use that value
 852 ### instead of the default.
 853
 854 ### It's not important that this name contain the PID; you can't run
 855 ### two configures in the same directory and have anything work
 856 ### anyway.
 857 tempcname="conftest.c"
 858
 859 echo '
 860 #include "'${srcdir}'/src/'${opsysfile}'"
 861 #include "'${srcdir}'/src/'${machfile}'"
 862
 863 configure___ LIBX=-lX11
 864
 865 configure___ unexec=UNEXEC
 866
 867 #ifdef SYSTEM_MALLOC
 868 configure___ system_malloc=yes
 869 #else
 870 configure___ system_malloc=no
 871 #endif
 872
 873 #ifdef USE_MMAP_FOR_BUFFERS
 874 configure___ use_mmap_for_buffers=yes
 875 #else
 876 configure___ use_mmap_for_buffers=no
 877 #endif
 878
 879 #ifndef C_OPTIMIZE_SWITCH
 880 #ifdef __GNUC__
 881 #define C_OPTIMIZE_SWITCH -O2
 882 #else
 883 #define C_OPTIMIZE_SWITCH -O
 884 #endif
 885 #endif
 886
 887 #ifndef C_WARNINGS_SWITCH
 888 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 889 #endif
 890
 891 #ifdef THIS_IS_CONFIGURE
 892
 893 /* Get the CFLAGS for tests in configure.  */
 894 #ifdef __GNUC__
 895 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 896 #else
 897 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 898 #endif
 899
 900 #else /* not THIS_IS_CONFIGURE */
 901
 902 /* Get the CFLAGS for real compilation.  */
 903 #ifdef __GNUC__
 904 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 905 #else
 906 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 907 #endif
 908
 909 #endif /* not THIS_IS_CONFIGURE */
 910 ' > ${tempcname}
 911
 912 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 913
 914 # The value of CPP is a quoted variable reference, so we need to do this
 915 # to get its actual value...
 916 CPP=`eval "echo $CPP"`
 917 [eval `${CPP} -Isrc ${tempcname} \
 918        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 919 if test "x$SPECIFIED_CFLAGS" = x; then
 920   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 921          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 922 else
 923   REAL_CFLAGS="$CFLAGS"
 924 fi]
 925 rm ${tempcname}
 926
 927
 928 LD_SWITCH_SYSTEM=
 929 case "$opsys" in
 930   freebsd)
 931    ## Let `ld' find image libs and similar things in /usr/local/lib.
 932    ## The system compiler, GCC, has apparently been modified to not
 933    ## look there, contrary to what a stock GCC would do.
 934    LD_SWITCH_SYSTEM=-L/usr/local/lib
 935    ;;
 936
 937   gnu-linux)
 938    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 939    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 940    ;;
 941
 942   netbsd)
 943    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 944    ;;
 945
 946   openbsd)
 947    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 948    ## otherwise Emacs dumps core on elf systems.
 949    LD_SWITCH_SYSTEM="-Z"
 950    ;;
 951 esac
 952 AC_SUBST(LD_SWITCH_SYSTEM)
 953
 954 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 955
 956 ## This is fun.  Some settings of LD_SWITCH_SYSTEM reference
 957 ## LD_SWITCH_X_SITE_AUX, which has not been defined yet.  When using
 958 ## cpp, it was expanded to null.  Thus LD_SWITCH_SYSTEM had different
 959 ## values in configure and the Makefiles.  How helpful.
 960 ## FIXME why not use LD_SWITCH_SYSTEM_TEMACS (or somesuch) instead?
 961 case "$opsys" in
 962   gnu-linux)
 963    ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
 964    LD_SWITCH_SYSTEM="$LD_SWITCH_SYSTEM \$(LD_SWITCH_X_SITE_AUX)" ;;
 965
 966   netbsd|openbsd)
 967    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 968    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 969 esac
 970
 971
 972 C_SWITCH_MACHINE=
 973 if test "$machine" = "alpha"; then
 974   AC_CHECK_DECL([__ELF__])
 975   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 976     ## With ELF, make sure that all common symbols get allocated to in the
 977     ## data section.  Otherwise, the dump of temacs may miss variables in
 978     ## the shared library that have been initialized.  For example, with
 979     ## GNU libc, __malloc_initialized would normally be resolved to the
 980     ## shared library's .bss section, which is fatal.
 981     if test "x$GCC" = "xyes"; then
 982       C_SWITCH_MACHINE="-fno-common"
 983     else
 984       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 985     fi
 986   fi
 987 fi
 988 AC_SUBST(C_SWITCH_MACHINE)
 989
 990
 991 C_SWITCH_SYSTEM=
 992 ## Some programs in src produce warnings saying certain subprograms
 993 ## are too complex and need a MAXMEM value greater than 2000 for
 994 ## additional optimization.  --nils@exp-math.uni-essen.de
 995 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 996   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 997 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 998 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 999 AC_SUBST(C_SWITCH_SYSTEM)
1000
1001
1002 LIBS_SYSTEM=
1003 case "$opsys" in
1004   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1005   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1006
1007   freebsd) LIBS_SYSTEM="-lutil" ;;
1008
1009   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1010
1011   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1012
1013   ## Motif needs -lgen.
1014   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1015 esac
1016 AC_SUBST(LIBS_SYSTEM)
1017
1018
1019 ### Make sure subsequent tests use flags consistent with the build flags.
1020
1021 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1022   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1023 else
1024   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1025 fi
1026
1027 dnl For AC_FUNC_GETLOADAVG, at least:
1028 AC_CONFIG_LIBOBJ_DIR(src)
1029
1030 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1031 AC_SYS_LARGEFILE
1032
1033
1034 ## If user specified a crt-dir, use that unconditionally.
1035 if test "X$CRT_DIR" = "X"; then
1036
1037   case "$canonical" in
1038     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1039     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1040     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1041     ## For anything else (eg /usr/lib32), it is up the user to specify
1042     ## the location (bug#5655).
1043     ## Test for crtn.o, not just the directory, because sometimes the
1044     ## directory exists but does not have the relevant files (bug#1287).
1045     ## FIXME better to test for binary compatibility somehow.
1046     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1047     ;;
1048
1049     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1050   esac
1051
1052   case "$opsys" in
1053     hpux10-20) CRT_DIR=/lib ;;
1054   esac
1055
1056   ## Default is /usr/lib.
1057   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1058
1059 else
1060
1061   ## Some platforms don't use any of these files, so it is not
1062   ## appropriate to put this test outside the if block.
1063   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1064     AC_MSG_ERROR([crt*.o not found in specified location.])
1065
1066 fi
1067
1068 AC_SUBST(CRT_DIR)
1069
1070 LIB_MATH=-lm
1071 LIB_STANDARD=
1072 START_FILES=
1073
1074 case $opsys in
1075   cygwin )
1076     LIB_MATH=
1077     START_FILES='ecrt0.o'
1078     ;;
1079   darwin )
1080     ## Adding -lm confuses the dynamic linker, so omit it.
1081     LIB_MATH=
1082     START_FILES='pre-crt0.o'
1083     ;;
1084   freebsd )
1085     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1086     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1087     ;;
1088   gnu-linux | gnu-kfreebsd )
1089     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1090     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1091     ;;
1092   hpux10-20 | hpux11 )
1093     LIB_STANDARD=-lc
1094     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1095     ;;
1096   netbsd | openbsd )
1097     if test -f $CRT_DIR/crti.o; then
1098         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1099         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1100     else
1101         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1102         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1103     fi
1104     ;;
1105 esac
1106
1107 AC_SUBST(LIB_MATH)
1108 AC_SUBST(START_FILES)
1109
1110 dnl This function definition taken from Gnome 2.0
1111 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1112 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1113 dnl also defines GSTUFF_PKG_ERRORS on error
1114 AC_DEFUN([PKG_CHECK_MODULES], [
1115   succeeded=no
1116
1117   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1118
1119   if test "$PKG_CONFIG" = "no" ; then
1120      ifelse([$4], , [AC_MSG_ERROR([
1121       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1122   else
1123      PKG_CONFIG_MIN_VERSION=0.9.0
1124      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1125         AC_MSG_CHECKING(for $2)
1126
1127         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1128             AC_MSG_RESULT(yes)
1129             succeeded=yes
1130
1131             AC_MSG_CHECKING($1_CFLAGS)
1132             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1133             AC_MSG_RESULT($$1_CFLAGS)
1134
1135             AC_MSG_CHECKING($1_LIBS)
1136             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1137             AC_MSG_RESULT($$1_LIBS)
1138         else
1139             AC_MSG_RESULT(no)
1140             $1_CFLAGS=""
1141             $1_LIBS=""
1142             ## If we have a custom action on failure, don't print errors, but
1143             ## do set a variable so people can do so.
1144             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1145             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1146         fi
1147
1148         AC_SUBST($1_CFLAGS)
1149         AC_SUBST($1_LIBS)
1150      else
1151         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1152         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1153      fi
1154   fi
1155
1156   if test $succeeded = yes; then
1157      ifelse([$3], , :, [$3])
1158   else
1159      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1160   fi
1161 ])
1162
1163
1164 if test "${with_sound}" != "no"; then
1165   # Sound support for GNU/Linux and the free BSDs.
1166   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1167   # Emulation library used on NetBSD.
1168   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1169   AC_SUBST(LIBSOUND)
1170
1171   ALSA_REQUIRED=1.0.0
1172   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1173   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1174   if test $HAVE_ALSA = yes; then
1175     SAVE_CFLAGS="$CFLAGS"
1176     SAVE_LDFLAGS="$LDFLAGS"
1177     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1178     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1179     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1180                     emacs_alsa_normal=yes,
1181                     emacs_alsa_normal=no)
1182     if test "$emacs_alsa_normal" != yes; then
1183       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1184                      [snd_lib_error_set_handler (0);],
1185                      emacs_alsa_subdir=yes,
1186                      emacs_alsa_subdir=no)
1187       if test "$emacs_alsa_subdir" != yes; then
1188         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1189       fi
1190       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1191     fi
1192
1193     CFLAGS="$SAVE_CFLAGS"
1194     LDFLAGS="$SAVE_LDFLAGS"
1195     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1196     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1197     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1198   fi
1199   AC_SUBST(CFLAGS_SOUND)
1200 fi
1201
1202 dnl checks for header files
1203 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1204   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1205   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1206   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1207   sys/utsname.h pwd.h utmp.h)
1208
1209 AC_MSG_CHECKING(if personality LINUX32 can be set)
1210 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1211                emacs_cv_personality_linux32=yes,
1212                emacs_cv_personality_linux32=no)
1213 AC_MSG_RESULT($emacs_cv_personality_linux32)
1214
1215 if test $emacs_cv_personality_linux32 = yes; then
1216   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1217             [Define to 1 if personality LINUX32 can be set.])
1218 fi
1219
1220 dnl On Solaris 8 there's a compilation warning for term.h because
1221 dnl it doesn't define `bool'.
1222 AC_CHECK_HEADERS(term.h, , , -)
1223 AC_HEADER_STDC
1224 AC_HEADER_TIME
1225 AC_CHECK_DECLS([sys_siglist])
1226 if test $ac_cv_have_decl_sys_siglist != yes; then
1227   # For Tru64, at least:
1228   AC_CHECK_DECLS([__sys_siglist])
1229   if test $ac_cv_have_decl___sys_siglist = yes; then
1230     AC_DEFINE(sys_siglist, __sys_siglist,
1231               [Define to any substitute for sys_siglist.])
1232   fi
1233 fi
1234 AC_HEADER_SYS_WAIT
1235
1236 dnl Some systems have utime.h but don't declare the struct anyplace.
1237 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1238 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1239 #include <sys/time.h>
1240 #include <time.h>
1241 #else
1242 #ifdef HAVE_SYS_TIME_H
1243 #include <sys/time.h>
1244 #else
1245 #include <time.h>
1246 #endif
1247 #endif
1248 #ifdef HAVE_UTIME_H
1249 #include <utime.h>
1250 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1251   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1252 if test $emacs_cv_struct_utimbuf = yes; then
1253   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1254 fi
1255
1256 dnl checks for typedefs
1257 AC_TYPE_SIGNAL
1258
1259 dnl Check for speed_t typedef.
1260 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1261   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1262     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1263 if test $emacs_cv_speed_t = yes; then
1264   AC_DEFINE(HAVE_SPEED_T, 1,
1265            [Define to 1 if `speed_t' is declared by <termios.h>.])
1266 fi
1267
1268 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1269 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1270 #include <sys/time.h>
1271 #include <time.h>
1272 #else
1273 #ifdef HAVE_SYS_TIME_H
1274 #include <sys/time.h>
1275 #else
1276 #include <time.h>
1277 #endif
1278 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1279   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1280 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1281 if test $emacs_cv_struct_timeval = yes; then
1282   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1283 fi
1284
1285 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1286 AC_TRY_COMPILE([#include <math.h>],
1287 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1288   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1289 HAVE_EXCEPTION=$emacs_cv_struct_exception
1290 if test $emacs_cv_struct_exception != yes; then
1291   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1292 fi
1293
1294 AC_CHECK_HEADERS(sys/socket.h)
1295 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1296 #if HAVE_SYS_SOCKET_H
1297 #include <sys/socket.h>
1298 #endif])
1299
1300 dnl checks for structure members
1301 AC_STRUCT_TM
1302 AC_STRUCT_TIMEZONE
1303 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1304                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1305                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1306                 [#include <time.h>])
1307 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1308                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1309                   struct ifreq.ifr_addr], , ,
1310                  [AC_INCLUDES_DEFAULT
1311 #if HAVE_SYS_SOCKET_H
1312 #include <sys/socket.h>
1313 #endif
1314 #if HAVE_NET_IF_H
1315 #include <net/if.h>
1316 #endif])
1317
1318 dnl checks for compiler characteristics
1319
1320 dnl Testing __STDC__ to determine prototype support isn't good enough.
1321 dnl DEC C, for instance, doesn't define it with default options, and
1322 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1323 dnl and void *.
1324 AC_C_PROTOTYPES
1325 AC_C_VOLATILE
1326 AC_C_CONST
1327 dnl This isn't useful because we can't turn on use of `inline' unless
1328 dnl the compiler groks `extern inline'.
1329 dnl AC_C_INLINE
1330 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1331   [AC_TRY_COMPILE(, [void * foo;],
1332                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1333 if test $emacs_cv_void_star = yes; then
1334   AC_DEFINE(POINTER_TYPE, void)
1335 else
1336   AC_DEFINE(POINTER_TYPE, char)
1337 fi
1338 AH_TEMPLATE(POINTER_TYPE,
1339             [Define as `void' if your compiler accepts `void *'; otherwise
1340              define as `char'.])dnl
1341
1342
1343
1344 dnl This could be used for targets which can have both byte sexes.
1345 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1346 dnl AC_C_BIGENDIAN
1347
1348 dnl check for Make feature
1349 AC_PROG_MAKE_SET
1350
1351 dnl check for GNU Make if we have GCC and autodepend is on.
1352 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1353    AC_MSG_CHECKING([whether we are using GNU Make])
1354    HAVE_GNU_MAKE=no
1355    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1356    if test "x$testval" != x; then
1357       HAVE_GNU_MAKE=yes
1358    else
1359       ac_enable_autodepend=no
1360    fi
1361    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1362    if test $HAVE_GNU_MAKE = yes; then
1363       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1364       SAVE_CFLAGS="$CFLAGS"
1365       CFLAGS="$CFLAGS -MMD -MF deps.d"
1366       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1367       CFLAGS="$SAVE_CFLAGS"
1368       test -f deps.d || ac_enable_autodepend=no
1369       rm -rf deps.d
1370       AC_MSG_RESULT([$ac_enable_autodepend])
1371    fi
1372    if test $ac_enable_autodepend = yes; then
1373       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1374    fi
1375 fi
1376
1377 dnl checks for operating system services
1378 AC_SYS_LONG_FILE_NAMES
1379
1380 #### Choose a window system.
1381
1382 AC_PATH_X
1383 if test "$no_x" = yes; then
1384   window_system=none
1385 else
1386   window_system=x11
1387 fi
1388
1389 ## Workaround for bug in autoconf <= 2.62.
1390 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1391 ## No need to do anything special for these standard directories.
1392 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1393
1394    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1395
1396 fi
1397
1398 LD_SWITCH_X_SITE_AUX=
1399 LD_SWITCH_X_SITE_AUX_RPATH=
1400 if test "${x_libraries}" != NONE; then
1401   if test -n "${x_libraries}"; then
1402     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1403     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1404     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1405   fi
1406   x_default_search_path=""
1407   x_search_path=${x_libraries}
1408   if test -z "${x_search_path}"; then
1409     x_search_path=/usr/lib
1410   fi
1411   for x_library in `echo ${x_search_path}: | \
1412                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1413     x_search_path="\
1414 ${x_library}/X11/%L/%T/%N%C%S:\
1415 ${x_library}/X11/%l/%T/%N%C%S:\
1416 ${x_library}/X11/%T/%N%C%S:\
1417 ${x_library}/X11/%L/%T/%N%S:\
1418 ${x_library}/X11/%l/%T/%N%S:\
1419 ${x_library}/X11/%T/%N%S"
1420     if test x"${x_default_search_path}" = x; then
1421       x_default_search_path=${x_search_path}
1422     else
1423       x_default_search_path="${x_search_path}:${x_default_search_path}"
1424     fi
1425   done
1426 fi
1427 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1428 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1429
1430 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1431   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1432 fi
1433
1434 if test x"${x_includes}" = x; then
1435   bitmapdir=/usr/include/X11/bitmaps
1436 else
1437   # accumulate include directories that have X11 bitmap subdirectories
1438   bmd_acc="dummyval"
1439   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1440     if test -d "${bmd}/X11/bitmaps"; then
1441       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1442     fi
1443     if test -d "${bmd}/bitmaps"; then
1444       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1445     fi
1446   done
1447   if test ${bmd_acc} != "dummyval"; then
1448     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1449   fi
1450 fi
1451
1452 HAVE_NS=no
1453 NS_IMPL_COCOA=no
1454 NS_IMPL_GNUSTEP=no
1455 NS_IMPL_GNUSTEP_INC=
1456 NS_IMPL_GNUSTEP_TEMACS_LDFLAGS=
1457 tmp_CPPFLAGS="$CPPFLAGS"
1458 tmp_CFLAGS="$CFLAGS"
1459 CPPFLAGS="$CPPFLAGS -x objective-c"
1460 CFLAGS="$CFLAGS -x objective-c"
1461 TEMACS_LDFLAGS2="\${LDFLAGS}"
1462 dnl I don't think it's especially important, but src/Makefile.in
1463 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1464 dnl trailing "/" to it, so now we do it here.
1465 if test "${with_ns}" != no; then
1466   if test "${opsys}" = darwin; then
1467      NS_IMPL_COCOA=yes
1468      ns_appdir=`pwd`/nextstep/Emacs.app/
1469      ns_appbindir=${ns_appdir}Contents/MacOS/
1470      ns_appresdir=${ns_appdir}Contents/Resources
1471      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1472   elif test -f $GNUSTEP_CONFIG_FILE; then
1473      NS_IMPL_GNUSTEP=yes
1474      ns_appdir=`pwd`/nextstep/Emacs.app/
1475      ns_appbindir=${ns_appdir}
1476      ns_appresdir=${ns_appdir}Resources
1477      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1478      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1479      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1480      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1481      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1482      ## Pull in stuff from GNUstep-make.
1483      NS_IMPL_GNUSTEP_INC="FOUNDATION_LIB=gnu
1484 GUI_LIB=gnu
1485 include $GNUSTEP_MAKEFILES/Additional/base.make
1486 include $GNUSTEP_MAKEFILES/Additional/gui.make
1487 shared=no
1488 "
1489      dnl Presumably ${CONFIG_SYSTEM_LIBS} is defined by above includes.
1490      NS_IMPL_GNUSTEP_TEMACS_LDFLAGS="-L${GNUSTEP_SYSTEM_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc \${CONFIG_SYSTEM_LIBS} -lpthread"
1491      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1492      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1493      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1494      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1495      LIB_STANDARD=
1496      START_FILES=
1497      TEMACS_LDFLAGS2=
1498   fi
1499   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1500                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1501   files are missing or cannot be compiled.])])
1502   NS_HAVE_NSINTEGER=yes
1503   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1504                                      [NSInteger i;])],
1505                     ns_have_nsinteger=yes,
1506                     ns_have_nsinteger=no)
1507   if test $ns_have_nsinteger = no; then
1508     NS_HAVE_NSINTEGER=no
1509   fi
1510 fi
1511 AC_SUBST(NS_IMPL_GNUSTEP_INC)
1512 AC_SUBST(NS_IMPL_GNUSTEP_TEMACS_LDFLAGS)
1513 AC_SUBST(TEMACS_LDFLAGS2)
1514
1515 NS_OBJ=
1516 NS_SUPPORT=
1517 if test "${HAVE_NS}" = yes; then
1518   window_system=nextstep
1519   with_xft=no
1520   # set up packaging dirs
1521   exec_prefix=${ns_appbindir}
1522   libexecdir=${ns_appbindir}/libexec
1523   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1524      prefix=${ns_appresdir}
1525   fi
1526   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1527   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1528 fi
1529 CFLAGS="$tmp_CFLAGS"
1530 CPPFLAGS="$tmp_CPPFLAGS"
1531 AC_SUBST(NS_OBJ)
1532 AC_SUBST(NS_SUPPORT)
1533 AC_SUBST(LIB_STANDARD)
1534
1535 case "${window_system}" in
1536   x11 )
1537     HAVE_X_WINDOWS=yes
1538     HAVE_X11=yes
1539     case "${with_x_toolkit}" in
1540       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1541       motif ) USE_X_TOOLKIT=MOTIF ;;
1542       gtk ) with_gtk=yes
1543 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1544 dnl USE_X_TOOLKIT is set.
1545             USE_X_TOOLKIT=none ;;
1546       no ) USE_X_TOOLKIT=none ;;
1547 dnl If user did not say whether to use a toolkit, make this decision later:
1548 dnl use the toolkit if we have gtk, or X11R5 or newer.
1549       * ) USE_X_TOOLKIT=maybe ;;
1550     esac
1551   ;;
1552   nextstep | none )
1553     HAVE_X_WINDOWS=no
1554     HAVE_X11=no
1555     USE_X_TOOLKIT=none
1556   ;;
1557 esac
1558
1559 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1560    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1561    if test "$HAVE_XSERVER" = true ||
1562       test -n "$DISPLAY" ||
1563       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1564         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1565 were found.  You should install the relevant development files for X
1566 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1567 sure you have development files for image handling, i.e.
1568 tiff, gif, jpeg, png and xpm.
1569 If you are sure you want Emacs compiled without X window support, pass
1570   --without-x
1571 to configure.])
1572    fi
1573 fi
1574
1575 ### If we're using X11, we should use the X menu package.
1576 HAVE_MENUS=no
1577 case ${HAVE_X11} in
1578   yes ) HAVE_MENUS=yes ;;
1579 esac
1580
1581 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1582 # Assume not, until told otherwise.
1583 GNU_MALLOC=yes
1584 doug_lea_malloc=yes
1585 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1586 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1587 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1588                emacs_cv_var___after_morecore_hook,
1589 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1590   emacs_cv_var___after_morecore_hook=yes,
1591   emacs_cv_var___after_morecore_hook=no)])
1592 if test $emacs_cv_var___after_morecore_hook = no; then
1593   doug_lea_malloc=no
1594 fi
1595 if test "${system_malloc}" = "yes"; then
1596   GNU_MALLOC=no
1597   GNU_MALLOC_reason="
1598     (The GNU allocators don't work with this system configuration.)"
1599 fi
1600 if test "$doug_lea_malloc" = "yes" ; then
1601   if test "$GNU_MALLOC" = yes ; then
1602     GNU_MALLOC_reason="
1603       (Using Doug Lea's new malloc from the GNU C Library.)"
1604   fi
1605   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1606             [Define to 1 if you are using the GNU C Library.])
1607 fi
1608
1609 if test x"${REL_ALLOC}" = x; then
1610   REL_ALLOC=${GNU_MALLOC}
1611 fi
1612
1613 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1614 dnl the system configuration file (s/*.h) to turn the use of mmap
1615 dnl in the relocating allocator on.
1616
1617 AC_FUNC_MMAP
1618 if test $use_mmap_for_buffers = yes; then
1619   REL_ALLOC=no
1620 fi
1621
1622 LIBS="$LIBS_SYSTEM $LIBS"
1623
1624 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1625 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1626 AC_CHECK_LIB(dnet, dnet_ntoa)
1627 dnl This causes -lresolv to get used in subsequent tests,
1628 dnl which causes failures on some systems such as HPUX 9.
1629 dnl AC_CHECK_LIB(resolv, gethostbyname)
1630
1631 dnl FIXME replace main with a function we actually want from this library.
1632 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1633
1634 AC_CHECK_LIB(pthreads, cma_open)
1635
1636 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1637 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1638 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1639 ## added to LIBS in configure would never contain the pthreads part,
1640 ## but the value used in Makefiles might.  FIXME?
1641 ##
1642 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1643 ## be harmless on older versions of X where it happens to exist.
1644 test "$opsys" = "aix4-2" && \
1645   test $ac_cv_lib_pthreads_cma_open = yes && \
1646   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1647
1648 dnl Check for need for bigtoc support on IBM AIX
1649
1650 case ${host_os} in
1651 aix*)
1652   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1653     case $GCC in
1654     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1655     *) gdb_cv_bigtoc=-bbigtoc ;;
1656     esac
1657
1658     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1659     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1660   ])
1661   ;;
1662 esac
1663
1664 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1665 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1666 # REAL_CPPFLAGS later on.
1667
1668 REAL_CPPFLAGS="$CPPFLAGS"
1669
1670 if test "${HAVE_X11}" = "yes"; then
1671   DEFS="$C_SWITCH_X_SITE $DEFS"
1672   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1673   LIBS="$LIBX $LIBS"
1674   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1675   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1676
1677   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1678   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1679   # but it's more convenient here to set LD_RUN_PATH
1680   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1681   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1682     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1683     export LD_RUN_PATH
1684   fi
1685
1686   if test "${opsys}" = "gnu-linux"; then
1687     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1688     AC_TRY_LINK([],
1689      [XOpenDisplay ("foo");],
1690      [xlinux_first_failure=no],
1691      [xlinux_first_failure=yes])
1692     if test "${xlinux_first_failure}" = "yes"; then
1693       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1694       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1695       OLD_CPPFLAGS="$CPPFLAGS"
1696       OLD_LIBS="$LIBS"
1697       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1698       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1699       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1700       LIBS="$LIBS -b i486-linuxaout"
1701       AC_TRY_LINK([],
1702        [XOpenDisplay ("foo");],
1703        [xlinux_second_failure=no],
1704        [xlinux_second_failure=yes])
1705       if test "${xlinux_second_failure}" = "yes"; then
1706         # If we get the same failure with -b, there is no use adding -b.
1707         # So take it out.  This plays safe.
1708         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1709         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1710         CPPFLAGS="$OLD_CPPFLAGS"
1711         LIBS="$OLD_LIBS"
1712         AC_MSG_RESULT(no)
1713       else
1714         AC_MSG_RESULT(yes)
1715       fi
1716     else
1717       AC_MSG_RESULT(no)
1718     fi
1719   fi
1720
1721   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1722   # header files included from there.
1723   AC_MSG_CHECKING(for Xkb)
1724   AC_TRY_LINK([#include <X11/Xlib.h>
1725 #include <X11/XKBlib.h>],
1726         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1727         emacs_xkb=yes, emacs_xkb=no)
1728   AC_MSG_RESULT($emacs_xkb)
1729   if test $emacs_xkb = yes; then
1730     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1731   fi
1732
1733   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1734 XScreenNumberOfScreen XSetWMProtocols)
1735 fi
1736
1737 if test "${window_system}" = "x11"; then
1738   AC_MSG_CHECKING(X11 version 6)
1739   AC_CACHE_VAL(emacs_cv_x11_version_6,
1740   [AC_TRY_LINK([#include <X11/Xlib.h>],
1741 [#if XlibSpecificationRelease < 6
1742 fail;
1743 #endif
1744 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1745   if test $emacs_cv_x11_version_6 = yes; then
1746     AC_MSG_RESULT(6 or newer)
1747     AC_DEFINE(HAVE_X11R6, 1,
1748               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1749   else
1750     AC_MSG_RESULT(before 6)
1751   fi
1752 fi
1753
1754
1755 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1756 HAVE_RSVG=no
1757 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1758   if test "${with_rsvg}" != "no"; then
1759     RSVG_REQUIRED=2.11.0
1760     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1761
1762     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1763     AC_SUBST(RSVG_CFLAGS)
1764     AC_SUBST(RSVG_LIBS)
1765
1766     if test ".${RSVG_CFLAGS}" != "."; then
1767       HAVE_RSVG=yes
1768       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1769       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1770       LIBS="$RSVG_LIBS $LIBS"
1771     fi
1772   fi
1773 fi
1774
1775
1776 HAVE_GTK=no
1777 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1778   GLIB_REQUIRED=2.6
1779   GTK_REQUIRED=2.6
1780   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1781
1782   dnl Checks for libraries.
1783   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1784   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1785      AC_MSG_ERROR($GTK_PKG_ERRORS)
1786   fi
1787 fi
1788
1789
1790 GTK_OBJ=
1791 if test x"$pkg_check_gtk" = xyes; then
1792
1793   AC_SUBST(GTK_CFLAGS)
1794   AC_SUBST(GTK_LIBS)
1795   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1796   CFLAGS="$CFLAGS $GTK_CFLAGS"
1797   LIBS="$GTK_LIBS $LIBS"
1798   dnl Try to compile a simple GTK program.
1799   GTK_COMPILES=no
1800   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1801   if test "${GTK_COMPILES}" != "yes"; then
1802     if test "$USE_X_TOOLKIT" != "maybe"; then
1803       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1804     fi
1805   else
1806     HAVE_GTK=yes
1807     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1808     GTK_OBJ=gtkutil.o
1809     USE_X_TOOLKIT=none
1810     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1811       :
1812     else
1813       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1814        closing open displays.  This is no problem if you just use
1815        one display, but if you use more than one and close one of them
1816        Emacs may crash.]])
1817       sleep 3
1818     fi
1819   fi
1820
1821 fi
1822 AC_SUBST(GTK_OBJ)
1823
1824
1825 if test "${HAVE_GTK}" = "yes"; then
1826
1827   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1828   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1829   if test "$with_toolkit_scroll_bars" != no; then
1830     with_toolkit_scroll_bars=yes
1831   fi
1832
1833   dnl  Check if we can use multiple displays with this GTK version.
1834   dnl  If gdk_display_open exists, assume all others are there also.
1835   HAVE_GTK_MULTIDISPLAY=no
1836   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1837   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1838     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1839               [Define to 1 if GTK can handle more than one display.])
1840   fi
1841
1842   dnl  Check if we have the old file selection dialog declared and
1843   dnl  in the link library.  In 2.x it may be in the library,
1844   dnl  but not declared if deprecated featured has been selected out.
1845   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1846   HAVE_GTK_FILE_SELECTION=no
1847   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1848                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1849 #include <gtk/gtk.h>])
1850   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1851     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1852                    HAVE_GTK_FILE_SELECTION=no)
1853   fi
1854
1855   dnl  Check if we have the new file chooser dialog
1856   HAVE_GTK_FILE_CHOOSER=no
1857   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1858                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1859 #include <gtk/gtk.h>])
1860   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1861     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1862                    HAVE_GTK_FILE_CHOOSER=no)
1863   fi
1864
1865   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1866      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1867     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1868               [Define to 1 if GTK has both file selection and chooser dialog.])
1869   fi
1870
1871   dnl Check if pthreads are available.  Emacs only needs this when using
1872   dnl gtk_file_chooser under Gnome.
1873   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1874     HAVE_GTK_AND_PTHREAD=no
1875     AC_CHECK_HEADERS(pthread.h)
1876     if test "$ac_cv_header_pthread_h"; then
1877       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1878     fi
1879     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1880       case "${canonical}" in
1881         *-hpux*) ;;
1882         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1883       esac
1884       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1885                [Define to 1 if you have GTK and pthread (-lpthread).])
1886     fi
1887   fi
1888 fi
1889
1890 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1891 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1892 dnl also not configured.
1893 HAVE_DBUS=no
1894 DBUS_OBJ=
1895 if test "${with_dbus}" = "yes"; then
1896    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1897    if test "$HAVE_DBUS" = yes; then
1898      LIBS="$LIBS $DBUS_LIBS"
1899      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1900      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1901      DBUS_OBJ=dbusbind.o
1902    fi
1903 fi
1904 AC_SUBST(DBUS_OBJ)
1905
1906 dnl GConf has been tested under GNU/Linux only.
1907 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1908 HAVE_GCONF=no
1909 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1910    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1911    if test "$HAVE_GCONF" = yes; then
1912       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1913    fi
1914 fi
1915
1916 dnl SELinux is available for GNU/Linux only.
1917 HAVE_LIBSELINUX=no
1918 LIBSELINUX_LIBS=
1919 if test "${with_selinux}" = "yes"; then
1920    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1921    if test "$HAVE_LIBSELINUX" = yes; then
1922       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1923       LIBSELINUX_LIBS=-lselinux
1924    fi
1925 fi
1926 AC_SUBST(LIBSELINUX_LIBS)
1927
1928 dnl Do not put whitespace before the #include statements below.
1929 dnl Older compilers (eg sunos4 cc) choke on it.
1930 HAVE_XAW3D=no
1931 LUCID_LIBW=
1932 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1933   if test "$with_xaw3d" != no; then
1934     AC_MSG_CHECKING(for xaw3d)
1935     AC_CACHE_VAL(emacs_cv_xaw3d,
1936     [AC_TRY_LINK([
1937 #include <X11/Intrinsic.h>
1938 #include <X11/Xaw3d/Simple.h>],
1939       [],
1940       emacs_cv_xaw3d=yes,
1941       emacs_cv_xaw3d=no)])
1942   else
1943     emacs_cv_xaw3d=no
1944   fi
1945   if test $emacs_cv_xaw3d = yes; then
1946     AC_MSG_RESULT([yes; using Lucid toolkit])
1947     USE_X_TOOLKIT=LUCID
1948     HAVE_XAW3D=yes
1949     LUCID_LIBW=-lXaw3d
1950     AC_DEFINE(HAVE_XAW3D, 1,
1951               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1952   else
1953     AC_MSG_RESULT(no)
1954     AC_MSG_CHECKING(for libXaw)
1955     AC_CACHE_VAL(emacs_cv_xaw,
1956     [AC_TRY_LINK([
1957 #include <X11/Intrinsic.h>
1958 #include <X11/Xaw/Simple.h>],
1959       [],
1960       emacs_cv_xaw=yes,
1961       emacs_cv_xaw=no)])
1962     if test $emacs_cv_xaw = yes; then
1963       AC_MSG_RESULT([yes; using Lucid toolkit])
1964       USE_X_TOOLKIT=LUCID
1965       LUCID_LIBW=-lXaw
1966     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1967       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1968     else
1969       AC_MSG_RESULT([no; do not use toolkit by default])
1970       USE_X_TOOLKIT=none
1971     fi
1972   fi
1973 fi
1974
1975 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1976
1977 LIBXTR6=
1978 if test "${USE_X_TOOLKIT}" != "none"; then
1979   AC_MSG_CHECKING(X11 toolkit version)
1980   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1981   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1982 [#if XtSpecificationRelease < 6
1983 fail;
1984 #endif
1985 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1986   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1987   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1988     AC_MSG_RESULT(6 or newer)
1989     AC_DEFINE(HAVE_X11XTR6, 1,
1990               [Define to 1 if you have the X11R6 or newer version of Xt.])
1991     LIBXTR6="-lSM -lICE"
1992     case "$opsys" in
1993       ## Use libw.a along with X11R6 Xt.
1994       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
1995     esac
1996   else
1997     AC_MSG_RESULT(before 6)
1998   fi
1999
2000 dnl If using toolkit, check whether libXmu.a exists.
2001 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2002   OLDLIBS="$LIBS"
2003   if test x$HAVE_X11XTR6 = xyes; then
2004     LIBS="-lXt -lSM -lICE $LIBS"
2005   else
2006     LIBS="-lXt $LIBS"
2007   fi
2008   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2009   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2010 fi
2011 AC_SUBST(LIBXTR6)
2012
2013 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2014 dnl Why not just test for libxmu in the normal way?
2015 LIBXMU=-lXmu
2016 case "$machine" in
2017   ## These machines don't supply Xmu.
2018   hpux* | aix4-2 )
2019     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2020     ;;
2021 esac
2022 AC_SUBST(LIBXMU)
2023
2024 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2025 if test "${HAVE_X11}" = "yes"; then
2026   if test "${USE_X_TOOLKIT}" != "none"; then
2027     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2028   fi
2029 fi
2030
2031 LIBXP=
2032 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2033   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2034   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2035     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2036 int x = 5;
2037 #else
2038 Motif version prior to 2.1.
2039 #endif],
2040     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2041   if test $emacs_cv_motif_version_2_1 = yes; then
2042     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2043   else
2044     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2045     # We put this in CFLAGS temporarily to precede other -I options
2046     # that might be in CFLAGS temporarily.
2047     # We put this in CPPFLAGS where it precedes the other -I options.
2048     OLD_CPPFLAGS=$CPPFLAGS
2049     OLD_CFLAGS=$CFLAGS
2050     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2051     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2052     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2053       [int x = 5;],
2054       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2055     if test $emacs_cv_lesstif = yes; then
2056       # Make sure this -I option remains in CPPFLAGS after it is set
2057       # back to REAL_CPPFLAGS.
2058       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2059       # have those other -I options anyway.  Ultimately, having this
2060       # directory ultimately in CPPFLAGS will be enough.
2061       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2062       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2063     else
2064       CFLAGS=$OLD_CFLAGS
2065       CPPFLAGS=$OLD_CPPFLAGS
2066     fi
2067   fi
2068 fi
2069
2070 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2071 dnl using Motif or Xaw3d is available, and unless
2072 dnl --with-toolkit-scroll-bars=no was specified.
2073
2074 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2075             [Define to 1 if we should use toolkit scroll bars.])dnl
2076 USE_TOOLKIT_SCROLL_BARS=no
2077 if test "${with_toolkit_scroll_bars}" != "no"; then
2078   if test "${USE_X_TOOLKIT}" != "none"; then
2079     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2080       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2081       HAVE_XAW3D=no
2082       USE_TOOLKIT_SCROLL_BARS=yes
2083     elif test "${HAVE_XAW3D}" = "yes"; then
2084       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2085       USE_TOOLKIT_SCROLL_BARS=yes
2086     fi
2087   elif test "${HAVE_GTK}" = "yes"; then
2088     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2089     USE_TOOLKIT_SCROLL_BARS=yes
2090   elif test "${HAVE_NS}" = "yes"; then
2091     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2092     USE_TOOLKIT_SCROLL_BARS=yes
2093   fi
2094 fi
2095
2096 dnl See if XIM is available.
2097 AC_TRY_COMPILE([
2098           #include <X11/Xlib.h>
2099           #include <X11/Xresource.h>],
2100          [XIMProc  callback;],
2101          [HAVE_XIM=yes
2102          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2103          HAVE_XIM=no)
2104
2105 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2106
2107 if test "${with_xim}" != "no"; then
2108   AC_DEFINE(USE_XIM, 1,
2109             [Define to 1 if we should use XIM, if it is available.])
2110 fi
2111
2112
2113 if test "${HAVE_XIM}" != "no"; then
2114   late_CFLAGS=$CFLAGS
2115   if test "$GCC" = yes; then
2116     CFLAGS="$CFLAGS --pedantic-errors"
2117   fi
2118   AC_TRY_COMPILE([
2119 #include <X11/Xlib.h>
2120 #include <X11/Xresource.h>],
2121 [Display *display;
2122 XrmDatabase db;
2123 char *res_name;
2124 char *res_class;
2125 XIMProc  callback;
2126 XPointer *client_data;
2127 #ifndef __GNUC__
2128 /* If we're not using GCC, it's probably not XFree86, and this is
2129    probably right, but we can't use something like --pedantic-errors.  */
2130 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2131                                            char*, XIMProc, XPointer*);
2132 #endif
2133 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2134    client_data);],
2135     [emacs_cv_arg6_star=yes])
2136   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2137          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2138 either XPointer or XPointer*.])dnl
2139   if test "$emacs_cv_arg6_star" = yes; then
2140     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2141   else
2142     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2143   fi
2144   CFLAGS=$late_CFLAGS
2145 fi
2146
2147 ### Start of font-backend (under any platform) section.
2148 # (nothing here yet -- this is a placeholder)
2149 ### End of font-backend (under any platform) section.
2150
2151 ### Start of font-backend (under X11) section.
2152 if test "${HAVE_X11}" = "yes"; then
2153    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2154
2155    ## Use -lXft if available, unless `--with-xft=no'.
2156    HAVE_XFT=maybe
2157     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2158       with_xft="no";
2159     fi
2160     if test "x${with_xft}" != "xno"; then
2161
2162       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2163       ## Because xftfont.c uses XRenderQueryExtension, we also
2164       ## need to link to -lXrender.
2165       HAVE_XRENDER=no
2166       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2167       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2168         OLD_CPPFLAGS="$CPPFLAGS"
2169         OLD_CFLAGS="$CFLAGS"
2170         OLD_LIBS="$LIBS"
2171         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2172         CFLAGS="$CFLAGS $XFT_CFLAGS"
2173         XFT_LIBS="-lXrender $XFT_LIBS"
2174         LIBS="$XFT_LIBS $LIBS"
2175         AC_CHECK_HEADER(X11/Xft/Xft.h,
2176           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2177
2178         if test "${HAVE_XFT}" = "yes"; then
2179           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2180             AC_SUBST(XFT_LIBS)
2181           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2182         else
2183           CPPFLAGS="$OLD_CPPFLAGS"
2184           CFLAGS="$OLD_CFLAGS"
2185           LIBS="$OLD_LIBS"
2186         fi                        # "${HAVE_XFT}" = "yes"
2187       fi                          # "$HAVE_XFT" != no
2188     fi                            # "x${with_xft}" != "xno"
2189
2190     dnl For the "Does Emacs use" message at the end.
2191     if test "$HAVE_XFT" != "yes"; then
2192        HAVE_XFT=no
2193     fi
2194
2195
2196     HAVE_FREETYPE=no
2197     ## We used to allow building with FreeType and without Xft.
2198     ## However, the ftx font backend driver is not in good shape.
2199     if test "${HAVE_XFT}" = "yes"; then
2200       dnl As we use Xft, we anyway use freetype.
2201       dnl There's no need for additional CFLAGS and LIBS.
2202       HAVE_FREETYPE=yes
2203       FONTCONFIG_CFLAGS=
2204       FONTCONFIG_LIBS=
2205     fi
2206
2207     HAVE_LIBOTF=no
2208     if test "${HAVE_FREETYPE}" = "yes"; then
2209       AC_DEFINE(HAVE_FREETYPE, 1,
2210                 [Define to 1 if using the freetype and fontconfig libraries.])
2211       if test "${with_libotf}" != "no"; then
2212         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2213                           HAVE_LIBOTF=no)
2214         if test "$HAVE_LIBOTF" = "yes"; then
2215           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2216           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2217                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2218                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2219           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2220             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2221                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2222           fi
2223         fi
2224       fi
2225     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2226     dnl Does the new font backend require it, or can it work without it?
2227     fi
2228
2229     HAVE_M17N_FLT=no
2230     if test "${HAVE_LIBOTF}" = yes; then
2231       if test "${with_m17n_flt}" != "no"; then
2232         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2233         if test "$HAVE_M17N_FLT" = "yes"; then
2234           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2235         fi
2236       fi
2237     fi
2238 else
2239     HAVE_XFT=no
2240     HAVE_FREETYPE=no
2241     HAVE_LIBOTF=no
2242     HAVE_M17N_FLT=no
2243 fi
2244
2245 ### End of font-backend (under X11) section.
2246
2247 AC_SUBST(FREETYPE_CFLAGS)
2248 AC_SUBST(FREETYPE_LIBS)
2249 AC_SUBST(FONTCONFIG_CFLAGS)
2250 AC_SUBST(FONTCONFIG_LIBS)
2251 AC_SUBST(LIBOTF_CFLAGS)
2252 AC_SUBST(LIBOTF_LIBS)
2253 AC_SUBST(M17N_FLT_CFLAGS)
2254 AC_SUBST(M17N_FLT_LIBS)
2255
2256 ### Use -lXpm if available, unless `--with-xpm=no'.
2257 HAVE_XPM=no
2258 LIBXPM=
2259 if test "${HAVE_X11}" = "yes"; then
2260   if test "${with_xpm}" != "no"; then
2261     AC_CHECK_HEADER(X11/xpm.h,
2262       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2263     if test "${HAVE_XPM}" = "yes"; then
2264       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2265       AC_EGREP_CPP(no_return_alloc_pixels,
2266       [#include "X11/xpm.h"
2267 #ifndef XpmReturnAllocPixels
2268 no_return_alloc_pixels
2269 #endif
2270       ], HAVE_XPM=no, HAVE_XPM=yes)
2271
2272       if test "${HAVE_XPM}" = "yes"; then
2273         AC_MSG_RESULT(yes)
2274       else
2275         AC_MSG_RESULT(no)
2276       fi
2277     fi
2278   fi
2279
2280   if test "${HAVE_XPM}" = "yes"; then
2281     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2282     LIBXPM=-lXpm
2283   fi
2284 fi
2285 AC_SUBST(LIBXPM)
2286
2287 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2288 HAVE_JPEG=no
2289 LIBJPEG=
2290 if test "${HAVE_X11}" = "yes"; then
2291   if test "${with_jpeg}" != "no"; then
2292     dnl Checking for jpeglib.h can lose because of a redefinition of
2293     dnl  HAVE_STDLIB_H.
2294     AC_CHECK_HEADER(jerror.h,
2295       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2296   fi
2297
2298   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2299   if test "${HAVE_JPEG}" = "yes"; then
2300     AC_DEFINE(HAVE_JPEG)
2301     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2302         [#include <jpeglib.h>
2303          version=JPEG_LIB_VERSION
2304 ],
2305         [AC_DEFINE(HAVE_JPEG)],
2306         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2307         HAVE_JPEG=no])
2308   fi
2309   if test "${HAVE_JPEG}" = "yes"; then
2310     LIBJPEG=-ljpeg
2311   fi
2312 fi
2313 AC_SUBST(LIBJPEG)
2314
2315 ### Use -lpng if available, unless `--with-png=no'.
2316 HAVE_PNG=no
2317 LIBPNG=
2318 if test "${HAVE_X11}" = "yes"; then
2319   if test "${with_png}" != "no"; then
2320     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2321     # in /usr/include/libpng.
2322     AC_CHECK_HEADERS(png.h libpng/png.h)
2323     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2324       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2325     fi
2326   fi
2327
2328   if test "${HAVE_PNG}" = "yes"; then
2329     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2330     LIBPNG="-lpng -lz -lm"
2331   fi
2332 fi
2333 AC_SUBST(LIBPNG)
2334
2335 ### Use -ltiff if available, unless `--with-tiff=no'.
2336 HAVE_TIFF=no
2337 LIBTIFF=
2338 if test "${HAVE_X11}" = "yes"; then
2339   if test "${with_tiff}" != "no"; then
2340     AC_CHECK_HEADER(tiffio.h,
2341       [tifflibs="-lz -lm"
2342       # At least one tiff package requires the jpeg library.
2343       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2344       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2345   fi
2346
2347   if test "${HAVE_TIFF}" = "yes"; then
2348     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2349     dnl FIXME -lz -lm, as per libpng?
2350     LIBTIFF=-ltiff
2351   fi
2352 fi
2353 AC_SUBST(LIBTIFF)
2354
2355 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2356 HAVE_GIF=no
2357 LIBGIF=
2358 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2359   AC_CHECK_HEADER(gif_lib.h,
2360 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2361 # Earlier versions can crash Emacs.
2362     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2363
2364   if test "$HAVE_GIF" = yes; then
2365     LIBGIF=-lgif
2366   elif test "$HAVE_GIF" = maybe; then
2367 # If gif_lib.h but no libgif, try libungif.
2368     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2369     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2370   fi
2371
2372   if test "${HAVE_GIF}" = "yes"; then
2373     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2374   fi
2375 fi
2376 AC_SUBST(LIBGIF)
2377
2378 dnl Check for required libraries.
2379 if test "${HAVE_X11}" = "yes"; then
2380   MISSING=""
2381   WITH_NO=""
2382   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2383     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2384   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2385     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2386   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2387     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2388   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2389     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2390   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2391     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2392
2393   if test "X${MISSING}" != X; then
2394     AC_MSG_ERROR([The following required libraries were not found:
2395     $MISSING
2396 Maybe some development libraries/packages are missing?
2397 If you don't want to link with them give
2398     $WITH_NO
2399 as options to configure])
2400   fi
2401 fi
2402
2403 ### Use -lgpm if available, unless `--with-gpm=no'.
2404 HAVE_GPM=no
2405 LIBGPM=
2406 MOUSE_SUPPORT=
2407 if test "${with_gpm}" != "no"; then
2408   AC_CHECK_HEADER(gpm.h,
2409     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2410
2411   if test "${HAVE_GPM}" = "yes"; then
2412     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2413     LIBGPM=-lgpm
2414     ## May be reset below.
2415     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2416   fi
2417 fi
2418 AC_SUBST(LIBGPM)
2419
2420 dnl Check for malloc/malloc.h on darwin
2421 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2422
2423 C_SWITCH_X_SYSTEM=
2424 ### Use NeXTstep API to implement GUI.
2425 if test "${HAVE_NS}" = "yes"; then
2426   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2427   if test "${NS_IMPL_COCOA}" = "yes"; then
2428     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2429     GNU_OBJC_CFLAGS=
2430   fi
2431   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2432     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2433     # See also .m.o rule in Makefile.in */
2434     # FIXME: are all these flags really needed?  Document here why.  */
2435     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2436     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2437   fi
2438   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2439     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2440   fi
2441   # We also have mouse menus.
2442   HAVE_MENUS=yes
2443   OTHER_FILES=ns-app
2444 fi
2445
2446
2447 ### Use session management (-lSM -lICE) if available
2448 HAVE_X_SM=no
2449 LIBXSM=
2450 if test "${HAVE_X11}" = "yes"; then
2451   AC_CHECK_HEADER(X11/SM/SMlib.h,
2452     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2453
2454   if test "${HAVE_X_SM}" = "yes"; then
2455     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2456     LIBXSM="-lSM -lICE"
2457     case "$LIBS" in
2458       *-lSM*) ;;
2459       *)      LIBS="$LIBXSM $LIBS" ;;
2460     esac
2461   fi
2462 fi
2463 AC_SUBST(LIBXSM)
2464
2465 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2466 AC_CACHE_CHECK(whether netdb declares h_errno,
2467                emacs_cv_netdb_declares_h_errno,
2468 [AC_TRY_LINK([#include <netdb.h>],
2469   [return h_errno;],
2470   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2471 if test $emacs_cv_netdb_declares_h_errno = yes; then
2472   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2473 fi
2474
2475 AC_FUNC_ALLOCA
2476
2477 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2478 dnl FIXME is there an autoconf test that does the right thing, without
2479 dnl needing to call A_M_E afterwards?
2480 if test x"$ac_cv_func_alloca_works" != xyes; then
2481    AC_MSG_ERROR( [a system implementation of alloca is required] )
2482 fi
2483
2484 # fmod, logb, and frexp are found in -lm on most systems.
2485 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2486 AC_CHECK_LIB(m, sqrt)
2487
2488 # Check for mail-locking functions in a "mail" library.  Probably this should
2489 # have the same check as for liblockfile below.
2490 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2491 if test $have_mail = yes; then
2492   LIBS_MAIL=-lmail
2493   LIBS="$LIBS_MAIL $LIBS"
2494   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2495 else
2496   LIBS_MAIL=
2497 fi
2498 dnl Debian, at least:
2499 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2500 if test $have_lockfile = yes; then
2501    LIBS_MAIL=-llockfile
2502    LIBS="$LIBS_MAIL $LIBS"
2503    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2504 else
2505 # If we have the shared liblockfile, assume we must use it for mail
2506 # locking (e.g. Debian).  If we couldn't link against liblockfile
2507 # (no liblockfile.a installed), ensure that we don't need to.
2508   dnl This works for files generally, not just executables.
2509   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2510   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2511                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2512   if test $ac_cv_prog_liblockfile = yes; then
2513     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2514 This probably means that movemail could lose mail.
2515 There may be a `development' package to install containing liblockfile.])
2516   fi
2517 fi
2518 AC_CHECK_FUNCS(touchlock)
2519 AC_CHECK_HEADERS(maillock.h)
2520 AC_SUBST(LIBS_MAIL)
2521
2522 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2523 ## interlock access to the mail spool.  The alternative is a lock file named
2524 ## /usr/spool/mail/$USER.lock.
2525 mail_lock=no
2526 case "$opsys" in
2527   aix4-2) mail_lock="lockf" ;;
2528
2529   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2530
2531   ## On GNU/Linux systems, both methods are used by various mail programs.
2532   ## I assume most people are using newer mailers that have heard of flock.
2533   ## Change this if you need to.
2534   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2535   ## configure gets the right answers, and that means *NOT* using flock.
2536   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2537   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2538   ## Debian maintainer hasn't provided a clean fix for Emacs.
2539   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2540   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2541   ## correct logic.  -- fx
2542   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2543   ## liblockfile is a Free Software replacement for libmail, used on
2544   ## Debian systems and elsewhere. -rfr.
2545   gnu-*)
2546     mail_lock="flock"
2547     if test $have_mail = yes || test $have_lockfile = yes; then
2548       test $ac_cv_header_maillock_h = yes && mail_lock=no
2549     fi
2550     ;;
2551 esac
2552
2553 BLESSMAIL_TARGET=
2554 case "$mail_lock" in
2555   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2556
2557   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2558
2559   *) BLESSMAIL_TARGET="need-blessmail" ;;
2560 esac
2561 AC_SUBST(BLESSMAIL_TARGET)
2562
2563
2564 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2565 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2566 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2567 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2568 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2569 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2570 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2571 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2572 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2573 cfmakeraw cfsetspeed isnan copysign)
2574
2575 AC_CHECK_HEADERS(sys/un.h)
2576
2577 AC_FUNC_MKTIME
2578 if test "$ac_cv_func_working_mktime" = no; then
2579   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2580 fi
2581
2582 AC_FUNC_GETLOADAVG
2583
2584 AC_FUNC_FSEEKO
2585
2586 # Configure getopt.
2587 m4_include([m4/getopt.m4])
2588 gl_GETOPT_IFELSE([
2589   gl_GETOPT_SUBSTITUTE_HEADER
2590   gl_PREREQ_GETOPT
2591   GETOPTOBJS='getopt.o getopt1.o'
2592 ])
2593 AC_SUBST(GETOPTOBJS)
2594
2595 AC_FUNC_GETPGRP
2596
2597 AC_FUNC_STRFTIME
2598
2599 # UNIX98 PTYs.
2600 AC_CHECK_FUNCS(grantpt)
2601
2602 # PTY-related GNU extensions.
2603 AC_CHECK_FUNCS(getpt)
2604
2605 # Check this now, so that we will NOT find the above functions in ncurses.
2606 # That is because we have not set up to link ncurses in lib-src.
2607 # It's better to believe a function is not available
2608 # than to expect to find it in ncurses.
2609 # Also we need tputs and friends to be able to build at all.
2610 have_tputs_et_al=true
2611 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2612 if test "$have_tputs_et_al" != true; then
2613   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2614 Maybe some development libraries/packages are missing?  Try installing
2615 libncurses-dev(el), libterminfo-dev(el) or similar.])
2616 fi
2617 # Must define this when any termcap library is found.
2618 AC_DEFINE(HAVE_LIBNCURSES, 1,
2619           [Define to 1 if you have the `ncurses' library (-lncurses).])
2620 ## FIXME This was the cpp logic, but I am not sure it is right.
2621 ## The above test has not necessarily found libncurses.
2622 HAVE_LIBNCURSES=yes
2623
2624 ## Use terminfo instead of termcap?
2625 ## Note only system files NOT using terminfo are:
2626 ## freebsd < 40000, ms-w32, msdos, netbsd, and
2627 ## darwin|gnu without ncurses.
2628 TERMINFO=no
2629 LIBS_TERMCAP=
2630 case "$opsys" in
2631   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2632   ## hpux10-20: Use the system provided termcap(3) library.
2633   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2634   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2635   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2636
2637   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2638   ##  The ncurses library has been moved out of the System framework in
2639   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2640   ##  option to use it.
2641   darwin|gnu*)
2642     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2643     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2644       TERMINFO=yes
2645       LIBS_TERMCAP="-lncurses"
2646     fi
2647     ;;
2648
2649   freebsd)
2650     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2651     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2652     [AC_TRY_LINK([#include <osreldate.h>],
2653 [#if __FreeBSD_version < 400000
2654 fail;
2655 #endif
2656 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2657
2658     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2659
2660     if test $emacs_cv_freebsd_terminfo = yes; then
2661       TERMINFO=yes
2662       LIBS_TERMCAP="-lncurses"
2663     else
2664       LIBS_TERMCAP="-ltermcap"
2665     fi
2666     ;;
2667
2668 esac
2669
2670 case "$opsys" in
2671   ## hpux: Make sure we get select from libc rather than from libcurses
2672   ##  because libcurses on HPUX 10.10 has a broken version of select.
2673   ##  We used to use -lc -lcurses, but this may be cleaner.
2674   hpux*|netbsd) LIBS_TERMCAP="-ltermcap" ;;
2675
2676   openbsd) LIBS_TERMCAP="-lncurses" ;;
2677
2678   ## Must use system termcap, if we use any termcap.  It does special things.
2679   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2680 esac
2681
2682 TERMCAP_OBJ=tparam.o
2683 if test $TERMINFO = yes; then
2684   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2685
2686   ## Default used to be -ltermcap.  Add a case above if need something else.
2687   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2688
2689   TERMCAP_OBJ=terminfo.o
2690 fi
2691 AC_SUBST(LIBS_TERMCAP)
2692 AC_SUBST(TERMCAP_OBJ)
2693
2694
2695 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2696 resolv=no
2697 AC_TRY_LINK([#include <netinet/in.h>
2698 #include <arpa/nameser.h>
2699 #include <resolv.h>],
2700     [return res_init();],
2701     have_res_init=yes, have_res_init=no)
2702 if test "$have_res_init" = no; then
2703   OLIBS="$LIBS"
2704   LIBS="$LIBS -lresolv"
2705   AC_MSG_CHECKING(for res_init with -lresolv)
2706   AC_TRY_LINK([#include <netinet/in.h>
2707 #include <arpa/nameser.h>
2708 #include <resolv.h>],
2709     [return res_init();],
2710     have_res_init=yes, have_res_init=no)
2711   AC_MSG_RESULT($have_res_init)
2712   if test "$have_res_init" = yes ; then
2713     resolv=yes
2714   fi
2715   LIBS="$OLIBS"
2716 fi
2717
2718 if test "$have_res_init" = yes; then
2719   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2720 fi
2721
2722 # Do we need the Hesiod library to provide the support routines?
2723 LIBHESIOD=
2724 if test "$with_hesiod" != no ; then
2725   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2726   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2727      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2728                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2729   if test "$resolv" = yes ; then
2730     RESOLVLIB=-lresolv
2731   else
2732     RESOLVLIB=
2733   fi
2734   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2735         hesiod=yes, :, $RESOLVLIB)])
2736
2737   if test x"$hesiod" = xyes; then
2738     AC_DEFINE(HAVE_LIBHESIOD, 1,
2739               [Define to 1 if you have the hesiod library (-lhesiod).])
2740     LIBHESIOD=-lhesiod
2741   fi
2742 fi
2743 AC_SUBST(LIBHESIOD)
2744
2745 # Do we need libresolv (due to res_init or Hesiod)?
2746 if test "$resolv" = yes ; then
2747   AC_DEFINE(HAVE_LIBRESOLV, 1,
2748             [Define to 1 if you have the resolv library (-lresolv).])
2749   LIBRESOLV=-lresolv
2750 else
2751   LIBRESOLV=
2752 fi
2753 AC_SUBST(LIBRESOLV)
2754
2755 # These tell us which Kerberos-related libraries to use.
2756 COM_ERRLIB=
2757 CRYPTOLIB=
2758 KRB5LIB=
2759 DESLIB=
2760 KRB4LIB=
2761
2762 if test "${with_kerberos}" != no; then
2763   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2764   if test $have_com_err = yes; then
2765     COM_ERRLIB=-lcom_err
2766     LIBS="$COM_ERRLIB $LIBS"
2767     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2768   fi
2769   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2770   if test $have_crypto = yes; then
2771     CRYPTOLIB=-lcrypto
2772     LIBS="$CRYPTOLIB $LIBS"
2773     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2774   fi
2775   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2776   if test $have_k5crypto = yes; then
2777     CRYPTOLIB=-lk5crypto
2778     LIBS="$CRYPTOLIB $LIBS"
2779     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2780   fi
2781   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2782   if test $have_krb5=yes; then
2783     KRB5LIB=-lkrb5
2784     LIBS="$KRB5LIB $LIBS"
2785     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2786   fi
2787   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2788   if test "${with_kerberos5}" = no; then
2789     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2790     if test $have_des425 = yes; then
2791       DESLIB=-ldes425
2792       LIBS="$DESLIB $LIBS"
2793       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2794     else
2795       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2796       if test $have_des = yes; then
2797         DESLIB=-ldes
2798         LIBS="$DESLIB $LIBS"
2799         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2800       fi
2801     fi
2802     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2803     if test $have_krb4 = yes; then
2804       KRB4LIB=-lkrb4
2805       LIBS="$KRB4LIB $LIBS"
2806       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2807     else
2808       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2809       if test $have_krb = yes; then
2810         KRB4LIB=-lkrb
2811         LIBS="$KRB4LIB $LIBS"
2812         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2813       fi
2814     fi
2815   fi
2816
2817   if test "${with_kerberos5}" != no; then
2818     AC_CHECK_HEADERS(krb5.h,
2819       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2820                         [#include <krb5.h>])])
2821   else
2822     AC_CHECK_HEADERS(des.h,,
2823                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2824                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2825     AC_CHECK_HEADERS(krb.h,,
2826                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2827                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2828   fi
2829   AC_CHECK_HEADERS(com_err.h)
2830 fi
2831
2832 AC_SUBST(COM_ERRLIB)
2833 AC_SUBST(CRYPTOLIB)
2834 AC_SUBST(KRB5LIB)
2835 AC_SUBST(DESLIB)
2836 AC_SUBST(KRB4LIB)
2837
2838 # Solaris requires -lintl if you want strerror (which calls dgettext)
2839 # to return localized messages.
2840 AC_CHECK_LIB(intl, dgettext)
2841
2842 AC_MSG_CHECKING(whether localtime caches TZ)
2843 AC_CACHE_VAL(emacs_cv_localtime_cache,
2844 [if test x$ac_cv_func_tzset = xyes; then
2845 AC_TRY_RUN([#include <time.h>
2846 extern char **environ;
2847 unset_TZ ()
2848 {
2849   char **from, **to;
2850   for (to = from = environ; (*to = *from); from++)
2851     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2852       to++;
2853 }
2854 char TZ_GMT0[] = "TZ=GMT0";
2855 char TZ_PST8[] = "TZ=PST8";
2856 main()
2857 {
2858   time_t now = time ((time_t *) 0);
2859   int hour_GMT0, hour_unset;
2860   if (putenv (TZ_GMT0) != 0)
2861     exit (1);
2862   hour_GMT0 = localtime (&now)->tm_hour;
2863   unset_TZ ();
2864   hour_unset = localtime (&now)->tm_hour;
2865   if (putenv (TZ_PST8) != 0)
2866     exit (1);
2867   if (localtime (&now)->tm_hour == hour_GMT0)
2868     exit (1);
2869   unset_TZ ();
2870   if (localtime (&now)->tm_hour != hour_unset)
2871     exit (1);
2872   exit (0);
2873 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2874 [# If we have tzset, assume the worst when cross-compiling.
2875 emacs_cv_localtime_cache=yes])
2876 else
2877         # If we lack tzset, report that localtime does not cache TZ,
2878         # since we can't invalidate the cache if we don't have tzset.
2879         emacs_cv_localtime_cache=no
2880 fi])dnl
2881 AC_MSG_RESULT($emacs_cv_localtime_cache)
2882 if test $emacs_cv_localtime_cache = yes; then
2883   AC_DEFINE(LOCALTIME_CACHE, 1,
2884             [Define to 1 if localtime caches TZ.])
2885 fi
2886
2887 if test "x$HAVE_TIMEVAL" = xyes; then
2888   AC_CHECK_FUNCS(gettimeofday)
2889   if test $ac_cv_func_gettimeofday = yes; then
2890     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2891                    emacs_cv_gettimeofday_two_arguments,
2892     [AC_TRY_COMPILE([
2893 #ifdef TIME_WITH_SYS_TIME
2894 #include <sys/time.h>
2895 #include <time.h>
2896 #else
2897 #ifdef HAVE_SYS_TIME_H
2898 #include <sys/time.h>
2899 #else
2900 #include <time.h>
2901 #endif
2902 #endif],
2903       [struct timeval time;
2904        gettimeofday (&time, 0);],
2905       emacs_cv_gettimeofday_two_arguments=yes,
2906       emacs_cv_gettimeofday_two_arguments=no)])
2907     if test $emacs_cv_gettimeofday_two_arguments = no; then
2908       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2909                 [Define to 1 if gettimeofday accepts only one argument.])
2910     fi
2911   fi
2912 fi
2913
2914 ok_so_far=yes
2915 AC_CHECK_FUNC(socket, , ok_so_far=no)
2916 if test $ok_so_far = yes; then
2917   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2918 fi
2919 if test $ok_so_far = yes; then
2920   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2921 fi
2922 if test $ok_so_far = yes; then
2923 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2924   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2925             [Define to 1 if you have inet sockets.])
2926 fi
2927
2928 AC_CHECK_HEADERS(sys/ioctl.h)
2929
2930 if test -f /usr/lpp/X11/bin/smt.exp; then
2931   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2932             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2933 fi
2934
2935 AC_MSG_CHECKING(whether system supports dynamic ptys)
2936 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2937   AC_MSG_RESULT(yes)
2938   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2939 else
2940   AC_MSG_RESULT(no)
2941 fi
2942
2943 AC_FUNC_FORK
2944
2945 dnl Adapted from Haible's version.
2946 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2947   [AC_TRY_LINK([#include <langinfo.h>],
2948     [char* cs = nl_langinfo(CODESET);],
2949     emacs_cv_langinfo_codeset=yes,
2950     emacs_cv_langinfo_codeset=no)
2951   ])
2952 if test $emacs_cv_langinfo_codeset = yes; then
2953   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2954     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2955 fi
2956
2957 AC_CHECK_TYPES(size_t)
2958
2959 AC_TYPE_MBSTATE_T
2960
2961 dnl Restrict could probably be used effectively other than in regex.c.
2962 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2963   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2964                   emacs_cv_c_restrict=yes,
2965                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2966                                   emacs_cv_c_restrict=__restrict,
2967                                   emacs_cv_c_restrict=no)])])
2968 case "$emacs_cv_c_restrict" in
2969   yes) emacs_restrict=restrict;;
2970   no) emacs_restrict="";;
2971   *) emacs_restrict="$emacs_cv_c_restrict";;
2972 esac
2973 if test "$emacs_restrict" != __restrict; then
2974   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2975     [Define to compiler's equivalent of C99 restrict keyword.
2976      Don't define if equivalent is `__restrict'.])
2977 fi
2978
2979 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2980   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2981                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2982 if test "$emacs_cv_c_restrict_arr" = yes; then
2983   AC_DEFINE(__restrict_arr, __restrict,
2984     [Define to compiler's equivalent of C99 restrict keyword in array
2985      declarations.  Define as empty for no equivalent.])
2986 fi
2987
2988 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2989 dnl how the tty code is related to POSIX and/or other versions of termios.
2990 dnl The following looks like a useful start.
2991 dnl
2992 dnl AC_SYS_POSIX_TERMIOS
2993 dnl if test $ac_cv_sys_posix_termios = yes; then
2994 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2995 dnl                                and macros for terminal control.])
2996 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2997 dnl fi
2998
2999 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3000
3001 # Set up the CFLAGS for real compilation, so we can substitute it.
3002 CFLAGS="$REAL_CFLAGS"
3003 CPPFLAGS="$REAL_CPPFLAGS"
3004
3005 ## Hack to detect a buggy GCC version.
3006 if test "x$GCC" = xyes \
3007    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3008    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3009    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3010    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3011 fi
3012
3013 #### Find out which version of Emacs this is.
3014 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3015          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3016 if test x"${version}" = x; then
3017   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3018 fi
3019 if test x"${version}" != x"$PACKAGE_VERSION"; then
3020   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3021 fi
3022
3023 ### Specify what sort of things we'll be editing into Makefile and config.h.
3024 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3025 AC_SUBST(version)
3026 AC_SUBST(configuration)
3027 ## Unused?
3028 AC_SUBST(canonical)
3029 AC_SUBST(srcdir)
3030 AC_SUBST(prefix)
3031 AC_SUBST(exec_prefix)
3032 AC_SUBST(bindir)
3033 AC_SUBST(datadir)
3034 AC_SUBST(sharedstatedir)
3035 AC_SUBST(libexecdir)
3036 AC_SUBST(mandir)
3037 AC_SUBST(infodir)
3038 AC_SUBST(lispdir)
3039 AC_SUBST(locallisppath)
3040 AC_SUBST(lisppath)
3041 AC_SUBST(x_default_search_path)
3042 AC_SUBST(etcdir)
3043 AC_SUBST(archlibdir)
3044 AC_SUBST(docdir)
3045 AC_SUBST(bitmapdir)
3046 AC_SUBST(gamedir)
3047 AC_SUBST(gameuser)
3048 AC_SUBST(unexec)
3049 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3050 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3051 ## end of LIBX_BASE, but nothing ever set it.
3052 AC_SUBST(LD_SWITCH_X_SITE)
3053 AC_SUBST(C_SWITCH_X_SITE)
3054 AC_SUBST(C_SWITCH_X_SYSTEM)
3055 AC_SUBST(CFLAGS)
3056 ## Used in lwlib/Makefile.in.
3057 AC_SUBST(X_TOOLKIT_TYPE)
3058 AC_SUBST(machfile)
3059 AC_SUBST(opsysfile)
3060 AC_SUBST(GETLOADAVG_LIBS)
3061 AC_SUBST(ns_appdir)
3062 AC_SUBST(ns_appbindir)
3063 AC_SUBST(ns_appresdir)
3064 AC_SUBST(ns_appsrc)
3065 AC_SUBST(GNU_OBJC_CFLAGS)
3066 AC_SUBST(OTHER_FILES)
3067
3068 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3069                    [Define to the canonical Emacs configuration name.])
3070 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3071                    [Define to the options passed to configure.])
3072 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3073                    [Define to the used machine dependent file.])
3074 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3075                    [Define to the used os dependent file.])
3076
3077 XMENU_OBJ=
3078 XOBJ=
3079 FONT_OBJ=
3080 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3081   AC_DEFINE(HAVE_X_WINDOWS, 1,
3082             [Define to 1 if you want to use the X window system.])
3083   XMENU_OBJ=xmenu.o
3084   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3085   FONT_OBJ=xfont.o
3086   if test "$HAVE_XFT" = "yes"; then
3087     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3088   elif test "$HAVE_FREETYPE" = "yes"; then
3089     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3090   fi
3091   AC_SUBST(FONT_OBJ)
3092 fi
3093 AC_SUBST(XMENU_OBJ)
3094 AC_SUBST(XOBJ)
3095 AC_SUBST(FONT_OBJ)
3096
3097 WIDGET_OBJ=
3098 MOTIF_LIBW=
3099 if test "${USE_X_TOOLKIT}" != "none" ; then
3100   WIDGET_OBJ=widget.o
3101   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3102   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3103     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3104   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3105     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3106     MOTIF_LIBW=-lXm
3107     case "$opsys" in
3108       gnu-linux)
3109         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3110         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3111         ;;
3112
3113       unixware)
3114         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3115         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3116         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3117         ;;
3118
3119       aix4-2)
3120         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3121         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3122         ;;
3123     esac
3124     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3125   fi
3126 fi
3127 AC_SUBST(WIDGET_OBJ)
3128
3129 TOOLKIT_LIBW=
3130 case "$USE_X_TOOLKIT" in
3131   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3132   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3133   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3134 esac
3135 AC_SUBST(TOOLKIT_LIBW)
3136
3137 if test "$USE_X_TOOLKIT" = "none"; then
3138   LIBXT_OTHER="\$(LIBXSM)"
3139   OLDXMENU_TARGET="really-oldXMenu"
3140 else
3141   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3142   OLDXMENU_TARGET="really-lwlib"
3143 fi
3144 AC_SUBST(LIBXT_OTHER)
3145 AC_SUBST(OLDXMENU_TARGET)
3146
3147 ## The X Menu stuff is present in the X10 distribution, but missing
3148 ## from X11.  If we have X10, just use the installed library;
3149 ## otherwise, use our own copy.
3150 if test "${HAVE_X11}" = "yes" ; then
3151   AC_DEFINE(HAVE_X11, 1,
3152             [Define to 1 if you want to use version 11 of X windows.
3153              Otherwise, Emacs expects to use version 10.])
3154
3155   if test "$USE_X_TOOLKIT" = "none"; then
3156     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3157   else
3158     OLDXMENU="\${lwlibdir}liblw.a"
3159   fi
3160   LIBXMENU="\$(OLDXMENU)"
3161   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3162 else
3163   OLDXMENU=
3164   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3165   if test "${HAVE_X_WINDOWS}" = "yes"; then
3166     LIBXMENU="-lXMenu"
3167   else
3168     LIBXMENU=
3169   fi
3170   LIBX_OTHER=
3171 fi
3172
3173 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3174   OLDXMENU=
3175   LIBXMENU=
3176 fi
3177
3178 AC_SUBST(OLDXMENU)
3179 AC_SUBST(LIBXMENU)
3180 AC_SUBST(LIBX_OTHER)
3181
3182 if test "${HAVE_MENUS}" = "yes" ; then
3183   AC_DEFINE(HAVE_MENUS, 1,
3184             [Define to 1 if you have mouse menus.
3185              (This is automatic if you use X, but the option to specify it remains.)
3186              It is also defined with other window systems that support xmenu.c.])
3187 fi
3188 if test "${GNU_MALLOC}" = "yes" ; then
3189   AC_DEFINE(GNU_MALLOC, 1,
3190             [Define to 1 if you want to use the GNU memory allocator.])
3191 fi
3192 if test "${REL_ALLOC}" = "yes" ; then
3193   AC_DEFINE(REL_ALLOC, 1,
3194             [Define REL_ALLOC if you want to use the relocating allocator for
3195              buffer space.])
3196 fi
3197
3198
3199 if test "$opsys" = "cygwin"; then
3200   CYGWIN_OBJ="sheap.o"
3201   ## Cygwin differs because of its unexec().
3202   PRE_ALLOC_OBJ=
3203   POST_ALLOC_OBJ="lastfile.o vm-limit.o"
3204 else
3205   CYGWIN_OBJ=
3206   PRE_ALLOC_OBJ=lastfile.o
3207   POST_ALLOC_OBJ="\$(vmlimitobj)"
3208 fi
3209 AC_SUBST(CYGWIN_OBJ)
3210 AC_SUBST(PRE_ALLOC_OBJ)
3211 AC_SUBST(POST_ALLOC_OBJ)
3212
3213
3214 case "$opsys" in
3215   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3216
3217   darwin)
3218   ## The -headerpad option tells ld (see man page) to leave room at the
3219   ## end of the header for adding load commands.  Needed for dumping.
3220   ## 0x690 is the total size of 30 segment load commands (at 56
3221   ## each); under Cocoa 31 commands are required.
3222   if test "$HAVE_NS" = "yes"; then
3223     libs_nsgui="-framework AppKit"
3224     headerpad_extra=6C8
3225   else
3226     libs_nsgui=
3227     headerpad_extra=690
3228   fi
3229   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3230   ;;
3231
3232   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3233 esac
3234 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3235
3236
3237 ## This exists because src/Makefile.in did some extra fiddling around
3238 ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3239 ##   #ifndef LD_SWITCH_SYSTEM
3240 ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3241 ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3242 ## not using gcc, darwin system not on an alpha (ie darwin, since
3243 ## darwin + alpha does not occur).
3244 ## Note that unlike L_S_S, this is not used in ac_link.
3245 if test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3246    test "$opsys" = "darwin"; then
3247   LD_SWITCH_SYSTEM_EXTRA="-X"
3248 else
3249   LD_SWITCH_SYSTEM_EXTRA=
3250 fi
3251 AC_SUBST(LD_SWITCH_SYSTEM_EXTRA)
3252
3253
3254 LIB_GCC=
3255 if test "x$GCC" = "xyes"; then
3256
3257   case "$opsys" in
3258     ## cygwin: don't link against static libgcc.
3259     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3260
3261     gnu-*)
3262       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3263       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3264       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3265       if test "$machine" = "arm"; then
3266         LIB_GCC="-lgcc_s"
3267       else
3268         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3269         ## immediately undefine it again and redefine it to empty.
3270         ## Was the C_SWITCH_X_SITE part really necessary?
3271 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3272         LIB_GCC=
3273       fi
3274       ;;
3275
3276     ## Ask GCC where to find libgcc.a.
3277     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3278   esac
3279 fi                              dnl if $GCC
3280 AC_SUBST(LIB_GCC)
3281
3282
3283 TOOLTIP_SUPPORT=
3284 WINDOW_SUPPORT=
3285 ## If we're using X11/GNUstep, define some consequences.
3286 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3287   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3288   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3289   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3290   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3291
3292   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3293   test "$HAVE_X_WINDOWS" = "yes" && \
3294     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3295
3296 fi
3297 AC_SUBST(MOUSE_SUPPORT)
3298 AC_SUBST(TOOLTIP_SUPPORT)
3299 AC_SUBST(WINDOW_SUPPORT)
3300
3301
3302 AH_TOP([/* GNU Emacs site configuration template file.
3303    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3304      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3305
3306 This file is part of GNU Emacs.
3307
3308 GNU Emacs is free software: you can redistribute it and/or modify
3309 it under the terms of the GNU General Public License as published by
3310 the Free Software Foundation, either version 3 of the License, or
3311 (at your option) any later version.
3312
3313 GNU Emacs is distributed in the hope that it will be useful,
3314 but WITHOUT ANY WARRANTY; without even the implied warranty of
3315 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3316 GNU General Public License for more details.
3317
3318 You should have received a copy of the GNU General Public License
3319 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3320
3321
3322 /* No code in Emacs #includes config.h twice, but some bits of code
3323    intended to work with other packages as well (like gmalloc.c)
3324    think they can include it as many times as they like.  */
3325 #ifndef EMACS_CONFIG_H
3326 #define EMACS_CONFIG_H
3327 ])dnl
3328
3329 AH_BOTTOM([
3330 /* Define AMPERSAND_FULL_NAME if you use the convention
3331    that & in the full name stands for the login id.  */
3332 /* Turned on June 1996 supposing nobody will mind it.  */
3333 #define AMPERSAND_FULL_NAME
3334
3335 /* Define HAVE_SOUND if we have sound support.  We know it works
3336    and compiles only on the specified platforms.   For others,
3337    it probably doesn't make sense to try.  */
3338
3339 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3340 #ifdef HAVE_MACHINE_SOUNDCARD_H
3341 #define HAVE_SOUND 1
3342 #endif
3343 #ifdef HAVE_SYS_SOUNDCARD_H
3344 #define HAVE_SOUND 1
3345 #endif
3346 #ifdef HAVE_SOUNDCARD_H
3347 #define HAVE_SOUND 1
3348 #endif
3349 #ifdef HAVE_ALSA
3350 #define HAVE_SOUND 1
3351 #endif
3352 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3353
3354 /* If using GNU, then support inline function declarations.  */
3355 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3356    generally, because even if non-gcc compilers accept `inline', they
3357    may reject `extern inline'.  */
3358 #if defined (__GNUC__) && defined (OPTIMIZE)
3359 #define INLINE __inline__
3360 #else
3361 #define INLINE
3362 #endif
3363
3364 /* `subprocesses' should be defined if you want to
3365    have code for asynchronous subprocesses
3366    (as used in M-x compile and M-x shell).
3367    Only MSDOS does not support this (it overrides
3368    this in its config_opsysfile below).  */
3369
3370 #define subprocesses
3371
3372 /* Include the os and machine dependent files.  */
3373 #include config_opsysfile
3374 #include config_machfile
3375
3376 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3377   (There is probably a better place to do this, but right now the Cocoa
3378    side does this in s/darwin.h and we cannot
3379    parallel this exactly since GNUstep is multi-OS.  */
3380 #ifdef HAVE_NS
3381 # ifdef NS_IMPL_GNUSTEP
3382 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3383 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3384 #  define SYSTEM_PURESIZE_EXTRA 30000
3385 # endif /* NS_IMPL_GNUSTEP */
3386 #endif /* HAVE_NS */
3387
3388 /* SIGTYPE is the macro we actually use.  */
3389 #ifndef SIGTYPE
3390 #define SIGTYPE RETSIGTYPE
3391 #endif
3392
3393 #ifdef emacs /* Don't do this for lib-src.  */
3394 /* Tell regex.c to use a type compatible with Emacs.  */
3395 #define RE_TRANSLATE_TYPE Lisp_Object
3396 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3397 #ifdef make_number
3398 /* If make_number is a macro, use it.  */
3399 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3400 #else
3401 /* If make_number is a function, avoid it.  */
3402 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3403 #endif
3404 #endif
3405
3406 /* Avoid link-time collision with system mktime if we will use our own.  */
3407 #if ! HAVE_MKTIME || BROKEN_MKTIME
3408 #define mktime emacs_mktime
3409 #endif
3410
3411 #define my_strftime nstrftime   /* for strftime.c */
3412
3413 /* The rest of the code currently tests the CPP symbol BSTRING.
3414    Override any claims made by the system-description files.
3415    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3416 #undef BSTRING
3417 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3418 #define BSTRING
3419 #endif
3420
3421 /* Some of the files of Emacs which are intended for use with other
3422    programs assume that if you have a config.h file, you must declare
3423    the type of getenv.
3424
3425    This declaration shouldn't appear when alloca.s or Makefile.in
3426    includes config.h.  */
3427 #ifndef NOT_C_CODE
3428 extern char *getenv ();
3429 #endif
3430
3431 /* These default definitions are good for almost all machines.
3432    The exceptions override them in m/MACHINE.h.  */
3433
3434 #ifndef BITS_PER_CHAR
3435 #define BITS_PER_CHAR 8
3436 #endif
3437
3438 #ifndef BITS_PER_SHORT
3439 #define BITS_PER_SHORT 16
3440 #endif
3441
3442 /* Note that lisp.h uses this in a preprocessor conditional, so it
3443    would not work to use sizeof.  That being so, we do all of them
3444    without sizeof, for uniformity's sake.  */
3445 #ifndef BITS_PER_INT
3446 #define BITS_PER_INT 32
3447 #endif
3448
3449 #ifndef BITS_PER_LONG
3450 #ifdef _LP64
3451 #define BITS_PER_LONG 64
3452 #else
3453 #define BITS_PER_LONG 32
3454 #endif
3455 #endif
3456
3457 /* Define if the compiler supports function prototypes.  It may do so
3458    but not define __STDC__ (e.g. DEC C by default) or may define it as
3459    zero.  */
3460 #undef PROTOTYPES
3461 /* For mktime.c:  */
3462 #ifndef __P
3463 # if defined PROTOTYPES
3464 #  define __P(args) args
3465 # else
3466 #  define __P(args) ()
3467 # endif  /* GCC.  */
3468 #endif /* __P */
3469
3470 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3471 #ifndef NOT_C_CODE
3472 #ifdef HAVE_STRING_H
3473 #include "string.h"
3474 #endif
3475 #ifdef HAVE_STRINGS_H
3476 #include "strings.h"  /* May be needed for bcopy & al.  */
3477 #endif
3478 #ifdef HAVE_STDLIB_H
3479 #include <stdlib.h>
3480 #endif
3481 #ifndef __GNUC__
3482 # ifdef HAVE_ALLOCA_H
3483 #  include <alloca.h>
3484 # else /* AIX files deal with #pragma.  */
3485 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3486 char *alloca ();
3487 #  endif
3488 # endif /* HAVE_ALLOCA_H */
3489 #endif /* __GNUC__ */
3490 #ifndef HAVE_SIZE_T
3491 typedef unsigned size_t;
3492 #endif
3493 #endif /* NOT_C_CODE */
3494
3495 /* Define HAVE_X_I18N if we have usable i18n support.  */
3496
3497 #ifdef HAVE_X11R6
3498 #define HAVE_X_I18N
3499 #endif
3500
3501 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3502
3503 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3504 #define HAVE_X11R6_XIM
3505 #endif
3506
3507 #if defined __GNUC__ && (__GNUC__ > 2 \
3508                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3509 #define NO_RETURN       __attribute__ ((__noreturn__))
3510 #else
3511 #define NO_RETURN       /* nothing */
3512 #endif
3513
3514 /* These won't be used automatically yet.  We also need to know, at least,
3515    that the stack is continuous.  */
3516 #ifdef __GNUC__
3517 #  ifndef GC_SETJMP_WORKS
3518   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3519 #    define GC_SETJMP_WORKS 1
3520 #  endif
3521 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3522 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3523 #  endif
3524 #endif
3525
3526 #ifndef HAVE_BCOPY
3527 #define bcopy(a,b,s) memcpy (b,a,s)
3528 #endif
3529 #ifndef HAVE_BZERO
3530 #define bzero(a,s) memset (a,0,s)
3531 #endif
3532 #ifndef HAVE_BCMP
3533 #define BCMP memcmp
3534 #endif
3535
3536 #endif /* EMACS_CONFIG_H */
3537
3538 /*
3539 Local Variables:
3540 mode: c
3541 End:
3542 */
3543 ])dnl
3544
3545 #### Report on what we decided to do.
3546 #### Report GTK as a toolkit, even if it doesn't use Xt.
3547 #### It makes printing result more understandable as using GTK sets
3548 #### toolkit_scroll_bars to yes by default.
3549 if test "${HAVE_GTK}" = "yes"; then
3550   USE_X_TOOLKIT=GTK
3551 fi
3552
3553 echo "
3554 Configured for \`${canonical}'.
3555
3556   Where should the build process find the source code?    ${srcdir}
3557   What operating system and machine description files should Emacs use?
3558         \`${opsysfile}' and \`${machfile}'
3559   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3560   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3561   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3562   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3563   What window system should Emacs use?                    ${window_system}
3564   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3565
3566 if test -n "${x_includes}"; then
3567 echo "  Where do we find X Windows header files?                ${x_includes}"
3568 else
3569 echo "  Where do we find X Windows header files?                Standard dirs"
3570 fi
3571 if test -n "${x_libraries}"; then
3572 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3573 else
3574 echo "  Where do we find X Windows libraries?                   Standard dirs"
3575 fi
3576
3577 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3578 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3579 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3580 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3581 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3582 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3583 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3584 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3585 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3586 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3587 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3588
3589 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3590 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3591 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3592 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3593
3594 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3595 echo
3596
3597 if test $USE_XASSERTS = yes; then
3598    echo "  Compiling with asserts turned on."
3599    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3600 fi
3601
3602 echo
3603
3604 if test "$HAVE_NS" = "yes"; then
3605    echo
3606    echo "You must run \"make install\" in order to test the built application.
3607 The installed application will go to nextstep/Emacs.app and can be
3608 run or moved from there."
3609    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3610       echo "The application will be fully self-contained."
3611     else
3612       echo "The lisp resources for the application will be installed under ${prefix}.
3613 You may need to run \"make install\" with sudo.  The application will fail
3614 to run if these resources are not installed."
3615    fi
3616    echo
3617 fi
3618
3619 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3620   echo "D-Bus integration has been tested for GNU/Linux only."
3621   echo
3622 fi
3623
3624
3625 # Remove any trailing slashes in these variables.
3626 [test "${prefix}" != NONE &&
3627   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3628 test "${exec_prefix}" != NONE &&
3629   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3630
3631 # Now get this: Some word that is part of the ${srcdir} directory name
3632 # or the ${configuration} value might, just might, happen to be an
3633 # identifier like `sun4' or `i386' or something, and be predefined by
3634 # the C preprocessor to some helpful value like 1, or maybe the empty
3635 # string.  Needless to say consequent macro substitutions are less
3636 # than conducive to the makefile finding the correct directory.
3637 # src/Makefile.in used to treat X11 as equivalent to HAVE_X11.
3638 # But nothing in Emacs defines X11, and everywhere else uses HAVE_X11,
3639 # so that cannot have been doing anything.
3640 [cpp_undefs="`echo $srcdir $configuration $canonical unix mktime register X11 |
3641   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3642   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3643
3644 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3645 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3646 ## from Makefile.c can correctly provide the arg `-traditional' to the
3647 ## C preprocessor.
3648
3649 AC_EGREP_CPP(yes..yes,
3650         [yes..yes],
3651         CPP_NEED_TRADITIONAL=no,
3652         CPP_NEED_TRADITIONAL=yes)
3653
3654 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3655         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3656         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3657         lwlib/Makefile lisp/Makefile leim/Makefile, [
3658
3659 ### Make the necessary directories, if they don't exist.
3660 for dir in etc lisp ; do
3661   test -d ${dir} || mkdir ${dir}
3662 done
3663
3664 # Build src/Makefile from ${srcdir}/src/Makefile.c
3665 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3666 # This must be done after src/config.h is built, since we rely on that file.
3667
3668 echo creating src/epaths.h
3669 ${MAKE-make} epaths-force
3670
3671 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3672 # `..' to `. .'  unless invoked with -traditional
3673
3674 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3675   CPPFLAGS="$CPPFLAGS -traditional"
3676 fi
3677
3678 echo creating src/Makefile
3679 ( cd src
3680   rm -f junk.c junk1.c junk2.c
3681   sed -e '/start of cpp stuff/q' \
3682       < Makefile.c > junk1.c
3683   sed -e '1,/start of cpp stuff/d'\
3684       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3685       < Makefile.c > junk.c
3686   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3687       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3688   cat junk1.c junk2.c > Makefile.new
3689   rm -f junk.c junk1.c junk2.c
3690   chmod 444 Makefile.new
3691   mv -f Makefile.new Makefile
3692 )
3693
3694 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3695   echo creating src/.gdbinit
3696   echo source $srcdir/src/.gdbinit > src/.gdbinit
3697 fi
3698
3699 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3700
3701 m4_if(dnl       Do not change this comment
3702    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3703 )dnl