lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Authors: Roland McGrath <roland@gnu.org>,
   8 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   9 ;; Maintainer: FSF
  10 ;; Keywords: tools, processes
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This package provides the compile facilities documented in the Emacs user's
  30 ;; manual.
  31
  32 ;; This mode uses some complex data-structures:
  33
  34 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  35
  36 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  37 ;; LINE will be nil for a message that doesn't contain them.  Then the
  38 ;; location refers to a indented beginning of line or beginning of file.
  39 ;; Once any location in some file has been jumped to, the list is extended to
  40 ;; (COLUMN LINE FILE-STRUCTURE MARKER TIMESTAMP . VISITED)
  41 ;; for all LOCs pertaining to that file.
  42 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  43 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  44 ;; before that point.  VISITED is t if we have jumped there, else nil.
  45 ;; TIMESTAMP is necessary because of "incremental compilation": `omake -P'
  46 ;; polls filesystem for changes and recompiles when a file is modified
  47 ;; using the same *compilation* buffer. this necessitates re-parsing markers.
  48
  49 ;;   FILE-STRUCTURE is a list of
  50 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  51
  52 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  53 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  54 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  55 ;; a file of that name can't be found.
  56 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  57 ;; are either nil or line numbers.  If present, nil comes first, followed by
  58 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  59 ;; ordered the same way.  Note that the whole file structure is referenced in
  60 ;; every LOC.
  61
  62 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  63
  64 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  65 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  66 ;; other end, if the parsed message contained a range.  If the end of the
  67 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  68 ;; These are the value of the `message' text-properties in the compilation
  69 ;; buffer.
  70
  71 ;;; Code:
  72
  73 (eval-when-compile (require 'cl))
  74 (require 'tool-bar)
  75 (require 'comint)
  76
  77 (defvar font-lock-extra-managed-props)
  78 (defvar font-lock-keywords)
  79 (defvar font-lock-maximum-size)
  80 (defvar font-lock-support-mode)
  81
  82
  83 (defgroup compilation nil
  84   "Run compiler as inferior of Emacs, parse error messages."
  85   :group 'tools
  86   :group 'processes)
  87
  88
  89 ;;;###autoload
  90 (defcustom compilation-mode-hook nil
  91   "List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  92   :type 'hook
  93   :group 'compilation)
  94
  95 ;;;###autoload
  96 (defcustom compilation-start-hook nil
  97   "List of hook functions run by `compilation-start' on the compilation process.
  98 \(See `run-hook-with-args').
  99 If you use \"omake -P\" and do not want \\[save-buffers-kill-terminal] to ask whether you want
 100 the compilation to be killed, you can use this hook:
 101   (add-hook 'compilation-start-hook
 102     (lambda (process) (set-process-query-on-exit-flag process nil)) nil t)"
 103   :type 'hook
 104   :group 'compilation)
 105
 106 ;;;###autoload
 107 (defcustom compilation-window-height nil
 108   "Number of lines in a compilation window.  If nil, use Emacs default."
 109   :type '(choice (const :tag "Default" nil)
 110                  integer)
 111   :group 'compilation)
 112
 113 (defvar compilation-first-column 1
 114   "*This is how compilers number the first column, usually 1 or 0.")
 115
 116 (defvar compilation-parse-errors-filename-function nil
 117   "Function to call to post-process filenames while parsing error messages.
 118 It takes one arg FILENAME which is the name of a file as found
 119 in the compilation output, and should return a transformed file name.")
 120
 121 ;;;###autoload
 122 (defvar compilation-process-setup-function nil
 123   "*Function to call to customize the compilation process.
 124 This function is called immediately before the compilation process is
 125 started.  It can be used to set any variables or functions that are used
 126 while processing the output of the compilation process.  The function
 127 is called with variables `compilation-buffer' and `compilation-window'
 128 bound to the compilation buffer and window, respectively.")
 129
 130 ;;;###autoload
 131 (defvar compilation-buffer-name-function nil
 132   "Function to compute the name of a compilation buffer.
 133 The function receives one argument, the name of the major mode of the
 134 compilation buffer.  It should return a string.
 135 If nil, compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 136
 137 ;;;###autoload
 138 (defvar compilation-finish-function nil
 139   "Function to call when a compilation process finishes.
 140 It is called with two arguments: the compilation buffer, and a string
 141 describing how the process finished.")
 142
 143 (make-obsolete-variable 'compilation-finish-function
 144   "use `compilation-finish-functions', but it works a little differently."
 145   "22.1")
 146
 147 ;;;###autoload
 148 (defvar compilation-finish-functions nil
 149   "Functions to call when a compilation process finishes.
 150 Each function is called with two arguments: the compilation buffer,
 151 and a string describing how the process finished.")
 152
 153 (defvar compilation-in-progress nil
 154   "List of compilation processes now running.")
 155 (or (assq 'compilation-in-progress minor-mode-alist)
 156     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 157                                  minor-mode-alist)))
 158
 159 (defvar compilation-error "error"
 160   "Stem of message to print when no matches are found.")
 161
 162 (defvar compilation-arguments nil
 163   "Arguments that were given to `compilation-start'.")
 164
 165 (defvar compilation-num-errors-found)
 166
 167 (defconst compilation-error-regexp-alist-alist
 168   '((absoft
 169      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 170 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 171
 172     (ada
 173      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 174
 175     (aix
 176      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 177
 178     (ant
 179      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 180 \\( warning\\)?" 1 2 3 (4))
 181
 182     (bash
 183      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 184
 185     (borland
 186      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 187 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 188  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 189
 190     (caml
 191      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 192 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 193      2 (3 . 4) (5 . 6) (7))
 194
 195     (comma
 196      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 197 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 198
 199     (edg-1
 200      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 201      1 2 nil (3 . 4))
 202     (edg-2
 203      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 204      2 1 nil 0)
 205
 206     (epc
 207      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 208
 209     (ftnchek
 210      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 211      4 2 3 (1))
 212
 213     (iar
 214      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 215      1 2 nil (3))
 216
 217     (ibm
 218      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 219  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 220
 221     ;; fixme: should be `mips'
 222     (irix
 223      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 224 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 225
 226     (java
 227      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 228
 229     (jikes-file
 230      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 231     (jikes-line
 232      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 233      nil 1 nil 2 0
 234      (2 (compilation-face '(3))))
 235
 236     (gnu
 237      ;; The first line matches the program name for
 238
 239      ;;     PROGRAM:SOURCE-FILE-NAME:LINENO: MESSAGE
 240
 241      ;; format, which is used for non-interactive programs other than
 242      ;; compilers (e.g. the "jade:" entry in compilation.txt).
 243
 244      ;; This first line makes things ambiguous with output such as
 245      ;; "foo:344:50:blabla" since the "foo" part can match this first
 246      ;; line (in which case the file name as "344").  To avoid this,
 247      ;; the second line disallows filenames exclusively composed of
 248      ;; digits.
 249
 250      ;; Similarly, we get lots of false positives with messages including
 251      ;; times of the form "HH:MM:SS" where MM is taken as a line number, so
 252      ;; the last line tries to rule out message where the info after the
 253      ;; line number starts with "SS".  --Stef
 254
 255      ;; The core of the regexp is the one with *?.  It says that a file name
 256      ;; can be composed of any non-newline char, but it also rules out some
 257      ;; valid but unlikely cases, such as a trailing space or a space
 258      ;; followed by a -.
 259      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 260 \\([0-9]*[^0-9\n]\\(?:[^\n ]\\| [^-/\n]\\)*?\\): ?\
 261 \\([0-9]+\\)\\(?:\\([.:]\\)\\([0-9]+\\)\\)?\
 262 \\(?:-\\([0-9]+\\)?\\(?:\\.\\([0-9]+\\)\\)?\\)?:\
 263 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 264  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\|instantiated from\\|[Nn]ote\\)\\|\
 265 \[0-9]?\\(?:[^0-9\n]\\|$\\)\\|[0-9][0-9][0-9]\\)"
 266      1 (2 . 5) (4 . 6) (7 . 8))
 267
 268     ;; The `gnu' style above can incorrectly match gcc's "In file
 269     ;; included from" message, so we process that first. -- cyd
 270     (gcc-include
 271      "^\\(?:In file included\\|                \\) from \
 272 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 273
 274     (lcc
 275      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 276      2 3 4 (1))
 277
 278     (makepp
 279      "^makepp\\(?:\\(?:: warning\\(:\\).*?\\|\\(: Scanning\\|: [LR]e?l?oading makefile\\|: Imported\\|log:.*?\\) \\|: .*?\\)\
 280 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 281      4 5 nil (1 . 2) 3
 282      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 283       (2 compilation-info-face)
 284       (3 compilation-line-face nil t)
 285       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 286          append)))
 287
 288     ;; This regexp is pathologically slow on long lines (Bug#3441).
 289     ;; (maven
 290     ;;  ;; Maven is a popular build tool for Java.  Maven is Free Software.
 291     ;;  "\\(.*?\\):\\[\\([0-9]+\\),\\([0-9]+\\)\\]" 1 2 3)
 292
 293     ;; Should be lint-1, lint-2 (SysV lint)
 294     (mips-1
 295      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 296     (mips-2
 297      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 298
 299     (msft
 300      ;; The message may be a "warning", "error", or "fatal error" with
 301      ;; an error code, or "see declaration of" without an error code.
 302      "^ *\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 303 : \\(?:see declaration\\|\\(?:warnin\\(g\\)\\|[a-z ]+\\) C[0-9]+:\\)"
 304      2 3 nil (4))
 305
 306     (omake
 307      ;; "omake -P" reports "file foo changed"
 308      ;; (useful if you do "cvs up" and want to see what has changed)
 309      "omake: file \\(.*\\) changed" 1)
 310
 311     (oracle
 312      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 313 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 314 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 315      3 1 2)
 316
 317     ;; "during global destruction": This comes out under "use
 318     ;; warnings" in recent perl when breaking circular references
 319     ;; during program or thread exit.
 320     (perl
 321      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\| \
 322 during global destruction\\.$\\)" 1 2)
 323
 324     (php
 325      "\\(?:Parse\\|Fatal\\) error: \\(.*\\) in \\(.*\\) on line \\([0-9]+\\)"
 326      2 3 nil nil)
 327
 328     (rxp
 329      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 330  \\([0-9]+\\) of file://\\(.+\\)"
 331      4 2 3 (1))
 332
 333     (sparc-pascal-file
 334      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 335  [12][09][0-9][0-9] +\\(.*\\):$"
 336      1 nil nil 0)
 337     (sparc-pascal-line
 338      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 339      nil 3 nil (2) nil (1 (compilation-face '(2))))
 340     (sparc-pascal-example
 341      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 342      nil 1 nil (3) nil (2 (compilation-face '(3))))
 343
 344     (sun
 345      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 346 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 347      3 4 5 (1 . 2))
 348
 349     (sun-ada
 350      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 351
 352     (watcom
 353      "\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)): ?\
 354 \\(?:\\(Error! E[0-9]+\\)\\|\\(Warning! W[0-9]+\\)\\):"
 355      1 2 nil (4))
 356
 357     (4bsd
 358      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 359 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 360
 361     (gcov-file
 362      "^ *-: *\\(0\\):Source:\\(.+\\)$"
 363      2 1 nil 0 nil
 364      (1 compilation-line-face prepend) (2 compilation-info-face prepend))
 365     (gcov-header
 366      "^ *-: *\\(0\\):\\(?:Object\\|Graph\\|Data\\|Runs\\|Programs\\):.+$"
 367      nil 1 nil 0 nil
 368      (1 compilation-line-face prepend))
 369     ;; Underlines over all lines of gcov output are too uncomfortable to read.
 370     ;; However, hyperlinks embedded in the lines are useful.
 371     ;; So I put default face on the lines; and then put
 372     ;; compilation-*-face by manually to eliminate the underlines.
 373     ;; The hyperlinks are still effective.
 374     (gcov-nomark
 375      "^ *-: *\\([1-9]\\|[0-9]\\{2,\\}\\):.*$"
 376      nil 1 nil 0 nil
 377      (0 'default t)
 378      (1 compilation-line-face prepend))
 379     (gcov-called-line
 380      "^ *\\([0-9]+\\): *\\([0-9]+\\):.*$"
 381      nil 2 nil 0 nil
 382      (0 'default t)
 383      (1 compilation-info-face prepend) (2 compilation-line-face prepend))
 384     (gcov-never-called
 385      "^ *\\(#####\\): *\\([0-9]+\\):.*$"
 386      nil 2 nil 2 nil
 387      (0 'default t)
 388      (1 compilation-error-face prepend) (2 compilation-line-face prepend))
 389
 390     (perl--Pod::Checker
 391      ;; podchecker error messages, per Pod::Checker.
 392      ;; The style is from the Pod::Checker::poderror() function, eg.
 393      ;; *** ERROR: Spurious text after =cut at line 193 in file foo.pm
 394      ;;
 395      ;; Plus end_pod() can give "at line EOF" instead of a
 396      ;; number, so for that match "on line N" which is the
 397      ;; originating spot, eg.
 398      ;; *** ERROR: =over on line 37 without closing =back at line EOF in file bar.pm
 399      ;;
 400      ;; Plus command() can give both "on line N" and "at line N";
 401      ;; the latter is desired and is matched because the .* is
 402      ;; greedy.
 403      ;; *** ERROR: =over on line 1 without closing =back (at head1) at line 3 in file x.pod
 404      ;;
 405      "^\\*\\*\\* \\(?:ERROR\\|\\(WARNING\\)\\).* \\(?:at\\|on\\) line \
 406 \\([0-9]+\\) \\(?:.* \\)?in file \\([^ \t\n]+\\)"
 407      3 2 nil (1))
 408     (perl--Test
 409      ;; perl Test module error messages.
 410      ;; Style per the ok() function "$context", eg.
 411      ;; # Failed test 1 in foo.t at line 6
 412      ;;
 413      "^# Failed test [0-9]+ in \\([^ \t\r\n]+\\) at line \\([0-9]+\\)"
 414      1 2)
 415     (perl--Test2
 416      ;; Or when comparing got/want values,
 417      ;; # Test 2 got: "xx" (t-compilation-perl-2.t at line 10)
 418      ;;
 419      ;; And under Test::Harness they're preceded by progress stuff with
 420      ;; \r and "NOK",
 421      ;; ... NOK 1# Test 1 got: "1234" (t/foo.t at line 46)
 422      ;;
 423      "^\\(.*NOK.*\\)?# Test [0-9]+ got:.* (\\([^ \t\r\n]+\\) at line \
 424 \\([0-9]+\\))"
 425      2 3)
 426     (perl--Test::Harness
 427      ;; perl Test::Harness output, eg.
 428      ;; NOK 1# Test 1 got: "1234" (t/foo.t at line 46)
 429      ;;
 430      ;; Test::Harness is slightly designed for tty output, since
 431      ;; it prints CRs to overwrite progress messages, but if you
 432      ;; run it in with M-x compile this pattern can at least step
 433      ;; through the failures.
 434      ;;
 435      "^.*NOK.* \\([^ \t\r\n]+\\) at line \\([0-9]+\\)"
 436      1 2)
 437     (weblint
 438      ;; The style comes from HTML::Lint::Error::as_string(), eg.
 439      ;; index.html (13:1) Unknown element <fdjsk>
 440      ;;
 441      ;; The pattern only matches filenames without spaces, since that
 442      ;; should be usual and should help reduce the chance of a false
 443      ;; match of a message from some unrelated program.
 444      ;;
 445      ;; This message style is quite close to the "ibm" entry which is
 446      ;; for IBM C, though that ibm bit doesn't put a space after the
 447      ;; filename.
 448      ;;
 449      "^\\([^ \t\r\n(]+\\) (\\([0-9]+\\):\\([0-9]+\\)) "
 450      1 2 3)
 451     )
 452   "Alist of values for `compilation-error-regexp-alist'.")
 453
 454 (defcustom compilation-error-regexp-alist
 455   (mapcar 'car compilation-error-regexp-alist-alist)
 456   "Alist that specifies how to match errors in compiler output.
 457 On GNU and Unix, any string is a valid filename, so these
 458 matchers must make some common sense assumptions, which catch
 459 normal cases.  A shorter list will be lighter on resource usage.
 460
 461 Instead of an alist element, you can use a symbol, which is
 462 looked up in `compilation-error-regexp-alist-alist'.  You can see
 463 the predefined symbols and their effects in the file
 464 `etc/compilation.txt' (linked below if you are customizing this).
 465
 466 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 467 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 468 gives the file name, and the LINE'th subexpression gives the line
 469 number.  The COLUMN'th subexpression gives the column number on
 470 that line.
 471
 472 If FILE, LINE or COLUMN are nil or that index didn't match, that
 473 information is not present on the matched line.  In that case the
 474 file name is assumed to be the same as the previous one in the
 475 buffer, line number defaults to 1 and column defaults to
 476 beginning of line's indentation.
 477
 478 FILE can also have the form (FILE FORMAT...), where the FORMATs
 479 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 480 name, until a file of that name is found.  Or FILE can also be a
 481 function that returns (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
 482 In the former case, FILENAME may be relative or absolute.
 483
 484 LINE can also be of the form (LINE . END-LINE) meaning a range
 485 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 486 meaning a range of columns starting on LINE and ending on
 487 END-LINE, if that matched.
 488
 489 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 490 TYPE can also be of the form (WARNING . INFO).  In that case this
 491 will be equivalent to 1 if the WARNING'th subexpression matched
 492 or else equivalent to 0 if the INFO'th subexpression matched.
 493 See `compilation-error-face', `compilation-warning-face',
 494 `compilation-info-face' and `compilation-skip-threshold'.
 495
 496 What matched the HYPERLINK'th subexpression has `mouse-face' and
 497 `compilation-message-face' applied.  If this is nil, the text
 498 matched by the whole REGEXP becomes the hyperlink.
 499
 500 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 501 be added."
 502   :type `(set :menu-tag "Pick"
 503               ,@(mapcar (lambda (elt)
 504                           (list 'const (car elt)))
 505                         compilation-error-regexp-alist-alist))
 506   :link `(file-link :tag "example file"
 507                     ,(expand-file-name "compilation.txt" data-directory))
 508   :group 'compilation)
 509
 510 ;;;###autoload(put 'compilation-directory 'safe-local-variable 'stringp)
 511 (defvar compilation-directory nil
 512   "Directory to restore to when doing `recompile'.")
 513
 514 (defvar compilation-directory-matcher
 515   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 516   "A list for tracking when directories are entered or left.
 517 If nil, do not track directories, e.g. if all file names are absolute.  The
 518 first element is the REGEXP matching these messages.  It can match any number
 519 of variants, e.g. different languages.  The remaining elements are all of the
 520 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 521 matches, that is a directory name.  If LEAVE is nil or the corresponding
 522 LEAVE'th subexpression doesn't match, this message is about going into another
 523 directory.  If it does match anything, this message is about going back to the
 524 directory we were in before the last entering message.  If you change this,
 525 you may also want to change `compilation-page-delimiter'.")
 526
 527 (defvar compilation-page-delimiter
 528   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 529   "Value of `page-delimiter' in Compilation mode.")
 530
 531 (defvar compilation-mode-font-lock-keywords
 532    '(;; configure output lines.
 533      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 534       (1 font-lock-variable-name-face)
 535       (2 (compilation-face '(4 . 3))))
 536      ;; Command output lines.  Recognize `make[n]:' lines too.
 537      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 538       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 539      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 540      ("^Compilation \\(finished\\).*"
 541       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 542       (1 compilation-info-face))
 543      ("^Compilation \\(exited abnormally\\|interrupt\\|killed\\|terminated\\|segmentation fault\\)\\(?:.*with code \\([0-9]+\\)\\)?.*"
 544       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 545       (1 compilation-error-face)
 546       (2 compilation-error-face nil t)))
 547    "Additional things to highlight in Compilation mode.
 548 This gets tacked on the end of the generated expressions.")
 549
 550 (defvar compilation-highlight-regexp t
 551   "Regexp matching part of visited source lines to highlight temporarily.
 552 Highlight entire line if t; don't highlight source lines if nil.")
 553
 554 (defvar compilation-highlight-overlay nil
 555   "Overlay used to temporarily highlight compilation matches.")
 556
 557 (defcustom compilation-error-screen-columns t
 558   "If non-nil, column numbers in error messages are screen columns.
 559 Otherwise they are interpreted as character positions, with
 560 each character occupying one column.
 561 The default is to use screen columns, which requires that the compilation
 562 program and Emacs agree about the display width of the characters,
 563 especially the TAB character."
 564   :type 'boolean
 565   :group 'compilation
 566   :version "20.4")
 567
 568 (defcustom compilation-read-command t
 569   "Non-nil means \\[compile] reads the compilation command to use.
 570 Otherwise, \\[compile] just uses the value of `compile-command'."
 571   :type 'boolean
 572   :group 'compilation)
 573
 574 ;;;###autoload
 575 (defcustom compilation-ask-about-save t
 576   "Non-nil means \\[compile] asks which buffers to save before compiling.
 577 Otherwise, it saves all modified buffers without asking."
 578   :type 'boolean
 579   :group 'compilation)
 580
 581 ;;;###autoload
 582 (defcustom compilation-search-path '(nil)
 583   "List of directories to search for source files named in error messages.
 584 Elements should be directory names, not file names of directories.
 585 The value nil as an element means to try the default directory."
 586   :type '(repeat (choice (const :tag "Default" nil)
 587                          (string :tag "Directory")))
 588   :group 'compilation)
 589
 590 ;;;###autoload
 591 (defcustom compile-command "make -k "
 592   "Last shell command used to do a compilation; default for next compilation.
 593
 594 Sometimes it is useful for files to supply local values for this variable.
 595 You might also use mode hooks to specify it in certain modes, like this:
 596
 597     (add-hook 'c-mode-hook
 598        (lambda ()
 599          (unless (or (file-exists-p \"makefile\")
 600                      (file-exists-p \"Makefile\"))
 601            (set (make-local-variable 'compile-command)
 602                 (concat \"make -k \"
 603                         (file-name-sans-extension buffer-file-name))))))"
 604   :type 'string
 605   :group 'compilation)
 606 ;;;###autoload(put 'compile-command 'safe-local-variable 'stringp)
 607
 608 ;;;###autoload
 609 (defcustom compilation-disable-input nil
 610   "If non-nil, send end-of-file as compilation process input.
 611 This only affects platforms that support asynchronous processes (see
 612 `start-process'); synchronous compilation processes never accept input."
 613   :type 'boolean
 614   :group 'compilation
 615   :version "22.1")
 616
 617 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 618 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 619 ;; key.  This holds the tree seen from root, for storing new nodes.
 620 (defvar compilation-locs ())
 621
 622 (defvar compilation-debug nil
 623   "*Set this to t before creating a *compilation* buffer.
 624 Then every error line will have a debug text property with the matcher that
 625 fit this line and the match data.  Use `describe-text-properties'.")
 626
 627 (defvar compilation-exit-message-function nil "\
 628 If non-nil, called when a compilation process dies to return a status message.
 629 This should be a function of three arguments: process status, exit status,
 630 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 631 write into the compilation buffer, and to put in its mode line.")
 632
 633 (defvar compilation-environment nil
 634   "*List of environment variables for compilation to inherit.
 635 Each element should be a string of the form ENVVARNAME=VALUE.
 636 This list is temporarily prepended to `process-environment' prior to
 637 starting the compilation process.")
 638
 639 ;; History of compile commands.
 640 (defvar compile-history nil)
 641
 642 (defface compilation-error
 643   '((t :inherit font-lock-warning-face))
 644   "Face used to highlight compiler errors."
 645   :group 'compilation
 646   :version "22.1")
 647
 648 (defface compilation-warning
 649   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 650     (((class color)) (:foreground "cyan" :weight bold))
 651     (t (:weight bold)))
 652   "Face used to highlight compiler warnings."
 653   :group 'compilation
 654   :version "22.1")
 655
 656 (defface compilation-info
 657   '((((class color) (min-colors 16) (background light))
 658      (:foreground "Green3" :weight bold))
 659     (((class color) (min-colors 88) (background dark))
 660      (:foreground "Green1" :weight bold))
 661     (((class color) (min-colors 16) (background dark))
 662      (:foreground "Green" :weight bold))
 663     (((class color)) (:foreground "green" :weight bold))
 664     (t (:weight bold)))
 665   "Face used to highlight compiler information."
 666   :group 'compilation
 667   :version "22.1")
 668
 669 (defface compilation-line-number
 670   '((t :inherit font-lock-variable-name-face))
 671   "Face for displaying line numbers in compiler messages."
 672   :group 'compilation
 673   :version "22.1")
 674
 675 (defface compilation-column-number
 676   '((t :inherit font-lock-type-face))
 677   "Face for displaying column numbers in compiler messages."
 678   :group 'compilation
 679   :version "22.1")
 680
 681 (defcustom compilation-message-face 'underline
 682   "Face name to use for whole messages.
 683 Faces `compilation-error-face', `compilation-warning-face',
 684 `compilation-info-face', `compilation-line-face' and
 685 `compilation-column-face' get prepended to this, when applicable."
 686   :type 'face
 687   :group 'compilation
 688   :version "22.1")
 689
 690 (defvar compilation-error-face 'compilation-error
 691   "Face name to use for file name in error messages.")
 692
 693 (defvar compilation-warning-face 'compilation-warning
 694   "Face name to use for file name in warning messages.")
 695
 696 (defvar compilation-info-face 'compilation-info
 697   "Face name to use for file name in informational messages.")
 698
 699 (defvar compilation-line-face 'compilation-line-number
 700   "Face name to use for line numbers in compiler messages.")
 701
 702 (defvar compilation-column-face 'compilation-column-number
 703   "Face name to use for column numbers in compiler messages.")
 704
 705 ;; same faces as dired uses
 706 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 707   "Face name to use for entering directory messages.")
 708
 709 (defvar compilation-leave-directory-face 'font-lock-type-face
 710   "Face name to use for leaving directory messages.")
 711
 712
 713
 714 ;; Used for compatibility with the old compile.el.
 715 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 716 (defvar compilation-parsing-end (make-marker))
 717 (defvar compilation-parse-errors-function nil)
 718 (defvar compilation-error-list nil)
 719 (defvar compilation-old-error-list nil)
 720
 721 (defcustom compilation-auto-jump-to-first-error nil
 722   "If non-nil, automatically jump to the first error during compilation."
 723   :type 'boolean
 724   :group 'compilation
 725   :version "23.1")
 726
 727 (defvar compilation-auto-jump-to-next nil
 728   "If non-nil, automatically jump to the next error encountered.")
 729 (make-variable-buffer-local 'compilation-auto-jump-to-next)
 730
 731
 732 (defvar compilation-skip-to-next-location t
 733   "*If non-nil, skip multiple error messages for the same source location.")
 734
 735 (defcustom compilation-skip-threshold 1
 736   "Compilation motion commands skip less important messages.
 737 The value can be either 2 -- skip anything less than error, 1 --
 738 skip anything less than warning or 0 -- don't skip any messages.
 739 Note that all messages not positively identified as warning or
 740 info, are considered errors."
 741   :type '(choice (const :tag "Warnings and info" 2)
 742                  (const :tag "Info" 1)
 743                  (const :tag "None" 0))
 744   :group 'compilation
 745   :version "22.1")
 746
 747 (defcustom compilation-skip-visited nil
 748   "Compilation motion commands skip visited messages if this is t.
 749 Visited messages are ones for which the file, line and column have been jumped
 750 to from the current content in the current compilation buffer, even if it was
 751 from a different message."
 752   :type 'boolean
 753   :group 'compilation
 754   :version "22.1")
 755
 756 (defun compilation-face (type)
 757   (or (and (car type) (match-end (car type)) compilation-warning-face)
 758       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 759       compilation-error-face))
 760
 761 ;; Internal function for calculating the text properties of a directory
 762 ;; change message.  The directory property is important, because it is
 763 ;; the stack of nested enter-messages.  Relative filenames on the following
 764 ;; lines are relative to the top of the stack.
 765 (defun compilation-directory-properties (idx leave)
 766   (if leave (setq leave (match-end leave)))
 767   ;; find previous stack, and push onto it, or if `leave' pop it
 768   (let ((dir (previous-single-property-change (point) 'directory)))
 769     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 770                           (get-text-property dir 'directory))))
 771     `(face ,(if leave
 772                 compilation-leave-directory-face
 773               compilation-enter-directory-face)
 774       directory ,(if leave
 775                      (or (cdr dir)
 776                          '(nil))        ; nil only isn't a property-change
 777                    (cons (match-string-no-properties idx) dir))
 778       mouse-face highlight
 779       keymap compilation-button-map
 780       help-echo "mouse-2: visit destination directory")))
 781
 782 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 783 ;; KEY element from the ALIST, creating it in the right position if not already
 784 ;; present. ALIST structure is
 785 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 786 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 787 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 788 ;; numbers can be inserted in front and searching can abort after half the
 789 ;; list on average.
 790 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 791 (defmacro compilation-assq (key alist)
 792   `(let* ((l1 ,alist)
 793           (l2 (cdr l1)))
 794      (car (if (if (null ,key)
 795                   (if l2 (null (caar l2)))
 796                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 797                   (setq l1 l2
 798                         l2 (cdr l1)))
 799                 (if l2 (eq ,key (caar l2))))
 800               l2
 801             (setcdr l1 (cons (list ,key) l2)))))))
 802
 803 (defun compilation-auto-jump (buffer pos)
 804   (with-current-buffer buffer
 805     (goto-char pos)
 806     (let ((win (get-buffer-window buffer 0)))
 807       (if win (set-window-point win pos)))
 808     (if compilation-auto-jump-to-first-error
 809         (compile-goto-error))))
 810
 811 ;; This function is the central driver, called when font-locking to gather
 812 ;; all information needed to later jump to corresponding source code.
 813 ;; Return a property list with all meta information on this error location.
 814
 815 (defun compilation-error-properties (file line end-line col end-col type fmt)
 816   (unless (< (next-single-property-change (match-beginning 0)
 817                                           'directory nil (point))
 818              (point))
 819     (if file
 820         (if (functionp file)
 821             (setq file (funcall file))
 822           (let (dir)
 823             (setq file (match-string-no-properties file))
 824             (unless (file-name-absolute-p file)
 825               (setq dir (previous-single-property-change (point) 'directory)
 826                     dir (if dir (or (get-text-property (1- dir) 'directory)
 827                                     (get-text-property dir 'directory)))))
 828             (setq file (cons file (car dir)))))
 829       ;; This message didn't mention one, get it from previous
 830       (let ((prev-pos
 831              ;; Find the previous message.
 832              (previous-single-property-change (point) 'message)))
 833         (if prev-pos
 834             ;; Get the file structure that belongs to it.
 835             (let* ((prev
 836                     (or (get-text-property (1- prev-pos) 'message)
 837                         (get-text-property prev-pos 'message)))
 838                    (prev-struct
 839                     (car (nth 2 (car prev)))))
 840               ;; Construct FILE . DIR from that.
 841               (if prev-struct
 842                   (setq file (cons (car prev-struct)
 843                                    (cadr prev-struct))))))
 844         (unless file
 845           (setq file '("*unknown*")))))
 846     ;; All of these fields are optional, get them only if we have an index, and
 847     ;; it matched some part of the message.
 848     (and line
 849          (setq line (match-string-no-properties line))
 850          (setq line (string-to-number line)))
 851     (and end-line
 852          (setq end-line (match-string-no-properties end-line))
 853          (setq end-line (string-to-number end-line)))
 854     (if col
 855         (if (functionp col)
 856             (setq col (funcall col))
 857           (and
 858            (setq col (match-string-no-properties col))
 859            (setq col (- (string-to-number col) compilation-first-column)))))
 860     (if (and end-col (functionp end-col))
 861         (setq end-col (funcall end-col))
 862       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 863           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 864         (if end-line (setq end-col -1))))
 865     (if (consp type)                    ; not a static type, check what it is.
 866         (setq type (or (and (car type) (match-end (car type)) 1)
 867                        (and (cdr type) (match-end (cdr type)) 0)
 868                        2)))
 869
 870     (when (and compilation-auto-jump-to-next
 871                (>= type compilation-skip-threshold))
 872       (kill-local-variable 'compilation-auto-jump-to-next)
 873       (run-with-timer 0 nil 'compilation-auto-jump
 874                       (current-buffer) (match-beginning 0)))
 875
 876     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 877
 878 (defun compilation-move-to-column (col screen)
 879   "Go to column COL on the current line.
 880 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 881 just char-counts."
 882   (if screen
 883       (move-to-column (max col 0))
 884     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 885
 886 (defun compilation-internal-error-properties (file line end-line col end-col type fmts)
 887   "Get the meta-info that will be added as text-properties.
 888 LINE, END-LINE, COL, END-COL are integers or nil.
 889 TYPE can be 0, 1, or 2, meaning error, warning, or just info.
 890 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil.
 891 FMTS is a list of format specs for transforming the file name.
 892  (See `compilation-error-regexp-alist'.)"
 893   (unless file (setq file '("*unknown*")))
 894   (let* ((file-struct (compilation-get-file-structure file fmts))
 895          ;; Get first already existing marker (if any has one, all have one).
 896          ;; Do this first, as the compilation-assq`s may create new nodes.
 897          (marker-line (car (cddr file-struct))) ; a line structure
 898          (marker (nth 3 (cadr marker-line)))    ; its marker
 899          (compilation-error-screen-columns compilation-error-screen-columns)
 900          end-marker loc end-loc)
 901     (if (not (and marker (marker-buffer marker)))
 902         (setq marker nil)               ; no valid marker for this file
 903       (setq loc (or line 1))            ; normalize no linenumber to line 1
 904       (catch 'marker                    ; find nearest loc, at least one exists
 905         (dolist (x (nthcdr 3 file-struct))      ; loop over remaining lines
 906           (if (> (car x) loc)           ; still bigger
 907               (setq marker-line x)
 908             (if (> (- (or (car marker-line) 1) loc)
 909                    (- loc (car x)))     ; current line is nearer
 910                 (setq marker-line x))
 911             (throw 'marker t))))
 912       (setq marker (nth 3 (cadr marker-line))
 913             marker-line (or (car marker-line) 1))
 914       (with-current-buffer (marker-buffer marker)
 915         (save-excursion
 916           (save-restriction
 917             (widen)
 918             (goto-char (marker-position marker))
 919             (when (or end-col end-line)
 920               (beginning-of-line (- (or end-line line) marker-line -1))
 921               (if (or (null end-col) (< end-col 0))
 922                   (end-of-line)
 923                 (compilation-move-to-column
 924                  end-col compilation-error-screen-columns))
 925               (setq end-marker (list (point-marker))))
 926             (beginning-of-line (if end-line
 927                                    (- line end-line -1)
 928                                  (- loc marker-line -1)))
 929             (if col
 930                 (compilation-move-to-column
 931                  col compilation-error-screen-columns)
 932               (forward-to-indentation 0))
 933             (setq marker (list (point-marker)))))))
 934
 935     (setq loc (compilation-assq line (cdr file-struct)))
 936     (if end-line
 937         (setq end-loc (compilation-assq end-line (cdr file-struct))
 938               end-loc (compilation-assq end-col end-loc))
 939       (if end-col                       ; use same line element
 940           (setq end-loc (compilation-assq end-col loc))))
 941     (setq loc (compilation-assq col loc))
 942     ;; If they are new, make the loc(s) reference the file they point to.
 943     (or (cdr loc) (setcdr loc `(,line ,file-struct ,@marker)))
 944     (if end-loc
 945         (or (cdr end-loc)
 946             (setcdr end-loc `(,(or end-line line) ,file-struct ,@end-marker))))
 947
 948     ;; Must start with face
 949     `(face ,compilation-message-face
 950            message (,loc ,type ,end-loc)
 951            ,@(if compilation-debug
 952                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 953                           ,@(match-data))))
 954            help-echo ,(if col
 955                           "mouse-2: visit this file, line and column"
 956                         (if line
 957                             "mouse-2: visit this file and line"
 958                           "mouse-2: visit this file"))
 959            keymap compilation-button-map
 960            mouse-face highlight)))
 961
 962 (defun compilation-mode-font-lock-keywords ()
 963   "Return expressions to highlight in Compilation mode."
 964   (if compilation-parse-errors-function
 965       ;; An old package!  Try the compatibility code.
 966       '((compilation-compat-parse-errors))
 967     (append
 968      ;; make directory tracking
 969      (if compilation-directory-matcher
 970          `((,(car compilation-directory-matcher)
 971             ,@(mapcar (lambda (elt)
 972                         `(,(car elt)
 973                           (compilation-directory-properties
 974                            ,(car elt) ,(cdr elt))
 975                           t t))
 976                       (cdr compilation-directory-matcher)))))
 977
 978      ;; Compiler warning/error lines.
 979      (mapcar
 980       (lambda (item)
 981         (if (symbolp item)
 982             (setq item (cdr (assq item
 983                                   compilation-error-regexp-alist-alist))))
 984         (let ((file (nth 1 item))
 985               (line (nth 2 item))
 986               (col (nth 3 item))
 987               (type (nth 4 item))
 988               (pat (car item))
 989               end-line end-col fmt)
 990           ;; omake reports some error indented, so skip the indentation.
 991           ;; another solution is to modify (some?) regexps in
 992           ;; `compilation-error-regexp-alist'.
 993           ;; note that omake usage is not limited to ocaml and C (for stubs).
 994           (when (and (= ?^ (aref pat 0)) ; anchored: starts with "^"
 995                      ;; but does not allow an arbitrary number of leading spaces
 996                      (not (and (= ?  (aref pat 1)) (= ?* (aref pat 2)))))
 997             (setq pat (concat "^ *" (substring pat 1))))
 998           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 999           (if (consp line)      (setq end-line (cdr line) line (car line)))
1000           (if (consp col)       (setq end-col (cdr col)   col (car col)))
1001
1002           (if (functionp line)
1003               ;; The old compile.el had here an undocumented hook that
1004               ;; allowed `line' to be a function that computed the actual
1005               ;; error location.  Let's do our best.
1006               `(,pat
1007                 (0 (save-match-data
1008                      (compilation-compat-error-properties
1009                       (funcall ',line (cons (match-string ,file)
1010                                             (cons default-directory
1011                                                   ',(nthcdr 4 item)))
1012                                ,(if col `(match-string ,col))))))
1013                 (,file compilation-error-face t))
1014
1015             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
1016               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
1017
1018             `(,pat
1019
1020               ,@(when (integerp file)
1021                   `((,file ,(if (consp type)
1022                                 `(compilation-face ',type)
1023                               (aref [compilation-info-face
1024                                      compilation-warning-face
1025                                      compilation-error-face]
1026                                     (or type 2))))))
1027
1028               ,@(when line
1029                   `((,line compilation-line-face nil t)))
1030               ,@(when end-line
1031                   `((,end-line compilation-line-face nil t)))
1032
1033               ,@(when (integerp col)
1034                   `((,col compilation-column-face nil t)))
1035               ,@(when (integerp end-col)
1036                   `((,end-col compilation-column-face nil t)))
1037
1038               ,@(nthcdr 6 item)
1039               (,(or (nth 5 item) 0)
1040                (compilation-error-properties ',file ,line ,end-line
1041                                              ,col ,end-col ',(or type 2)
1042                                              ',fmt)
1043                append)))))              ; for compilation-message-face
1044       compilation-error-regexp-alist)
1045
1046      compilation-mode-font-lock-keywords)))
1047
1048 (defun compilation-read-command (command)
1049   (read-shell-command "Compile command: " command
1050                       (if (equal (car compile-history) command)
1051                           '(compile-history . 1)
1052                         'compile-history)))
1053
1054 \f
1055 ;;;###autoload
1056 (defun compile (command &optional comint)
1057   "Compile the program including the current buffer.  Default: run `make'.
1058 Runs COMMAND, a shell command, in a separate process asynchronously
1059 with output going to the buffer `*compilation*'.
1060
1061 You can then use the command \\[next-error] to find the next error message
1062 and move to the source code that caused it.
1063
1064 If optional second arg COMINT is t the buffer will be in Comint mode with
1065 `compilation-shell-minor-mode'.
1066
1067 Interactively, prompts for the command if `compilation-read-command' is
1068 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
1069 Additionally, with universal prefix arg, compilation buffer will be in
1070 comint mode, i.e. interactive.
1071
1072 To run more than one compilation at once, start one then rename
1073 the \`*compilation*' buffer to some other name with
1074 \\[rename-buffer].  Then _switch buffers_ and start the new compilation.
1075 It will create a new \`*compilation*' buffer.
1076
1077 On most systems, termination of the main compilation process
1078 kills its subprocesses.
1079
1080 The name used for the buffer is actually whatever is returned by
1081 the function in `compilation-buffer-name-function', so you can set that
1082 to a function that generates a unique name."
1083   (interactive
1084    (list
1085     (let ((command (eval compile-command)))
1086       (if (or compilation-read-command current-prefix-arg)
1087           (compilation-read-command command)
1088         command))
1089     (consp current-prefix-arg)))
1090   (unless (equal command (eval compile-command))
1091     (setq compile-command command))
1092   (save-some-buffers (not compilation-ask-about-save) nil)
1093   (setq-default compilation-directory default-directory)
1094   (compilation-start command comint))
1095
1096 ;; run compile with the default command line
1097 (defun recompile (&optional edit-command)
1098   "Re-compile the program including the current buffer.
1099 If this is run in a Compilation mode buffer, re-use the arguments from the
1100 original use.  Otherwise, recompile using `compile-command'.
1101 If the optional argument `edit-command' is non-nil, the command can be edited."
1102   (interactive "P")
1103   (save-some-buffers (not compilation-ask-about-save) nil)
1104   (let ((default-directory (or compilation-directory default-directory)))
1105     (when edit-command
1106       (setcar compilation-arguments
1107               (compilation-read-command (car compilation-arguments))))
1108     (apply 'compilation-start (or compilation-arguments
1109                                   `(,(eval compile-command))))))
1110
1111 (defcustom compilation-scroll-output nil
1112   "Non-nil to scroll the *compilation* buffer window as output appears.
1113
1114 Setting it causes the Compilation mode commands to put point at the
1115 end of their output window so that the end of the output is always
1116 visible rather than the beginning.
1117
1118 The value `first-error' stops scrolling at the first error, and leaves
1119 point on its location in the *compilation* buffer."
1120   :type '(choice (const :tag "No scrolling" nil)
1121                  (const :tag "Scroll compilation output" t)
1122                  (const :tag "Stop scrolling at the first error" first-error))
1123   :version "20.3"
1124   :group 'compilation)
1125
1126
1127 (defun compilation-buffer-name (mode-name mode-command name-function)
1128   "Return the name of a compilation buffer to use.
1129 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
1130 to determine the buffer name.
1131 Likewise if `compilation-buffer-name-function' is non-nil.
1132 If current buffer has the major mode MODE-COMMAND,
1133 return the name of the current buffer, so that it gets reused.
1134 Otherwise, construct a buffer name from MODE-NAME."
1135   (cond (name-function
1136          (funcall name-function mode-name))
1137         (compilation-buffer-name-function
1138          (funcall compilation-buffer-name-function mode-name))
1139         ((eq mode-command major-mode)
1140          (buffer-name))
1141         (t
1142          (concat "*" (downcase mode-name) "*"))))
1143
1144 ;; This is a rough emulation of the old hack, until the transition to new
1145 ;; compile is complete.
1146 (defun compile-internal (command error-message
1147                                  &optional name-of-mode parser
1148                                  error-regexp-alist name-function
1149                                  enter-regexp-alist leave-regexp-alist
1150                                  file-regexp-alist nomessage-regexp-alist
1151                                  no-async highlight-regexp local-map)
1152   (if parser
1153       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
1154   (let ((compilation-error-regexp-alist
1155          (append file-regexp-alist (or error-regexp-alist
1156                                        compilation-error-regexp-alist)))
1157         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
1158                                                      "\\1" error-message)))
1159     (compilation-start command nil name-function highlight-regexp)))
1160 (make-obsolete 'compile-internal 'compilation-start "22.1")
1161
1162 ;;;###autoload
1163 (defun compilation-start (command &optional mode name-function highlight-regexp)
1164   "Run compilation command COMMAND (low level interface).
1165 If COMMAND starts with a cd command, that becomes the `default-directory'.
1166 The rest of the arguments are optional; for them, nil means use the default.
1167
1168 MODE is the major mode to set in the compilation buffer.  Mode
1169 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
1170
1171 If NAME-FUNCTION is non-nil, call it with one argument (the mode name)
1172 to determine the buffer name.  Otherwise, the default is to
1173 reuses the current buffer if it has the proper major mode,
1174 else use or create a buffer with name based on the major mode.
1175
1176 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
1177 the matching section of the visited source line; the default is to use the
1178 global value of `compilation-highlight-regexp'.
1179
1180 Returns the compilation buffer created."
1181   (or mode (setq mode 'compilation-mode))
1182   (let* ((name-of-mode
1183           (if (eq mode t)
1184               "compilation"
1185             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
1186          (thisdir default-directory)
1187          outwin outbuf)
1188     (with-current-buffer
1189         (setq outbuf
1190               (get-buffer-create
1191                (compilation-buffer-name name-of-mode mode name-function)))
1192       (let ((comp-proc (get-buffer-process (current-buffer))))
1193         (if comp-proc
1194             (if (or (not (eq (process-status comp-proc) 'run))
1195                     (yes-or-no-p
1196                      (format "A %s process is running; kill it? "
1197                              name-of-mode)))
1198                 (condition-case ()
1199                     (progn
1200                       (interrupt-process comp-proc)
1201                       (sit-for 1)
1202                       (delete-process comp-proc))
1203                   (error nil))
1204               (error "Cannot have two processes in `%s' at once"
1205                      (buffer-name)))))
1206       ;; first transfer directory from where M-x compile was called
1207       (setq default-directory thisdir)
1208       ;; Make compilation buffer read-only.  The filter can still write it.
1209       ;; Clear out the compilation buffer.
1210       (let ((inhibit-read-only t)
1211             (default-directory thisdir))
1212         ;; Then evaluate a cd command if any, but don't perform it yet, else
1213         ;; start-command would do it again through the shell: (cd "..") AND
1214         ;; sh -c "cd ..; make"
1215         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
1216                 (if (match-end 1)
1217                     (substitute-env-vars (match-string 1 command))
1218                   "~")
1219               default-directory))
1220         (erase-buffer)
1221         ;; Select the desired mode.
1222         (if (not (eq mode t))
1223             (progn
1224               (buffer-disable-undo)
1225               (funcall mode))
1226           (setq buffer-read-only nil)
1227           (with-no-warnings (comint-mode))
1228           (compilation-shell-minor-mode))
1229         ;; Remember the original dir, so we can use it when we recompile.
1230         ;; default-directory' can't be used reliably for that because it may be
1231         ;; affected by the special handling of "cd ...;".
1232         ;; NB: must be fone after (funcall mode) as that resets local variables
1233         (set (make-local-variable 'compilation-directory) thisdir)
1234         (if highlight-regexp
1235             (set (make-local-variable 'compilation-highlight-regexp)
1236                  highlight-regexp))
1237         (if (or compilation-auto-jump-to-first-error
1238                 (eq compilation-scroll-output 'first-error))
1239             (set (make-local-variable 'compilation-auto-jump-to-next) t))
1240         ;; Output a mode setter, for saving and later reloading this buffer.
1241         (insert "-*- mode: " name-of-mode
1242                 "; default-directory: " (prin1-to-string default-directory)
1243                 " -*-\n"
1244                 (format "%s started at %s\n\n"
1245                         mode-name
1246                         (substring (current-time-string) 0 19))
1247                 command "\n")
1248         (setq thisdir default-directory))
1249       (set-buffer-modified-p nil))
1250     ;; Pop up the compilation buffer.
1251     ;; http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01638.html
1252     (setq outwin (display-buffer outbuf))
1253     (with-current-buffer outbuf
1254       (let ((process-environment
1255              (append
1256               compilation-environment
1257               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1258                       system-uses-terminfo)
1259                   (list "TERM=dumb" "TERMCAP="
1260                         (format "COLUMNS=%d" (window-width)))
1261                 (list "TERM=emacs"
1262                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1263                               (window-width))))
1264               ;; Set the EMACS variable, but
1265               ;; don't override users' setting of $EMACS.
1266               (unless (getenv "EMACS")
1267                 (list "EMACS=t"))
1268               (list "INSIDE_EMACS=t")
1269               (copy-sequence process-environment))))
1270         (set (make-local-variable 'compilation-arguments)
1271              (list command mode name-function highlight-regexp))
1272         (set (make-local-variable 'revert-buffer-function)
1273              'compilation-revert-buffer)
1274         (set-window-start outwin (point-min))
1275
1276         ;; Position point as the user will see it.
1277         (let ((desired-visible-point
1278                ;; Put it at the end if `compilation-scroll-output' is set.
1279                (if compilation-scroll-output
1280                    (point-max)
1281                  ;; Normally put it at the top.
1282                  (point-min))))
1283           (if (eq outwin (selected-window))
1284               (goto-char desired-visible-point)
1285             (set-window-point outwin desired-visible-point)))
1286
1287         ;; The setup function is called before compilation-set-window-height
1288         ;; so it can set the compilation-window-height buffer locally.
1289         (if compilation-process-setup-function
1290             (funcall compilation-process-setup-function))
1291         (compilation-set-window-height outwin)
1292         ;; Start the compilation.
1293         (if (fboundp 'start-process)
1294             (let ((proc
1295                    (if (eq mode t)
1296                        ;; comint uses `start-file-process'.
1297                        (get-buffer-process
1298                         (with-no-warnings
1299                           (comint-exec
1300                            outbuf (downcase mode-name)
1301                            (if (file-remote-p default-directory)
1302                                "/bin/sh"
1303                              shell-file-name)
1304                            nil `("-c" ,command))))
1305                      (start-file-process-shell-command (downcase mode-name)
1306                                                        outbuf command))))
1307               ;; Make the buffer's mode line show process state.
1308               (setq mode-line-process
1309                     (list (propertize ":%s" 'face 'compilation-warning)))
1310               (set-process-sentinel proc 'compilation-sentinel)
1311               (unless (eq mode t)
1312                 ;; Keep the comint filter, since it's needed for proper handling
1313                 ;; of the prompts.
1314                 (set-process-filter proc 'compilation-filter))
1315               ;; Use (point-max) here so that output comes in
1316               ;; after the initial text,
1317               ;; regardless of where the user sees point.
1318               (set-marker (process-mark proc) (point-max) outbuf)
1319               (when compilation-disable-input
1320                 (condition-case nil
1321                     (process-send-eof proc)
1322                   ;; The process may have exited already.
1323                   (error nil)))
1324               (run-hook-with-args 'compilation-start-hook proc)
1325               (setq compilation-in-progress
1326                     (cons proc compilation-in-progress)))
1327           ;; No asynchronous processes available.
1328           (message "Executing `%s'..." command)
1329           ;; Fake modeline display as if `start-process' were run.
1330           (setq mode-line-process
1331                 (list (propertize ":run" 'face 'compilation-warning)))
1332           (force-mode-line-update)
1333           (sit-for 0)                   ; Force redisplay
1334           (save-excursion
1335             ;; Insert the output at the end, after the initial text,
1336             ;; regardless of where the user sees point.
1337             (goto-char (point-max))
1338             (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1339                    (status (call-process shell-file-name nil outbuf nil "-c"
1340                                          command)))
1341               (cond ((numberp status)
1342                      (compilation-handle-exit
1343                       'exit status
1344                       (if (zerop status)
1345                           "finished\n"
1346                         (format "exited abnormally with code %d\n" status))))
1347                     ((stringp status)
1348                      (compilation-handle-exit 'signal status
1349                                               (concat status "\n")))
1350                     (t
1351                      (compilation-handle-exit 'bizarre status status)))))
1352           ;; Without async subprocesses, the buffer is not yet
1353           ;; fontified, so fontify it now.
1354           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1355             (font-lock-fontify-buffer))
1356           (set-buffer-modified-p nil)
1357           (message "Executing `%s'...done" command)))
1358       ;; Now finally cd to where the shell started make/grep/...
1359       (setq default-directory thisdir)
1360       ;; The following form selected outwin ever since revision 1.183,
1361       ;; so possibly messing up point in some other window (bug#1073).
1362       ;; Moved into the scope of with-current-buffer, though still with
1363       ;; complete disregard for the case when compilation-scroll-output
1364       ;; equals 'first-error (martin 2008-10-04).
1365       (when compilation-scroll-output
1366         (goto-char (point-max))))
1367
1368     ;; Make it so the next C-x ` will use this buffer.
1369     (setq next-error-last-buffer outbuf)))
1370
1371 (defun compilation-set-window-height (window)
1372   "Set the height of WINDOW according to `compilation-window-height'."
1373   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1374     (and height
1375          (window-full-width-p window)
1376          ;; If window is alone in its frame, aside from a minibuffer,
1377          ;; don't change its height.
1378          (not (eq window (frame-root-window (window-frame window))))
1379          ;; Stef said that doing the saves in this order is safer:
1380          (save-excursion
1381            (save-selected-window
1382              (select-window window)
1383              (enlarge-window (- height (window-height))))))))
1384
1385 (defvar compilation-menu-map
1386   (let ((map (make-sparse-keymap "Errors"))
1387         (opt-map (make-sparse-keymap "Skip")))
1388     (define-key map [stop-subjob]
1389       '(menu-item "Stop Compilation" kill-compilation
1390                   :help "Kill the process made by the M-x compile or M-x grep commands"))
1391     (define-key map [compilation-mode-separator3]
1392       '("----" . nil))
1393     (define-key map [compilation-next-error-follow-minor-mode]
1394       '(menu-item
1395         "Auto Error Display" next-error-follow-minor-mode
1396         :help "Display the error under cursor when moving the cursor"
1397         :button (:toggle . next-error-follow-minor-mode)))
1398     (define-key map [compilation-skip]
1399       (cons "Skip Less Important Messages" opt-map))
1400     (define-key opt-map [compilation-skip-none]
1401       '(menu-item "Don't Skip Any Messages"
1402                   (lambda ()
1403                     (interactive)
1404                     (customize-set-variable 'compilation-skip-threshold 0))
1405                   :help "Do not skip any type of messages"
1406                   :button (:radio . (eq compilation-skip-threshold 0))))
1407     (define-key opt-map [compilation-skip-info]
1408       '(menu-item "Skip Info"
1409                   (lambda ()
1410                     (interactive)
1411                     (customize-set-variable 'compilation-skip-threshold 1))
1412                   :help "Skip anything less than warning"
1413                   :button (:radio . (eq compilation-skip-threshold 1))))
1414     (define-key opt-map [compilation-skip-warning-and-info]
1415       '(menu-item "Skip Warnings and Info"
1416                   (lambda ()
1417                     (interactive)
1418                     (customize-set-variable 'compilation-skip-threshold 2))
1419                   :help "Skip over Warnings and Info, stop for errors"
1420                   :button (:radio . (eq compilation-skip-threshold 2))))
1421     (define-key map [compilation-mode-separator2]
1422       '("----" . nil))
1423     (define-key map [compilation-first-error]
1424       '(menu-item "First Error" first-error
1425                   :help "Restart at the first error, visit corresponding source code"))
1426     (define-key map [compilation-previous-error]
1427       '(menu-item "Previous Error" previous-error
1428                   :help "Visit previous `next-error' message and corresponding source code"))
1429     (define-key map [compilation-next-error]
1430       '(menu-item "Next Error" next-error
1431                   :help "Visit next `next-error' message and corresponding source code"))
1432     map))
1433
1434 (defvar compilation-minor-mode-map
1435   (let ((map (make-sparse-keymap)))
1436     (define-key map [mouse-2] 'compile-goto-error)
1437     (define-key map [follow-link] 'mouse-face)
1438     (define-key map "\C-c\C-c" 'compile-goto-error)
1439     (define-key map "\C-m" 'compile-goto-error)
1440     (define-key map "\C-c\C-k" 'kill-compilation)
1441     (define-key map "\M-n" 'compilation-next-error)
1442     (define-key map "\M-p" 'compilation-previous-error)
1443     (define-key map "\M-{" 'compilation-previous-file)
1444     (define-key map "\M-}" 'compilation-next-file)
1445     (define-key map "g" 'recompile) ; revert
1446     (define-key map "q" 'quit-window)
1447     ;; Set up the menu-bar
1448     (define-key map [menu-bar compilation]
1449       (cons "Errors" compilation-menu-map))
1450     map)
1451   "Keymap for `compilation-minor-mode'.")
1452
1453 (defvar compilation-shell-minor-mode-map
1454   (let ((map (make-sparse-keymap)))
1455     (define-key map "\M-\C-m" 'compile-goto-error)
1456     (define-key map "\M-\C-n" 'compilation-next-error)
1457     (define-key map "\M-\C-p" 'compilation-previous-error)
1458     (define-key map "\M-{" 'compilation-previous-file)
1459     (define-key map "\M-}" 'compilation-next-file)
1460     ;; Set up the menu-bar
1461     (define-key map [menu-bar compilation]
1462       (cons "Errors" compilation-menu-map))
1463     map)
1464   "Keymap for `compilation-shell-minor-mode'.")
1465
1466 (defvar compilation-button-map
1467   (let ((map (make-sparse-keymap)))
1468     (define-key map [mouse-2] 'compile-goto-error)
1469     (define-key map [follow-link] 'mouse-face)
1470     (define-key map "\C-m" 'compile-goto-error)
1471     map)
1472   "Keymap for compilation-message buttons.")
1473 (fset 'compilation-button-map compilation-button-map)
1474
1475 (defvar compilation-mode-map
1476   (let ((map (make-sparse-keymap)))
1477     ;; Don't inherit from compilation-minor-mode-map,
1478     ;; because that introduces a menu bar item we don't want.
1479     ;; That confuses C-down-mouse-3.
1480     (define-key map [mouse-2] 'compile-goto-error)
1481     (define-key map [follow-link] 'mouse-face)
1482     (define-key map "\C-c\C-c" 'compile-goto-error)
1483     (define-key map "\C-m" 'compile-goto-error)
1484     (define-key map "\C-c\C-k" 'kill-compilation)
1485     (define-key map "\M-n" 'compilation-next-error)
1486     (define-key map "\M-p" 'compilation-previous-error)
1487     (define-key map "\M-{" 'compilation-previous-file)
1488     (define-key map "\M-}" 'compilation-next-file)
1489     (define-key map "\t" 'compilation-next-error)
1490     (define-key map [backtab] 'compilation-previous-error)
1491     (define-key map "g" 'recompile) ; revert
1492     (define-key map "q" 'quit-window)
1493
1494     (define-key map " " 'scroll-up)
1495     (define-key map "\^?" 'scroll-down)
1496     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1497
1498     ;; Set up the menu-bar
1499     (let ((submap (make-sparse-keymap "Compile")))
1500       (define-key map [menu-bar compilation]
1501         (cons "Compile" submap))
1502       (set-keymap-parent submap compilation-menu-map))
1503     (define-key map [menu-bar compilation compilation-separator2]
1504       '("----" . nil))
1505     (define-key map [menu-bar compilation compilation-grep]
1506       '(menu-item "Search Files (grep)..." grep
1507                   :help "Run grep, with user-specified args, and collect output in a buffer"))
1508     (define-key map [menu-bar compilation compilation-recompile]
1509       '(menu-item "Recompile" recompile
1510         :help "Re-compile the program including the current buffer"))
1511     (define-key map [menu-bar compilation compilation-compile]
1512       '(menu-item "Compile..." compile
1513                   :help "Compile the program including the current buffer.  Default: run `make'"))
1514     map)
1515   "Keymap for compilation log buffers.
1516 `compilation-minor-mode-map' is a parent of this.")
1517
1518 (defvar compilation-mode-tool-bar-map
1519   ;; When bootstrapping, tool-bar-map is not properly initialized yet,
1520   ;; so don't do anything.
1521   (when (keymapp (butlast tool-bar-map))
1522     (let ((map (butlast (copy-keymap tool-bar-map)))
1523           (help (last tool-bar-map))) ;; Keep Help last in tool bar
1524       (tool-bar-local-item
1525        "left-arrow" 'previous-error-no-select 'previous-error-no-select map
1526        :rtl "right-arrow"
1527        :help "Goto previous error")
1528       (tool-bar-local-item
1529        "right-arrow" 'next-error-no-select 'next-error-no-select map
1530        :rtl "left-arrow"
1531        :help "Goto next error")
1532       (tool-bar-local-item
1533        "cancel" 'kill-compilation 'kill-compilation map
1534        :enable '(let ((buffer (compilation-find-buffer)))
1535                   (get-buffer-process buffer))
1536        :help "Stop compilation")
1537       (tool-bar-local-item
1538        "refresh" 'recompile 'recompile map
1539        :help "Restart compilation")
1540       (append map help))))
1541
1542 (put 'compilation-mode 'mode-class 'special)
1543
1544 ;;;###autoload
1545 (defun compilation-mode (&optional name-of-mode)
1546   "Major mode for compilation log buffers.
1547 \\<compilation-mode-map>To visit the source for a line-numbered error,
1548 move point to the error message line and type \\[compile-goto-error].
1549 To kill the compilation, type \\[kill-compilation].
1550
1551 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1552
1553 \\{compilation-mode-map}"
1554   (interactive)
1555   (kill-all-local-variables)
1556   (use-local-map compilation-mode-map)
1557   ;; Let windows scroll along with the output.
1558   (set (make-local-variable 'window-point-insertion-type) t)
1559   (set (make-local-variable 'tool-bar-map) compilation-mode-tool-bar-map)
1560   (setq major-mode 'compilation-mode
1561         mode-name (or name-of-mode "Compilation"))
1562   (set (make-local-variable 'page-delimiter)
1563        compilation-page-delimiter)
1564   (compilation-setup)
1565   (setq buffer-read-only t)
1566   (run-mode-hooks 'compilation-mode-hook))
1567
1568 (defmacro define-compilation-mode (mode name doc &rest body)
1569   "This is like `define-derived-mode' without the PARENT argument.
1570 The parent is always `compilation-mode' and the customizable `compilation-...'
1571 variables are also set from the name of the mode you have chosen,
1572 by replacing the first word, e.g `compilation-scroll-output' from
1573 `grep-scroll-output' if that variable exists."
1574   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1575     `(define-derived-mode ,mode compilation-mode ,name
1576        ,doc
1577        ,@(mapcar (lambda (v)
1578                    (setq v (cons v
1579                                  (intern-soft (replace-regexp-in-string
1580                                                "^compilation" mode-name
1581                                                (symbol-name v)))))
1582                    (and (cdr v)
1583                         (or (boundp (cdr v))
1584                             (if (boundp 'byte-compile-bound-variables)
1585                                 (memq (cdr v) byte-compile-bound-variables)))
1586                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1587                  '(compilation-buffer-name-function
1588                    compilation-directory-matcher
1589                    compilation-error
1590                    compilation-error-regexp-alist
1591                    compilation-error-regexp-alist-alist
1592                    compilation-error-screen-columns
1593                    compilation-finish-function
1594                    compilation-finish-functions
1595                    compilation-first-column
1596                    compilation-mode-font-lock-keywords
1597                    compilation-page-delimiter
1598                    compilation-parse-errors-filename-function
1599                    compilation-process-setup-function
1600                    compilation-scroll-output
1601                    compilation-search-path
1602                    compilation-skip-threshold
1603                    compilation-window-height))
1604        ,@body)))
1605
1606 (defun compilation-revert-buffer (ignore-auto noconfirm)
1607   (if buffer-file-name
1608       (let (revert-buffer-function)
1609         (revert-buffer ignore-auto noconfirm))
1610     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1611         (apply 'compilation-start compilation-arguments))))
1612
1613 (defvar compilation-current-error nil
1614   "Marker to the location from where the next error will be found.
1615 The global commands next/previous/first-error/goto-error use this.")
1616
1617 (defvar compilation-messages-start nil
1618   "Buffer position of the beginning of the compilation messages.
1619 If nil, use the beginning of buffer.")
1620
1621 ;; A function name can't be a hook, must be something with a value.
1622 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1623
1624 (defun compilation-setup (&optional minor)
1625   "Prepare the buffer for the compilation parsing commands to work.
1626 Optional argument MINOR indicates this is called from
1627 `compilation-minor-mode'."
1628   (make-local-variable 'compilation-current-error)
1629   (make-local-variable 'compilation-messages-start)
1630   (make-local-variable 'compilation-error-screen-columns)
1631   (make-local-variable 'overlay-arrow-position)
1632   (set (make-local-variable 'overlay-arrow-string) "")
1633   (setq next-error-overlay-arrow-position nil)
1634   (add-hook 'kill-buffer-hook
1635             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1636   ;; Note that compilation-next-error-function is for interfacing
1637   ;; with the next-error function in simple.el, and it's only
1638   ;; coincidentally named similarly to compilation-next-error.
1639   (setq next-error-function 'compilation-next-error-function)
1640   (set (make-local-variable 'comint-file-name-prefix)
1641        (or (file-remote-p default-directory) ""))
1642   (set (make-local-variable 'font-lock-extra-managed-props)
1643        '(directory message help-echo mouse-face debug))
1644   (set (make-local-variable 'compilation-locs)
1645        (make-hash-table :test 'equal :weakness 'value))
1646   ;; lazy-lock would never find the message unless it's scrolled to.
1647   ;; jit-lock might fontify some things too late.
1648   (set (make-local-variable 'font-lock-support-mode) nil)
1649   (set (make-local-variable 'font-lock-maximum-size) nil)
1650   (if minor
1651       (let ((fld font-lock-defaults))
1652         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1653         (if font-lock-mode
1654             (if fld
1655                 (font-lock-fontify-buffer)
1656               (font-lock-change-mode)
1657               (turn-on-font-lock))
1658           (turn-on-font-lock)))
1659     (setq font-lock-defaults '(compilation-mode-font-lock-keywords t))
1660     ;; maybe defer font-lock till after derived mode is set up
1661     (run-mode-hooks 'compilation-turn-on-font-lock)))
1662
1663 ;;;###autoload
1664 (define-minor-mode compilation-shell-minor-mode
1665   "Toggle compilation shell minor mode.
1666 With arg, turn compilation mode on if and only if arg is positive.
1667 In this minor mode, all the error-parsing commands of the
1668 Compilation major mode are available but bound to keys that don't
1669 collide with Shell mode.  See `compilation-mode'.
1670 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1671   nil " Shell-Compile"
1672   :group 'compilation
1673   (if compilation-shell-minor-mode
1674       (compilation-setup t)
1675     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1676     (font-lock-fontify-buffer)))
1677
1678 ;;;###autoload
1679 (define-minor-mode compilation-minor-mode
1680   "Toggle compilation minor mode.
1681 With arg, turn compilation mode on if and only if arg is positive.
1682 In this minor mode, all the error-parsing commands of the
1683 Compilation major mode are available.  See `compilation-mode'.
1684 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1685   nil " Compilation"
1686   :group 'compilation
1687   (if compilation-minor-mode
1688       (compilation-setup t)
1689     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1690     (font-lock-fontify-buffer)))
1691
1692 (defun compilation-handle-exit (process-status exit-status msg)
1693   "Write MSG in the current buffer and hack its `mode-line-process'."
1694   (let ((inhibit-read-only t)
1695         (status (if compilation-exit-message-function
1696                     (funcall compilation-exit-message-function
1697                              process-status exit-status msg)
1698                   (cons msg exit-status)))
1699         (omax (point-max))
1700         (opoint (point))
1701         (cur-buffer (current-buffer)))
1702     ;; Record where we put the message, so we can ignore it later on.
1703     (goto-char omax)
1704     (insert ?\n mode-name " " (car status))
1705     (if (and (numberp compilation-window-height)
1706              (zerop compilation-window-height))
1707         (message "%s" (cdr status)))
1708     (if (bolp)
1709         (forward-char -1))
1710     (insert " at " (substring (current-time-string) 0 19))
1711     (goto-char (point-max))
1712     ;; Prevent that message from being recognized as a compilation error.
1713     (add-text-properties omax (point)
1714                          (append '(compilation-handle-exit t) nil))
1715     (setq mode-line-process
1716           (let ((out-string (format ":%s [%s]" process-status (cdr status)))
1717                 (msg (format "%s %s" mode-name
1718                              (replace-regexp-in-string "\n?$" "" (car status)))))
1719             (message "%s" msg)
1720             (propertize out-string
1721                         'help-echo msg 'face (if (> exit-status 0)
1722                                                  'compilation-error
1723                                                'compilation-info))))
1724     ;; Force mode line redisplay soon.
1725     (force-mode-line-update)
1726     (if (and opoint (< opoint omax))
1727         (goto-char opoint))
1728     (with-no-warnings
1729       (if compilation-finish-function
1730           (funcall compilation-finish-function cur-buffer msg)))
1731     (run-hook-with-args 'compilation-finish-functions cur-buffer msg)))
1732
1733 ;; Called when compilation process changes state.
1734 (defun compilation-sentinel (proc msg)
1735   "Sentinel for compilation buffers."
1736   (if (memq (process-status proc) '(exit signal))
1737       (let ((buffer (process-buffer proc)))
1738         (if (null (buffer-name buffer))
1739             ;; buffer killed
1740             (set-process-buffer proc nil)
1741           (with-current-buffer buffer
1742             ;; Write something in the compilation buffer
1743             ;; and hack its mode line.
1744             (compilation-handle-exit (process-status proc)
1745                                      (process-exit-status proc)
1746                                      msg)
1747             ;; Since the buffer and mode line will show that the
1748             ;; process is dead, we can delete it now.  Otherwise it
1749             ;; will stay around until M-x list-processes.
1750             (delete-process proc)))
1751         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1752
1753 (defun compilation-filter (proc string)
1754   "Process filter for compilation buffers.
1755 Just inserts the text,
1756 handles carriage motion (see `comint-inhibit-carriage-motion'),
1757 and runs `compilation-filter-hook'."
1758   (when (buffer-live-p (process-buffer proc))
1759     (with-current-buffer (process-buffer proc)
1760       (let ((inhibit-read-only t)
1761             ;; `save-excursion' doesn't use the right insertion-type for us.
1762             (pos (copy-marker (point) t))
1763             (min (point-min-marker))
1764             (max (point-max-marker)))
1765         (unwind-protect
1766             (progn
1767               ;; If we are inserting at the end of the accessible part
1768               ;; of the buffer, keep the inserted text visible.
1769               (set-marker-insertion-type max t)
1770               (widen)
1771               (goto-char (process-mark proc))
1772               ;; We used to use `insert-before-markers', so that windows with
1773               ;; point at `process-mark' scroll along with the output, but we
1774               ;; now use window-point-insertion-type instead.
1775               (insert string)
1776               (unless comint-inhibit-carriage-motion
1777                 (comint-carriage-motion (process-mark proc) (point)))
1778               (set-marker (process-mark proc) (point))
1779               (run-hooks 'compilation-filter-hook))
1780           (goto-char pos)
1781           (narrow-to-region min max)
1782           (set-marker min nil)
1783           (set-marker max nil))))))
1784
1785 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1786 (defsubst compilation-buffer-internal-p ()
1787   "Test if inside a compilation buffer."
1788   (local-variable-p 'compilation-locs))
1789
1790 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1791 (defsubst compilation-buffer-p (buffer)
1792   "Test if BUFFER is a compilation buffer."
1793   (with-current-buffer buffer
1794     (compilation-buffer-internal-p)))
1795
1796 (defmacro compilation-loop (< property-change 1+ error limit)
1797   `(let (opt)
1798      (while (,< n 0)
1799        (setq opt pt)
1800        (or (setq pt (,property-change pt 'message))
1801            ;; Handle the case where where the first error message is
1802            ;; at the start of the buffer, and n < 0.
1803            (if (or (eq (get-text-property ,limit 'message)
1804                        (get-text-property opt 'message))
1805                    (eq pt opt))
1806                (error ,error compilation-error)
1807              (setq pt ,limit)))
1808        ;; prop 'message usually has 2 changes, on and off, so
1809        ;; re-search if off
1810        (or (setq msg (get-text-property pt 'message))
1811            (if (setq pt (,property-change pt 'message nil ,limit))
1812                (setq msg (get-text-property pt 'message)))
1813            (error ,error compilation-error))
1814        (or (< (cadr msg) compilation-skip-threshold)
1815            (if different-file
1816                (eq (prog1 last (setq last (nth 2 (car msg))))
1817                    last))
1818            (if compilation-skip-visited
1819                (nthcdr 5 (car msg)))
1820            (if compilation-skip-to-next-location
1821                (eq (car msg) loc))
1822            ;; count this message only if none of the above are true
1823            (setq n (,1+ n))))))
1824
1825 (defun compilation-next-error (n &optional different-file pt)
1826   "Move point to the next error in the compilation buffer.
1827 This function does NOT find the source line like \\[next-error].
1828 Prefix arg N says how many error messages to move forwards (or
1829 backwards, if negative).
1830 Optional arg DIFFERENT-FILE, if non-nil, means find next error for a
1831 file that is different from the current one.
1832 Optional arg PT, if non-nil, specifies the value of point to start
1833 looking for the next message."
1834   (interactive "p")
1835   (or (compilation-buffer-p (current-buffer))
1836       (error "Not in a compilation buffer"))
1837   (or pt (setq pt (point)))
1838   (let* ((msg (get-text-property pt 'message))
1839          ;; `loc' is used by the compilation-loop macro.
1840          (loc (car msg))
1841          last)
1842     (if (zerop n)
1843         (unless (or msg                 ; find message near here
1844                     (setq msg (get-text-property (max (1- pt) (point-min))
1845                                                  'message)))
1846           (setq pt (previous-single-property-change pt 'message nil
1847                                                     (line-beginning-position)))
1848           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1849             (setq pt (next-single-property-change pt 'message nil
1850                                                   (line-end-position)))
1851             (or (setq msg (get-text-property pt 'message))
1852                 (setq pt (point)))))
1853       (setq last (nth 2 (car msg)))
1854       (if (>= n 0)
1855           (compilation-loop > next-single-property-change 1-
1856                             (if (get-buffer-process (current-buffer))
1857                                 "No more %ss yet"
1858                               "Moved past last %s")
1859                             (point-max))
1860         ;; Don't move "back" to message at or before point.
1861         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1862         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1863         (compilation-loop < previous-single-property-change 1+
1864                           "Moved back before first %s" (point-min))))
1865     (goto-char pt)
1866     (or msg
1867         (error "No %s here" compilation-error))))
1868
1869 (defun compilation-previous-error (n)
1870   "Move point to the previous error in the compilation buffer.
1871 Prefix arg N says how many error messages to move backwards (or
1872 forwards, if negative).
1873 Does NOT find the source line like \\[previous-error]."
1874   (interactive "p")
1875   (compilation-next-error (- n)))
1876
1877 (defun compilation-next-file (n)
1878   "Move point to the next error for a different file than the current one.
1879 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1880   (interactive "p")
1881   (compilation-next-error n t))
1882
1883 (defun compilation-previous-file (n)
1884   "Move point to the previous error for a different file than the current one.
1885 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1886   (interactive "p")
1887   (compilation-next-file (- n)))
1888
1889 (defun kill-compilation ()
1890   "Kill the process made by the \\[compile] or \\[grep] commands."
1891   (interactive)
1892   (let ((buffer (compilation-find-buffer)))
1893     (if (get-buffer-process buffer)
1894         (interrupt-process (get-buffer-process buffer))
1895       (error "The %s process is not running" (downcase mode-name)))))
1896
1897 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1898
1899 (defun compile-goto-error (&optional event)
1900   "Visit the source for the error message at point.
1901 Use this command in a compilation log buffer.  Sets the mark at point there."
1902   (interactive (list last-input-event))
1903   (if event (posn-set-point (event-end event)))
1904   (or (compilation-buffer-p (current-buffer))
1905       (error "Not in a compilation buffer"))
1906   (if (get-text-property (point) 'directory)
1907       (dired-other-window (car (get-text-property (point) 'directory)))
1908     (push-mark)
1909     (setq compilation-current-error (point))
1910     (next-error-internal)))
1911
1912 (defun compilation-find-buffer (&optional avoid-current)
1913   "Return a compilation buffer.
1914 If AVOID-CURRENT is nil, and the current buffer is a compilation buffer,
1915 return it.  If AVOID-CURRENT is non-nil, return the current buffer only
1916 as a last resort."
1917   (if (and (compilation-buffer-internal-p) (not avoid-current))
1918       (current-buffer)
1919     (next-error-find-buffer avoid-current 'compilation-buffer-internal-p)))
1920
1921 ;;;###autoload
1922 (defun compilation-next-error-function (n &optional reset)
1923   "Advance to the next error message and visit the file where the error was.
1924 This is the value of `next-error-function' in Compilation buffers."
1925   (interactive "p")
1926   (when reset
1927     (setq compilation-current-error nil))
1928   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1929          (last 1) timestamp
1930          (loc (compilation-next-error (or n 1) nil
1931                                       (or compilation-current-error
1932                                           compilation-messages-start
1933                                           (point-min))))
1934          (end-loc (nth 2 loc))
1935          (marker (point-marker)))
1936     (setq compilation-current-error (point-marker)
1937           overlay-arrow-position
1938             (if (bolp)
1939                 compilation-current-error
1940               (copy-marker (line-beginning-position)))
1941           loc (car loc))
1942     ;; If loc contains no marker, no error in that file has been visited.
1943     ;; If the marker is invalid the buffer has been killed.
1944     ;; If the file is newer than the timestamp, it has been modified
1945     ;; (`omake -P' polls filesystem for changes and recompiles when needed
1946     ;;  in the same process and buffer).
1947     ;; So, recalculate all markers for that file.
1948     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)) (nthcdr 4 loc)
1949                  ;; There may be no timestamp info if the loc is a `fake-loc',
1950                  ;; but we just checked that the file has been visited before!
1951                  (equal (nth 4 loc)
1952                         (setq timestamp
1953                               (with-current-buffer (marker-buffer (nth 3 loc))
1954                                 (visited-file-modtime)))))
1955       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1956                                                   (cadr (car (nth 2 loc))))
1957         (save-restriction
1958           (widen)
1959           (goto-char (point-min))
1960           ;; Treat file's found lines in forward order, 1 by 1.
1961           (dolist (line (reverse (cddr (nth 2 loc))))
1962             (when (car line)            ; else this is a filename w/o a line#
1963               (beginning-of-line (- (car line) last -1))
1964               (setq last (car line)))
1965             ;; Treat line's found columns and store/update a marker for each.
1966             (dolist (col (cdr line))
1967               (if (car col)
1968                   (if (eq (car col) -1) ; special case for range end
1969                       (end-of-line)
1970                     (compilation-move-to-column (car col) columns))
1971                 (beginning-of-line)
1972                 (skip-chars-forward " \t"))
1973               (if (nth 3 col)
1974                   (set-marker (nth 3 col) (point))
1975                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1976     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1977     (setcdr (nthcdr 3 loc) (list timestamp))
1978     (setcdr (nthcdr 4 loc) t)))         ; Set this one as visited.
1979
1980 (defvar compilation-gcpro nil
1981   "Internal variable used to keep some values from being GC'd.")
1982 (make-variable-buffer-local 'compilation-gcpro)
1983
1984 (defun compilation-fake-loc (marker file &optional line col)
1985   "Preassociate MARKER with FILE.
1986 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1987 This is useful when you compile temporary files, but want
1988 automatic translation of the messages to the real buffer from
1989 which the temporary file came.  This only works if done before a
1990 message about FILE appears!
1991
1992 Optional args LINE and COL default to 1 and beginning of
1993 indentation respectively.  The marker is expected to reflect
1994 this.  In the simplest case the marker points to the first line
1995 of the region that was saved to the temp file.
1996
1997 If you concatenate several regions into the temp file (e.g. a
1998 header with variable assignments and a code region), you must
1999 call this several times, once each for the last line of one
2000 region and the first line of the next region."
2001   (or (consp file) (setq file (list file)))
2002   (setq file (compilation-get-file-structure file))
2003   ;; Between the current call to compilation-fake-loc and the first occurrence
2004   ;; of an error message referring to `file', the data is only kept in the
2005   ;; weak hash-table compilation-locs, so we need to prevent this entry
2006   ;; in compilation-locs from being GC'd away.  --Stef
2007   (push file compilation-gcpro)
2008   (let ((loc (compilation-assq (or line 1) (cdr file))))
2009     (setq loc (compilation-assq col loc))
2010     (if (cdr loc)
2011         (setcdr (cddr loc) (list marker))
2012       (setcdr loc (list line file marker)))
2013     loc))
2014
2015 (defcustom compilation-context-lines nil
2016   "Display this many lines of leading context before the current message.
2017 If nil and the left fringe is displayed, don't scroll the
2018 compilation output window; an arrow in the left fringe points to
2019 the current message.  If nil and there is no left fringe, the message
2020 displays at the top of the window; there is no arrow."
2021   :type '(choice integer (const :tag "No window scrolling" nil))
2022   :group 'compilation
2023   :version "22.1")
2024
2025 (defsubst compilation-set-window (w mk)
2026   "Align the compilation output window W with marker MK near top."
2027   (if (integerp compilation-context-lines)
2028       (set-window-start w (save-excursion
2029                             (goto-char mk)
2030                             (beginning-of-line
2031                              (- 1 compilation-context-lines))
2032                             (point)))
2033     ;; If there is no left fringe.
2034     (if (equal (car (window-fringes)) 0)
2035         (set-window-start w (save-excursion
2036                               (goto-char mk)
2037                             (beginning-of-line 1)
2038                             (point)))))
2039     (set-window-point w mk))
2040
2041 (defvar next-error-highlight-timer)
2042
2043 (defun compilation-goto-locus (msg mk end-mk)
2044   "Jump to an error corresponding to MSG at MK.
2045 All arguments are markers.  If END-MK is non-nil, mark is set there
2046 and overlay is highlighted between MK and END-MK."
2047   ;; Show compilation buffer in other window, scrolled to this error.
2048   (let* ((from-compilation-buffer (eq (window-buffer (selected-window))
2049                                       (marker-buffer msg)))
2050          ;; Use an existing window if it is in a visible frame.
2051          (pre-existing (get-buffer-window (marker-buffer msg) 0))
2052          (w (if (and from-compilation-buffer pre-existing)
2053                 ;; Calling display-buffer here may end up (partly) hiding
2054                 ;; the error location if the two buffers are in two
2055                 ;; different frames.  So don't do it if it's not necessary.
2056                 pre-existing
2057               (let ((display-buffer-reuse-frames t)
2058                     (pop-up-windows t))
2059                 ;; Pop up a window.
2060                 (display-buffer (marker-buffer msg)))))
2061          (highlight-regexp (with-current-buffer (marker-buffer msg)
2062                              ;; also do this while we change buffer
2063                              (compilation-set-window w msg)
2064                              compilation-highlight-regexp)))
2065     ;; Ideally, the window-size should be passed to `display-buffer' (via
2066     ;; something like special-display-buffer) so it's only used when
2067     ;; creating a new window.
2068     (unless pre-existing (compilation-set-window-height w))
2069
2070     (if from-compilation-buffer
2071         ;; If the compilation buffer window was selected,
2072         ;; keep the compilation buffer in this window;
2073         ;; display the source in another window.
2074         (let ((pop-up-windows t))
2075           (pop-to-buffer (marker-buffer mk) 'other-window))
2076       (if (window-dedicated-p (selected-window))
2077           (pop-to-buffer (marker-buffer mk))
2078         (switch-to-buffer (marker-buffer mk))))
2079     (unless (eq (goto-char mk) (point))
2080       ;; If narrowing gets in the way of going to the right place, widen.
2081       (widen)
2082       (if next-error-move-function
2083           (funcall next-error-move-function msg mk)
2084         (goto-char mk)))
2085     (if end-mk
2086         (push-mark end-mk t)
2087       (if mark-active (setq mark-active)))
2088     ;; If hideshow got in the way of
2089     ;; seeing the right place, open permanently.
2090     (dolist (ov (overlays-at (point)))
2091       (when (eq 'hs (overlay-get ov 'invisible))
2092         (delete-overlay ov)
2093         (goto-char mk)))
2094
2095     (when highlight-regexp
2096       (if (timerp next-error-highlight-timer)
2097           (cancel-timer next-error-highlight-timer))
2098       (unless compilation-highlight-overlay
2099         (setq compilation-highlight-overlay
2100               (make-overlay (point-min) (point-min)))
2101         (overlay-put compilation-highlight-overlay 'face 'next-error))
2102       (with-current-buffer (marker-buffer mk)
2103         (save-excursion
2104           (if end-mk (goto-char end-mk) (end-of-line))
2105           (let ((end (point)))
2106             (if mk (goto-char mk) (beginning-of-line))
2107             (if (and (stringp highlight-regexp)
2108                      (re-search-forward highlight-regexp end t))
2109                 (progn
2110                   (goto-char (match-beginning 0))
2111                   (move-overlay compilation-highlight-overlay
2112                                 (match-beginning 0) (match-end 0)
2113                                 (current-buffer)))
2114               (move-overlay compilation-highlight-overlay
2115                             (point) end (current-buffer)))
2116             (if (or (eq next-error-highlight t)
2117                     (numberp next-error-highlight))
2118                 ;; We want highlighting: delete overlay on next input.
2119                 (add-hook 'pre-command-hook
2120                           'compilation-goto-locus-delete-o)
2121               ;; We don't want highlighting: delete overlay now.
2122               (delete-overlay compilation-highlight-overlay))
2123             ;; We want highlighting for a limited time:
2124             ;; set up a timer to delete it.
2125             (when (numberp next-error-highlight)
2126               (setq next-error-highlight-timer
2127                     (run-at-time next-error-highlight nil
2128                                  'compilation-goto-locus-delete-o)))))))
2129     (when (and (eq next-error-highlight 'fringe-arrow))
2130       ;; We want a fringe arrow (instead of highlighting).
2131       (setq next-error-overlay-arrow-position
2132             (copy-marker (line-beginning-position))))))
2133
2134 (defun compilation-goto-locus-delete-o ()
2135   (delete-overlay compilation-highlight-overlay)
2136   ;; Get rid of timer and hook that would try to do this again.
2137   (if (timerp next-error-highlight-timer)
2138       (cancel-timer next-error-highlight-timer))
2139   (remove-hook 'pre-command-hook
2140                'compilation-goto-locus-delete-o))
2141 \f
2142 (defun compilation-find-file (marker filename directory &rest formats)
2143   "Find a buffer for file FILENAME.
2144 If FILENAME is not found at all, ask the user where to find it.
2145 Pop up the buffer containing MARKER and scroll to MARKER if we ask
2146 the user where to find the file.
2147 Search the directories in `compilation-search-path'.
2148 A nil in `compilation-search-path' means to try the
2149 \"current\" directory, which is passed in DIRECTORY.
2150 If DIRECTORY is relative, it is combined with `default-directory'.
2151 If DIRECTORY is nil, that means use `default-directory'.
2152 FORMATS, if given, is a list of formats to reformat FILENAME when
2153 looking for it: for each element FMT in FORMATS, this function
2154 attempts to find a file whose name is produced by (format FMT FILENAME)."
2155   (or formats (setq formats '("%s")))
2156   (let ((dirs compilation-search-path)
2157         (spec-dir (if directory
2158                       (expand-file-name directory)
2159                     default-directory))
2160         buffer thisdir fmts name)
2161     (if (file-name-absolute-p filename)
2162         ;; The file name is absolute.  Use its explicit directory as
2163         ;; the first in the search path, and strip it from FILENAME.
2164         (setq filename (abbreviate-file-name (expand-file-name filename))
2165               dirs (cons (file-name-directory filename) dirs)
2166               filename (file-name-nondirectory filename)))
2167     ;; Now search the path.
2168     (while (and dirs (null buffer))
2169       (setq thisdir (or (car dirs) spec-dir)
2170             fmts formats)
2171       ;; For each directory, try each format string.
2172       (while (and fmts (null buffer))
2173         (setq name (expand-file-name (format (car fmts) filename) thisdir)
2174               buffer (and (file-exists-p name)
2175                           (find-file-noselect name))
2176               fmts (cdr fmts)))
2177       (setq dirs (cdr dirs)))
2178     (while (null buffer)    ;Repeat until the user selects an existing file.
2179       ;; The file doesn't exist.  Ask the user where to find it.
2180       (save-excursion            ;This save-excursion is probably not right.
2181         (let ((pop-up-windows t))
2182           (compilation-set-window (display-buffer (marker-buffer marker))
2183                                   marker)
2184           (let* ((name (read-file-name
2185                         (format "Find this %s in (default %s): "
2186                                 compilation-error filename)
2187                         spec-dir filename t nil
2188                         ;; The predicate below is fine when called from
2189                         ;; minibuffer-complete-and-exit, but it's too
2190                         ;; restrictive otherwise, since it also prevents the
2191                         ;; user from completing "fo" to "foo/" when she
2192                         ;; wants to enter "foo/bar".
2193                         ;;
2194                         ;; Try to make sure the user can only select
2195                         ;; a valid answer.  This predicate may be ignored,
2196                         ;; tho, so we still have to double-check afterwards.
2197                         ;; TODO: We should probably fix read-file-name so
2198                         ;; that it never ignores this predicate, even when
2199                         ;; using popup dialog boxes.
2200                         ;; (lambda (name)
2201                         ;;   (if (file-directory-p name)
2202                         ;;       (setq name (expand-file-name filename name)))
2203                         ;;   (file-exists-p name))
2204                         ))
2205                  (origname name))
2206             (cond
2207              ((not (file-exists-p name))
2208               (message "Cannot find file `%s'" name)
2209               (ding) (sit-for 2))
2210              ((and (file-directory-p name)
2211                    (not (file-exists-p
2212                          (setq name (expand-file-name filename name)))))
2213               (message "No `%s' in directory %s" filename origname)
2214               (ding) (sit-for 2))
2215              (t
2216               (setq buffer (find-file-noselect name))))))))
2217     ;; Make intangible overlays tangible.
2218     ;; This is weird: it's not even clear which is the current buffer,
2219     ;; so the code below can't be expected to DTRT here.  -- Stef
2220     (dolist (ov (overlays-in (point-min) (point-max)))
2221       (when (overlay-get ov 'intangible)
2222         (overlay-put ov 'intangible nil)))
2223     buffer))
2224
2225 (defun compilation-get-file-structure (file &optional fmt)
2226   "Retrieve FILE's file-structure or create a new one.
2227 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
2228 In the former case, FILENAME may be relative or absolute.
2229
2230 The file-structure looks like this:
2231   (list (list FILENAME [DIR-FROM-PREV-MSG]) FMT LINE-STRUCT...)"
2232   (or (gethash file compilation-locs)
2233       ;; File was not previously encountered, at least not in the form passed.
2234       ;; Let's normalize it and look again.
2235       (let ((filename (car file))
2236             ;; Get the specified directory from FILE.
2237             (spec-directory (if (cdr file)
2238                                 (file-truename (cdr file)))))
2239
2240         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
2241         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
2242         ;; buffer.)
2243         (when (and (boundp 'comint-file-name-prefix)
2244                    (not (equal comint-file-name-prefix "")))
2245           (if (file-name-absolute-p filename)
2246               (setq filename
2247                     (concat comint-file-name-prefix filename))
2248             (if spec-directory
2249                 (setq spec-directory
2250                       (file-truename
2251                        (concat comint-file-name-prefix spec-directory))))))
2252
2253         ;; If compilation-parse-errors-filename-function is
2254         ;; defined, use it to process the filename.
2255         (when compilation-parse-errors-filename-function
2256           (setq filename
2257                 (funcall compilation-parse-errors-filename-function
2258                          filename)))
2259
2260         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
2261         ;; file names like "./bar//foo.c" for file "bar/foo.c";
2262         ;; expand-file-name will collapse these into "/foo.c" and fail to find
2263         ;; the appropriate file.  So we look for doubled slashes in the file
2264         ;; name and fix them.
2265         (setq filename (command-line-normalize-file-name filename))
2266
2267         ;; Store it for the possibly unnormalized name
2268         (puthash file
2269                  ;; Retrieve or create file-structure for normalized name
2270                  ;; The gethash used to not use spec-directory, but
2271                  ;; this leads to errors when files in different
2272                  ;; directories have the same name:
2273                  ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg00463.html
2274                  (or (gethash (cons filename spec-directory) compilation-locs)
2275                      (puthash (cons filename spec-directory)
2276                               (list (list filename spec-directory) fmt)
2277                               compilation-locs))
2278                  compilation-locs))))
2279
2280 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
2281
2282 ;;; Compatibility with the old compile.el.
2283
2284 (defun compile-buffer-substring (n) (if n (match-string n)))
2285
2286 (defun compilation-compat-error-properties (err)
2287   "Map old-style error ERR to new-style message."
2288   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
2289   ;; (MARKER . MARKER).
2290   (let ((dst (cdr err)))
2291     (if (markerp dst)
2292         ;; Must start with a face, for font-lock.
2293         `(face nil
2294           message ,(list (list nil nil nil dst) 2)
2295           help-echo "mouse-2: visit the source location"
2296           keymap compilation-button-map
2297           mouse-face highlight)
2298       ;; Too difficult to do it by hand: dispatch to the normal code.
2299       (let* ((file (pop dst))
2300              (line (pop dst))
2301              (col (pop dst))
2302              (filename (pop file))
2303              (dirname (pop file))
2304              (fmt (pop file)))
2305         (compilation-internal-error-properties
2306          (cons filename dirname) line nil col nil 2 fmt)))))
2307
2308 (defun compilation-compat-parse-errors (limit)
2309   (when compilation-parse-errors-function
2310     ;; FIXME: We should remove the rest of the compilation keywords
2311     ;; but we can't do that from here because font-lock is using
2312     ;; the value right now.  --stef
2313     (save-excursion
2314       (setq compilation-error-list nil)
2315       ;; Reset compilation-parsing-end each time because font-lock
2316       ;; might force us the re-parse many times (typically because
2317       ;; some code adds some text-property to the output that we
2318       ;; already parsed).  You might say "why reparse", well:
2319       ;; because font-lock has just removed the `message' property so
2320       ;; have to do it all over again.
2321       (if compilation-parsing-end
2322           (set-marker compilation-parsing-end (point))
2323         (setq compilation-parsing-end (point-marker)))
2324       (condition-case nil
2325           ;; Ignore any error: we're calling this function earlier than
2326           ;; in the old compile.el so things might not all be setup yet.
2327           (funcall compilation-parse-errors-function limit nil)
2328         (error nil))
2329       (dolist (err (if (listp compilation-error-list) compilation-error-list))
2330         (let* ((src (car err))
2331                (dst (cdr err))
2332                (loc (cond ((markerp dst) (list nil nil nil dst))
2333                           ((consp dst)
2334                            (list (nth 2 dst) (nth 1 dst)
2335                                  (cons (cdar dst) (caar dst)))))))
2336           (when loc
2337             (goto-char src)
2338             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
2339             (put-text-property src (line-end-position)
2340                                'message (list loc 2)))))))
2341   (goto-char limit)
2342   nil)
2343
2344 ;; Beware: this is not only compatibility code.  New code stil uses it.  --Stef
2345 (defun compilation-forget-errors ()
2346   ;; In case we hit the same file/line specs, we want to recompute a new
2347   ;; marker for them, so flush our cache.
2348   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
2349   (setq compilation-gcpro nil)
2350   ;; FIXME: the old code reset the directory-stack, so maybe we should
2351   ;; put a `directory change' marker of some sort, but where?  -stef
2352   ;;
2353   ;; FIXME: The old code moved compilation-current-error (which was
2354   ;; virtually represented by a mix of compilation-parsing-end and
2355   ;; compilation-error-list) to point-min, but that was only meaningful for
2356   ;; the internal uses of compilation-forget-errors: all calls from external
2357   ;; packages seem to be followed by a move of compilation-parsing-end to
2358   ;; something equivalent to point-max.  So we heuristically move
2359   ;; compilation-current-error to point-max (since the external package
2360   ;; won't know that it should do it).  --Stef
2361   (setq compilation-current-error nil)
2362   (let* ((proc (get-buffer-process (current-buffer)))
2363          (mark (if proc (process-mark proc)))
2364          (pos (or mark (point-max))))
2365     (setq compilation-messages-start
2366           ;; In the future, ignore the text already present in the buffer.
2367           ;; Since many process filter functions insert before markers,
2368           ;; we need to put ours just before the insertion point rather
2369           ;; than at the insertion point.  If that's not possible, then
2370           ;; don't use a marker.  --Stef
2371           (if (> pos (point-min)) (copy-marker (1- pos)) pos)))
2372   ;; Again, since this command is used in buffers that contain several
2373   ;; compilations, to set the beginning of "this compilation", it's a good
2374   ;; place to reset compilation-auto-jump-to-next.
2375   (set (make-local-variable 'compilation-auto-jump-to-next)
2376        (or compilation-auto-jump-to-first-error
2377            (eq compilation-scroll-output 'first-error))))
2378
2379 ;;;###autoload
2380 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
2381
2382 (provide 'compile)
2383
2384 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
2385 ;;; compile.el ends here