configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(locallisppath,
 234 [AS_HELP_STRING([--enable-locallisppath=PATH],
 235                 [directories Emacs should search for lisp files specific
 236                  to this site])],
 237 if test "${enableval}" = "no"; then
 238   locallisppath=
 239 elif test "${enableval}" != "yes"; then
 240   locallisppath=${enableval}
 241 fi)
 242
 243 AC_ARG_ENABLE(checking,
 244 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 245                 [enable expensive run-time checks.  With LIST,
 246                  enable only specific categories of checks.
 247                  Categories are: all,yes,no.
 248                  Flags are: stringbytes, stringoverrun, stringfreelist,
 249                  xmallocoverrun, conslist, glyphs])],
 250 [ac_checking_flags="${enableval}"],[])
 251 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 252 for check in $ac_checking_flags
 253 do
 254         case $check in
 255         # these set all the flags to specific states
 256         yes)            ac_enable_checking=1 ;;
 257         no)             ac_enable_checking= ;
 258                         ac_gc_check_stringbytes= ;
 259                         ac_gc_check_string_overrun= ;
 260                         ac_gc_check_string_free_list= ;
 261                         ac_xmalloc_overrun= ;
 262                         ac_gc_check_cons_list= ;
 263                         ac_glyphs_debug= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;
 270                         ac_glyphs_debug=1 ;;
 271         # these enable particular checks
 272         stringbytes)    ac_gc_check_stringbytes=1 ;;
 273         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 274         stringfreelist) ac_gc_check_string_free_list=1 ;;
 275         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 276         conslist)       ac_gc_check_cons_list=1 ;;
 277         glyphs)         ac_glyphs_debug=1 ;;
 278         *)      AC_MSG_ERROR(unknown check category $check) ;;
 279         esac
 280 done
 281 IFS="$ac_save_IFS"
 282
 283 if test x$ac_enable_checking != x ; then
 284   AC_DEFINE(ENABLE_CHECKING, 1,
 285 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 286 fi
 287 if test x$ac_gc_check_stringbytes != x ; then
 288   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 289 [Define this temporarily to hunt a bug.  If defined, the size of
 290    strings is redundantly recorded in sdata structures so that it can
 291    be compared to the sizes recorded in Lisp strings.])
 292 fi
 293 if test x$ac_gc_check_string_overrun != x ; then
 294   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 295 [Define this to check for short string overrun.])
 296 fi
 297 if test x$ac_gc_check_string_free_list != x ; then
 298   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 299 [Define this to check the string free list.])
 300 fi
 301 if test x$ac_xmalloc_overrun != x ; then
 302   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 303 [Define this to check for malloc buffer overrun.])
 304 fi
 305 if test x$ac_gc_check_cons_list != x ; then
 306   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 307 [Define this to check for errors in cons list.])
 308 fi
 309 if test x$ac_glyphs_debug != x ; then
 310   AC_DEFINE(GLYPH_DEBUG, 1,
 311 [Define this to enable glyphs debugging code.])
 312 fi
 313
 314 AC_ARG_ENABLE(check-lisp-object-type,
 315 [AS_HELP_STRING([--enable-check-lisp-object-type],
 316                 [enable compile time checks for the Lisp_Object data type.
 317                 This is useful for development for catching certain types of bugs.])],
 318 if test "${enableval}" != "no"; then
 319    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 320    [Define this to enable compile time checks for the Lisp_Object data type.])
 321 fi)
 322
 323
 324 AC_ARG_ENABLE(profiling,
 325 [AS_HELP_STRING([--enable-profiling],
 326                 [build emacs with profiling support.
 327                  This might not work on all platforms])],
 328 [ac_enable_profiling="${enableval}"],[])
 329 if test x$ac_enable_profiling != x ; then
 330    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 331 else
 332    PROFILING_CFLAGS=
 333 fi
 334 AC_SUBST(PROFILING_CFLAGS)
 335
 336 AC_ARG_ENABLE(autodepend,
 337 [AS_HELP_STRING([--enable-autodepend],
 338                 [automatically generate dependencies to .h-files.
 339                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 340                  found])],
 341 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 342
 343 #### Make srcdir absolute, if it isn't already.  It's important to
 344 #### avoid running the path through pwd unnecessarily, since pwd can
 345 #### give you automounter prefixes, which can go away.  We do all this
 346 #### so Emacs can find its files when run uninstalled.
 347 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 348 unset CDPATH
 349 case "${srcdir}" in
 350   /* ) ;;
 351   . )
 352     ## We may be able to use the $PWD environment variable to make this
 353     ## absolute.  But sometimes PWD is inaccurate.
 354     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 355     ## but that tested only for a well-formed and valid PWD,
 356     ## it did not object when PWD was well-formed and valid but just wrong.
 357     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 358     then
 359       srcdir="$PWD"
 360     else
 361       srcdir="`(cd ${srcdir}; pwd)`"
 362     fi
 363   ;;
 364   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 365 esac
 366
 367 #### Given the configuration name, set opsysfile to the
 368 #### name of s/*.h file we should use.
 369
 370 ### Canonicalize the configuration name.
 371
 372 AC_CANONICAL_HOST
 373 canonical=$host
 374 configuration=${host_alias-${build_alias-$host}}
 375
 376 dnl This used to use changequote, but, apart from `changequote is evil'
 377 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 378 dnl the great gob of text.  Thus it's not processed for possible expansion.
 379 dnl Just make sure the brackets remain balanced.
 380 dnl
 381 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 382 dnl indicated by comments.
 383 dnl quotation begins
 384 [
 385
 386 ### If you add support for a new configuration, add code to this
 387 ### switch statement to recognize your configuration name and select
 388 ### the appropriate operating system file.
 389
 390 ### You would hope that you could choose an s/*.h
 391 ### file based on the operating system portion.  However, it turns out
 392 ### that each s/*.h file is pretty manufacturer-specific.
 393 ### So we basically have to have a special case for each
 394 ### configuration name.
 395 ###
 396 ### As far as handling version numbers on operating systems is
 397 ### concerned, make sure things will fail in a fixable way.  If
 398 ### /etc/MACHINES doesn't say anything about version numbers, be
 399 ### prepared to handle anything reasonably.  If version numbers
 400 ### matter, be sure /etc/MACHINES says something about it.
 401
 402 opsys='' unported=no
 403 case "${canonical}" in
 404
 405   ## GNU/Linux and similar ports
 406   *-*-linux* )
 407     opsys=gnu-linux
 408   ;;
 409
 410   ## FreeBSD ports
 411   *-*-freebsd* )
 412     opsys=freebsd
 413   ;;
 414
 415   ## FreeBSD kernel + glibc based userland
 416   *-*-kfreebsd*gnu* )
 417     opsys=gnu-kfreebsd
 418   ;;
 419
 420   ## NetBSD ports
 421   *-*-netbsd* )
 422     opsys=netbsd
 423   ;;
 424
 425   ## OpenBSD ports
 426   *-*-openbsd* )
 427     opsys=openbsd
 428   ;;
 429
 430   ## Apple Darwin / Mac OS X
 431   *-apple-darwin* )
 432     case "${canonical}" in
 433       i[3456]86-* )  ;;
 434       powerpc-* )    ;;
 435       x86_64-* )     ;;
 436       * )            unported=yes ;;
 437     esac
 438     opsys=darwin
 439     ## Use fink packages if available.
 440     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 441 ##    if test -d /sw/include && test -d /sw/lib; then
 442 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 443 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 444 ##    fi
 445   ;;
 446
 447   ## HP 9000 series 700 and 800, running HP/UX
 448   hppa*-hp-hpux10.2* )
 449     opsys=hpux10-20
 450   ;;
 451   hppa*-hp-hpux1[1-9]* )
 452     opsys=hpux11
 453     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 454   ;;
 455
 456   ## IBM machines
 457   rs6000-ibm-aix4.[23]* )
 458     opsys=aix4-2
 459   ;;
 460   powerpc-ibm-aix4.[23]*  )
 461     opsys=aix4-2
 462   ;;
 463   rs6000-ibm-aix[56]* )
 464     opsys=aix4-2
 465   ;;
 466   powerpc-ibm-aix[56]*  )
 467     opsys=aix4-2
 468   ;;
 469
 470   ## Silicon Graphics machines
 471   ## Iris 4D
 472   mips-sgi-irix6.5 )
 473     opsys=irix6-5
 474     # Without defining _LANGUAGE_C, things get masked out in the headers
 475     # so that, for instance, grepping for `free' in stdlib.h fails and
 476     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 477     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 478   ;;
 479
 480   ## Suns
 481   *-sun-solaris* \
 482     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 483     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 484     case "${canonical}" in
 485       i[3456]86-*-* )   ;;
 486       amd64-*-*|x86_64-*-*) ;;
 487       sparc* )          ;;
 488       * )               unported=yes ;;
 489     esac
 490     case "${canonical}" in
 491       *-sunos5.6* | *-solaris2.6* )
 492                 opsys=sol2-6
 493                 RANLIB="ar -ts"
 494                 ;;
 495       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 496                 opsys=sol2-6
 497                 emacs_check_sunpro_c=yes
 498                 ;;
 499       *-sunos5* | *-solaris* )
 500                 opsys=sol2-10
 501                 emacs_check_sunpro_c=yes
 502                 ;;
 503     esac
 504     ## Watch out for a compiler that we know will not work.
 505     case "${canonical}" in
 506      *-solaris* | *-sunos5* )
 507                 if [ "x$CC" = x/usr/ucb/cc ]; then
 508                   ## /usr/ucb/cc doesn't work;
 509                   ## we should find some other compiler that does work.
 510                   unset CC
 511                 fi
 512                 ;;
 513       *) ;;
 514     esac
 515   ;;
 516
 517   ## Intel 386 machines where we don't care about the manufacturer.
 518   i[3456]86-*-* )
 519     case "${canonical}" in
 520       *-cygwin )                opsys=cygwin ;;
 521       *-darwin* )               opsys=darwin ;;
 522       *-sysv4.2uw* )            opsys=unixware ;;
 523       *-sysv5uw* )              opsys=unixware ;;
 524       *-sysv5OpenUNIX* )        opsys=unixware ;;
 525       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 526     esac
 527   ;;
 528
 529   * )
 530     unported=yes
 531   ;;
 532 esac
 533
 534 ### If the code above didn't choose an operating system, just choose
 535 ### an operating system based on the configuration name.  You really
 536 ### only want to use this when you have no idea what the right
 537 ### operating system is; if you know what operating systems a machine
 538 ### runs, it's cleaner to make it explicit in the case statement
 539 ### above.
 540 if test x"${opsys}" = x; then
 541   case "${canonical}" in
 542     *-gnu* )                            opsys=gnu ;;
 543     * )
 544       unported=yes
 545     ;;
 546   esac
 547 fi
 548
 549 ]
 550 dnl quotation ends
 551
 552 if test $unported = yes; then
 553   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 554 Check `etc/MACHINES' for recognized configuration names.])
 555 fi
 556
 557 opsysfile="s/${opsys}.h"
 558
 559
 560 #### Choose a compiler.
 561
 562 dnl Sets GCC=yes if using gcc.
 563 AC_PROG_CC
 564 AM_PROG_CC_C_O
 565
 566 if test x$GCC = xyes; then
 567   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 568 else
 569   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 570 fi
 571
 572 # Initialize gnulib right after choosing the compiler.
 573 gl_EARLY
 574
 575 AC_ARG_ENABLE([gcc-warnings],
 576   [AS_HELP_STRING([--enable-gcc-warnings],
 577                   [turn on lots of GCC warnings (for developers)])],
 578   [case $enableval in
 579      yes|no) ;;
 580      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 581    esac
 582    gl_gcc_warnings=$enableval],
 583   [gl_gcc_warnings=no]
 584 )
 585
 586 AC_ARG_ENABLE(link-time-optimization,
 587 [AS_HELP_STRING([--enable-link-time-optimization],
 588                 [build emacs with link-time optimization.
 589                  This is supported only for GCC since 4.5.0.])],
 590 if test "${enableval}" != "no"; then
 591    AC_MSG_CHECKING([whether link-time optimization is supported])
 592    ac_lto_supported=no
 593    if test x$GCC = xyes; then
 594       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 595       if test x$CPUS != x; then
 596          LTO="-flto=$CPUS"
 597       else
 598          LTO="-flto"
 599       fi
 600       old_CFLAGS=$CFLAGS
 601       CFLAGS="$CFLAGS $LTO"
 602       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 603         [ac_lto_supported=yes], [ac_lto_supported=no])
 604       CFLAGS="$old_CFLAGS"
 605    fi
 606    AC_MSG_RESULT([$ac_lto_supported])
 607    if test "$ac_lto_supported" = "yes"; then
 608       CFLAGS="$CFLAGS $LTO"
 609    fi
 610 fi)
 611
 612 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 613 # ------------------------------------------------
 614 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 615 # Otherwise, run RUN-IF-NOT-FOUND.
 616 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 617   [AC_PREPROC_IFELSE(
 618     [AC_LANG_PROGRAM(
 619       [[
 620 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 621 /* ok */
 622 #else
 623 # error "your version of gcc is older than $1.$2"
 624 #endif
 625       ]]),
 626     ], [$3], [$4])
 627   ]
 628 )
 629
 630 # When compiling with GCC, prefer -isystem to -I when including system
 631 # include files, to avoid generating useless diagnostics for the files.
 632 if test "$gl_gcc_warnings" != yes; then
 633   isystem='-I'
 634 else
 635   isystem='-isystem '
 636
 637   # This, $nw, is the list of warnings we disable.
 638   nw=
 639
 640   case $with_x_toolkit in
 641     lucid | athena | motif)
 642        # Old toolkits mishandle 'const'.
 643        nw="$nw -Wwrite-strings"
 644        ;;
 645     *)
 646        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 647        ;;
 648   esac
 649   AC_SUBST([WERROR_CFLAGS])
 650
 651   nw="$nw -Waggregate-return"       # anachronistic
 652   nw="$nw -Wlong-long"              # C90 is anachronistic
 653   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 654   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 655   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 656   nw="$nw -Wcast-qual"              # Too many warnings for now
 657   nw="$nw -Wconversion"             # Too many warnings for now
 658   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 659   nw="$nw -Wsign-conversion"        # Too many warnings for now
 660   nw="$nw -Woverlength-strings"     # Not a problem these days
 661   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 662   nw="$nw -Wpadded"                 # Our structs are not padded
 663   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 664   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 665   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 666   nw="$nw -Wvla"                    # warnings in gettext.h
 667   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 668   nw="$nw -Wswitch-enum"            # Too many warnings for now
 669   nw="$nw -Wswitch-default"         # Too many warnings for now
 670   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 671   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 672
 673   # Emacs doesn't care about shadowing; see
 674   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 675   nw="$nw -Wshadow"
 676
 677   # The following lines should be removable at some point.
 678   nw="$nw -Wstack-protector"
 679   nw="$nw -Wstrict-overflow"
 680   nw="$nw -Wsuggest-attribute=const"
 681   nw="$nw -Wsuggest-attribute=pure"
 682
 683   gl_MANYWARN_ALL_GCC([ws])
 684   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 685   for w in $ws; do
 686     gl_WARN_ADD([$w])
 687   done
 688   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 689   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 690   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 691   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 692   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 693   gl_WARN_ADD([-Wno-format-nonliteral])
 694
 695   # In spite of excluding -Wlogical-op above, it is enabled, as of
 696   # gcc 4.5.0 20090517.
 697   gl_WARN_ADD([-Wno-logical-op])
 698
 699   gl_WARN_ADD([-fdiagnostics-show-option])
 700   gl_WARN_ADD([-funit-at-a-time])
 701
 702   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 703   AC_DEFINE([_FORTIFY_SOURCE], [2],
 704     [enable compile-time and run-time bounds-checking, and some warnings])
 705   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 706
 707   # We use a slightly smaller set of warning options for lib/.
 708   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 709   nw=
 710   nw="$nw -Wunused-macros"
 711
 712   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 713   AC_SUBST([GNULIB_WARN_CFLAGS])
 714 fi
 715
 716
 717
 718 dnl Some other nice autoconf tests.
 719 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 720 dnl AC_PROG_INSTALL
 721 dnl AC_PROG_MKDIR_P
 722 dnl if test "x$RANLIB" = x; then
 723 dnl   AC_PROG_RANLIB
 724 dnl fi
 725
 726 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 727   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 728 dnl Don't use GZIP, which is used by gzip for additional parameters.
 729 AC_PATH_PROG(GZIP_PROG, gzip)
 730
 731 if test $opsys = gnu-linux; then
 732   AC_PATH_PROG(PAXCTL, paxctl,,
 733     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 734 fi
 735
 736 ## Need makeinfo >= 4.7 (?) to build the manuals.
 737 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 738 dnl By this stage, configure has already checked for egrep and set EGREP,
 739 dnl or exited with an error if no egrep was found.
 740 if test "$MAKEINFO" != "no" && \
 741   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 742    MAKEINFO=no
 743 fi
 744
 745 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 746 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 747 ## therefore in the category of "special tools" not normally required, which
 748 ## configure does not have to check for (eg autoconf itself).
 749 ## In a Bazaar checkout on the other hand, the manuals are not included.
 750 ## So makeinfo is a requirement to build from Bazaar, and configure
 751 ## should test for it as it does for any other build requirement.
 752 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 753 ## with pre-built manuals, from a Bazaar checkout.
 754 HAVE_MAKEINFO=yes
 755
 756 if test "$MAKEINFO" = "no"; then
 757   MAKEINFO=makeinfo
 758   if test "x${with_makeinfo}" = "xno"; then
 759     HAVE_MAKEINFO=no
 760   elif test ! -e $srcdir/info/emacs; then
 761     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 762 source tree does not seem to have pre-built manuals in the `info' directory.
 763 Either install a suitable version of makeinfo, or re-run configure
 764 with the `--without-makeinfo' option to build without the manuals.] )
 765   fi
 766 fi
 767 AC_SUBST(HAVE_MAKEINFO)
 768
 769 dnl Just so that there is only a single place we need to edit.
 770 INFO_EXT=.info
 771 INFO_OPTS=--no-split
 772 AC_SUBST(INFO_EXT)
 773 AC_SUBST(INFO_OPTS)
 774
 775 dnl Add our options to ac_link now, after it is set up.
 776
 777 if test x$GCC = xyes; then
 778   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 779     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 780 else
 781   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 782     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 783 fi
 784
 785 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 786 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 787 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 788 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 789 dnl if not built to support GNU ld.
 790
 791 late_LDFLAGS=$LDFLAGS
 792 if test x$GCC = xyes; then
 793   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 794 else
 795   LDFLAGS="$LDFLAGS -znocombreloc"
 796 fi
 797
 798 AC_MSG_CHECKING([for -znocombreloc])
 799 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 800   [AC_MSG_RESULT(yes)],
 801   LDFLAGS=$late_LDFLAGS
 802   [AC_MSG_RESULT(no)])
 803
 804
 805 dnl The function dump-emacs will not be defined and temacs will do
 806 dnl (load "loadup") automatically unless told otherwise.
 807 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 808 case "$opsys" in
 809   your-opsys-here) CANNOT_DUMP=yes ;;
 810 esac
 811
 812 test "$CANNOT_DUMP" = "yes" && \
 813   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 814
 815 AC_SUBST(CANNOT_DUMP)
 816
 817
 818 UNEXEC_OBJ=unexelf.o
 819 case "$opsys" in
 820   # MSDOS uses unexcoff.o
 821   # MSWindows uses unexw32.o
 822   aix4-2)
 823    UNEXEC_OBJ=unexaix.o
 824    ;;
 825   cygwin)
 826    UNEXEC_OBJ=unexcw.o
 827    ;;
 828   darwin)
 829    UNEXEC_OBJ=unexmacosx.o
 830    ;;
 831   hpux10-20 | hpux11)
 832    UNEXEC_OBJ=unexhp9k800.o
 833    ;;
 834   sol2-10)
 835    # Use the Solaris dldump() function, called from unexsol.c, to dump
 836    # emacs, instead of the generic ELF dump code found in unexelf.c.
 837    # The resulting binary has a complete symbol table, and is better
 838    # for debugging and other observability tools (debuggers, pstack, etc).
 839    #
 840    # If you encounter a problem using dldump(), please consider sending
 841    # a message to the OpenSolaris tools-linking mailing list:
 842    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 843    #
 844    # It is likely that dldump() works with older Solaris too, but this has
 845    # not been tested, so for now this change is for Solaris 10 or newer.
 846    UNEXEC_OBJ=unexsol.o
 847    ;;
 848 esac
 849
 850 LD_SWITCH_SYSTEM=
 851 case "$opsys" in
 852   freebsd)
 853    ## Let `ld' find image libs and similar things in /usr/local/lib.
 854    ## The system compiler, GCC, has apparently been modified to not
 855    ## look there, contrary to what a stock GCC would do.
 856 ### It's not our place to do this.  See bug#10313#17.
 857 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 858       :
 859    ;;
 860
 861   gnu-linux)
 862    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 863    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 864    ;;
 865
 866   netbsd)
 867 ### It's not our place to do this.  See bug#10313#17.
 868 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 869       :
 870    ;;
 871
 872   openbsd)
 873    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 874    ## otherwise Emacs dumps core on elf systems.
 875    LD_SWITCH_SYSTEM="-Z"
 876    ;;
 877 esac
 878 AC_SUBST(LD_SWITCH_SYSTEM)
 879
 880 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 881
 882 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 883 ## which has not been defined yet.  When this was handled with cpp,
 884 ## it was expanded to null when configure sourced the s/*.h file.
 885 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 886 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 887 ## (or somesuch), but because it is supposed to go at the _front_
 888 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 889 ## Compare with the gnu-linux case below, which added to the end
 890 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 891 ## LD_SWITCH_SYSTEM_TEMACS.
 892 case "$opsys" in
 893   netbsd|openbsd)
 894    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 895 esac
 896
 897
 898 C_SWITCH_MACHINE=
 899 case $canonical in
 900  alpha*)
 901   AC_CHECK_DECL([__ELF__])
 902   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 903     ## With ELF, make sure that all common symbols get allocated to in the
 904     ## data section.  Otherwise, the dump of temacs may miss variables in
 905     ## the shared library that have been initialized.  For example, with
 906     ## GNU libc, __malloc_initialized would normally be resolved to the
 907     ## shared library's .bss section, which is fatal.
 908     if test "x$GCC" = "xyes"; then
 909       C_SWITCH_MACHINE="-fno-common"
 910     else
 911       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 912     fi
 913   else
 914     UNEXEC_OBJ=unexalpha.o
 915   fi
 916   ;;
 917 esac
 918 AC_SUBST(C_SWITCH_MACHINE)
 919
 920 AC_SUBST(UNEXEC_OBJ)
 921
 922 C_SWITCH_SYSTEM=
 923 ## Some programs in src produce warnings saying certain subprograms
 924 ## are too complex and need a MAXMEM value greater than 2000 for
 925 ## additional optimization.  --nils@exp-math.uni-essen.de
 926 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 927   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 928 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 929 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 930 AC_SUBST(C_SWITCH_SYSTEM)
 931
 932
 933 LIBS_SYSTEM=
 934 case "$opsys" in
 935   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 936   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 937
 938   freebsd) LIBS_SYSTEM="-lutil" ;;
 939
 940   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 941
 942   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 943
 944   ## Motif needs -lgen.
 945   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 946 esac
 947 AC_SUBST(LIBS_SYSTEM)
 948
 949
 950 ### Make sure subsequent tests use flags consistent with the build flags.
 951
 952 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 953   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 954 else
 955   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 956 fi
 957
 958 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 959 AC_DEFUN([AC_TYPE_SIZE_T])
 960 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 961 AC_DEFUN([AC_TYPE_UID_T])
 962
 963
 964 LIB_MATH=-lm
 965 LIB_STANDARD=
 966 START_FILES=
 967 dnl Current possibilities handled by sed (aix4-2 -> aix,
 968 dnl gnu-linux -> gnu/linux, etc.):
 969 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 970 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 971 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 972
 973 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 974 case $opsys in
 975   cygwin )
 976     LIB_MATH=
 977     START_FILES='pre-crt0.o'
 978     ;;
 979   darwin )
 980     ## Adding -lm confuses the dynamic linker, so omit it.
 981     LIB_MATH=
 982     START_FILES='pre-crt0.o'
 983     ;;
 984   freebsd )
 985     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 986     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 987     SYSTEM_TYPE=berkeley-unix
 988     ;;
 989   gnu-linux | gnu-kfreebsd )
 990     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 991     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 992     ;;
 993   hpux10-20 | hpux11 )
 994     LIB_STANDARD=-lc
 995     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 996     ;;
 997   dnl NB this may be adjusted below.
 998   netbsd | openbsd )
 999     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1000     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1001     SYSTEM_TYPE=berkeley-unix
