configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(use-lisp-union-type,
 309 [AS_HELP_STRING([--enable-use-lisp-union-type],
 310                 [use a union for the Lisp_Object data type.
 311                 This is only useful for development for catching certain types of bugs.])],
 312 if test "${enableval}" != "no"; then
 313    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 314    [Define this to use a lisp union for the Lisp_Object data type.])
 315 fi)
 316
 317
 318 AC_ARG_ENABLE(profiling,
 319 [AS_HELP_STRING([--enable-profiling],
 320                 [build emacs with profiling support.
 321                  This might not work on all platforms])],
 322 [ac_enable_profiling="${enableval}"],[])
 323 if test x$ac_enable_profiling != x ; then
 324    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 325    PROFILING_LDFLAGS="-pg"
 326 else
 327    PROFILING_CFLAGS=
 328    PROFILING_LDFLAGS=
 329 fi
 330 AC_SUBST(PROFILING_CFLAGS)
 331 AC_SUBST(PROFILING_LDFLAGS)
 332
 333 AC_ARG_ENABLE(autodepend,
 334 [AS_HELP_STRING([--enable-autodepend],
 335                 [automatically generate dependencies to .h-files.
 336                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 337                  found])],
 338 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 339
 340 #### Make srcdir absolute, if it isn't already.  It's important to
 341 #### avoid running the path through pwd unnecessarily, since pwd can
 342 #### give you automounter prefixes, which can go away.  We do all this
 343 #### so Emacs can find its files when run uninstalled.
 344 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 345 unset CDPATH
 346 case "${srcdir}" in
 347   /* ) ;;
 348   . )
 349     ## We may be able to use the $PWD environment variable to make this
 350     ## absolute.  But sometimes PWD is inaccurate.
 351     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 352     ## but that tested only for a well-formed and valid PWD,
 353     ## it did not object when PWD was well-formed and valid but just wrong.
 354     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 355     then
 356       srcdir="$PWD"
 357     else
 358       srcdir="`(cd ${srcdir}; pwd)`"
 359     fi
 360   ;;
 361   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 362 esac
 363
 364 #### Check if the source directory already has a configured system in it.
 365 if test `pwd` != `(cd ${srcdir} && pwd)` \
 366    && test -f "${srcdir}/src/config.h" ; then
 367   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 368    as a build directory right now; it has been configured in its own
 369    right.  To configure in another directory as well, you MUST
 370    use GNU make.  If you do not have GNU make, then you must
 371    now do `make distclean' in ${srcdir},
 372    and then run $0 again.]])
 373 fi
 374
 375 #### Given the configuration name, set machfile and opsysfile to the
 376 #### names of the m/*.h and s/*.h files we should use.
 377
 378 ### Canonicalize the configuration name.
 379
 380 AC_CANONICAL_HOST
 381 canonical=$host
 382 configuration=${host_alias-${build_alias-$host}}
 383
 384 dnl This used to use changequote, but, apart from `changequote is evil'
 385 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 386 dnl the great gob of text.  Thus it's not processed for possible expansion.
 387 dnl Just make sure the brackets remain balanced.
 388 dnl
 389 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 390 dnl indicated by comments.
 391 dnl quotation begins
 392 [
 393
 394 ### If you add support for a new configuration, add code to this
 395 ### switch statement to recognize your configuration name and select
 396 ### the appropriate operating system and machine description files.
 397
 398 ### You would hope that you could choose an m/*.h file pretty much
 399 ### based on the machine portion of the configuration name, and an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each m/*.h file is pretty manufacturer-specific - for
 402 ### example mips.h is MIPS
 403 ### So we basically have to have a special case for each
 404 ### configuration name.
 405 ###
 406 ### As far as handling version numbers on operating systems is
 407 ### concerned, make sure things will fail in a fixable way.  If
 408 ### /etc/MACHINES doesn't say anything about version numbers, be
 409 ### prepared to handle anything reasonably.  If version numbers
 410 ### matter, be sure /etc/MACHINES says something about it.
 411
 412 machine='' opsys='' unported=no
 413 case "${canonical}" in
 414
 415   ## FreeBSD ports
 416   *-*-freebsd* )
 417     opsys=freebsd
 418     case "${canonical}" in
 419       alpha*)           machine=alpha ;;
 420       amd64-*|x86_64-*) machine=amdx86-64 ;;
 421       arm*)             machine=arm ;;
 422       ia64-*)           machine=ia64 ;;
 423       i[3456]86-*)      machine=intel386 ;;
 424       powerpc-*)        machine=macppc ;;
 425       sparc-*)          machine=sparc ;;
 426       sparc64-*)        machine=sparc ;;
 427     esac
 428   ;;
 429
 430   ## FreeBSD kernel + glibc based userland
 431   *-*-kfreebsd*gnu* )
 432     opsys=gnu-kfreebsd
 433     case "${canonical}" in
 434       alpha*)           machine=alpha ;;
 435       amd64-*|x86_64-*) machine=amdx86-64 ;;
 436       ia64-*)           machine=ia64 ;;
 437       i[3456]86-*)      machine=intel386 ;;
 438       powerpc-*)        machine=macppc ;;
 439       sparc-*)          machine=sparc ;;
 440       sparc64-*)        machine=sparc ;;
 441     esac
 442   ;;
 443
 444   ## NetBSD ports
 445   *-*-netbsd* )
 446     opsys=netbsd
 447     case "${canonical}" in
 448       alpha*)      machine=alpha ;;
 449       x86_64-*)    machine=amdx86-64 ;;
 450       arm-*)       machine=arm ;;
 451       hppa-*)      machine=hp800 ;;
 452       i[3456]86-*) machine=intel386 ;;
 453       m68k-*)      machine=m68k ;;
 454       powerpc-*)   machine=macppc ;;
 455       mips-*)      machine=mips ;;
 456       mipse[bl]-*) machine=mips ;;
 457       sparc*-)     machine=sparc ;;
 458       vax-*)       machine=vax ;;
 459     esac
 460   ;;
 461
 462   ## OpenBSD ports
 463   *-*-openbsd* )
 464     opsys=openbsd
 465     case "${canonical}" in
 466       alpha*)    machine=alpha ;;
 467       x86_64-*)  machine=amdx86-64 ;;
 468       arm-*)     machine=arm ;;
 469       hppa-*)    machine=hp800 ;;
 470       i386-*)    machine=intel386 ;;
 471       powerpc-*) machine=macppc ;;
 472       sparc*)    machine=sparc ;;
 473       vax-*)     machine=vax ;;
 474     esac
 475   ;;
 476
 477   alpha*-*-linux-gnu* )
 478     machine=alpha opsys=gnu-linux
 479   ;;
 480
 481   arm*-*-linux-gnu* )
 482     machine=arm opsys=gnu-linux
 483   ;;
 484
 485   ## Apple Darwin / Mac OS X
 486   *-apple-darwin* )
 487     case "${canonical}" in
 488       i[3456]86-* )  machine=intel386 ;;
 489       powerpc-* )    machine=macppc ;;
 490       x86_64-* )     machine=amdx86-64 ;;
 491       * )            unported=yes ;;
 492     esac
 493     opsys=darwin
 494     # Define CPP as follows to make autoconf work correctly.
 495     CPP="${CC-cc} -E -no-cpp-precomp"
 496     # Use fink packages if available.
 497     if test -d /sw/include && test -d /sw/lib; then
 498       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 499       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 500       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 501     fi
 502   ;;
 503
 504   ## HP 9000 series 700 and 800, running HP/UX
 505   hppa*-hp-hpux10.2* )
 506     machine=hp800 opsys=hpux10-20
 507   ;;
 508   hppa*-hp-hpux1[1-9]* )
 509     machine=hp800 opsys=hpux11
 510     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 511   ;;
 512
 513   hppa*-*-linux-gnu* )
 514     machine=hp800 opsys=gnu-linux
 515   ;;
 516
 517   ## IBM machines
 518   s390-*-linux-gnu* )
 519     machine=ibms390 opsys=gnu-linux
 520   ;;
 521   s390x-*-linux-gnu* )
 522     machine=ibms390x opsys=gnu-linux
 523   ;;
 524   rs6000-ibm-aix4.[23]* )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527   powerpc-ibm-aix4.[23]*  )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   rs6000-ibm-aix[56]* )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   powerpc-ibm-aix[56]*  )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536
 537   ## Macintosh PowerPC
 538   powerpc*-*-linux-gnu* )
 539     machine=macppc opsys=gnu-linux
 540   ;;
 541
 542   ## Silicon Graphics machines
 543   ## Iris 4D
 544   mips-sgi-irix6.5 )
 545     machine=iris4d opsys=irix6-5
 546     # Without defining _LANGUAGE_C, things get masked out in the headers
 547     # so that, for instance, grepping for `free' in stdlib.h fails and
 548     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 549     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 550     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 551   ;;
 552
 553   ## Suns
 554   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 555     machine=sparc opsys=gnu-linux
 556   ;;
 557
 558   *-sun-solaris* \
 559     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 560     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 561     case "${canonical}" in
 562       i[3456]86-*-* )     machine=intel386 ;;
 563       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 564       sparc* )          machine=sparc ;;
 565       * )               unported=yes ;;
 566     esac
 567     case "${canonical}" in
 568       *-sunos5.6* | *-solaris2.6* )
 569                 opsys=sol2-6
 570                 NON_GNU_CPP=/usr/ccs/lib/cpp
 571                 RANLIB="ar -ts"
 572                 ;;
 573       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 574                 opsys=sol2-6
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578       *-sunos5* | *-solaris* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 NON_GNU_CPP=/usr/ccs/lib/cpp
 582                 ;;
 583     esac
 584     ## Watch out for a compiler that we know will not work.
 585     case "${canonical}" in
 586      *-solaris* | *-sunos5* )
 587                 if [ "x$CC" = x/usr/ucb/cc ]; then
 588                   ## /usr/ucb/cc doesn't work;
 589                   ## we should find some other compiler that does work.
 590                   unset CC
 591                 fi
 592                 ;;
 593       *) ;;
 594     esac
 595   ;;
 596
 597   ## IA-64
 598   ia64*-*-linux* )
 599     machine=ia64 opsys=gnu-linux
 600   ;;
 601
 602   ## Intel 386 machines where we don't care about the manufacturer.
 603   i[3456]86-*-* )
 604     machine=intel386
 605     case "${canonical}" in
 606       *-cygwin )                opsys=cygwin ;;
 607       *-darwin* )               opsys=darwin
 608                                 CPP="${CC-cc} -E -no-cpp-precomp"
 609                                 ;;
 610       *-linux-gnu* )            opsys=gnu-linux ;;
 611       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 613       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 614       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 615     esac
 616   ;;
 617
 618   ## m68k Linux-based GNU system
 619   m68k-*-linux-gnu* )
 620     machine=m68k opsys=gnu-linux
 621   ;;
 622
 623   ## Mips Linux-based GNU system
 624   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 625     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 626     machine=mips opsys=gnu-linux
 627   ;;
 628
 629   ## AMD x86-64 Linux-based GNU system
 630   x86_64-*-linux-gnu* )
 631     machine=amdx86-64 opsys=gnu-linux
 632   ;;
 633
 634   ## Tensilica Xtensa Linux-based GNU system
 635   xtensa*-*-linux-gnu* )
 636     machine=xtensa opsys=gnu-linux
 637     ;;
 638
 639   ## SuperH Linux-based GNU system
 640   sh[34]*-*-linux-gnu* )
 641     machine=sh3 opsys=gnu-linux
 642   ;;
 643
 644   * )
 645     unported=yes
 646   ;;
 647 esac
 648
 649 ### If the code above didn't choose an operating system, just choose
 650 ### an operating system based on the configuration name.  You really
 651 ### only want to use this when you have no idea what the right
 652 ### operating system is; if you know what operating systems a machine
 653 ### runs, it's cleaner to make it explicit in the case statement
 654 ### above.
 655 if test x"${opsys}" = x; then
 656   case "${canonical}" in
 657     *-gnu* )                            opsys=gnu ;;
 658     * )
 659       unported=yes
 660     ;;
 661   esac
 662 fi
 663
 664 ]
 665 dnl quotation ends
 666
 667 if test $unported = yes; then
 668   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 669 Check `etc/MACHINES' for recognized configuration names.])
 670 fi
 671
 672 machfile="m/${machine}.h"
 673 opsysfile="s/${opsys}.h"
 674
 675
 676 #### Choose a compiler.
 677 test -n "$CC" && cc_specified=yes
 678
 679 # Save the value of CFLAGS that the user specified.
 680 SPECIFIED_CFLAGS="$CFLAGS"
 681
 682 dnl Sets GCC=yes if using gcc.
 683 AC_PROG_CC
 684
 685 # On Suns, sometimes $CPP names a directory.
 686 if test -n "$CPP" && test -d "$CPP"; then
 687   CPP=
 688 fi
 689
 690 ## If not using gcc, and on Solaris, and no CPP specified, see if
 691 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 692 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 693  test x"$CPP" = x; then
 694   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 695   AC_CACHE_VAL(emacs_cv_sunpro_c,
 696   [AC_TRY_LINK([],
 697 [#ifndef __SUNPRO_C
 698 fail;
 699 #endif
 700 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 701   AC_MSG_RESULT($emacs_cv_sunpro_c)
 702
 703   if test x"$emacs_cv_sunpro_c" = xyes; then
 704     NON_GNU_CPP="$CC -E -Xs"
 705   fi
 706 fi
 707
 708 #### Some systems specify a CPP to use unless we are using GCC.
 709 #### Now that we know whether we are using GCC, we can decide whether
 710 #### to use that one.
 711 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 712 then
 713   CPP="$NON_GNU_CPP"
 714 fi
 715
 716 #### Some systems specify a CC to use unless we are using GCC.
 717 #### Now that we know whether we are using GCC, we can decide whether
 718 #### to use that one.
 719 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 720   test x$cc_specified != xyes
 721 then
 722   CC="$NON_GNU_CC"
 723 fi
 724
 725 if test x$GCC = xyes; then
 726   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 727 else
 728   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl checks for Unix variants
 732 AC_USE_SYSTEM_EXTENSIONS
 733
 734 ### Use -Wno-pointer-sign if the compiler supports it
 735 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 736 SAVE_CFLAGS="$CFLAGS"
 737 CFLAGS="$CFLAGS -Wno-pointer-sign"
 738 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 739 if test $has_option = yes; then
 740    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 741 fi
 742 AC_MSG_RESULT($has_option)
 743 CFLAGS="$SAVE_CFLAGS"
 744 unset has_option
 745 unset SAVE_CFLAGS
 746
 747 ### Use -Wdeclaration-after-statement if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 ### Use -Wold-style-definition if the compiler supports it
 761 # This can be removed when conversion to standard C is finished.
 762 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 763 SAVE_CFLAGS="$CFLAGS"
 764 CFLAGS="$CFLAGS -Wold-style-definition"
 765 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 766 if test $has_option = yes; then
 767    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 768 fi
 769 AC_MSG_RESULT($has_option)
 770 CFLAGS="$SAVE_CFLAGS"
 771 unset has_option
 772 unset SAVE_CFLAGS
 773 AC_SUBST(C_WARNINGS_SWITCH)
 774
 775
 776 #### Some other nice autoconf tests.
 777
 778 dnl checks for programs
 779 AC_PROG_CPP
 780 AC_PROG_INSTALL
 781 if test "x$RANLIB" = x; then
 782   AC_PROG_RANLIB
 783 fi
 784
 785 ## Although we're running on an amd64 kernel, we're actually compiling for
 786 ## the x86 architecture.  The user should probably have provided an
 787 ## explicit --build to `configure', but if everything else than the kernel
 788 ## is running in i386 mode, we can help them out.
 789 if test "$machine" = "amdx86-64"; then
 790   AC_CHECK_DECL([i386])
 791   if test "$ac_cv_have_decl_i386" = "yes"; then
 792     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 793     machine=intel386
 794     machfile="m/${machine}.h"
 795   fi
 796 fi
 797
 798 AC_PATH_PROG(INSTALL_INFO, install-info)
 799 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 800 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 801 dnl Don't use GZIP, which is used by gzip for additional parameters.
 802 AC_PATH_PROG(GZIP_PROG, gzip)
 803
 804
 805 ## Need makeinfo >= 4.6 (?) to build the manuals.
 806 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 807 dnl By this stage, configure has already checked for egrep and set EGREP,
 808 dnl or exited with an error if no egrep was found.
 809 if test "$MAKEINFO" != "no" && \
 810   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 811    MAKEINFO=no
 812 fi
 813
 814 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 815 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 816 ## therefore in the category of "special tools" not normally required, which
 817 ## configure does not have to check for (eg autoconf itself).
 818 ## In a Bazaar checkout on the other hand, the manuals are not included.
 819 ## So makeinfo is a requirement to build from Bazaar, and configure
 820 ## should test for it as it does for any other build requirement.
 821 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 822 ## with pre-built manuals, from a Bazaar checkout.
 823 if test "$MAKEINFO" = "no"; then
 824   if test "x${with_makeinfo}" = "xno"; then
 825     MAKEINFO=off
 826   elif test ! -e $srcdir/info/emacs; then
 827     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 828 source tree does not seem to have pre-built manuals in the `info' directory.
 829 Either install a suitable version of makeinfo, or re-run configure
 830 with the `--without-makeinfo' option to build without the manuals.] )
 831   fi
 832 fi
 833
 834 dnl Add our options to ac_link now, after it is set up.
 835
 836 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 837 then
 838   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 839 fi
 840
 841 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 842 then
 843   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 844 fi
 845
 846 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 847 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 848 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 849 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 850 dnl if not built to support GNU ld.
 851
 852 late_LDFLAGS=$LDFLAGS
 853 if test "$GCC" = yes; then
 854   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 855 else
 856   LDFLAGS="$LDFLAGS -znocombreloc"
 857 fi
 858
 859 AC_MSG_CHECKING([for -znocombreloc])
 860 AC_LINK_IFELSE([main(){return 0;}],
 861   [AC_MSG_RESULT(yes)],
 862   LDFLAGS=$late_LDFLAGS
 863   [AC_MSG_RESULT(no)])
 864
 865
 866 # The value of CPP is a quoted variable reference, so we need to do this
 867 # to get its actual value...
 868 CPP=`eval "echo $CPP"`
 869
 870
 871 dnl Not used by any currently supported platform.
 872 dnl The function dump-emacs will not be defined and temacs will do
 873 dnl (load "loadup") automatically unless told otherwise.
 874 CANNOT_DUMP=no
 875 case "$opsys" in
 876   your-opsys-here)
 877    CANNOT_DUMP=yes
 878    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 879   ;;
 880 esac
 881 AC_SUBST(CANNOT_DUMP)
 882
 883
 884 UNEXEC_OBJ=unexelf.o
 885 case "$opsys" in
 886   # MSDOS uses unexcoff.o
 887   # MSWindows uses unexw32.o
 888   aix4-2)
 889    UNEXEC_OBJ=unexaix.o
 890    ;;
 891   cygwin)
 892    UNEXEC_OBJ=unexcw.o
 893    ;;
 894   darwin)
 895    UNEXEC_OBJ=unexmacosx.o
 896    ;;
 897   hpux10-20 | hpux11)
 898    UNEXEC_OBJ=unexhp9k800.o
 899    ;;
 900   sol2-10)
 901    # Use the Solaris dldump() function, called from unexsol.c, to dump
 902    # emacs, instead of the generic ELF dump code found in unexelf.c.
 903    # The resulting binary has a complete symbol table, and is better
 904    # for debugging and other observability tools (debuggers, pstack, etc).
 905    #
 906    # If you encounter a problem using dldump(), please consider sending
 907    # a message to the OpenSolaris tools-linking mailing list:
 908    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 909    #
 910    # It is likely that dldump() works with older Solaris too, but this has
 911    # not been tested, so for now this change is for Solaris 10 or newer.
 912    UNEXEC_OBJ=unexsol.o
 913    ;;
 914 esac
 915
 916 LD_SWITCH_SYSTEM=
 917 case "$opsys" in
 918   freebsd)
 919    ## Let `ld' find image libs and similar things in /usr/local/lib.
 920    ## The system compiler, GCC, has apparently been modified to not
 921    ## look there, contrary to what a stock GCC would do.
 922    LD_SWITCH_SYSTEM=-L/usr/local/lib
 923    ;;
 924
 925   gnu-linux)
 926    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 927    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 928    ;;
 929
 930   netbsd)
 931    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 932    ;;
 933
 934   openbsd)
 935    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 936    ## otherwise Emacs dumps core on elf systems.
 937    LD_SWITCH_SYSTEM="-Z"
 938    ;;
 939 esac
 940 AC_SUBST(LD_SWITCH_SYSTEM)
 941
 942 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 943
 944 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 945 ## which has not been defined yet.  When this was handled with cpp,
 946 ## it was expanded to null when configure sourced the s/*.h file.
 947 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 948 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 949 ## (or somesuch), but because it is supposed to go at the _front_
 950 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 951 ## Compare with the gnu-linux case below, which added to the end
 952 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 953 ## LD_SWITCH_SYSTEM_TEMACS.
 954 case "$opsys" in
 955   netbsd|openbsd)
 956    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 957    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 958 esac
 959
 960
 961 C_SWITCH_MACHINE=
 962 if test "$machine" = "alpha"; then
 963   AC_CHECK_DECL([__ELF__])
 964   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 965     ## With ELF, make sure that all common symbols get allocated to in the
 966     ## data section.  Otherwise, the dump of temacs may miss variables in
 967     ## the shared library that have been initialized.  For example, with
 968     ## GNU libc, __malloc_initialized would normally be resolved to the
 969     ## shared library's .bss section, which is fatal.
 970     if test "x$GCC" = "xyes"; then
 971       C_SWITCH_MACHINE="-fno-common"
 972     else
 973       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 974     fi
 975   else
 976     UNEXEC_OBJ=unexalpha.o
 977   fi
 978 fi
 979 AC_SUBST(C_SWITCH_MACHINE)
 980
 981 AC_SUBST(UNEXEC_OBJ)
 982
 983 C_SWITCH_SYSTEM=
 984 ## Some programs in src produce warnings saying certain subprograms
 985 ## are too complex and need a MAXMEM value greater than 2000 for
 986 ## additional optimization.  --nils@exp-math.uni-essen.de
 987 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 988   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 989 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 990 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 991 AC_SUBST(C_SWITCH_SYSTEM)
 992
 993
 994 LIBS_SYSTEM=
 995 case "$opsys" in
 996   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 997   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 998
 999   freebsd) LIBS_SYSTEM="-lutil" ;;
1000
1001   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1002
1003   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1004
1005   ## Motif needs -lgen.
1006   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1007 esac
1008 AC_SUBST(LIBS_SYSTEM)
1009
1010
1011 ### Make sure subsequent tests use flags consistent with the build flags.
1012
1013 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1014   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1015 else
1016   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1017 fi
1018
1019 dnl For AC_FUNC_GETLOADAVG, at least:
1020 AC_CONFIG_LIBOBJ_DIR(src)
1021
1022 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1023 AC_SYS_LARGEFILE
1024
1025
1026 ## If user specified a crt-dir, use that unconditionally.
1027 if test "X$CRT_DIR" = "X"; then
1028
1029   case "$canonical" in
1030     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1031     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1032     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1033     ## For anything else (eg /usr/lib32), it is up the user to specify
1034     ## the location (bug#5655).
1035     ## Test for crtn.o, not just the directory, because sometimes the
1036     ## directory exists but does not have the relevant files (bug#1287).
1037     ## FIXME better to test for binary compatibility somehow.
1038     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1039     ;;
1040
1041     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1042   esac
1043
1044   case "$opsys" in
1045     hpux10-20) CRT_DIR=/lib ;;
1046   esac
1047
1048   ## Default is /usr/lib.
1049   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1050
1051 else
1052
1053   ## Some platforms don't use any of these files, so it is not
1054   ## appropriate to put this test outside the if block.
1055   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1056     AC_MSG_ERROR([crt*.o not found in specified location.])
1057
1058 fi
1059
1060 AC_SUBST(CRT_DIR)
1061
1062 LIB_MATH=-lm
1063 LIB_STANDARD=
1064 START_FILES=
1065
1066 case $opsys in
1067   cygwin )
1068     LIB_MATH=
1069     START_FILES='pre-crt0.o'
1070     ;;
1071   darwin )
1072     ## Adding -lm confuses the dynamic linker, so omit it.
1073     LIB_MATH=
1074     START_FILES='pre-crt0.o'
1075     ;;
1076   freebsd )
1077     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1078     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1079     ;;
1080   gnu-linux | gnu-kfreebsd )
1081     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1082     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1083     ;;
1084   hpux10-20 | hpux11 )
1085     LIB_STANDARD=-lc
1086     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1087     ;;
1088   netbsd | openbsd )
1089     if test -f $CRT_DIR/crti.o; then
1090         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1091         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1092     else
1093         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1094         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1095     fi
1096     ;;
1097 esac
1098
1099 AC_SUBST(LIB_MATH)
1100 AC_SUBST(START_FILES)
1101
1102 dnl This function definition taken from Gnome 2.0
1103 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1104 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1105 dnl also defines GSTUFF_PKG_ERRORS on error
1106 AC_DEFUN([PKG_CHECK_MODULES], [
1107   succeeded=no
1108
1109   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1110
1111   if test "$PKG_CONFIG" = "no" ; then
1112      ifelse([$4], , [AC_MSG_ERROR([
1113       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1114   else
1115      PKG_CONFIG_MIN_VERSION=0.9.0
1116      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1117         AC_MSG_CHECKING(for $2)
1118
1119         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1120             AC_MSG_RESULT(yes)
1121             succeeded=yes
1122
1123             AC_MSG_CHECKING($1_CFLAGS)
1124             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1125             AC_MSG_RESULT($$1_CFLAGS)
1126
1127             AC_MSG_CHECKING($1_LIBS)
1128             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1129             AC_MSG_RESULT($$1_LIBS)
1130         else
1131             AC_MSG_RESULT(no)
1132             $1_CFLAGS=""
1133             $1_LIBS=""
1134             ## If we have a custom action on failure, don't print errors, but
1135             ## do set a variable so people can do so.
1136             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1137             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1138         fi
1139
1140         AC_SUBST($1_CFLAGS)
1141         AC_SUBST($1_LIBS)
1142      else
1143         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1144         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1145      fi
1146   fi
1147
1148   if test $succeeded = yes; then
1149      ifelse([$3], , :, [$3])
1150   else
1151      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1152   fi
1153 ])
1154
1155
1156 if test "${with_sound}" != "no"; then
1157   # Sound support for GNU/Linux and the free BSDs.
1158   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1159     have_sound_header=yes)
1160   # Emulation library used on NetBSD.
1161   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1162   AC_SUBST(LIBSOUND)
1163
1164   ALSA_REQUIRED=1.0.0
1165   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1166   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1167   if test $HAVE_ALSA = yes; then
1168     SAVE_CFLAGS="$CFLAGS"
1169     SAVE_LDFLAGS="$LDFLAGS"
1170     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1171     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1172     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1173                     emacs_alsa_normal=yes,
1174                     emacs_alsa_normal=no)
1175     if test "$emacs_alsa_normal" != yes; then
1176       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1177                      [snd_lib_error_set_handler (0);],
1178                      emacs_alsa_subdir=yes,
1179                      emacs_alsa_subdir=no)
1180       if test "$emacs_alsa_subdir" != yes; then
1181         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1182       fi
1183       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1184     fi
1185
1186     CFLAGS="$SAVE_CFLAGS"
1187     LDFLAGS="$SAVE_LDFLAGS"
1188     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1189     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1190     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1191   fi
1192
1193   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1194   dnl compiles only on the specified platforms.  For others, it
1195   dnl probably doesn't make sense to try.
1196   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1197      case "$opsys" in
1198        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1199        gnu-linux|freebsd|netbsd)
1200          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1201          ;;
1202      esac
1203   fi
1204
1205   AC_SUBST(CFLAGS_SOUND)
1206 fi
1207
1208 dnl checks for header files
1209 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1210   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1211   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1212   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1213   sys/utsname.h pwd.h utmp.h dirent.h)
1214
1215 AC_MSG_CHECKING(if personality LINUX32 can be set)
1216 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1217                emacs_cv_personality_linux32=yes,
1218                emacs_cv_personality_linux32=no)
1219 AC_MSG_RESULT($emacs_cv_personality_linux32)
1220
1221 if test $emacs_cv_personality_linux32 = yes; then
1222   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1223             [Define to 1 if personality LINUX32 can be set.])
1224 fi
1225
1226 dnl On Solaris 8 there's a compilation warning for term.h because
1227 dnl it doesn't define `bool'.
1228 AC_CHECK_HEADERS(term.h, , , -)
1229 AC_HEADER_STDC
1230 AC_HEADER_TIME
1231 AC_CHECK_DECLS([sys_siglist])
1232 if test $ac_cv_have_decl_sys_siglist != yes; then
1233   # For Tru64, at least:
1234   AC_CHECK_DECLS([__sys_siglist])
1235   if test $ac_cv_have_decl___sys_siglist = yes; then
1236     AC_DEFINE(sys_siglist, __sys_siglist,
1237               [Define to any substitute for sys_siglist.])
1238   fi
1239 fi
1240 AC_HEADER_SYS_WAIT
1241
1242 dnl Some systems have utime.h but don't declare the struct anyplace.
1243 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1244 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1245 #include <sys/time.h>
1246 #include <time.h>
1247 #else
1248 #ifdef HAVE_SYS_TIME_H
1249 #include <sys/time.h>
1250 #else
1251 #include <time.h>
1252 #endif
1253 #endif
1254 #ifdef HAVE_UTIME_H
1255 #include <utime.h>
1256 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1257   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1258 if test $emacs_cv_struct_utimbuf = yes; then
1259   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1260 fi
1261
1262 dnl checks for typedefs
1263 AC_TYPE_SIGNAL
1264
1265 dnl Check for speed_t typedef.
1266 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1267   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1268     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1269 if test $emacs_cv_speed_t = yes; then
1270   AC_DEFINE(HAVE_SPEED_T, 1,
1271            [Define to 1 if `speed_t' is declared by <termios.h>.])
1272 fi
1273
1274 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1275 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1276 #include <sys/time.h>
1277 #include <time.h>
1278 #else
1279 #ifdef HAVE_SYS_TIME_H
1280 #include <sys/time.h>
1281 #else
1282 #include <time.h>
1283 #endif
1284 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1285   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1286 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1287 if test $emacs_cv_struct_timeval = yes; then
1288   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1289 fi
1290
1291 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1292 AC_TRY_COMPILE([#include <math.h>],
1293 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1294   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1295 HAVE_EXCEPTION=$emacs_cv_struct_exception
1296 if test $emacs_cv_struct_exception != yes; then
1297   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1298 fi
1299
1300 AC_CHECK_HEADERS(sys/socket.h)
1301 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1302 #if HAVE_SYS_SOCKET_H
1303 #include <sys/socket.h>
1304 #endif])
1305
1306 dnl checks for structure members
1307 AC_STRUCT_TM
1308 AC_STRUCT_TIMEZONE
1309 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1310                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1311                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1312                 [#include <time.h>])
1313 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1314                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1315                   struct ifreq.ifr_addr], , ,
1316                  [AC_INCLUDES_DEFAULT
1317 #if HAVE_SYS_SOCKET_H
1318 #include <sys/socket.h>
1319 #endif
1320 #if HAVE_NET_IF_H
1321 #include <net/if.h>
1322 #endif])
1323
1324 dnl checks for compiler characteristics
1325
1326 dnl Testing __STDC__ to determine prototype support isn't good enough.
1327 dnl DEC C, for instance, doesn't define it with default options, and
1328 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1329 dnl and void *.
1330 AC_C_PROTOTYPES
1331 AC_C_VOLATILE
1332 AC_C_CONST
1333 dnl This isn't useful because we can't turn on use of `inline' unless
1334 dnl the compiler groks `extern inline'.
1335 dnl AC_C_INLINE
1336 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1337   [AC_TRY_COMPILE(, [void * foo;],
1338                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1339 if test $emacs_cv_void_star = yes; then
1340   AC_DEFINE(POINTER_TYPE, void)
1341 else
1342   AC_DEFINE(POINTER_TYPE, char)
1343 fi
1344 AH_TEMPLATE(POINTER_TYPE,
1345             [Define as `void' if your compiler accepts `void *'; otherwise
1346              define as `char'.])dnl
1347
1348
1349
1350 dnl This could be used for targets which can have both byte sexes.
1351 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1352 dnl AC_C_BIGENDIAN
1353
1354 dnl check for Make feature
1355 AC_PROG_MAKE_SET
1356
1357 DEPFLAGS=
1358 MKDEPDIR=":"
1359 deps_frag=deps.mk
1360 dnl check for GNU Make if we have GCC and autodepend is on.
1361 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1362    AC_MSG_CHECKING([whether we are using GNU Make])
1363    HAVE_GNU_MAKE=no
1364    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1365    if test "x$testval" != x; then
1366       HAVE_GNU_MAKE=yes
1367    else
1368       ac_enable_autodepend=no
1369    fi
1370    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1371    if test $HAVE_GNU_MAKE = yes; then
1372       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1373       SAVE_CFLAGS="$CFLAGS"
1374       CFLAGS="$CFLAGS -MMD -MF deps.d"
1375       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1376       CFLAGS="$SAVE_CFLAGS"
1377       test -f deps.d || ac_enable_autodepend=no
1378       rm -rf deps.d
1379       AC_MSG_RESULT([$ac_enable_autodepend])
1380    fi
1381    if test $ac_enable_autodepend = yes; then
1382       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1383       ## In parallel builds, another make might create depdir between
1384       ## the first test and mkdir, so stick another test on the end.
1385       ## Or use mkinstalldirs?  mkdir -p is not portable.
1386       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1387       deps_frag=autodeps.mk
1388    fi
1389 fi
1390 deps_frag=$srcdir/src/$deps_frag
1391 AC_SUBST(MKDEPDIR)
1392 AC_SUBST(DEPFLAGS)
1393 AC_SUBST_FILE(deps_frag)
1394
1395
1396 dnl checks for operating system services
1397 AC_SYS_LONG_FILE_NAMES
1398
1399 #### Choose a window system.
1400
1401 AC_PATH_X
1402 if test "$no_x" = yes; then
1403   window_system=none
1404 else
1405   window_system=x11
1406 fi
1407
1408 ## Workaround for bug in autoconf <= 2.62.
1409 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1410 ## No need to do anything special for these standard directories.
1411 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1412
1413    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1414
1415 fi
1416
1417 LD_SWITCH_X_SITE_AUX=
1418 LD_SWITCH_X_SITE_AUX_RPATH=
1419 if test "${x_libraries}" != NONE; then
1420   if test -n "${x_libraries}"; then
1421     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1422     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1423     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1424   fi
1425   x_default_search_path=""
1426   x_search_path=${x_libraries}
1427   if test -z "${x_search_path}"; then
1428     x_search_path=/usr/lib
1429   fi
1430   for x_library in `echo ${x_search_path}: | \
1431                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1432     x_search_path="\
1433 ${x_library}/X11/%L/%T/%N%C%S:\
1434 ${x_library}/X11/%l/%T/%N%C%S:\
1435 ${x_library}/X11/%T/%N%C%S:\
1436 ${x_library}/X11/%L/%T/%N%S:\
1437 ${x_library}/X11/%l/%T/%N%S:\
1438 ${x_library}/X11/%T/%N%S"
1439     if test x"${x_default_search_path}" = x; then
1440       x_default_search_path=${x_search_path}
1441     else
1442       x_default_search_path="${x_search_path}:${x_default_search_path}"
1443     fi
1444   done
1445 fi
1446 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1447 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1448
1449 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1450   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1451 fi
1452
1453 if test x"${x_includes}" = x; then
1454   bitmapdir=/usr/include/X11/bitmaps
1455 else
1456   # accumulate include directories that have X11 bitmap subdirectories
1457   bmd_acc="dummyval"
1458   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1459     if test -d "${bmd}/X11/bitmaps"; then
1460       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1461     fi
1462     if test -d "${bmd}/bitmaps"; then
1463       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1464     fi
1465   done
1466   if test ${bmd_acc} != "dummyval"; then
1467     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1468   fi
1469 fi
1470
1471 HAVE_NS=no
1472 NS_IMPL_COCOA=no
1473 NS_IMPL_GNUSTEP=no
1474 tmp_CPPFLAGS="$CPPFLAGS"
1475 tmp_CFLAGS="$CFLAGS"
1476 CPPFLAGS="$CPPFLAGS -x objective-c"
1477 CFLAGS="$CFLAGS -x objective-c"
1478 TEMACS_LDFLAGS2="\${LDFLAGS} \${PROFILING_LDFLAGS}"
1479 dnl I don't think it's especially important, but src/Makefile.in
1480 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1481 dnl trailing "/" to it, so now we do it here.
1482 if test "${with_ns}" != no; then
1483   if test "${opsys}" = darwin; then
1484      NS_IMPL_COCOA=yes
1485      ns_appdir=`pwd`/nextstep/Emacs.app/
1486      ns_appbindir=${ns_appdir}Contents/MacOS/
1487      ns_appresdir=${ns_appdir}Contents/Resources
1488      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1489   elif test -f $GNUSTEP_CONFIG_FILE; then
1490      NS_IMPL_GNUSTEP=yes
1491      ns_appdir=`pwd`/nextstep/Emacs.app/
1492      ns_appbindir=${ns_appdir}
1493      ns_appresdir=${ns_appdir}Resources
1494      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1495      dnl FIXME sourcing this several times in subshells seems inefficient.
1496      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1497      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1498      dnl I seemed to need these as well with GNUstep-startup 0.25.
1499      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1500      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1501      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1502        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1503      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1504        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1505      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1506      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1507      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1508      LIB_STANDARD=
1509      START_FILES=
1510      TEMACS_LDFLAGS2=
1511   fi
1512   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1513                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1514   files are missing or cannot be compiled.])])
1515   NS_HAVE_NSINTEGER=yes
1516   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1517                                      [NSInteger i;])],
1518                     ns_have_nsinteger=yes,
1519                     ns_have_nsinteger=no)
1520   if test $ns_have_nsinteger = no; then
1521     NS_HAVE_NSINTEGER=no
1522   fi
1523 fi
1524 AC_SUBST(TEMACS_LDFLAGS2)
1525
1526 ns_frag=/dev/null
1527 NS_OBJ=
1528 NS_SUPPORT=
1529 if test "${HAVE_NS}" = yes; then
1530   window_system=nextstep
1531   with_xft=no
1532   # set up packaging dirs
1533   exec_prefix=${ns_appbindir}
1534   libexecdir=${ns_appbindir}/libexec
1535   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1536      prefix=${ns_appresdir}
1537   fi
1538   ns_frag=$srcdir/src/ns.mk
1539   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1540   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1541 fi
1542 CFLAGS="$tmp_CFLAGS"
1543 CPPFLAGS="$tmp_CPPFLAGS"
1544 AC_SUBST(NS_OBJ)
1545 AC_SUBST(NS_SUPPORT)
1546 AC_SUBST(LIB_STANDARD)
1547 AC_SUBST_FILE(ns_frag)
1548
1549 case "${window_system}" in
1550   x11 )
1551     HAVE_X_WINDOWS=yes
1552     HAVE_X11=yes
1553     case "${with_x_toolkit}" in
1554       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1555       motif ) USE_X_TOOLKIT=MOTIF ;;
1556       gtk ) with_gtk=yes
1557 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1558 dnl USE_X_TOOLKIT is set.
1559             USE_X_TOOLKIT=none ;;
1560       gtk3 ) with_gtk3=yes
1561              USE_X_TOOLKIT=none ;;
1562       no ) USE_X_TOOLKIT=none ;;
1563 dnl If user did not say whether to use a toolkit, make this decision later:
1564 dnl use the toolkit if we have gtk, or X11R5 or newer.
1565       * ) USE_X_TOOLKIT=maybe ;;
1566     esac
1567   ;;
1568   nextstep | none )
1569     HAVE_X_WINDOWS=no
1570     HAVE_X11=no
1571     USE_X_TOOLKIT=none
1572   ;;
1573 esac
1574
1575 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1576    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1577    if test "$HAVE_XSERVER" = true ||
1578       test -n "$DISPLAY" ||
1579       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1580         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1581 were found.  You should install the relevant development files for X
1582 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1583 sure you have development files for image handling, i.e.
1584 tiff, gif, jpeg, png and xpm.
1585 If you are sure you want Emacs compiled without X window support, pass
1586   --without-x
1587 to configure.])
1588    fi
1589 fi
1590
1591 ### If we're using X11, we should use the X menu package.
1592 HAVE_MENUS=no
1593 case ${HAVE_X11} in
1594   yes ) HAVE_MENUS=yes ;;
1595 esac
1596
1597 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1598 # Assume not, until told otherwise.
1599 GNU_MALLOC=yes
1600 doug_lea_malloc=yes
1601 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1602 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1603 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1604                emacs_cv_var___after_morecore_hook,
1605 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1606   emacs_cv_var___after_morecore_hook=yes,
1607   emacs_cv_var___after_morecore_hook=no)])
1608 if test $emacs_cv_var___after_morecore_hook = no; then
1609   doug_lea_malloc=no
1610 fi
1611
1612
1613 dnl See comments in aix4-2.h about maybe using system malloc there.
1614 system_malloc=no
1615 case "$opsys" in
1616   ## darwin ld insists on the use of malloc routines in the System framework.
1617   darwin|sol2-10) system_malloc=yes ;;
1618 esac
1619
1620 if test "${system_malloc}" = "yes"; then
1621   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1622   GNU_MALLOC=no
1623   GNU_MALLOC_reason="
1624     (The GNU allocators don't work with this system configuration.)"
1625   GMALLOC_OBJ=
1626   VMLIMIT_OBJ=
1627 else
1628   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1629   VMLIMIT_OBJ=vm-limit.o
1630 fi
1631 AC_SUBST(GMALLOC_OBJ)
1632 AC_SUBST(VMLIMIT_OBJ)
1633
1634 if test "$doug_lea_malloc" = "yes" ; then
1635   if test "$GNU_MALLOC" = yes ; then
1636     GNU_MALLOC_reason="
1637       (Using Doug Lea's new malloc from the GNU C Library.)"
1638   fi
1639   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1640             [Define to 1 if you are using the GNU C Library.])
1641
1642   ## Use mmap directly for allocating larger buffers.
1643   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1644   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1645   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1646   case "$opsys" in
1647     gnu*) REL_ALLOC=no ;;
1648   esac
1649 fi
1650
1651 if test x"${REL_ALLOC}" = x; then
1652   REL_ALLOC=${GNU_MALLOC}
1653 fi
1654
1655 use_mmap_for_buffers=no
1656 case "$opsys" in
1657   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1658 esac
1659
1660 AC_FUNC_MMAP
1661 if test $use_mmap_for_buffers = yes; then
1662   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1663   REL_ALLOC=no
1664 fi
1665
1666 LIBS="$LIBS_SYSTEM $LIBS"
1667
1668 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1669 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1670 AC_CHECK_LIB(dnet, dnet_ntoa)
1671 dnl This causes -lresolv to get used in subsequent tests,
1672 dnl which causes failures on some systems such as HPUX 9.
1673 dnl AC_CHECK_LIB(resolv, gethostbyname)
1674
1675 dnl FIXME replace main with a function we actually want from this library.
1676 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1677
1678 AC_CHECK_LIB(pthreads, cma_open)
1679
1680 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1681 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1682 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1683 ## added to LIBS in configure would never contain the pthreads part,
1684 ## but the value used in Makefiles might.  FIXME?
1685 ##
1686 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1687 ## be harmless on older versions of X where it happens to exist.
1688 test "$opsys" = "aix4-2" && \
1689   test $ac_cv_lib_pthreads_cma_open = yes && \
1690   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1691
1692 dnl Check for need for bigtoc support on IBM AIX
1693
1694 case ${host_os} in
1695 aix*)
1696   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1697     case $GCC in
1698     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1699     *) gdb_cv_bigtoc=-bbigtoc ;;
1700     esac
1701
1702     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1703     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1704   ])
1705   ;;
1706 esac
1707
1708 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1709 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1710 # REAL_CPPFLAGS later on.
1711
1712 REAL_CFLAGS="$CFLAGS"
1713 REAL_CPPFLAGS="$CPPFLAGS"
1714
1715 if test "${HAVE_X11}" = "yes"; then
1716   DEFS="$C_SWITCH_X_SITE $DEFS"
1717   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1718   LIBS="-lX11 $LIBS"
1719   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1720   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1721
1722   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1723   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1724   # but it's more convenient here to set LD_RUN_PATH
1725   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1726   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1727     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1728     export LD_RUN_PATH
1729   fi
1730
1731   if test "${opsys}" = "gnu-linux"; then
1732     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1733     AC_TRY_LINK([],
1734      [XOpenDisplay ("foo");],
1735      [xlinux_first_failure=no],
1736      [xlinux_first_failure=yes])
1737     if test "${xlinux_first_failure}" = "yes"; then
1738       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1739       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1740       OLD_CPPFLAGS="$CPPFLAGS"
1741       OLD_LIBS="$LIBS"
1742       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1743       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1744       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1745       LIBS="$LIBS -b i486-linuxaout"
1746       AC_TRY_LINK([],
1747        [XOpenDisplay ("foo");],
1748        [xlinux_second_failure=no],
1749        [xlinux_second_failure=yes])
1750       if test "${xlinux_second_failure}" = "yes"; then
1751         # If we get the same failure with -b, there is no use adding -b.
1752         # So take it out.  This plays safe.
1753         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1754         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1755         CPPFLAGS="$OLD_CPPFLAGS"
1756         LIBS="$OLD_LIBS"
1757         AC_MSG_RESULT(no)
1758       else
1759         AC_MSG_RESULT(yes)
1760       fi
1761     else
1762       AC_MSG_RESULT(no)
1763     fi
1764   fi
1765
1766   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1767   # header files included from there.
1768   AC_MSG_CHECKING(for Xkb)
1769   AC_TRY_LINK([#include <X11/Xlib.h>
1770 #include <X11/XKBlib.h>],
1771         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1772         emacs_xkb=yes, emacs_xkb=no)
1773   AC_MSG_RESULT($emacs_xkb)
1774   if test $emacs_xkb = yes; then
1775     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1776   fi
1777
1778   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1779 XScreenNumberOfScreen XSetWMProtocols)
1780 fi
1781
1782 if test "${window_system}" = "x11"; then
1783   AC_MSG_CHECKING(X11 version 6)
1784   AC_CACHE_VAL(emacs_cv_x11_version_6,
1785   [AC_TRY_LINK([#include <X11/Xlib.h>],
1786 [#if XlibSpecificationRelease < 6
1787 fail;
1788 #endif
1789 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1790   if test $emacs_cv_x11_version_6 = yes; then
1791     AC_MSG_RESULT(6 or newer)
1792     AC_DEFINE(HAVE_X11R6, 1,
1793               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1794     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1795     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1796     ## XIM support.
1797     case "$opsys" in
1798       sol2-*) : ;;
1799       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1800            [Define if you have usable X11R6-style XIM support.])
1801          ;;
1802     esac
1803   else
1804     AC_MSG_RESULT(before 6)
1805   fi
1806 fi
1807
1808
1809 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1810 HAVE_RSVG=no
1811 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1812   if test "${with_rsvg}" != "no"; then
1813     RSVG_REQUIRED=2.11.0
1814     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1815
1816     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1817     AC_SUBST(RSVG_CFLAGS)
1818     AC_SUBST(RSVG_LIBS)
1819
1820     if test ".${RSVG_CFLAGS}" != "."; then
1821       HAVE_RSVG=yes
1822       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1823       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1824       LIBS="$RSVG_LIBS $LIBS"
1825     fi
1826   fi
1827 fi
1828
1829
1830 HAVE_GTK=no
1831 if test "${with_gtk3}" = "yes"; then
1832   GLIB_REQUIRED=2.6
1833   GTK_REQUIRED=2.90
1834   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1835
1836   dnl Checks for libraries.
1837   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1838   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1839      AC_MSG_ERROR($GTK_PKG_ERRORS)
1840   fi
1841 fi
1842
1843 if test "$pkg_check_gtk" != "yes"; then
1844   HAVE_GTK=no
1845 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1846   GLIB_REQUIRED=2.6
1847   GTK_REQUIRED=2.6
1848   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1849
1850   dnl Checks for libraries.
1851   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1852   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1853      AC_MSG_ERROR($GTK_PKG_ERRORS)
1854   fi
1855 fi
1856 fi
1857
1858 GTK_OBJ=
1859 if test x"$pkg_check_gtk" = xyes; then
1860
1861   AC_SUBST(GTK_CFLAGS)
1862   AC_SUBST(GTK_LIBS)
1863   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1864   CFLAGS="$CFLAGS $GTK_CFLAGS"
1865   LIBS="$GTK_LIBS $LIBS"
1866   dnl Try to compile a simple GTK program.
1867   GTK_COMPILES=no
1868   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1869   if test "${GTK_COMPILES}" != "yes"; then
1870     if test "$USE_X_TOOLKIT" != "maybe"; then
1871       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1872     fi
1873   else
1874     HAVE_GTK=yes
1875     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1876     GTK_OBJ=gtkutil.o
1877     USE_X_TOOLKIT=none
1878     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1879       :
1880     else
1881       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1882        closing open displays.  This is no problem if you just use
1883        one display, but if you use more than one and close one of them
1884        Emacs may crash.]])
1885       sleep 3
1886     fi
1887   fi
1888
1889 fi
1890 AC_SUBST(GTK_OBJ)
1891
1892
1893 if test "${HAVE_GTK}" = "yes"; then
1894
1895   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1896   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1897   if test "$with_toolkit_scroll_bars" != no; then
1898     with_toolkit_scroll_bars=yes
1899   fi
1900
1901   dnl  Check if we have the old file selection dialog declared and
1902   dnl  in the link library.  In 2.x it may be in the library,
1903   dnl  but not declared if deprecated featured has been selected out.
1904   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1905   HAVE_GTK_FILE_SELECTION=no
1906   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1907                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1908 #include <gtk/gtk.h>])
1909   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1910     AC_CHECK_FUNCS(gtk_file_selection_new)
1911   fi
1912
1913   dnl Check if pthreads are available.  Emacs only needs this when using
1914   dnl gtk_file_chooser under Gnome.
1915     HAVE_GTK_AND_PTHREAD=no
1916     AC_CHECK_HEADERS(pthread.h)
1917     if test "$ac_cv_header_pthread_h"; then
1918       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1919     fi
1920     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1921       case "${canonical}" in
1922         *-hpux*) ;;
1923         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1924       esac
1925       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1926                [Define to 1 if you have GTK and pthread (-lpthread).])
1927     fi
1928
1929   dnl Check for functions introduced in 2.14 and later.
1930   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1931                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1932                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1933                  gtk_orientable_set_orientation)
1934
1935 fi
1936
1937 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1938 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1939 dnl also not configured.
1940 HAVE_DBUS=no
1941 DBUS_OBJ=
1942 if test "${with_dbus}" = "yes"; then
1943    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1944    if test "$HAVE_DBUS" = yes; then
1945      LIBS="$LIBS $DBUS_LIBS"
1946      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1947      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1948      DBUS_OBJ=dbusbind.o
1949    fi
1950 fi
1951 AC_SUBST(DBUS_OBJ)
1952
1953 dnl GConf has been tested under GNU/Linux only.
1954 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1955 HAVE_GCONF=no
1956 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1957    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1958    if test "$HAVE_GCONF" = yes; then
1959       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1960    fi
1961 fi
1962
1963 dnl SELinux is available for GNU/Linux only.
1964 HAVE_LIBSELINUX=no
1965 LIBSELINUX_LIBS=
1966 if test "${with_selinux}" = "yes"; then
1967    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1968    if test "$HAVE_LIBSELINUX" = yes; then
1969       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1970       LIBSELINUX_LIBS=-lselinux
1971    fi
1972 fi
1973 AC_SUBST(LIBSELINUX_LIBS)
1974
1975 dnl Do not put whitespace before the #include statements below.
1976 dnl Older compilers (eg sunos4 cc) choke on it.
1977 HAVE_XAW3D=no
1978 LUCID_LIBW=
1979 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1980   if test "$with_xaw3d" != no; then
1981     AC_MSG_CHECKING(for xaw3d)
1982     AC_CACHE_VAL(emacs_cv_xaw3d,
1983     [AC_TRY_LINK([
1984 #include <X11/Intrinsic.h>
1985 #include <X11/Xaw3d/Simple.h>],
1986       [],
1987       emacs_cv_xaw3d=yes,
1988       emacs_cv_xaw3d=no)])
1989   else
1990     emacs_cv_xaw3d=no
1991   fi
1992   if test $emacs_cv_xaw3d = yes; then
1993     AC_MSG_RESULT([yes; using Lucid toolkit])
1994     USE_X_TOOLKIT=LUCID
1995     HAVE_XAW3D=yes
1996     LUCID_LIBW=-lXaw3d
1997     AC_DEFINE(HAVE_XAW3D, 1,
1998               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1999   else
2000     AC_MSG_RESULT(no)
2001     AC_MSG_CHECKING(for libXaw)
2002     AC_CACHE_VAL(emacs_cv_xaw,
2003     [AC_TRY_LINK([
2004 #include <X11/Intrinsic.h>
2005 #include <X11/Xaw/Simple.h>],
2006       [],
2007       emacs_cv_xaw=yes,
2008       emacs_cv_xaw=no)])
2009     if test $emacs_cv_xaw = yes; then
2010       AC_MSG_RESULT([yes; using Lucid toolkit])
2011       USE_X_TOOLKIT=LUCID
2012       LUCID_LIBW=-lXaw
2013     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2014       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2015     else
2016       AC_MSG_RESULT([no; do not use toolkit by default])
2017       USE_X_TOOLKIT=none
2018     fi
2019   fi
2020 fi
2021
2022 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2023
2024 LIBXTR6=
2025 if test "${USE_X_TOOLKIT}" != "none"; then
2026   AC_MSG_CHECKING(X11 toolkit version)
2027   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2028   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2029 [#if XtSpecificationRelease < 6
2030 fail;
2031 #endif
2032 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2033   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2034   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2035     AC_MSG_RESULT(6 or newer)
2036     AC_DEFINE(HAVE_X11XTR6, 1,
2037               [Define to 1 if you have the X11R6 or newer version of Xt.])
2038     LIBXTR6="-lSM -lICE"
2039     case "$opsys" in
2040       ## Use libw.a along with X11R6 Xt.
2041       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2042     esac
2043   else
2044     AC_MSG_RESULT(before 6)
2045   fi
2046
2047 dnl If using toolkit, check whether libXmu.a exists.
2048 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2049   OLDLIBS="$LIBS"
2050   if test x$HAVE_X11XTR6 = xyes; then
2051     LIBS="-lXt -lSM -lICE $LIBS"
2052   else
2053     LIBS="-lXt $LIBS"
2054   fi
2055   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2056   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2057 fi
2058 AC_SUBST(LIBXTR6)
2059
2060 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2061 dnl Why not just test for libxmu in the normal way?
2062 LIBXMU=-lXmu
2063 case "$machine" in
2064   ## These machines don't supply Xmu.
2065   hpux* | aix4-2 )
2066     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2067     ;;
2068 esac
2069 AC_SUBST(LIBXMU)
2070
2071 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2072 if test "${HAVE_X11}" = "yes"; then
2073   if test "${USE_X_TOOLKIT}" != "none"; then
2074     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2075   fi
2076 fi
2077
2078 LIBXP=
2079 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2080   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2081   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2082     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2083 int x = 5;
2084 #else
2085 Motif version prior to 2.1.
2086 #endif],
2087     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2088   if test $emacs_cv_motif_version_2_1 = yes; then
2089     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2090   else
2091     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2092     # We put this in CFLAGS temporarily to precede other -I options
2093     # that might be in CFLAGS temporarily.
2094     # We put this in CPPFLAGS where it precedes the other -I options.
2095     OLD_CPPFLAGS=$CPPFLAGS
2096     OLD_CFLAGS=$CFLAGS
2097     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2098     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2099     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2100       [int x = 5;],
2101       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2102     if test $emacs_cv_lesstif = yes; then
2103       # Make sure this -I option remains in CPPFLAGS after it is set
2104       # back to REAL_CPPFLAGS.
2105       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2106       # have those other -I options anyway.  Ultimately, having this
2107       # directory ultimately in CPPFLAGS will be enough.
2108       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2109       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2110     else
2111       CFLAGS=$OLD_CFLAGS
2112       CPPFLAGS=$OLD_CPPFLAGS
2113     fi
2114   fi
2115 fi
2116
2117 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2118 dnl using Motif or Xaw3d is available, and unless
2119 dnl --with-toolkit-scroll-bars=no was specified.
2120
2121 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2122             [Define to 1 if we should use toolkit scroll bars.])dnl
2123 USE_TOOLKIT_SCROLL_BARS=no
2124 if test "${with_toolkit_scroll_bars}" != "no"; then
2125   if test "${USE_X_TOOLKIT}" != "none"; then
2126     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2127       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2128       HAVE_XAW3D=no
2129       USE_TOOLKIT_SCROLL_BARS=yes
2130     elif test "${HAVE_XAW3D}" = "yes"; then
2131       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2132       USE_TOOLKIT_SCROLL_BARS=yes
2133     fi
2134   elif test "${HAVE_GTK}" = "yes"; then
2135     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2136     USE_TOOLKIT_SCROLL_BARS=yes
2137   elif test "${HAVE_NS}" = "yes"; then
2138     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2139     USE_TOOLKIT_SCROLL_BARS=yes
2140   fi
2141 fi
2142
2143 dnl See if XIM is available.
2144 AC_TRY_COMPILE([
2145           #include <X11/Xlib.h>
2146           #include <X11/Xresource.h>],
2147          [XIMProc  callback;],
2148          [HAVE_XIM=yes
2149          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2150          HAVE_XIM=no)
2151
2152 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2153
2154 if test "${with_xim}" != "no"; then
2155   AC_DEFINE(USE_XIM, 1,
2156             [Define to 1 if we should use XIM, if it is available.])
2157 fi
2158
2159
2160 if test "${HAVE_XIM}" != "no"; then
2161   late_CFLAGS=$CFLAGS
2162   if test "$GCC" = yes; then
2163     CFLAGS="$CFLAGS --pedantic-errors"
2164   fi
2165   AC_TRY_COMPILE([
2166 #include <X11/Xlib.h>
2167 #include <X11/Xresource.h>],
2168 [Display *display;
2169 XrmDatabase db;
2170 char *res_name;
2171 char *res_class;
2172 XIMProc  callback;
2173 XPointer *client_data;
2174 #ifndef __GNUC__
2175 /* If we're not using GCC, it's probably not XFree86, and this is
2176    probably right, but we can't use something like --pedantic-errors.  */
2177 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2178                                            char*, XIMProc, XPointer*);
2179 #endif
2180 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2181    client_data);],
2182     [emacs_cv_arg6_star=yes])
2183   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2184          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2185 either XPointer or XPointer*.])dnl
2186   if test "$emacs_cv_arg6_star" = yes; then
2187     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2188   else
2189     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2190   fi
2191   CFLAGS=$late_CFLAGS
2192 fi
2193
2194 ### Start of font-backend (under any platform) section.
2195 # (nothing here yet -- this is a placeholder)
2196 ### End of font-backend (under any platform) section.
2197
2198 ### Start of font-backend (under X11) section.
2199 if test "${HAVE_X11}" = "yes"; then
2200    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2201
2202    ## Use -lXft if available, unless `--with-xft=no'.
2203    HAVE_XFT=maybe
2204     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2205       with_xft="no";
2206     fi
2207     if test "x${with_xft}" != "xno"; then
2208
2209       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2210       ## Because xftfont.c uses XRenderQueryExtension, we also
2211       ## need to link to -lXrender.
2212       HAVE_XRENDER=no
2213       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2214       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2215         OLD_CPPFLAGS="$CPPFLAGS"
2216         OLD_CFLAGS="$CFLAGS"
2217         OLD_LIBS="$LIBS"
2218         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2219         CFLAGS="$CFLAGS $XFT_CFLAGS"
2220         XFT_LIBS="-lXrender $XFT_LIBS"
2221         LIBS="$XFT_LIBS $LIBS"
2222         AC_CHECK_HEADER(X11/Xft/Xft.h,
2223           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2224
2225         if test "${HAVE_XFT}" = "yes"; then
2226           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2227             AC_SUBST(XFT_LIBS)
2228           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2229         else
2230           CPPFLAGS="$OLD_CPPFLAGS"
2231           CFLAGS="$OLD_CFLAGS"
2232           LIBS="$OLD_LIBS"
2233         fi                        # "${HAVE_XFT}" = "yes"
2234       fi                          # "$HAVE_XFT" != no
2235     fi                            # "x${with_xft}" != "xno"
2236
2237     dnl For the "Does Emacs use" message at the end.
2238     if test "$HAVE_XFT" != "yes"; then
2239        HAVE_XFT=no
2240     fi
2241
2242
2243     HAVE_FREETYPE=no
2244     ## We used to allow building with FreeType and without Xft.
2245     ## However, the ftx font backend driver is not in good shape.
2246     if test "${HAVE_XFT}" = "yes"; then
2247       dnl As we use Xft, we anyway use freetype.
2248       dnl There's no need for additional CFLAGS and LIBS.
2249       HAVE_FREETYPE=yes
2250       FONTCONFIG_CFLAGS=
2251       FONTCONFIG_LIBS=
2252     fi
2253
2254     HAVE_LIBOTF=no
2255     if test "${HAVE_FREETYPE}" = "yes"; then
2256       AC_DEFINE(HAVE_FREETYPE, 1,
2257                 [Define to 1 if using the freetype and fontconfig libraries.])
2258       if test "${with_libotf}" != "no"; then
2259         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2260                           HAVE_LIBOTF=no)
2261         if test "$HAVE_LIBOTF" = "yes"; then
2262           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2263           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2264                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2265                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2266           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2267             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2268                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2269           fi
2270         fi
2271       fi
2272     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2273     dnl Does the new font backend require it, or can it work without it?
2274     fi
2275
2276     HAVE_M17N_FLT=no
2277     if test "${HAVE_LIBOTF}" = yes; then
2278       if test "${with_m17n_flt}" != "no"; then
2279         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2280         if test "$HAVE_M17N_FLT" = "yes"; then
2281           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2282         fi
2283       fi
2284     fi
2285 else
2286     HAVE_XFT=no
2287     HAVE_FREETYPE=no
2288     HAVE_LIBOTF=no
2289     HAVE_M17N_FLT=no
2290 fi
2291
2292 ### End of font-backend (under X11) section.
2293
2294 AC_SUBST(FREETYPE_CFLAGS)
2295 AC_SUBST(FREETYPE_LIBS)
2296 AC_SUBST(FONTCONFIG_CFLAGS)
2297 AC_SUBST(FONTCONFIG_LIBS)
2298 AC_SUBST(LIBOTF_CFLAGS)
2299 AC_SUBST(LIBOTF_LIBS)
2300 AC_SUBST(M17N_FLT_CFLAGS)
2301 AC_SUBST(M17N_FLT_LIBS)
2302
2303 ### Use -lXpm if available, unless `--with-xpm=no'.
2304 HAVE_XPM=no
2305 LIBXPM=
2306 if test "${HAVE_X11}" = "yes"; then
2307   if test "${with_xpm}" != "no"; then
2308     AC_CHECK_HEADER(X11/xpm.h,
2309       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2310     if test "${HAVE_XPM}" = "yes"; then
2311       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2312       AC_EGREP_CPP(no_return_alloc_pixels,
2313       [#include "X11/xpm.h"
2314 #ifndef XpmReturnAllocPixels
2315 no_return_alloc_pixels
2316 #endif
2317       ], HAVE_XPM=no, HAVE_XPM=yes)
2318
2319       if test "${HAVE_XPM}" = "yes"; then
2320         AC_MSG_RESULT(yes)
2321       else
2322         AC_MSG_RESULT(no)
2323       fi
2324     fi
2325   fi
2326
2327   if test "${HAVE_XPM}" = "yes"; then
2328     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2329     LIBXPM=-lXpm
2330   fi
2331 fi
2332 AC_SUBST(LIBXPM)
2333
2334 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2335 HAVE_JPEG=no
2336 LIBJPEG=
2337 if test "${HAVE_X11}" = "yes"; then
2338   if test "${with_jpeg}" != "no"; then
2339     dnl Checking for jpeglib.h can lose because of a redefinition of
2340     dnl  HAVE_STDLIB_H.
2341     AC_CHECK_HEADER(jerror.h,
2342       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2343   fi
2344
2345   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2346   if test "${HAVE_JPEG}" = "yes"; then
2347     AC_DEFINE(HAVE_JPEG)
2348     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2349         [#include <jpeglib.h>
2350          version=JPEG_LIB_VERSION
2351 ],
2352         [AC_DEFINE(HAVE_JPEG)],
2353         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2354         HAVE_JPEG=no])
2355   fi
2356   if test "${HAVE_JPEG}" = "yes"; then
2357     LIBJPEG=-ljpeg
2358   fi
2359 fi
2360 AC_SUBST(LIBJPEG)
2361
2362 ### Use -lpng if available, unless `--with-png=no'.
2363 HAVE_PNG=no
2364 LIBPNG=
2365 if test "${HAVE_X11}" = "yes"; then
2366   if test "${with_png}" != "no"; then
2367     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2368     # in /usr/include/libpng.
2369     AC_CHECK_HEADERS(png.h libpng/png.h)
2370     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2371       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2372     fi
2373   fi
2374
2375   if test "${HAVE_PNG}" = "yes"; then
2376     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2377     LIBPNG="-lpng -lz -lm"
2378   fi
2379 fi
2380 AC_SUBST(LIBPNG)
2381
2382 ### Use -ltiff if available, unless `--with-tiff=no'.
2383 HAVE_TIFF=no
2384 LIBTIFF=
2385 if test "${HAVE_X11}" = "yes"; then
2386   if test "${with_tiff}" != "no"; then
2387     AC_CHECK_HEADER(tiffio.h,
2388       [tifflibs="-lz -lm"
2389       # At least one tiff package requires the jpeg library.
2390       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2391       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2392   fi
2393
2394   if test "${HAVE_TIFF}" = "yes"; then
2395     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2396     dnl FIXME -lz -lm, as per libpng?
2397     LIBTIFF=-ltiff
2398   fi
2399 fi
2400 AC_SUBST(LIBTIFF)
2401
2402 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2403 HAVE_GIF=no
2404 LIBGIF=
2405 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2406   AC_CHECK_HEADER(gif_lib.h,
2407 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2408 # Earlier versions can crash Emacs.
2409     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2410
2411   if test "$HAVE_GIF" = yes; then
2412     LIBGIF=-lgif
2413   elif test "$HAVE_GIF" = maybe; then
2414 # If gif_lib.h but no libgif, try libungif.
2415     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2416     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2417   fi
2418
2419   if test "${HAVE_GIF}" = "yes"; then
2420     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2421   fi
2422 fi
2423 AC_SUBST(LIBGIF)
2424
2425 dnl Check for required libraries.
2426 if test "${HAVE_X11}" = "yes"; then
2427   MISSING=""
2428   WITH_NO=""
2429   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2430     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2431   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2432     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2433   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2434     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2435   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2436     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2437   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2438     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2439
2440   if test "X${MISSING}" != X; then
2441     AC_MSG_ERROR([The following required libraries were not found:
2442     $MISSING
2443 Maybe some development libraries/packages are missing?
2444 If you don't want to link with them give
2445     $WITH_NO
2446 as options to configure])
2447   fi
2448 fi
2449
2450 ### Use -lgpm if available, unless `--with-gpm=no'.
2451 HAVE_GPM=no
2452 LIBGPM=
2453 MOUSE_SUPPORT=
2454 if test "${with_gpm}" != "no"; then
2455   AC_CHECK_HEADER(gpm.h,
2456     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2457
2458   if test "${HAVE_GPM}" = "yes"; then
2459     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2460     LIBGPM=-lgpm
2461     ## May be reset below.
2462     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2463   fi
2464 fi
2465 AC_SUBST(LIBGPM)
2466
2467 dnl Check for malloc/malloc.h on darwin
2468 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2469
2470 C_SWITCH_X_SYSTEM=
2471 ### Use NeXTstep API to implement GUI.
2472 if test "${HAVE_NS}" = "yes"; then
2473   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2474   if test "${NS_IMPL_COCOA}" = "yes"; then
2475     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2476     GNU_OBJC_CFLAGS=
2477   fi
2478   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2479     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2480     # See also .m.o rule in Makefile.in */
2481     # FIXME: are all these flags really needed?  Document here why.  */
2482     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2483     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2484   fi
2485   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2486     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2487   fi
2488   # We also have mouse menus.
2489   HAVE_MENUS=yes
2490   OTHER_FILES=ns-app
2491 fi
2492
2493
2494 ### Use session management (-lSM -lICE) if available
2495 HAVE_X_SM=no
2496 LIBXSM=
2497 if test "${HAVE_X11}" = "yes"; then
2498   AC_CHECK_HEADER(X11/SM/SMlib.h,
2499     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2500
2501   if test "${HAVE_X_SM}" = "yes"; then
2502     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2503     LIBXSM="-lSM -lICE"
2504     case "$LIBS" in
2505       *-lSM*) ;;
2506       *)      LIBS="$LIBXSM $LIBS" ;;
2507     esac
2508   fi
2509 fi
2510 AC_SUBST(LIBXSM)
2511
2512 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2513 AC_CACHE_CHECK(whether netdb declares h_errno,
2514                emacs_cv_netdb_declares_h_errno,
2515 [AC_TRY_LINK([#include <netdb.h>],
2516   [return h_errno;],
2517   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2518 if test $emacs_cv_netdb_declares_h_errno = yes; then
2519   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2520 fi
2521
2522 AC_FUNC_ALLOCA
2523
2524 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2525 dnl FIXME is there an autoconf test that does the right thing, without
2526 dnl needing to call A_M_E afterwards?
2527 if test x"$ac_cv_func_alloca_works" != xyes; then
2528    AC_MSG_ERROR( [a system implementation of alloca is required] )
2529 fi
2530
2531 # fmod, logb, and frexp are found in -lm on most systems.
2532 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2533 AC_CHECK_LIB(m, sqrt)
2534
2535 # Check for mail-locking functions in a "mail" library.  Probably this should
2536 # have the same check as for liblockfile below.
2537 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2538 if test $have_mail = yes; then
2539   LIBS_MAIL=-lmail
2540   LIBS="$LIBS_MAIL $LIBS"
2541   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2542 else
2543   LIBS_MAIL=
2544 fi
2545 dnl Debian, at least:
2546 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2547 if test $have_lockfile = yes; then
2548    LIBS_MAIL=-llockfile
2549    LIBS="$LIBS_MAIL $LIBS"
2550    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2551 else
2552 # If we have the shared liblockfile, assume we must use it for mail
2553 # locking (e.g. Debian).  If we couldn't link against liblockfile
2554 # (no liblockfile.a installed), ensure that we don't need to.
2555   dnl This works for files generally, not just executables.
2556   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2557   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2558                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2559   if test $ac_cv_prog_liblockfile = yes; then
2560     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2561 This probably means that movemail could lose mail.
2562 There may be a `development' package to install containing liblockfile.])
2563   fi
2564 fi
2565 AC_CHECK_FUNCS(touchlock)
2566 AC_CHECK_HEADERS(maillock.h)
2567 AC_SUBST(LIBS_MAIL)
2568
2569 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2570 ## interlock access to the mail spool.  The alternative is a lock file named
2571 ## /usr/spool/mail/$USER.lock.
2572 mail_lock=no
2573 case "$opsys" in
2574   aix4-2) mail_lock="lockf" ;;
2575
2576   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2577
2578   ## On GNU/Linux systems, both methods are used by various mail programs.
2579   ## I assume most people are using newer mailers that have heard of flock.
2580   ## Change this if you need to.
2581   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2582   ## configure gets the right answers, and that means *NOT* using flock.
2583   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2584   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2585   ## Debian maintainer hasn't provided a clean fix for Emacs.
2586   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2587   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2588   ## correct logic.  -- fx
2589   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2590   ## liblockfile is a Free Software replacement for libmail, used on
2591   ## Debian systems and elsewhere. -rfr.
2592   gnu-*)
2593     mail_lock="flock"
2594     if test $have_mail = yes || test $have_lockfile = yes; then
2595       test $ac_cv_header_maillock_h = yes && mail_lock=no
2596     fi
2597     ;;
2598 esac
2599
2600 BLESSMAIL_TARGET=
2601 case "$mail_lock" in
2602   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2603
2604   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2605
2606   *) BLESSMAIL_TARGET="need-blessmail" ;;
2607 esac
2608 AC_SUBST(BLESSMAIL_TARGET)
2609
2610
2611 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2612 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2613 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2614 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2615 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2616 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2617 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2618 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2619 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2620 cfmakeraw cfsetspeed isnan copysign __executable_start)
2621
2622 AC_CHECK_HEADERS(sys/un.h)
2623
2624 AC_FUNC_MKTIME
2625 if test "$ac_cv_func_working_mktime" = no; then
2626   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2627 fi
2628
2629 AC_FUNC_GETLOADAVG
2630
2631 AC_FUNC_FSEEKO
2632
2633 # Configure getopt.
2634 m4_include([m4/getopt.m4])
2635 gl_GETOPT_IFELSE([
2636   gl_GETOPT_SUBSTITUTE_HEADER
2637   gl_PREREQ_GETOPT
2638   GETOPTOBJS='getopt.o getopt1.o'
2639 ])
2640 AC_SUBST(GETOPTOBJS)
2641
2642 AC_FUNC_GETPGRP
2643
2644 AC_FUNC_STRFTIME
2645
2646 # UNIX98 PTYs.
2647 AC_CHECK_FUNCS(grantpt)
2648
2649 # PTY-related GNU extensions.
2650 AC_CHECK_FUNCS(getpt)
2651
2652 # Check this now, so that we will NOT find the above functions in ncurses.
2653 # That is because we have not set up to link ncurses in lib-src.
2654 # It's better to believe a function is not available
2655 # than to expect to find it in ncurses.
2656 # Also we need tputs and friends to be able to build at all.
2657 have_tputs_et_al=true
2658 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2659 if test "$have_tputs_et_al" != true; then
2660   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2661 Maybe some development libraries/packages are missing?  Try installing
2662 libncurses-dev(el), libterminfo-dev(el) or similar.])
2663 fi
2664 # Must define this when any termcap library is found.
2665 AC_DEFINE(HAVE_LIBNCURSES, 1,
2666           [Define to 1 if you have the `ncurses' library (-lncurses).])
2667 ## FIXME This was the cpp logic, but I am not sure it is right.
2668 ## The above test has not necessarily found libncurses.
2669 HAVE_LIBNCURSES=yes
2670
2671 ## Use terminfo instead of termcap?
2672 ## Note only system files NOT using terminfo are:
2673 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2674 ## darwin|gnu without ncurses.
2675 TERMINFO=no
2676 LIBS_TERMCAP=
2677 case "$opsys" in
2678   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2679   ## hpux10-20: Use the system provided termcap(3) library.
2680   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2681   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2682   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2683
2684   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2685   ##  The ncurses library has been moved out of the System framework in
2686   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2687   ##  option to use it.
2688   darwin|gnu*)
2689     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2690     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2691       TERMINFO=yes
2692       LIBS_TERMCAP="-lncurses"
2693     fi
2694     ;;
2695
2696   freebsd)
2697     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2698     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2699     [AC_TRY_LINK([#include <osreldate.h>],
2700 [#if __FreeBSD_version < 400000
2701 fail;
2702 #endif
2703 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2704
2705     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2706
2707     if test $emacs_cv_freebsd_terminfo = yes; then
2708       TERMINFO=yes
2709       LIBS_TERMCAP="-lncurses"
2710     else
2711       LIBS_TERMCAP="-ltermcap"
2712     fi
2713     ;;
2714
2715   netbsd)
2716     if test $ac_cv_search_tputs = -lterminfo; then
2717       TERMINFO=yes
2718       LIBS_TERMCAP="-lterminfo"
2719     else
2720       LIBS_TERMCAP="-ltermcap"
2721     fi
2722     ;;
2723
2724 esac
2725
2726 case "$opsys" in
2727   ## hpux: Make sure we get select from libc rather than from libcurses
2728   ##  because libcurses on HPUX 10.10 has a broken version of select.
2729   ##  We used to use -lc -lcurses, but this may be cleaner.
2730   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2731
2732   openbsd) LIBS_TERMCAP="-lncurses" ;;
2733
2734   ## Must use system termcap, if we use any termcap.  It does special things.
2735   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2736 esac
2737
2738 TERMCAP_OBJ=tparam.o
2739 if test $TERMINFO = yes; then
2740   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2741
2742   ## Default used to be -ltermcap.  Add a case above if need something else.
2743   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2744
2745   TERMCAP_OBJ=terminfo.o
2746 fi
2747 AC_SUBST(LIBS_TERMCAP)
2748 AC_SUBST(TERMCAP_OBJ)
2749
2750
2751 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2752 resolv=no
2753 AC_TRY_LINK([#include <netinet/in.h>
2754 #include <arpa/nameser.h>
2755 #include <resolv.h>],
2756     [return res_init();],
2757     have_res_init=yes, have_res_init=no)
2758 if test "$have_res_init" = no; then
2759   OLIBS="$LIBS"
2760   LIBS="$LIBS -lresolv"
2761   AC_MSG_CHECKING(for res_init with -lresolv)
2762   AC_TRY_LINK([#include <netinet/in.h>
2763 #include <arpa/nameser.h>
2764 #include <resolv.h>],
2765     [return res_init();],
2766     have_res_init=yes, have_res_init=no)
2767   AC_MSG_RESULT($have_res_init)
2768   if test "$have_res_init" = yes ; then
2769     resolv=yes
2770   fi
2771   LIBS="$OLIBS"
2772 fi
2773
2774 if test "$have_res_init" = yes; then
2775   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2776 fi
2777
2778 # Do we need the Hesiod library to provide the support routines?
2779 LIBHESIOD=
2780 if test "$with_hesiod" != no ; then
2781   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2782   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2783      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2784                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2785   if test "$resolv" = yes ; then
2786     RESOLVLIB=-lresolv
2787   else
2788     RESOLVLIB=
2789   fi
2790   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2791         hesiod=yes, :, $RESOLVLIB)])
2792
2793   if test x"$hesiod" = xyes; then
2794     AC_DEFINE(HAVE_LIBHESIOD, 1,
2795               [Define to 1 if you have the hesiod library (-lhesiod).])
2796     LIBHESIOD=-lhesiod
2797   fi
2798 fi
2799 AC_SUBST(LIBHESIOD)
2800
2801 # Do we need libresolv (due to res_init or Hesiod)?
2802 if test "$resolv" = yes ; then
2803   AC_DEFINE(HAVE_LIBRESOLV, 1,
2804             [Define to 1 if you have the resolv library (-lresolv).])
2805   LIBRESOLV=-lresolv
2806 else
2807   LIBRESOLV=
2808 fi
2809 AC_SUBST(LIBRESOLV)
2810
2811 # These tell us which Kerberos-related libraries to use.
2812 COM_ERRLIB=
2813 CRYPTOLIB=
2814 KRB5LIB=
2815 DESLIB=
2816 KRB4LIB=
2817
2818 if test "${with_kerberos}" != no; then
2819   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2820   if test $have_com_err = yes; then
2821     COM_ERRLIB=-lcom_err
2822     LIBS="$COM_ERRLIB $LIBS"
2823     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2824   fi
2825   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2826   if test $have_crypto = yes; then
2827     CRYPTOLIB=-lcrypto
2828     LIBS="$CRYPTOLIB $LIBS"
2829     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2830   fi
2831   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2832   if test $have_k5crypto = yes; then
2833     CRYPTOLIB=-lk5crypto
2834     LIBS="$CRYPTOLIB $LIBS"
2835     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2836   fi
2837   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2838   if test $have_krb5=yes; then
2839     KRB5LIB=-lkrb5
2840     LIBS="$KRB5LIB $LIBS"
2841     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2842   fi
2843   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2844   if test "${with_kerberos5}" = no; then
2845     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2846     if test $have_des425 = yes; then
2847       DESLIB=-ldes425
2848       LIBS="$DESLIB $LIBS"
2849       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2850     else
2851       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2852       if test $have_des = yes; then
2853         DESLIB=-ldes
2854         LIBS="$DESLIB $LIBS"
2855         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2856       fi
2857     fi
2858     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2859     if test $have_krb4 = yes; then
2860       KRB4LIB=-lkrb4
2861       LIBS="$KRB4LIB $LIBS"
2862       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2863     else
2864       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2865       if test $have_krb = yes; then
2866         KRB4LIB=-lkrb
2867         LIBS="$KRB4LIB $LIBS"
2868         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2869       fi
2870     fi
2871   fi
2872
2873   if test "${with_kerberos5}" != no; then
2874     AC_CHECK_HEADERS(krb5.h,
2875       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2876                         [#include <krb5.h>])])
2877   else
2878     AC_CHECK_HEADERS(des.h,,
2879                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2880                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2881     AC_CHECK_HEADERS(krb.h,,
2882                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2883                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2884   fi
2885   AC_CHECK_HEADERS(com_err.h)
2886 fi
2887
2888 AC_SUBST(COM_ERRLIB)
2889 AC_SUBST(CRYPTOLIB)
2890 AC_SUBST(KRB5LIB)
2891 AC_SUBST(DESLIB)
2892 AC_SUBST(KRB4LIB)
2893
2894 # Solaris requires -lintl if you want strerror (which calls dgettext)
2895 # to return localized messages.
2896 AC_CHECK_LIB(intl, dgettext)
2897
2898 AC_MSG_CHECKING(whether localtime caches TZ)
2899 AC_CACHE_VAL(emacs_cv_localtime_cache,
2900 [if test x$ac_cv_func_tzset = xyes; then
2901 AC_TRY_RUN([#include <time.h>
2902 extern char **environ;
2903 unset_TZ ()
2904 {
2905   char **from, **to;
2906   for (to = from = environ; (*to = *from); from++)
2907     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2908       to++;
2909 }
2910 char TZ_GMT0[] = "TZ=GMT0";
2911 char TZ_PST8[] = "TZ=PST8";
2912 main()
2913 {
2914   time_t now = time ((time_t *) 0);
2915   int hour_GMT0, hour_unset;
2916   if (putenv (TZ_GMT0) != 0)
2917     exit (1);
2918   hour_GMT0 = localtime (&now)->tm_hour;
2919   unset_TZ ();
2920   hour_unset = localtime (&now)->tm_hour;
2921   if (putenv (TZ_PST8) != 0)
2922     exit (1);
2923   if (localtime (&now)->tm_hour == hour_GMT0)
2924     exit (1);
2925   unset_TZ ();
2926   if (localtime (&now)->tm_hour != hour_unset)
2927     exit (1);
2928   exit (0);
2929 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2930 [# If we have tzset, assume the worst when cross-compiling.
2931 emacs_cv_localtime_cache=yes])
2932 else
2933         # If we lack tzset, report that localtime does not cache TZ,
2934         # since we can't invalidate the cache if we don't have tzset.
2935         emacs_cv_localtime_cache=no
2936 fi])dnl
2937 AC_MSG_RESULT($emacs_cv_localtime_cache)
2938 if test $emacs_cv_localtime_cache = yes; then
2939   AC_DEFINE(LOCALTIME_CACHE, 1,
2940             [Define to 1 if localtime caches TZ.])
2941 fi
2942
2943 if test "x$HAVE_TIMEVAL" = xyes; then
2944   AC_CHECK_FUNCS(gettimeofday)
2945   if test $ac_cv_func_gettimeofday = yes; then
2946     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2947                    emacs_cv_gettimeofday_two_arguments,
2948     [AC_TRY_COMPILE([
2949 #ifdef TIME_WITH_SYS_TIME
2950 #include <sys/time.h>
2951 #include <time.h>
2952 #else
2953 #ifdef HAVE_SYS_TIME_H
2954 #include <sys/time.h>
2955 #else
2956 #include <time.h>
2957 #endif
2958 #endif],
2959       [struct timeval time;
2960        gettimeofday (&time, 0);],
2961       emacs_cv_gettimeofday_two_arguments=yes,
2962       emacs_cv_gettimeofday_two_arguments=no)])
2963     if test $emacs_cv_gettimeofday_two_arguments = no; then
2964       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2965                 [Define to 1 if gettimeofday accepts only one argument.])
2966     fi
2967   fi
2968 fi
2969
2970 ok_so_far=yes
2971 AC_CHECK_FUNC(socket, , ok_so_far=no)
2972 if test $ok_so_far = yes; then
2973   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2974 fi
2975 if test $ok_so_far = yes; then
2976   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2977 fi
2978 if test $ok_so_far = yes; then
2979 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2980   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2981             [Define to 1 if you have inet sockets.])
2982 fi
2983
2984 AC_CHECK_HEADERS(sys/ioctl.h)
2985
2986 if test -f /usr/lpp/X11/bin/smt.exp; then
2987   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2988             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2989 fi
2990
2991 AC_MSG_CHECKING(whether system supports dynamic ptys)
2992 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2993   AC_MSG_RESULT(yes)
2994   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2995 else
2996   AC_MSG_RESULT(no)
2997 fi
2998
2999 AC_FUNC_FORK
3000
3001 dnl Adapted from Haible's version.
3002 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3003   [AC_TRY_LINK([#include <langinfo.h>],
3004     [char* cs = nl_langinfo(CODESET);],
3005     emacs_cv_langinfo_codeset=yes,
3006     emacs_cv_langinfo_codeset=no)
3007   ])
3008 if test $emacs_cv_langinfo_codeset = yes; then
3009   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3010     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3011 fi
3012
3013 AC_CHECK_TYPES(size_t)
3014
3015 AC_TYPE_MBSTATE_T
3016
3017 dnl Restrict could probably be used effectively other than in regex.c.
3018 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3019   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3020                   emacs_cv_c_restrict=yes,
3021                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3022                                   emacs_cv_c_restrict=__restrict,
3023                                   emacs_cv_c_restrict=no)])])
3024 case "$emacs_cv_c_restrict" in
3025   yes) emacs_restrict=restrict;;
3026   no) emacs_restrict="";;
3027   *) emacs_restrict="$emacs_cv_c_restrict";;
3028 esac
3029 if test "$emacs_restrict" != __restrict; then
3030   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3031     [Define to compiler's equivalent of C99 restrict keyword.
3032      Don't define if equivalent is `__restrict'.])
3033 fi
3034
3035 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3036   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3037                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3038 if test "$emacs_cv_c_restrict_arr" = yes; then
3039   AC_DEFINE(__restrict_arr, __restrict,
3040     [Define to compiler's equivalent of C99 restrict keyword in array
3041      declarations.  Define as empty for no equivalent.])
3042 fi
3043
3044 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3045 dnl how the tty code is related to POSIX and/or other versions of termios.
3046 dnl The following looks like a useful start.
3047 dnl
3048 dnl AC_SYS_POSIX_TERMIOS
3049 dnl if test $ac_cv_sys_posix_termios = yes; then
3050 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3051 dnl                                and macros for terminal control.])
3052 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3053 dnl fi
3054
3055 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3056
3057 # Set up the CFLAGS for real compilation, so we can substitute it.
3058 CFLAGS="$REAL_CFLAGS"
3059 CPPFLAGS="$REAL_CPPFLAGS"
3060
3061 ## Hack to detect a buggy GCC version.
3062 if test "x$GCC" = xyes \
3063    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3064    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3065    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3066    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3067 fi
3068
3069 #### Find out which version of Emacs this is.
3070 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3071          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3072 if test x"${version}" = x; then
3073   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3074 fi
3075 if test x"${version}" != x"$PACKAGE_VERSION"; then
3076   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3077 fi
3078
3079 ### Specify what sort of things we'll be editing into Makefile and config.h.
3080 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3081 AC_SUBST(version)
3082 AC_SUBST(configuration)
3083 ## Unused?
3084 AC_SUBST(canonical)
3085 AC_SUBST(srcdir)
3086 AC_SUBST(prefix)
3087 AC_SUBST(exec_prefix)
3088 AC_SUBST(bindir)
3089 AC_SUBST(datadir)
3090 AC_SUBST(sharedstatedir)
3091 AC_SUBST(libexecdir)
3092 AC_SUBST(mandir)
3093 AC_SUBST(infodir)
3094 AC_SUBST(lispdir)
3095 AC_SUBST(locallisppath)
3096 AC_SUBST(lisppath)
3097 AC_SUBST(x_default_search_path)
3098 AC_SUBST(etcdir)
3099 AC_SUBST(archlibdir)
3100 AC_SUBST(docdir)
3101 AC_SUBST(bitmapdir)
3102 AC_SUBST(gamedir)
3103 AC_SUBST(gameuser)
3104 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3105 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3106 ## end of LIBX_BASE, but nothing ever set it.
3107 AC_SUBST(LD_SWITCH_X_SITE)
3108 AC_SUBST(C_SWITCH_X_SITE)
3109 AC_SUBST(C_SWITCH_X_SYSTEM)
3110 AC_SUBST(CFLAGS)
3111 ## Used in lwlib/Makefile.in.
3112 AC_SUBST(X_TOOLKIT_TYPE)
3113 AC_SUBST(machfile)
3114 AC_SUBST(opsysfile)
3115 AC_SUBST(GETLOADAVG_LIBS)
3116 AC_SUBST(ns_appdir)
3117 AC_SUBST(ns_appbindir)
3118 AC_SUBST(ns_appresdir)
3119 AC_SUBST(ns_appsrc)
3120 AC_SUBST(GNU_OBJC_CFLAGS)
3121 AC_SUBST(OTHER_FILES)
3122
3123 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3124                    [Define to the canonical Emacs configuration name.])
3125 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3126                    [Define to the options passed to configure.])
3127 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3128                    [Define to the used machine dependent file.])
3129 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3130                    [Define to the used os dependent file.])
3131
3132 XMENU_OBJ=
3133 XOBJ=
3134 FONT_OBJ=
3135 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3136   AC_DEFINE(HAVE_X_WINDOWS, 1,
3137             [Define to 1 if you want to use the X window system.])
3138   XMENU_OBJ=xmenu.o
3139   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3140   FONT_OBJ=xfont.o
3141   if test "$HAVE_XFT" = "yes"; then
3142     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3143   elif test "$HAVE_FREETYPE" = "yes"; then
3144     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3145   fi
3146   AC_SUBST(FONT_OBJ)
3147 fi
3148 AC_SUBST(XMENU_OBJ)
3149 AC_SUBST(XOBJ)
3150 AC_SUBST(FONT_OBJ)
3151
3152 WIDGET_OBJ=
3153 MOTIF_LIBW=
3154 if test "${USE_X_TOOLKIT}" != "none" ; then
3155   WIDGET_OBJ=widget.o
3156   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3157   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3158     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3159   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3160     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3161     MOTIF_LIBW=-lXm
3162     case "$opsys" in
3163       gnu-linux)
3164         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3165         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3166         ;;
3167
3168       unixware)
3169         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3170         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3171         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3172         ;;
3173
3174       aix4-2)
3175         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3176         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3177         ;;
3178     esac
3179     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3180   fi
3181 fi
3182 AC_SUBST(WIDGET_OBJ)
3183
3184 TOOLKIT_LIBW=
3185 case "$USE_X_TOOLKIT" in
3186   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3187   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3188   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3189 esac
3190 AC_SUBST(TOOLKIT_LIBW)
3191
3192 if test "$USE_X_TOOLKIT" = "none"; then
3193   LIBXT_OTHER="\$(LIBXSM)"
3194   OLDXMENU_TARGET="really-oldXMenu"
3195 else
3196   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3197   OLDXMENU_TARGET="really-lwlib"
3198 fi
3199 AC_SUBST(LIBXT_OTHER)
3200
3201 ## The X Menu stuff is present in the X10 distribution, but missing
3202 ## from X11.  If we have X10, just use the installed library;
3203 ## otherwise, use our own copy.
3204 if test "${HAVE_X11}" = "yes" ; then
3205   AC_DEFINE(HAVE_X11, 1,
3206             [Define to 1 if you want to use version 11 of X windows.
3207              Otherwise, Emacs expects to use version 10.])
3208
3209   if test "$USE_X_TOOLKIT" = "none"; then
3210     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3211   else
3212     OLDXMENU="\${lwlibdir}liblw.a"
3213   fi
3214   LIBXMENU="\$(OLDXMENU)"
3215   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3216   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3217 else
3218   ## For a syntactically valid Makefile; not actually used for anything.
3219   ## See comments in src/Makefile.in.
3220   OLDXMENU=nothing
3221   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3222   if test "${HAVE_X_WINDOWS}" = "yes"; then
3223     LIBXMENU="-lXMenu"
3224   else
3225     LIBXMENU=
3226   fi
3227   LIBX_OTHER=
3228   OLDXMENU_DEPS=
3229 fi
3230
3231 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3232   OLDXMENU_TARGET=
3233   OLDXMENU=nothing
3234   LIBXMENU=
3235   OLDXMENU_DEPS=
3236 fi
3237
3238 AC_SUBST(OLDXMENU_TARGET)
3239 AC_SUBST(OLDXMENU)
3240 AC_SUBST(LIBXMENU)
3241 AC_SUBST(LIBX_OTHER)
3242 AC_SUBST(OLDXMENU_DEPS)
3243
3244 if test "${HAVE_MENUS}" = "yes" ; then
3245   AC_DEFINE(HAVE_MENUS, 1,
3246             [Define to 1 if you have mouse menus.
3247              (This is automatic if you use X, but the option to specify it remains.)
3248              It is also defined with other window systems that support xmenu.c.])
3249 fi
3250
3251 if test "${GNU_MALLOC}" = "yes" ; then
3252   AC_DEFINE(GNU_MALLOC, 1,
3253             [Define to 1 if you want to use the GNU memory allocator.])
3254 fi
3255
3256 RALLOC_OBJ=
3257 if test "${REL_ALLOC}" = "yes" ; then
3258   AC_DEFINE(REL_ALLOC, 1,
3259             [Define REL_ALLOC if you want to use the relocating allocator for
3260              buffer space.])
3261
3262   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3263 fi
3264 AC_SUBST(RALLOC_OBJ)
3265
3266 if test "$opsys" = "cygwin"; then
3267   CYGWIN_OBJ="sheap.o"
3268   ## Cygwin differs because of its unexec().
3269   PRE_ALLOC_OBJ=
3270   POST_ALLOC_OBJ=lastfile.o
3271 else
3272   CYGWIN_OBJ=
3273   PRE_ALLOC_OBJ=lastfile.o
3274   POST_ALLOC_OBJ=
3275 fi
3276 AC_SUBST(CYGWIN_OBJ)
3277 AC_SUBST(PRE_ALLOC_OBJ)
3278 AC_SUBST(POST_ALLOC_OBJ)
3279
3280
3281 case "$opsys" in
3282   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3283
3284   darwin)
3285    ## The -headerpad option tells ld (see man page) to leave room at the
3286    ## end of the header for adding load commands.  Needed for dumping.
3287    ## 0x690 is the total size of 30 segment load commands (at 56
3288    ## each); under Cocoa 31 commands are required.
3289    if test "$HAVE_NS" = "yes"; then
3290      libs_nsgui="-framework AppKit"
3291      headerpad_extra=6C8
3292    else
3293      libs_nsgui=
3294      headerpad_extra=690
3295    fi
3296    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3297
3298    ## This is here because src/Makefile.in did some extra fiddling around
3299    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3300    ##   #ifndef LD_SWITCH_SYSTEM
3301    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3302    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3303    ## not using gcc, darwin system not on an alpha (ie darwin, since
3304    ## darwin + alpha does not occur).
3305    ## Because this was done in src/Makefile.in, the resulting part of
3306    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3307    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3308    ## rather than LD_SWITCH_SYSTEM.
3309    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3310      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3311    ;;
3312
3313   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3314   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3315   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3316   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3317   ## had different values in configure (in ac_link) and src/Makefile.in.
3318   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3319   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3320
3321   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3322 esac
3323
3324 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3325   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3326 fi
3327
3328 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3329
3330
3331 LINKER=
3332 ORDINARY_LINK=
3333 case "$opsys" in
3334   ## gnu: GNU needs its own crt0.
3335   aix4-2|cygwin|darwin|gnu|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3336
3337   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3338   ## library search parth, i.e. it won't search /usr/lib for libc and
3339   ## friends.  Using -nostartfiles instead avoids this problem, and
3340   ## will also work on earlier NetBSD releases.
3341   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3342
3343   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3344   ##   MkLinux/LinuxPPC needs this.
3345   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3346   gnu-*)
3347     case "$machine" in
3348       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3349     esac
3350     ;;
3351 esac
3352
3353
3354 if test "x$ORDINARY_LINK" = "xyes"; then
3355
3356   LINKER="\$(CC)"
3357   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3358
3359 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3360 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3361 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3362
3363   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3364   ## places that are difficult to figure out at make time.  Fortunately,
3365   ## these same versions allow you to pass arbitrary flags on to the
3366   ## linker, so there is no reason not to use it as a linker.
3367   ##
3368   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3369   ## searching for libraries in its internal directories, so we have to
3370   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3371   LINKER="\$(CC) -nostdlib"
3372 fi
3373
3374 test "x$LINKER" = "x" && LINKER=ld
3375 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3376 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3377
3378 AC_SUBST(LINKER)
3379
3380
3381 ## FIXME? The logic here is not precisely the same as that above.
3382 ## There is no check here for a pre-defined LINKER.
3383 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3384 LIB_GCC=
3385 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3386
3387   case "$opsys" in
3388     freebsd|netbsd|openbsd) LIB_GCC= ;;
3389
3390     gnu-*)
3391       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3392       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3393       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3394       if test "$machine" = "arm"; then
3395         LIB_GCC="-lgcc_s"
3396       else
3397         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3398         ## immediately undefine it again and redefine it to empty.
3399         ## Was the C_SWITCH_X_SITE part really necessary?
3400 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3401         LIB_GCC=
3402       fi
3403       ;;
3404
3405     ## Ask GCC where to find libgcc.a.
3406     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3407   esac
3408 fi                              dnl if $GCC
3409 AC_SUBST(LIB_GCC)
3410
3411
3412 TOOLTIP_SUPPORT=
3413 WINDOW_SUPPORT=
3414 ## If we're using X11/GNUstep, define some consequences.
3415 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3416   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3417   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3418   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3419   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3420
3421   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3422   test "$HAVE_X_WINDOWS" = "yes" && \
3423     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3424
3425 fi
3426 AC_SUBST(MOUSE_SUPPORT)
3427 AC_SUBST(TOOLTIP_SUPPORT)
3428 AC_SUBST(WINDOW_SUPPORT)
3429
3430
3431 AH_TOP([/* GNU Emacs site configuration template file.
3432    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3433      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3434
3435 This file is part of GNU Emacs.
3436
3437 GNU Emacs is free software: you can redistribute it and/or modify
3438 it under the terms of the GNU General Public License as published by
3439 the Free Software Foundation, either version 3 of the License, or
3440 (at your option) any later version.
3441
3442 GNU Emacs is distributed in the hope that it will be useful,
3443 but WITHOUT ANY WARRANTY; without even the implied warranty of
3444 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3445 GNU General Public License for more details.
3446
3447 You should have received a copy of the GNU General Public License
3448 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3449
3450
3451 /* No code in Emacs #includes config.h twice, but some bits of code
3452    intended to work with other packages as well (like gmalloc.c)
3453    think they can include it as many times as they like.  */
3454 #ifndef EMACS_CONFIG_H
3455 #define EMACS_CONFIG_H
3456 ])dnl
3457
3458 AH_BOTTOM([
3459 /* Define AMPERSAND_FULL_NAME if you use the convention
3460    that & in the full name stands for the login id.  */
3461 /* Turned on June 1996 supposing nobody will mind it.  */
3462 #define AMPERSAND_FULL_NAME
3463
3464 /* If using GNU, then support inline function declarations.  */
3465 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3466    generally, because even if non-gcc compilers accept `inline', they
3467    may reject `extern inline'.  */
3468 #if defined (__GNUC__) && defined (OPTIMIZE)
3469 #define INLINE __inline__
3470 #else
3471 #define INLINE
3472 #endif
3473
3474 /* `subprocesses' should be defined if you want to
3475    have code for asynchronous subprocesses
3476    (as used in M-x compile and M-x shell).
3477    Only MSDOS does not support this (it overrides
3478    this in its config_opsysfile below).  */
3479
3480 #define subprocesses
3481
3482 /* Include the os and machine dependent files.  */
3483 #include config_opsysfile
3484 #include config_machfile
3485
3486 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3487   (There is probably a better place to do this, but right now the Cocoa
3488    side does this in s/darwin.h and we cannot
3489    parallel this exactly since GNUstep is multi-OS.  */
3490 #ifdef HAVE_NS
3491 # ifdef NS_IMPL_GNUSTEP
3492 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3493 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3494 #  define SYSTEM_PURESIZE_EXTRA 30000
3495 # endif /* NS_IMPL_GNUSTEP */
3496 #endif /* HAVE_NS */
3497
3498 /* SIGTYPE is the macro we actually use.  */
3499 #ifndef SIGTYPE
3500 #define SIGTYPE RETSIGTYPE
3501 #endif
3502
3503 #ifdef emacs /* Don't do this for lib-src.  */
3504 /* Tell regex.c to use a type compatible with Emacs.  */
3505 #define RE_TRANSLATE_TYPE Lisp_Object
3506 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3507 #ifdef make_number
3508 /* If make_number is a macro, use it.  */
3509 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3510 #else
3511 /* If make_number is a function, avoid it.  */
3512 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3513 #endif
3514 #endif
3515
3516 /* Avoid link-time collision with system mktime if we will use our own.  */
3517 #if ! HAVE_MKTIME || BROKEN_MKTIME
3518 #define mktime emacs_mktime
3519 #endif
3520
3521 #define my_strftime nstrftime   /* for strftime.c */
3522
3523 /* These default definitions are good for almost all machines.
3524    The exceptions override them in m/MACHINE.h.  */
3525
3526 #ifndef BITS_PER_CHAR
3527 #define BITS_PER_CHAR 8
3528 #endif
3529
3530 #ifndef BITS_PER_SHORT
3531 #define BITS_PER_SHORT 16
3532 #endif
3533
3534 /* Note that lisp.h uses this in a preprocessor conditional, so it
3535    would not work to use sizeof.  That being so, we do all of them
3536    without sizeof, for uniformity's sake.  */
3537 #ifndef BITS_PER_INT
3538 #define BITS_PER_INT 32
3539 #endif
3540
3541 #ifndef BITS_PER_LONG
3542 #ifdef _LP64
3543 #define BITS_PER_LONG 64
3544 #else
3545 #define BITS_PER_LONG 32
3546 #endif
3547 #endif
3548
3549 /* Define if the compiler supports function prototypes.  It may do so but
3550    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3551 #undef PROTOTYPES
3552
3553 #ifdef HAVE_STRING_H
3554 #include <string.h>
3555 #endif
3556
3557 #ifdef HAVE_STDLIB_H
3558 #include <stdlib.h>
3559 #endif
3560
3561 #ifdef HAVE_ALLOCA_H
3562 # include <alloca.h>
3563 #elif defined __GNUC__
3564 # define alloca __builtin_alloca
3565 #elif defined _AIX
3566 # define alloca __alloca
3567 #else
3568 # include <stddef.h>
3569 # ifdef  __cplusplus
3570 extern "C"
3571 # endif
3572 void *alloca (size_t);
3573 #endif
3574
3575 #ifndef HAVE_SIZE_T
3576 typedef unsigned size_t;
3577 #endif
3578
3579 #ifndef HAVE_STRCHR
3580 #define strchr(a, b) index (a, b)
3581 #endif
3582
3583 #ifndef HAVE_STRRCHR
3584 #define strrchr(a, b) rindex (a, b)
3585 #endif
3586
3587 #if defined __GNUC__ && (__GNUC__ > 2 \
3588                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3589 #define NO_RETURN       __attribute__ ((__noreturn__))
3590 #else
3591 #define NO_RETURN       /* nothing */
3592 #endif
3593
3594 /* These won't be used automatically yet.  We also need to know, at least,
3595    that the stack is continuous.  */
3596 #ifdef __GNUC__
3597 #  ifndef GC_SETJMP_WORKS
3598   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3599 #    define GC_SETJMP_WORKS 1
3600 #  endif
3601 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3602 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3603 #  endif
3604 #endif
3605
3606 #endif /* EMACS_CONFIG_H */
3607
3608 /*
3609 Local Variables:
3610 mode: c
3611 End:
3612 */
3613 ])dnl
3614
3615 #### Report on what we decided to do.
3616 #### Report GTK as a toolkit, even if it doesn't use Xt.
3617 #### It makes printing result more understandable as using GTK sets
3618 #### toolkit_scroll_bars to yes by default.
3619 if test "${HAVE_GTK}" = "yes"; then
3620   USE_X_TOOLKIT=GTK
3621 fi
3622
3623 echo "
3624 Configured for \`${canonical}'.
3625
3626   Where should the build process find the source code?    ${srcdir}
3627   What operating system and machine description files should Emacs use?
3628         \`${opsysfile}' and \`${machfile}'
3629   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3630   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3631   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3632   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3633   What window system should Emacs use?                    ${window_system}
3634   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3635
3636 if test -n "${x_includes}"; then
3637 echo "  Where do we find X Windows header files?                ${x_includes}"
3638 else
3639 echo "  Where do we find X Windows header files?                Standard dirs"
3640 fi
3641 if test -n "${x_libraries}"; then
3642 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3643 else
3644 echo "  Where do we find X Windows libraries?                   Standard dirs"
3645 fi
3646
3647 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3648 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3649 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3650 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3651 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3652 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3653 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3654 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3655 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3656 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3657 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3658
3659 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3660 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3661 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3662 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3663
3664 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3665 echo
3666
3667 if test $USE_XASSERTS = yes; then
3668    echo "  Compiling with asserts turned on."
3669    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3670 fi
3671
3672 echo
3673
3674 if test "$HAVE_NS" = "yes"; then
3675    echo
3676    echo "You must run \"make install\" in order to test the built application.
3677 The installed application will go to nextstep/Emacs.app and can be
3678 run or moved from there."
3679    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3680       echo "The application will be fully self-contained."
3681     else
3682       echo "The lisp resources for the application will be installed under ${prefix}.
3683 You may need to run \"make install\" with sudo.  The application will fail
3684 to run if these resources are not installed."
3685    fi
3686    echo
3687 fi
3688
3689 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3690   echo "D-Bus integration has been tested for GNU/Linux only."
3691   echo
3692 fi
3693
3694
3695 # Remove any trailing slashes in these variables.
3696 [test "${prefix}" != NONE &&
3697   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3698 test "${exec_prefix}" != NONE &&
3699   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3700
3701 dnl You might wonder (I did) why epaths.h is generated by running make,
3702 dnl rather than just letting configure generate it from epaths.in.
3703 dnl One reason is that the various paths are not fully expanded (see above);
3704 dnl eg gamedir=${prefix}/var/games/emacs.
3705 dnl Secondly, the GNU Coding standards require that one should be able
3706 dnl to run `make prefix=/some/where/else' and override the values set
3707 dnl by configure.  This also explains the `move-if-change' test and
3708 dnl the use of force in the `epaths-force' rule in Makefile.in.
3709 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3710         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3711         doc/lispref/Makefile src/Makefile \
3712         lwlib/Makefile lisp/Makefile leim/Makefile, [
3713
3714 ### Make the necessary directories, if they don't exist.
3715 for dir in etc lisp ; do
3716   test -d ${dir} || mkdir ${dir}
3717 done
3718
3719 echo creating src/epaths.h
3720 ${MAKE-make} epaths-force
3721
3722 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3723   echo creating src/.gdbinit
3724   echo source $srcdir/src/.gdbinit > src/.gdbinit
3725 fi
3726
3727 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3728
3729 m4_if(dnl       Do not change this comment
3730    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3731 )dnl