lisp/imenu.el

   1 ;;; imenu.el --- framework for mode-specific buffer indexes
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Ake Stenhoff <etxaksf@aom.ericsson.se>
   7 ;;         Lars Lindberg <lli@sypro.cap.se>
   8 ;; Maintainer: FSF
   9 ;; Created: 8 Feb 1994
  10 ;; Keywords: tools convenience
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Purpose of this package:
  30 ;;   To present a framework for mode-specific buffer indexes.
  31 ;;   A buffer index is an alist of names and buffer positions.
  32 ;;   For instance all functions in a C-file and their positions.
  33 ;;
  34 ;;   It is documented in the Emacs Lisp manual.
  35 ;;
  36 ;; How it works:
  37
  38 ;;   A mode-specific function is called to generate the index.  It is
  39 ;;   then presented to the user, who can choose from this index.
  40 ;;
  41 ;;   The package comes with a set of example functions for how to
  42 ;;   utilize this package.
  43
  44 ;;   There are *examples* for index gathering functions/regular
  45 ;;   expressions for C/C++ and Lisp/Emacs Lisp but it is easy to
  46 ;;   customize for other modes.  A function for jumping to the chosen
  47 ;;   index position is also supplied.
  48
  49 ;;; History:
  50 ;;  Thanks go to
  51 ;;  [simon] - Simon Leinen simon@lia.di.epfl.ch
  52 ;;  [dean] - Dean Andrews ada@unison.com
  53 ;;  [alon] - Alon Albert al@mercury.co.il
  54 ;;  [greg] - Greg Thompson gregt@porsche.visix.COM
  55 ;;  [wolfgang] - Wolfgang Bangerth zcg51122@rpool1.rus.uni-stuttgart.de
  56 ;;  [kai] - Kai Grossjohann grossjoh@linus.informatik.uni-dortmund.de
  57 ;;  [david] - David M. Smith dsmith@stats.adelaide.edu.au
  58 ;;  [christian] - Christian Egli Christian.Egli@hcsd.hac.com
  59 ;;  [karl] - Karl Fogel kfogel@floss.life.uiuc.edu
  60
  61 ;;; Code:
  62
  63 (eval-when-compile (require 'cl))
  64
  65 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  66 ;;;
  67 ;;; Customizable variables
  68 ;;;
  69 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  70
  71 (defgroup imenu nil
  72   "Mode-specific buffer indexes."
  73   :group 'matching
  74   :group 'frames
  75   :group 'convenience
  76   :link '(custom-manual "(elisp)Imenu"))
  77
  78 (defcustom imenu-use-markers t
  79   "Non-nil means use markers instead of integers for Imenu buffer positions.
  80
  81 Setting this to nil makes Imenu work a little faster but editing the
  82 buffer will make the generated index positions wrong.
  83
  84 This might not yet be honored by all index-building functions."
  85   :type 'boolean
  86   :group 'imenu)
  87
  88
  89 (defcustom imenu-max-item-length 60
  90   "If a number, truncate Imenu entries to that length."
  91   :type '(choice integer
  92                  (const :tag "Unlimited"))
  93   :group 'imenu)
  94
  95 (defcustom imenu-auto-rescan nil
  96   "Non-nil means Imenu should always rescan the buffers."
  97   :type 'boolean
  98   :group 'imenu)
  99
 100 (defcustom imenu-auto-rescan-maxout 60000
 101   "Imenu auto-rescan is disabled in buffers larger than this size (in bytes).
 102 This variable is buffer-local."
 103   :type 'integer
 104   :group 'imenu)
 105
 106 (defvar imenu-always-use-completion-buffer-p nil)
 107 (make-obsolete-variable 'imenu-always-use-completion-buffer-p
 108                         'imenu-use-popup-menu "22.1")
 109
 110 (defcustom imenu-use-popup-menu
 111   (if imenu-always-use-completion-buffer-p
 112       (not (eq imenu-always-use-completion-buffer-p 'never))
 113     'on-mouse)
 114   "Use a popup menu rather than a minibuffer prompt.
 115 If nil, always use a minibuffer prompt.
 116 If t, always use a popup menu,
 117 If `on-mouse' use a popup menu when `imenu' was invoked with the mouse."
 118   :type '(choice (const :tag "On Mouse" on-mouse)
 119                  (const :tag "Never" nil)
 120                  (other :tag "Always" t))
 121   :group 'imenu)
 122
 123 (defcustom imenu-eager-completion-buffer
 124   (not (eq imenu-always-use-completion-buffer-p 'never))
 125   "If non-nil, eagerly popup the completion buffer."
 126   :type 'boolean
 127   :group 'imenu
 128   :version "22.1")
 129
 130 (defcustom imenu-after-jump-hook nil
 131   "Hooks called after jumping to a place in the buffer.
 132
 133 Useful things to use here include `reposition-window', `recenter', and
 134 \(lambda () (recenter 0)) to show at top of screen."
 135   :type 'hook
 136   :group 'imenu)
 137
 138 ;;;###autoload
 139 (defcustom imenu-sort-function nil
 140   "The function to use for sorting the index mouse-menu.
 141
 142 Affects only the mouse index menu.
 143
 144 Set this to nil if you don't want any sorting (faster).
 145 The items in the menu are then presented in the order they were found
 146 in the buffer.
 147
 148 Set it to `imenu--sort-by-name' if you want alphabetic sorting.
 149
 150 The function should take two arguments and return t if the first
 151 element should come before the second.  The arguments are cons cells;
 152 \(NAME . POSITION).  Look at `imenu--sort-by-name' for an example."
 153   :type '(choice (const :tag "No sorting" nil)
 154                  (const :tag "Sort by name" imenu--sort-by-name)
 155                  (function :tag "Another function"))
 156   :group 'imenu)
 157
 158 (defcustom imenu-max-items 25
 159   "Maximum number of elements in a mouse menu for Imenu."
 160   :type 'integer
 161   :group 'imenu)
 162
 163 ;; No longer used.  KFS 2004-10-27
 164 ;; (defcustom imenu-scanning-message "Scanning buffer for index (%3d%%)"
 165 ;;   "*Progress message during the index scanning of the buffer.
 166 ;; If non-nil, user gets a message during the scanning of the buffer.
 167 ;;
 168 ;; Relevant only if the mode-specific function that creates the buffer
 169 ;; index use `imenu-progress-message', and not useful if that is fast, in
 170 ;; which case you might as well set this to nil."
 171 ;;   :type '(choice string
 172 ;;               (const :tag "None" nil))
 173 ;;   :group 'imenu)
 174
 175 (defcustom imenu-space-replacement "."
 176   "The replacement string for spaces in index names.
 177 Used when presenting the index in a completion buffer to make the
 178 names work as tokens."
 179   :type '(choice string (const nil))
 180   :group 'imenu)
 181
 182 (defcustom imenu-level-separator ":"
 183   "The separator between index names of different levels.
 184 Used for making mouse-menu titles and for flattening nested indexes
 185 with name concatenation."
 186   :type 'string
 187   :group 'imenu)
 188
 189 ;;;###autoload
 190 (defvar imenu-generic-expression nil
 191   "The regex pattern to use for creating a buffer index.
 192
 193 If non-nil this pattern is passed to `imenu--generic-function' to
 194 create a buffer index.  Look there for the documentation of this
 195 pattern's structure.
 196
 197 For example, see the value of `fortran-imenu-generic-expression' used by
 198 `fortran-mode' with `imenu-syntax-alist' set locally to give the
 199 characters which normally have \"symbol\" syntax \"word\" syntax
 200 during matching.")
 201
 202 ;;;###autoload
 203 (make-variable-buffer-local 'imenu-generic-expression)
 204
 205 ;;;; Hooks
 206
 207 ;;;###autoload
 208 (defvar imenu-create-index-function 'imenu-default-create-index-function
 209   "The function to use for creating an index alist of the current buffer.
 210
 211 It should be a function that takes no arguments and returns
 212 an index alist of the current buffer.  The function is
 213 called within a `save-excursion'.
 214
 215 See `imenu--index-alist' for the format of the buffer index alist.")
 216 ;;;###autoload
 217 (make-variable-buffer-local 'imenu-create-index-function)
 218
 219 ;;;###autoload
 220 (defvar imenu-prev-index-position-function 'beginning-of-defun
 221   "Function for finding the next index position.
 222
 223 If `imenu-create-index-function' is set to
 224 `imenu-default-create-index-function', then you must set this variable
 225 to a function that will find the next index, looking backwards in the
 226 file.
 227
 228 The function should leave point at the place to be connected to the
 229 index and it should return nil when it doesn't find another index.")
 230 ;;;###autoload
 231 (make-variable-buffer-local 'imenu-prev-index-position-function)
 232
 233 ;;;###autoload
 234 (defvar imenu-extract-index-name-function nil
 235   "Function for extracting the index item name, given a position.
 236
 237 This function is called after `imenu-prev-index-position-function'
 238 finds a position for an index item, with point at that position.
 239 It should return the name for that index item.")
 240 ;;;###autoload
 241 (make-variable-buffer-local 'imenu-extract-index-name-function)
 242
 243 ;;;###autoload
 244 (defvar imenu-name-lookup-function nil
 245   "Function to compare string with index item.
 246
 247 This function will be called with two strings, and should return
 248 non-nil if they match.
 249
 250 If nil, comparison is done with `string='.
 251 Set this to some other function for more advanced comparisons,
 252 such as \"begins with\" or \"name matches and number of
 253 arguments match\".")
 254 ;;;###autoload
 255 (make-variable-buffer-local 'imenu-name-lookup-function)
 256
 257 ;;;###autoload
 258 (defvar imenu-default-goto-function 'imenu-default-goto-function
 259   "The default function called when selecting an Imenu item.
 260 The function in this variable is called when selecting a normal index-item.")
 261 ;;;###autoload
 262 (make-variable-buffer-local 'imenu-default-goto-function)
 263
 264
 265 (defun imenu--subalist-p (item)
 266   (and (consp (cdr item)) (listp (cadr item))
 267        (not (eq (car (cadr item)) 'lambda))))
 268
 269 ;; Macro to display a progress message.
 270 ;; RELPOS is the relative position to display.
 271 ;; If RELPOS is nil, then the relative position in the buffer
 272 ;; is calculated.
 273 ;; PREVPOS is the variable in which we store the last position displayed.
 274 (defmacro imenu-progress-message (prevpos &optional relpos reverse)
 275
 276 ;; Made obsolete/empty, as computers are now faster than the eye, and
 277 ;; it had problems updating the messages correctly, and could shadow
 278 ;; more important messages/prompts in the minibuffer.  KFS 2004-10-27.
 279
 280 ;;  `(and
 281 ;;    imenu-scanning-message
 282 ;;    (let ((pos ,(if relpos
 283 ;;                  relpos
 284 ;;                `(imenu--relative-position ,reverse))))
 285 ;;      (if ,(if relpos t
 286 ;;           `(> pos (+ 5 ,prevpos)))
 287 ;;        (progn
 288 ;;          (message imenu-scanning-message pos)
 289 ;;          (setq ,prevpos pos)))))
 290 )
 291
 292
 293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 294 ;;;;
 295 ;;;; Some examples of functions utilizing the framework of this
 296 ;;;; package.
 297 ;;;;
 298 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 299
 300 ;; FIXME: This is the only imenu-example-* definition that's actually used,
 301 ;; and it seems to only be used by cperl-mode.el.  We should just move it to
 302 ;; cperl-mode.el and remove the rest.
 303 (defun imenu-example--name-and-position ()
 304   "Return the current/previous sexp and its (beginning) location.
 305 Don't move point."
 306   (save-excursion
 307     (forward-sexp -1)
 308     ;; [ydi] modified for imenu-use-markers
 309     (let ((beg (if imenu-use-markers (point-marker) (point)))
 310           (end (progn (forward-sexp) (point))))
 311       (cons (buffer-substring beg end)
 312             beg))))
 313
 314 ;;;
 315 ;;; Lisp
 316 ;;;
 317
 318 (defun imenu-example--lisp-extract-index-name ()
 319   ;; Example of a candidate for `imenu-extract-index-name-function'.
 320   ;; This will generate a flat index of definitions in a lisp file.
 321   (save-match-data
 322     (and (looking-at "(def")
 323          (condition-case nil
 324              (progn
 325                (down-list 1)
 326                (forward-sexp 2)
 327                (let ((beg (point))
 328                      (end (progn (forward-sexp -1) (point))))
 329                  (buffer-substring beg end)))
 330            (error nil)))))
 331
 332 (defun imenu-example--create-lisp-index ()
 333   ;; Example of a candidate for `imenu-create-index-function'.
 334   ;; It will generate a nested index of definitions.
 335   (let ((index-alist '())
 336         (index-var-alist '())
 337         (index-type-alist '())
 338         (index-unknown-alist '())
 339         prev-pos)
 340     (goto-char (point-max))
 341     (imenu-progress-message prev-pos 0)
 342     ;; Search for the function
 343     (while (beginning-of-defun)
 344       (imenu-progress-message prev-pos nil t)
 345           (save-match-data
 346             (and (looking-at "(def")
 347                  (save-excursion
 348                (down-list 1)
 349                    (cond
 350                 ((looking-at "def\\(var\\|const\\)")
 351                      (forward-sexp 2)
 352                      (push (imenu-example--name-and-position)
 353                            index-var-alist))
 354                 ((looking-at "def\\(un\\|subst\\|macro\\|advice\\)")
 355                      (forward-sexp 2)
 356                      (push (imenu-example--name-and-position)
 357                            index-alist))
 358                 ((looking-at "def\\(type\\|struct\\|class\\|ine-condition\\)")
 359                      (forward-sexp 2)
 360                  (if (= (char-after (1- (point))) ?\))
 361                          (progn
 362                        (forward-sexp -1)
 363                            (down-list 1)
 364                        (forward-sexp 1)))
 365                      (push (imenu-example--name-and-position)
 366                            index-type-alist))
 367                     (t
 368                      (forward-sexp 2)
 369                      (push (imenu-example--name-and-position)
 370                        index-unknown-alist)))))))
 371     (imenu-progress-message prev-pos 100)
 372     (and index-var-alist
 373          (push (cons "Variables" index-var-alist)
 374                index-alist))
 375     (and index-type-alist
 376          (push (cons "Types" index-type-alist)
 377                index-alist))
 378     (and index-unknown-alist
 379          (push (cons "Syntax-unknown" index-unknown-alist)
 380                index-alist))
 381     index-alist))
 382
 383 ;; Regular expression to find C functions
 384 (defvar imenu-example--function-name-regexp-c
 385   (concat
 386    "^[a-zA-Z0-9]+[ \t]?"                ; type specs; there can be no
 387    "\\([a-zA-Z0-9_*]+[ \t]+\\)?"        ; more than 3 tokens, right?
 388    "\\([a-zA-Z0-9_*]+[ \t]+\\)?"
 389    "\\([*&]+[ \t]*\\)?"                 ; pointer
 390    "\\([a-zA-Z0-9_*]+\\)[ \t]*("        ; name
 391    ))
 392
 393 (defun imenu-example--create-c-index (&optional regexp)
 394   (let ((index-alist '())
 395         prev-pos char)
 396     (goto-char (point-min))
 397     (imenu-progress-message prev-pos 0)
 398     ;; Search for the function
 399     (save-match-data
 400       (while (re-search-forward
 401               (or regexp imenu-example--function-name-regexp-c)
 402               nil t)
 403         (imenu-progress-message prev-pos)
 404         (backward-up-list 1)
 405         (save-excursion
 406           (goto-char (scan-sexps (point) 1))
 407           (setq char (following-char)))
 408         ;; Skip this function name if it is a prototype declaration.
 409         (if (not (eq char ?\;))
 410             (push (imenu-example--name-and-position) index-alist))))
 411     (imenu-progress-message prev-pos 100)
 412     (nreverse index-alist)))
 413
 414
 415 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 416 ;;;
 417 ;;; Internal variables
 418 ;;;
 419 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 420
 421 ;; The item to use in the index for rescanning the buffer.
 422 (defconst imenu--rescan-item '("*Rescan*" . -99))
 423
 424 ;; The latest buffer index.
 425 ;; Buffer local.
 426 (defvar imenu--index-alist nil
 427   "The buffer index alist computed for this buffer in Imenu.
 428
 429 Simple elements in the alist look like (INDEX-NAME . POSITION).
 430 POSITION is the buffer position of the item; to go to the item
 431 is simply to move point to that position.
 432
 433 Special elements look like (INDEX-NAME POSITION FUNCTION ARGUMENTS...).
 434 To \"go to\" a special element means applying FUNCTION
 435 to INDEX-NAME, POSITION, and the ARGUMENTS.
 436
 437 A nested sub-alist element looks like (INDEX-NAME SUB-ALIST).
 438 The function `imenu--subalist-p' tests an element and returns t
 439 if it is a sub-alist.
 440
 441 There is one simple element with negative POSITION; selecting that
 442 element recalculates the buffer's index alist.")
 443
 444 (make-variable-buffer-local 'imenu--index-alist)
 445
 446 (defvar imenu--last-menubar-index-alist nil
 447   "The latest buffer index alist used to update the menu bar menu.")
 448
 449 (make-variable-buffer-local 'imenu--last-menubar-index-alist)
 450
 451 ;; History list for 'jump-to-function-in-buffer'.
 452 ;; Making this buffer local caused it not to work!
 453 (defvar imenu--history-list nil)
 454
 455 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 456 ;;;
 457 ;;; Internal support functions
 458 ;;;
 459 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 460
 461 ;;;
 462 ;;; Sort function
 463 ;;; Sorts the items depending on their index name.
 464 ;;; An item looks like (NAME . POSITION).
 465 ;;;
 466 (defun imenu--sort-by-name (item1 item2)
 467   (string-lessp (car item1) (car item2)))
 468
 469 (defun imenu--sort-by-position (item1 item2)
 470   (< (cdr item1) (cdr item2)))
 471
 472 (defun imenu--relative-position (&optional reverse)
 473   ;; Support function to calculate relative position in buffer
 474   ;; Beginning of buffer is 0 and end of buffer is 100
 475   ;; If REVERSE is non-nil then the beginning is 100 and the end is 0.
 476   (let ((pos (point))
 477         (total (buffer-size)))
 478     (and reverse (setq pos (- total pos)))
 479     (if (> total 50000)
 480         ;; Avoid overflow from multiplying by 100!
 481         (/ (1- pos) (max (/ total 100) 1))
 482       (/ (* 100 (1- pos)) (max total 1)))))
 483
 484 ;; Split LIST into sublists of max length N.
 485 ;; Example (imenu--split '(1 2 3 4 5 6 7 8) 3)-> '((1 2 3) (4 5 6) (7 8))
 486 ;;
 487 ;; The returned list DOES NOT share structure with LIST.
 488 (defun imenu--split (list n)
 489   (let ((remain list)
 490         (result '())
 491         (sublist '())
 492         (i 0))
 493     (while remain
 494       (push (pop remain) sublist)
 495       (incf i)
 496       (and (= i n)
 497            ;; We have finished a sublist
 498            (progn (push (nreverse sublist) result)
 499                   (setq i 0)
 500                   (setq sublist '()))))
 501     ;; There might be a sublist (if the length of LIST mod n is != 0)
 502     ;; that has to be added to the result list.
 503     (and sublist
 504          (push (nreverse sublist) result))
 505     (nreverse result)))
 506
 507 ;;; Split the alist MENULIST into a nested alist, if it is long enough.
 508 ;;; In any case, add TITLE to the front of the alist.
 509 ;;; If IMENU--RESCAN-ITEM is present in MENULIST, it is moved to the
 510 ;;; beginning of the returned alist.
 511 ;;;
 512 ;;; The returned alist DOES NOT share structure with MENULIST.
 513 (defun imenu--split-menu (menulist title)
 514   (let ((menulist (copy-sequence menulist))
 515         keep-at-top tail)
 516     (if (memq imenu--rescan-item menulist)
 517         (setq keep-at-top (list imenu--rescan-item)
 518               menulist (delq imenu--rescan-item menulist)))
 519     (setq tail menulist)
 520     (dolist (item tail)
 521       (when (imenu--subalist-p item)
 522         (push item keep-at-top)
 523         (setq menulist (delq item menulist))))
 524     (if imenu-sort-function
 525         (setq menulist (sort menulist imenu-sort-function)))
 526     (if (> (length menulist) imenu-max-items)
 527         (setq menulist
 528               (mapcar
 529                (lambda (menu)
 530                  (cons (format "From: %s" (caar menu)) menu))
 531                (imenu--split menulist imenu-max-items))))
 532     (cons title
 533           (nconc (nreverse keep-at-top) menulist))))
 534
 535 ;;; Split up each long alist that are nested within ALIST
 536 ;;; into nested alists.
 537 ;;;
 538 ;;; Return a split and sorted copy of ALIST. The returned alist DOES
 539 ;;; NOT share structure with ALIST.
 540 (defun imenu--split-submenus (alist)
 541   (mapcar (function
 542            (lambda (elt)
 543              (if (and (consp elt)
 544                       (stringp (car elt))
 545                       (listp (cdr elt)))
 546                  (imenu--split-menu (cdr elt) (car elt))
 547                elt)))
 548           alist))
 549
 550 ;;; Truncate all strings in MENULIST to imenu-max-item-length
 551 (defun imenu--truncate-items (menulist)
 552   (mapcar (function
 553            (lambda (item)
 554              (cond
 555               ((consp (cdr item))
 556                (imenu--truncate-items (cdr item)))
 557               ;; truncate if necessary
 558               ((and (numberp imenu-max-item-length)
 559                     (> (length (car item)) imenu-max-item-length))
 560                (setcar item (substring (car item) 0 imenu-max-item-length))))))
 561           menulist))
 562
 563
 564 (defun imenu--make-index-alist (&optional noerror)
 565   "Create an index alist for the definitions in the current buffer.
 566 This works by using the hook function `imenu-create-index-function'.
 567 Report an error if the list is empty unless NOERROR is supplied and
 568 non-nil.
 569
 570 See `imenu--index-alist' for the format of the index alist."
 571   (or (and imenu--index-alist
 572            (or (not imenu-auto-rescan)
 573                (and imenu-auto-rescan
 574                     (> (buffer-size)  imenu-auto-rescan-maxout))))
 575       ;; Get the index; truncate if necessary
 576       (progn
 577         (setq imenu--index-alist
 578               (save-excursion
 579                 (save-restriction
 580                   (widen)
 581                   (funcall imenu-create-index-function))))
 582         (imenu--truncate-items imenu--index-alist)))
 583   (or imenu--index-alist noerror
 584       (error "No items suitable for an index found in this buffer"))
 585   (or imenu--index-alist
 586       (setq imenu--index-alist (list nil)))
 587   ;; Add a rescan option to the index.
 588   (cons imenu--rescan-item imenu--index-alist))
 589
 590 ;;; Find all markers in alist and makes
 591 ;;; them point nowhere.
 592 ;;; The top-level call uses nil as the argument;
 593 ;;; non-nil arguments are in recursivecalls.
 594 (defvar imenu--cleanup-seen)
 595
 596 (defun imenu--cleanup (&optional alist)
 597   ;; If alist is provided use that list.
 598   ;; If not, empty the table of lists already seen
 599   ;; and use imenu--index-alist.
 600   (if alist
 601       (setq imenu--cleanup-seen (cons alist imenu--cleanup-seen))
 602     (setq alist imenu--index-alist imenu--cleanup-seen (list alist)))
 603
 604   (and alist
 605        (mapc
 606         (lambda (item)
 607           (cond
 608            ((markerp (cdr item))
 609             (set-marker (cdr item) nil))
 610            ;; Don't process one alist twice.
 611            ((memq (cdr item) imenu--cleanup-seen))
 612            ((imenu--subalist-p item)
 613             (imenu--cleanup (cdr item)))))
 614         alist)
 615        t))
 616
 617 (defun imenu--create-keymap (title alist &optional cmd)
 618   (list* 'keymap title
 619          (mapcar
 620           (lambda (item)
 621             (list* (car item) (car item)
 622                    (cond
 623                     ((imenu--subalist-p item)
 624                      (imenu--create-keymap (car item) (cdr item) cmd))
 625                     (t
 626                      `(lambda () (interactive)
 627                         ,(if cmd `(,cmd ',item) (list 'quote item)))))))
 628           alist)))
 629
 630 (defun imenu--in-alist (str alist)
 631   "Check whether the string STR is contained in multi-level ALIST."
 632   (let (elt head tail res)
 633     (setq res nil)
 634     (while alist
 635       (setq elt (car alist)
 636             tail (cdr elt)
 637             alist (cdr alist)
 638             head (car elt))
 639       ;; A nested ALIST element looks like
 640       ;;   (INDEX-NAME (INDEX-NAME . INDEX-POSITION) ...)
 641       ;; while a bottom-level element looks like
 642       ;;   (INDEX-NAME . INDEX-POSITION)
 643       ;; We are only interested in the bottom-level elements, so we need to
 644       ;; recurse if TAIL is a list.
 645       (cond ((listp tail)
 646              (if (setq res (imenu--in-alist str tail))
 647                  (setq alist nil)))
 648             ((if imenu-name-lookup-function
 649                  (funcall imenu-name-lookup-function str head)
 650                (string= str head))
 651              (setq alist nil res elt))))
 652     res))
 653
 654 (defvar imenu-syntax-alist nil
 655   "Alist of syntax table modifiers to use while in `imenu--generic-function'.
 656
 657 The car of the assocs may be either a character or a string and the
 658 cdr is a syntax description appropriate for `modify-syntax-entry'.  For
 659 a string, all the characters in the string get the specified syntax.
 660
 661 This is typically used to give word syntax to characters which
 662 normally have symbol syntax to simplify `imenu-expression'
 663 and speed-up matching.")
 664 ;;;###autoload
 665 (make-variable-buffer-local 'imenu-syntax-alist)
 666
 667 (defun imenu-default-create-index-function ()
 668   "Default function to create an index alist of the current buffer.
 669
 670 The most general method is to move point to end of buffer, then repeatedly call
 671 `imenu-prev-index-position-function' and `imenu-extract-index-name-function'.
 672 All the results returned by the latter are gathered into an index alist.
 673 This method is used if those two variables are non-nil.
 674
 675 The alternate method, which is the one most often used, is to call
 676 `imenu--generic-function' with `imenu-generic-expression' as argument."
 677   ;; These should really be done by setting imenu-create-index-function
 678   ;; in these major modes.  But save that change for later.
 679   (cond ((and imenu-prev-index-position-function
 680               imenu-extract-index-name-function)
 681          (let ((index-alist '())
 682                prev-pos name)
 683            (goto-char (point-max))
 684            (imenu-progress-message prev-pos 0 t)
 685            ;; Search for the function
 686            (while (funcall imenu-prev-index-position-function)
 687              (imenu-progress-message prev-pos nil t)
 688              (save-excursion
 689                (setq name (funcall imenu-extract-index-name-function)))
 690              (and (stringp name)
 691                   ;; [ydi] updated for imenu-use-markers
 692                   (push (cons name (if imenu-use-markers (point-marker) (point)))
 693                         index-alist)))
 694            (imenu-progress-message prev-pos 100 t)
 695            index-alist))
 696         ;; Use generic expression if possible.
 697         ((and imenu-generic-expression)
 698          (imenu--generic-function imenu-generic-expression))
 699         (t
 700          (error "This buffer cannot use `imenu-default-create-index-function'"))))
 701
 702 ;;;
 703 ;;; Generic index gathering function.
 704 ;;;
 705
 706 (defvar imenu-case-fold-search t
 707   "Defines whether `imenu--generic-function' should fold case when matching.
 708
 709 This variable should be set (only) by initialization code
 710 for modes which use `imenu--generic-function'.  If it is not set, but
 711 `font-lock-defaults' is set, then font-lock's setting is used.")
 712 ;;;###autoload
 713 (make-variable-buffer-local 'imenu-case-fold-search)
 714
 715 ;; This function can be called with quitting disabled,
 716 ;; so it needs to be careful never to loop!
 717 (defun imenu--generic-function (patterns)
 718   "Return an index alist of the current buffer based on PATTERNS.
 719
 720 PATTERNS is an alist with elements that look like this:
 721  (MENU-TITLE REGEXP INDEX)
 722 or like this:
 723  (MENU-TITLE REGEXP INDEX FUNCTION ARGUMENTS...)
 724 with zero or more ARGUMENTS.  The former format creates a simple
 725 element in the index alist when it matches; the latter creates a
 726 special element of the form (INDEX-NAME POSITION-MARKER FUNCTION
 727 ARGUMENTS...) with FUNCTION and ARGUMENTS copied from PATTERNS.
 728
 729 MENU-TITLE is a string used as the title for the submenu or nil
 730 if the entries are not nested.
 731
 732 REGEXP is a regexp that should match a construct in the buffer
 733 that is to be displayed in the menu; i.e., function or variable
 734 definitions, etc.  It contains a substring which is the name to
 735 appear in the menu.  See the info section on Regexps for more
 736 information.  REGEXP may also be a function, called without
 737 arguments.  It is expected to search backwards.  It shall return
 738 true and set `match-data' if it finds another element.
 739
 740 INDEX points to the substring in REGEXP that contains the
 741 name (of the function, variable or type) that is to appear in the
 742 menu.
 743
 744 The variable `imenu-case-fold-search' determines whether or not the
 745 regexp matches are case sensitive, and `imenu-syntax-alist' can be
 746 used to alter the syntax table for the search.
 747
 748 See `lisp-imenu-generic-expression' for an example of PATTERNS.
 749
 750 Returns an index of the current buffer as an alist.  The elements in
 751 the alist look like:
 752  (INDEX-NAME . INDEX-POSITION)
 753 or like:
 754  (INDEX-NAME INDEX-POSITION FUNCTION ARGUMENTS...)
 755 They may also be nested index alists like:
 756  (INDEX-NAME . INDEX-ALIST)
 757 depending on PATTERNS."
 758
 759   (let ((index-alist (list 'dummy))
 760         prev-pos
 761         (case-fold-search (if (or (local-variable-p 'imenu-case-fold-search)
 762                                   (not (local-variable-p 'font-lock-defaults)))
 763                               imenu-case-fold-search
 764                             (nth 2 font-lock-defaults)))
 765         (old-table (syntax-table))
 766         (table (copy-syntax-table (syntax-table)))
 767         (slist imenu-syntax-alist))
 768     ;; Modify the syntax table used while matching regexps.
 769     (dolist (syn slist)
 770       ;; The character(s) to modify may be a single char or a string.
 771       (if (numberp (car syn))
 772           (modify-syntax-entry (car syn) (cdr syn) table)
 773         (mapc (lambda (c)
 774                 (modify-syntax-entry c (cdr syn) table))
 775               (car syn))))
 776     (goto-char (point-max))
 777     (imenu-progress-message prev-pos 0 t)
 778     (unwind-protect                     ; for syntax table
 779         (save-match-data
 780           (set-syntax-table table)
 781
 782           ;; map over the elements of imenu-generic-expression
 783           ;; (typically functions, variables ...)
 784           (dolist (pat patterns)
 785             (let ((menu-title (car pat))
 786                   (regexp (nth 1 pat))
 787                   (index (nth 2 pat))
 788                   (function (nth 3 pat))
 789                   (rest (nthcdr 4 pat))
 790                   start beg)
 791               ;; Go backwards for convenience of adding items in order.
 792               (goto-char (point-max))
 793               (while (and (if (functionp regexp)
 794                               (funcall regexp)
 795                             (re-search-backward regexp nil t))
 796                           ;; Exit the loop if we get an empty match,
 797                           ;; because it means a bad regexp was specified.
 798                           (not (= (match-beginning 0) (match-end 0))))
 799                 (setq start (point))
 800                 ;; Record the start of the line in which the match starts.
 801                 ;; That's the official position of this definition.
 802                 (goto-char (match-beginning index))
 803                 (beginning-of-line)
 804                 (setq beg (point))
 805                 (imenu-progress-message prev-pos nil t)
 806                 ;; Add this sort of submenu only when we've found an
 807                 ;; item for it, avoiding empty, duff menus.
 808                 (unless (assoc menu-title index-alist)
 809                   (push (list menu-title) index-alist))
 810                 (if imenu-use-markers
 811                     (setq beg (copy-marker beg)))
 812                 (let ((item
 813                        (if function
 814                            (nconc (list (match-string-no-properties index)
 815                                         beg function)
 816                                   rest)
 817                          (cons (match-string-no-properties index)
 818                                beg)))
 819                       ;; This is the desired submenu,
 820                       ;; starting with its title (or nil).
 821                       (menu (assoc menu-title index-alist)))
 822                   ;; Insert the item unless it is already present.
 823                   (unless (member item (cdr menu))
 824                     (setcdr menu
 825                             (cons item (cdr menu)))))
 826                 ;; Go to the start of the match, to make sure we
 827                 ;; keep making progress backwards.
 828                 (goto-char start))))
 829           (set-syntax-table old-table)))
 830     (imenu-progress-message prev-pos 100 t)
 831     ;; Sort each submenu by position.
 832     ;; This is in case one submenu gets items from two different regexps.
 833     (dolist (item index-alist)
 834       (when (listp item)
 835         (setcdr item (sort (cdr item) 'imenu--sort-by-position))))
 836     (let ((main-element (assq nil index-alist)))
 837       (nconc (delq main-element (delq 'dummy index-alist))
 838              (cdr main-element)))))
 839
 840 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 841 ;;;
 842 ;;; The main functions for this package!
 843 ;;;
 844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 845
 846 ;; See also info-lookup-find-item
 847 (defun imenu-find-default (guess completions)
 848   "Fuzzily find an item based on GUESS inside the alist COMPLETIONS."
 849   (catch 'found
 850     (let ((case-fold-search t))
 851       (if (assoc guess completions) guess
 852         (dolist (re (list (concat "\\`" (regexp-quote guess) "\\'")
 853                           (concat "\\`" (regexp-quote guess))
 854                           (concat (regexp-quote guess) "\\'")
 855                           (regexp-quote guess)))
 856           (dolist (x completions)
 857             (if (string-match re (car x)) (throw 'found (car x)))))))))
 858
 859 (defun imenu--completion-buffer (index-alist &optional prompt)
 860   "Let the user select from INDEX-ALIST in a completion buffer with PROMPT.
 861
 862 Return one of the entries in index-alist or nil."
 863   ;; Create a list for this buffer only when needed.
 864   (let ((name (thing-at-point 'symbol))
 865         choice
 866         (prepared-index-alist
 867          (if (not imenu-space-replacement) index-alist
 868            (mapcar
 869             (lambda (item)
 870               (cons (subst-char-in-string ?\s (aref imenu-space-replacement 0)
 871                                           (car item))
 872                     (cdr item)))
 873             index-alist))))
 874     (when (stringp name)
 875       (setq name (or (imenu-find-default name prepared-index-alist) name)))
 876     (cond (prompt)
 877           ((and name (imenu--in-alist name prepared-index-alist))
 878            (setq prompt (format "Index item (default %s): " name)))
 879           (t (setq prompt "Index item: ")))
 880     (let ((minibuffer-setup-hook minibuffer-setup-hook))
 881       ;; Display the completion buffer.
 882       (if (not imenu-eager-completion-buffer)
 883           (add-hook 'minibuffer-setup-hook 'minibuffer-completion-help))
 884       (setq name (completing-read prompt
 885                                   prepared-index-alist
 886                                   nil t nil 'imenu--history-list name)))
 887
 888     (when (stringp name)
 889       (setq choice (assoc name prepared-index-alist))
 890       (if (imenu--subalist-p choice)
 891           (imenu--completion-buffer (cdr choice) prompt)
 892         choice))))
 893
 894 (defun imenu--mouse-menu (index-alist event &optional title)
 895   "Let the user select from a buffer index from a mouse menu.
 896
 897 INDEX-ALIST is the buffer index and EVENT is a mouse event.
 898
 899 Returns t for rescan and otherwise an element or subelement of INDEX-ALIST."
 900   (setq index-alist (imenu--split-submenus index-alist))
 901   (let* ((menu (imenu--split-menu index-alist (or title (buffer-name))))
 902          (map (imenu--create-keymap (car menu)
 903                                     (cdr (if (< 1 (length (cdr menu)))
 904                                              menu
 905                                            (car (cdr menu)))))))
 906     (popup-menu map event)))
 907
 908 (defun imenu-choose-buffer-index (&optional prompt alist)
 909   "Let the user select from a buffer index and return the chosen index.
 910
 911 If the user originally activated this function with the mouse, a mouse
 912 menu is used.  Otherwise a completion buffer is used and the user is
 913 prompted with PROMPT.
 914
 915 If you call this function with index alist ALIST, then it lets the user
 916 select from ALIST.
 917
 918 With no index alist ALIST, it calls `imenu--make-index-alist' to
 919 create the index alist.
 920
 921 If `imenu-use-popup-menu' is nil, then the completion buffer
 922 is always used, no matter if the mouse was used or not.
 923
 924 The returned value is of the form (INDEX-NAME . INDEX-POSITION)."
 925   (let (index-alist
 926         (mouse-triggered (listp last-nonmenu-event))
 927         (result t))
 928     ;; If selected by mouse, see to that the window where the mouse is
 929     ;; really is selected.
 930     (and mouse-triggered
 931          (not (equal last-nonmenu-event '(menu-bar)))
 932          (let ((window (posn-window (event-start last-nonmenu-event))))
 933            (or (framep window) (null window) (select-window window))))
 934     ;; Create a list for this buffer only when needed.
 935     (while (eq result t)
 936       (setq index-alist (if alist alist (imenu--make-index-alist)))
 937       (setq result
 938             (if (and imenu-use-popup-menu
 939                      (or (eq imenu-use-popup-menu t) mouse-triggered))
 940                 (imenu--mouse-menu index-alist last-nonmenu-event)
 941               (imenu--completion-buffer index-alist prompt)))
 942       (and (equal result imenu--rescan-item)
 943            (imenu--cleanup)
 944            (setq result t imenu--index-alist nil)))
 945     result))
 946
 947 ;;;###autoload
 948 (defun imenu-add-to-menubar (name)
 949   "Add an `imenu' entry to the menu bar for the current buffer.
 950 NAME is a string used to name the menu bar item.
 951 See the command `imenu' for more information."
 952   (interactive "sImenu menu item name: ")
 953   (if (or (and imenu-prev-index-position-function
 954                imenu-extract-index-name-function)
 955           imenu-generic-expression
 956           (not (eq imenu-create-index-function
 957                    'imenu-default-create-index-function)))
 958       (let ((newmap (make-sparse-keymap)))
 959         (set-keymap-parent newmap (current-local-map))
 960         (setq imenu--last-menubar-index-alist nil)
 961         (define-key newmap [menu-bar index]
 962           `(menu-item ,name ,(make-sparse-keymap "Imenu")))
 963         (use-local-map newmap)
 964         (add-hook 'menu-bar-update-hook 'imenu-update-menubar))
 965     (error "The mode `%s' does not support Imenu"
 966            (format-mode-line mode-name))))
 967
 968 ;;;###autoload
 969 (defun imenu-add-menubar-index ()
 970   "Add an Imenu \"Index\" entry on the menu bar for the current buffer.
 971
 972 A trivial interface to `imenu-add-to-menubar' suitable for use in a hook."
 973   (interactive)
 974   (imenu-add-to-menubar "Index"))
 975
 976 (defvar imenu-buffer-menubar nil)
 977
 978 (defvar imenu-menubar-modified-tick 0
 979   "The value of (buffer-chars-modified-tick) as of the last call
 980 to `imenu-update-menubar'.")
 981 (make-variable-buffer-local 'imenu-menubar-modified-tick)
 982
 983 (defun imenu-update-menubar ()
 984   (when (and (current-local-map)
 985              (keymapp (lookup-key (current-local-map) [menu-bar index]))
 986              (/= (buffer-chars-modified-tick) imenu-menubar-modified-tick))
 987     (setq imenu-menubar-modified-tick (buffer-chars-modified-tick))
 988     (let ((index-alist (imenu--make-index-alist t)))
 989       ;; Don't bother updating if the index-alist has not changed
 990       ;; since the last time we did it.
 991       (unless (equal index-alist imenu--last-menubar-index-alist)
 992         (let (menu menu1 old)
 993           (setq imenu--last-menubar-index-alist index-alist)
 994           (setq index-alist (imenu--split-submenus index-alist))
 995           (setq menu (imenu--split-menu index-alist
 996                                         (buffer-name)))
 997           (setq menu1 (imenu--create-keymap (car menu)
 998                                             (cdr (if (< 1 (length (cdr menu)))
 999                                                      menu
1000                                                    (car (cdr menu))))
1001                                             'imenu--menubar-select))
1002           (setq old (lookup-key (current-local-map) [menu-bar index]))
1003           (setcdr old (cdr menu1)))))))
1004
1005 (defun imenu--menubar-select (item)
1006   "Use Imenu to select the function or variable named in this menu ITEM."
1007   (if (equal item imenu--rescan-item)
1008       (progn
1009         (imenu--cleanup)
1010         ;; Make sure imenu-update-menubar redoes everything.
1011         (setq imenu-menubar-modified-tick -1)
1012         (setq imenu--index-alist nil)
1013         (setq imenu--last-menubar-index-alist nil)
1014         (imenu-update-menubar)
1015         t)
1016     (imenu item)
1017     nil))
1018
1019 (defun imenu-default-goto-function (name position &optional rest)
1020   "Move to the given position.
1021
1022 NAME is ignored.  POSITION is where to move.  REST is also ignored.
1023 The ignored args just make this function have the same interface as a
1024 function placed in a special index-item."
1025   (if (or (< position (point-min))
1026           (> position (point-max)))
1027       ;; widen if outside narrowing
1028       (widen))
1029   (goto-char position))
1030
1031 ;;;###autoload
1032 (defun imenu (index-item)
1033   "Jump to a place in the buffer chosen using a buffer menu or mouse menu.
1034 INDEX-ITEM specifies the position.  See `imenu-choose-buffer-index'
1035 for more information."
1036   (interactive (list (imenu-choose-buffer-index)))
1037   ;; Convert a string to an alist element.
1038   (if (stringp index-item)
1039       (setq index-item (assoc index-item (imenu--make-index-alist))))
1040   (when index-item
1041     (push-mark)
1042     (let* ((is-special-item (listp (cdr index-item)))
1043            (function
1044             (if is-special-item
1045                 (nth 2 index-item) imenu-default-goto-function))
1046            (position (if is-special-item
1047                          (cadr index-item) (cdr index-item)))
1048            (rest (if is-special-item (cddr index-item))))
1049       (apply function (car index-item) position rest))
1050     (run-hooks 'imenu-after-jump-hook)))
1051
1052 (dolist (mess
1053          '("^No items suitable for an index found in this buffer$"
1054            "^This buffer cannot use `imenu-default-create-index-function'$"
1055            "^The mode `.*' does not support Imenu$"))
1056   (add-to-list 'debug-ignored-errors mess))
1057
1058 (provide 'imenu)
1059
1060 ;; arch-tag: 98a2f5f5-4b91-4704-b18c-3aacf77d77a7
1061 ;;; imenu.el ends here