lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process
   2
   3 ;; Copyright (C) 1986, 1987, 1992, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   4 ;;   2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes
   9
  10 ;; Changes by peck@sun.com and by rms.
  11 ;; Overhaul by Karoly Lorentey <lorentey@elte.hu> for multi-tty support.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This Lisp code is run in Emacs when it is to operate as
  33 ;; a server for other processes.
  34
  35 ;; Load this library and do M-x server-edit to enable Emacs as a server.
  36 ;; Emacs opens up a socket for communication with clients.  If there are no
  37 ;; client buffers to edit, server-edit acts like (switch-to-buffer
  38 ;; (other-buffer))
  39
  40 ;; When some other program runs "the editor" to edit a file,
  41 ;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  42 ;; This program transmits the file names to Emacs through
  43 ;; the server subprocess, and Emacs visits them and lets you edit them.
  44
  45 ;; Note that any number of clients may dispatch files to Emacs to be edited.
  46
  47 ;; When you finish editing a Server buffer, again call server-edit
  48 ;; to mark that buffer as done for the client and switch to the next
  49 ;; Server buffer.  When all the buffers for a client have been edited
  50 ;; and exited with server-edit, the client "editor" will return
  51 ;; to the program that invoked it.
  52
  53 ;; Your editing commands and Emacs's display output go to and from
  54 ;; the terminal in the usual way.  Thus, server operation is possible
  55 ;; only when Emacs can talk to the terminal at the time you invoke
  56 ;; the client.  This is possible in four cases:
  57
  58 ;; 1. On a window system, where Emacs runs in one window and the
  59 ;; program that wants to use "the editor" runs in another.
  60
  61 ;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  62 ;; program that wants to use "the editor" runs on another.
  63
  64 ;; 3. When the program that wants to use "the editor" is running
  65 ;; as a subprocess of Emacs.
  66
  67 ;; 4. On a system with job control, when Emacs is suspended, the program
  68 ;; that wants to use "the editor" will stop and display
  69 ;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  70 ;; brought into the foreground for editing.  When done editing, Emacs is
  71 ;; suspended again, and the client program is brought into the foreground.
  72
  73 ;; The buffer local variable "server-buffer-clients" lists
  74 ;; the clients who are waiting for this buffer to be edited.
  75 ;; The global variable "server-clients" lists all the waiting clients,
  76 ;; and which files are yet to be edited for each.
  77
  78 ;;; Code:
  79
  80 (eval-when-compile (require 'cl))
  81
  82 (defgroup server nil
  83   "Emacs running as a server process."
  84   :group 'external)
  85
  86 (defcustom server-visit-hook nil
  87   "*Hook run when visiting a file for the Emacs server."
  88   :group 'server
  89   :type 'hook)
  90
  91 (defcustom server-switch-hook nil
  92   "*Hook run when switching to a buffer for the Emacs server."
  93   :group 'server
  94   :type 'hook)
  95
  96 (defcustom server-done-hook nil
  97   "*Hook run when done editing a buffer for the Emacs server."
  98   :group 'server
  99   :type 'hook)
 100
 101 (defvar server-process nil
 102   "The current server process.")
 103
 104 (defvar server-clients nil
 105   "List of current server clients.
 106 Each element is (PROC PROPERTIES...) where PROC is a process object,
 107 and PROPERTIES is an association list of client properties.")
 108
 109 (defvar server-buffer-clients nil
 110   "List of client ids for clients requesting editing of current buffer.")
 111 (make-variable-buffer-local 'server-buffer-clients)
 112 ;; Changing major modes should not erase this local.
 113 (put 'server-buffer-clients 'permanent-local t)
 114
 115 (defcustom server-window nil
 116   "*Specification of the window to use for selecting Emacs server buffers.
 117 If nil, use the selected window.
 118 If it is a function, it should take one argument (a buffer) and
 119 display and select it.  A common value is `pop-to-buffer'.
 120 If it is a window, use that.
 121 If it is a frame, use the frame's selected window.
 122
 123 It is not meaningful to set this to a specific frame or window with Custom.
 124 Only programs can do so."
 125   :group 'server
 126   :version "22.1"
 127   :type '(choice (const :tag "Use selected window"
 128                         :match (lambda (widget value)
 129                                  (not (functionp value)))
 130                         nil)
 131                  (function-item :tag "Use pop-to-buffer" pop-to-buffer)
 132                  (function :tag "Other function")))
 133
 134 (defcustom server-temp-file-regexp "^/tmp/Re\\|/draft$"
 135   "*Regexp matching names of temporary files.
 136 These are deleted and reused after each edit by the programs that
 137 invoke the Emacs server."
 138   :group 'server
 139   :type 'regexp)
 140
 141 (defcustom server-kill-new-buffers t
 142   "*Whether to kill buffers when done with them.
 143 If non-nil, kill a buffer unless it already existed before editing
 144 it with Emacs server.  If nil, kill only buffers as specified by
 145 `server-temp-file-regexp'.
 146 Please note that only buffers are killed that still have a client,
 147 i.e. buffers visited which \"emacsclient --no-wait\" are never killed in
 148 this way."
 149   :group 'server
 150   :type 'boolean
 151   :version "21.1")
 152
 153 (or (assq 'server-buffer-clients minor-mode-alist)
 154     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 155
 156 (defvar server-existing-buffer nil
 157   "Non-nil means the buffer existed before the server was asked to visit it.
 158 This means that the server should not kill the buffer when you say you
 159 are done with it in the server.")
 160 (make-variable-buffer-local 'server-existing-buffer)
 161
 162 (defvar server-name "server")
 163
 164 (defvar server-socket-dir nil
 165   "The directory in which to place the server socket.
 166 Initialized by `server-start'.")
 167
 168 (defun server-client (proc)
 169   "Return the Emacs client corresponding to PROC.
 170 PROC must be a process object.
 171 The car of the result is PROC; the cdr is an association list.
 172 See `server-client-get' and `server-client-set'."
 173   (assq proc server-clients))
 174
 175 (defun server-client-get (client property)
 176   "Get the value of PROPERTY in CLIENT.
 177 CLIENT may be a process object, or a client returned by `server-client'.
 178 Return nil if CLIENT has no such property."
 179   (or (listp client) (setq client (server-client client)))
 180   (cdr (assq property (cdr client))))
 181
 182 (defun server-client-set (client property value)
 183   "Set the PROPERTY to VALUE in CLIENT, and return VALUE.
 184 CLIENT may be a process object, or a client returned by `server-client'."
 185   (let (p proc)
 186     (if (listp client)
 187         (setq proc (car client))
 188       (setq proc client
 189             client (server-client client)))
 190     (setq p (assq property client))
 191     (cond
 192      (p (setcdr p value))
 193      (client (setcdr client (cons (cons property value) (cdr client))))
 194      (t (setq server-clients
 195               `((,proc (,property . ,value)) . ,server-clients))))
 196     value))
 197
 198 (defun server-clients-with (property value)
 199   "Return a list of clients with PROPERTY set to VALUE."
 200   (let (result)
 201     (dolist (client server-clients result)
 202       (when (equal value (server-client-get client property))
 203         (setq result (cons (car client) result))))))
 204
 205 (defun server-add-client (proc)
 206   "Create a client for process PROC, if it doesn't already have one.
 207 New clients have no properties."
 208   (unless (server-client proc)
 209     (setq server-clients (cons (cons proc nil)
 210                                server-clients))))
 211
 212 ;;;###autoload
 213 (defun server-getenv (variable &optional frame)
 214   "Get the value of VARIABLE in the client environment of frame FRAME.
 215 VARIABLE should be a string.  Value is nil if VARIABLE is undefined in
 216 the environment.  Otherwise, value is a string.
 217
 218 If FRAME is an emacsclient frame, then the variable is looked up
 219 in the environment of the emacsclient process; otherwise the
 220 function consults the environment of the Emacs process.
 221
 222 If FRAME is nil or missing, then the selected frame is used."
 223   (when (not frame) (setq frame (selected-frame)))
 224   (let ((client (frame-parameter frame 'client)) env)
 225     (if (null client)
 226         (getenv variable)
 227       (setq env (server-client-get client 'environment))
 228       (if (null env)
 229           (getenv variable)
 230         (cdr (assoc variable env))))))
 231
 232 (defmacro server-with-client-environment (client vars &rest body)
 233   "Evaluate BODY with environment variables VARS set to those of CLIENT.
 234 The environment variables are then restored to their previous values.
 235
 236 VARS should be a list of strings."
 237   (declare (indent 2))
 238   (let ((oldvalues (make-symbol "oldvalues"))
 239         (var (make-symbol "var"))
 240         (value (make-symbol "value"))
 241         (pair (make-symbol "pair")))
 242     `(let (,oldvalues)
 243        (dolist (,var (quote ,vars))
 244          (let ((,value (cdr (assoc ,var (server-client-get ,client 'environment)))))
 245            (setq ,oldvalues (cons (cons ,var (getenv ,var)) ,oldvalues))
 246            (setenv ,var ,value)))
 247        (unwind-protect
 248            (progn ,@body)
 249          (dolist (,pair ,oldvalues)
 250            (setenv (car ,pair) (cdr ,pair)))))))
 251
 252 (defun server-delete-client (client &optional noframe)
 253   "Delete CLIENT, including its buffers, devices and frames.
 254 If NOFRAME is non-nil, let the frames live.  (To be used from
 255 `delete-frame-functions'."
 256   ;; Force a new lookup of client (prevents infinite recursion).
 257   (setq client (server-client
 258                 (if (listp client) (car client) client)))
 259   (let ((proc (car client))
 260         (buffers (server-client-get client 'buffers)))
 261     (when client
 262       (setq server-clients (delq client server-clients))
 263
 264       (dolist (buf buffers)
 265         (when (buffer-live-p buf)
 266           (with-current-buffer buf
 267             ;; Remove PROC from the clients of each buffer.
 268             (setq server-buffer-clients (delq proc server-buffer-clients))
 269             ;; Kill the buffer if necessary.
 270             (when (and (null server-buffer-clients)
 271                        (or (and server-kill-new-buffers
 272                                 (not server-existing-buffer))
 273                            (server-temp-file-p)))
 274               (kill-buffer (current-buffer))))))
 275
 276       ;; Delete the client's tty.
 277       (let ((device (server-client-get client 'device)))
 278         (when (eq (display-live-p device) t)
 279           (delete-display device)))
 280
 281       ;; Delete the client's frames.
 282       (unless noframe
 283         (dolist (frame (frame-list))
 284           (if (and (frame-live-p frame)
 285                    (equal (car client) (frame-parameter frame 'client)))
 286               (delete-frame frame))))
 287
 288       ;; Delete the client's process.
 289       (if (eq (process-status (car client)) 'open)
 290           (delete-process (car client)))
 291
 292       (server-log "Deleted" proc))))
 293
 294 (defun server-log (string &optional client)
 295   "If a *server* buffer exists, write STRING to it for logging purposes.
 296 If CLIENT is non-nil, add a description of it to the logged
 297 message."
 298   (if (get-buffer "*server*")
 299       (with-current-buffer "*server*"
 300         (goto-char (point-max))
 301         (insert (current-time-string)
 302                 (cond
 303                  ((null client) " ")
 304                  ((listp client) (format " %s: " (car client)))
 305                  (t (format " %s: " client)))
 306                 string)
 307         (or (bolp) (newline)))))
 308
 309 (defun server-sentinel (proc msg)
 310   "The process sentinel for Emacs server connections."
 311   (server-log (format "Status changed to %s: %s" (process-status proc) msg) proc)
 312   (server-delete-client proc))
 313
 314 (defun server-handle-delete-frame (frame)
 315   "Delete the client connection when the emacsclient frame is deleted."
 316   (let ((proc (frame-parameter frame 'client)))
 317     (when (and (frame-live-p frame)
 318                proc
 319                (or (window-system frame)
 320                    ;; A terminal device must not yet be deleted if
 321                    ;; there are other frames on it.
 322                    (< 0 (let ((frame-num 0))
 323                           (mapc (lambda (f)
 324                                   (when (eq (frame-display f)
 325                                             (frame-display frame))
 326                                     (setq frame-num (1+ frame-num))))
 327                                 (frame-list))
 328                           frame-num))))
 329       (server-log (format "server-handle-delete-frame, frame %s" frame) proc)
 330       (server-delete-client proc 'noframe)))) ; Let delete-frame delete the frame later.
 331
 332 (defun server-handle-suspend-tty (device)
 333   "Notify the emacsclient process to suspend itself when its tty device is suspended."
 334   (dolist (proc (server-clients-with 'device device))
 335     (server-log (format "server-handle-suspend-tty, device %s" device) proc)
 336     (condition-case err
 337         (server-send-string proc "-suspend \n")
 338       (file-error (condition-case nil (server-delete-client proc) (error nil))))))
 339
 340 (defun server-unquote-arg (arg)
 341   "Remove &-quotation from ARG.
 342 See `server-quote-arg' and `server-process-filter'."
 343   (replace-regexp-in-string
 344    "&." (lambda (s)
 345           (case (aref s 1)
 346             (?& "&")
 347             (?- "-")
 348             (?n "\n")
 349             (t " ")))
 350    arg t t))
 351
 352 (defun server-quote-arg (arg)
 353   "In ARG, insert a & before each &, each space, each newline, and -.
 354 Change spaces to underscores, too, so that the return value never
 355 contains a space.
 356
 357 See `server-unquote-arg' and `server-process-filter'."
 358   (replace-regexp-in-string
 359    "[-&\n ]" (lambda (s)
 360                (case (aref s 0)
 361                  (?& "&&")
 362                  (?- "&-")
 363                  (?\n "&n")
 364                  (?\s "&_")))
 365    arg t t))
 366
 367 (defun server-send-string (proc string)
 368   "A wrapper around `proc-send-string' for logging."
 369   (server-log (concat "Sent " string) proc)
 370   (process-send-string proc string))
 371
 372 (defun server-ensure-safe-dir (dir)
 373   "Make sure DIR is a directory with no race-condition issues.
 374 Creates the directory if necessary and makes sure:
 375 - there's no symlink involved
 376 - it's owned by us
 377 - it's not readable/writable by anybody else."
 378   (setq dir (directory-file-name dir))
 379   (let ((attrs (file-attributes dir)))
 380     (unless attrs
 381       (letf (((default-file-modes) ?\700)) (make-directory dir))
 382       (setq attrs (file-attributes dir)))
 383     ;; Check that it's safe for use.
 384     (unless (and (eq t (car attrs)) (eq (nth 2 attrs) (user-uid))
 385                  (zerop (logand ?\077 (file-modes dir))))
 386       (error "The directory %s is unsafe" dir))))
 387
 388 ;;;###autoload
 389 (defun server-start (&optional leave-dead)
 390   "Allow this Emacs process to be a server for client processes.
 391 This starts a server communications subprocess through which
 392 client \"editors\" can send your editing commands to this Emacs
 393 job.  To use the server, set up the program `emacsclient' in the
 394 Emacs distribution as your standard \"editor\".
 395
 396 Prefix arg LEAVE-DEAD means just kill any existing server
 397 communications subprocess."
 398   (interactive "P")
 399   (when (or
 400          (not server-clients)
 401          (yes-or-no-p
 402           "The current server still has clients; delete them? "))
 403     ;; It is safe to get the user id now.
 404     (setq server-socket-dir (or server-socket-dir
 405                                 (format "/tmp/emacs%d" (user-uid))))
 406     ;; Make sure there is a safe directory in which to place the socket.
 407     (server-ensure-safe-dir server-socket-dir)
 408     ;; kill it dead!
 409     (if server-process
 410         (condition-case () (delete-process server-process) (error nil)))
 411     ;; Delete the socket files made by previous server invocations.
 412     (condition-case ()
 413         (delete-file (expand-file-name server-name server-socket-dir))
 414       (error nil))
 415     ;; If this Emacs already had a server, clear out associated status.
 416     (while server-clients
 417       (server-delete-client (car server-clients)))
 418     (if leave-dead
 419         (progn
 420           (server-log (message "Server stopped"))
 421           (setq server-process nil))
 422       (if server-process
 423           (server-log (message "Restarting server"))
 424         (server-log (message "Starting server")))
 425       (letf (((default-file-modes) ?\700))
 426         (add-hook 'suspend-tty-functions 'server-handle-suspend-tty)
 427         (add-hook 'delete-frame-functions 'server-handle-delete-frame)
 428         (add-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
 429         (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
 430         (setq server-process
 431               (make-network-process
 432                :name "server" :family 'local :server t :noquery t
 433                :service (expand-file-name server-name server-socket-dir)
 434                :sentinel 'server-sentinel :filter 'server-process-filter
 435                ;; We must receive file names without being decoded.
 436                ;; Those are decoded by server-process-filter according
 437                ;; to file-name-coding-system.
 438                :coding 'raw-text))))))
 439
 440 ;;;###autoload
 441 (define-minor-mode server-mode
 442   "Toggle Server mode.
 443 With ARG, turn Server mode on if ARG is positive, off otherwise.
 444 Server mode runs a process that accepts commands from the
 445 `emacsclient' program.  See `server-start' and Info node `Emacs server'."
 446   :global t
 447   :group 'server
 448   :version "22.1"
 449   ;; Fixme: Should this check for an existing server socket and do
 450   ;; nothing if there is one (for multiple Emacs sessions)?
 451   (server-start (not server-mode)))
 452 \f
 453 (defun server-process-filter (proc string)
 454   "Process a request from the server to edit some files.
 455 PROC is the server process.  STRING consists of a sequence of
 456 commands prefixed by a dash.  Some commands have arguments; these
 457 are &-quoted and need to be decoded by `server-unquote-arg'.  The
 458 filter parses and executes these commands.
 459
 460 To illustrate the protocol, here is an example command that
 461 emacsclient sends to create a new X frame (note that the whole
 462 sequence is sent on a single line):
 463
 464         -version 21.3.50 xterm
 465         -env HOME /home/lorentey
 466         -env DISPLAY :0.0
 467         ... lots of other -env commands
 468         -display :0.0
 469         -window-system
 470
 471 The server normally sends back the single command `-good-version'
 472 as a response.
 473
 474 The following commands are accepted by the server:
 475
 476 `-version CLIENT-VERSION'
 477   Check version numbers between server and client, and signal an
 478   error if there is a mismatch.  The server replies with
 479   `-good-version' to confirm the match.
 480
 481 `-env NAME VALUE'
 482   An environment variable on the client side.
 483
 484 `-current-frame'
 485   Forbid the creation of new frames.
 486
 487 `-nowait'
 488   Request that the next frame created should not be
 489   associated with this client.
 490
 491 `-display DISPLAY'
 492   Set the display name to open X frames on.
 493
 494 `-position LINE[:COLUMN]'
 495   Go to the given line and column number
 496   in the next file opened.
 497
 498 `-file FILENAME'
 499   Load the given file in the current frame.
 500
 501 `-eval EXPR'
 502   Evaluate EXPR as a Lisp expression and return the
 503   result in -print commands.
 504
 505 `-window-system'
 506   Open a new X frame.
 507
 508 `-tty DEVICENAME TYPE'
 509   Open a new tty frame at the client.
 510
 511 `-resume'
 512   Resume this tty frame. The client sends this string when it
 513   gets the SIGCONT signal and it is the foreground process on its
 514   controlling tty.
 515
 516 `-suspend'
 517   Suspend this tty frame.  The client sends this string in
 518   response to SIGTSTP and SIGTTOU.  The server must cease all I/O
 519   on this tty until it gets a -resume command.
 520
 521 `-ignore COMMENT'
 522   Do nothing, but put the comment in the server
 523   log.  Useful for debugging.
 524
 525
 526 The following commands are accepted by the client:
 527
 528 `-good-version'
 529   Signals a version match between the client and the server.
 530
 531 `-emacs-pid PID'
 532   Describes the process id of the Emacs process;
 533   used to forward window change signals to it.
 534
 535 `-window-system-unsupported'
 536   Signals that the server does not
 537   support creating X frames; the client must try again with a tty
 538   frame.
 539
 540 `-print STRING'
 541   Print STRING on stdout.  Used to send values
 542   returned by -eval.
 543
 544 `-error DESCRIPTION'
 545   Signal an error (but continue processing).
 546
 547 `-suspend'
 548   Suspend this terminal, i.e., stop the client process.  Sent
 549   when the user presses C-z."
 550   (server-log (concat "Received " string) proc)
 551   (let ((prev (process-get proc 'previous-string)))
 552     (when prev
 553       (setq string (concat prev string))
 554       (process-put proc 'previous-string nil)))
 555   (condition-case err
 556       (progn
 557         (server-add-client proc)
 558         ;; If the input is multiple lines,
 559         ;; process each line individually.
 560         (while (string-match "\n" string)
 561           (let ((request (substring string 0 (match-beginning 0)))
 562                 (coding-system (and default-enable-multibyte-characters
 563                                     (or file-name-coding-system
 564                                         default-file-name-coding-system)))
 565                 (client (server-client proc))
 566                 current-frame
 567                 nowait ; t if emacsclient does not want to wait for us.
 568                 frame ; The frame that was opened for the client (if any).
 569                 display ; Open the frame on this display.
 570                 dontkill       ; t if the client should not be killed.
 571                 (files nil)
 572                 (lineno 1)
 573                 (columnno 0))
 574             ;; Remove this line from STRING.
 575             (setq string (substring string (match-end 0)))
 576             (while (string-match " *[^ ]* " request)
 577               (let ((arg (substring request (match-beginning 0) (1- (match-end 0)))))
 578                 (setq request (substring request (match-end 0)))
 579                 (cond
 580                  ;; -version CLIENT-VERSION:
 581                  ;; Check version numbers, signal an error if there is a mismatch.
 582                  ((and (equal "-version" arg)
 583                        (string-match "\\([0-9.]+\\) " request))
 584                   (let* ((client-version (match-string 1 request))
 585                          (truncated-emacs-version
 586                           (substring emacs-version 0 (length client-version))))
 587                     (setq request (substring request (match-end 0)))
 588                     (if (equal client-version truncated-emacs-version)
 589                         (progn
 590                           (server-send-string proc "-good-version \n")
 591                           (server-client-set client 'version client-version))
 592                       (error (concat "Version mismatch: Emacs is "
 593                                      truncated-emacs-version
 594                                      ", emacsclient is " client-version)))))
 595
 596                  ;; -nowait:  Emacsclient won't wait for a result.
 597                  ((equal "-nowait" arg) (setq nowait t))
 598
 599                  ;; -current-frame:  Don't create frames.
 600                  ((equal "-current-frame" arg) (setq current-frame t))
 601
 602                  ;; -display DISPLAY:
 603                  ;; Open X frames on the given instead of the default.
 604                  ((and (equal "-display" arg) (string-match "\\([^ ]*\\) " request))
 605                   (setq display (match-string 1 request)
 606                         request (substring request (match-end 0))))
 607
 608                  ;; -window-system:  Open a new X frame.
 609                  ((equal "-window-system" arg)
 610                   (unless (server-client-get client 'version)
 611                     (error "Protocol error; make sure to use the correct version of emacsclient"))
 612                   (unless current-frame
 613                     (if (fboundp 'x-create-frame)
 614                         (let ((params (if nowait
 615                                           nil
 616                                         (list (cons 'client proc)))))
 617                           (setq frame (make-frame-on-display
 618                                        (or display
 619                                            (frame-parameter nil 'device)
 620                                            (getenv "DISPLAY")
 621                                            (error "Please specify display"))
 622                                        params))
 623                           (server-log (format "%s created" frame) proc)
 624                           ;; XXX We need to ensure the parameters are
 625                           ;; really set because Emacs forgets unhandled
 626                           ;; initialization parameters for X frames at
 627                           ;; the moment.
 628                           (modify-frame-parameters frame params)
 629                           (select-frame frame)
 630                           (server-client-set client 'frame frame)
 631                           (server-client-set client 'device (frame-display frame))
 632                           (setq dontkill t))
 633                       ;; This emacs does not support X.
 634                       (server-log "Window system unsupported" proc)
 635                       (server-send-string proc "-window-system-unsupported \n")
 636                       (setq dontkill t))))
 637
 638                  ;; -resume:  Resume a suspended tty frame.
 639                  ((equal "-resume" arg)
 640                   (let ((device (server-client-get client 'device)))
 641                     (setq dontkill t)
 642                     (when (eq (display-live-p device) t)
 643                       (resume-tty device))))
 644
 645                  ;; -suspend:  Suspend the client's frame.  (In case we
 646                  ;; get out of sync, and a C-z sends a SIGTSTP to
 647                  ;; emacsclient.)
 648                  ((equal "-suspend" arg)
 649                   (let ((device (server-client-get client 'device)))
 650                     (setq dontkill t)
 651                     (when (eq (display-live-p device) t)
 652                       (suspend-tty device))))
 653
 654                  ;; -ignore COMMENT:  Noop; useful for debugging emacsclient.
 655                  ;; (The given comment appears in the server log.)
 656                  ((and (equal "-ignore" arg) (string-match "\\([^ ]*\\) " request))
 657                   (setq dontkill t
 658                         request (substring request (match-end 0))))
 659
 660                  ;; -tty DEVICE-NAME TYPE:  Open a new tty frame at the client.
 661                  ((and (equal "-tty" arg) (string-match "\\([^ ]*\\) \\([^ ]*\\) " request))
 662                   (let ((tty (server-unquote-arg (match-string 1 request)))
 663                         (type (server-unquote-arg (match-string 2 request))))
 664                     (setq request (substring request (match-end 0)))
 665                     (unless (server-client-get client 'version)
 666                       (error "Protocol error; make sure you use the correct version of emacsclient"))
 667                     (unless current-frame
 668                       (server-with-client-environment proc
 669                           ("LANG" "LC_CTYPE" "LC_ALL"
 670                            ;; For tgetent(3); list according to ncurses(3).
 671                            "BAUDRATE" "COLUMNS" "ESCDELAY" "HOME" "LINES"
 672                            "NCURSES_ASSUMED_COLORS" "NCURSES_NO_PADDING"
 673                            "NCURSES_NO_SETBUF" "TERM" "TERMCAP" "TERMINFO"
 674                            "TERMINFO_DIRS" "TERMPATH")
 675                         (setq frame (make-frame-on-tty tty type
 676                                                        ;; Ignore nowait here; we always need to clean
 677                                                        ;; up opened ttys when the client dies.
 678                                                        `((client . ,proc)))))
 679                       (select-frame frame)
 680                       (server-client-set client 'frame frame)
 681                       (server-client-set client 'tty (display-name frame))
 682                       (server-client-set client 'device (frame-display frame))
 683
 684                       ;; Reply with our pid.
 685                       (server-send-string proc (concat "-emacs-pid " (number-to-string (emacs-pid)) "\n"))
 686                       (setq dontkill t))))
 687
 688                  ;; -position LINE:  Go to the given line in the next file.
 689                  ((and (equal "-position" arg) (string-match "\\(\\+[0-9]+\\) " request))
 690                   (setq request (substring request (match-end 0))
 691                         lineno (string-to-number (substring (match-string 1 request) 1))))
 692
 693                  ;; -position LINE:COLUMN:  Set point to the given position in the next file.
 694                  ((and (equal "-position" arg) (string-match "\\+\\([0-9]+\\):\\([0-9]+\\) " request))
 695                   (setq lineno (string-to-number (match-string 1 request))
 696                         columnno (string-to-number (match-string 2 request))
 697                         request (substring request (match-end 0))))
 698
 699                  ;; -file FILENAME:  Load the given file.
 700                  ((and (equal "-file" arg) (string-match "\\([^ ]+\\) " request))
 701                   (let ((file (server-unquote-arg (match-string 1 request))))
 702                     (setq request (substring request (match-end 0)))
 703                     (if coding-system
 704                         (setq file (decode-coding-string file coding-system)))
 705                     (setq file (command-line-normalize-file-name file))
 706                     (push (list file lineno columnno) files))
 707                   (setq lineno 1
 708                         columnno 0))
 709
 710                  ;; -eval EXPR:  Evaluate a Lisp expression.
 711                  ((and (equal "-eval" arg) (string-match "\\([^ ]+\\) " request))
 712                   (let ((expr (server-unquote-arg (match-string 1 request))))
 713                     (setq request (substring request (match-end 0)))
 714                     (if coding-system
 715                         (setq expr (decode-coding-string expr coding-system)))
 716                     (let ((v (eval (car (read-from-string expr)))))
 717                       (when (and (not frame) v)
 718                         (with-temp-buffer
 719                           (let ((standard-output (current-buffer)))
 720                             (pp v)
 721                             (server-send-string
 722                              proc (format "-print %s\n"
 723                                           (server-quote-arg
 724                                            (buffer-substring-no-properties (point-min)
 725                                                                            (point-max)))))))))
 726                     (setq lineno 1
 727                           columnno 0)))
 728
 729                  ;; -env NAME VALUE:  An environment variable.
 730                  ((and (equal "-env" arg) (string-match "\\([^ ]+\\) \\([^ ]+\\) " request))
 731                   (let ((name (server-unquote-arg (match-string 1 request)))
 732                         (value (server-unquote-arg (match-string 2 request))))
 733                     (when coding-system
 734                         (setq name (decode-coding-string name coding-system))
 735                         (setq value (decode-coding-string value coding-system)))
 736                     (setq request (substring request (match-end 0)))
 737                     (server-client-set
 738                      client 'environment
 739                      (cons (cons name value)
 740                            (server-client-get client 'environment)))))
 741
 742                  ;; Unknown command.
 743                  (t (error "Unknown command: %s" arg)))))
 744
 745             (let (buffers)
 746               (when files
 747                 (run-hooks 'pre-command-hook)
 748                 (setq buffers (server-visit-files files client nowait))
 749                 (run-hooks 'post-command-hook))
 750
 751               ;; Delete the client if necessary.
 752               (cond
 753                (nowait
 754                 ;; Client requested nowait; return immediately.
 755                 (server-log "Close nowait client" proc)
 756                 (server-delete-client proc))
 757                ((and (not dontkill) (null buffers))
 758                 ;; This client is empty; get rid of it immediately.
 759                 (server-log "Close empty client" proc)
 760                 (server-delete-client proc)))
 761               (cond
 762                ((or isearch-mode (minibufferp))
 763                 nil)
 764                ((and frame (null buffers))
 765                 (message (substitute-command-keys
 766                           "When done with this frame, type \\[delete-frame]")))
 767                ((not (null buffers))
 768                 (server-switch-buffer (car buffers))
 769                 (run-hooks 'server-switch-hook)
 770                 (unless nowait
 771                   (message (substitute-command-keys
 772                             "When done with a buffer, type \\[server-edit]"))))))))
 773
 774         ;; Save for later any partial line that remains.
 775         (when (> (length string) 0)
 776           (process-put proc 'previous-string string)))
 777     ;; condition-case
 778     (error (ignore-errors
 779              (server-send-string
 780               proc (concat "-error " (server-quote-arg (error-message-string err))))
 781              (setq string "")
 782              (server-log (error-message-string err) proc)
 783              (delete-process proc)))))
 784
 785 (defun server-goto-line-column (file-line-col)
 786   "Move point to the position indicated in FILE-LINE-COL.
 787 FILE-LINE-COL should be a three-element list as described in
 788 `server-visit-files'."
 789   (goto-line (nth 1 file-line-col))
 790   (let ((column-number (nth 2 file-line-col)))
 791     (if (> column-number 0)
 792         (move-to-column (1- column-number)))))
 793
 794 (defun server-visit-files (files client &optional nowait)
 795   "Find FILES and return a list of buffers created.
 796 FILES is an alist whose elements are (FILENAME LINENUMBER COLUMNNUMBER).
 797 CLIENT is the client that requested this operation.
 798 NOWAIT non-nil means this client is not waiting for the results,
 799 so don't mark these buffers specially, just visit them normally."
 800   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
 801   (let ((last-nonmenu-event t) client-record)
 802     ;; Restore the current buffer afterward, but not using save-excursion,
 803     ;; because we don't want to save point in this buffer
 804     ;; if it happens to be one of those specified by the server.
 805     (save-current-buffer
 806       (dolist (file files)
 807         ;; If there is an existing buffer modified or the file is
 808         ;; modified, revert it.  If there is an existing buffer with
 809         ;; deleted file, offer to write it.
 810         (let* ((filen (car file))
 811                (obuf (get-file-buffer filen)))
 812           (push filen file-name-history)
 813           (if (and obuf (set-buffer obuf))
 814               (progn
 815                 (cond ((file-exists-p filen)
 816                        (if (not (verify-visited-file-modtime obuf))
 817                            (revert-buffer t nil)))
 818                       (t
 819                        (if (y-or-n-p
 820                             (concat "File no longer exists: " filen
 821                                     ", write buffer to file? "))
 822                            (write-file filen))))
 823                 (setq server-existing-buffer t)
 824                 (server-goto-line-column file))
 825             (set-buffer (find-file-noselect filen))
 826             (server-goto-line-column file)
 827             (run-hooks 'server-visit-hook)))
 828         (unless nowait
 829           ;; When the buffer is killed, inform the clients.
 830           (add-hook 'kill-buffer-hook 'server-kill-buffer nil t)
 831           (push (car client) server-buffer-clients))
 832         (push (current-buffer) client-record)))
 833     (unless nowait
 834       (server-client-set
 835        client 'buffers
 836        (nconc (server-client-get client 'buffers) client-record)))
 837     client-record))
 838 \f
 839 (defun server-buffer-done (buffer &optional for-killing)
 840   "Mark BUFFER as \"done\" for its client(s).
 841 This buries the buffer, then returns a list of the form (NEXT-BUFFER KILLED).
 842 NEXT-BUFFER is another server buffer, as a suggestion for what to select next,
 843 or nil.  KILLED is t if we killed BUFFER (typically, because it was visiting
 844 a temp file).
 845 FOR-KILLING if non-nil indicates that we are called from `kill-buffer'."
 846   (let ((next-buffer nil)
 847         (killed nil))
 848     (dolist (client server-clients)
 849       (let ((buffers (server-client-get client 'buffers)))
 850         (or next-buffer
 851             (setq next-buffer (nth 1 (memq buffer buffers))))
 852         (when buffers                   ; Ignore bufferless clients.
 853           (setq buffers (delq buffer buffers))
 854           ;; Delete all dead buffers from CLIENT.
 855           (dolist (b buffers)
 856             (and (bufferp b)
 857                  (not (buffer-live-p b))
 858                  (setq buffers (delq b buffers))))
 859           (server-client-set client 'buffers buffers)
 860           ;; If client now has no pending buffers,
 861           ;; tell it that it is done, and forget it entirely.
 862           (unless buffers
 863             (server-log "Close" client)
 864             (server-delete-client client)))))
 865     (if (and (bufferp buffer) (buffer-name buffer))
 866         ;; We may or may not kill this buffer;
 867         ;; if we do, do not call server-buffer-done recursively
 868         ;; from kill-buffer-hook.
 869         (let ((server-kill-buffer-running t))
 870           (with-current-buffer buffer
 871             (setq server-buffer-clients nil)
 872             (run-hooks 'server-done-hook))
 873           ;; Notice whether server-done-hook killed the buffer.
 874           (if (null (buffer-name buffer))
 875               (setq killed t)
 876             ;; Don't bother killing or burying the buffer
 877             ;; when we are called from kill-buffer.
 878             (unless for-killing
 879               (when (and (not killed)
 880                          server-kill-new-buffers
 881                          (with-current-buffer buffer
 882                            (not server-existing-buffer)))
 883                 (setq killed t)
 884                 (bury-buffer buffer)
 885                 (kill-buffer buffer))
 886               (unless killed
 887                 (if (server-temp-file-p buffer)
 888                     (progn
 889                       (kill-buffer buffer)
 890                       (setq killed t))
 891                   (bury-buffer buffer)))))))
 892     (list next-buffer killed)))
 893
 894 (defun server-temp-file-p (&optional buffer)
 895   "Return non-nil if BUFFER contains a file considered temporary.
 896 These are files whose names suggest they are repeatedly
 897 reused to pass information to another program.
 898
 899 The variable `server-temp-file-regexp' controls which filenames
 900 are considered temporary."
 901   (and (buffer-file-name buffer)
 902        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 903
 904 (defun server-done ()
 905   "Offer to save current buffer, mark it as \"done\" for clients.
 906 This kills or buries the buffer, then returns a list
 907 of the form (NEXT-BUFFER KILLED).  NEXT-BUFFER is another server buffer,
 908 as a suggestion for what to select next, or nil.
 909 KILLED is t if we killed BUFFER, which happens if it was created
 910 specifically for the clients and did not exist before their request for it."
 911   (when server-buffer-clients
 912     (if (server-temp-file-p)
 913         ;; For a temp file, save, and do make a non-numeric backup
 914         ;; (unless make-backup-files is nil).
 915         (let ((version-control nil)
 916               (buffer-backed-up nil))
 917           (save-buffer))
 918       (if (and (buffer-modified-p)
 919                buffer-file-name
 920                (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 921           (save-buffer)))
 922     (server-buffer-done (current-buffer))))
 923
 924 ;; Ask before killing a server buffer.
 925 ;; It was suggested to release its client instead,
 926 ;; but I think that is dangerous--the client would proceed
 927 ;; using whatever is on disk in that file. -- rms.
 928 (defun server-kill-buffer-query-function ()
 929   "Ask before killing a server buffer."
 930   (or (not server-buffer-clients)
 931       (let ((res t))
 932         (dolist (proc server-buffer-clients res)
 933           (let ((client (server-client proc)))
 934             (when (and client (eq (process-status proc) 'open))
 935               (setq res nil)))))
 936       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
 937                            (buffer-name (current-buffer))))))
 938
 939 (defun server-kill-emacs-query-function ()
 940   "Ask before exiting Emacs it has live clients."
 941   (or (not server-clients)
 942       (let (live-client)
 943         (dolist (client server-clients live-client)
 944           (if (memq t (mapcar 'buffer-live-p (server-client-get
 945                                               client 'buffers)))
 946               (setq live-client t))))
 947       (yes-or-no-p "This Emacs session has clients; exit anyway? ")))
 948
 949 (defvar server-kill-buffer-running nil
 950   "Non-nil while `server-kill-buffer' or `server-buffer-done' is running.")
 951
 952 (defun server-kill-buffer ()
 953   "Remove the current buffer from its clients' buffer list.
 954 Designed to be added to `kill-buffer-hook'."
 955   ;; Prevent infinite recursion if user has made server-done-hook
 956   ;; call kill-buffer.
 957   (or server-kill-buffer-running
 958       (and server-buffer-clients
 959            (let ((server-kill-buffer-running t))
 960              (when server-process
 961                (server-buffer-done (current-buffer) t))))))
 962 \f
 963 (defun server-edit (&optional arg)
 964   "Switch to next server editing buffer; say \"Done\" for current buffer.
 965 If a server buffer is current, it is marked \"done\" and optionally saved.
 966 The buffer is also killed if it did not exist before the clients asked for it.
 967 When all of a client's buffers are marked as \"done\", the client is notified.
 968
 969 Temporary files such as MH <draft> files are always saved and backed up,
 970 no questions asked.  (The variable `make-backup-files', if nil, still
 971 inhibits a backup; you can set it locally in a particular buffer to
 972 prevent a backup for it.)  The variable `server-temp-file-regexp' controls
 973 which filenames are considered temporary.
 974
 975 If invoked with a prefix argument, or if there is no server process running,
 976 starts server process and that is all.  Invoked by \\[server-edit]."
 977   (interactive "P")
 978   (if (or arg
 979           (not server-process)
 980           (memq (process-status server-process) '(signal exit)))
 981       (server-start nil)
 982     (apply 'server-switch-buffer (server-done))))
 983
 984 (defun server-switch-buffer (&optional next-buffer killed-one)
 985   "Switch to another buffer, preferably one that has a client.
 986 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it.
 987
 988 KILLED-ONE is t in a recursive call if we have already killed one
 989 temp-file server buffer.  This means we should avoid the final
 990 \"switch to some other buffer\" since we've already effectively
 991 done that."
 992   (if (null next-buffer)
 993       (progn
 994         (let ((rest server-clients))
 995           (while (and rest (not next-buffer))
 996             (let ((client (car rest)))
 997               ;; Only look at frameless clients.
 998               (when (not (server-client-get client 'frame))
 999                 (setq next-buffer (car (server-client-get client 'buffers))))
1000               (setq rest (cdr rest)))))
1001         (and next-buffer (server-switch-buffer next-buffer killed-one))
1002         (unless (or next-buffer killed-one (window-dedicated-p (selected-window)))
1003           ;; (switch-to-buffer (other-buffer))
1004           (message "No server buffers remain to edit")))
1005     (if (not (buffer-live-p next-buffer))
1006         ;; If NEXT-BUFFER is a dead buffer, remove the server records for it
1007         ;; and try the next surviving server buffer.
1008         (apply 'server-switch-buffer (server-buffer-done next-buffer))
1009       ;; OK, we know next-buffer is live, let's display and select it.
1010       (if (functionp server-window)
1011           (funcall server-window next-buffer)
1012         (let ((win (get-buffer-window next-buffer 0)))
1013           (if (and win (not server-window))
1014               ;; The buffer is already displayed: just reuse the window.
1015               (let ((frame (window-frame win)))
1016                 (if (eq (frame-visible-p frame) 'icon)
1017                     (raise-frame frame))
1018                 (select-window win)
1019                 (set-buffer next-buffer))
1020             ;; Otherwise, let's find an appropriate window.
1021             (cond ((and (windowp server-window)
1022                         (window-live-p server-window))
1023                    (select-window server-window))
1024                   ((framep server-window)
1025                    (if (not (frame-live-p server-window))
1026                        (setq server-window (make-frame)))
1027                    (select-window (frame-selected-window server-window))))
1028             (if (window-minibuffer-p (selected-window))
1029                 (select-window (next-window nil 'nomini 0)))
1030             ;; Move to a non-dedicated window, if we have one.
1031             (when (window-dedicated-p (selected-window))
1032               (select-window
1033                (get-window-with-predicate
1034                 (lambda (w)
1035                   (and (not (window-dedicated-p w))
1036                        (equal (frame-parameter (window-frame w) 'device)
1037                               (frame-parameter (selected-frame) 'device))))
1038                 'nomini 'visible (selected-window))))
1039             (condition-case nil
1040                 (switch-to-buffer next-buffer)
1041               ;; After all the above, we might still have ended up with
1042               ;; a minibuffer/dedicated-window (if there's no other).
1043               (error (pop-to-buffer next-buffer)))))))))
1044
1045 (defun server-save-buffers-kill-display (&optional arg)
1046   "Offer to save each buffer, then kill the current connection.
1047 If the current frame has no client, kill Emacs itself.
1048
1049 With prefix arg, silently save all file-visiting buffers, then kill.
1050
1051 If emacsclient was started with a list of filenames to edit, then
1052 only these files will be asked to be saved."
1053   (interactive "P")
1054   (let ((proc (frame-parameter (selected-frame) 'client)))
1055     (if proc
1056         (let ((buffers (server-client-get proc 'buffers)))
1057           ;; If client is bufferless, emulate a normal Emacs session
1058           ;; exit and offer to save all buffers.  Otherwise, offer to
1059           ;; save only the buffers belonging to the client.
1060           (save-some-buffers arg
1061                              (if buffers
1062                                  (lambda () (memq (current-buffer) buffers))
1063                                t))
1064           (server-delete-client proc))
1065       (save-buffers-kill-emacs))))
1066
1067 (define-key ctl-x-map "#" 'server-edit)
1068
1069 (defun server-unload-hook ()
1070   "Unload the server library."
1071   (server-start t)
1072   (remove-hook 'suspend-tty-functions 'server-handle-suspend-tty)
1073   (remove-hook 'delete-frame-functions 'server-handle-delete-frame)
1074   (remove-hook 'kill-buffer-query-functions 'server-kill-buffer-query-function)
1075   (remove-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
1076   (remove-hook 'kill-buffer-hook 'server-kill-buffer))
1077
1078 (add-hook 'server-unload-hook 'server-unload-hook)
1079 \f
1080 (provide 'server)
1081
1082 ;;; arch-tag: 1f7ecb42-f00a-49f8-906d-61995d84c8d6
1083 ;;; server.el ends here