lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems.
   2
   3 ;;;; Copyright (C) 1993 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;;; This file is part of GNU Emacs.
   9 ;;;
  10 ;;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 2, or (at your option)
  13 ;;; any later version.
  14 ;;;
  15 ;;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (defvar frame-creation-function nil
  27   "Window-system dependent function to call to create a new frame.
  28 The window system startup file should set this to its frame creation
  29 function, which should take an alist of parameters as its argument.")
  30
  31 ;;; The initial value given here for this must ask for a minibuffer.
  32 ;;; There must always exist a frame with a minibuffer, and after we
  33 ;;; delete the terminal frame, this will be the only frame.
  34 (defvar initial-frame-alist '((minibuffer . t))
  35   "Alist of frame parameters for creating the initial X window frame.
  36 You can set this in your `.emacs' file; for example,
  37  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  38 If the value calls for a frame without a minibuffer, and you do not create a
  39 minibuffer frame on your own, one is created according to
  40 `minibuffer-frame-alist'.
  41 Parameters specified here supersede the values given in
  42 `default-frame-alist'.")
  43
  44 (defvar minibuffer-frame-alist '((width . 80) (height . 2))
  45   "Alist of frame parameters for initially creating a minibuffer frame.
  46 You can set this in your `.emacs' file; for example,
  47  (setq minibuffer-frame-alist
  48    '((top . 1) (left . 1) (width . 80) (height . 2)))
  49 Parameters specified here supersede the values given in
  50 `default-frame-alist'.")
  51
  52 (defvar pop-up-frame-alist nil
  53   "Alist of frame parameters used when creating pop-up frames.
  54 Pop-up frames are used for completions, help, and the like.
  55 This variable can be set in your init file, like this:
  56   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  57 These supercede the values given in `default-frame-alist'.")
  58
  59 (setq pop-up-frame-function
  60       (function (lambda ()
  61                   (new-frame pop-up-frame-alist))))
  62
  63 \f
  64 ;;;; Arrangement of frames at startup
  65
  66 ;;; 1) Load the window system startup file from the lisp library and read the
  67 ;;; high-priority arguments (-q and the like).  The window system startup
  68 ;;; file should create any frames specified in the window system defaults.
  69 ;;;
  70 ;;; 2) If no frames have been opened, we open an initial text frame.
  71 ;;;
  72 ;;; 3) Once the init file is done, we apply any newly set parameters
  73 ;;; in initial-frame-alist to the frame.
  74
  75 (add-hook 'before-init-hook 'frame-initialize)
  76 (add-hook 'window-setup-hook 'frame-notice-user-settings)
  77
  78 ;;; If we create the initial frame, this is it.
  79 (defvar frame-initial-frame nil)
  80
  81 ;;; startup.el calls this function before loading the user's init
  82 ;;; file - if there is no frame with a minibuffer open now, create
  83 ;;; one to display messages while loading the init file.
  84 (defun frame-initialize ()
  85
  86   ;; Are we actually running under a window system at all?
  87   (if (and window-system (not noninteractive))
  88       (progn
  89         ;; If there is no frame with a minibuffer besides the terminal
  90         ;; frame, then we need to create the opening frame.  Make sure
  91         ;; it has a minibuffer, but let initial-frame-alist omit the
  92         ;; minibuffer spec.
  93         (or (delq terminal-frame (minibuffer-frame-list))
  94             (setq default-minibuffer-frame
  95                   (setq frame-initial-frame
  96                         (new-frame initial-frame-alist))))
  97
  98         ;; At this point, we know that we have a frame open, so we
  99         ;; can delete the terminal frame.
 100         (delete-frame terminal-frame)
 101         (setq terminal-frame nil))
 102
 103     ;; No, we're not running a window system.  Arrange to cause errors.
 104     (setq frame-creation-function
 105           (function
 106            (lambda (parameters)
 107              (error
 108               "Can't create multiple frames without a window system"))))))
 109
 110 ;;; startup.el calls this function after loading the user's init
 111 ;;; file.  Now default-frame-alist and initial-frame-alist contain
 112 ;;; information to which we must react; do what needs to be done.
 113 (defun frame-notice-user-settings ()
 114
 115   ;; Creating and deleting frames may shift the selected frame around,
 116   ;; and thus the current buffer.  Protect against that.  We don't
 117   ;; want to use save-excursion here, because that may also try to set
 118   ;; the buffer of the selected window, which fails when the selected
 119   ;; window is the minibuffer.
 120   (let ((old-buffer (current-buffer)))
 121
 122     ;; If the initial frame is still around, apply initial-frame-alist
 123     ;; and default-frame-alist to it.
 124     (if (frame-live-p frame-initial-frame)
 125
 126         ;; The initial frame we create above always has a minibuffer.
 127         ;; If the user wants to remove it, or make it a minibuffer-only
 128         ;; frame, then we'll have to delete the current frame and make a
 129         ;; new one; you can't remove or add a root window to/from an
 130         ;; existing frame.
 131         ;;
 132         ;; NOTE: default-frame-alist was nil when we created the
 133         ;; existing frame.  We need to explicitly include
 134         ;; default-frame-alist in the parameters of the screen we
 135         ;; create here, so that its new value, gleaned from the user's
 136         ;; .emacs file, will be applied to the existing screen.
 137         (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 138                               (assq 'minibuffer default-frame-alist)
 139                               '(minibuffer . t)))
 140                      t))
 141             ;; Create the new frame.
 142             (let ((new
 143                    (new-frame
 144                     (append initial-frame-alist
 145                             default-frame-alist
 146                             (frame-parameters frame-initial-frame)))))
 147
 148               ;; The initial frame, which we are about to delete, may be
 149               ;; the only frame with a minibuffer.  If it is, create a
 150               ;; new one.
 151               (or (delq frame-initial-frame (minibuffer-frame-list))
 152                   (new-frame (append minibuffer-frame-alist
 153                                      '((minibuffer . only)))))
 154
 155               ;; If the initial frame is serving as a surrogate
 156               ;; minibuffer frame for any frames, we need to wean them
 157               ;; onto a new frame.  The default-minibuffer-frame
 158               ;; variable must be handled similarly.
 159               (let ((users-of-initial
 160                      (filtered-frame-list
 161                       (function (lambda (frame)
 162                                   (and (not (eq frame frame-initial-frame))
 163                                        (eq (window-frame
 164                                             (minibuffer-window frame))
 165                                            frame-initial-frame)))))))
 166                 (if (or users-of-initial
 167                         (eq default-minibuffer-frame frame-initial-frame))
 168
 169                     ;; Choose an appropriate frame.  Prefer frames which
 170                     ;; are only minibuffers.
 171                     (let* ((new-surrogate
 172                             (car
 173                              (or (filtered-frame-list
 174                                   (function
 175                                    (lambda (frame)
 176                                      (eq (cdr (assq 'minibuffer
 177                                                     (frame-parameters frame)))
 178                                          'only))))
 179                                  (minibuffer-frame-list))))
 180                            (new-minibuffer (minibuffer-window new-surrogate)))
 181
 182                       (if (eq default-minibuffer-frame frame-initial-frame)
 183                           (setq default-minibuffer-frame new-surrogate))
 184
 185                       ;; Wean the frames using frame-initial-frame as
 186                       ;; their minibuffer frame.
 187                       (mapcar
 188                        (function
 189                         (lambda (frame)
 190                           (modify-frame-parameters
 191                            frame (list (cons 'minibuffer new-minibuffer)))))
 192                        users-of-initial))))
 193
 194               ;; Redirect events enqueued at this frame to the new frame.
 195               ;; Is this a good idea?
 196               (redirect-frame-focus frame-initial-frame new)
 197
 198               ;; Finally, get rid of the old frame.
 199               (delete-frame frame-initial-frame))
 200
 201           ;; Otherwise, we don't need all that rigamarole; just apply
 202           ;; the new parameters.
 203           (modify-frame-parameters frame-initial-frame
 204                                    (append initial-frame-alist
 205                                            default-frame-alist))))
 206
 207     ;; Restore the original buffer.
 208     (set-buffer old-buffer)
 209
 210     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 211     (makunbound 'frame-initial-frame)))
 212
 213 \f
 214 ;;;; Creation of additional frames, and other frame miscellanea
 215
 216 ;;; Return some frame other than the current frame, creating one if
 217 ;;; neccessary.  Note that the minibuffer frame, if separate, is not
 218 ;;; considered (see next-frame).
 219 (defun get-other-frame ()
 220   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 221                (new-frame)
 222              (next-frame (selected-frame)))))
 223     s))
 224
 225 (defun next-multiframe-window ()
 226   "Select the next window, regardless of which frame it is on."
 227   (interactive)
 228   (select-window (next-window (selected-window)
 229                               (> (minibuffer-depth) 0)
 230                               t)))
 231
 232 (defun previous-multiframe-window ()
 233   "Select the previous window, regardless of which frame it is on."
 234   (interactive)
 235   (select-window (previous-window (selected-window)
 236                                   (> (minibuffer-depth) 0)
 237                                   t)))
 238
 239 ;; Alias, kept temporarily.
 240 (fset 'new-frame 'make-frame)
 241 (defun make-frame (&optional parameters)
 242   "Create a new frame, displaying the current buffer.
 243
 244 Optional argument PARAMETERS is an alist of parameters for the new
 245 frame.  Specifically, PARAMETERS is a list of pairs, each having one
 246 of the following forms:
 247
 248 \(name . STRING)        - The frame should be named STRING.
 249
 250 \(height . NUMBER) - The frame should be NUMBER text lines high.  If
 251         this parameter is present, the width parameter must also be
 252         given.
 253
 254 \(width . NUMBER) - The frame should be NUMBER characters in width.
 255         If this parameter is present, the height parameter must also
 256         be given.
 257
 258 \(minibuffer . t) - the frame should have a minibuffer
 259 \(minibuffer . nil) - the frame should have no minibuffer
 260 \(minibuffer . only) - the frame should contain only a minibuffer
 261 \(minibuffer . WINDOW) - the frame should use WINDOW as its minibuffer window.
 262
 263 The documentation for the function `x-create-frame' describes
 264 additional frame parameters that Emacs recognizes for X window frames."
 265   (interactive)
 266   (funcall frame-creation-function parameters))
 267
 268 (defun filtered-frame-list (predicate)
 269   "Return a list of all live frames which satisfy PREDICATE."
 270   (let ((frames (frame-list))
 271         good-frames)
 272     (while (consp frames)
 273       (if (funcall predicate (car frames))
 274           (setq good-frames (cons (car frames) good-frames)))
 275       (setq frames (cdr frames)))
 276     good-frames))
 277
 278 (defun minibuffer-frame-list ()
 279   "Return a list of all frames with their own minibuffers."
 280   (filtered-frame-list
 281    (function (lambda (frame)
 282                (eq frame (window-frame (minibuffer-window frame)))))))
 283
 284 \f
 285 ;;;; Frame configurations
 286
 287 (defun current-frame-configuration ()
 288   "Return a list describing the positions and states of all frames.
 289 Its car is `frame-configuration'.
 290 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 291 where
 292   FRAME is a frame object,
 293   ALIST is an association list specifying some of FRAME's parameters, and
 294   WINDOW-CONFIG is a window configuration object for FRAME."
 295   (cons 'frame-configuration
 296         (mapcar (function
 297                  (lambda (frame)
 298                    (list frame
 299                          (frame-parameters frame)
 300                          (current-window-configuration frame))))
 301                 (frame-list))))
 302
 303 (defun set-frame-configuration (configuration)
 304   "Restore the frames to the state described by CONFIGURATION.
 305 Each frame listed in CONFIGURATION has its position, size, window
 306 configuration, and other parameters set as specified in CONFIGURATION."
 307   (or (frame-configuration-p configuration)
 308       (signal 'wrong-type-argument
 309               (list 'frame-configuration-p configuration)))
 310   (let ((config-alist (cdr configuration))
 311         frames-to-delete)
 312     (mapcar (function
 313              (lambda (frame)
 314                (let ((parameters (assq frame config-alist)))
 315                  (if parameters
 316                      (progn
 317                        (modify-frame-parameters frame (nth 1 parameters))
 318                        (set-window-configuration (nth 2 parameters)))
 319                    (setq frames-to-delete (cons frame frames-to-delete))))))
 320             (frame-list))
 321     (mapcar 'delete-frame frames-to-delete)))
 322
 323 (defun frame-configuration-p (object)
 324   "Return non-nil if OBJECT seems to be a frame configuration.
 325 Any list whose car is `frame-configuration' is assumed to be a frame
 326 configuration."
 327   (and (consp object)
 328        (eq (car object) 'frame-configuration)))
 329
 330 \f
 331 ;;;; Convenience functions for accessing and interactively changing
 332 ;;;; frame parameters.
 333
 334 (defun frame-height (&optional frame)
 335   "Return number of lines available for display on FRAME.
 336 If FRAME is omitted, describe the currently selected frame."
 337   (cdr (assq 'height (frame-parameters frame))))
 338
 339 (defun frame-width (&optional frame)
 340   "Return number of columns available for display on FRAME.
 341 If FRAME is omitted, describe the currently selected frame."
 342   (cdr (assq 'width (frame-parameters frame))))
 343
 344 (defun set-default-font (font-name)
 345   "Set the font of the selected frame to FONT.
 346 When called interactively, prompt for the name of the font to use."
 347   (interactive "sFont name: ")
 348   (modify-frame-parameters (selected-frame)
 349                            (list (cons 'font font-name))))
 350
 351 (defun set-background-color (color-name)
 352   "Set the background color of the selected frame to COLOR.
 353 When called interactively, prompt for the name of the color to use."
 354   (interactive "sColor: ")
 355   (modify-frame-parameters (selected-frame)
 356                            (list (cons 'background-color color-name))))
 357
 358 (defun set-foreground-color (color-name)
 359   "Set the foreground color of the selected frame to COLOR.
 360 When called interactively, prompt for the name of the color to use."
 361   (interactive "sColor: ")
 362   (modify-frame-parameters (selected-frame)
 363                            (list (cons 'foreground-color color-name))))
 364
 365 (defun set-cursor-color (color-name)
 366   "Set the text cursor color of the selected frame to COLOR.
 367 When called interactively, prompt for the name of the color to use."
 368   (interactive "sColor: ")
 369   (modify-frame-parameters (selected-frame)
 370                            (list (cons 'cursor-color color-name))))
 371
 372 (defun set-mouse-color (color-name)
 373   "Set the color of the mouse pointer of the selected frame to COLOR.
 374 When called interactively, prompt for the name of the color to use."
 375   (interactive "sColor: ")
 376   (modify-frame-parameters (selected-frame)
 377                            (list (cons 'mouse-color color-name))))
 378
 379 (defun set-border-color (color-name)
 380   "Set the color of the border of the selected frame to COLOR.
 381 When called interactively, prompt for the name of the color to use."
 382   (interactive "sColor: ")
 383   (modify-frame-parameters (selected-frame)
 384                            (list (cons 'border-color color-name))))
 385
 386 (defun auto-raise-mode (arg)
 387   "Toggle whether or not the selected frame should auto-raise.
 388 With arg, turn auto-raise mode on if and only if arg is positive."
 389   (interactive "P")
 390   (if (null arg)
 391       (setq arg
 392             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
 393                 -1 1)))
 394   (modify-frame-parameters (selected-frame)
 395                            (list (cons 'auto-raise (> arg 0)))))
 396
 397 (defun auto-lower-mode (arg)
 398   "Toggle whether or not the selected frame should auto-lower.
 399 With arg, turn auto-lower mode on if and only if arg is positive."
 400   (interactive "P")
 401   (if (null arg)
 402       (setq arg
 403             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
 404                 -1 1)))
 405   (modify-frame-parameters (selected-frame)
 406                            (list (cons 'auto-lower (> arg 0)))))
 407
 408 (defun toggle-vertical-scroll-bar (arg)
 409   "Toggle whether or not the selected frame has vertical scroll bars.
 410 With arg, turn vertical scroll bars on if and only if arg is positive."
 411   (interactive "P")
 412   (if (null arg)
 413       (setq arg
 414             (if (cdr (assq 'vertical-scroll-bars
 415                            (frame-parameters (selected-frame))))
 416                 -1 1)))
 417   (modify-frame-parameters (selected-frame)
 418                            (list (cons 'vertical-scroll-bars (> arg 0)))))
 419
 420 (defun toggle-horizontal-scroll-bar (arg)
 421   "Toggle whether or not the selected frame has horizontal scroll bars.
 422 With arg, turn horizontal scroll bars on if and only if arg is positive.
 423 Horizontal scroll bars aren't implemented yet."
 424   (interactive "P")
 425   (error "Horizontal scroll bars aren't implemented yet"))
 426
 427 \f
 428 ;;;; Aliases for backward compatibility with Emacs 18.
 429 (fset 'screen-height 'frame-height)
 430 (fset 'screen-width 'frame-width)
 431
 432 (defun set-screen-width (cols &optional pretend)
 433   "Obsolete function to change the size of the screen to COLS columns.\n\
 434 Optional second arg non-nil means that redisplay should use COLS columns\n\
 435 but that the idea of the actual width of the frame should not be changed.\n\
 436 This function is provided only for compatibility with Emacs 18; new code\n\
 437 should use `set-frame-width instead'."
 438   (set-frame-width (selected-frame) cols pretend))
 439
 440 (defun set-screen-height (lines &optional pretend)
 441   "Obsolete function to change the height of the screen to LINES lines.\n\
 442 Optional second arg non-nil means that redisplay should use LINES lines\n\
 443 but that the idea of the actual height of the screen should not be changed.\n\
 444 This function is provided only for compatibility with Emacs 18; new code\n\
 445 should use `set-frame-width' instead."
 446   (set-frame-height (selected-frame) lines pretend))
 447
 448 (make-obsolete 'screen-height 'frame-height)
 449 (make-obsolete 'screen-width  'frame-width)
 450 (make-obsolete 'set-screen-width 'set-frame-width)
 451 (make-obsolete 'set-screen-height 'set-frame-height)
 452
 453 \f
 454 ;;;; Key bindings
 455 (defvar ctl-x-5-map (make-sparse-keymap)
 456   "Keymap for frame commands.")
 457 (fset 'ctl-x-5-prefix ctl-x-5-map)
 458 (define-key ctl-x-map "5" 'ctl-x-5-prefix)
 459
 460 (define-key ctl-x-5-map "2" 'new-frame)
 461 (define-key ctl-x-5-map "0" 'delete-frame)
 462
 463 (provide 'frame)
 464
 465 ;;; frame.el ends here