1002     ;;
1003
1004   sol2* | unixware )
1005     SYSTEM_TYPE=usg-unix-v
1006     ;;
1007
1008 esac
1009
1010 AC_SUBST(LIB_MATH)
1011 AC_SUBST(START_FILES)
1012 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1013   [The type of system you are compiling for; sets `system-type'.])
1014
1015 dnl Not all platforms use crtn.o files.  Check if the current one does.
1016 crt_files=
1017
1018 for file in x $LIB_STANDARD $START_FILES; do
1019   case "$file" in
1020     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1021   esac
1022 done
1023
1024 if test "x$crt_files" != x; then
1025
1026   ## If user specified a crt-dir, use that unconditionally.
1027   crt_gcc=no
1028
1029   if test "X$CRT_DIR" = "X"; then
1030
1031     CRT_DIR=/usr/lib            # default
1032
1033     case "$canonical" in
1034       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1035       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1036       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1037       ## For anything else (eg /usr/lib32), it is up the user to specify
1038       ## the location (bug#5655).
1039       ## Test for crtn.o, not just the directory, because sometimes the
1040       ## directory exists but does not have the relevant files (bug#1287).
1041       ## FIXME better to test for binary compatibility somehow.
1042       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1043       ;;
1044
1045       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1046     esac
1047
1048     case "$opsys" in
1049       hpux10-20) CRT_DIR=/lib ;;
1050     esac
1051
1052     test "x${GCC}" = xyes && crt_gcc=yes
1053
1054   fi                            # CRT_DIR = ""
1055
1056   crt_missing=
1057
1058   for file in $crt_files; do
1059
1060     ## If we're using gcc, try to determine it automatically by asking
1061     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1062     ## system-dependent default from above.]
1063     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1064
1065        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1066        case "$crt_file" in
1067          */*)
1068            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1069            ;;
1070        esac
1071     fi
1072
1073     dnl We expect all the files to be in a single directory, so after the
1074     dnl first there is no point asking gcc.
1075     crt_gcc=no
1076
1077     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1078   done                          # $crt_files
1079
1080   test "x$crt_missing" = x || \
1081     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1082 Try using the --with-crt-dir option.])
1083
1084 fi                              # crt_files != ""
1085
1086 AC_SUBST(CRT_DIR)
1087
1088 case $opsys in
1089   netbsd | openbsd )
1090     if test -f $CRT_DIR/crti.o; then
1091
1092         test -f $CRT_DIR/crtn.o || \
1093           AC_MSG_ERROR([Required file not found: crtn.o])
1094
1095         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1096         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1097     fi
1098     ;;
1099 esac
1100
1101
1102 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1103 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1104 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1105 gl_ASSERT_NO_GNULIB_POSIXCHECK
1106 gl_ASSERT_NO_GNULIB_TESTS
1107 gl_INIT
1108
1109 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1110
1111 dnl This function definition taken from Gnome 2.0
1112 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1113 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1114 dnl also defines GSTUFF_PKG_ERRORS on error
1115 AC_DEFUN([PKG_CHECK_MODULES], [
1116   succeeded=no
1117
1118   if test "$PKG_CONFIG" = "no" ; then
1119      ifelse([$4], , [AC_MSG_ERROR([
1120       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1121   else
1122      PKG_CONFIG_MIN_VERSION=0.9.0
1123      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1124         AC_MSG_CHECKING(for $2)
1125
1126         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1127            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1128            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1129             edit_cflags="
1130               s,///*,/,g
1131               s/^/ /
1132               s/ -I/ $isystem/g
1133               s/^ //
1134             "
1135             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1136             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1137             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1138             succeeded=yes
1139         else
1140             AC_MSG_RESULT(no)
1141             $1_CFLAGS=""
1142             $1_LIBS=""
1143             ## If we have a custom action on failure, don't print errors, but
1144             ## do set a variable so people can do so.
1145             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1146             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1147         fi
1148
1149         AC_SUBST($1_CFLAGS)
1150         AC_SUBST($1_LIBS)
1151      else
1152         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1153         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1154      fi
1155   fi
1156
1157   if test $succeeded = yes; then
1158      ifelse([$3], , :, [$3])
1159   else
1160      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1161   fi
1162 ])
1163
1164
1165 if test "${with_sound}" != "no"; then
1166   # Sound support for GNU/Linux and the free BSDs.
1167   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1168     have_sound_header=yes)
1169   # Emulation library used on NetBSD.
1170   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1171   AC_SUBST(LIBSOUND)
1172
1173   ALSA_REQUIRED=1.0.0
1174   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1175   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1176   if test $HAVE_ALSA = yes; then
1177     SAVE_CFLAGS="$CFLAGS"
1178     SAVE_LIBS="$LIBS"
1179     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1180     LIBS="$ALSA_LIBS $LIBS"
1181     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1182                     emacs_alsa_normal=yes,
1183                     emacs_alsa_normal=no)
1184     if test "$emacs_alsa_normal" != yes; then
1185       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1186                      [[snd_lib_error_set_handler (0);]])],
1187                      emacs_alsa_subdir=yes,
1188                      emacs_alsa_subdir=no)
1189       if test "$emacs_alsa_subdir" != yes; then
1190         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1191       fi
1192       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1193     fi
1194
1195     CFLAGS="$SAVE_CFLAGS"
1196     LIBS="$SAVE_LIBS"
1197     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1198     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1199     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1200   fi
1201
1202   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1203   dnl compiles only on the specified platforms.  For others, it
1204   dnl probably doesn't make sense to try.
1205   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1206      case "$opsys" in
1207        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1208        gnu-linux|freebsd|netbsd)
1209          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1210          ;;
1211      esac
1212   fi
1213
1214   AC_SUBST(CFLAGS_SOUND)
1215 fi
1216
1217 dnl checks for header files
1218 AC_CHECK_HEADERS_ONCE(
1219   linux/version.h sys/systeminfo.h
1220   stdio_ext.h fcntl.h coff.h pty.h
1221   sys/vlimit.h sys/resource.h
1222   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1223
1224 AC_MSG_CHECKING(if personality LINUX32 can be set)
1225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1226                emacs_cv_personality_linux32=yes,
1227                emacs_cv_personality_linux32=no)
1228 AC_MSG_RESULT($emacs_cv_personality_linux32)
1229
1230 if test $emacs_cv_personality_linux32 = yes; then
1231   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1232             [Define to 1 if personality LINUX32 can be set.])
1233 fi
1234
1235 dnl On Solaris 8 there's a compilation warning for term.h because
1236 dnl it doesn't define `bool'.
1237 AC_CHECK_HEADERS(term.h, , , -)
1238 AC_HEADER_TIME
1239 AC_CHECK_DECLS([sys_siglist])
1240 if test $ac_cv_have_decl_sys_siglist != yes; then
1241   # For Tru64, at least:
1242   AC_CHECK_DECLS([__sys_siglist])
1243   if test $ac_cv_have_decl___sys_siglist = yes; then
1244     AC_DEFINE(sys_siglist, __sys_siglist,
1245               [Define to any substitute for sys_siglist.])
1246   fi
1247 fi
1248 AC_HEADER_SYS_WAIT
1249
1250 dnl Check for speed_t typedef.
1251 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1252   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1253     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1254 if test $emacs_cv_speed_t = yes; then
1255   AC_DEFINE(HAVE_SPEED_T, 1,
1256            [Define to 1 if `speed_t' is declared by <termios.h>.])
1257 fi
1258
1259 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1260 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1261 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1262   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1263 HAVE_EXCEPTION=$emacs_cv_struct_exception
1264 if test $emacs_cv_struct_exception != yes; then
1265   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1266 fi
1267
1268 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1269 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1270 #if HAVE_SYS_SOCKET_H
1271 #include <sys/socket.h>
1272 #endif])
1273 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1274 #if HAVE_SYS_SOCKET_H
1275 #include <sys/socket.h>
1276 #endif])
1277 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1278 #if HAVE_SYS_SOCKET_H
1279 #include <sys/socket.h>
1280 #endif])
1281
1282 dnl checks for structure members
1283 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1284                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1285                   struct ifreq.ifr_addr,
1286                   struct ifreq.ifr_addr.sa_len], , ,
1287                  [AC_INCLUDES_DEFAULT
1288 #if HAVE_SYS_SOCKET_H
1289 #include <sys/socket.h>
1290 #endif
1291 #if HAVE_NET_IF_H
1292 #include <net/if.h>
1293 #endif])
1294
1295 dnl Check for endianness.
1296 dnl AC_C_BIGENDIAN is done by gnulib.
1297
1298 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1299   [emacs_cv_attribute_aligned],
1300   [AC_COMPILE_IFELSE(
1301      [AC_LANG_PROGRAM(
1302         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1303         [[]])],
1304      [emacs_cv_attribute_aligned=yes],
1305      [emacs_cv_attribute_aligned=no])])
1306 if test $emacs_cv_attribute_aligned = yes; then
1307   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1308     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1309 fi
1310
1311 dnl check for Make feature
1312 dnl AC_PROG_MAKE_SET is done by Automake.
1313
1314 DEPFLAGS=
1315 MKDEPDIR=":"
1316 deps_frag=deps.mk
1317 dnl check for GNU Make if we have GCC and autodepend is on.
1318 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1319    AC_MSG_CHECKING([whether we are using GNU Make])
1320    HAVE_GNU_MAKE=no
1321    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1322    if test "x$testval" != x; then
1323       HAVE_GNU_MAKE=yes
1324    else
1325       ac_enable_autodepend=no
1326    fi
1327    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1328    if test $HAVE_GNU_MAKE = yes; then
1329       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1330       SAVE_CFLAGS="$CFLAGS"
1331       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1332       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1333       CFLAGS="$SAVE_CFLAGS"
1334       test -f deps.d || ac_enable_autodepend=no
1335       rm -rf deps.d
1336       AC_MSG_RESULT([$ac_enable_autodepend])
1337    fi
1338    if test $ac_enable_autodepend = yes; then
1339       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1340       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1341       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1342       deps_frag=autodeps.mk
1343    fi
1344 fi
1345 deps_frag=$srcdir/src/$deps_frag
1346 AC_SUBST(MKDEPDIR)
1347 AC_SUBST(DEPFLAGS)
1348 AC_SUBST_FILE(deps_frag)
1349
1350
1351 lisp_frag=$srcdir/src/lisp.mk
1352 AC_SUBST_FILE(lisp_frag)
1353
1354
1355 dnl checks for operating system services
1356 AC_SYS_LONG_FILE_NAMES
1357
1358 #### Choose a window system.
1359
1360 AC_PATH_X
1361 if test "$no_x" = yes; then
1362   window_system=none
1363 else
1364   window_system=x11
1365 fi
1366
1367 LD_SWITCH_X_SITE_RPATH=
1368 if test "${x_libraries}" != NONE; then
1369   if test -n "${x_libraries}"; then
1370     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1371     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1372   fi
1373   x_default_search_path=""
1374   x_search_path=${x_libraries}
1375   if test -z "${x_search_path}"; then
1376     x_search_path=/usr/lib
1377   fi
1378   for x_library in `echo ${x_search_path}: | \
1379                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1380     x_search_path="\
1381 ${x_library}/X11/%L/%T/%N%C%S:\
1382 ${x_library}/X11/%l/%T/%N%C%S:\
1383 ${x_library}/X11/%T/%N%C%S:\
1384 ${x_library}/X11/%L/%T/%N%S:\
1385 ${x_library}/X11/%l/%T/%N%S:\
1386 ${x_library}/X11/%T/%N%S"
1387     if test x"${x_default_search_path}" = x; then
1388       x_default_search_path=${x_search_path}
1389     else
1390       x_default_search_path="${x_search_path}:${x_default_search_path}"
1391     fi
1392   done
1393 fi
1394 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1395
1396 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1397   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1398 fi
1399
1400 if test x"${x_includes}" = x; then
1401   bitmapdir=/usr/include/X11/bitmaps
1402 else
1403   # accumulate include directories that have X11 bitmap subdirectories
1404   bmd_acc="dummyval"
1405   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1406     if test -d "${bmd}/X11/bitmaps"; then
1407       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1408     fi
1409     if test -d "${bmd}/bitmaps"; then
1410       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1411     fi
1412   done
1413   if test ${bmd_acc} != "dummyval"; then
1414     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1415   fi
1416 fi
1417
1418 HAVE_NS=no
1419 NS_IMPL_COCOA=no
1420 NS_IMPL_GNUSTEP=no
1421 tmp_CPPFLAGS="$CPPFLAGS"
1422 tmp_CFLAGS="$CFLAGS"
1423 CPPFLAGS="$CPPFLAGS -x objective-c"
1424 CFLAGS="$CFLAGS -x objective-c"
1425 TEMACS_LDFLAGS2="\${LDFLAGS}"
1426 GNU_OBJC_CFLAGS=
1427 if test "${with_ns}" != no; then
1428   if test "${opsys}" = darwin; then
1429      NS_IMPL_COCOA=yes
1430      ns_appdir=`pwd`/nextstep/Emacs.app
1431      ns_appbindir=${ns_appdir}/Contents/MacOS
1432      ns_appresdir=${ns_appdir}/Contents/Resources
1433      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1434   elif test -f $GNUSTEP_CONFIG_FILE; then
1435      NS_IMPL_GNUSTEP=yes
1436      ns_appdir=`pwd`/nextstep/Emacs.app
1437      ns_appbindir=${ns_appdir}
1438      ns_appresdir=${ns_appdir}/Resources
1439      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1440      dnl FIXME sourcing this several times in subshells seems inefficient.
1441      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1442      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1443      dnl I seemed to need these as well with GNUstep-startup 0.25.
1444      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1445      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1446      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1447        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1448      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1449        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1450      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1451      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1452      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1453      LIB_STANDARD=
1454      START_FILES=
1455      TEMACS_LDFLAGS2=
1456      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1457      dnl If they had chosen to either define it or not, we could have
1458      dnl just used AC_CHECK_DECL here.
1459      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1460        emacs_cv_objc_exceptions,
1461 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1462 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1463 1;
1464 #else
1465 fail;
1466 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1467      if test $emacs_cv_objc_exceptions = yes; then
1468        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1469        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1470          [Define if GNUstep uses ObjC exceptions.])
1471        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1472      fi
1473   fi
1474
1475   dnl This is only used while we test the NS headers, it gets reset below.
1476   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1477
1478   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1479                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1480   files are missing or cannot be compiled.])])
1481   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1482                                      [NSInteger i;])],
1483                     ns_have_nsinteger=yes,
1484                     ns_have_nsinteger=no)
1485   if test $ns_have_nsinteger = yes; then
1486     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1487   fi
1488 fi
1489 AC_SUBST(TEMACS_LDFLAGS2)
1490
1491 INSTALL_ARCH_INDEP_EXTRA=install-etc
1492 ns_self_contained=no
1493 ns_frag=/dev/null
1494 NS_OBJ=
1495 NS_OBJC_OBJ=
1496 if test "${HAVE_NS}" = yes; then
1497   if test "$with_toolkit_scroll_bars" = "no"; then
1498     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1499   fi
1500
1501   window_system=nextstep
1502   with_xft=no
1503   # set up packaging dirs
1504   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1505      ns_self_contained=yes
1506      prefix=${ns_appresdir}
1507      exec_prefix=${ns_appbindir}
1508      dnl This one isn't really used, only archlibdir is.
1509      libexecdir="\${ns_appbindir}/libexec"
1510      archlibdir="\${ns_appbindir}/libexec"
1511      docdir="\${ns_appresdir}/etc"
1512      etcdir="\${ns_appresdir}/etc"
1513      dnl FIXME maybe set datarootdir instead.
1514      dnl That would also get applications, icons, man.
1515      infodir="\${ns_appresdir}/info"
1516      mandir="\${ns_appresdir}/man"
1517      lispdir="\${ns_appresdir}/lisp"
1518      leimdir="\${ns_appresdir}/leim"
1519      INSTALL_ARCH_INDEP_EXTRA=
1520   fi
1521   ns_frag=$srcdir/src/ns.mk
1522   NS_OBJ="fontset.o fringe.o image.o"
1523   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1524 fi
1525 CFLAGS="$tmp_CFLAGS"
1526 CPPFLAGS="$tmp_CPPFLAGS"
1527 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1528 AC_SUBST(ns_self_contained)
1529 AC_SUBST(NS_OBJ)
1530 AC_SUBST(NS_OBJC_OBJ)
1531 AC_SUBST(LIB_STANDARD)
1532 AC_SUBST_FILE(ns_frag)
1533
1534 case "${window_system}" in
1535   x11 )
1536     HAVE_X_WINDOWS=yes
1537     HAVE_X11=yes
1538     case "${with_x_toolkit}" in
1539       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1540       motif ) USE_X_TOOLKIT=MOTIF ;;
1541       gtk ) with_gtk=yes
1542 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1543 dnl USE_X_TOOLKIT is set.
1544             USE_X_TOOLKIT=none ;;
1545       gtk3 ) with_gtk3=yes
1546              USE_X_TOOLKIT=none ;;
1547       no ) USE_X_TOOLKIT=none ;;
1548 dnl If user did not say whether to use a toolkit, make this decision later:
1549 dnl use the toolkit if we have gtk, or X11R5 or newer.
1550       * ) USE_X_TOOLKIT=maybe ;;
1551     esac
1552   ;;
1553   nextstep | none )
1554     HAVE_X_WINDOWS=no
1555     HAVE_X11=no
1556     USE_X_TOOLKIT=none
1557   ;;
1558 esac
1559
1560 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1561    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1562    if test "$HAVE_XSERVER" = true ||
1563       test -n "$DISPLAY" ||
1564       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1565         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1566 were found.  You should install the relevant development files for X
1567 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1568 sure you have development files for image handling, i.e.
1569 tiff, gif, jpeg, png and xpm.
1570 If you are sure you want Emacs compiled without X window support, pass
1571   --without-x
1572 to configure.])
1573    fi
1574 fi
1575
1576 ### If we're using X11, we should use the X menu package.
1577 HAVE_MENUS=no
1578 case ${HAVE_X11} in
1579   yes ) HAVE_MENUS=yes ;;
1580 esac
1581
1582 # Does the opsystem file prohibit the use of the GNU malloc?
1583 # Assume not, until told otherwise.
1584 GNU_MALLOC=yes
1585
1586 AC_CACHE_CHECK(
1587   [whether malloc is Doug Lea style],
1588   [emacs_cv_var_doug_lea_malloc],
1589   [AC_LINK_IFELSE(
1590      [AC_LANG_PROGRAM(
1591         [[#include <malloc.h>
1592           static void hook (void) {}]],
1593         [[malloc_set_state (malloc_get_state ());
1594           __after_morecore_hook = hook;
1595           __malloc_initialize_hook = hook;]])],
1596      [emacs_cv_var_doug_lea_malloc=yes],
1597      [emacs_cv_var_doug_lea_malloc=no])])
1598 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1599
1600
1601 dnl See comments in aix4-2.h about maybe using system malloc there.
1602 system_malloc=no
1603 case "$opsys" in
1604   ## darwin ld insists on the use of malloc routines in the System framework.
1605   darwin|sol2-10) system_malloc=yes ;;
1606 esac
1607
1608 if test "${system_malloc}" = "yes"; then
1609   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1610   GNU_MALLOC=no
1611   GNU_MALLOC_reason="
1612     (The GNU allocators don't work with this system configuration.)"
1613   GMALLOC_OBJ=
1614   VMLIMIT_OBJ=
1615 else
1616   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1617   VMLIMIT_OBJ=vm-limit.o
1618 fi
1619 AC_SUBST(GMALLOC_OBJ)
1620 AC_SUBST(VMLIMIT_OBJ)
1621
1622 if test "$doug_lea_malloc" = "yes" ; then
1623   if test "$GNU_MALLOC" = yes ; then
1624     GNU_MALLOC_reason="
1625       (Using Doug Lea's new malloc from the GNU C Library.)"
1626   fi
1627   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1628             [Define to 1 if you are using the GNU C Library.])
1629
1630   ## Use mmap directly for allocating larger buffers.
1631   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1632   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1633   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1634   case "$opsys" in
1635     gnu*) REL_ALLOC=no ;;
1636   esac
1637 fi
1638
1639 if test x"${REL_ALLOC}" = x; then
1640   REL_ALLOC=${GNU_MALLOC}
1641 fi
1642
1643 use_mmap_for_buffers=no
1644 case "$opsys" in
1645   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1646 esac
1647
1648 AC_FUNC_MMAP
1649 if test $use_mmap_for_buffers = yes; then
1650   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1651   REL_ALLOC=no
1652 fi
1653
1654 LIBS="$LIBS_SYSTEM $LIBS"
1655
1656 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1657 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1658 AC_CHECK_LIB(dnet, dnet_ntoa)
1659 dnl This causes -lresolv to get used in subsequent tests,
1660 dnl which causes failures on some systems such as HPUX 9.
1661 dnl AC_CHECK_LIB(resolv, gethostbyname)
1662
1663 dnl FIXME replace main with a function we actually want from this library.
1664 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1665
1666 dnl Check if pthreads is available.
1667 LIB_PTHREAD=
1668 AC_CHECK_HEADERS_ONCE(pthread.h)
1669 if test "$ac_cv_header_pthread_h"; then
1670   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1671   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1672   dnl testing for pthread_self if Emacs uses gmalloc.c.
1673   if test "$GMALLOC_OBJ" = gmalloc.o; then
1674     emacs_pthread_function=pthread_atfork
1675   else
1676     emacs_pthread_function=pthread_self
1677   fi
1678   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1679 fi
1680 if test "$HAVE_PTHREAD" = yes; then
1681   case "${canonical}" in
1682     *-hpux*) ;;
1683     *) LIB_PTHREAD="-lpthread"
1684        LIBS="$LIB_PTHREAD $LIBS" ;;
1685   esac
1686   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1687 fi
1688 AC_SUBST([LIB_PTHREAD])
1689
1690 AC_CHECK_LIB(pthreads, cma_open)
1691
1692 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1693 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1694 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1695 ## added to LIBS in configure would never contain the pthreads part,
1696 ## but the value used in Makefiles might.  FIXME?
1697 ##
1698 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1699 ## be harmless on older versions of X where it happens to exist.
1700 test "$opsys" = "aix4-2" && \
1701   test $ac_cv_lib_pthreads_cma_open = yes && \
1702   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1703
1704 dnl Check for need for bigtoc support on IBM AIX
1705
1706 case ${host_os} in
1707 aix*)
1708   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1709     case $GCC in
1710     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1711     *) gdb_cv_bigtoc=-bbigtoc ;;
1712     esac
1713
1714     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1715     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1716   ])
1717   ;;
1718 esac
1719
1720 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1721 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1722 # REAL_CPPFLAGS later on.
1723
1724 REAL_CFLAGS="$CFLAGS"
1725 REAL_CPPFLAGS="$CPPFLAGS"
1726
1727 if test "${HAVE_X11}" = "yes"; then
1728   DEFS="$C_SWITCH_X_SITE $DEFS"
1729   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1730   LIBS="-lX11 $LIBS"
1731   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1732   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1733
1734   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1735   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1736   # but it's more convenient here to set LD_RUN_PATH since this
1737   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1738   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1739     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1740     export LD_RUN_PATH
1741   fi
1742
1743   if test "${opsys}" = "gnu-linux"; then
1744     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1745     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1746      [[XOpenDisplay ("foo");]])],
1747      [xgnu_linux_first_failure=no],
1748      [xgnu_linux_first_failure=yes])
1749     if test "${xgnu_linux_first_failure}" = "yes"; then
1750       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1751       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1752       OLD_CPPFLAGS="$CPPFLAGS"
1753       OLD_LIBS="$LIBS"
1754       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1755       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1756       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1757       LIBS="$LIBS -b i486-linuxaout"
1758       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1759        [[XOpenDisplay ("foo");]])],
1760        [xgnu_linux_second_failure=no],
1761        [xgnu_linux_second_failure=yes])
1762       if test "${xgnu_linux_second_failure}" = "yes"; then
1763         # If we get the same failure with -b, there is no use adding -b.
1764         # So take it out.  This plays safe.
1765         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1766         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1767         CPPFLAGS="$OLD_CPPFLAGS"
1768         LIBS="$OLD_LIBS"
1769         AC_MSG_RESULT(no)
1770       else
1771         AC_MSG_RESULT(yes)
1772       fi
1773     else
1774       AC_MSG_RESULT(no)
1775     fi
1776   fi
1777
1778   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1779   # header files included from there.
1780   AC_MSG_CHECKING(for Xkb)
1781   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1782 #include <X11/XKBlib.h>]],
1783         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1784         emacs_xkb=yes, emacs_xkb=no)
1785   AC_MSG_RESULT($emacs_xkb)
1786   if test $emacs_xkb = yes; then
1787     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1788   fi
1789
1790   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1791 XScreenNumberOfScreen)
1792 fi
1793
1794 if test "${window_system}" = "x11"; then
1795   AC_MSG_CHECKING(X11 version 6)
1796   AC_CACHE_VAL(emacs_cv_x11_version_6,
1797   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1798 [[#if XlibSpecificationRelease < 6
1799 fail;
1800 #endif
1801 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1802   if test $emacs_cv_x11_version_6 = yes; then
1803     AC_MSG_RESULT(6 or newer)
1804     AC_DEFINE(HAVE_X11R6, 1,
1805               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1806     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1807     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1808     ## XIM support.
1809     case "$opsys" in
1810       sol2-*) : ;;
1811       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1812            [Define if you have usable X11R6-style XIM support.])
1813          ;;
1814     esac
1815   else
1816     AC_MSG_RESULT(before 6)
1817   fi
1818 fi
1819
1820
1821 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1822 HAVE_RSVG=no
1823 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1824   if test "${with_rsvg}" != "no"; then
1825     RSVG_REQUIRED=2.11.0
1826     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1827
1828     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1829     AC_SUBST(RSVG_CFLAGS)
1830     AC_SUBST(RSVG_LIBS)
1831
1832     if test $HAVE_RSVG = yes; then
1833       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1834       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1835       LIBS="$RSVG_LIBS $LIBS"
1836     fi
1837   fi
1838 fi
1839
1840 HAVE_IMAGEMAGICK=no
1841 if test "${HAVE_X11}" = "yes"; then
1842   if test "${with_imagemagick}" != "no"; then
1843     ## 6.2.8 is the earliest version known to work, but earlier versions
1844     ## might work - let us know if you find one.
1845     ## 6.0.7 does not work.  See bug#7955.
1846     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1847     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1848     AC_SUBST(IMAGEMAGICK_CFLAGS)
1849     AC_SUBST(IMAGEMAGICK_LIBS)
1850
1851     if test $HAVE_IMAGEMAGICK = yes; then
1852       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1853       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1854       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1855       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1856     fi
1857   fi
1858 fi
1859
1860
1861 HAVE_GTK=no
1862 GTK_OBJ=
1863 if test "${with_gtk3}" = "yes"; then
1864   GLIB_REQUIRED=2.28
1865   GTK_REQUIRED=3.0
1866   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1867
1868   dnl Checks for libraries.
1869   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1870   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1871      AC_MSG_ERROR($GTK_PKG_ERRORS)
1872   fi
1873   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1874   GTK_OBJ=emacsgtkfixed.o
1875 fi
1876
1877 if test "$pkg_check_gtk" != "yes"; then
1878   HAVE_GTK=no
1879 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1880   GLIB_REQUIRED=2.10
1881   GTK_REQUIRED=2.10
1882   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1883
1884   dnl Checks for libraries.
1885   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1886   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1887      AC_MSG_ERROR($GTK_PKG_ERRORS)
1888   fi
1889 fi
1890 fi
1891
1892 if test x"$pkg_check_gtk" = xyes; then
1893
1894   AC_SUBST(GTK_CFLAGS)
1895   AC_SUBST(GTK_LIBS)
1896   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1897   CFLAGS="$CFLAGS $GTK_CFLAGS"
1898   LIBS="$GTK_LIBS $LIBS"
1899   dnl Try to compile a simple GTK program.
1900   GTK_COMPILES=no
1901   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1902   if test "${GTK_COMPILES}" != "yes"; then
1903     if test "$USE_X_TOOLKIT" != "maybe"; then
1904       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1905     fi
1906   else
1907     HAVE_GTK=yes
1908     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1909     GTK_OBJ="gtkutil.o $GTK_OBJ"
1910     USE_X_TOOLKIT=none
1911     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1912       :
1913     else
1914       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1915        closing open displays.  This is no problem if you just use
1916        one display, but if you use more than one and close one of them
1917        Emacs may crash.]])
1918       sleep 3
1919     fi
1920   fi
1921
1922 fi
1923 AC_SUBST(GTK_OBJ)
1924
1925
1926 if test "${HAVE_GTK}" = "yes"; then
1927
1928   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1929   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1930   if test "$with_toolkit_scroll_bars" != no; then
1931     with_toolkit_scroll_bars=yes
1932   fi
1933
1934   dnl  Check if we have the old file selection dialog declared and
1935   dnl  in the link library.  In 2.x it may be in the library,
1936   dnl  but not declared if deprecated featured has been selected out.
1937   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1938   HAVE_GTK_FILE_SELECTION=no
1939   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1940                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1941 #include <gtk/gtk.h>])
1942   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1943     AC_CHECK_FUNCS(gtk_file_selection_new)
1944   fi
1945
1946
1947   dnl Check for functions introduced in 2.14 and later.
1948   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1949                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1950                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1951                  gtk_orientable_set_orientation \
1952                  gtk_window_set_has_resize_grip)
1953 fi
1954
1955 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1956 dnl other platforms.
1957 HAVE_DBUS=no
1958 DBUS_OBJ=
1959 if test "${with_dbus}" = "yes"; then
1960    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1961    if test "$HAVE_DBUS" = yes; then
1962      LIBS="$LIBS $DBUS_LIBS"
1963      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1964      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1965      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1966      dnl D-Bus 1.5.12.
1967      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1968                     dbus_type_is_valid \
1969                     dbus_validate_bus_name \
1970                     dbus_validate_path \
1971                     dbus_validate_interface \
1972                     dbus_validate_member)
1973      DBUS_OBJ=dbusbind.o
1974    fi
1975 fi
1976 AC_SUBST(DBUS_OBJ)
1977
1978 dnl GSettings has been tested under GNU/Linux only.
1979 HAVE_GSETTINGS=no
1980 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1981    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1982    if test "$HAVE_GSETTINGS" = "yes"; then
1983       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1984       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1985       SETTINGS_LIBS="$GSETTINGS_LIBS"
1986    fi
1987 fi
1988
1989 dnl GConf has been tested under GNU/Linux only.
1990 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1991 HAVE_GCONF=no
1992 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1993    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1994    if test "$HAVE_GCONF" = yes; then
1995       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1996       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1997       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1998       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1999    fi
2000 fi
2001
2002 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2003     SAVE_CFLAGS="$CFLAGS"
2004     SAVE_LIBS="$LIBS"
2005     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2006     LIBS="$SETTINGS_LIBS $LIBS"
2007     AC_CHECK_FUNCS([g_type_init])
2008     CFLAGS="$SAVE_CFLAGS"
2009     LIBS="$SAVE_LIBS"
2010 fi
2011 AC_SUBST(SETTINGS_CFLAGS)
2012 AC_SUBST(SETTINGS_LIBS)
2013
2014
2015 dnl SELinux is available for GNU/Linux only.
2016 HAVE_LIBSELINUX=no
2017 LIBSELINUX_LIBS=
2018 if test "${with_selinux}" = "yes"; then
2019    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2020    if test "$HAVE_LIBSELINUX" = yes; then
2021       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2022       LIBSELINUX_LIBS=-lselinux
2023    fi
2024 fi
2025 AC_SUBST(LIBSELINUX_LIBS)
2026
2027 HAVE_GNUTLS=no
2028 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2029 if test "${with_gnutls}" = "yes" ; then
2030   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2031   if test "${HAVE_GNUTLS}" = "yes"; then
2032     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2033   fi
2034
2035   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2036   LIBS="$LIBGNUTLS_LIBS $LIBS"
2037   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2038
2039   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2040     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2041   fi
2042 fi
2043
2044 AC_SUBST(LIBGNUTLS_LIBS)
2045 AC_SUBST(LIBGNUTLS_CFLAGS)
2046
2047 dnl Do not put whitespace before the #include statements below.
2048 dnl Older compilers (eg sunos4 cc) choke on it.
2049 HAVE_XAW3D=no
2050 LUCID_LIBW=
2051 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2052   if test "$with_xaw3d" != no; then
2053     AC_MSG_CHECKING(for xaw3d)
2054     AC_CACHE_VAL(emacs_cv_xaw3d,
2055     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2056 #include <X11/Intrinsic.h>
2057 #include <X11/Xaw3d/Simple.h>]],
2058       [[]])],
2059       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2060                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2061       emacs_cv_xaw3d=no)])
2062   else
2063     emacs_cv_xaw3d=no
2064   fi
2065   if test $emacs_cv_xaw3d = yes; then
2066     AC_MSG_RESULT([yes; using Lucid toolkit])
2067     USE_X_TOOLKIT=LUCID
2068     HAVE_XAW3D=yes
2069     LUCID_LIBW=-lXaw3d
2070     AC_DEFINE(HAVE_XAW3D, 1,
2071               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2072   else
2073     AC_MSG_RESULT(no)
2074     AC_MSG_CHECKING(for libXaw)
2075     AC_CACHE_VAL(emacs_cv_xaw,
2076     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2077 #include <X11/Intrinsic.h>
2078 #include <X11/Xaw/Simple.h>]],
2079       [[]])],
2080       emacs_cv_xaw=yes,
2081       emacs_cv_xaw=no)])
2082     if test $emacs_cv_xaw = yes; then
2083       AC_MSG_RESULT([yes; using Lucid toolkit])
2084       USE_X_TOOLKIT=LUCID
2085       LUCID_LIBW=-lXaw
2086     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2087       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2088     else
2089       AC_MSG_ERROR([No X toolkit could be found.
2090 If you are sure you want Emacs compiled without an X toolkit, pass
2091   --with-x-toolkit=no
2092 to configure.  Otherwise, install the development libraries for the toolkit
2093 that you want to use (e.g. Gtk+) and re-run configure.])
2094     fi
2095   fi
2096 fi
2097
2098 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2099
2100 LIBXTR6=
2101 if test "${USE_X_TOOLKIT}" != "none"; then
2102   AC_MSG_CHECKING(X11 toolkit version)
2103   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2104   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2105 [[#if XtSpecificationRelease < 6
2106 fail;
2107 #endif
2108 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2109   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2110   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2111     AC_MSG_RESULT(6 or newer)
2112     AC_DEFINE(HAVE_X11XTR6, 1,
2113               [Define to 1 if you have the X11R6 or newer version of Xt.])
2114     LIBXTR6="-lSM -lICE"
2115     case "$opsys" in
2116       ## Use libw.a along with X11R6 Xt.
2117       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2118     esac
2119   else
2120     AC_MSG_RESULT(before 6)
2121   fi
2122
2123 dnl If using toolkit, check whether libXmu.a exists.
2124 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2125   OLDLIBS="$LIBS"
2126   if test x$HAVE_X11XTR6 = xyes; then
2127     LIBS="-lXt -lSM -lICE $LIBS"
2128   else
2129     LIBS="-lXt $LIBS"
2130   fi
2131   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2132   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2133 fi
2134 AC_SUBST(LIBXTR6)
2135
2136 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2137 dnl Why not just test for libxmu in the normal way?
2138 LIBXMU=-lXmu
2139 case $opsys in
2140   ## These systems don't supply Xmu.
2141   hpux* | aix4-2 )
2142     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2143     ;;
2144 esac
2145 AC_SUBST(LIBXMU)
2146
2147 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2148 if test "${HAVE_X11}" = "yes"; then
2149   if test "${USE_X_TOOLKIT}" != "none"; then
2150     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2151   fi
2152 fi
2153
2154 LIBXP=
2155 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2156   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2157   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2158     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2159 int x = 5;
2160 #else
2161 Motif version prior to 2.1.
2162 #endif]])],
2163     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2164   if test $emacs_cv_motif_version_2_1 = yes; then
2165     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2166   else
2167     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2168     # We put this in CFLAGS temporarily to precede other -I options
2169     # that might be in CFLAGS temporarily.
2170     # We put this in CPPFLAGS where it precedes the other -I options.
2171     OLD_CPPFLAGS=$CPPFLAGS
2172     OLD_CFLAGS=$CFLAGS
2173     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2174     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2175     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2176       [[int x = 5;]])],
2177       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2178     if test $emacs_cv_lesstif = yes; then
2179       # Make sure this -I option remains in CPPFLAGS after it is set
2180       # back to REAL_CPPFLAGS.
2181       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2182       # have those other -I options anyway.  Ultimately, having this
2183       # directory ultimately in CPPFLAGS will be enough.
2184       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2185       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2186     else
2187       CFLAGS=$OLD_CFLAGS
2188       CPPFLAGS=$OLD_CPPFLAGS
2189     fi
2190   fi
2191   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2192     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2193 fi
2194
2195 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2196 dnl using Motif or Xaw3d is available, and unless
2197 dnl --with-toolkit-scroll-bars=no was specified.
2198
2199 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2200             [Define to 1 if we should use toolkit scroll bars.])dnl
2201 USE_TOOLKIT_SCROLL_BARS=no
2202 if test "${with_toolkit_scroll_bars}" != "no"; then
2203   if test "${USE_X_TOOLKIT}" != "none"; then
2204     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2205       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2206       HAVE_XAW3D=no
2207       USE_TOOLKIT_SCROLL_BARS=yes
2208     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2209       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2210       USE_TOOLKIT_SCROLL_BARS=yes
2211     fi
2212   elif test "${HAVE_GTK}" = "yes"; then
2213     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2214     USE_TOOLKIT_SCROLL_BARS=yes
2215   elif test "${HAVE_NS}" = "yes"; then
2216     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2217     USE_TOOLKIT_SCROLL_BARS=yes
2218   fi
2219 fi
2220
2221 dnl See if XIM is available.
2222 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2223           #include <X11/Xlib.h>
2224           #include <X11/Xresource.h>]],
2225          [[XIMProc  callback;]])],
2226          [HAVE_XIM=yes
2227          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2228          HAVE_XIM=no)
2229
2230 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2231
2232 if test "${with_xim}" != "no"; then
2233   AC_DEFINE(USE_XIM, 1,
2234             [Define to 1 if we should use XIM, if it is available.])
2235 fi
2236
2237
2238 if test "${HAVE_XIM}" != "no"; then
2239   late_CFLAGS=$CFLAGS
2240   if test "$GCC" = yes; then
2241     CFLAGS="$CFLAGS --pedantic-errors"
2242   fi
2243   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2244 #include <X11/Xlib.h>
2245 #include <X11/Xresource.h>]],
2246 [[Display *display;
2247 XrmDatabase db;
2248 char *res_name;
2249 char *res_class;
2250 XIMProc  callback;
2251 XPointer *client_data;
2252 #ifndef __GNUC__
2253 /* If we're not using GCC, it's probably not XFree86, and this is
2254    probably right, but we can't use something like --pedantic-errors.  */
2255 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2256                                            char*, XIMProc, XPointer*);
2257 #endif
2258 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2259    client_data);]])],
2260     [emacs_cv_arg6_star=yes])
2261   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2262          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2263 either XPointer or XPointer*.])dnl
2264   if test "$emacs_cv_arg6_star" = yes; then
2265     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2266   else
2267     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2268   fi
2269   CFLAGS=$late_CFLAGS
2270 fi
2271
2272 ### Start of font-backend (under any platform) section.
2273 # (nothing here yet -- this is a placeholder)
2274 ### End of font-backend (under any platform) section.
2275
2276 ### Start of font-backend (under X11) section.
2277 if test "${HAVE_X11}" = "yes"; then
2278    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2279
2280    ## Use -lXft if available, unless `--with-xft=no'.
2281    HAVE_XFT=maybe
2282     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2283       with_xft="no";
2284     fi
2285     if test "x${with_xft}" != "xno"; then
2286
2287       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2288       ## Because xftfont.c uses XRenderQueryExtension, we also
2289       ## need to link to -lXrender.
2290       HAVE_XRENDER=no
2291       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2292       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2293         OLD_CPPFLAGS="$CPPFLAGS"
2294         OLD_CFLAGS="$CFLAGS"
2295         OLD_LIBS="$LIBS"
2296         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2297         CFLAGS="$CFLAGS $XFT_CFLAGS"
2298         XFT_LIBS="-lXrender $XFT_LIBS"
2299         LIBS="$XFT_LIBS $LIBS"
2300         AC_CHECK_HEADER(X11/Xft/Xft.h,
2301           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2302
2303         if test "${HAVE_XFT}" = "yes"; then
2304           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2305             AC_SUBST(XFT_LIBS)
2306           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2307         else
2308           CPPFLAGS="$OLD_CPPFLAGS"
2309           CFLAGS="$OLD_CFLAGS"
2310           LIBS="$OLD_LIBS"
2311         fi                        # "${HAVE_XFT}" = "yes"
2312       fi                          # "$HAVE_XFT" != no
2313     fi                            # "x${with_xft}" != "xno"
2314
2315     ## We used to allow building with FreeType and without Xft.
2316     ## However, the ftx font backend driver is not in good shape.
2317     if test "$HAVE_XFT" != "yes"; then
2318        dnl For the "Does Emacs use" message at the end.
2319        HAVE_XFT=no
2320        HAVE_FREETYPE=no
2321     else
2322        dnl Strict linkers fail with
2323        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2324        dnl if -lfreetype is not specified.
2325        dnl The following is needed to set FREETYPE_LIBS.
2326        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2327                          HAVE_FREETYPE=no)
2328
2329        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2330     fi
2331
2332     HAVE_LIBOTF=no
2333     if test "${HAVE_FREETYPE}" = "yes"; then
2334       AC_DEFINE(HAVE_FREETYPE, 1,
2335                 [Define to 1 if using the freetype and fontconfig libraries.])
2336       if test "${with_libotf}" != "no"; then
2337         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2338                           HAVE_LIBOTF=no)
2339         if test "$HAVE_LIBOTF" = "yes"; then
2340           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2341           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2342                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2343                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2344           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2345             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2346                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2347           fi
2348         fi
2349       fi
2350     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2351     dnl Does the new font backend require it, or can it work without it?
2352     fi
2353
2354     HAVE_M17N_FLT=no
2355     if test "${HAVE_LIBOTF}" = yes; then
2356       if test "${with_m17n_flt}" != "no"; then
2357         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2358         if test "$HAVE_M17N_FLT" = "yes"; then
2359           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2360         fi
2361       fi
2362     fi
2363 else
2364     HAVE_XFT=no
2365     HAVE_FREETYPE=no
2366     HAVE_LIBOTF=no
2367     HAVE_M17N_FLT=no
2368 fi
2369
2370 ### End of font-backend (under X11) section.
2371
2372 AC_SUBST(FREETYPE_CFLAGS)
2373 AC_SUBST(FREETYPE_LIBS)
2374 AC_SUBST(FONTCONFIG_CFLAGS)
2375 AC_SUBST(FONTCONFIG_LIBS)
2376 AC_SUBST(LIBOTF_CFLAGS)
2377 AC_SUBST(LIBOTF_LIBS)
2378 AC_SUBST(M17N_FLT_CFLAGS)
2379 AC_SUBST(M17N_FLT_LIBS)
2380
2381 ### Use -lXpm if available, unless `--with-xpm=no'.
2382 HAVE_XPM=no
2383 LIBXPM=
2384 if test "${HAVE_X11}" = "yes"; then
2385   if test "${with_xpm}" != "no"; then
2386     AC_CHECK_HEADER(X11/xpm.h,
2387       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2388     if test "${HAVE_XPM}" = "yes"; then
2389       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2390       AC_EGREP_CPP(no_return_alloc_pixels,
2391       [#include "X11/xpm.h"
2392 #ifndef XpmReturnAllocPixels
2393 no_return_alloc_pixels
2394 #endif
2395       ], HAVE_XPM=no, HAVE_XPM=yes)
2396
2397       if test "${HAVE_XPM}" = "yes"; then
2398         AC_MSG_RESULT(yes)
2399       else
2400         AC_MSG_RESULT(no)
2401       fi
2402     fi
2403   fi
2404
2405   if test "${HAVE_XPM}" = "yes"; then
2406     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2407     LIBXPM=-lXpm
2408   fi
2409 fi
2410 AC_SUBST(LIBXPM)
2411
2412 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2413 HAVE_JPEG=no
2414 LIBJPEG=
2415 if test "${HAVE_X11}" = "yes"; then
2416   if test "${with_jpeg}" != "no"; then
2417     dnl Checking for jpeglib.h can lose because of a redefinition of
2418     dnl  HAVE_STDLIB_H.
2419     AC_CHECK_HEADER(jerror.h,
2420       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2421   fi
2422
2423   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2424   if test "${HAVE_JPEG}" = "yes"; then
2425     AC_DEFINE(HAVE_JPEG)
2426     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2427         [#include <jpeglib.h>
2428          version=JPEG_LIB_VERSION
2429 ],
2430         [AC_DEFINE(HAVE_JPEG)],
2431         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2432         HAVE_JPEG=no])
2433   fi
2434   if test "${HAVE_JPEG}" = "yes"; then
2435     LIBJPEG=-ljpeg
2436   fi
2437 fi
2438 AC_SUBST(LIBJPEG)
2439
2440 ### Use -lpng if available, unless `--with-png=no'.
2441 HAVE_PNG=no
2442 LIBPNG=
2443 if test "${HAVE_X11}" = "yes"; then
2444   if test "${with_png}" != "no"; then
2445     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2446     # in /usr/include/libpng.
2447     AC_CHECK_HEADERS(png.h libpng/png.h)
2448     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2449       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2450     fi
2451   fi
2452
2453   if test "${HAVE_PNG}" = "yes"; then
2454     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2455     LIBPNG="-lpng -lz -lm"
2456   fi
2457 fi
2458 AC_SUBST(LIBPNG)
2459
2460 ### Use -ltiff if available, unless `--with-tiff=no'.
2461 HAVE_TIFF=no
2462 LIBTIFF=
2463 if test "${HAVE_X11}" = "yes"; then
2464   if test "${with_tiff}" != "no"; then
2465     AC_CHECK_HEADER(tiffio.h,
2466       [tifflibs="-lz -lm"
2467       # At least one tiff package requires the jpeg library.
2468       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2469       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2470   fi
2471
2472   if test "${HAVE_TIFF}" = "yes"; then
2473     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2474     dnl FIXME -lz -lm, as per libpng?
2475     LIBTIFF=-ltiff
2476   fi
2477 fi
2478 AC_SUBST(LIBTIFF)
2479
2480 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2481 HAVE_GIF=no
2482 LIBGIF=
2483 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2484   AC_CHECK_HEADER(gif_lib.h,
2485 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2486 # Earlier versions can crash Emacs.
2487     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2488
2489   if test "$HAVE_GIF" = yes; then
2490     LIBGIF=-lgif
2491   elif test "$HAVE_GIF" = maybe; then
2492 # If gif_lib.h but no libgif, try libungif.
2493     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2494     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2495   fi
2496
2497   if test "${HAVE_GIF}" = "yes"; then
2498     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2499   fi
2500 fi
2501 AC_SUBST(LIBGIF)
2502
2503 dnl Check for required libraries.
2504 if test "${HAVE_X11}" = "yes"; then
2505   MISSING=""
2506   WITH_NO=""
2507   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2508     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2509   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2510     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2511   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2512     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2513   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2514     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2515   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2516     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2517
2518   if test "X${MISSING}" != X; then
2519     AC_MSG_ERROR([The following required libraries were not found:
2520     $MISSING
2521 Maybe some development libraries/packages are missing?
2522 If you don't want to link with them give
2523     $WITH_NO
2524 as options to configure])
2525   fi
2526 fi
2527
2528 ### Use -lgpm if available, unless `--with-gpm=no'.
2529 HAVE_GPM=no
2530 LIBGPM=
2531 if test "${with_gpm}" != "no"; then
2532   AC_CHECK_HEADER(gpm.h,
2533     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2534
2535   if test "${HAVE_GPM}" = "yes"; then
2536     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2537     LIBGPM=-lgpm
2538   fi
2539 fi
2540 AC_SUBST(LIBGPM)
2541
2542 dnl Check for malloc/malloc.h on darwin
2543 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2544
2545 GNUSTEP_CFLAGS=
2546 ### Use NeXTstep API to implement GUI.
2547 if test "${HAVE_NS}" = "yes"; then
2548   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2549   if test "${NS_IMPL_COCOA}" = "yes"; then
2550     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2551   fi
2552   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2553     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2554     # See also .m.o rule in Makefile.in */
2555     # FIXME: are all these flags really needed?  Document here why.  */
2556     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2557     ## Extra CFLAGS applied to src/*.m files.
2558     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2559   fi
2560   # We also have mouse menus.
2561   HAVE_MENUS=yes
2562   OTHER_FILES=ns-app
2563 fi
2564
2565
2566 ### Use session management (-lSM -lICE) if available
2567 HAVE_X_SM=no
2568 LIBXSM=
2569 if test "${HAVE_X11}" = "yes"; then
2570   AC_CHECK_HEADER(X11/SM/SMlib.h,
2571     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2572
2573   if test "${HAVE_X_SM}" = "yes"; then
2574     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2575     LIBXSM="-lSM -lICE"
2576     case "$LIBS" in
2577       *-lSM*) ;;
2578       *)      LIBS="$LIBXSM $LIBS" ;;
2579     esac
2580   fi
2581 fi
2582 AC_SUBST(LIBXSM)
2583
2584 ### Use libxml (-lxml2) if available
2585 HAVE_LIBXML2=no
2586 if test "${with_xml2}" != "no"; then
2587   ### I'm not sure what the version number should be, so I just guessed.
2588   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2589   if test "${HAVE_LIBXML2}" = "yes"; then
2590     LIBS="$LIBXML2_LIBS $LIBS"
2591     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2592     if test "${HAVE_LIBXML2}" = "yes"; then
2593       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2594     else
2595       LIBXML2_LIBS=""
2596       LIBXML2_CFLAGS=""
2597     fi
2598   fi
2599 fi
2600 AC_SUBST(LIBXML2_LIBS)
2601 AC_SUBST(LIBXML2_CFLAGS)
2602
2603 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2604 AC_CACHE_CHECK(whether netdb declares h_errno,
2605                emacs_cv_netdb_declares_h_errno,
2606 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2607   [[return h_errno;]])],
2608   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2609 if test $emacs_cv_netdb_declares_h_errno = yes; then
2610   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2611 fi
2612
2613 # fmod, logb, and frexp are found in -lm on most systems.
2614 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2615 AC_CHECK_LIB(m, sqrt)
2616
2617 # Check for mail-locking functions in a "mail" library.  Probably this should
2618 # have the same check as for liblockfile below.
2619 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2620 if test $have_mail = yes; then
2621   LIBS_MAIL=-lmail
2622   LIBS="$LIBS_MAIL $LIBS"
2623   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2624 else
2625   LIBS_MAIL=
2626 fi
2627 dnl Debian, at least:
2628 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2629 if test $have_lockfile = yes; then
2630    LIBS_MAIL=-llockfile
2631    LIBS="$LIBS_MAIL $LIBS"
2632    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2633 else
2634 # If we have the shared liblockfile, assume we must use it for mail
2635 # locking (e.g. Debian).  If we couldn't link against liblockfile
2636 # (no liblockfile.a installed), ensure that we don't need to.
2637   dnl This works for files generally, not just executables.
2638   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2639   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2640                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2641   if test $ac_cv_prog_liblockfile = yes; then
2642     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2643 This probably means that movemail could lose mail.
2644 There may be a `development' package to install containing liblockfile.])
2645   fi
2646 fi
2647 AC_CHECK_HEADERS_ONCE(maillock.h)
2648 AC_SUBST(LIBS_MAIL)
2649
2650 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2651 ## interlock access to the mail spool.  The alternative is a lock file named
2652 ## /usr/spool/mail/$USER.lock.
2653 mail_lock=no
2654 case "$opsys" in
2655   aix4-2) mail_lock="lockf" ;;
2656
2657   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2658
2659   ## On GNU/Linux systems, both methods are used by various mail programs.
2660   ## I assume most people are using newer mailers that have heard of flock.
2661   ## Change this if you need to.
2662   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2663   ## configure gets the right answers, and that means *NOT* using flock.
2664   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2665   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2666   ## Debian maintainer hasn't provided a clean fix for Emacs.
2667   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2668   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2669   ## correct logic.  -- fx
2670   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2671   ## liblockfile is a Free Software replacement for libmail, used on
2672   ## Debian systems and elsewhere. -rfr.
2673   gnu-*)
2674     mail_lock="flock"
2675     if test $have_mail = yes || test $have_lockfile = yes; then
2676       test $ac_cv_header_maillock_h = yes && mail_lock=no
2677     fi
2678     ;;
2679 esac
2680
2681 BLESSMAIL_TARGET=
2682 case "$mail_lock" in
2683   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2684
2685   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2686
2687   *) BLESSMAIL_TARGET="need-blessmail" ;;
2688 esac
2689 AC_SUBST(BLESSMAIL_TARGET)
2690
2691
2692 AC_CHECK_FUNCS(gethostname \
2693 rename closedir mkdir rmdir getrusage get_current_dir_name \
2694 random lrand48 logb frexp fmod rint cbrt setsid \
2695 strerror fpathconf select euidaccess getpagesize setlocale \
2696 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2697 __fpending strsignal setitimer \
2698 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2699 gai_strerror mkstemp getline getdelim fsync sync \
2700 difftime posix_memalign \
2701 getpwent endpwent getgrent endgrent \
2702 touchlock \
2703 strcasecmp strncasecmp \
2704 cfmakeraw cfsetspeed copysign __executable_start)
2705
2706 dnl Cannot use AC_CHECK_FUNCS
2707 AC_CACHE_CHECK([for __builtin_unwind_init],
2708                emacs_cv_func___builtin_unwind_init,
2709 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2710                 emacs_cv_func___builtin_unwind_init=yes,
2711                 emacs_cv_func___builtin_unwind_init=no)])
2712 if test $emacs_cv_func___builtin_unwind_init = yes; then
2713   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2714             [Define to 1 if you have the `__builtin_unwind_init' function.])
2715 fi
2716
2717 AC_CHECK_HEADERS_ONCE(sys/un.h)
2718
2719 AC_FUNC_FSEEKO
2720
2721 AC_FUNC_GETPGRP
2722
2723 # UNIX98 PTYs.
2724 AC_CHECK_FUNCS(grantpt)
2725
2726 # PTY-related GNU extensions.
2727 AC_CHECK_FUNCS(getpt)
2728
2729 # Check this now, so that we will NOT find the above functions in ncurses.
2730 # That is because we have not set up to link ncurses in lib-src.
2731 # It's better to believe a function is not available
2732 # than to expect to find it in ncurses.
2733 # Also we need tputs and friends to be able to build at all.
2734 AC_MSG_CHECKING([for library containing tputs])
2735 # Run a test program that contains a call to tputs, a call that is
2736 # never executed.  This tests whether a pre-'main' dynamic linker
2737 # works with the library.  It's too much trouble to actually call
2738 # tputs in the test program, due to portability hassles.  When
2739 # cross-compiling, assume the test program will run if it links.
2740 AC_DEFUN([tputs_link_source], [
2741   AC_LANG_SOURCE(
2742      [[extern void tputs (const char *, int, int (*)(int));
2743        int main (int argc, char **argv)
2744        {
2745           if (argc == 10000)
2746             tputs (argv[0], 0, 0);
2747           return 0;
2748        }]])
2749 ])
2750 # Maybe curses should be tried earlier?
2751 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2752 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2753   OLIBS=$LIBS
2754   if test -z "$tputs_library"; then
2755     LIBS_TERMCAP=
2756     msg='none required'
2757   else
2758     LIBS_TERMCAP=-l$tputs_library
2759     msg=$LIBS_TERMCAP
2760     LIBS="$LIBS_TERMCAP $LIBS"
2761   fi
2762   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2763     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2764   LIBS=$OLIBS
2765   if test "X$msg" != Xno; then
2766     break
2767   fi
2768 done
2769 AC_MSG_RESULT([$msg])
2770 if test "X$msg" = Xno; then
2771   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2772 The following libraries were tried (in order):
2773   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2774 Please try installing whichever of these libraries is most appropriate
2775 for your system, together with its header files.
2776 For example, a libncurses-dev(el) or similar package.])
2777 fi
2778
2779 ## Use termcap instead of terminfo?
2780 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2781 TERMINFO=yes
2782 ## FIXME?  In the cases below where we unconditionally set
2783 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2784 ## if that was found above to have tputs.
2785 ## Should we use the gnu* logic everywhere?
2786 case "$opsys" in
2787   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2788   ##  The ncurses library has been moved out of the System framework in
2789   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2790   ##  option to use it.
2791   darwin) LIBS_TERMCAP="-lncurses" ;;
2792
2793   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2794
2795   freebsd)
2796     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2797     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2798     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2799 [[#if __FreeBSD_version < 400000
2800 fail;
2801 #endif
2802 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2803
2804     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2805
2806     if test $emacs_cv_freebsd_terminfo = yes; then
2807       LIBS_TERMCAP="-lncurses"
2808     else
2809       TERMINFO=no
2810       LIBS_TERMCAP="-ltermcap"
2811     fi
2812     ;;
2813
2814   netbsd)
2815     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2816       TERMINFO=no
2817       LIBS_TERMCAP="-ltermcap"
2818     fi
2819     ;;
2820
2821   openbsd) LIBS_TERMCAP="-lncurses" ;;
2822
2823   ## hpux: Make sure we get select from libc rather than from libcurses
2824   ##  because libcurses on HPUX 10.10 has a broken version of select.
2825   ##  We used to use -lc -lcurses, but this may be cleaner.
2826   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2827   # set that way, now it uses the default).  Isn't this a contradiction?
2828   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2829
2830 esac
2831
2832 TERMCAP_OBJ=tparam.o
2833 if test $TERMINFO = yes; then
2834   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2835   TERMCAP_OBJ=terminfo.o
2836 fi
2837 AC_SUBST(LIBS_TERMCAP)
2838 AC_SUBST(TERMCAP_OBJ)
2839
2840
2841 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2842 resolv=no
2843 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2844 #include <arpa/nameser.h>
2845 #include <resolv.h>]],
2846     [[return res_init();]])],
2847     have_res_init=yes, have_res_init=no)
2848 if test "$have_res_init" = no; then
2849   OLIBS="$LIBS"
2850   LIBS="$LIBS -lresolv"
2851   AC_MSG_CHECKING(for res_init with -lresolv)
2852   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2853 #include <arpa/nameser.h>
2854 #include <resolv.h>]],
2855     [[return res_init();]])],
2856     have_res_init=yes, have_res_init=no)
2857   AC_MSG_RESULT($have_res_init)
2858   if test "$have_res_init" = yes ; then
2859     resolv=yes
2860   fi
2861   LIBS="$OLIBS"
2862 fi
2863
2864 if test "$have_res_init" = yes; then
2865   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2866 fi
2867
2868 # Do we need the Hesiod library to provide the support routines?
2869 LIBHESIOD=
2870 if test "$with_hesiod" != no ; then
2871   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2872   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2873      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2874                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2875   if test "$resolv" = yes ; then
2876     RESOLVLIB=-lresolv
2877   else
2878     RESOLVLIB=
2879   fi
2880   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2881         hesiod=yes, :, $RESOLVLIB)])
2882
2883   if test x"$hesiod" = xyes; then
2884     AC_DEFINE(HAVE_LIBHESIOD, 1,
2885               [Define to 1 if you have the hesiod library (-lhesiod).])
2886     LIBHESIOD=-lhesiod
2887   fi
2888 fi
2889 AC_SUBST(LIBHESIOD)
2890
2891 # Do we need libresolv (due to res_init or Hesiod)?
2892 if test "$resolv" = yes ; then
2893   AC_DEFINE(HAVE_LIBRESOLV, 1,
2894             [Define to 1 if you have the resolv library (-lresolv).])
2895   LIBRESOLV=-lresolv
2896 else
2897   LIBRESOLV=
2898 fi
2899 AC_SUBST(LIBRESOLV)
2900
2901 # These tell us which Kerberos-related libraries to use.
2902 COM_ERRLIB=
2903 CRYPTOLIB=
2904 KRB5LIB=
2905 DESLIB=
2906 KRB4LIB=
2907
2908 if test "${with_kerberos}" != no; then
2909   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2910   if test $have_com_err = yes; then
2911     COM_ERRLIB=-lcom_err
2912     LIBS="$COM_ERRLIB $LIBS"
2913     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2914   fi
2915   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2916   if test $have_crypto = yes; then
2917     CRYPTOLIB=-lcrypto
2918     LIBS="$CRYPTOLIB $LIBS"
2919     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2920   fi
2921   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2922   if test $have_k5crypto = yes; then
2923     CRYPTOLIB=-lk5crypto
2924     LIBS="$CRYPTOLIB $LIBS"
2925     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2926   fi
2927   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2928   if test $have_krb5=yes; then
2929     KRB5LIB=-lkrb5
2930     LIBS="$KRB5LIB $LIBS"
2931     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2932   fi
2933   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2934   if test "${with_kerberos5}" = no; then
2935     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2936     if test $have_des425 = yes; then
2937       DESLIB=-ldes425
2938       LIBS="$DESLIB $LIBS"
2939       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2940     else
2941       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2942       if test $have_des = yes; then
2943         DESLIB=-ldes
2944         LIBS="$DESLIB $LIBS"
2945         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2946       fi
2947     fi
2948     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2949     if test $have_krb4 = yes; then
2950       KRB4LIB=-lkrb4
2951       LIBS="$KRB4LIB $LIBS"
2952       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2953     else
2954       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2955       if test $have_krb = yes; then
2956         KRB4LIB=-lkrb
2957         LIBS="$KRB4LIB $LIBS"
2958         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2959       fi
2960     fi
2961   fi
2962
2963   if test "${with_kerberos5}" != no; then
2964     AC_CHECK_HEADERS(krb5.h,
2965       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2966                         [#include <krb5.h>])])
2967   else
2968     AC_CHECK_HEADERS(des.h,,
2969                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2970                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2971     AC_CHECK_HEADERS(krb.h,,
2972                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2973                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2974   fi
2975   AC_CHECK_HEADERS(com_err.h)
2976 fi
2977
2978 AC_SUBST(COM_ERRLIB)
2979 AC_SUBST(CRYPTOLIB)
2980 AC_SUBST(KRB5LIB)
2981 AC_SUBST(DESLIB)
2982 AC_SUBST(KRB4LIB)
2983
2984 AC_CHECK_FUNCS(tzset)
2985 AC_MSG_CHECKING(whether localtime caches TZ)
2986 AC_CACHE_VAL(emacs_cv_localtime_cache,
2987 [if test x$ac_cv_func_tzset = xyes; then
2988 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2989 char TZ_GMT0[] = "TZ=GMT0";
2990 char TZ_PST8[] = "TZ=PST8";
2991 main()
2992 {
2993   time_t now = time ((time_t *) 0);
2994   int hour_GMT0, hour_unset;
2995   if (putenv (TZ_GMT0) != 0)
2996     exit (1);
2997   hour_GMT0 = localtime (&now)->tm_hour;
2998   unsetenv("TZ");
2999   hour_unset = localtime (&now)->tm_hour;
3000   if (putenv (TZ_PST8) != 0)
3001     exit (1);
3002   if (localtime (&now)->tm_hour == hour_GMT0)
3003     exit (1);
3004   unsetenv("TZ");
3005   if (localtime (&now)->tm_hour != hour_unset)
3006     exit (1);
3007   exit (0);
3008 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3009 [# If we have tzset, assume the worst when cross-compiling.
3010 emacs_cv_localtime_cache=yes])
3011 else
3012         # If we lack tzset, report that localtime does not cache TZ,
3013         # since we can't invalidate the cache if we don't have tzset.
3014         emacs_cv_localtime_cache=no
3015 fi])dnl
3016 AC_MSG_RESULT($emacs_cv_localtime_cache)
3017 if test $emacs_cv_localtime_cache = yes; then
3018   AC_DEFINE(LOCALTIME_CACHE, 1,
3019             [Define to 1 if localtime caches TZ.])
3020 fi
3021
3022 ok_so_far=yes
3023 AC_CHECK_FUNC(socket, , ok_so_far=no)
3024 if test $ok_so_far = yes; then
3025   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3026 fi
3027 if test $ok_so_far = yes; then
3028   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3029 fi
3030 if test $ok_so_far = yes; then
3031 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3032   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3033             [Define to 1 if you have inet sockets.])
3034 fi
3035
3036 if test -f /usr/lpp/X11/bin/smt.exp; then
3037   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3038             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3039 fi
3040
3041 AC_MSG_CHECKING(whether system supports dynamic ptys)
3042 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3043   AC_MSG_RESULT(yes)
3044   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3045 else
3046   AC_MSG_RESULT(no)
3047 fi
3048
3049 AC_FUNC_FORK
3050
3051 AC_CHECK_FUNCS(snprintf)
3052
3053 dnl Adapted from Haible's version.
3054 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3055   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3056     [[char* cs = nl_langinfo(CODESET);]])],
3057     emacs_cv_langinfo_codeset=yes,
3058     emacs_cv_langinfo_codeset=no)
3059   ])
3060 if test $emacs_cv_langinfo_codeset = yes; then
3061   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3062     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3063 fi
3064
3065 AC_TYPE_MBSTATE_T
3066
3067 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3068   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3069                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3070 if test "$emacs_cv_c_restrict_arr" = yes; then
3071   AC_DEFINE(__restrict_arr, __restrict,
3072     [Define to compiler's equivalent of C99 restrict keyword in array
3073      declarations.  Define as empty for no equivalent.])
3074 fi
3075
3076 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3077 dnl how the tty code is related to POSIX and/or other versions of termios.
3078 dnl The following looks like a useful start.
3079 dnl
3080 dnl AC_SYS_POSIX_TERMIOS
3081 dnl if test $ac_cv_sys_posix_termios = yes; then
3082 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3083 dnl                                and macros for terminal control.])
3084 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3085 dnl fi
3086
3087 case $opsys in
3088   darwin | gnu | hpux* | *bsd )
3089     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3090   ;;
3091 esac
3092
3093 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3094 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3095 case $opsys in
3096   hpux* | irix6-5 | openbsd | sol2* | unixware )
3097     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3098   ;;
3099 esac
3100
3101 case $opsys in
3102   gnu-* | sol2-10 )
3103     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3104     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3105   ;;
3106 esac
3107
3108 case $opsys in
3109    gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3110
3111    hpux11)
3112      dnl SA_RESTART resets the timeout of `select', so don't use it.
3113      AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should not
3114        be used.])
3115      dnl It works to open the pty's tty in the parent (Emacs), then
3116      dnl close and reopen it in the child.
3117      AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3118        works to open a pty's tty in the parent process, then close and
3119        reopen it in the child.])
3120
3121      opsysfile="s/hpux10-20.h"
3122    ;;
3123
3124    openbsd) opsysfile="s/netbsd.h" ;;
3125
3126    sol2-10)
3127      AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3128        on Solaris.])
3129      opsysfile="s/sol2-6.h"
3130    ;;
3131 esac
3132
3133 # Set up the CFLAGS for real compilation, so we can substitute it.
3134 CFLAGS="$REAL_CFLAGS"
3135 CPPFLAGS="$REAL_CPPFLAGS"
3136
3137 ## Hack to detect a buggy GCC version.
3138 if test "x$GCC" = xyes \
3139    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3140    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3141    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3142    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3143 fi
3144
3145 version=$PACKAGE_VERSION
3146
3147 ### Specify what sort of things we'll be editing into Makefile and config.h.
3148 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3149 AC_SUBST(version)
3150 AC_SUBST(configuration)
3151 ## Unused?
3152 AC_SUBST(canonical)
3153 AC_SUBST(srcdir)
3154 AC_SUBST(prefix)
3155 AC_SUBST(exec_prefix)
3156 AC_SUBST(bindir)
3157 AC_SUBST(datadir)
3158 AC_SUBST(sharedstatedir)
3159 AC_SUBST(libexecdir)
3160 AC_SUBST(mandir)
3161 AC_SUBST(infodir)
3162 AC_SUBST(lispdir)
3163 AC_SUBST(leimdir)
3164 AC_SUBST(locallisppath)
3165 AC_SUBST(lisppath)
3166 AC_SUBST(x_default_search_path)
3167 AC_SUBST(etcdir)
3168 AC_SUBST(archlibdir)
3169 AC_SUBST(docdir)
3170 AC_SUBST(bitmapdir)
3171 AC_SUBST(gamedir)
3172 AC_SUBST(gameuser)
3173 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3174 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3175 ## end of LIBX_BASE, but nothing ever set it.
3176 AC_SUBST(LD_SWITCH_X_SITE)
3177 AC_SUBST(C_SWITCH_X_SITE)
3178 AC_SUBST(GNUSTEP_CFLAGS)
3179 AC_SUBST(CFLAGS)
3180 ## Used in lwlib/Makefile.in.
3181 AC_SUBST(X_TOOLKIT_TYPE)
3182 if test -n "${opsysfile}"; then
3183   S_FILE="\$(srcdir)/${opsysfile}"
3184 else
3185   S_FILE=
3186 fi
3187 AC_SUBST(S_FILE)
3188 AC_SUBST(ns_appdir)
3189 AC_SUBST(ns_appbindir)
3190 AC_SUBST(ns_appresdir)
3191 AC_SUBST(ns_appsrc)
3192 AC_SUBST(GNU_OBJC_CFLAGS)
3193 AC_SUBST(OTHER_FILES)
3194
3195 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3196                    [Define to the canonical Emacs configuration name.])
3197 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3198                    [Define to the options passed to configure.])
3199 if test -n "$opsysfile"; then
3200   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3201                      [Define to the used os dependent file.])
3202 fi
3203
3204 XMENU_OBJ=
3205 XOBJ=
3206 FONT_OBJ=
3207 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3208   AC_DEFINE(HAVE_X_WINDOWS, 1,
3209             [Define to 1 if you want to use the X window system.])
3210   XMENU_OBJ=xmenu.o
3211   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3212   FONT_OBJ=xfont.o
3213   if test "$HAVE_XFT" = "yes"; then
3214     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3215   elif test "$HAVE_FREETYPE" = "yes"; then
3216     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3217   fi
3218   AC_SUBST(FONT_OBJ)
3219 fi
3220 AC_SUBST(XMENU_OBJ)
3221 AC_SUBST(XOBJ)
3222 AC_SUBST(FONT_OBJ)
3223
3224 WIDGET_OBJ=
3225 MOTIF_LIBW=
3226 if test "${USE_X_TOOLKIT}" != "none" ; then
3227   WIDGET_OBJ=widget.o
3228   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3229   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3230     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3231   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3232     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3233     MOTIF_LIBW=-lXm
3234     case "$opsys" in
3235       gnu-linux)
3236         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3237         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3238         ;;
3239
3240       unixware)
3241         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3242         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3243         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3244         ;;
3245
3246       aix4-2)
3247         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3248         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3249         ;;
3250     esac
3251     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3252   fi
3253 fi
3254 AC_SUBST(WIDGET_OBJ)
3255
3256 TOOLKIT_LIBW=
3257 case "$USE_X_TOOLKIT" in
3258   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3259   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3260   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3261 esac
3262 AC_SUBST(TOOLKIT_LIBW)
3263
3264 if test "$USE_X_TOOLKIT" = "none"; then
3265   LIBXT_OTHER="\$(LIBXSM)"
3266   OLDXMENU_TARGET="really-oldXMenu"
3267 else
3268   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3269   OLDXMENU_TARGET="really-lwlib"
3270 fi
3271 AC_SUBST(LIBXT_OTHER)
3272
3273 ## The X Menu stuff is present in the X10 distribution, but missing
3274 ## from X11.  If we have X10, just use the installed library;
3275 ## otherwise, use our own copy.
3276 if test "${HAVE_X11}" = "yes" ; then
3277   AC_DEFINE(HAVE_X11, 1,
3278             [Define to 1 if you want to use version 11 of X windows.
3279              Otherwise, Emacs expects to use version 10.])
3280
3281   if test "$USE_X_TOOLKIT" = "none"; then
3282     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3283   else
3284     OLDXMENU="\${lwlibdir}/liblw.a"
3285   fi
3286   LIBXMENU="\$(OLDXMENU)"
3287   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3288   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3289 else
3290   ## For a syntactically valid Makefile; not actually used for anything.
3291   ## See comments in src/Makefile.in.
3292   OLDXMENU=nothing
3293   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3294   if test "${HAVE_X_WINDOWS}" = "yes"; then
3295     LIBXMENU="-lXMenu"
3296   else
3297     LIBXMENU=
3298   fi
3299   LIBX_OTHER=
3300   OLDXMENU_DEPS=
3301 fi
3302
3303 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3304   OLDXMENU_TARGET=
3305   OLDXMENU=nothing
3306   LIBXMENU=
3307   OLDXMENU_DEPS=
3308 fi
3309
3310 AC_SUBST(OLDXMENU_TARGET)
3311 AC_SUBST(OLDXMENU)
3312 AC_SUBST(LIBXMENU)
3313 AC_SUBST(LIBX_OTHER)
3314 AC_SUBST(OLDXMENU_DEPS)
3315
3316 if test "${HAVE_MENUS}" = "yes" ; then
3317   AC_DEFINE(HAVE_MENUS, 1,
3318             [Define to 1 if you have mouse menus.
3319              (This is automatic if you use X, but the option to specify it remains.)
3320              It is also defined with other window systems that support xmenu.c.])
3321 fi
3322
3323 if test "${GNU_MALLOC}" = "yes" ; then
3324   AC_DEFINE(GNU_MALLOC, 1,
3325             [Define to 1 if you want to use the GNU memory allocator.])
3326 fi
3327
3328 RALLOC_OBJ=
3329 if test "${REL_ALLOC}" = "yes" ; then
3330   AC_DEFINE(REL_ALLOC, 1,
3331             [Define REL_ALLOC if you want to use the relocating allocator for
3332              buffer space.])
3333
3334   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3335 fi
3336 AC_SUBST(RALLOC_OBJ)
3337
3338 if test "$opsys" = "cygwin"; then
3339   CYGWIN_OBJ="sheap.o"
3340   ## Cygwin differs because of its unexec().
3341   PRE_ALLOC_OBJ=
3342   POST_ALLOC_OBJ=lastfile.o
3343 else
3344   CYGWIN_OBJ=
3345   PRE_ALLOC_OBJ=lastfile.o
3346   POST_ALLOC_OBJ=
3347 fi
3348 AC_SUBST(CYGWIN_OBJ)
3349 AC_SUBST(PRE_ALLOC_OBJ)
3350 AC_SUBST(POST_ALLOC_OBJ)
3351
3352 case "$opsys" in
3353   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3354
3355   darwin)
3356    ## The -headerpad option tells ld (see man page) to leave room at the
3357    ## end of the header for adding load commands.  Needed for dumping.
3358    ## 0x690 is the total size of 30 segment load commands (at 56
3359    ## each); under Cocoa 31 commands are required.
3360    if test "$HAVE_NS" = "yes"; then
3361      libs_nsgui="-framework AppKit"
3362      headerpad_extra=6C8
3363    else
3364      libs_nsgui=
3365      headerpad_extra=690
3366    fi
3367    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3368
3369    ## This is here because src/Makefile.in did some extra fiddling around
3370    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3371    ##   #ifndef LD_SWITCH_SYSTEM
3372    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3373    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3374    ## not using gcc, darwin.
3375    ## Because this was done in src/Makefile.in, the resulting part of
3376    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3377    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3378    ## rather than LD_SWITCH_SYSTEM.
3379    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3380      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3381    ;;
3382
3383   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3384   ## find X at run-time.
3385   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3386   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3387   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3388   ## had different values in configure (in ac_link) and src/Makefile.in.
3389   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3390   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3391
3392   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3393 esac
3394
3395 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3396   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3397 fi
3398
3399 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3400
3401
3402 LD_FIRSTFLAG=
3403 ORDINARY_LINK=
3404 case "$opsys" in
3405   ## gnu: GNU needs its own crt0.
3406   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3407
3408   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3409   ## library search parth, i.e. it won't search /usr/lib for libc and
3410   ## friends.  Using -nostartfiles instead avoids this problem, and
3411   ## will also work on earlier NetBSD releases.
3412   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3413
3414   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3415   ##   MkLinux/LinuxPPC needs this.
3416   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3417   gnu-*)
3418     case "$canonical" in
3419       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3420     esac
3421     ;;
3422 esac
3423
3424
3425 if test "x$ORDINARY_LINK" = "xyes"; then
3426
3427   LD_FIRSTFLAG=""
3428   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3429
3430 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3431 ## freebsd, gnu-* not on powerpc*|s390x*.
3432 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3433
3434   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3435   ## places that are difficult to figure out at make time.  Fortunately,
3436   ## these same versions allow you to pass arbitrary flags on to the
3437   ## linker, so there is no reason not to use it as a linker.
3438   ##
3439   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3440   ## searching for libraries in its internal directories, so we have to
3441   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3442   LD_FIRSTFLAG="-nostdlib"
3443 fi
3444
3445 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3446 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3447
3448 AC_SUBST(LD_FIRSTFLAG)
3449
3450
3451 ## FIXME? The logic here is not precisely the same as that above.
3452 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3453 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3454 LIB_GCC=
3455 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3456
3457   case "$opsys" in
3458     freebsd|netbsd|openbsd) LIB_GCC= ;;
3459
3460     gnu-*)
3461       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3462       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3463       case $host_cpu in
3464       arm*)
3465         LIB_GCC="-lgcc_s"
3466         ;;
3467       *)
3468         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3469         ## immediately undefine it again and redefine it to empty.
3470         ## Was the C_SWITCH_X_SITE part really necessary?
3471 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3472         LIB_GCC=
3473         ;;
3474       esac
3475       ;;
3476
3477     ## Ask GCC where to find libgcc.a.
3478     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3479   esac
3480 fi                              dnl if $GCC
3481 AC_SUBST(LIB_GCC)
3482
3483
3484 ## If we're using X11/GNUstep, define some consequences.
3485 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3486   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3487   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3488 fi
3489
3490
3491 AH_TOP([/* GNU Emacs site configuration template file.
3492
3493 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3494   Free Software Foundation, Inc.
3495
3496 This file is part of GNU Emacs.
3497
3498 GNU Emacs is free software: you can redistribute it and/or modify
3499 it under the terms of the GNU General Public License as published by
3500 the Free Software Foundation, either version 3 of the License, or
3501 (at your option) any later version.
3502
3503 GNU Emacs is distributed in the hope that it will be useful,
3504 but WITHOUT ANY WARRANTY; without even the implied warranty of
3505 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3506 GNU General Public License for more details.
3507
3508 You should have received a copy of the GNU General Public License
3509 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3510
3511
3512 /* No code in Emacs #includes config.h twice, but some bits of code
3513    intended to work with other packages as well (like gmalloc.c)
3514    think they can include it as many times as they like.  */
3515 #ifndef EMACS_CONFIG_H
3516 #define EMACS_CONFIG_H
3517 ])dnl
3518
3519 AH_BOTTOM([
3520 /* On AIX 3 this must be included before any other include file.  */
3521 #include <alloca.h>
3522 #if ! HAVE_ALLOCA
3523 # error "alloca not available on this machine"
3524 #endif
3525
3526 /* Define AMPERSAND_FULL_NAME if you use the convention
3527    that & in the full name stands for the login id.  */
3528 /* Turned on June 1996 supposing nobody will mind it.  */
3529 #define AMPERSAND_FULL_NAME
3530
3531 /* `subprocesses' should be defined if you want to
3532    have code for asynchronous subprocesses
3533    (as used in M-x compile and M-x shell).
3534    Only MSDOS does not support this (it overrides
3535    this in its config_opsysfile below).  */
3536
3537 #define subprocesses
3538
3539 /* Include the os dependent file.  */
3540 #ifdef config_opsysfile
3541 # include config_opsysfile
3542 #endif
3543
3544 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3545    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3546   (There is probably a better place to do this, but right now the
3547    Cocoa side does this in s/darwin.h and we cannot parallel this
3548    exactly since GNUstep is multi-OS.  */
3549 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3550 #  define SYSTEM_PURESIZE_EXTRA 30000
3551 #endif
3552
3553 #ifdef emacs /* Don't do this for lib-src.  */
3554 /* Tell regex.c to use a type compatible with Emacs.  */
3555 #define RE_TRANSLATE_TYPE Lisp_Object
3556 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3557 #ifdef make_number
3558 /* If make_number is a macro, use it.  */
3559 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3560 #else
3561 /* If make_number is a function, avoid it.  */
3562 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3563 #endif
3564 #endif
3565
3566 #include <string.h>
3567 #include <stdlib.h>
3568
3569 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3570 #define NO_INLINE __attribute__((noinline))
3571 #else
3572 #define NO_INLINE
3573 #endif
3574
3575 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3576 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3577 #else
3578 #define EXTERNALLY_VISIBLE
3579 #endif
3580
3581 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3582 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3583 #else
3584 # define ATTRIBUTE_FORMAT(spec) /* empty */
3585 #endif
3586
3587 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3588 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3589    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3590 #else
3591 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3592    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3593 #endif
3594
3595 /* Some versions of GNU/Linux define noinline in their headers.  */
3596 #ifdef noinline
3597 #undef noinline
3598 #endif
3599
3600 /* These won't be used automatically yet.  We also need to know, at least,
3601    that the stack is continuous.  */
3602 #ifdef __GNUC__
3603 #  ifndef GC_SETJMP_WORKS
3604   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3605 #    define GC_SETJMP_WORKS 1
3606 #  endif
3607 #endif
3608
3609 #endif /* EMACS_CONFIG_H */
3610
3611 /*
3612 Local Variables:
3613 mode: c
3614 End:
3615 */
3616 ])dnl
3617
3618 #### Report on what we decided to do.
3619 #### Report GTK as a toolkit, even if it doesn't use Xt.
3620 #### It makes printing result more understandable as using GTK sets
3621 #### toolkit_scroll_bars to yes by default.
3622 if test "${HAVE_GTK}" = "yes"; then
3623   USE_X_TOOLKIT=GTK
3624 fi
3625
3626 echo "
3627 Configured for \`${canonical}'.
3628
3629   Where should the build process find the source code?    ${srcdir}
3630   What operating system file should Emacs use?            ${opsysfile-none}
3631   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3632   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3633   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3634   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3635   What window system should Emacs use?                    ${window_system}
3636   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3637
3638 if test -n "${x_includes}"; then
3639 echo "  Where do we find X Windows header files?                ${x_includes}"
3640 else
3641 echo "  Where do we find X Windows header files?                Standard dirs"
3642 fi
3643 if test -n "${x_libraries}"; then
3644 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3645 else
3646 echo "  Where do we find X Windows libraries?                   Standard dirs"
3647 fi
3648
3649 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3650 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3651 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3652 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3653 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3654 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3655 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3656 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3657
3658 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3659 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3660 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3661 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3662 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3663 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3664 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3665
3666 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3667 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3668 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3669 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3670
3671 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3672 echo
3673
3674 if test -n "${EMACSDATA}"; then
3675    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3676 fi
3677 if test -n "${EMACSDOC}"; then
3678    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3679 fi
3680
3681 echo
3682
3683 if test "$HAVE_NS" = "yes"; then
3684    echo
3685    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3686 The installed application will go to nextstep/Emacs.app and can be
3687 run or moved from there."
3688    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3689       echo "The application will be fully self-contained."
3690     else
3691       echo "The lisp resources for the application will be installed under ${prefix}.
3692 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3693 to run if these resources are not installed."
3694    fi
3695    echo
3696 fi
3697
3698 if test "${opsys}" = "cygwin"; then
3699   case `uname -r` in
3700     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3701            echo
3702            ;;
3703   esac
3704 fi
3705
3706 # Remove any trailing slashes in these variables.
3707 [test "${prefix}" != NONE &&
3708   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3709 test "${exec_prefix}" != NONE &&
3710   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3711
3712 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3713 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3714 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3715 dnl (else you get "no `Makefile.am' found for any configure output").
3716 dnl This will work, but you get a config.status that is not quite right
3717 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3718 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3719 dnl it seems better to just live with the duplication.
3720 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3721
3722 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3723        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3724        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3725        leim/Makefile])
3726
3727 dnl test/ is not present in release tarfiles.
3728 opt_makefile=test/automated/Makefile
3729
3730 if test -f $srcdir/${opt_makefile}.in; then
3731   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3732   dnl Again, it's best not to use a variable.  Though you can add
3733   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3734   AC_CONFIG_FILES([test/automated/Makefile])
3735 fi
3736
3737
3738 dnl admin/ may or may not be present.
3739 opt_makefile=admin/unidata/Makefile
3740
3741 if test -f $srcdir/${opt_makefile}.in; then
3742   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3743   AC_CONFIG_FILES([admin/unidata/Makefile])
3744 fi
3745
3746
3747 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3748
3749 AC_SUBST(SUBDIR_MAKEFILES_IN)
3750
3751 dnl Make the necessary directories, if they don't exist.
3752 AC_CONFIG_COMMANDS([mkdirs], [
3753 for dir in etc lisp ; do
3754   test -d ${dir} || mkdir ${dir}
3755 done
3756 ])
3757
3758 dnl You might wonder (I did) why epaths.h is generated by running make,
3759 dnl rather than just letting configure generate it from epaths.in.
3760 dnl One reason is that the various paths are not fully expanded (see above);
3761 dnl eg gamedir=${prefix}/var/games/emacs.
3762 dnl Secondly, the GNU Coding standards require that one should be able
3763 dnl to run `make prefix=/some/where/else' and override the values set
3764 dnl by configure.  This also explains the `move-if-change' test and
3765 dnl the use of force in the `epaths-force' rule in Makefile.in.
3766 AC_CONFIG_COMMANDS([epaths], [
3767 echo creating src/epaths.h
3768 ${MAKE-make} epaths-force
3769 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3770
3771 AC_CONFIG_COMMANDS([gdbinit], [
3772 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3773   echo creating src/.gdbinit
3774   echo source $srcdir/src/.gdbinit > src/.gdbinit
3775 fi
3776 ])
3777
3778 AC_OUTPUT
3779
3780 dnl configure.in ends here