lisp/url/url.el

   1 ;;; url.el --- Uniform Resource Locator retrieval tool
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004,
   4 ;;   2005, 2006, 2007  Free Software Foundation, Inc.
   5
   6 ;; Author: Bill Perry <wmperry@gnu.org>
   7 ;; Keywords: comm, data, processes, hypermedia
   8
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Registered URI schemes: http://www.iana.org/assignments/uri-schemes
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (eval-when-compile
  35   (require 'mm-decode)
  36   (require 'mm-view))
  37
  38 (require 'mailcap)
  39 (require 'url-vars)
  40 (require 'url-cookie)
  41 (require 'url-history)
  42 (require 'url-expand)
  43 (require 'url-privacy)
  44 (require 'url-methods)
  45 (require 'url-proxy)
  46 (require 'url-parse)
  47 (require 'url-util)
  48
  49 ;; Fixme: customize? convert-standard-filename?
  50 (defvar url-configuration-directory
  51   (cond
  52    ((file-directory-p "~/.url") "~/.url")
  53    ((file-directory-p user-emacs-directory)
  54     (concat user-emacs-directory "url"))
  55    (t "~/.url")))
  56
  57 (defun url-do-setup ()
  58   "Setup the url package.
  59 This is to avoid conflict with user settings if URL is dumped with
  60 Emacs."
  61   (unless url-setup-done
  62
  63     ;; Make OS/2 happy
  64     ;;(push '("http" "80") tcp-binary-process-input-services)
  65
  66     (mailcap-parse-mailcaps)
  67     (mailcap-parse-mimetypes)
  68
  69     ;; Register all the authentication schemes we can handle
  70     (url-register-auth-scheme "basic" nil 4)
  71     (url-register-auth-scheme "digest" nil 7)
  72
  73     (setq url-cookie-file
  74           (or url-cookie-file
  75               (expand-file-name "cookies" url-configuration-directory)))
  76
  77     (setq url-history-file
  78           (or url-history-file
  79               (expand-file-name "history" url-configuration-directory)))
  80
  81     ;; Parse the global history file if it exists, so that it can be used
  82     ;; for URL completion, etc.
  83     (url-history-parse-history)
  84     (url-history-setup-save-timer)
  85
  86     ;; Ditto for cookies
  87     (url-cookie-setup-save-timer)
  88     (url-cookie-parse-file url-cookie-file)
  89
  90     ;; Read in proxy gateways
  91     (let ((noproxy (and (not (assoc "no_proxy" url-proxy-services))
  92                         (or (getenv "NO_PROXY")
  93                             (getenv "no_PROXY")
  94                             (getenv "no_proxy")))))
  95       (if noproxy
  96           (setq url-proxy-services
  97                 (cons (cons "no_proxy"
  98                             (concat "\\("
  99                                     (mapconcat
 100                                      (lambda (x)
 101                                        (cond
 102                                         ((= x ?,) "\\|")
 103                                         ((= x ? ) "")
 104                                         ((= x ?.) (regexp-quote "."))
 105                                         ((= x ?*) ".*")
 106                                         ((= x ??) ".")
 107                                         (t (char-to-string x))))
 108                                      noproxy "") "\\)"))
 109                       url-proxy-services))))
 110
 111     (url-setup-privacy-info)
 112     (run-hooks 'url-load-hook)
 113     (setq url-setup-done t)))
 114
 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 116 ;;; Retrieval functions
 117 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 118
 119 (defvar url-redirect-buffer nil
 120   "New buffer into which the retrieval will take place.
 121 Sometimes while retrieving a URL, the URL library needs to use another buffer
 122 than the one returned initially by `url-retrieve'.  In this case, it sets this
 123 variable in the original buffer as a forwarding pointer.")
 124
 125 ;;;###autoload
 126 (defun url-retrieve (url callback &optional cbargs)
 127   "Retrieve URL asynchronously and call CALLBACK with CBARGS when finished.
 128 URL is either a string or a parsed URL.
 129
 130 CALLBACK is called when the object has been completely retrieved, with
 131 the current buffer containing the object, and any MIME headers associated
 132 with it.  It is called as (apply CALLBACK STATUS CBARGS).
 133 STATUS is a list with an even number of elements representing
 134 what happened during the request, with most recent events first,
 135 or an empty list if no events have occurred.  Each pair is one of:
 136
 137 \(:redirect REDIRECTED-TO) - the request was redirected to this URL
 138 \(:error (ERROR-SYMBOL . DATA)) - an error occurred.  The error can be
 139 signaled with (signal ERROR-SYMBOL DATA).
 140
 141 Return the buffer URL will load into, or nil if the process has
 142 already completed (i.e. URL was a mailto URL or similar; in this case
 143 the callback is not called).
 144
 145 The variables `url-request-data', `url-request-method' and
 146 `url-request-extra-headers' can be dynamically bound around the
 147 request; dynamic binding of other variables doesn't necessarily
 148 take effect."
 149 ;;; XXX: There is code in Emacs that does dynamic binding
 150 ;;; of the following variables around url-retrieve:
 151 ;;; url-standalone-mode, url-gateway-unplugged, w3-honor-stylesheets,
 152 ;;; url-confirmation-func, url-cookie-multiple-line,
 153 ;;; url-cookie-{{,secure-}storage,confirmation}
 154 ;;; url-standalone-mode and url-gateway-unplugged should work as
 155 ;;; usual.  url-confirmation-func is only used in nnwarchive.el and
 156 ;;; webmail.el; the latter should be updated.  Is
 157 ;;; url-cookie-multiple-line needed anymore?  The other url-cookie-*
 158 ;;; are (for now) only used in synchronous retrievals.
 159   (url-retrieve-internal url callback (cons nil cbargs)))
 160
 161 (defun url-retrieve-internal (url callback cbargs)
 162   "Internal function; external interface is `url-retrieve'.
 163 CBARGS is what the callback will actually receive - the first item is
 164 the list of events, as described in the docstring of `url-retrieve'."
 165   (url-do-setup)
 166   (url-gc-dead-buffers)
 167   (if (stringp url)
 168        (set-text-properties 0 (length url) nil url))
 169   (if (not (vectorp url))
 170       (setq url (url-generic-parse-url url)))
 171   (if (not (functionp callback))
 172       (error "Must provide a callback function to url-retrieve"))
 173   (unless (url-type url)
 174     (error "Bad url: %s" (url-recreate-url url)))
 175   (let ((loader (url-scheme-get-property (url-type url) 'loader))
 176         (url-using-proxy (if (url-host url)
 177                              (url-find-proxy-for-url url (url-host url))))
 178         (buffer nil)
 179         (asynch (url-scheme-get-property (url-type url) 'asynchronous-p)))
 180     (if url-using-proxy
 181         (setq asynch t
 182               loader 'url-proxy))
 183     (if asynch
 184         (setq buffer (funcall loader url callback cbargs))
 185       (setq buffer (funcall loader url))
 186       (if buffer
 187           (with-current-buffer buffer
 188             (apply callback cbargs))))
 189     (if url-history-track
 190         (url-history-update-url url (current-time)))
 191     buffer))
 192
 193 ;;;###autoload
 194 (defun url-retrieve-synchronously (url)
 195   "Retrieve URL synchronously.
 196 Return the buffer containing the data, or nil if there are no data
 197 associated with it (the case for dired, info, or mailto URLs that need
 198 no further processing).  URL is either a string or a parsed URL."
 199   (url-do-setup)
 200
 201   (lexical-let ((retrieval-done nil)
 202                 (asynch-buffer nil))
 203     (setq asynch-buffer
 204           (url-retrieve url (lambda (&rest ignored)
 205                               (url-debug 'retrieval "Synchronous fetching done (%S)" (current-buffer))
 206                               (setq retrieval-done t
 207                                     asynch-buffer (current-buffer)))))
 208     (if (null asynch-buffer)
 209         ;; We do not need to do anything, it was a mailto or something
 210         ;; similar that takes processing completely outside of the URL
 211         ;; package.
 212         nil
 213       (let ((proc (get-buffer-process asynch-buffer)))
 214         ;; If the access method was synchronous, `retrieval-done' should
 215         ;; hopefully already be set to t.  If it is nil, and `proc' is also
 216         ;; nil, it implies that the async process is not running in
 217         ;; asynch-buffer.  This happens e.g. for FTP files.  In such a case
 218         ;; url-file.el should probably set something like a `url-process'
 219         ;; buffer-local variable so we can find the exact process that we
 220         ;; should be waiting for.  In the mean time, we'll just wait for any
 221         ;; process output.
 222         (while (not retrieval-done)
 223           (url-debug 'retrieval
 224                      "Spinning in url-retrieve-synchronously: %S (%S)"
 225                      retrieval-done asynch-buffer)
 226           (if (buffer-local-value 'url-redirect-buffer asynch-buffer)
 227               (setq proc (get-buffer-process
 228                           (setq asynch-buffer
 229                                 (buffer-local-value 'url-redirect-buffer
 230                                                     asynch-buffer))))
 231             (if (and proc (memq (process-status proc)
 232                                 '(closed exit signal failed))
 233                      ;; Make sure another process hasn't been started.
 234                      (eq proc (or (get-buffer-process asynch-buffer) proc)))
 235                 ;; FIXME: It's not clear whether url-retrieve's callback is
 236                 ;; guaranteed to be called or not.  It seems that url-http
 237                 ;; decides sometimes consciously not to call it, so it's not
 238                 ;; clear that it's a bug, but even then we need to decide how
 239                 ;; url-http can then warn us that the download has completed.
 240                 ;; In the mean time, we use this here workaround.
 241                 ;; XXX: The callback must always be called.  Any
 242                 ;; exception is a bug that should be fixed, not worked
 243                 ;; around.
 244                 (setq retrieval-done t))
 245             ;; We used to use `sit-for' here, but in some cases it wouldn't
 246             ;; work because apparently pending keyboard input would always
 247             ;; interrupt it before it got a chance to handle process input.
 248             ;; `sleep-for' was tried but it lead to other forms of
 249             ;; hanging.  --Stef
 250             (unless (or (with-local-quit
 251                           (accept-process-output proc))
 252                         (null proc))
 253               ;; accept-process-output returned nil, maybe because the process
 254               ;; exited (and may have been replaced with another).  If we got
 255               ;; a quit, just stop.
 256               (when quit-flag
 257                 (delete-process proc))
 258               (setq proc (and (not quit-flag)
 259                               (get-buffer-process asynch-buffer)))))))
 260       asynch-buffer)))
 261
 262 (defun url-mm-callback (&rest ignored)
 263   (let ((handle (mm-dissect-buffer t)))
 264     (url-mark-buffer-as-dead (current-buffer))
 265     (with-current-buffer
 266         (generate-new-buffer (url-recreate-url url-current-object))
 267       (if (eq (mm-display-part handle) 'external)
 268           (progn
 269             (set-process-sentinel
 270              ;; Fixme: this shouldn't have to know the form of the
 271              ;; undisplayer produced by `mm-display-part'.
 272              (get-buffer-process (cdr (mm-handle-undisplayer handle)))
 273              `(lambda (proc event)
 274                 (mm-destroy-parts (quote ,handle))))
 275             (message "Viewing externally")
 276             (kill-buffer (current-buffer)))
 277         (display-buffer (current-buffer))
 278         (add-hook 'kill-buffer-hook
 279                   `(lambda () (mm-destroy-parts ',handle))
 280                   nil
 281                   t)))))
 282
 283 (defun url-mm-url (url)
 284   "Retrieve URL and pass to the appropriate viewing application."
 285   ;; These requires could advantageously be moved to url-mm-callback or
 286   ;; turned into autoloads, but I suspect that it would introduce some bugs
 287   ;; because loading those files from a process sentinel or filter may
 288   ;; result in some undesirable carner cases.
 289   (require 'mm-decode)
 290   (require 'mm-view)
 291   (url-retrieve url 'url-mm-callback nil))
 292
 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 294 ;;; Miscellaneous
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 (defvar url-dead-buffer-list nil)
 297
 298 (defun url-mark-buffer-as-dead (buff)
 299   (push buff url-dead-buffer-list))
 300
 301 (defun url-gc-dead-buffers ()
 302   (let ((buff))
 303     (while (setq buff (pop url-dead-buffer-list))
 304       (if (buffer-live-p buff)
 305           (kill-buffer buff)))))
 306
 307 (cond
 308  ((fboundp 'display-warning)
 309   (defalias 'url-warn 'display-warning))
 310  ((fboundp 'warn)
 311   (defun url-warn (class message &optional level)
 312     (warn "(%s/%s) %s" class (or level 'warning) message)))
 313  (t
 314   (defun url-warn (class message &optional level)
 315     (with-current-buffer (get-buffer-create "*URL-WARNINGS*")
 316       (goto-char (point-max))
 317       (save-excursion
 318         (insert (format "(%s/%s) %s\n" class (or level 'warning) message)))
 319       (display-buffer (current-buffer))))))
 320
 321 (provide 'url)
 322
 323 ;; arch-tag: bc182f1f-d187-4f10-b961-47af2066579a
 324 ;;; url.el ends here