m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 35
   2 dnl Copyright (C) 2007-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([_Noreturn],
  16 [/* The _Noreturn keyword of C11.  */
  17 #if ! (defined _Noreturn \
  18        || (defined __STDC_VERSION__ && 201112 <= __STDC_VERSION__))
  19 # if (3 <= __GNUC__ || (__GNUC__ == 2 && 8 <= __GNUC_MINOR__) \
  20       || 0x5110 <= __SUNPRO_C)
  21 #  define _Noreturn __attribute__ ((__noreturn__))
  22 # elif defined _MSC_VER && 1200 <= _MSC_VER
  23 #  define _Noreturn __declspec (noreturn)
  24 # else
  25 #  define _Noreturn
  26 # endif
  27 #endif
  28 ])
  29   AH_VERBATIM([isoc99_inline],
  30 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  31    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  32    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  33    __APPLE__ && __MACH__ test for Mac OS X.
  34    __APPLE_CC__ tests for the Apple compiler and its version.
  35    __STDC_VERSION__ tests for the C99 mode.  */
  36 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  37 # define __GNUC_STDC_INLINE__ 1
  38 #endif])
  39   AH_VERBATIM([unused_parameter],
  40 [/* Define as a marker that can be attached to declarations that might not
  41     be used.  This helps to reduce warnings, such as from
  42     GCC -Wunused-parameter.  */
  43 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  44 # define _GL_UNUSED __attribute__ ((__unused__))
  45 #else
  46 # define _GL_UNUSED
  47 #endif
  48 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  49    is a misnomer outside of parameter lists.  */
  50 #define _UNUSED_PARAMETER_ _GL_UNUSED
  51
  52 /* gcc supports the "unused" attribute on possibly unused labels, and
  53    g++ has since version 4.5.  */
  54 #if !defined __cplusplus || __GNUC__ > 4 \
  55     || (__GNUC__ == 4 && __GNUC_MINOR__ >= 5)
  56 # define _GL_UNUSED_LABEL _GL_UNUSED
  57 #else
  58 # define _GL_UNUSED_LABEL
  59 #endif
  60
  61 /* The __pure__ attribute was added in gcc 2.96.  */
  62 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
  63 # define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
  64 #else
  65 # define _GL_ATTRIBUTE_PURE /* empty */
  66 #endif
  67
  68 /* The __const__ attribute was added in gcc 2.95.  */
  69 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
  70 # define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
  71 #else
  72 # define _GL_ATTRIBUTE_CONST /* empty */
  73 #endif
  74 ])
  75   dnl Preparation for running test programs:
  76   dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
  77   dnl to /dev/tty, so they can be redirected to log files.  Such diagnostics
  78   dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
  79   LIBC_FATAL_STDERR_=1
  80   export LIBC_FATAL_STDERR_
  81 ])
  82
  83 # gl_MODULE_INDICATOR_CONDITION
  84 # expands to a C preprocessor expression that evaluates to 1 or 0, depending
  85 # whether a gnulib module that has been requested shall be considered present
  86 # or not.
  87 m4_define([gl_MODULE_INDICATOR_CONDITION], [1])
  88
  89 # gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
  90 # sets the shell variable that indicates the presence of the given module to
  91 # a C preprocessor expression that will evaluate to 1.
  92 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
  93 [
  94   gl_MODULE_INDICATOR_SET_VARIABLE_AUX(
  95     [GNULIB_[]m4_translit([[$1]],
  96                           [abcdefghijklmnopqrstuvwxyz./-],
  97                           [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])],
  98     [gl_MODULE_INDICATOR_CONDITION])
  99 ])
 100
 101 # gl_MODULE_INDICATOR_SET_VARIABLE_AUX([variable])
 102 # modifies the shell variable to include the gl_MODULE_INDICATOR_CONDITION.
 103 # The shell variable's value is a C preprocessor expression that evaluates
 104 # to 0 or 1.
 105 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX],
 106 [
 107   m4_if(m4_defn([gl_MODULE_INDICATOR_CONDITION]), [1],
 108     [
 109      dnl Simplify the expression VALUE || 1 to 1.
 110      $1=1
 111     ],
 112     [gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([$1],
 113                                              [gl_MODULE_INDICATOR_CONDITION])])
 114 ])
 115
 116 # gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([variable], [condition])
 117 # modifies the shell variable to include the given condition.  The shell
 118 # variable's value is a C preprocessor expression that evaluates to 0 or 1.
 119 AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR],
 120 [
 121   dnl Simplify the expression 1 || CONDITION to 1.
 122   if test "$[]$1" != 1; then
 123     dnl Simplify the expression 0 || CONDITION to CONDITION.
 124     if test "$[]$1" = 0; then
 125       $1=$2
 126     else
 127       $1="($[]$1 || $2)"
 128     fi
 129   fi
 130 ])
 131
 132 # gl_MODULE_INDICATOR([modulename])
 133 # defines a C macro indicating the presence of the given module
 134 # in a location where it can be used.
 135 #                                             |  Value  |   Value   |
 136 #                                             | in lib/ | in tests/ |
 137 # --------------------------------------------+---------+-----------+
 138 # Module present among main modules:          |    1    |     1     |
 139 # --------------------------------------------+---------+-----------+
 140 # Module present among tests-related modules: |    0    |     1     |
 141 # --------------------------------------------+---------+-----------+
 142 # Module not present at all:                  |    0    |     0     |
 143 # --------------------------------------------+---------+-----------+
 144 AC_DEFUN([gl_MODULE_INDICATOR],
 145 [
 146   AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
 147       [abcdefghijklmnopqrstuvwxyz./-],
 148       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
 149     [gl_MODULE_INDICATOR_CONDITION],
 150     [Define to a C preprocessor expression that evaluates to 1 or 0,
 151      depending whether the gnulib module $1 shall be considered present.])
 152 ])
 153
 154 # gl_MODULE_INDICATOR_FOR_TESTS([modulename])
 155 # defines a C macro indicating the presence of the given module
 156 # in lib or tests. This is useful to determine whether the module
 157 # should be tested.
 158 #                                             |  Value  |   Value   |
 159 #                                             | in lib/ | in tests/ |
 160 # --------------------------------------------+---------+-----------+
 161 # Module present among main modules:          |    1    |     1     |
 162 # --------------------------------------------+---------+-----------+
 163 # Module present among tests-related modules: |    1    |     1     |
 164 # --------------------------------------------+---------+-----------+
 165 # Module not present at all:                  |    0    |     0     |
 166 # --------------------------------------------+---------+-----------+
 167 AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
 168 [
 169   AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
 170       [abcdefghijklmnopqrstuvwxyz./-],
 171       [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
 172     [Define to 1 when the gnulib module $1 should be tested.])
 173 ])
 174
 175 # gl_ASSERT_NO_GNULIB_POSIXCHECK
 176 # asserts that there will never be a need to #define GNULIB_POSIXCHECK.
 177 # and thereby enables an optimization of configure and config.h.
 178 # Used by Emacs.
 179 AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
 180 [
 181   dnl Override gl_WARN_ON_USE_PREPARE.
 182   dnl But hide this definition from 'aclocal'.
 183   AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
 184 ])
 185
 186 # gl_ASSERT_NO_GNULIB_TESTS
 187 # asserts that there will be no gnulib tests in the scope of the configure.ac
 188 # and thereby enables an optimization of config.h.
 189 # Used by Emacs.
 190 AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
 191 [
 192   dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
 193   AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
 194 ])
 195
 196 # Test whether <features.h> exists.
 197 # Set HAVE_FEATURES_H.
 198 AC_DEFUN([gl_FEATURES_H],
 199 [
 200   AC_CHECK_HEADERS_ONCE([features.h])
 201   if test $ac_cv_header_features_h = yes; then
 202     HAVE_FEATURES_H=1
 203   else
 204     HAVE_FEATURES_H=0
 205   fi
 206   AC_SUBST([HAVE_FEATURES_H])
 207 ])
 208
 209 # m4_foreach_w
 210 # is a backport of autoconf-2.59c's m4_foreach_w.
 211 # Remove this macro when we can assume autoconf >= 2.60.
 212 m4_ifndef([m4_foreach_w],
 213   [m4_define([m4_foreach_w],
 214     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
 215
 216 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
 217 # ----------------------------------------------------
 218 # Backport of autoconf-2.63b's macro.
 219 # Remove this macro when we can assume autoconf >= 2.64.
 220 m4_ifndef([AS_VAR_IF],
 221 [m4_define([AS_VAR_IF],
 222 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
 223
 224 # gl_PROG_CC_C99
 225 # Modifies the value of the shell variable CC in an attempt to make $CC
 226 # understand ISO C99 source code.
 227 # This is like AC_PROG_CC_C99, except that
 228 # - AC_PROG_CC_C99 did not exist in Autoconf versions < 2.60,
 229 # - AC_PROG_CC_C99 does not mix well with AC_PROG_CC_STDC
 230 #   <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00367.html>,
 231 #   but many more packages use AC_PROG_CC_STDC than AC_PROG_CC_C99
 232 #   <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00441.html>.
 233 # Remaining problems:
 234 # - When AC_PROG_CC_STDC is invoked twice, it adds the C99 enabling options
 235 #   to CC twice
 236 #   <http://lists.gnu.org/archive/html/bug-gnulib/2011-09/msg00431.html>.
 237 # - AC_PROG_CC_STDC is likely to change now that C11 is an ISO standard.
 238 AC_DEFUN([gl_PROG_CC_C99],
 239 [
 240   dnl Change that version number to the minimum Autoconf version that supports
 241   dnl mixing AC_PROG_CC_C99 calls with AC_PROG_CC_STDC calls.
 242   m4_version_prereq([9.0],
 243     [AC_REQUIRE([AC_PROG_CC_C99])],
 244     [AC_REQUIRE([AC_PROG_CC_STDC])])
 245 ])
 246
 247 # gl_PROG_AR_RANLIB
 248 # Determines the values for AR, ARFLAGS, RANLIB that fit with the compiler.
 249 # The user can set the variables AR, ARFLAGS, RANLIB if he wants to override
 250 # the values.
 251 AC_DEFUN([gl_PROG_AR_RANLIB],
 252 [
 253   dnl Minix 3 comes with two toolchains: The Amsterdam Compiler Kit compiler
 254   dnl as "cc", and GCC as "gcc". They have different object file formats and
 255   dnl library formats. In particular, the GNU binutils programs ar, ranlib
 256   dnl produce libraries that work only with gcc, not with cc.
 257   AC_REQUIRE([AC_PROG_CC])
 258   AC_CACHE_CHECK([for Minix Amsterdam compiler], [gl_cv_c_amsterdam_compiler],
 259     [
 260       AC_EGREP_CPP([Amsterdam],
 261         [
 262 #ifdef __ACK__
 263 Amsterdam
 264 #endif
 265         ],
 266         [gl_cv_c_amsterdam_compiler=yes],
 267         [gl_cv_c_amsterdam_compiler=no])
 268     ])
 269   if test -z "$AR"; then
 270     if test $gl_cv_c_amsterdam_compiler = yes; then
 271       AR='cc -c.a'
 272       if test -z "$ARFLAGS"; then
 273         ARFLAGS='-o'
 274       fi
 275     else
 276       dnl Use the Automake-documented default values for AR and ARFLAGS,
 277       dnl but prefer ${host}-ar over ar (useful for cross-compiling).
 278       AC_CHECK_TOOL([AR], [ar], [ar])
 279       if test -z "$ARFLAGS"; then
 280         ARFLAGS='cru'
 281       fi
 282     fi
 283   else
 284     if test -z "$ARFLAGS"; then
 285       ARFLAGS='cru'
 286     fi
 287   fi
 288   AC_SUBST([AR])
 289   AC_SUBST([ARFLAGS])
 290   if test -z "$RANLIB"; then
 291     if test $gl_cv_c_amsterdam_compiler = yes; then
 292       RANLIB=':'
 293     else
 294       dnl Use the ranlib program if it is available.
 295       AC_PROG_RANLIB
 296     fi
 297   fi
 298   AC_SUBST([RANLIB])
 299 ])
 300
 301 # AC_PROG_MKDIR_P
 302 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
 303 # for interoperability with automake-1.9.6 from autoconf-2.62.
 304 # Remove this macro when we can assume autoconf >= 2.62 or
 305 # autoconf >= 2.60 && automake >= 1.10.
 306 # AC_AUTOCONF_VERSION was introduced in 2.62, so use that as the witness.
 307 m4_ifndef([AC_AUTOCONF_VERSION],[
 308 m4_ifdef([AC_PROG_MKDIR_P], [
 309   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
 310   m4_define([AC_PROG_MKDIR_P],
 311     m4_defn([AC_PROG_MKDIR_P])[
 312     AC_SUBST([MKDIR_P])])], [
 313   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
 314   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
 315     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
 316      MKDIR_P='$(mkdir_p)'
 317      AC_SUBST([MKDIR_P])])])
 318 ])
 319
 320 # AC_C_RESTRICT
 321 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
 322 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
 323 # works.
 324 # This definition can be removed once autoconf >= 2.62 can be assumed.
 325 # AC_AUTOCONF_VERSION was introduced in 2.62, so use that as the witness.
 326 m4_ifndef([AC_AUTOCONF_VERSION],[
 327 AC_DEFUN([AC_C_RESTRICT],
 328 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
 329   [ac_cv_c_restrict=no
 330    # The order here caters to the fact that C++ does not require restrict.
 331    for ac_kw in __restrict __restrict__ _Restrict restrict; do
 332      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 333       [[typedef int * int_ptr;
 334         int foo (int_ptr $ac_kw ip) {
 335         return ip[0];
 336        }]],
 337       [[int s[1];
 338         int * $ac_kw t = s;
 339         t[0] = 0;
 340         return foo(t)]])],
 341       [ac_cv_c_restrict=$ac_kw])
 342      test "$ac_cv_c_restrict" != no && break
 343    done
 344   ])
 345  AH_VERBATIM([restrict],
 346 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 347    nothing if this is not supported.  Do not define if restrict is
 348    supported directly.  */
 349 #undef restrict
 350 /* Work around a bug in Sun C++: it does not support _Restrict, even
 351    though the corresponding Sun C compiler does, which causes
 352    "#define restrict _Restrict" in the previous line.  Perhaps some future
 353    version of Sun C++ will work with _Restrict; if so, it'll probably
 354    define __RESTRICT, just as Sun C does.  */
 355 #if defined __SUNPRO_CC && !defined __RESTRICT
 356 # define _Restrict
 357 #endif])
 358  case $ac_cv_c_restrict in
 359    restrict) ;;
 360    no) AC_DEFINE([restrict], []) ;;
 361    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 362  esac
 363 ])
 364 ])
 365
 366 # gl_BIGENDIAN
 367 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 368 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 369 # macros invoke AC_C_BIGENDIAN with arguments.
 370 AC_DEFUN([gl_BIGENDIAN],
 371 [
 372   AC_C_BIGENDIAN
 373 ])
 374
 375 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 376 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 377 # output a spurious "(cached)" mark in the midst of other configure output.
 378 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 379 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 380 AC_DEFUN([gl_CACHE_VAL_SILENT],
 381 [
 382   saved_as_echo_n="$as_echo_n"
 383   as_echo_n=':'
 384   AC_CACHE_VAL([$1], [$2])
 385   as_echo_n="$saved_as_echo_n"
 386 ])
 387
 388 # AS_VAR_COPY was added in autoconf 2.63b
 389 m4_define_default([AS_VAR_COPY],
 390 [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 391
 392 # AC_PROG_SED was added in autoconf 2.59b
 393 m4_ifndef([AC_PROG_SED],
 394 [AC_DEFUN([AC_PROG_SED],
 395 [AC_CACHE_CHECK([for a sed that does not truncate output], ac_cv_path_SED,
 396     [dnl ac_script should not contain more than 99 commands (for HP-UX sed),
 397      dnl but more than about 7000 bytes, to catch a limit in Solaris 8 /usr/ucb/sed.
 398      ac_script=s/aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa/bbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbb/
 399      for ac_i in 1 2 3 4 5 6 7; do
 400        ac_script="$ac_script$as_nl$ac_script"
 401      done
 402      echo "$ac_script" 2>/dev/null | sed 99q >conftest.sed
 403      AS_UNSET([ac_script])
 404      if test -z "$SED"; then
 405        ac_path_SED_found=false
 406        _AS_PATH_WALK([], [
 407          for ac_prog in sed gsed; do
 408            for ac_exec_ext in '' $ac_executable_extensions; do
 409              ac_path_SED="$as_dir/$ac_prog$ac_exec_ext"
 410              AS_EXECUTABLE_P(["$ac_path_SED"]) || continue
 411              case `"$ac_path_SED" --version 2>&1` in
 412                *GNU*) ac_cv_path_SED=$ac_path_SED ac_path_SED_found=:;;
 413                *)
 414                  ac_count=0
 415                  _AS_ECHO_N([0123456789]) >conftest.in
 416                  while :
 417                  do
 418                    cat conftest.in conftest.in >conftest.tmp
 419                    mv conftest.tmp conftest.in
 420                    cp conftest.in conftest.nl
 421                    echo >> conftest.nl
 422                    "$ac_path_SED" -f conftest.sed <conftest.nl >conftest.out 2>/dev/null || break
 423                    diff conftest.out conftest.nl >/dev/null 2>&1 || break
 424                    ac_count=`expr $ac_count + 1`
 425                    if test $ac_count -gt ${ac_path_SED_max-0}; then
 426                      # Best so far, but keep looking for better
 427                      ac_cv_path_SED=$ac_path_SED
 428                      ac_path_SED_max=$ac_count
 429                    fi
 430                    test $ac_count -gt 10 && break
 431                  done
 432                  rm -f conftest.in conftest.tmp conftest.nl conftest.out;;
 433              esac
 434              $ac_path_SED_found && break 3
 435            done
 436          done])
 437        if test -z "$ac_cv_path_SED"; then
 438          AC_ERROR([no acceptable sed could be found in \$PATH])
 439        fi
 440      else
 441        ac_cv_path_SED=$SED
 442      fi
 443  SED="$ac_cv_path_SED"
 444  AC_SUBST([SED])dnl
 445  rm -f conftest.sed
 446 ])])])