configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 23.1.96)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(ns-self-contained,
 180 [AS_HELP_STRING([--disable-ns-self-contained],
 181                 [disable self contained build under NeXTstep])],
 182    EN_NS_SELF_CONTAINED=$enableval,
 183    EN_NS_SELF_CONTAINED=yes)
 184
 185 AC_ARG_ENABLE(asserts,
 186 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 187       USE_XASSERTS=$enableval,
 188       USE_XASSERTS=no)
 189
 190 AC_ARG_ENABLE(maintainer-mode,
 191 [AS_HELP_STRING([--enable-maintainer-mode],
 192                 [enable make rules and dependencies not useful (and sometimes
 193                  confusing) to the casual installer])],
 194       USE_MAINTAINER_MODE=$enableval,
 195       USE_MAINTAINER_MODE=no)
 196 if test $USE_MAINTAINER_MODE = yes; then
 197   MAINT=
 198 else
 199   MAINT=#
 200 fi
 201 AC_SUBST(MAINT)
 202
 203 AC_ARG_ENABLE(locallisppath,
 204 [AS_HELP_STRING([--enable-locallisppath=PATH],
 205                 [directories Emacs should search for lisp files specific
 206                  to this site])],
 207 if test "${enableval}" = "no"; then
 208   locallisppath=
 209 elif test "${enableval}" != "yes"; then
 210   locallisppath=${enableval}
 211 fi)
 212
 213 AC_ARG_ENABLE(checking,
 214 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 215                 [enable expensive run-time checks.  With LIST,
 216                  enable only specific categories of checks.
 217                  Categories are: all,yes,no.
 218                  Flags are: stringbytes, stringoverrun, stringfreelist,
 219                  xmallocoverrun, conslist])],
 220 [ac_checking_flags="${enableval}"],[])
 221 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 222 for check in $ac_checking_flags
 223 do
 224         case $check in
 225         # these set all the flags to specific states
 226         yes)            ac_enable_checking=1 ;;
 227         no)             ac_enable_checking= ;
 228                         ac_gc_check_stringbytes= ;
 229                         ac_gc_check_string_overrun= ;
 230                         ac_gc_check_string_free_list= ;
 231                         ac_xmalloc_overrun= ;
 232                         ac_gc_check_cons_list= ;;
 233         all)            ac_enable_checking=1 ;
 234                         ac_gc_check_stringbytes=1 ;
 235                         ac_gc_check_string_overrun=1 ;
 236                         ac_gc_check_string_free_list=1 ;
 237                         ac_xmalloc_overrun=1 ;
 238                         ac_gc_check_cons_list=1 ;;
 239         # these enable particular checks
 240         stringbytes)    ac_gc_check_stringbytes=1 ;;
 241         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 242         stringfreelist) ac_gc_check_string_free_list=1 ;;
 243         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 244         conslist)       ac_gc_check_cons_list=1 ;;
 245         *)      AC_MSG_ERROR(unknown check category $check) ;;
 246         esac
 247 done
 248 IFS="$ac_save_IFS"
 249
 250 if test x$ac_enable_checking != x ; then
 251   AC_DEFINE(ENABLE_CHECKING, 1,
 252 [Enable expensive run-time checking of data types?])
 253 fi
 254 if test x$ac_gc_check_stringbytes != x ; then
 255   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 256 [Define this temporarily to hunt a bug.  If defined, the size of
 257    strings is redundantly recorded in sdata structures so that it can
 258    be compared to the sizes recorded in Lisp strings.])
 259 fi
 260 if test x$ac_gc_check_stringoverrun != x ; then
 261   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 262 [Define this to check for short string overrun.])
 263 fi
 264 if test x$ac_gc_check_string_free_list != x ; then
 265   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 266 [Define this to check the string free list.])
 267 fi
 268 if test x$ac_xmalloc_overrun != x ; then
 269   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 270 [Define this to check for malloc buffer overrun.])
 271 fi
 272 if test x$ac_gc_check_cons_list != x ; then
 273   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 274 [Define this to check for errors in cons list.])
 275 fi
 276
 277 AC_ARG_ENABLE(profiling,
 278 [AS_HELP_STRING([--enable-profiling],
 279                 [build emacs with profiling support.
 280                  This might not work on all platforms])],
 281 [ac_enable_profiling="${enableval}"],[])
 282 if test x$ac_enable_profiling != x ; then
 283    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 284    PROFILING_LDFLAGS="-pg"
 285 else
 286    PROFILING_CFLAGS=
 287    PROFILING_LDFLAGS=
 288 fi
 289
 290 AC_ARG_ENABLE(autodepend,
 291 [AS_HELP_STRING([--enable-autodepend],
 292                 [automatically generate dependencies to .h-files.
 293                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 294                  found])],
 295 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 296
 297 #### Make srcdir absolute, if it isn't already.  It's important to
 298 #### avoid running the path through pwd unnecessarily, since pwd can
 299 #### give you automounter prefixes, which can go away.  We do all this
 300 #### so Emacs can find its files when run uninstalled.
 301 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 302 unset CDPATH
 303 case "${srcdir}" in
 304   /* ) ;;
 305   . )
 306     ## We may be able to use the $PWD environment variable to make this
 307     ## absolute.  But sometimes PWD is inaccurate.
 308     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 309     ## but that tested only for a well-formed and valid PWD,
 310     ## it did not object when PWD was well-formed and valid but just wrong.
 311     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 312     then
 313       srcdir="$PWD"
 314     else
 315       srcdir="`(cd ${srcdir}; pwd)`"
 316     fi
 317   ;;
 318   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 319 esac
 320
 321 #### Check if the source directory already has a configured system in it.
 322 if test `pwd` != `(cd ${srcdir} && pwd)` \
 323    && test -f "${srcdir}/src/config.h" ; then
 324   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 325    as a build directory right now; it has been configured in its own
 326    right.  To configure in another directory as well, you MUST
 327    use GNU make.  If you do not have GNU make, then you must
 328    now do `make distclean' in ${srcdir},
 329    and then run $0 again.]])
 330 fi
 331
 332 #### Given the configuration name, set machfile and opsysfile to the
 333 #### names of the m/*.h and s/*.h files we should use.
 334
 335 ### Canonicalize the configuration name.
 336
 337 AC_CANONICAL_HOST
 338 canonical=$host
 339 configuration=${host_alias-${build_alias-$host}}
 340
 341 dnl This used to use changequote, but, apart from `changequote is evil'
 342 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 343 dnl the great gob of text.  Thus it's not processed for possible expansion.
 344 dnl Just make sure the brackets remain balanced.
 345 dnl
 346 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 347 dnl indicated by comments.
 348 dnl quotation begins
 349 [
 350
 351 ### If you add support for a new configuration, add code to this
 352 ### switch statement to recognize your configuration name and select
 353 ### the appropriate operating system and machine description files.
 354
 355 ### You would hope that you could choose an m/*.h file pretty much
 356 ### based on the machine portion of the configuration name, and an s-
 357 ### file based on the operating system portion.  However, it turns out
 358 ### that each m/*.h file is pretty manufacturer-specific - for
 359 ### example mips.h is MIPS
 360 ### So we basically have to have a special case for each
 361 ### configuration name.
 362 ###
 363 ### As far as handling version numbers on operating systems is
 364 ### concerned, make sure things will fail in a fixable way.  If
 365 ### /etc/MACHINES doesn't say anything about version numbers, be
 366 ### prepared to handle anything reasonably.  If version numbers
 367 ### matter, be sure /etc/MACHINES says something about it.
 368 ###
 369 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 370 ### "System V Release 4"; he writes, "The old convention encouraged
 371 ### confusion between `system' and `release' levels'."
 372
 373 machine='' opsys='' unported=no
 374 case "${canonical}" in
 375
 376   ## FreeBSD ports
 377   *-*-freebsd* )
 378     opsys=freebsd
 379     case "${canonical}" in
 380       alpha*-*-freebsd*)        machine=alpha ;;
 381       arm*-*-freebsd*)          machine=arm ;;
 382       ia64-*-freebsd*)          machine=ia64 ;;
 383       sparc-*-freebsd*)         machine=sparc ;;
 384       sparc64-*-freebsd*)       machine=sparc ;;
 385       powerpc-*-freebsd*)       machine=macppc ;;
 386       i[3456]86-*-freebsd*)     machine=intel386 ;;
 387       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 388     esac
 389   ;;
 390
 391   ## FreeBSD kernel + glibc based userland
 392   *-*-kfreebsd*gnu* )
 393     opsys=gnu-kfreebsd
 394     case "${canonical}" in
 395       alpha*-*-kfreebsd*)       machine=alpha ;;
 396       ia64-*-kfreebsd*)         machine=ia64 ;;
 397       sparc-*-kfreebsd*)        machine=sparc ;;
 398       sparc64-*-kfreebsd*)      machine=sparc ;;
 399       powerpc-*-kfreebsd*)      machine=macppc ;;
 400       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 401       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 402     esac
 403   ;;
 404
 405   ## NetBSD ports
 406   *-*-netbsd* )
 407     opsys=netbsd
 408     if test -f /usr/lib/crti.o; then]
 409 dnl The close and open brackets here are because this section is quoted --
 410 dnl see the `changequote' comment above.
 411       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 412 [   fi
 413
 414     case "${canonical}" in
 415       alpha*-*-netbsd*) machine=alpha ;;
 416       i[3456]86-*-netbsd*) machine=intel386 ;;
 417       mips-*-netbsd*)   machine=mips ;;
 418       mipsel-*-netbsd*) machine=mips ;;
 419       mipseb-*-netbsd*) machine=mips ;;
 420       powerpc-*-netbsd*) machine=macppc ;;
 421       sparc*-*-netbsd*) machine=sparc ;;
 422       vax-*-netbsd*)    machine=vax ;;
 423       arm-*-netbsd*)    machine=arm ;;
 424       x86_64-*-netbsd*) machine=amdx86-64 ;;
 425       hppa-*-netbsd*)   machine=hp800 ;;
 426       m68k-*-netbsd*)   machine=m68k ;;
 427     esac
 428   ;;
 429
 430   ## OpenBSD ports
 431   *-*-openbsd* )
 432     opsys=openbsd
 433     case "${canonical}" in
 434       alpha*-*-openbsd*)        machine=alpha ;;
 435       arm-*-openbsd*)          machine=arm ;;
 436       i386-*-openbsd*)         machine=intel386 ;;
 437       powerpc-*-openbsd*)      machine=macppc ;;
 438       sparc*-*-openbsd*)       machine=sparc ;;
 439       vax-*-openbsd*)          machine=vax ;;
 440       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 441       hppa-*-openbsd*)         machine=hp800 ;;
 442     esac
 443   ;;
 444
 445   ## LynxOS ports
 446   *-*-lynxos* )
 447     opsys=lynxos
 448     case "${canonical}" in
 449       i[3456]86-*-lynxos*) machine=intel386 ;;
 450       powerpc-*-lynxos*) machine=powerpc ;;
 451     esac
 452   ;;
 453
 454   alpha*-*-linux-gnu* )
 455     machine=alpha opsys=gnu-linux
 456   ;;
 457
 458   arm*-*-linux-gnu* )
 459     machine=arm opsys=gnu-linux
 460   ;;
 461
 462   ## Apple Darwin / Mac OS X
 463   *-apple-darwin* )
 464     case "${canonical}" in
 465       i[3456]86-* )  machine=intel386 ;;
 466       powerpc-* )    machine=macppc ;;
 467       x86_64-* )     machine=amdx86-64 ;;
 468       * )            unported=yes ;;
 469     esac
 470     opsys=darwin
 471     # Define CPP as follows to make autoconf work correctly.
 472     CPP="${CC-cc} -E -no-cpp-precomp"
 473     # Use fink packages if available.
 474     if test -d /sw/include && test -d /sw/lib; then
 475       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 476       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 477       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 478     fi
 479   ;;
 480
 481   ## HP 9000 series 700 and 800, running HP/UX
 482   hppa*-hp-hpux10.2* )
 483     machine=hp800 opsys=hpux10-20
 484   ;;
 485   hppa*-hp-hpux1[1-9]* )
 486     machine=hp800 opsys=hpux11
 487     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 488   ;;
 489
 490   hppa*-*-linux-gnu* )
 491     machine=hp800 opsys=gnu-linux
 492   ;;
 493
 494   ## IBM machines
 495   s390-*-linux-gnu* )
 496     machine=ibms390 opsys=gnu-linux
 497   ;;
 498   s390x-*-linux-gnu* )
 499     machine=ibms390x opsys=gnu-linux
 500   ;;
 501   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 502     machine=ibmrs6000 opsys=aix4-2
 503   ;;
 504   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 505     machine=ibmrs6000 opsys=aix4-2
 506   ;;
 507   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 508     machine=ibmrs6000 opsys=aix4-2
 509   ;;
 510   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513
 514   ## Macintosh PowerPC
 515   powerpc*-*-linux-gnu* )
 516     machine=macppc opsys=gnu-linux
 517   ;;
 518
 519   ## Silicon Graphics machines
 520   ## Iris 4D
 521   mips-sgi-irix6.5 )
 522     machine=iris4d opsys=irix6-5
 523     # Without defining _LANGUAGE_C, things get masked out in the headers
 524     # so that, for instance, grepping for `free' in stdlib.h fails and
 525     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 526     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 527     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 528   ;;
 529
 530   ## Suns
 531   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 532     machine=sparc opsys=gnu-linux
 533   ;;
 534
 535   *-sun-solaris* \
 536     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 537     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 538     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 539     case "${canonical}" in
 540       i[3456]86-*-* )     machine=intel386 ;;
 541       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 542       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 543       sparc* )          machine=sparc ;;
 544       * )               unported=yes ;;
 545     esac
 546     case "${canonical}" in
 547       *-sunos5.3* | *-solaris2.3* )
 548                 opsys=sol2-3
 549                 NON_GNU_CPP=/usr/ccs/lib/cpp
 550                 ;;
 551       *-sunos5.4* | *-solaris2.4* )
 552                 opsys=sol2-4
 553                 NON_GNU_CPP=/usr/ccs/lib/cpp
 554                 RANLIB="ar -ts"
 555                 ;;
 556       *-sunos5.5* | *-solaris2.5* )
 557                 opsys=sol2-5
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 RANLIB="ar -ts"
 560                 ;;
 561       *-sunos5.6* | *-solaris2.6* )
 562                 opsys=sol2-6
 563                 NON_GNU_CPP=/usr/ccs/lib/cpp
 564                 RANLIB="ar -ts"
 565                 ;;
 566       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 567                 opsys=sol2-6
 568                 emacs_check_sunpro_c=yes
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 ;;
 571       *-sunos5* | *-solaris* )
 572                 opsys=sol2-10
 573                 emacs_check_sunpro_c=yes
 574                 NON_GNU_CPP=/usr/ccs/lib/cpp
 575                 ;;
 576     esac
 577     ## Watch out for a compiler that we know will not work.
 578     case "${canonical}" in
 579      *-solaris* | *-sunos5* )
 580                 if [ "x$CC" = x/usr/ucb/cc ]; then
 581                   ## /usr/ucb/cc doesn't work;
 582                   ## we should find some other compiler that does work.
 583                   unset CC
 584                 fi
 585                 ;;
 586       *) ;;
 587     esac
 588   ;;
 589
 590   ## IA-64
 591   ia64*-*-linux* )
 592     machine=ia64 opsys=gnu-linux
 593   ;;
 594
 595   ## Intel 386 machines where we don't care about the manufacturer
 596   i[3456]86-*-* )
 597     machine=intel386
 598     case "${canonical}" in
 599       *-cygwin )                opsys=cygwin ;;
 600       *-darwin* )               opsys=darwin
 601                                 CPP="${CC-cc} -E -no-cpp-precomp"
 602                                 ;;
 603       *-linux-gnu* )            opsys=gnu-linux ;;
 604       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 606       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 607       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 608     esac
 609   ;;
 610
 611   ## m68k Linux-based GNU system
 612   m68k-*-linux-gnu* )
 613     machine=m68k opsys=gnu-linux
 614   ;;
 615
 616   ## Mips Linux-based GNU system
 617   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 618     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 619     machine=mips opsys=gnu-linux
 620   ;;
 621
 622   ## AMD x86-64 Linux-based GNU system
 623   x86_64-*-linux-gnu* )
 624     machine=amdx86-64 opsys=gnu-linux
 625   ;;
 626
 627   ## Tensilica Xtensa Linux-based GNU system
 628   xtensa*-*-linux-gnu* )
 629     machine=xtensa opsys=gnu-linux
 630     ;;
 631
 632   ## SuperH Linux-based GNU system
 633   sh[34]*-*-linux-gnu* )
 634     machine=sh3 opsys=gnu-linux
 635   ;;
 636
 637   * )
 638     unported=yes
 639   ;;
 640 esac
 641
 642 ### If the code above didn't choose an operating system, just choose
 643 ### an operating system based on the configuration name.  You really
 644 ### only want to use this when you have no idea what the right
 645 ### operating system is; if you know what operating systems a machine
 646 ### runs, it's cleaner to make it explicit in the case statement
 647 ### above.
 648 if test x"${opsys}" = x; then
 649   case "${canonical}" in
 650     *-gnu* )                            opsys=gnu ;;
 651     *-sysv4.2uw* )                      opsys=unixware ;;
 652     *-sysv5uw* )                        opsys=unixware ;;
 653     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 654     *-sysv4.1* | *-sysvr4.1* )
 655         NON_GNU_CPP=/usr/lib/cpp
 656         opsys=usg5-4 ;;
 657     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 658         if [ x$NON_GNU_CPP = x ]; then
 659           if [ -f /usr/ccs/lib/cpp ]; then
 660             NON_GNU_CPP=/usr/ccs/lib/cpp
 661           else
 662             NON_GNU_CPP=/lib/cpp
 663           fi
 664         fi
 665         opsys=usg5-4-2 ;;
 666     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 667     * )
 668       unported=yes
 669     ;;
 670   esac
 671 fi
 672
 673 ]
 674 dnl quotation ends
 675
 676 if test $unported = yes; then
 677   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 678 Check `etc/MACHINES' for recognized configuration names.])
 679 fi
 680
 681 machfile="m/${machine}.h"
 682 opsysfile="s/${opsys}.h"
 683
 684
 685 #### Choose a compiler.
 686 test -n "$CC" && cc_specified=yes
 687
 688 # Save the value of CFLAGS that the user specified.
 689 SPECIFIED_CFLAGS="$CFLAGS"
 690
 691 dnl Sets GCC=yes if using gcc.
 692 AC_PROG_CC
 693
 694 # On Suns, sometimes $CPP names a directory.
 695 if test -n "$CPP" && test -d "$CPP"; then
 696   CPP=
 697 fi
 698
 699 ## If not using gcc, and on Solaris, and no CPP specified, see if
 700 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 701 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 702  test x"$CPP" = x; then
 703   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 704   AC_CACHE_VAL(emacs_cv_sunpro_c,
 705   [AC_TRY_LINK([],
 706 [#ifndef __SUNPRO_C
 707 fail;
 708 #endif
 709 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 710   AC_MSG_RESULT($emacs_cv_sunpro_c)
 711
 712   if test x"$emacs_cv_sunpro_c" = xyes; then
 713     NON_GNU_CPP="$CC -E -Xs"
 714   fi
 715 fi
 716
 717 #### Some systems specify a CPP to use unless we are using GCC.
 718 #### Now that we know whether we are using GCC, we can decide whether
 719 #### to use that one.
 720 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 721 then
 722   CPP="$NON_GNU_CPP"
 723 fi
 724
 725 #### Some systems specify a CC to use unless we are using GCC.
 726 #### Now that we know whether we are using GCC, we can decide whether
 727 #### to use that one.
 728 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 729   test x$cc_specified != xyes
 730 then
 731   CC="$NON_GNU_CC"
 732 fi
 733
 734 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 735 then
 736   CC="$CC $GCC_TEST_OPTIONS"
 737 fi
 738
 739 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 740 then
 741   CC="$CC $NON_GCC_TEST_OPTIONS"
 742 fi
 743
 744 dnl checks for Unix variants
 745 AC_USE_SYSTEM_EXTENSIONS
 746
 747 ### Use -Wno-pointer-sign if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wno-pointer-sign"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 ### Use -Wdeclaration-after-statement if the compiler supports it
 761 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 762 SAVE_CFLAGS="$CFLAGS"
 763 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 764 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 765 if test $has_option = yes; then
 766    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 767 fi
 768 AC_MSG_RESULT($has_option)
 769 CFLAGS="$SAVE_CFLAGS"
 770 unset has_option
 771 unset SAVE_CFLAGS
 772
 773 #### Some other nice autoconf tests.
 774
 775 dnl checks for programs
 776 AC_PROG_LN_S
 777 AC_PROG_CPP
 778 AC_PROG_INSTALL
 779 if test "x$RANLIB" = x; then
 780   AC_PROG_RANLIB
 781 fi
 782 AC_PATH_PROG(INSTALL_INFO, install-info)
 783 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 784 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 785 dnl Don't use GZIP, which is used by gzip for additional parameters.
 786 AC_PATH_PROG(GZIP_PROG, gzip)
 787
 788
 789 ## Need makeinfo >= 4.6 (?) to build the manuals.
 790 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 791 dnl By this stage, configure has already checked for egrep and set EGREP,
 792 dnl or exited with an error if no egrep was found.
 793 if test "$MAKEINFO" != "no" && \
 794   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 795    MAKEINFO=no
 796 fi
 797
 798 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 799 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 800 ## therefore in the category of "special tools" not normally required, which
 801 ## configure does not have to check for (eg autoconf itself).
 802 ## In a Bazaar checkout on the other hand, the manuals are not included.
 803 ## So makeinfo is a requirement to build from Bazaar, and configure
 804 ## should test for it as it does for any other build requirement.
 805 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 806 ## with pre-built manuals, from a Bazaar checkout.
 807 if test "$MAKEINFO" = "no"; then
 808   if test "x${with_makeinfo}" = "xno"; then
 809     MAKEINFO=off
 810   elif ! test -e $srcdir/info/emacs; then
 811     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 812 source tree does not seem to have pre-built manuals in the `info' directory.
 813 Either install a suitable version of makeinfo, or re-run configure
 814 with the `--without-makeinfo' option to build without the manuals.] )
 815   fi
 816 fi
 817
 818 dnl Add our options to ac_link now, after it is set up.
 819
 820 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 821 then
 822   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 823 fi
 824
 825 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 826 then
 827   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 828 fi
 829
 830 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 831 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 832 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 833 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 834 dnl if not built to support GNU ld.
 835
 836 late_LDFLAGS=$LDFLAGS
 837 if test "$GCC" = yes; then
 838   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 839 else
 840   LDFLAGS="$LDFLAGS -znocombreloc"
 841 fi
 842
 843 AC_MSG_CHECKING([for -znocombreloc])
 844 AC_LINK_IFELSE([main(){return 0;}],
 845   [AC_MSG_RESULT(yes)],
 846   LDFLAGS=$late_LDFLAGS
 847   [AC_MSG_RESULT(no)])
 848
 849 #### Extract some information from the operating system and machine files.
 850
 851 AC_CHECKING([the machine- and system-dependent files to find out
 852  - which libraries the lib-src programs will want, and
 853  - whether the GNU malloc routines are usable])
 854
 855 ### First figure out CFLAGS (which we use for running the compiler here)
 856 ### and REAL_CFLAGS (which we use for real compilation).
 857 ### The two are the same except on a few systems, where they are made
 858 ### different to work around various lossages.  For example,
 859 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 860 ### as implying static linking.
 861
 862 ### If the CFLAGS env var is specified, we use that value
 863 ### instead of the default.
 864
 865 ### It's not important that this name contain the PID; you can't run
 866 ### two configures in the same directory and have anything work
 867 ### anyway.
 868 tempcname="conftest.c"
 869
 870 echo '
 871 #include "'${srcdir}'/src/'${opsysfile}'"
 872 #include "'${srcdir}'/src/'${machfile}'"
 873 #ifndef LIBS_MACHINE
 874 #define LIBS_MACHINE
 875 #endif
 876 #ifndef LIBS_SYSTEM
 877 #define LIBS_SYSTEM
 878 #endif
 879 #ifndef C_SWITCH_SYSTEM
 880 #define C_SWITCH_SYSTEM
 881 #endif
 882 #ifndef C_SWITCH_MACHINE
 883 #define C_SWITCH_MACHINE
 884 #endif
 885 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 886 configure___ c_switch_system=C_SWITCH_SYSTEM
 887 configure___ c_switch_machine=C_SWITCH_MACHINE
 888
 889 #ifndef LIB_X11_LIB
 890 #define LIB_X11_LIB -lX11
 891 #endif
 892
 893 #ifndef LIBX11_SYSTEM
 894 #define LIBX11_SYSTEM
 895 #endif
 896 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 897
 898 #ifdef UNEXEC
 899 configure___ unexec=UNEXEC
 900 #else
 901 configure___ unexec=unexec.o
 902 #endif
 903
 904 #ifdef SYSTEM_MALLOC
 905 configure___ system_malloc=yes
 906 #else
 907 configure___ system_malloc=no
 908 #endif
 909
 910 #ifdef USE_MMAP_FOR_BUFFERS
 911 configure___ use_mmap_for_buffers=yes
 912 #else
 913 configure___ use_mmap_for_buffers=no
 914 #endif
 915
 916 #ifndef C_DEBUG_SWITCH
 917 #define C_DEBUG_SWITCH -g
 918 #endif
 919
 920 #ifndef C_OPTIMIZE_SWITCH
 921 #ifdef __GNUC__
 922 #define C_OPTIMIZE_SWITCH -O2
 923 #else
 924 #define C_OPTIMIZE_SWITCH -O
 925 #endif
 926 #endif
 927
 928 #ifndef C_WARNINGS_SWITCH
 929 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 930 #endif
 931
 932 #ifndef LD_SWITCH_MACHINE
 933 #define LD_SWITCH_MACHINE
 934 #endif
 935
 936 #ifndef LD_SWITCH_SYSTEM
 937 #define LD_SWITCH_SYSTEM
 938 #endif
 939
 940 #ifndef LD_SWITCH_X_SITE_AUX
 941 #define LD_SWITCH_X_SITE_AUX
 942 #endif
 943
 944 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 945 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 946
 947 #ifdef THIS_IS_CONFIGURE
 948
 949 /* Get the CFLAGS for tests in configure.  */
 950 #ifdef __GNUC__
 951 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 952 #else
 953 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 954 #endif
 955
 956 #else /* not THIS_IS_CONFIGURE */
 957
 958 /* Get the CFLAGS for real compilation.  */
 959 #ifdef __GNUC__
 960 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 961 #else
 962 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 963 #endif
 964
 965 #endif /* not THIS_IS_CONFIGURE */
 966 ' > ${tempcname}
 967
 968 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 969
 970 # The value of CPP is a quoted variable reference, so we need to do this
 971 # to get its actual value...
 972 CPP=`eval "echo $CPP"`
 973 [eval `${CPP} -Isrc ${tempcname} \
 974        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 975 if test "x$SPECIFIED_CFLAGS" = x; then
 976   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 977          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 978 else
 979   REAL_CFLAGS="$CFLAGS"
 980 fi]
 981 rm ${tempcname}
 982
 983 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 984
 985 ### Make sure subsequent tests use flags consistent with the build flags.
 986
 987 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 988   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 989 else
 990   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 991 fi
 992
 993 dnl For AC_FUNC_GETLOADAVG, at least:
 994 AC_CONFIG_LIBOBJ_DIR(src)
 995
 996 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 997 AC_SYS_LARGEFILE
 998
 999
1000 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1001 ### be located in either /usr/lib64 or /usr/lib.
1002 ### In some rare cases, /usr/lib64 exists but does not contain the
1003 ### relevant files (bug#1287).  Hence test for crtn.o.
1004 case "${canonical}" in
1005   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1006     if test -e /usr/lib64/crtn.o; then
1007       AC_DEFINE(HAVE_LIB64_DIR, 1,
1008         [Define to 1 if the directory /usr/lib64 exists.])
1009 fi
1010 esac
1011
1012 dnl This function defintion taken from Gnome 2.0
1013 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1014 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1015 dnl also defines GSTUFF_PKG_ERRORS on error
1016 AC_DEFUN([PKG_CHECK_MODULES], [
1017   succeeded=no
1018
1019   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1020
1021   if test "$PKG_CONFIG" = "no" ; then
1022      ifelse([$4], , [AC_MSG_ERROR([
1023       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1024   else
1025      PKG_CONFIG_MIN_VERSION=0.9.0
1026      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1027         AC_MSG_CHECKING(for $2)
1028
1029         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1030             AC_MSG_RESULT(yes)
1031             succeeded=yes
1032
1033             AC_MSG_CHECKING($1_CFLAGS)
1034             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1035             AC_MSG_RESULT($$1_CFLAGS)
1036
1037             AC_MSG_CHECKING($1_LIBS)
1038             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1039             AC_MSG_RESULT($$1_LIBS)
1040         else
1041             AC_MSG_RESULT(no)
1042             $1_CFLAGS=""
1043             $1_LIBS=""
1044             ## If we have a custom action on failure, don't print errors, but
1045             ## do set a variable so people can do so.
1046             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1047             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1048         fi
1049
1050         AC_SUBST($1_CFLAGS)
1051         AC_SUBST($1_LIBS)
1052      else
1053         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1054         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1055      fi
1056   fi
1057
1058   if test $succeeded = yes; then
1059      ifelse([$3], , :, [$3])
1060   else
1061      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1062   fi
1063 ])
1064
1065
1066 if test "${with_sound}" != "no"; then
1067   # Sound support for GNU/Linux and the free BSDs.
1068   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1069   # Emulation library used on NetBSD.
1070   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1071   AC_SUBST(LIBSOUND)
1072
1073   ALSA_REQUIRED=1.0.0
1074   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1075   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1076   if test $HAVE_ALSA = yes; then
1077     SAVE_CFLAGS="$CFLAGS"
1078     SAVE_LDFLAGS="$LDFLAGS"
1079     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1080     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1081     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1082                     emacs_alsa_normal=yes,
1083                     emacs_alsa_normal=no)
1084     if test "$emacs_alsa_normal" != yes; then
1085       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1086                      [snd_lib_error_set_handler (0);],
1087                      emacs_alsa_subdir=yes,
1088                      emacs_alsa_subdir=no)
1089       if test "$emacs_alsa_subdir" != yes; then
1090         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1091       fi
1092       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1093     fi
1094
1095     CFLAGS="$SAVE_CFLAGS"
1096     LDFLAGS="$SAVE_LDFLAGS"
1097     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1098     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1099     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1100   fi
1101   AC_SUBST(CFLAGS_SOUND)
1102 fi
1103
1104 dnl checks for header files
1105 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1106   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1107   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1108   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1109   sys/utsname.h pwd.h utmp.h)
1110
1111 AC_MSG_CHECKING(if personality LINUX32 can be set)
1112 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1113                emacs_cv_personality_linux32=yes,
1114                emacs_cv_personality_linux32=no)
1115 AC_MSG_RESULT($emacs_cv_personality_linux32)
1116
1117 if test $emacs_cv_personality_linux32 = yes; then
1118   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1119             [Define to 1 if personality LINUX32 can be set.])
1120 fi
1121
1122 dnl On Solaris 8 there's a compilation warning for term.h because
1123 dnl it doesn't define `bool'.
1124 AC_CHECK_HEADERS(term.h, , , -)
1125 AC_HEADER_STDC
1126 AC_HEADER_TIME
1127 AC_CHECK_DECLS([sys_siglist])
1128 if test $ac_cv_have_decl_sys_siglist != yes; then
1129   # For Tru64, at least:
1130   AC_CHECK_DECLS([__sys_siglist])
1131   if test $ac_cv_have_decl___sys_siglist = yes; then
1132     AC_DEFINE(sys_siglist, __sys_siglist,
1133               [Define to any substitute for sys_siglist.])
1134   fi
1135 fi
1136 AC_HEADER_SYS_WAIT
1137
1138 dnl Some systems have utime.h but don't declare the struct anyplace.
1139 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1140 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1141 #include <sys/time.h>
1142 #include <time.h>
1143 #else
1144 #ifdef HAVE_SYS_TIME_H
1145 #include <sys/time.h>
1146 #else
1147 #include <time.h>
1148 #endif
1149 #endif
1150 #ifdef HAVE_UTIME_H
1151 #include <utime.h>
1152 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1153   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1154 if test $emacs_cv_struct_utimbuf = yes; then
1155   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1156 fi
1157
1158 dnl checks for typedefs
1159 AC_TYPE_SIGNAL
1160
1161 dnl Check for speed_t typedef.
1162 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1163   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1164     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1165 if test $emacs_cv_speed_t = yes; then
1166   AC_DEFINE(HAVE_SPEED_T, 1,
1167            [Define to 1 if `speed_t' is declared by <termios.h>.])
1168 fi
1169
1170 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1171 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1172 #include <sys/time.h>
1173 #include <time.h>
1174 #else
1175 #ifdef HAVE_SYS_TIME_H
1176 #include <sys/time.h>
1177 #else
1178 #include <time.h>
1179 #endif
1180 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1181   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1182 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1183 if test $emacs_cv_struct_timeval = yes; then
1184   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1185 fi
1186
1187 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1188 AC_TRY_COMPILE([#include <math.h>],
1189 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1190   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1191 HAVE_EXCEPTION=$emacs_cv_struct_exception
1192 if test $emacs_cv_struct_exception != yes; then
1193   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1194 fi
1195
1196 AC_CHECK_HEADERS(sys/socket.h)
1197 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1198 #if HAVE_SYS_SOCKET_H
1199 #include <sys/socket.h>
1200 #endif])
1201
1202 dnl checks for structure members
1203 AC_STRUCT_TM
1204 AC_STRUCT_TIMEZONE
1205 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1206                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1207                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1208                 [#include <time.h>])
1209 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1210                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1211                   struct ifreq.ifr_addr], , ,
1212                  [AC_INCLUDES_DEFAULT
1213 #if HAVE_SYS_SOCKET_H
1214 #include <sys/socket.h>
1215 #endif
1216 #if HAVE_NET_IF_H
1217 #include <net/if.h>
1218 #endif])
1219
1220 dnl checks for compiler characteristics
1221
1222 dnl Testing __STDC__ to determine prototype support isn't good enough.
1223 dnl DEC C, for instance, doesn't define it with default options, and
1224 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1225 dnl and void *.
1226 AC_C_PROTOTYPES
1227 AC_C_VOLATILE
1228 AC_C_CONST
1229 dnl This isn't useful because we can't turn on use of `inline' unless
1230 dnl the compiler groks `extern inline'.
1231 dnl AC_C_INLINE
1232 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1233   [AC_TRY_COMPILE(, [void * foo;],
1234                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1235 if test $emacs_cv_void_star = yes; then
1236   AC_DEFINE(POINTER_TYPE, void)
1237 else
1238   AC_DEFINE(POINTER_TYPE, char)
1239 fi
1240 AH_TEMPLATE(POINTER_TYPE,
1241             [Define as `void' if your compiler accepts `void *'; otherwise
1242              define as `char'.])dnl
1243
1244
1245
1246 dnl This could be used for targets which can have both byte sexes.
1247 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1248 dnl AC_C_BIGENDIAN
1249
1250 dnl check for Make feature
1251 AC_PROG_MAKE_SET
1252
1253 dnl check for GNU Make if we have GCC and autodepend is on.
1254 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1255    AC_MSG_CHECKING([whether we are using GNU Make])
1256    HAVE_GNU_MAKE=no
1257    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1258    if test "x$testval" != x; then
1259       HAVE_GNU_MAKE=yes
1260    else
1261       ac_enable_autodepend=no
1262    fi
1263    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1264    if test $HAVE_GNU_MAKE = yes; then
1265       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1266       SAVE_CFLAGS="$CFLAGS"
1267       CFLAGS="$CFLAGS -MMD -MF deps.d"
1268       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1269       CFLAGS="$SAVE_CFLAGS"
1270       test -f deps.d || ac_enable_autodepend=no
1271       rm -rf deps.d
1272       AC_MSG_RESULT([$ac_enable_autodepend])
1273    fi
1274    if test $ac_enable_autodepend = yes; then
1275       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1276    fi
1277 fi
1278
1279 dnl checks for operating system services
1280 AC_SYS_LONG_FILE_NAMES
1281
1282 #### Choose a window system.
1283
1284 AC_PATH_X
1285 if test "$no_x" = yes; then
1286   window_system=none
1287 else
1288   window_system=x11
1289 fi
1290
1291 ## Workaround for bug in autoconf <= 2.62.
1292 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1293 ## No need to do anything special for these standard directories.
1294 ## This is an experiment, take it out if it causes problems.
1295 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1296
1297    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1298
1299 fi
1300
1301 if test "${x_libraries}" != NONE; then
1302   if test -n "${x_libraries}"; then
1303     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1304     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1305   fi
1306   x_default_search_path=""
1307   x_search_path=${x_libraries}
1308   if test -z "${x_search_path}"; then
1309     x_search_path=/usr/lib
1310   fi
1311   for x_library in `echo ${x_search_path}: | \
1312                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1313     x_search_path="\
1314 ${x_library}/X11/%L/%T/%N%C%S:\
1315 ${x_library}/X11/%l/%T/%N%C%S:\
1316 ${x_library}/X11/%T/%N%C%S:\
1317 ${x_library}/X11/%L/%T/%N%S:\
1318 ${x_library}/X11/%l/%T/%N%S:\
1319 ${x_library}/X11/%T/%N%S"
1320     if test x"${x_default_search_path}" = x; then
1321       x_default_search_path=${x_search_path}
1322     else
1323       x_default_search_path="${x_search_path}:${x_default_search_path}"
1324     fi
1325   done
1326 fi
1327 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1328   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1329 fi
1330
1331 if test x"${x_includes}" = x; then
1332   bitmapdir=/usr/include/X11/bitmaps
1333 else
1334   # accumulate include directories that have X11 bitmap subdirectories
1335   bmd_acc="dummyval"
1336   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1337     if test -d "${bmd}/X11/bitmaps"; then
1338       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1339     fi
1340     if test -d "${bmd}/bitmaps"; then
1341       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1342     fi
1343   done
1344   if test ${bmd_acc} != "dummyval"; then
1345     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1346   fi
1347 fi
1348
1349 HAVE_NS=no
1350 NS_IMPL_COCOA=no
1351 NS_IMPL_GNUSTEP=no
1352 tmp_CPPFLAGS="$CPPFLAGS"
1353 tmp_CFLAGS="$CFLAGS"
1354 CPPFLAGS="$CPPFLAGS -x objective-c"
1355 CFLAGS="$CFLAGS -x objective-c"
1356 if test "${with_ns}" != no; then
1357   if test "${opsys}" = darwin; then
1358      NS_IMPL_COCOA=yes
1359      ns_appdir=`pwd`/nextstep/Emacs.app
1360      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1361      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1362      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1363   elif test -f $GNUSTEP_CONFIG_FILE; then
1364      NS_IMPL_GNUSTEP=yes
1365      ns_appdir=`pwd`/nextstep/Emacs.app
1366      ns_appbindir=`pwd`/nextstep/Emacs.app
1367      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1368      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1369      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1370      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1371      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1372      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1373      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1374      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1375      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1376      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1377   fi
1378   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1379                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1380   files are missing or cannot be compiled.])])
1381   NS_HAVE_NSINTEGER=yes
1382   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1383                                      [NSInteger i;])],
1384                     ns_have_nsinteger=yes,
1385                     ns_have_nsinteger=no)
1386   if test $ns_have_nsinteger = no; then
1387     NS_HAVE_NSINTEGER=no
1388   fi
1389 fi
1390 if test "${HAVE_NS}" = yes; then
1391   window_system=nextstep
1392   with_xft=no
1393   # set up packaging dirs
1394   exec_prefix=${ns_appbindir}
1395   libexecdir=${ns_appbindir}/libexec
1396   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1397      prefix=${ns_appresdir}
1398   fi
1399 fi
1400 CFLAGS="$tmp_CFLAGS"
1401 CPPFLAGS="$tmp_CPPFLAGS"
1402
1403 case "${window_system}" in
1404   x11 )
1405     HAVE_X_WINDOWS=yes
1406     HAVE_X11=yes
1407     case "${with_x_toolkit}" in
1408       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1409       motif ) USE_X_TOOLKIT=MOTIF ;;
1410       gtk ) with_gtk=yes
1411 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1412 dnl USE_X_TOOLKIT is set.
1413             USE_X_TOOLKIT=none ;;
1414       no ) USE_X_TOOLKIT=none ;;
1415 dnl If user did not say whether to use a toolkit, make this decision later:
1416 dnl use the toolkit if we have gtk, or X11R5 or newer.
1417       * ) USE_X_TOOLKIT=maybe ;;
1418     esac
1419   ;;
1420   nextstep | none )
1421     HAVE_X_WINDOWS=no
1422     HAVE_X11=no
1423     USE_X_TOOLKIT=none
1424   ;;
1425 esac
1426
1427 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1428    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1429    if test "$HAVE_XSERVER" = true ||
1430       test -n "$DISPLAY" ||
1431       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1432         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1433 were found.  You should install the relevant development files for X
1434 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1435 sure you have development files for image handling, i.e.
1436 tiff, gif, jpeg, png and xpm.
1437 If you are sure you want Emacs compiled without X window support, pass
1438   --without-x
1439 to configure.])
1440    fi
1441 fi
1442
1443 ### If we're using X11, we should use the X menu package.
1444 HAVE_MENUS=no
1445 case ${HAVE_X11} in
1446   yes ) HAVE_MENUS=yes ;;
1447 esac
1448
1449 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1450 # Assume not, until told otherwise.
1451 GNU_MALLOC=yes
1452 doug_lea_malloc=yes
1453 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1454 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1455 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1456                emacs_cv_var___after_morecore_hook,
1457 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1458   emacs_cv_var___after_morecore_hook=yes,
1459   emacs_cv_var___after_morecore_hook=no)])
1460 if test $emacs_cv_var___after_morecore_hook = no; then
1461   doug_lea_malloc=no
1462 fi
1463 if test "${system_malloc}" = "yes"; then
1464   GNU_MALLOC=no
1465   GNU_MALLOC_reason="
1466     (The GNU allocators don't work with this system configuration.)"
1467 fi
1468 if test "$doug_lea_malloc" = "yes" ; then
1469   if test "$GNU_MALLOC" = yes ; then
1470     GNU_MALLOC_reason="
1471       (Using Doug Lea's new malloc from the GNU C Library.)"
1472   fi
1473   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1474             [Define to 1 if you are using the GNU C Library.])
1475 fi
1476
1477 if test x"${REL_ALLOC}" = x; then
1478   REL_ALLOC=${GNU_MALLOC}
1479 fi
1480
1481 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1482 dnl the system configuration file (s/*.h) to turn the use of mmap
1483 dnl in the relocating allocator on.
1484
1485 AC_FUNC_MMAP
1486 if test $use_mmap_for_buffers = yes; then
1487   REL_ALLOC=no
1488 fi
1489
1490 LIBS="$libsrc_libs $LIBS"
1491
1492 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1493 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1494 AC_CHECK_LIB(dnet, dnet_ntoa)
1495 dnl This causes -lresolv to get used in subsequent tests,
1496 dnl which causes failures on some systems such as HPUX 9.
1497 dnl AC_CHECK_LIB(resolv, gethostbyname)
1498
1499 dnl FIXME replace main with a function we actually want from this library.
1500 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1501
1502 AC_CHECK_LIB(pthreads, cma_open)
1503
1504 dnl Check for need for bigtoc support on IBM AIX
1505
1506 case ${host_os} in
1507 aix*)
1508   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1509     case $GCC in
1510     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1511     *) gdb_cv_bigtoc=-bbigtoc ;;
1512     esac
1513
1514     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1515     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1516   ])
1517   ;;
1518 esac
1519
1520 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1521 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1522 # REAL_CPPFLAGS later on.
1523
1524 REAL_CPPFLAGS="$CPPFLAGS"
1525
1526 if test "${HAVE_X11}" = "yes"; then
1527   DEFS="$C_SWITCH_X_SITE $DEFS"
1528   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1529   LIBS="$LIBX $LIBS"
1530   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1531   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1532
1533   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1534   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1535   # but it's more convenient here to set LD_RUN_PATH
1536   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1537   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1538     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1539     export LD_RUN_PATH
1540   fi
1541
1542   if test "${opsys}" = "gnu-linux"; then
1543     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1544     AC_TRY_LINK([],
1545      [XOpenDisplay ("foo");],
1546      [xlinux_first_failure=no],
1547      [xlinux_first_failure=yes])
1548     if test "${xlinux_first_failure}" = "yes"; then
1549       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1550       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1551       OLD_CPPFLAGS="$CPPFLAGS"
1552       OLD_LIBS="$LIBS"
1553       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1554       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1555       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1556       LIBS="$LIBS -b i486-linuxaout"
1557       AC_TRY_LINK([],
1558        [XOpenDisplay ("foo");],
1559        [xlinux_second_failure=no],
1560        [xlinux_second_failure=yes])
1561       if test "${xlinux_second_failure}" = "yes"; then
1562         # If we get the same failure with -b, there is no use adding -b.
1563         # So take it out.  This plays safe.
1564         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1565         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1566         CPPFLAGS="$OLD_CPPFLAGS"
1567         LIBS="$OLD_LIBS"
1568         AC_MSG_RESULT(no)
1569       else
1570         AC_MSG_RESULT(yes)
1571       fi
1572     else
1573       AC_MSG_RESULT(no)
1574     fi
1575   fi
1576
1577   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1578   # header files included from there.
1579   AC_MSG_CHECKING(for Xkb)
1580   AC_TRY_LINK([#include <X11/Xlib.h>
1581 #include <X11/XKBlib.h>],
1582         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1583         emacs_xkb=yes, emacs_xkb=no)
1584   AC_MSG_RESULT($emacs_xkb)
1585   if test $emacs_xkb = yes; then
1586     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1587   fi
1588
1589   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1590 XScreenNumberOfScreen XSetWMProtocols)
1591 fi
1592
1593 if test "${window_system}" = "x11"; then
1594   AC_MSG_CHECKING(X11 version 6)
1595   AC_CACHE_VAL(emacs_cv_x11_version_6,
1596   [AC_TRY_LINK([#include <X11/Xlib.h>],
1597 [#if XlibSpecificationRelease < 6
1598 fail;
1599 #endif
1600 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1601   if test $emacs_cv_x11_version_6 = yes; then
1602     AC_MSG_RESULT(6 or newer)
1603     AC_DEFINE(HAVE_X11R6, 1,
1604               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1605   else
1606     AC_MSG_RESULT(before 6)
1607   fi
1608 fi
1609
1610
1611 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1612 HAVE_RSVG=no
1613 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1614   if test "${with_rsvg}" != "no"; then
1615     RSVG_REQUIRED=2.11.0
1616     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1617
1618     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1619     AC_SUBST(RSVG_CFLAGS)
1620     AC_SUBST(RSVG_LIBS)
1621
1622     if test ".${RSVG_CFLAGS}" != "."; then
1623       HAVE_RSVG=yes
1624       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1625       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1626       LIBS="$RSVG_LIBS $LIBS"
1627     fi
1628   fi
1629 fi
1630
1631
1632 HAVE_GTK=no
1633 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1634   GLIB_REQUIRED=2.6
1635   GTK_REQUIRED=2.6
1636   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1637
1638   dnl Checks for libraries.
1639   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1640   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1641      AC_MSG_ERROR($GTK_PKG_ERRORS)
1642   fi
1643 fi
1644
1645
1646 if test x"$pkg_check_gtk" = xyes; then
1647
1648   AC_SUBST(GTK_CFLAGS)
1649   AC_SUBST(GTK_LIBS)
1650   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1651   CFLAGS="$CFLAGS $GTK_CFLAGS"
1652   LIBS="$GTK_LIBS $LIBS"
1653   dnl Try to compile a simple GTK program.
1654   GTK_COMPILES=no
1655   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1656   if test "${GTK_COMPILES}" != "yes"; then
1657     if test "$USE_X_TOOLKIT" != "maybe"; then
1658       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1659     fi
1660   else
1661     HAVE_GTK=yes
1662     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1663     USE_X_TOOLKIT=none
1664     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1665       :
1666     else
1667       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1668        closing open displays.  This is no problem if you just use
1669        one display, but if you use more than one and close one of them
1670        Emacs may crash.]])
1671       sleep 3
1672     fi
1673   fi
1674
1675 fi
1676
1677
1678 if test "${HAVE_GTK}" = "yes"; then
1679
1680   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1681   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1682   if test "$with_toolkit_scroll_bars" != no; then
1683     with_toolkit_scroll_bars=yes
1684   fi
1685
1686   dnl  Check if we can use multiple displays with this GTK version.
1687   dnl  If gdk_display_open exists, assume all others are there also.
1688   HAVE_GTK_MULTIDISPLAY=no
1689   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1690   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1691     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1692               [Define to 1 if GTK can handle more than one display.])
1693   fi
1694
1695   dnl  Check if we have the old file selection dialog declared and
1696   dnl  in the link library.  In 2.x it may be in the library,
1697   dnl  but not declared if deprecated featured has been selected out.
1698   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1699   HAVE_GTK_FILE_SELECTION=no
1700   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1701                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1702 #include <gtk/gtk.h>])
1703   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1704     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1705                    HAVE_GTK_FILE_SELECTION=no)
1706   fi
1707
1708   dnl  Check if we have the new file chooser dialog
1709   HAVE_GTK_FILE_CHOOSER=no
1710   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1711                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1712 #include <gtk/gtk.h>])
1713   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1714     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1715                    HAVE_GTK_FILE_CHOOSER=no)
1716   fi
1717
1718   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1719      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1720     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1721               [Define to 1 if GTK has both file selection and chooser dialog.])
1722   fi
1723
1724   dnl Check if pthreads are available.  Emacs only needs this when using
1725   dnl gtk_file_chooser under Gnome.
1726   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1727     HAVE_GTK_AND_PTHREAD=no
1728     AC_CHECK_HEADERS(pthread.h)
1729     if test "$ac_cv_header_pthread_h"; then
1730       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1731     fi
1732     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1733       case "${canonical}" in
1734         *-hpux*) ;;
1735         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1736       esac
1737       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1738                [Define to 1 if you have GTK and pthread (-lpthread).])
1739     fi
1740   fi
1741 fi
1742
1743 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1744 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1745 dnl also not configured.
1746 HAVE_DBUS=no
1747 if test "${with_dbus}" = "yes"; then
1748    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1749    if test "$HAVE_DBUS" = yes; then
1750      LIBS="$LIBS $DBUS_LIBS"
1751      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1752      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1753    fi
1754 fi
1755
1756 dnl GConf has been tested under GNU/Linux only.
1757 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1758 HAVE_GCONF=no
1759 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1760    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1761    if test "$HAVE_GCONF" = yes; then
1762       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1763    fi
1764 fi
1765
1766 dnl Do not put whitespace before the #include statements below.
1767 dnl Older compilers (eg sunos4 cc) choke on it.
1768 HAVE_XAW3D=no
1769 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1770   if test "$with_xaw3d" != no; then
1771     AC_MSG_CHECKING(for xaw3d)
1772     AC_CACHE_VAL(emacs_cv_xaw3d,
1773     [AC_TRY_LINK([
1774 #include <X11/Intrinsic.h>
1775 #include <X11/Xaw3d/Simple.h>],
1776       [],
1777       emacs_cv_xaw3d=yes,
1778       emacs_cv_xaw3d=no)])
1779   else
1780     emacs_cv_xaw3d=no
1781   fi
1782   if test $emacs_cv_xaw3d = yes; then
1783     AC_MSG_RESULT([yes; using Lucid toolkit])
1784     USE_X_TOOLKIT=LUCID
1785     HAVE_XAW3D=yes
1786     AC_DEFINE(HAVE_XAW3D, 1,
1787               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1788   else
1789     AC_MSG_RESULT(no)
1790     AC_MSG_CHECKING(for libXaw)
1791     AC_CACHE_VAL(emacs_cv_xaw,
1792     [AC_TRY_LINK([
1793 #include <X11/Intrinsic.h>
1794 #include <X11/Xaw/Simple.h>],
1795       [],
1796       emacs_cv_xaw=yes,
1797       emacs_cv_xaw=no)])
1798     if test $emacs_cv_xaw = yes; then
1799       AC_MSG_RESULT([yes; using Lucid toolkit])
1800       USE_X_TOOLKIT=LUCID
1801     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1802       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1803     else
1804       AC_MSG_RESULT([no; do not use toolkit by default])
1805       USE_X_TOOLKIT=none
1806     fi
1807   fi
1808 fi
1809
1810 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1811
1812 if test "${USE_X_TOOLKIT}" != "none"; then
1813   AC_MSG_CHECKING(X11 toolkit version)
1814   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1815   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1816 [#if XtSpecificationRelease < 6
1817 fail;
1818 #endif
1819 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1820   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1821   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1822     AC_MSG_RESULT(6 or newer)
1823     AC_DEFINE(HAVE_X11XTR6, 1,
1824               [Define to 1 if you have the X11R6 or newer version of Xt.])
1825   else
1826     AC_MSG_RESULT(before 6)
1827   fi
1828
1829 dnl If using toolkit, check whether libXmu.a exists.
1830 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1831   OLDLIBS="$LIBS"
1832   if test x$HAVE_X11XTR6 = xyes; then
1833     LIBS="-lXt -lSM -lICE $LIBS"
1834   else
1835     LIBS="-lXt $LIBS"
1836   fi
1837   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1838   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1839 fi
1840
1841 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1842 if test "${HAVE_X11}" = "yes"; then
1843   if test "${USE_X_TOOLKIT}" != "none"; then
1844     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1845   fi
1846 fi
1847
1848 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1849   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1850   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1851     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1852 int x = 5;
1853 #else
1854 Motif version prior to 2.1.
1855 #endif],
1856     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1857   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1858   if test $emacs_cv_motif_version_2_1 = yes; then
1859     HAVE_LIBXP=no
1860     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1861               [Define to 1 if you have Motif 2.1 or newer.])
1862     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1863     if test ${HAVE_LIBXP} = yes; then
1864       AC_DEFINE(HAVE_LIBXP, 1,
1865                 [Define to 1 if you have the Xp library (-lXp).])
1866     fi
1867   else
1868     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1869     # We put this in CFLAGS temporarily to precede other -I options
1870     # that might be in CFLAGS temporarily.
1871     # We put this in CPPFLAGS where it precedes the other -I options.
1872     OLD_CPPFLAGS=$CPPFLAGS
1873     OLD_CFLAGS=$CFLAGS
1874     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1875     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1876     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1877       [int x = 5;],
1878       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1879     if test $emacs_cv_lesstif = yes; then
1880       # Make sure this -I option remains in CPPFLAGS after it is set
1881       # back to REAL_CPPFLAGS.
1882       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1883       # have those other -I options anyway.  Ultimately, having this
1884       # directory ultimately in CPPFLAGS will be enough.
1885       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1886       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1887     else
1888       CFLAGS=$OLD_CFLAGS
1889       CPPFLAGS=$OLD_CPPFLAGS
1890     fi
1891   fi
1892 fi
1893
1894 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1895 dnl using Motif or Xaw3d is available, and unless
1896 dnl --with-toolkit-scroll-bars=no was specified.
1897
1898 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1899             [Define to 1 if we should use toolkit scroll bars.])dnl
1900 USE_TOOLKIT_SCROLL_BARS=no
1901 if test "${with_toolkit_scroll_bars}" != "no"; then
1902   if test "${USE_X_TOOLKIT}" != "none"; then
1903     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1904       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1905       HAVE_XAW3D=no
1906       USE_TOOLKIT_SCROLL_BARS=yes
1907     elif test "${HAVE_XAW3D}" = "yes"; then
1908       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1909       USE_TOOLKIT_SCROLL_BARS=yes
1910     fi
1911   elif test "${HAVE_GTK}" = "yes"; then
1912     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1913     USE_TOOLKIT_SCROLL_BARS=yes
1914   elif test "${HAVE_NS}" = "yes"; then
1915     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1916     USE_TOOLKIT_SCROLL_BARS=yes
1917   fi
1918 fi
1919
1920 dnl See if XIM is available.
1921 AC_TRY_COMPILE([
1922           #include <X11/Xlib.h>
1923           #include <X11/Xresource.h>],
1924          [XIMProc  callback;],
1925          [HAVE_XIM=yes
1926          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1927          HAVE_XIM=no)
1928
1929 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1930
1931 if test "${with_xim}" != "no"; then
1932   AC_DEFINE(USE_XIM, 1,
1933             [Define to 1 if we should use XIM, if it is available.])
1934 fi
1935
1936
1937 if test "${HAVE_XIM}" != "no"; then
1938   late_CFLAGS=$CFLAGS
1939   if test "$GCC" = yes; then
1940     CFLAGS="$CFLAGS --pedantic-errors"
1941   fi
1942   AC_TRY_COMPILE([
1943 #include <X11/Xlib.h>
1944 #include <X11/Xresource.h>],
1945 [Display *display;
1946 XrmDatabase db;
1947 char *res_name;
1948 char *res_class;
1949 XIMProc  callback;
1950 XPointer *client_data;
1951 #ifndef __GNUC__
1952 /* If we're not using GCC, it's probably not XFree86, and this is
1953    probably right, but we can't use something like --pedantic-errors.  */
1954 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1955                                            char*, XIMProc, XPointer*);
1956 #endif
1957 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1958    client_data);],
1959     [emacs_cv_arg6_star=yes])
1960   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1961          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1962 either XPointer or XPointer*.])dnl
1963   if test "$emacs_cv_arg6_star" = yes; then
1964     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1965   else
1966     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1967   fi
1968   CFLAGS=$late_CFLAGS
1969 fi
1970
1971 ### Start of font-backend (under any platform) section.
1972 # (nothing here yet -- this is a placeholder)
1973 ### End of font-backend (under any platform) section.
1974
1975 ### Start of font-backend (under X11) section.
1976 if test "${HAVE_X11}" = "yes"; then
1977    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1978
1979    ## Use -lXft if available, unless `--with-xft=no'.
1980    HAVE_XFT=maybe
1981     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1982       with_xft="no";
1983     fi
1984     if test "x${with_xft}" != "xno"; then
1985
1986       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1987       ## Because xftfont.c uses XRenderQueryExtension, we also
1988       ## need to link to -lXrender.
1989       HAVE_XRENDER=no
1990       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
1991       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
1992         OLD_CPPFLAGS="$CPPFLAGS"
1993         OLD_CFLAGS="$CFLAGS"
1994         OLD_LIBS="$LIBS"
1995         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1996         CFLAGS="$CFLAGS $XFT_CFLAGS"
1997         XFT_LIBS="-lXrender $XFT_LIBS"
1998         LIBS="$XFT_LIBS $LIBS"
1999         AC_CHECK_HEADER(X11/Xft/Xft.h,
2000           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2001
2002         if test "${HAVE_XFT}" = "yes"; then
2003           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2004             AC_SUBST(XFT_LIBS)
2005           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2006         else
2007           CPPFLAGS="$OLD_CPPFLAGS"
2008           CFLAGS="$OLD_CFLAGS"
2009           LIBS="$OLD_LIBS"
2010         fi                        # "${HAVE_XFT}" = "yes"
2011       fi                          # "$HAVE_XFT" != no
2012     fi                            # "x${with_xft}" != "xno"
2013
2014     dnl For the "Does Emacs use" message at the end.
2015     if test "$HAVE_XFT" != "yes"; then
2016        HAVE_XFT=no
2017     fi
2018
2019
2020     HAVE_FREETYPE=no
2021     ## We used to allow building with FreeType and without Xft.
2022     ## However, the ftx font backend driver is not in good shape.
2023     if test "${HAVE_XFT}" = "yes"; then
2024       dnl As we use Xft, we anyway use freetype.
2025       dnl There's no need for additional CFLAGS and LIBS.
2026       HAVE_FREETYPE=yes
2027       FONTCONFIG_CFLAGS=
2028       FONTCONFIG_LIBS=
2029     fi
2030
2031     HAVE_LIBOTF=no
2032     if test "${HAVE_FREETYPE}" = "yes"; then
2033       AC_DEFINE(HAVE_FREETYPE, 1,
2034                 [Define to 1 if using the freetype and fontconfig libraries.])
2035       if test "${with_libotf}" != "no"; then
2036         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2037                           HAVE_LIBOTF=no)
2038         if test "$HAVE_LIBOTF" = "yes"; then
2039           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2040           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2041                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2042                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2043           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2044             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2045                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2046           fi
2047         fi
2048       fi
2049     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2050     dnl Does the new font backend require it, or can it work without it?
2051     fi
2052
2053     HAVE_M17N_FLT=no
2054     if test "${HAVE_LIBOTF}" = yes; then
2055       if test "${with_m17n_flt}" != "no"; then
2056         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2057         if test "$HAVE_M17N_FLT" = "yes"; then
2058           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2059         fi
2060       fi
2061     fi
2062 else
2063     HAVE_XFT=no
2064     HAVE_FREETYPE=no
2065     HAVE_LIBOTF=no
2066     HAVE_M17N_FLT=no
2067 fi
2068 ### End of font-backend (under X11) section.
2069
2070 AC_SUBST(FREETYPE_CFLAGS)
2071 AC_SUBST(FREETYPE_LIBS)
2072 AC_SUBST(FONTCONFIG_CFLAGS)
2073 AC_SUBST(FONTCONFIG_LIBS)
2074 AC_SUBST(LIBOTF_CFLAGS)
2075 AC_SUBST(LIBOTF_LIBS)
2076 AC_SUBST(M17N_FLT_CFLAGS)
2077 AC_SUBST(M17N_FLT_LIBS)
2078
2079 ### Use -lXpm if available, unless `--with-xpm=no'.
2080 HAVE_XPM=no
2081 if test "${HAVE_X11}" = "yes"; then
2082   if test "${with_xpm}" != "no"; then
2083     AC_CHECK_HEADER(X11/xpm.h,
2084       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2085     if test "${HAVE_XPM}" = "yes"; then
2086       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2087       AC_EGREP_CPP(no_return_alloc_pixels,
2088       [#include "X11/xpm.h"
2089 #ifndef XpmReturnAllocPixels
2090 no_return_alloc_pixels
2091 #endif
2092       ], HAVE_XPM=no, HAVE_XPM=yes)
2093
2094       if test "${HAVE_XPM}" = "yes"; then
2095         AC_MSG_RESULT(yes)
2096       else
2097         AC_MSG_RESULT(no)
2098       fi
2099     fi
2100   fi
2101
2102   if test "${HAVE_XPM}" = "yes"; then
2103     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2104   fi
2105 fi
2106
2107 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2108 HAVE_JPEG=no
2109 if test "${HAVE_X11}" = "yes"; then
2110   if test "${with_jpeg}" != "no"; then
2111     dnl Checking for jpeglib.h can lose because of a redefinition of
2112     dnl  HAVE_STDLIB_H.
2113     AC_CHECK_HEADER(jerror.h,
2114       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2115   fi
2116
2117   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2118   if test "${HAVE_JPEG}" = "yes"; then
2119     AC_DEFINE(HAVE_JPEG)
2120     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2121         [#include <jpeglib.h>
2122          version=JPEG_LIB_VERSION
2123 ],
2124         [AC_DEFINE(HAVE_JPEG)],
2125         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2126         HAVE_JPEG=no])
2127   fi
2128 fi
2129
2130 ### Use -lpng if available, unless `--with-png=no'.
2131 HAVE_PNG=no
2132 if test "${HAVE_X11}" = "yes"; then
2133   if test "${with_png}" != "no"; then
2134     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2135     # in /usr/include/libpng.
2136     AC_CHECK_HEADERS(png.h libpng/png.h)
2137     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2138       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2139     fi
2140   fi
2141
2142   if test "${HAVE_PNG}" = "yes"; then
2143     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2144   fi
2145 fi
2146
2147 ### Use -ltiff if available, unless `--with-tiff=no'.
2148 HAVE_TIFF=no
2149 if test "${HAVE_X11}" = "yes"; then
2150   if test "${with_tiff}" != "no"; then
2151     AC_CHECK_HEADER(tiffio.h,
2152       [tifflibs="-lz -lm"
2153       # At least one tiff package requires the jpeg library.
2154       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2155       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2156   fi
2157
2158   if test "${HAVE_TIFF}" = "yes"; then
2159     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2160   fi
2161 fi
2162
2163 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2164 HAVE_GIF=no
2165 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2166   AC_CHECK_HEADER(gif_lib.h,
2167 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2168 # Earlier versions can crash Emacs.
2169     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2170
2171   if test "$HAVE_GIF" = yes; then
2172       ac_gif_lib_name="-lgif"
2173   fi
2174
2175 # If gif_lib.h but no libgif, try libungif.
2176   if test x"$try_libungif" = xyes; then
2177     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2178
2179     if test "$HAVE_GIF" = yes; then
2180       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2181       ac_gif_lib_name="-lungif"
2182     fi
2183   fi
2184
2185   if test "${HAVE_GIF}" = "yes"; then
2186     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2187   fi
2188 fi
2189
2190 dnl Check for required libraries.
2191 if test "${HAVE_X11}" = "yes"; then
2192   MISSING=""
2193   WITH_NO=""
2194   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2195     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2196   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2197     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2198   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2199     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2200   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2201     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2202   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2203     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2204
2205   if test "X${MISSING}" != X; then
2206     AC_MSG_ERROR([The following required libraries were not found:
2207     $MISSING
2208 Maybe some development libraries/packages are missing?
2209 If you don't want to link with them give
2210     $WITH_NO
2211 as options to configure])
2212   fi
2213 fi
2214
2215 ### Use -lgpm if available, unless `--with-gpm=no'.
2216 HAVE_GPM=no
2217 if test "${with_gpm}" != "no"; then
2218   AC_CHECK_HEADER(gpm.h,
2219     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2220 fi
2221
2222 if test "${HAVE_GPM}" = "yes"; then
2223   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2224 fi
2225
2226 dnl Check for malloc/malloc.h on darwin
2227 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2228
2229 ### Use NeXTstep API to implement GUI.
2230 if test "${HAVE_NS}" = "yes"; then
2231   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2232   if test "${NS_IMPL_COCOA}" = "yes"; then
2233     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2234     GNU_OBJC_CFLAGS=
2235   fi
2236   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2237     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2238     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2239   fi
2240   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2241     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2242   fi
2243   # We also have mouse menus.
2244   HAVE_MENUS=yes
2245   OTHER_FILES=ns-app
2246 fi
2247
2248
2249 ### Use session management (-lSM -lICE) if available
2250 HAVE_X_SM=no
2251 if test "${HAVE_X11}" = "yes"; then
2252   AC_CHECK_HEADER(X11/SM/SMlib.h,
2253     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2254
2255   if test "${HAVE_X_SM}" = "yes"; then
2256     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2257     case "$LIBS" in
2258       *-lSM*) ;;
2259       *)      LIBS="-lSM -lICE $LIBS" ;;
2260     esac
2261   fi
2262 fi
2263
2264 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2265 AC_CACHE_CHECK(whether netdb declares h_errno,
2266                emacs_cv_netdb_declares_h_errno,
2267 [AC_TRY_LINK([#include <netdb.h>],
2268   [return h_errno;],
2269   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2270 if test $emacs_cv_netdb_declares_h_errno = yes; then
2271   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2272 fi
2273
2274 AC_FUNC_ALLOCA
2275
2276 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2277 dnl FIXME is there an autoconf test that does the right thing, without
2278 dnl needing to call A_M_E afterwards?
2279 if test x"$ac_cv_func_alloca_works" != xyes; then
2280    AC_MSG_ERROR( [a system implementation of alloca is required] )
2281 fi
2282
2283 # fmod, logb, and frexp are found in -lm on most systems.
2284 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2285 AC_CHECK_LIB(m, sqrt)
2286
2287 # Check for mail-locking functions in a "mail" library.  Probably this should
2288 # have the same check as for liblockfile below.
2289 AC_CHECK_LIB(mail, maillock)
2290 dnl Debian, at least:
2291 AC_CHECK_LIB(lockfile, maillock)
2292 # If we have the shared liblockfile, assume we must use it for mail
2293 # locking (e.g. Debian).  If we couldn't link against liblockfile
2294 # (no liblockfile.a installed), ensure that we don't need to.
2295 if test "$ac_cv_lib_lockfile_maillock" = no; then
2296   dnl This works for files generally, not just executables.
2297   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2298   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2299                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2300   if test $ac_cv_prog_liblockfile = yes; then
2301     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2302 This probably means that movemail could lose mail.
2303 There may be a `development' package to install containing liblockfile.])
2304   else :
2305   fi
2306 fi
2307 AC_CHECK_FUNCS(touchlock)
2308 AC_CHECK_HEADERS(maillock.h)
2309
2310 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2311 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2312 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2313 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2314 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2315 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2316 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2317 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2318 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2319 cfmakeraw cfsetspeed)
2320
2321 AC_CHECK_HEADERS(sys/un.h)
2322
2323 AC_FUNC_MKTIME
2324 if test "$ac_cv_func_working_mktime" = no; then
2325   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2326 fi
2327
2328 AC_FUNC_GETLOADAVG
2329
2330 AC_FUNC_FSEEKO
2331
2332 # Configure getopt.
2333 m4_include([m4/getopt.m4])
2334 gl_GETOPT_IFELSE([
2335   gl_GETOPT_SUBSTITUTE_HEADER
2336   gl_PREREQ_GETOPT
2337   GETOPTOBJS='getopt.o getopt1.o'
2338 ])
2339 AC_SUBST(GETOPTOBJS)
2340
2341 AC_FUNC_GETPGRP
2342
2343 AC_FUNC_STRFTIME
2344
2345 # UNIX98 PTYs.
2346 AC_CHECK_FUNCS(grantpt)
2347
2348 # PTY-related GNU extensions.
2349 AC_CHECK_FUNCS(getpt)
2350
2351 # Check this now, so that we will NOT find the above functions in ncurses.
2352 # That is because we have not set up to link ncurses in lib-src.
2353 # It's better to believe a function is not available
2354 # than to expect to find it in ncurses.
2355 AC_CHECK_LIB(ncurses, tparm)
2356
2357 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2358
2359 resolv=no
2360 AC_TRY_LINK([#include <netinet/in.h>
2361 #include <arpa/nameser.h>
2362 #include <resolv.h>],
2363     [return res_init();],
2364     have_res_init=yes, have_res_init=no)
2365 if test "$have_res_init" = no; then
2366   OLIBS="$LIBS"
2367   LIBS="$LIBS -lresolv"
2368   AC_MSG_CHECKING(for res_init with -lresolv)
2369   AC_TRY_LINK([#include <netinet/in.h>
2370 #include <arpa/nameser.h>
2371 #include <resolv.h>],
2372     [return res_init();],
2373     have_res_init=yes, have_res_init=no)
2374   AC_MSG_RESULT($have_res_init)
2375   if test "$have_res_init" = yes ; then
2376     resolv=yes
2377   fi
2378   LIBS="$OLIBS"
2379 fi
2380
2381 if test "$have_res_init" = yes; then
2382   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2383 fi
2384
2385 # Do we need the Hesiod library to provide the support routines?
2386 if test "$with_hesiod" != no ; then
2387   # Don't set $LIBS here -- see comments above.
2388   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2389      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2390                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2391   if test "$resolv" = yes ; then
2392     RESOLVLIB=-lresolv
2393   else
2394     RESOLVLIB=
2395   fi
2396   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2397         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2398                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2399         :, $RESOLVLIB)])
2400 fi
2401
2402 # Do we need libresolv (due to res_init or Hesiod)?
2403 if test "$resolv" = yes ; then
2404   AC_DEFINE(HAVE_LIBRESOLV, 1,
2405             [Define to 1 if you have the resolv library (-lresolv).])
2406 fi
2407
2408 # These tell us which Kerberos-related libraries to use.
2409 if test "${with_kerberos}" != no; then
2410   AC_CHECK_LIB(com_err, com_err)
2411   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2412   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2413   AC_CHECK_LIB(krb5, krb5_init_context)
2414   if test "${with_kerberos5}" = no; then
2415     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2416                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2417     AC_CHECK_LIB(krb4, krb_get_cred,,
2418                  [AC_CHECK_LIB(krb, krb_get_cred)])
2419   fi
2420
2421   if test "${with_kerberos5}" != no; then
2422     AC_CHECK_HEADERS(krb5.h,
2423       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2424                         [#include <krb5.h>])])
2425   else
2426     AC_CHECK_HEADERS(des.h,,
2427                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2428                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2429     AC_CHECK_HEADERS(krb.h,,
2430                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2431                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2432   fi
2433   AC_CHECK_HEADERS(com_err.h)
2434 fi
2435
2436 # Solaris requires -lintl if you want strerror (which calls dgettext)
2437 # to return localized messages.
2438 AC_CHECK_LIB(intl, dgettext)
2439
2440 AC_MSG_CHECKING(whether localtime caches TZ)
2441 AC_CACHE_VAL(emacs_cv_localtime_cache,
2442 [if test x$ac_cv_func_tzset = xyes; then
2443 AC_TRY_RUN([#include <time.h>
2444 extern char **environ;
2445 unset_TZ ()
2446 {
2447   char **from, **to;
2448   for (to = from = environ; (*to = *from); from++)
2449     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2450       to++;
2451 }
2452 char TZ_GMT0[] = "TZ=GMT0";
2453 char TZ_PST8[] = "TZ=PST8";
2454 main()
2455 {
2456   time_t now = time ((time_t *) 0);
2457   int hour_GMT0, hour_unset;
2458   if (putenv (TZ_GMT0) != 0)
2459     exit (1);
2460   hour_GMT0 = localtime (&now)->tm_hour;
2461   unset_TZ ();
2462   hour_unset = localtime (&now)->tm_hour;
2463   if (putenv (TZ_PST8) != 0)
2464     exit (1);
2465   if (localtime (&now)->tm_hour == hour_GMT0)
2466     exit (1);
2467   unset_TZ ();
2468   if (localtime (&now)->tm_hour != hour_unset)
2469     exit (1);
2470   exit (0);
2471 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2472 [# If we have tzset, assume the worst when cross-compiling.
2473 emacs_cv_localtime_cache=yes])
2474 else
2475         # If we lack tzset, report that localtime does not cache TZ,
2476         # since we can't invalidate the cache if we don't have tzset.
2477         emacs_cv_localtime_cache=no
2478 fi])dnl
2479 AC_MSG_RESULT($emacs_cv_localtime_cache)
2480 if test $emacs_cv_localtime_cache = yes; then
2481   AC_DEFINE(LOCALTIME_CACHE, 1,
2482             [Define to 1 if localtime caches TZ.])
2483 fi
2484
2485 if test "x$HAVE_TIMEVAL" = xyes; then
2486   AC_CHECK_FUNCS(gettimeofday)
2487   if test $ac_cv_func_gettimeofday = yes; then
2488     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2489                    emacs_cv_gettimeofday_two_arguments,
2490     [AC_TRY_COMPILE([
2491 #ifdef TIME_WITH_SYS_TIME
2492 #include <sys/time.h>
2493 #include <time.h>
2494 #else
2495 #ifdef HAVE_SYS_TIME_H
2496 #include <sys/time.h>
2497 #else
2498 #include <time.h>
2499 #endif
2500 #endif],
2501       [struct timeval time;
2502        gettimeofday (&time, 0);],
2503       emacs_cv_gettimeofday_two_arguments=yes,
2504       emacs_cv_gettimeofday_two_arguments=no)])
2505     if test $emacs_cv_gettimeofday_two_arguments = no; then
2506       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2507                 [Define to 1 if gettimeofday accepts only one argument.])
2508     fi
2509   fi
2510 fi
2511
2512 ok_so_far=yes
2513 AC_CHECK_FUNC(socket, , ok_so_far=no)
2514 if test $ok_so_far = yes; then
2515   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2516 fi
2517 if test $ok_so_far = yes; then
2518   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2519 fi
2520 if test $ok_so_far = yes; then
2521 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2522   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2523             [Define to 1 if you have inet sockets.])
2524 fi
2525
2526 AC_CHECK_HEADERS(sys/ioctl.h)
2527
2528 if test -f /usr/lpp/X11/bin/smt.exp; then
2529   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2530             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2531 fi
2532
2533 AC_MSG_CHECKING(whether system supports dynamic ptys)
2534 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2535   AC_MSG_RESULT(yes)
2536   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2537 else
2538   AC_MSG_RESULT(no)
2539 fi
2540
2541 AC_FUNC_FORK
2542
2543 dnl Adapted from Haible's version.
2544 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2545   [AC_TRY_LINK([#include <langinfo.h>],
2546     [char* cs = nl_langinfo(CODESET);],
2547     emacs_cv_langinfo_codeset=yes,
2548     emacs_cv_langinfo_codeset=no)
2549   ])
2550 if test $emacs_cv_langinfo_codeset = yes; then
2551   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2552     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2553 fi
2554
2555 AC_CHECK_TYPES(size_t)
2556
2557 AC_TYPE_MBSTATE_T
2558
2559 dnl Restrict could probably be used effectively other than in regex.c.
2560 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2561   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2562                   emacs_cv_c_restrict=yes,
2563                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2564                                   emacs_cv_c_restrict=__restrict,
2565                                   emacs_cv_c_restrict=no)])])
2566 case "$emacs_cv_c_restrict" in
2567   yes) emacs_restrict=restrict;;
2568   no) emacs_restrict="";;
2569   *) emacs_restrict="$emacs_cv_c_restrict";;
2570 esac
2571 if test "$emacs_restrict" != __restrict; then
2572   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2573     [Define to compiler's equivalent of C99 restrict keyword.
2574      Don't define if equivalent is `__restrict'.])
2575 fi
2576
2577 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2578   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2579                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2580 if test "$emacs_cv_c_restrict_arr" = yes; then
2581   AC_DEFINE(__restrict_arr, __restrict,
2582     [Define to compiler's equivalent of C99 restrict keyword in array
2583      declarations.  Define as empty for no equivalent.])
2584 fi
2585
2586 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2587 dnl how the tty code is related to POSIX and/or other versions of termios.
2588 dnl The following looks like a useful start.
2589 dnl
2590 dnl AC_SYS_POSIX_TERMIOS
2591 dnl if test $ac_cv_sys_posix_termios = yes; then
2592 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2593 dnl                                and macros for terminal control.])
2594 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2595 dnl fi
2596
2597 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2598
2599 # Set up the CFLAGS for real compilation, so we can substitute it.
2600 CFLAGS="$REAL_CFLAGS"
2601 CPPFLAGS="$REAL_CPPFLAGS"
2602
2603 #### Find out which version of Emacs this is.
2604 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2605          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2606 if test x"${version}" = x; then
2607   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2608 fi
2609 if test x"${version}" != x"$PACKAGE_VERSION"; then
2610   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2611 fi
2612
2613 ### Specify what sort of things we'll be editing into Makefile and config.h.
2614 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2615 AC_SUBST(version)
2616 AC_SUBST(configuration)
2617 AC_SUBST(canonical)
2618 AC_SUBST(srcdir)
2619 AC_SUBST(prefix)
2620 AC_SUBST(exec_prefix)
2621 AC_SUBST(bindir)
2622 AC_SUBST(datadir)
2623 AC_SUBST(sharedstatedir)
2624 AC_SUBST(libexecdir)
2625 AC_SUBST(mandir)
2626 AC_SUBST(infodir)
2627 AC_SUBST(lispdir)
2628 AC_SUBST(locallisppath)
2629 AC_SUBST(lisppath)
2630 AC_SUBST(x_default_search_path)
2631 AC_SUBST(etcdir)
2632 AC_SUBST(archlibdir)
2633 AC_SUBST(docdir)
2634 AC_SUBST(bitmapdir)
2635 AC_SUBST(gamedir)
2636 AC_SUBST(gameuser)
2637 AC_SUBST(c_switch_system)
2638 AC_SUBST(c_switch_machine)
2639 AC_SUBST(LD_SWITCH_X_SITE)
2640 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2641 AC_SUBST(C_SWITCH_X_SITE)
2642 AC_SUBST(CFLAGS)
2643 AC_SUBST(X_TOOLKIT_TYPE)
2644 AC_SUBST(machfile)
2645 AC_SUBST(opsysfile)
2646 AC_SUBST(GETLOADAVG_LIBS)
2647 AC_SUBST(ns_appdir)
2648 AC_SUBST(ns_appbindir)
2649 AC_SUBST(ns_appresdir)
2650 AC_SUBST(ns_appsrc)
2651 AC_SUBST(GNUSTEP_MAKEFILES)
2652 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2653 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2654 AC_SUBST(GNU_OBJC_CFLAGS)
2655 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2656 AC_SUBST(OTHER_FILES)
2657
2658 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2659                    [Define to the canonical Emacs configuration name.])
2660 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2661                    [Define to the options passed to configure.])
2662 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2663                    [Define to the used machine dependent file.])
2664 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2665                    [Define to the used os dependent file.])
2666 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2667 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2668  may need to deal with X Windows.  For instance, if you've defined
2669  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2670  your loader can find on its own, you might want to add "-L/..." or
2671  something similar.])
2672 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2673                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2674                     in case it's needed (for Solaris, for example).])
2675 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2676 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2677  may need to deal with X Windows.  For instance, if you've defined
2678  HAVE_X_WINDOWS above and your X include files aren't in a place
2679  that your compiler can find on its own, you might want to add
2680  "-I/..." or something similar.])
2681 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2682                    [Define to the unexec source file name.])
2683
2684 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2685   AC_DEFINE(HAVE_X_WINDOWS, 1,
2686             [Define to 1 if you want to use the X window system.])
2687 fi
2688 if test "${USE_X_TOOLKIT}" != "none" ; then
2689   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2690   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2691     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2692   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2693     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2694   fi
2695 fi
2696 if test "${HAVE_X11}" = "yes" ; then
2697   AC_DEFINE(HAVE_X11, 1,
2698             [Define to 1 if you want to use version 11 of X windows.
2699              Otherwise, Emacs expects to use version 10.])
2700 fi
2701 if test "${HAVE_MENUS}" = "yes" ; then
2702   AC_DEFINE(HAVE_MENUS, 1,
2703             [Define to 1 if you have mouse menus.
2704              (This is automatic if you use X, but the option to specify it remains.)
2705              It is also defined with other window systems that support xmenu.c.])
2706 fi
2707 if test "${GNU_MALLOC}" = "yes" ; then
2708   AC_DEFINE(GNU_MALLOC, 1,
2709             [Define to 1 if you want to use the GNU memory allocator.])
2710 fi
2711 if test "${REL_ALLOC}" = "yes" ; then
2712   AC_DEFINE(REL_ALLOC, 1,
2713             [Define REL_ALLOC if you want to use the relocating allocator for
2714              buffer space.])
2715 fi
2716
2717
2718 AH_TOP([/* GNU Emacs site configuration template file.
2719    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2720      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2721
2722 This file is part of GNU Emacs.
2723
2724 GNU Emacs is free software: you can redistribute it and/or modify
2725 it under the terms of the GNU General Public License as published by
2726 the Free Software Foundation, either version 3 of the License, or
2727 (at your option) any later version.
2728
2729 GNU Emacs is distributed in the hope that it will be useful,
2730 but WITHOUT ANY WARRANTY; without even the implied warranty of
2731 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2732 GNU General Public License for more details.
2733
2734 You should have received a copy of the GNU General Public License
2735 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2736
2737
2738 /* No code in Emacs #includes config.h twice, but some bits of code
2739    intended to work with other packages as well (like gmalloc.c)
2740    think they can include it as many times as they like.  */
2741 #ifndef EMACS_CONFIG_H
2742 #define EMACS_CONFIG_H
2743 ])dnl
2744
2745 AH_BOTTOM([
2746 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2747 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2748 #define HAVE_WINDOW_SYSTEM
2749 #define HAVE_MOUSE
2750 #endif
2751
2752 /* Define AMPERSAND_FULL_NAME if you use the convention
2753    that & in the full name stands for the login id.  */
2754 /* Turned on June 1996 supposing nobody will mind it.  */
2755 #define AMPERSAND_FULL_NAME
2756
2757 /* Define HAVE_SOUND if we have sound support.  We know it works
2758    and compiles only on the specified platforms.   For others,
2759    it probably doesn't make sense to try.  */
2760
2761 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2762 #ifdef HAVE_MACHINE_SOUNDCARD_H
2763 #define HAVE_SOUND 1
2764 #endif
2765 #ifdef HAVE_SYS_SOUNDCARD_H
2766 #define HAVE_SOUND 1
2767 #endif
2768 #ifdef HAVE_SOUNDCARD_H
2769 #define HAVE_SOUND 1
2770 #endif
2771 #ifdef HAVE_ALSA
2772 #define HAVE_SOUND 1
2773 #endif
2774 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2775
2776 /* If using GNU, then support inline function declarations. */
2777 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2778    generally, because even if non-gcc compilers accept `inline', they
2779    may reject `extern inline'.  */
2780 #if defined (__GNUC__) && defined (OPTIMIZE)
2781 #define INLINE __inline__
2782 #else
2783 #define INLINE
2784 #endif
2785
2786 /* `subprocesses' should be defined if you want to
2787    have code for asynchronous subprocesses
2788    (as used in M-x compile and M-x shell).
2789    Only MSDOS does not support this (it overrides
2790    this in its config_opsysfile below).  */
2791
2792 #define subprocesses
2793
2794 /* Include the os and machine dependent files.  */
2795 #include config_opsysfile
2796 #include config_machfile
2797
2798 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2799   (There is probably a better place to do this, but right now the Cocoa
2800    side does this in s/darwin.h and we cannot
2801    parallel this exactly since GNUstep is multi-OS. */
2802 #ifdef HAVE_NS
2803 # ifdef NS_IMPL_GNUSTEP
2804 /* See also .m.o rule in Makefile.in */
2805 /* FIXME: are all these flags really needed?  Document here why.  */
2806 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2807 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2808 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2809 #  define SYSTEM_PURESIZE_EXTRA 30000
2810 # endif /* NS_IMPL_GNUSTEP */
2811 #endif /* HAVE_NS */
2812
2813 /* SIGTYPE is the macro we actually use.  */
2814 #ifndef SIGTYPE
2815 #define SIGTYPE RETSIGTYPE
2816 #endif
2817
2818 #ifdef emacs /* Don't do this for lib-src.  */
2819 /* Tell regex.c to use a type compatible with Emacs.  */
2820 #define RE_TRANSLATE_TYPE Lisp_Object
2821 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2822 #ifdef make_number
2823 /* If make_number is a macro, use it.  */
2824 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2825 #else
2826 /* If make_number is a function, avoid it.  */
2827 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2828 #endif
2829 #endif
2830
2831 /* Avoid link-time collision with system mktime if we will use our own.  */
2832 #if ! HAVE_MKTIME || BROKEN_MKTIME
2833 #define mktime emacs_mktime
2834 #endif
2835
2836 #define my_strftime nstrftime   /* for strftime.c */
2837
2838 /* The rest of the code currently tests the CPP symbol BSTRING.
2839    Override any claims made by the system-description files.
2840    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2841 #undef BSTRING
2842 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2843 #define BSTRING
2844 #endif
2845
2846 /* Some of the files of Emacs which are intended for use with other
2847    programs assume that if you have a config.h file, you must declare
2848    the type of getenv.
2849
2850    This declaration shouldn't appear when alloca.s or Makefile.in
2851    includes config.h.  */
2852 #ifndef NOT_C_CODE
2853 extern char *getenv ();
2854 #endif
2855
2856 /* These default definitions are good for almost all machines.
2857    The exceptions override them in m/MACHINE.h.  */
2858
2859 #ifndef BITS_PER_CHAR
2860 #define BITS_PER_CHAR 8
2861 #endif
2862
2863 #ifndef BITS_PER_SHORT
2864 #define BITS_PER_SHORT 16
2865 #endif
2866
2867 /* Note that lisp.h uses this in a preprocessor conditional, so it
2868    would not work to use sizeof.  That being so, we do all of them
2869    without sizeof, for uniformity's sake.  */
2870 #ifndef BITS_PER_INT
2871 #define BITS_PER_INT 32
2872 #endif
2873
2874 #ifndef BITS_PER_LONG
2875 #ifdef _LP64
2876 #define BITS_PER_LONG 64
2877 #else
2878 #define BITS_PER_LONG 32
2879 #endif
2880 #endif
2881
2882 /* Define if the compiler supports function prototypes.  It may do so
2883    but not define __STDC__ (e.g. DEC C by default) or may define it as
2884    zero.  */
2885 #undef PROTOTYPES
2886 /* For mktime.c:  */
2887 #ifndef __P
2888 # if defined PROTOTYPES
2889 #  define __P(args) args
2890 # else
2891 #  define __P(args) ()
2892 # endif  /* GCC.  */
2893 #endif /* __P */
2894
2895 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2896 #ifndef NOT_C_CODE
2897 #ifdef HAVE_STRING_H
2898 #include "string.h"
2899 #endif
2900 #ifdef HAVE_STRINGS_H
2901 #include "strings.h"  /* May be needed for bcopy & al. */
2902 #endif
2903 #ifdef HAVE_STDLIB_H
2904 #include <stdlib.h>
2905 #endif
2906 #ifndef __GNUC__
2907 # ifdef HAVE_ALLOCA_H
2908 #  include <alloca.h>
2909 # else /* AIX files deal with #pragma.  */
2910 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2911 char *alloca ();
2912 #  endif
2913 # endif /* HAVE_ALLOCA_H */
2914 #endif /* __GNUC__ */
2915 #ifndef HAVE_SIZE_T
2916 typedef unsigned size_t;
2917 #endif
2918 #endif /* NOT_C_CODE */
2919
2920 /* Define HAVE_X_I18N if we have usable i18n support.  */
2921
2922 #ifdef HAVE_X11R6
2923 #define HAVE_X_I18N
2924 #elif !defined X11R5_INHIBIT_I18N
2925 #define HAVE_X_I18N
2926 #endif
2927
2928 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2929
2930 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2931 #define HAVE_X11R6_XIM
2932 #endif
2933
2934 #if defined __GNUC__ && (__GNUC__ > 2 \
2935                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2936 #define NO_RETURN       __attribute__ ((__noreturn__))
2937 #else
2938 #define NO_RETURN       /* nothing */
2939 #endif
2940
2941 /* These won't be used automatically yet.  We also need to know, at least,
2942    that the stack is continuous.  */
2943 #ifdef __GNUC__
2944 #  ifndef GC_SETJMP_WORKS
2945   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2946      see NON_SAVING_SETJMP in the target descriptions.  */
2947   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2948      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2949      Fixme: Deal with SVR3.  */
2950 #    define GC_SETJMP_WORKS 1
2951 #  endif
2952 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2953 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2954 #  endif
2955 #endif
2956
2957 #ifndef HAVE_BCOPY
2958 #define bcopy(a,b,s) memcpy (b,a,s)
2959 #endif
2960 #ifndef HAVE_BZERO
2961 #define bzero(a,s) memset (a,0,s)
2962 #endif
2963 #ifndef HAVE_BCMP
2964 #define BCMP memcmp
2965 #endif
2966
2967 #endif /* EMACS_CONFIG_H */
2968
2969 /*
2970 Local Variables:
2971 mode: c
2972 End:
2973 */
2974 ])dnl
2975
2976 #### Report on what we decided to do.
2977 #### Report GTK as a toolkit, even if it doesn't use Xt.
2978 #### It makes printing result more understandable as using GTK sets
2979 #### toolkit_scroll_bars to yes by default.
2980 if test "${HAVE_GTK}" = "yes"; then
2981   USE_X_TOOLKIT=GTK
2982 fi
2983
2984 echo "
2985 Configured for \`${canonical}'.
2986
2987   Where should the build process find the source code?    ${srcdir}
2988   What operating system and machine description files should Emacs use?
2989         \`${opsysfile}' and \`${machfile}'
2990   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2991   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2992   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2993   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2994   What window system should Emacs use?                    ${window_system}
2995   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2996
2997 if test -n "${x_includes}"; then
2998 echo "  Where do we find X Windows header files?                ${x_includes}"
2999 else
3000 echo "  Where do we find X Windows header files?                Standard dirs"
3001 fi
3002 if test -n "${x_libraries}"; then
3003 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3004 else
3005 echo "  Where do we find X Windows libraries?                   Standard dirs"
3006 fi
3007
3008 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3009 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3010 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3011 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3012 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
3013 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3014 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3015 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3016 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3017 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3018
3019 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3020 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3021 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3022 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3023
3024 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3025 echo
3026
3027 if test $USE_XASSERTS = yes; then
3028    echo "  Compiling with asserts turned on."
3029    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3030 fi
3031
3032 echo
3033
3034 if test "$HAVE_NS" = "yes"; then
3035    echo
3036    echo "You must run \"make install\" in order to test the built application.
3037 The installed application will go to nextstep/Emacs.app and can be
3038 run or moved from there."
3039    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3040       echo "The application will be fully self-contained."
3041     else
3042       echo "The lisp resources for the application will be installed under ${prefix}.
3043 You may need to run \"make install\" with sudo.  The application will fail
3044 to run if these resources are not installed."
3045    fi
3046    echo
3047 fi
3048
3049 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3050   echo "D-Bus integration has been tested for GNU/Linux only."
3051   echo
3052 fi
3053
3054
3055 # Remove any trailing slashes in these variables.
3056 [test "${prefix}" != NONE &&
3057   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3058 test "${exec_prefix}" != NONE &&
3059   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3060
3061 # Now get this: Some word that is part of the ${srcdir} directory name
3062 # or the ${configuration} value might, just might, happen to be an
3063 # identifier like `sun4' or `i386' or something, and be predefined by
3064 # the C preprocessor to some helpful value like 1, or maybe the empty
3065 # string.  Needless to say consequent macro substitutions are less
3066 # than conducive to the makefile finding the correct directory.
3067 [cpp_undefs="`echo $srcdir $configuration $canonical |
3068   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3069   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3070
3071 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3072 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3073 ## from Makefile.c can correctly provide the arg `-traditional' to the
3074 ## C preprocessor.
3075
3076 AC_EGREP_CPP(yes..yes,
3077         [yes..yes],
3078         CPP_NEED_TRADITIONAL=no,
3079         CPP_NEED_TRADITIONAL=yes)
3080
3081 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3082         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3083         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3084         lwlib/Makefile lisp/Makefile leim/Makefile, [
3085
3086 ### Make the necessary directories, if they don't exist.
3087 for dir in etc lisp ; do
3088   test -d ${dir} || mkdir ${dir}
3089 done
3090
3091 # Build src/Makefile from ${srcdir}/src/Makefile.c
3092 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3093 # This must be done after src/config.h is built, since we rely on that file.
3094
3095 echo creating src/epaths.h
3096 ${MAKE-make} epaths-force
3097
3098 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3099 # `..' to `. .'  unless invoked with -traditional
3100
3101 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3102   CPPFLAGS="$CPPFLAGS -traditional"
3103 fi
3104
3105 echo creating lib-src/Makefile
3106 ( cd lib-src
3107   rm -f junk.c junk1.c junk2.c
3108   sed -e '/start of cpp stuff/q' \
3109       < Makefile.c > junk1.c
3110   sed -e '1,/start of cpp stuff/d'\
3111       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3112       < Makefile.c > junk.c
3113   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3114       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3115   cat junk1.c junk2.c > Makefile.new
3116   rm -f junk.c junk1.c junk2.c
3117   chmod 444 Makefile.new
3118   mv -f Makefile.new Makefile
3119 )
3120
3121 echo creating src/Makefile
3122 ( cd src
3123   rm -f junk.c junk1.c junk2.c
3124   sed -e '/start of cpp stuff/q' \
3125       < Makefile.c > junk1.c
3126   sed -e '1,/start of cpp stuff/d'\
3127       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3128       < Makefile.c > junk.c
3129   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3130       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3131   cat junk1.c junk2.c > Makefile.new
3132   rm -f junk.c junk1.c junk2.c
3133   chmod 444 Makefile.new
3134   mv -f Makefile.new Makefile
3135 )
3136
3137 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3138   echo creating src/.gdbinit
3139   echo source $srcdir/src/.gdbinit > src/.gdbinit
3140 fi
3141
3142 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3143
3144 m4_if(dnl       Do not change this comment
3145    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3146 )dnl